libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN([GLIBCXX_CHECK_HOST], [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
  27   AC_MSG_NOTICE([OS config directory is $os_include_dir])
  28 ])
  29
  30 dnl
  31 dnl Initialize the rest of the library configury.  At this point we have
  32 dnl variables like $host.
  33 dnl
  34 dnl Sets:
  35 dnl  SUBDIRS
  36 dnl Substs:
  37 dnl  glibcxx_builddir     (absolute path)
  38 dnl  glibcxx_srcdir       (absolute path)
  39 dnl  toplevel_srcdir      (absolute path)
  40 dnl  with_cross_host
  41 dnl  with_newlib
  42 dnl  with_target_subdir
  43 dnl plus
  44 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  45 dnl  - default settings for all AM_CONFITIONAL test variables
  46 dnl  - lots of tools, like CC and CXX
  47 dnl
  48 AC_DEFUN([GLIBCXX_CONFIGURE], [
  49   # Keep these sync'd with the list in Makefile.am.  The first provides an
  50   # expandable list at autoconf time; the second provides an expandable list
  51   # (i.e., shell variable) at configure time.
  52   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src doc po testsuite])
  53   SUBDIRS='glibcxx_SUBDIRS'
  54
  55   # These need to be absolute paths, yet at the same time need to
  56   # canonicalize only relative paths, because then amd will not unmount
  57   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  58   glibcxx_builddir=`${PWDCMD-pwd}`
  59   case $srcdir in
  60     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  61     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  62   esac
  63   toplevel_srcdir=${glibcxx_srcdir}/..
  64   AC_SUBST(glibcxx_builddir)
  65   AC_SUBST(glibcxx_srcdir)
  66   AC_SUBST(toplevel_srcdir)
  67
  68   # We use these options to decide which functions to include.  They are
  69   # set from the top level.
  70   AC_ARG_WITH([target-subdir],
  71     AC_HELP_STRING([--with-target-subdir=SUBDIR],
  72                    [configuring in a subdirectory]))
  73
  74   AC_ARG_WITH([cross-host],
  75     AC_HELP_STRING([--with-cross-host=HOST],
  76                    [configuring with a cross compiler]))
  77
  78   AC_ARG_WITH([newlib],
  79     AC_HELP_STRING([--with-newlib],
  80                    [assume newlib as a system C library]))
  81
  82   # We're almost certainly being configured before anything else which uses
  83   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
  84   # we not cache the value of CXX that we "discover" here, because it's set
  85   # to something unique for us and libjava.  Other target libraries need to
  86   # find CXX for themselves.  We yank the rug out from under the normal AC_*
  87   # process by sneakily renaming the cache variable.  This also lets us debug
  88   # the value of "our" CXX in postmortems.
  89   #
  90   # We must also force CXX to /not/ be a precious variable, otherwise the
  91   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
  92   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
  93   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
  94   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
  95   #
  96   # -fno-builtin must be present here so that a non-conflicting form of
  97   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  98
  99   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 100   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 101   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 102   save_CXXFLAGS="$CXXFLAGS"
 103   CXXFLAGS="$CXXFLAGS -fno-builtin"
 104   AC_PROG_CC
 105   AC_PROG_CXX
 106   CXXFLAGS="$save_CXXFLAGS"
 107   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 108   AC_SUBST(CFLAGS)
 109   AC_SUBST(CXXFLAGS)
 110
 111   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 112   # available).  Uncomment the next line to force a particular method.
 113   AC_PROG_LN_S
 114   #LN_S='cp -p'
 115
 116   AC_CHECK_TOOL(AS, as)
 117   AC_CHECK_TOOL(AR, ar)
 118   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 119
 120   AM_MAINTAINER_MODE
 121
 122   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 123   # which are themselves conditionally expanded.
 124   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 125   ## other macros from doing the same.  This should be automated.)  -pme
 126   need_libmath=no
 127
 128   # Check for uClibc since Linux platforms use different configuration
 129   # directories depending on the C library in use.
 130   AC_EGREP_CPP([_using_uclibc], [
 131   #include <stdio.h>
 132   #if __UCLIBC__
 133     _using_uclibc
 134   #endif
 135   ], uclibc=yes, uclibc=no)
 136
 137   # Find platform-specific directories containing configuration info.
 138   # Also possibly modify flags used elsewhere, as needed by the platform.
 139   GLIBCXX_CHECK_HOST
 140 ])
 141
 142
 143 dnl
 144 dnl Tests for newer compiler features, or features that are present in newer
 145 dnl compiler versions but not older compiler versions still in use, should
 146 dnl be placed here.
 147 dnl
 148 dnl Defines:
 149 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 150 dnl   new inlining code or the new system_header pragma will die on -Werror.
 151 dnl   Leave it out by default and use maint-mode to use it.
 152 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 153 dnl   compiler supports it and the user has not requested debug mode.
 154 dnl
 155 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
 156   # All these tests are for C++; save the language and the compiler flags.
 157   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 158   # found in GLIBCXX_CONFIGURE.
 159   AC_LANG_SAVE
 160   AC_LANG_CPLUSPLUS
 161   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 162   ac_save_CXXFLAGS="$CXXFLAGS"
 163
 164   # Check for maintainer-mode bits.
 165   if test x"$USE_MAINTAINER_MODE" = xno; then
 166     WERROR=''
 167   else
 168     WERROR='-Werror'
 169   fi
 170
 171   # Check for -ffunction-sections -fdata-sections
 172   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 173   CXXFLAGS='-g -Werror -ffunction-sections -fdata-sections'
 174   AC_TRY_COMPILE([int foo; void bar() { };],, [ac_fdsections=yes], [ac_fdsections=no])
 175   if test "$ac_test_CXXFLAGS" = set; then
 176     CXXFLAGS="$ac_save_CXXFLAGS"
 177   else
 178     # this is the suspicious part
 179     CXXFLAGS=''
 180   fi
 181   if test x"$ac_fdsections" = x"yes"; then
 182     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 183   fi
 184   AC_MSG_RESULT($ac_fdsections)
 185
 186   AC_LANG_RESTORE
 187   AC_SUBST(WERROR)
 188   AC_SUBST(SECTION_FLAGS)
 189 ])
 190
 191
 192 dnl
 193 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 194 dnl the native linker is in use, all variables will be defined to something
 195 dnl safe (like an empty string).
 196 dnl
 197 dnl Defines:
 198 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 199 dnl  OPT_LDFLAGS='-Wl,-O1' and '-z,relro' if possible
 200 dnl  LD (as a side effect of testing)
 201 dnl Sets:
 202 dnl  with_gnu_ld
 203 dnl  glibcxx_gnu_ld_version (possibly)
 204 dnl
 205 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 206 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 207 dnl
 208 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
 209   # If we're not using GNU ld, then there's no point in even trying these
 210   # tests.  Check for that first.  We should have already tested for gld
 211   # by now (in libtool), but require it now just to be safe...
 212   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 213   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 214   AC_REQUIRE([AC_PROG_LD])
 215   AC_REQUIRE([AC_PROG_AWK])
 216
 217   # The name set by libtool depends on the version of libtool.  Shame on us
 218   # for depending on an impl detail, but c'est la vie.  Older versions used
 219   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 220   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 221   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 222   # set (hence we're using an older libtool), then set it.
 223   if test x${with_gnu_ld+set} != xset; then
 224     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 225       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 226       with_gnu_ld=no
 227     else
 228       with_gnu_ld=$ac_cv_prog_gnu_ld
 229     fi
 230   fi
 231
 232   # Start by getting the version number.  I think the libtool test already
 233   # does some of this, but throws away the result.
 234   if test x"$with_gnu_ld" = x"yes"; then
 235     AC_MSG_CHECKING([for ld version])
 236     changequote(,)
 237     ldver=`$LD --version 2>/dev/null | head -1 | \
 238            sed -e 's/GNU ld \(version \)\{0,1\}\(([^)]*) \)\{0,1\}\([0-9.][0-9.]*\).*/\3/'`
 239     changequote([,])
 240     glibcxx_gnu_ld_version=`echo $ldver | \
 241            $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 242     AC_MSG_RESULT($glibcxx_gnu_ld_version)
 243   fi
 244
 245   # Set --gc-sections.
 246   glibcxx_gcsections_min_ld=21602
 247   if test x"$with_gnu_ld" = x"yes" &&
 248         test $glibcxx_gnu_ld_version -gt $glibcxx_gcsections_min_ld ; then
 249
 250     # Sufficiently young GNU ld it is!  Joy and bunny rabbits!
 251     # NB: This flag only works reliably after 2.16.1. Configure tests
 252     # for this are difficult, so hard wire a value that should work.
 253
 254     ac_test_CFLAGS="${CFLAGS+set}"
 255     ac_save_CFLAGS="$CFLAGS"
 256     CFLAGS='-Wl,--gc-sections'
 257
 258     # Check for -Wl,--gc-sections
 259     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 260     AC_TRY_LINK([ int one(void) { return 1; }
 261      int two(void) { return 2; }
 262         ], [ two(); ] , [ac_gcsections=yes], [ac_gcsections=no])
 263     if test "$ac_gcsections" = "yes"; then
 264       rm -f conftest.c
 265       touch conftest.c
 266       if $CC -c conftest.c; then
 267         if $LD --gc-sections -o conftest conftest.o 2>&1 | \
 268            grep "Warning: gc-sections option ignored" > /dev/null; then
 269           ac_gcsections=no
 270         fi
 271       fi
 272       rm -f conftest.c conftest.o conftest
 273     fi
 274     if test "$ac_gcsections" = "yes"; then
 275       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 276     fi
 277     AC_MSG_RESULT($ac_gcsections)
 278
 279     if test "$ac_test_CFLAGS" = set; then
 280       CFLAGS="$ac_save_CFLAGS"
 281     else
 282       # this is the suspicious part
 283       CFLAGS=''
 284     fi
 285   fi
 286
 287   # Set -z,relro.
 288   # Note this is only for shared objects.
 289   ac_ld_relro=no
 290   if test x"$with_gnu_ld" = x"yes"; then
 291     AC_MSG_CHECKING([for ld that supports -Wl,-z,relro])
 292     cxx_z_relo=`$LD -v --help 2>/dev/null | grep "z relro"`
 293     if test -n "$cxx_z_relo"; then
 294       OPT_LDFLAGS="-Wl,-z,relro"
 295       ac_ld_relro=yes
 296     fi
 297     AC_MSG_RESULT($ac_ld_relro)
 298   fi
 299
 300   # Set linker optimization flags.
 301   if test x"$with_gnu_ld" = x"yes"; then
 302     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 303   fi
 304
 305   AC_SUBST(SECTION_LDFLAGS)
 306   AC_SUBST(OPT_LDFLAGS)
 307 ])
 308
 309
 310 dnl
 311 dnl Check for headers for, and arguments to, the setrlimit() function.
 312 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 313 dnl
 314 dnl Defines:
 315 dnl  _GLIBCXX_RES_LIMITS if we can set artificial resource limits
 316 dnl  various HAVE_LIMIT_* for individual limit names
 317 dnl
 318 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
 319   AC_MSG_CHECKING([for RLIMIT_$1])
 320   AC_TRY_COMPILE(
 321     [#include <unistd.h>
 322      #include <sys/time.h>
 323      #include <sys/resource.h>
 324     ],
 325     [ int f = RLIMIT_$1 ; ],
 326     [glibcxx_mresult=1], [glibcxx_mresult=0])
 327   AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
 328                      [Only used in build directory testsuite_hooks.h.])
 329   if test $glibcxx_mresult = 1 ; then res=yes ; else res=no ; fi
 330   AC_MSG_RESULT($res)
 331 ])
 332
 333 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
 334   setrlimit_have_headers=yes
 335   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 336                    [],
 337                    [setrlimit_have_headers=no])
 338   # If don't have the headers, then we can't run the tests now, and we
 339   # won't be seeing any of these during testsuite compilation.
 340   if test $setrlimit_have_headers = yes; then
 341     # Can't do these in a loop, else the resulting syntax is wrong.
 342     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 343     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 344     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 345     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 346     GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
 347
 348     # Check for rlimit, setrlimit.
 349     AC_CACHE_VAL(ac_setrlimit, [
 350       AC_TRY_COMPILE(
 351         [#include <unistd.h>
 352          #include <sys/time.h>
 353          #include <sys/resource.h>
 354         ],
 355         [struct rlimit r;
 356          setrlimit(0, &r);],
 357         [ac_setrlimit=yes], [ac_setrlimit=no])
 358     ])
 359   fi
 360
 361   AC_MSG_CHECKING([for testsuite resource limits support])
 362   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 363     ac_res_limits=yes
 364     AC_DEFINE(_GLIBCXX_RES_LIMITS, 1,
 365               [Define if using setrlimit to set resource limits during
 366               "make check"])
 367   else
 368     ac_res_limits=no
 369   fi
 370   AC_MSG_RESULT($ac_res_limits)
 371 ])
 372
 373
 374 dnl
 375 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 376 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 377 dnl
 378 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
 379   AC_MSG_CHECKING([for S_ISREG or S_IFREG])
 380   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 381     AC_TRY_LINK(
 382       [#include <sys/stat.h>],
 383       [struct stat buffer;
 384        fstat(0, &buffer);
 385        S_ISREG(buffer.st_mode);],
 386       [glibcxx_cv_S_ISREG=yes],
 387       [glibcxx_cv_S_ISREG=no])
 388   ])
 389   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 390     AC_TRY_LINK(
 391       [#include <sys/stat.h>],
 392       [struct stat buffer;
 393        fstat(0, &buffer);
 394        S_IFREG & buffer.st_mode;],
 395       [glibcxx_cv_S_IFREG=yes],
 396       [glibcxx_cv_S_IFREG=no])
 397   ])
 398   res=no
 399   if test $glibcxx_cv_S_ISREG = yes; then
 400     AC_DEFINE(HAVE_S_ISREG, 1,
 401               [Define if S_IFREG is available in <sys/stat.h>.])
 402     res=S_ISREG
 403   elif test $glibcxx_cv_S_IFREG = yes; then
 404     AC_DEFINE(HAVE_S_IFREG, 1,
 405               [Define if S_IFREG is available in <sys/stat.h>.])
 406     res=S_IFREG
 407   fi
 408   AC_MSG_RESULT($res)
 409 ])
 410
 411
 412 dnl
 413 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 414 dnl
 415 AC_DEFUN([GLIBCXX_CHECK_POLL], [
 416   AC_MSG_CHECKING([for poll])
 417   AC_CACHE_VAL(glibcxx_cv_POLL, [
 418     AC_TRY_LINK(
 419       [#include <poll.h>],
 420       [struct pollfd pfd[1];
 421        pfd[0].events = POLLIN;
 422        poll(pfd, 1, 0);],
 423       [glibcxx_cv_POLL=yes],
 424       [glibcxx_cv_POLL=no])
 425   ])
 426   if test $glibcxx_cv_POLL = yes; then
 427     AC_DEFINE(HAVE_POLL, 1, [Define if poll is available in <poll.h>.])
 428   fi
 429   AC_MSG_RESULT($glibcxx_cv_POLL)
 430 ])
 431
 432
 433 dnl
 434 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 435 dnl
 436 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
 437   AC_MSG_CHECKING([for writev])
 438   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 439     AC_TRY_LINK(
 440       [#include <sys/uio.h>],
 441       [struct iovec iov[2];
 442        writev(0, iov, 0);],
 443       [glibcxx_cv_WRITEV=yes],
 444       [glibcxx_cv_WRITEV=no])
 445   ])
 446   if test $glibcxx_cv_WRITEV = yes; then
 447     AC_DEFINE(HAVE_WRITEV, 1, [Define if writev is available in <sys/uio.h>.])
 448   fi
 449   AC_MSG_RESULT($glibcxx_cv_WRITEV)
 450 ])
 451
 452
 453 dnl
 454 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 455 dnl
 456 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
 457   AC_MSG_CHECKING([for int64_t])
 458   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 459     AC_TRY_COMPILE(
 460       [#include <stdint.h>],
 461       [int64_t var;],
 462       [glibcxx_cv_INT64_T=yes],
 463       [glibcxx_cv_INT64_T=no])
 464   ])
 465   if test $glibcxx_cv_INT64_T = yes; then
 466     AC_DEFINE(HAVE_INT64_T, 1, [Define if int64_t is available in <stdint.h>.])
 467   fi
 468   AC_MSG_RESULT($glibcxx_cv_INT64_T)
 469 ])
 470
 471
 472 dnl
 473 dnl Check whether LFS support is available.
 474 dnl
 475 AC_DEFUN([GLIBCXX_CHECK_LFS], [
 476   AC_LANG_SAVE
 477   AC_LANG_CPLUSPLUS
 478   ac_save_CXXFLAGS="$CXXFLAGS"
 479   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 480   AC_MSG_CHECKING([for LFS support])
 481   AC_CACHE_VAL(glibcxx_cv_LFS, [
 482     AC_TRY_LINK(
 483       [#include <unistd.h>
 484        #include <stdio.h>
 485        #include <sys/stat.h>
 486       ],
 487       [FILE* fp;
 488        fopen64("t", "w");
 489        fseeko64(fp, 0, SEEK_CUR);
 490        ftello64(fp);
 491        lseek64(1, 0, SEEK_CUR);
 492        struct stat64 buf;
 493        fstat64(1, &buf);],
 494       [glibcxx_cv_LFS=yes],
 495       [glibcxx_cv_LFS=no])
 496   ])
 497   if test $glibcxx_cv_LFS = yes; then
 498     AC_DEFINE(_GLIBCXX_USE_LFS, 1, [Define if LFS support is available.])
 499   fi
 500   AC_MSG_RESULT($glibcxx_cv_LFS)
 501   CXXFLAGS="$ac_save_CXXFLAGS"
 502   AC_LANG_RESTORE
 503 ])
 504
 505
 506 dnl
 507 dnl Check for whether a fully dynamic basic_string implementation should
 508 dnl be turned on, that does not put empty objects in per-process static
 509 dnl memory (mostly useful together with shared memory allocators, see PR
 510 dnl libstdc++/16612 for details).
 511 dnl
 512 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING
 513 dnl --disable-fully-dynamic-string leaves _GLIBCXX_FULLY_DYNAMIC_STRING undefined
 514 dnl  +  Usage:  GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
 515 dnl       Where DEFAULT is either `yes' or `no'.
 516 dnl
 517 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
 518   GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
 519   if test $enable_fully_dynamic_string = yes; then
 520     AC_DEFINE(_GLIBCXX_FULLY_DYNAMIC_STRING, 1,
 521               [Define if a fully dynamic basic_string is wanted.])
 522   fi
 523 ])
 524
 525
 526 dnl
 527 dnl Does any necessary configuration of the testsuite directory.  Generates
 528 dnl the testsuite_hooks.h header.
 529 dnl
 530 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 531 dnl
 532 dnl Sets:
 533 dnl  enable_abi_check
 534 dnl  GLIBCXX_TEST_WCHAR_T
 535 dnl  GLIBCXX_TEST_THREAD
 536 dnl Substs:
 537 dnl  baseline_dir
 538 dnl
 539 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
 540   if $GLIBCXX_IS_NATIVE ; then
 541     # Do checks for resource limit functions.
 542     GLIBCXX_CHECK_SETRLIMIT
 543
 544     # Look for setenv, so that extended locale tests can be performed.
 545     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 546   fi
 547
 548   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes &&
 549      test $enable_symvers != no; then
 550     case "$host" in
 551       *-*-cygwin*)
 552         enable_abi_check=no ;;
 553       *)
 554         enable_abi_check=yes ;;
 555     esac
 556   else
 557     # Only build this as native, since automake does not understand
 558     # CXX_FOR_BUILD.
 559     enable_abi_check=no
 560   fi
 561
 562   # Export file names for ABI checking.
 563   baseline_dir="$glibcxx_srcdir/config/abi/post/${abi_baseline_pair}\$(MULTISUBDIR)"
 564   AC_SUBST(baseline_dir)
 565 ])
 566
 567
 568 dnl
 569 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 570 dnl
 571 dnl Substs:
 572 dnl  GLIBCXX_INCLUDES
 573 dnl  TOPLEVEL_INCLUDES
 574 dnl
 575 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
 576   # Used for every C++ compile we perform.
 577   GLIBCXX_INCLUDES="\
 578 -I$glibcxx_builddir/include/$host_alias \
 579 -I$glibcxx_builddir/include \
 580 -I$glibcxx_srcdir/libsupc++"
 581
 582   # For Canadian crosses, pick this up too.
 583   if test $CANADIAN = yes; then
 584     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 585   fi
 586
 587   # Stuff in the actual top level.  Currently only used by libsupc++ to
 588   # get unwind* headers from the gcc dir.
 589   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 590   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 591
 592   # Now, export this to all the little Makefiles....
 593   AC_SUBST(GLIBCXX_INCLUDES)
 594   AC_SUBST(TOPLEVEL_INCLUDES)
 595 ])
 596
 597
 598 dnl
 599 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 600 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 601 dnl
 602 dnl Substs:
 603 dnl  OPTIMIZE_CXXFLAGS
 604 dnl  WARN_FLAGS
 605 dnl
 606 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
 607   # Optimization flags that are probably a good idea for thrill-seekers. Just
 608   # uncomment the lines below and make, everything else is ready to go...
 609   # Alternatively OPTIMIZE_CXXFLAGS can be set in configure.host.
 610   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 611   AC_SUBST(OPTIMIZE_CXXFLAGS)
 612
 613   WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
 614   AC_SUBST(WARN_FLAGS)
 615 ])
 616
 617
 618 dnl
 619 dnl All installation directory information is determined here.
 620 dnl
 621 dnl Substs:
 622 dnl  gxx_install_dir
 623 dnl  glibcxx_prefixdir
 624 dnl  glibcxx_toolexecdir
 625 dnl  glibcxx_toolexeclibdir
 626 dnl
 627 dnl Assumes cross_compiling bits already done, and with_cross_host in
 628 dnl particular.
 629 dnl
 630 dnl This logic must match gcc/configure.ac's setting of gcc_gxx_include_dir.
 631 dnl config/gxx-include-dir.m4 must be kept consistant with this as well.
 632 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
 633   glibcxx_toolexecdir=no
 634   glibcxx_toolexeclibdir=no
 635   glibcxx_prefixdir=$prefix
 636
 637   AC_MSG_CHECKING([for gxx-include-dir])
 638   AC_ARG_WITH([gxx-include-dir],
 639     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 640                    [installation directory for include files]),
 641     [case "$withval" in
 642       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 643       no)  gxx_include_dir=no ;;
 644       *)   gxx_include_dir=$withval ;;
 645      esac],
 646     [gxx_include_dir=no])
 647   AC_MSG_RESULT($gxx_include_dir)
 648
 649   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 650   AC_ARG_ENABLE([version-specific-runtime-libs],
 651     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 652                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 653     [case "$enableval" in
 654       yes) version_specific_libs=yes ;;
 655       no)  version_specific_libs=no ;;
 656       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 657      esac],
 658     [version_specific_libs=no])
 659   AC_MSG_RESULT($version_specific_libs)
 660
 661   # Default case for install directory for include files.
 662   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 663     gxx_include_dir='include/c++/${gcc_version}'
 664     if test -n "$with_cross_host" &&
 665        test x"$with_cross_host" != x"no"; then
 666       gxx_include_dir='${prefix}/${target_alias}/'"$gxx_include_dir"
 667     else
 668       gxx_include_dir='${prefix}/'"$gxx_include_dir"
 669     fi
 670   fi
 671
 672   # Version-specific runtime libs processing.
 673   if test $version_specific_libs = yes; then
 674     # Need the gcc compiler version to know where to install libraries
 675     # and header files if --enable-version-specific-runtime-libs option
 676     # is selected.  FIXME: these variables are misnamed, there are
 677     # no executables installed in _toolexecdir or _toolexeclibdir.
 678     if test x"$gxx_include_dir" = x"no"; then
 679       gxx_include_dir='${libdir}/gcc/${host_alias}/${gcc_version}/include/c++'
 680     fi
 681     glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 682     glibcxx_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
 683   fi
 684
 685   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 686   # Install a library built with a cross compiler in tooldir, not libdir.
 687   if test x"$glibcxx_toolexecdir" = x"no"; then
 688     if test -n "$with_cross_host" &&
 689        test x"$with_cross_host" != x"no"; then
 690       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 691       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 692     else
 693       glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 694       glibcxx_toolexeclibdir='${libdir}'
 695     fi
 696     multi_os_directory=`$CXX -print-multi-os-directory`
 697     case $multi_os_directory in
 698       .) ;; # Avoid trailing /.
 699       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 700     esac
 701   fi
 702
 703   AC_MSG_CHECKING([for install location])
 704   AC_MSG_RESULT($gxx_include_dir)
 705
 706   AC_SUBST(glibcxx_prefixdir)
 707   AC_SUBST(gxx_include_dir)
 708   AC_SUBST(glibcxx_toolexecdir)
 709   AC_SUBST(glibcxx_toolexeclibdir)
 710 ])
 711
 712
 713 dnl
 714 dnl GLIBCXX_ENABLE
 715 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 716 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 717 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 718 dnl
 719 dnl See docs/html/17_intro/configury.html#enable for documentation.
 720 dnl
 721 m4_define([GLIBCXX_ENABLE],[dnl
 722 m4_define([_g_switch],[--enable-$1])dnl
 723 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 724  AC_ARG_ENABLE($1,_g_help,
 725   m4_bmatch([$5],
 726    [^permit ],
 727      [[
 728       case "$enableval" in
 729        m4_bpatsubst([$5],[permit ])) ;;
 730        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 731           dnl Idea for future:  generate a URL pointing to
 732           dnl "onlinedocs/configopts.html#whatever"
 733       esac
 734      ]],
 735    [^$],
 736      [[
 737       case "$enableval" in
 738        yes|no) ;;
 739        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 740       esac
 741      ]],
 742    [[$5]]),
 743   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 744 m4_undefine([_g_switch])dnl
 745 m4_undefine([_g_help])dnl
 746 ])
 747
 748
 749 dnl
 750 dnl Check for ISO/IEC 9899:1999 "C99" support.
 751 dnl
 752 dnl --enable-c99 defines _GLIBCXX_USE_C99
 753 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 754 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 755 dnl       Where DEFAULT is either `yes' or `no'.
 756 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 757 dnl
 758 AC_DEFUN([GLIBCXX_ENABLE_C99], [
 759   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 760
 761   if test x"$enable_c99" = x"yes"; then
 762
 763   AC_LANG_SAVE
 764   AC_LANG_CPLUSPLUS
 765
 766   # Use -std=c++98 because the default (-std=gnu++98) leaves __STRICT_ANSI__
 767   # undefined and fake C99 facilities - like pre-standard snprintf - may be
 768   # spuriously enabled.
 769   # Long term, -std=c++0x could be even better, could manage to explicitely
 770   # request C99 facilities to the underlying C headers.
 771   ac_save_CXXFLAGS="$CXXFLAGS"
 772   CXXFLAGS="$CXXFLAGS -std=c++98"
 773   ac_save_LIBS="$LIBS"
 774   ac_save_gcc_no_link="$gcc_no_link"
 775
 776   if test x$gcc_no_link != xyes; then
 777     # Use -fno-exceptions to that the C driver can link these tests without
 778     # hitting undefined references to personality routines.
 779     CXXFLAGS="$CXXFLAGS -fno-exceptions"
 780     AC_CHECK_LIB(m, sin, [
 781       LIBS="$LIBS -lm"
 782     ], [
 783       # Use the default compile-only tests in GCC_TRY_COMPILE_OR_LINK
 784       gcc_no_link=yes
 785     ])
 786   fi
 787
 788   # Check for the existence of <math.h> functions used if C99 is enabled.
 789   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 790   AC_CACHE_VAL(ac_c99_math, [
 791   GCC_TRY_COMPILE_OR_LINK(
 792      [#include <math.h>
 793       volatile double d1, d2;
 794       volatile int i;],
 795      [i = fpclassify(d1);
 796       i = isfinite(d1);
 797       i = isinf(d1);
 798       i = isnan(d1);
 799       i = isnormal(d1);
 800       i = signbit(d1);
 801       i = isgreater(d1, d2);
 802       i = isgreaterequal(d1, d2);
 803       i = isless(d1, d2);
 804       i = islessequal(d1, d2);
 805       i = islessgreater(d1, d2);
 806       i = islessgreater(d1, d2);
 807       i = isunordered(d1, d2);
 808      ],[ac_c99_math=yes], [ac_c99_math=no])
 809   ])
 810   AC_MSG_RESULT($ac_c99_math)
 811   if test x"$ac_c99_math" = x"yes"; then
 812     AC_DEFINE(_GLIBCXX_USE_C99_MATH, 1,
 813               [Define if C99 functions or macros in <math.h> should be imported
 814               in <cmath> in namespace std.])
 815   fi
 816
 817   # Check for the existence of <complex.h> complex math functions.
 818   # This is necessary even though libstdc++ uses the builtin versions
 819   # of these functions, because if the builtin cannot be used, a reference
 820   # to the library function is emitted.
 821   AC_CHECK_HEADERS(tgmath.h, ac_has_tgmath_h=yes, ac_has_tgmath_h=no)
 822   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
 823   ac_c99_complex=no;
 824   if test x"$ac_has_complex_h" = x"yes"; then
 825     AC_MSG_CHECKING([for ISO C99 support in <complex.h>])
 826     GCC_TRY_COMPILE_OR_LINK(
 827        [#include <complex.h>
 828         typedef __complex__ float float_type;
 829         typedef __complex__ double double_type;
 830         typedef __complex__ long double ld_type;
 831         volatile float_type tmpf;
 832         volatile double_type tmpd;
 833         volatile ld_type tmpld;
 834         volatile float f;
 835         volatile double d;
 836         volatile long double ld;],
 837        [f = cabsf(tmpf);
 838         f = cargf(tmpf);
 839         tmpf = ccosf(tmpf);
 840         tmpf = ccoshf(tmpf);
 841         tmpf = cexpf(tmpf);
 842         tmpf = clogf(tmpf);
 843         tmpf = csinf(tmpf);
 844         tmpf = csinhf(tmpf);
 845         tmpf = csqrtf(tmpf);
 846         tmpf = ctanf(tmpf);
 847         tmpf = ctanhf(tmpf);
 848         tmpf = cpowf(tmpf, tmpf);
 849         d = cabs(tmpd);
 850         d = carg(tmpd);
 851         tmpd = ccos(tmpd);
 852         tmpd = ccosh(tmpd);
 853         tmpd = cexp(tmpd);
 854         tmpd = clog(tmpd);
 855         tmpd = csin(tmpd);
 856         tmpd = csinh(tmpd);
 857         tmpd = csqrt(tmpd);
 858         tmpd = ctan(tmpd);
 859         tmpd = ctanh(tmpd);
 860         tmpd = cpow(tmpd, tmpd);
 861         ld = cabsl(tmpld);
 862         ld = cargl(tmpld);
 863         tmpld = ccosl(tmpld);
 864         tmpld = ccoshl(tmpld);
 865         tmpld = cexpl(tmpld);
 866         tmpld = clogl(tmpld);
 867         tmpld = csinl(tmpld);
 868         tmpld = csinhl(tmpld);
 869         tmpld = csqrtl(tmpld);
 870         tmpld = ctanl(tmpld);
 871         tmpld = ctanhl(tmpld);
 872         tmpld = cpowl(tmpld, tmpld);
 873        ],[ac_c99_complex=yes], [ac_c99_complex=no])
 874   fi
 875   AC_MSG_RESULT($ac_c99_complex)
 876   if test x"$ac_c99_complex" = x"yes"; then
 877     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX, 1,
 878               [Define if C99 functions in <complex.h> should be used in
 879               <complex>. Using compiler builtins for these functions requires
 880               corresponding C99 library functions to be present.])
 881   fi
 882
 883   # Check for the existence in <stdio.h> of vscanf, et. al.
 884   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 885   AC_CACHE_VAL(ac_c99_stdio, [
 886   GCC_TRY_COMPILE_OR_LINK(
 887      [#include <stdio.h>
 888       #include <stdarg.h>
 889       void foo(char* fmt, ...)
 890       {
 891         va_list args; va_start(args, fmt);
 892         vfscanf(stderr, "%i", args);
 893         vscanf("%i", args);
 894         vsnprintf(fmt, 0, "%i", args);
 895         vsscanf(fmt, "%i", args);
 896       }],
 897      [snprintf("12", 0, "%i");],
 898      [ac_c99_stdio=yes], [ac_c99_stdio=no])
 899   ])
 900   AC_MSG_RESULT($ac_c99_stdio)
 901
 902   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 903   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 904   AC_CACHE_VAL(ac_c99_stdlib, [
 905   GCC_TRY_COMPILE_OR_LINK(
 906      [#include <stdlib.h>
 907       volatile float f;
 908       volatile long double ld;
 909       volatile unsigned long long ll;
 910       lldiv_t mydivt;],
 911      [char* tmp;
 912       f = strtof("gnu", &tmp);
 913       ld = strtold("gnu", &tmp);
 914       ll = strtoll("gnu", &tmp, 10);
 915       ll = strtoull("gnu", &tmp, 10);
 916       ll = llabs(10);
 917       mydivt = lldiv(10,1);
 918       ll = mydivt.quot;
 919       ll = mydivt.rem;
 920       ll = atoll("10");
 921       _Exit(0);
 922       ],[ac_c99_stdlib=yes], [ac_c99_stdlib=no])
 923   ])
 924   AC_MSG_RESULT($ac_c99_stdlib)
 925
 926   # Check for the existence in <wchar.h> of wcstold, etc.
 927   ac_c99_wchar=no;
 928   if test x"$ac_has_wchar_h" = xyes &&
 929      test x"$ac_has_wctype_h" = xyes; then
 930     AC_MSG_CHECKING([for ISO C99 support in <wchar.h>])
 931     AC_TRY_COMPILE([#include <wchar.h>
 932                     namespace test
 933                     {
 934                       using ::wcstold;
 935                       using ::wcstoll;
 936                       using ::wcstoull;
 937                     }
 938                    ],[],[ac_c99_wchar=yes], [ac_c99_wchar=no])
 939
 940     # Checks for wide character functions that may not be present.
 941     # Injection of these is wrapped with guard macros.
 942     # NB: only put functions here, instead of immediately above, if
 943     # absolutely necessary.
 944     AC_TRY_COMPILE([#include <wchar.h>
 945                     namespace test { using ::vfwscanf; } ], [],
 946                    [AC_DEFINE(HAVE_VFWSCANF,1,
 947                         [Defined if vfwscanf exists.])],[])
 948
 949     AC_TRY_COMPILE([#include <wchar.h>
 950                     namespace test { using ::vswscanf; } ], [],
 951                    [AC_DEFINE(HAVE_VSWSCANF,1,
 952                         [Defined if vswscanf exists.])],[])
 953
 954     AC_TRY_COMPILE([#include <wchar.h>
 955                     namespace test { using ::vwscanf; } ], [],
 956                    [AC_DEFINE(HAVE_VWSCANF,1,[Defined if vwscanf exists.])],[])
 957
 958     AC_TRY_COMPILE([#include <wchar.h>
 959                     namespace test { using ::wcstof; } ], [],
 960                    [AC_DEFINE(HAVE_WCSTOF,1,[Defined if wcstof exists.])],[])
 961
 962     AC_TRY_COMPILE([#include <wctype.h>],
 963                    [ wint_t t; int i = iswblank(t);],
 964                    [AC_DEFINE(HAVE_ISWBLANK,1,
 965                         [Defined if iswblank exists.])],[])
 966
 967     AC_MSG_RESULT($ac_c99_wchar)
 968   fi
 969
 970   # Option parsed, now set things appropriately.
 971   if test x"$ac_c99_math" = x"no" ||
 972      test x"$ac_c99_complex" = x"no" ||
 973      test x"$ac_c99_stdio" = x"no" ||
 974      test x"$ac_c99_stdlib" = x"no" ||
 975      test x"$ac_c99_wchar" = x"no"; then
 976     enable_c99=no;
 977   else
 978     AC_DEFINE(_GLIBCXX_USE_C99, 1,
 979     [Define if C99 functions or macros from <wchar.h>, <math.h>,
 980     <complex.h>, <stdio.h>, and <stdlib.h> can be used or exposed.])
 981   fi
 982
 983   gcc_no_link="$ac_save_gcc_no_link"
 984   LIBS="$ac_save_LIBS"
 985   CXXFLAGS="$ac_save_CXXFLAGS"
 986   AC_LANG_RESTORE
 987   fi
 988
 989   AC_MSG_CHECKING([for fully enabled ISO C99 support])
 990   AC_MSG_RESULT($enable_c99)
 991 ])
 992
 993
 994 dnl
 995 dnl Check for ISO/IEC 9899:1999 "C99" support to ISO/IEC DTR 19768 "TR1"
 996 dnl facilities in Chapter 8, "C compatibility".
 997 dnl
 998 AC_DEFUN([GLIBCXX_CHECK_C99_TR1], [
 999
1000   AC_LANG_SAVE
1001   AC_LANG_CPLUSPLUS
1002
1003   # Use -std=c++98 because the default (-std=gnu++98) leaves __STRICT_ANSI__
1004   # undefined and fake C99 facilities may be spuriously enabled.
1005   ac_save_CXXFLAGS="$CXXFLAGS"
1006   CXXFLAGS="$CXXFLAGS -std=c++98"
1007
1008   # Check for the existence of <complex.h> complex math functions used
1009   # by tr1/complex.
1010   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
1011   ac_c99_complex_tr1=no;
1012   if test x"$ac_has_complex_h" = x"yes"; then
1013     AC_MSG_CHECKING([for ISO C99 support to TR1 in <complex.h>])
1014     AC_TRY_COMPILE([#include <complex.h>],
1015                    [typedef __complex__ float float_type; float_type tmpf;
1016                     cacosf(tmpf);
1017                     casinf(tmpf);
1018                     catanf(tmpf);
1019                     cacoshf(tmpf);
1020                     casinhf(tmpf);
1021                     catanhf(tmpf);
1022                     typedef __complex__ double double_type; double_type tmpd;
1023                     cacos(tmpd);
1024                     casin(tmpd);
1025                     catan(tmpd);
1026                     cacosh(tmpd);
1027                     casinh(tmpd);
1028                     catanh(tmpd);
1029                     typedef __complex__ long double ld_type; ld_type tmpld;
1030                     cacosl(tmpld);
1031                     casinl(tmpld);
1032                     catanl(tmpld);
1033                     cacoshl(tmpld);
1034                     casinhl(tmpld);
1035                     catanhl(tmpld);
1036                    ],[ac_c99_complex_tr1=yes], [ac_c99_complex_tr1=no])
1037   fi
1038   AC_MSG_RESULT($ac_c99_complex_tr1)
1039   if test x"$ac_c99_complex_tr1" = x"yes"; then
1040     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX_TR1, 1,
1041               [Define if C99 functions in <complex.h> should be used in
1042               <tr1/complex>. Using compiler builtins for these functions
1043               requires corresponding C99 library functions to be present.])
1044   fi
1045
1046   # Check for the existence of <ctype.h> functions.
1047   AC_MSG_CHECKING([for ISO C99 support to TR1 in <ctype.h>])
1048   AC_CACHE_VAL(ac_c99_ctype_tr1, [
1049   AC_TRY_COMPILE([#include <ctype.h>],
1050                  [int ch;
1051                   int ret;
1052                   ret = isblank(ch);
1053                  ],[ac_c99_ctype_tr1=yes], [ac_c99_ctype_tr1=no])
1054   ])
1055   AC_MSG_RESULT($ac_c99_ctype_tr1)
1056   if test x"$ac_c99_ctype_tr1" = x"yes"; then
1057     AC_DEFINE(_GLIBCXX_USE_C99_CTYPE_TR1, 1,
1058               [Define if C99 functions in <ctype.h> should be imported in
1059               <tr1/cctype> in namespace std::tr1.])
1060   fi
1061
1062   # Check for the existence of <fenv.h> functions.
1063   AC_CHECK_HEADERS(fenv.h, ac_has_fenv_h=yes, ac_has_fenv_h=no)
1064   ac_c99_fenv_tr1=no;
1065   if test x"$ac_has_fenv_h" = x"yes"; then
1066     AC_MSG_CHECKING([for ISO C99 support to TR1 in <fenv.h>])
1067     AC_TRY_COMPILE([#include <fenv.h>],
1068                    [int except, mode;
1069                     fexcept_t* pflag;
1070                     fenv_t* penv;
1071                     int ret;
1072                     ret = feclearexcept(except);
1073                     ret = fegetexceptflag(pflag, except);
1074                     ret = feraiseexcept(except);
1075                     ret = fesetexceptflag(pflag, except);
1076                     ret = fetestexcept(except);
1077                     ret = fegetround();
1078                     ret = fesetround(mode);
1079                     ret = fegetenv(penv);
1080                     ret = feholdexcept(penv);
1081                     ret = fesetenv(penv);
1082                     ret = feupdateenv(penv);
1083                    ],[ac_c99_fenv_tr1=yes], [ac_c99_fenv_tr1=no])
1084   fi
1085   AC_MSG_RESULT($ac_c99_fenv_tr1)
1086   if test x"$ac_c99_fenv_tr1" = x"yes"; then
1087     AC_DEFINE(_GLIBCXX_USE_C99_FENV_TR1, 1,
1088               [Define if C99 functions in <fenv.h> should be imported in
1089               <tr1/cfenv> in namespace std::tr1.])
1090   fi
1091
1092   # Check for the existence of <stdint.h> types.
1093   AC_MSG_CHECKING([for ISO C99 support to TR1 in <stdint.h>])
1094   AC_CACHE_VAL(ac_c99_stdint_tr1, [
1095   AC_TRY_COMPILE([#include <stdint.h>],
1096                  [typedef int8_t          my_int8_t;
1097                   typedef int16_t         my_int16_t;
1098                   typedef int32_t         my_int32_t;
1099                   typedef int64_t         my_int64_t;
1100                   typedef int_fast8_t     my_int_fast8_t;
1101                   typedef int_fast16_t    my_int_fast16_t;
1102                   typedef int_fast32_t    my_int_fast32_t;
1103                   typedef int_fast64_t    my_int_fast64_t;
1104                   typedef int_least8_t    my_int_least8_t;
1105                   typedef int_least16_t   my_int_least16_t;
1106                   typedef int_least32_t   my_int_least32_t;
1107                   typedef int_least64_t   my_int_least64_t;
1108                   typedef intmax_t        my_intmax_t;
1109                   typedef intptr_t        my_intptr_t;
1110                   typedef uint8_t         my_uint8_t;
1111                   typedef uint16_t        my_uint16_t;
1112                   typedef uint32_t        my_uint32_t;
1113                   typedef uint64_t        my_uint64_t;
1114                   typedef uint_fast8_t    my_uint_fast8_t;
1115                   typedef uint_fast16_t   my_uint_fast16_t;
1116                   typedef uint_fast32_t   my_uint_fast32_t;
1117                   typedef uint_fast64_t   my_uint_fast64_t;
1118                   typedef uint_least8_t   my_uint_least8_t;
1119                   typedef uint_least16_t  my_uint_least16_t;
1120                   typedef uint_least32_t  my_uint_least32_t;
1121                   typedef uint_least64_t  my_uint_least64_t;
1122                   typedef uintmax_t       my_uintmax_t;
1123                   typedef uintptr_t       my_uintptr_t;
1124                  ],[ac_c99_stdint_tr1=yes], [ac_c99_stdint_tr1=no])
1125   ])
1126   AC_MSG_RESULT($ac_c99_stdint_tr1)
1127   if test x"$ac_c99_stdint_tr1" = x"yes"; then
1128     AC_DEFINE(_GLIBCXX_USE_C99_STDINT_TR1, 1,
1129               [Define if C99 types in <stdint.h> should be imported in
1130               <tr1/cstdint> in namespace std::tr1.])
1131   fi
1132
1133   # Check for the existence of <math.h> functions.
1134   AC_MSG_CHECKING([for ISO C99 support to TR1 in <math.h>])
1135   AC_CACHE_VAL(ac_c99_math_tr1, [
1136   AC_TRY_COMPILE([#include <math.h>],
1137                  [typedef double_t  my_double_t;
1138                   typedef float_t   my_float_t;
1139                   acosh(0.0);
1140                   acoshf(0.0f);
1141                   acoshl(0.0l);
1142                   asinh(0.0);
1143                   asinhf(0.0f);
1144                   asinhl(0.0l);
1145                   atanh(0.0);
1146                   atanhf(0.0f);
1147                   atanhl(0.0l);
1148                   cbrt(0.0);
1149                   cbrtf(0.0f);
1150                   cbrtl(0.0l);
1151                   copysign(0.0, 0.0);
1152                   copysignf(0.0f, 0.0f);
1153                   copysignl(0.0l, 0.0l);
1154                   erf(0.0);
1155                   erff(0.0f);
1156                   erfl(0.0l);
1157                   erfc(0.0);
1158                   erfcf(0.0f);
1159                   erfcl(0.0l);
1160                   exp2(0.0);
1161                   exp2f(0.0f);
1162                   exp2l(0.0l);
1163                   expm1(0.0);
1164                   expm1f(0.0f);
1165                   expm1l(0.0l);
1166                   fdim(0.0, 0.0);
1167                   fdimf(0.0f, 0.0f);
1168                   fdiml(0.0l, 0.0l);
1169                   fma(0.0, 0.0, 0.0);
1170                   fmaf(0.0f, 0.0f, 0.0f);
1171                   fmal(0.0l, 0.0l, 0.0l);
1172                   fmax(0.0, 0.0);
1173                   fmaxf(0.0f, 0.0f);
1174                   fmaxl(0.0l, 0.0l);
1175                   fmin(0.0, 0.0);
1176                   fminf(0.0f, 0.0f);
1177                   fminl(0.0l, 0.0l);
1178                   hypot(0.0, 0.0);
1179                   hypotf(0.0f, 0.0f);
1180                   hypotl(0.0l, 0.0l);
1181                   ilogb(0.0);
1182                   ilogbf(0.0f);
1183                   ilogbl(0.0l);
1184                   lgamma(0.0);
1185                   lgammaf(0.0f);
1186                   lgammal(0.0l);
1187                   llrint(0.0);
1188                   llrintf(0.0f);
1189                   llrintl(0.0l);
1190                   llround(0.0);
1191                   llroundf(0.0f);
1192                   llroundl(0.0l);
1193                   log1p(0.0);
1194                   log1pf(0.0f);
1195                   log1pl(0.0l);
1196                   log2(0.0);
1197                   log2f(0.0f);
1198                   log2l(0.0l);
1199                   logb(0.0);
1200                   logbf(0.0f);
1201                   logbl(0.0l);
1202                   lrint(0.0);
1203                   lrintf(0.0f);
1204                   lrintl(0.0l);
1205                   lround(0.0);
1206                   lroundf(0.0f);
1207                   lroundl(0.0l);
1208                   nan(0);
1209                   nanf(0);
1210                   nanl(0);
1211                   nearbyint(0.0);
1212                   nearbyintf(0.0f);
1213                   nearbyintl(0.0l);
1214                   nextafter(0.0, 0.0);
1215                   nextafterf(0.0f, 0.0f);
1216                   nextafterl(0.0l, 0.0l);
1217                   nexttoward(0.0, 0.0);
1218                   nexttowardf(0.0f, 0.0f);
1219                   nexttowardl(0.0l, 0.0l);
1220                   remainder(0.0, 0.0);
1221                   remainderf(0.0f, 0.0f);
1222                   remainderl(0.0l, 0.0l);
1223                   remquo(0.0, 0.0, 0);
1224                   remquo(0.0f, 0.0f, 0);
1225                   remquo(0.0l, 0.0l, 0);
1226                   rint(0.0);
1227                   rintf(0.0f);
1228                   rintl(0.0l);
1229                   round(0.0);
1230                   roundf(0.0f);
1231                   roundl(0.0l);
1232                   scalbln(0.0, 0l);
1233                   scalblnf(0.0f, 0l);
1234                   scalblnl(0.0l, 0l);
1235                   scalbn(0.0, 0);
1236                   scalbnf(0.0f, 0);
1237                   scalbnl(0.0l, 0);
1238                   tgamma(0.0);
1239                   tgammaf(0.0f);
1240                   tgammal(0.0l);
1241                   trunc(0.0);
1242                   truncf(0.0f);
1243                   truncl(0.0l);
1244                  ],[ac_c99_math_tr1=yes], [ac_c99_math_tr1=no])
1245   ])
1246   AC_MSG_RESULT($ac_c99_math_tr1)
1247   if test x"$ac_c99_math_tr1" = x"yes"; then
1248     AC_DEFINE(_GLIBCXX_USE_C99_MATH_TR1, 1,
1249               [Define if C99 functions or macros in <math.h> should be imported
1250               in <tr1/cmath> in namespace std::tr1.])
1251   fi
1252
1253   # Check for the existence of <inttypes.h> functions (NB: doesn't make
1254   # sense if the previous check fails, per C99, 7.8/1).
1255   ac_c99_inttypes_tr1=no;
1256   if test x"$ac_c99_stdint_tr1" = x"yes"; then
1257     AC_MSG_CHECKING([for ISO C99 support to TR1 in <inttypes.h>])
1258     AC_TRY_COMPILE([#include <inttypes.h>],
1259                    [intmax_t i, numer, denom, base;
1260                     const char* s;
1261                     char** endptr;
1262                     intmax_t ret = imaxabs(i);
1263                     imaxdiv_t dret = imaxdiv(numer, denom);
1264                     ret = strtoimax(s, endptr, base);
1265                     uintmax_t uret = strtoumax(s, endptr, base);
1266                    ],[ac_c99_inttypes_tr1=yes], [ac_c99_inttypes_tr1=no])
1267   fi
1268   AC_MSG_RESULT($ac_c99_inttypes_tr1)
1269   if test x"$ac_c99_inttypes_tr1" = x"yes"; then
1270     AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_TR1, 1,
1271               [Define if C99 functions in <inttypes.h> should be imported in
1272               <tr1/cinttypes> in namespace std::tr1.])
1273   fi
1274
1275   # Check for the existence of the <stdbool.h> header.
1276   AC_CHECK_HEADERS(stdbool.h)
1277
1278   CXXFLAGS="$ac_save_CXXFLAGS"
1279   AC_LANG_RESTORE
1280 ])
1281
1282 dnl
1283 dnl Check whether "dev/random" and "dev/urandom" are available for the
1284 dnl random_device of "TR1" (Chapter 5.1, "Random number generation").
1285 dnl
1286 AC_DEFUN([GLIBCXX_CHECK_RANDOM_TR1], [
1287
1288   AC_MSG_CHECKING([for "dev/random" and "dev/urandom" for TR1 random_device])
1289   AC_CACHE_VAL(ac_random_tr1, [
1290   AC_TRY_RUN([#include <stdio.h>
1291               int main()
1292               {
1293                 return !(fopen("/dev/random", "r")
1294                          && fopen("/dev/urandom", "r"));
1295               }
1296              ],
1297              [ac_random_tr1=yes], [ac_random_tr1=no],
1298              [ac_random_tr1=no])
1299   ])
1300   AC_MSG_RESULT($ac_random_tr1)
1301   if test x"$ac_random_tr1" = x"yes"; then
1302     AC_DEFINE(_GLIBCXX_USE_RANDOM_TR1, 1,
1303               [Define if dev/random and dev/urandom are available for
1304                the random_device of TR1 (Chapter 5.1).])
1305   fi
1306
1307 ])
1308
1309 dnl
1310 dnl Check whether macros, etc are present for <system_error>
1311 dnl
1312 AC_DEFUN([GLIBCXX_CHECK_SYSTEM_ERROR], [
1313
1314   AC_MSG_CHECKING([for EOWNERDEAD])
1315   AC_CACHE_VAL(ac_system_error1, [
1316   AC_TRY_COMPILE([#include <errno.h>], [ int i = EOWNERDEAD; ],
1317              [ac_system_error1=yes], [ac_system_error1=no])
1318   ])
1319   AC_MSG_RESULT($ac_system_error1)
1320   if test x"$ac_system_error1" = x"yes"; then
1321     AC_DEFINE(HAVE_EOWNERDEAD, 1, [Define if EOWNERDEAD exists.])
1322   fi
1323
1324   AC_MSG_CHECKING([for ENOTRECOVERABLE])
1325   AC_CACHE_VAL(ac_system_error2, [
1326   AC_TRY_COMPILE([#include <errno.h>], [ int i = ENOTRECOVERABLE; ],
1327              [ac_system_error2=yes], [ac_system_error2=no])
1328   ])
1329   AC_MSG_RESULT($ac_system_error2)
1330   if test x"$ac_system_error2" = x"yes"; then
1331     AC_DEFINE(HAVE_ENOTRECOVERABLE, 1, [Define if ENOTRECOVERABLE exists.])
1332   fi
1333
1334   AC_MSG_CHECKING([for ENOLINK])
1335   AC_CACHE_VAL(ac_system_error3, [
1336   AC_TRY_COMPILE([#include <errno.h>], [ int i = ENOLINK; ],
1337              [ac_system_error3=yes], [ac_system_error3=no])
1338   ])
1339   AC_MSG_RESULT($ac_system_error3)
1340   if test x"$ac_system_error3" = x"yes"; then
1341     AC_DEFINE(HAVE_ENOLINK, 1, [Define if ENOLINK exists.])
1342   fi
1343
1344   AC_MSG_CHECKING([for EPROTO])
1345   AC_CACHE_VAL(ac_system_error_4, [
1346   AC_TRY_COMPILE([#include <errno.h>], [ int i = EPROTO; ],
1347              [ac_system_error_4=yes], [ac_system_error_4=no])
1348   ])
1349   AC_MSG_RESULT($ac_system_error_4)
1350   if test x"$ac_system_error_4" = x"yes"; then
1351     AC_DEFINE(HAVE_EPROTO, 1, [Define if EPROTO exists.])
1352   fi
1353
1354   AC_MSG_CHECKING([for ENODATA])
1355   AC_CACHE_VAL(ac_system_error_5, [
1356   AC_TRY_COMPILE([#include <errno.h>], [ int i = ENODATA; ],
1357              [ac_system_error_5=yes], [ac_system_error_5=no])
1358   ])
1359   AC_MSG_RESULT($ac_system_error_5)
1360   if test x"$ac_system_error_5" = x"yes"; then
1361     AC_DEFINE(HAVE_ENODATA, 1, [Define if ENODATA exists.])
1362   fi
1363
1364   AC_MSG_CHECKING([for ENOSR])
1365   AC_CACHE_VAL(ac_system_error_6, [
1366   AC_TRY_COMPILE([#include <errno.h>], [ int i = ENOSR; ],
1367              [ac_system_error_6=yes], [ac_system_error_6=no])
1368   ])
1369   AC_MSG_RESULT($ac_system_error_6)
1370   if test x"$ac_system_error_6" = x"yes"; then
1371     AC_DEFINE(HAVE_ENOSR, 1, [Define if ENOSR exists.])
1372   fi
1373
1374   AC_MSG_CHECKING([for ENOSTR])
1375   AC_CACHE_VAL(ac_system_error_7, [
1376   AC_TRY_COMPILE([#include <errno.h>], [ int i = ENOSTR; ],
1377              [ac_system_error_7=yes], [ac_system_error_7=no])
1378   ])
1379   AC_MSG_RESULT($ac_system_error_7)
1380   if test x"$ac_system_error_7" = x"yes"; then
1381     AC_DEFINE(HAVE_ENOSTR, 1, [Define if ENOSTR exists.])
1382   fi
1383
1384   AC_MSG_CHECKING([for ETIME])
1385   AC_CACHE_VAL(ac_system_error_8, [
1386   AC_TRY_COMPILE([#include <errno.h>], [ int i = ETIME; ],
1387              [ac_system_error_8=yes], [ac_system_error_8=no])
1388   ])
1389   AC_MSG_RESULT($ac_system_error_8)
1390   if test x"$ac_system_error_8" = x"yes"; then
1391     AC_DEFINE(HAVE_ETIME, 1, [Define if ETIME exists.])
1392   fi
1393
1394   AC_MSG_CHECKING([for sys_nerr])
1395   AC_CACHE_VAL(ac_system_error9, [
1396   AC_TRY_COMPILE([#include <errno.h> ], [ int i = sys_nerr; ],
1397              [ac_system_error9=yes], [ac_system_error9=no])
1398   ])
1399   AC_MSG_RESULT($ac_system_error9)
1400   if test x"$ac_system_error9" = x"yes"; then
1401     AC_DEFINE(HAVE_SYS_NERR, 1, [Define if sys_nerr exists.])
1402   fi
1403
1404   AC_MSG_CHECKING([for EBADMSG])
1405   AC_CACHE_VAL(ac_system_error_10, [
1406   AC_TRY_COMPILE([#include <errno.h>], [ int i = EBADMSG; ],
1407              [ac_system_error_10=yes], [ac_system_error_10=no])
1408   ])
1409   AC_MSG_RESULT($ac_system_error_10)
1410   if test x"$ac_system_error_10" = x"yes"; then
1411     AC_DEFINE(HAVE_EBADMSG, 1, [Define if EBADMSG exists.])
1412   fi
1413
1414   AC_MSG_CHECKING([for ECANCELED])
1415   AC_CACHE_VAL(ac_system_error_11, [
1416   AC_TRY_COMPILE([#include <errno.h>], [ int i = ECANCELED; ],
1417              [ac_system_error_11=yes], [ac_system_error_11=no])
1418   ])
1419   AC_MSG_RESULT($ac_system_error_11)
1420   if test x"$ac_system_error_11" = x"yes"; then
1421     AC_DEFINE(HAVE_ECANCELED, 1, [Define if ECANCELED exists.])
1422   fi
1423
1424   AC_MSG_CHECKING([for EOVERFLOW])
1425   AC_CACHE_VAL(ac_system_error_12, [
1426   AC_TRY_COMPILE([#include <errno.h>], [ int i = EOVERFLOW; ],
1427              [ac_system_error_12=yes], [ac_system_error_12=no])
1428   ])
1429   AC_MSG_RESULT($ac_system_error_12)
1430   if test x"$ac_system_error_12" = x"yes"; then
1431     AC_DEFINE(HAVE_EOVERFLOW, 1, [Define if EOVERFLOW exists.])
1432   fi
1433
1434   AC_MSG_CHECKING([for ENOTSUP])
1435   AC_CACHE_VAL(ac_system_error_13, [
1436   AC_TRY_COMPILE([#include <errno.h>], [ int i = ENOTSUP; ],
1437              [ac_system_error_13=yes], [ac_system_error_13=no])
1438   ])
1439   AC_MSG_RESULT($ac_system_error_13)
1440   if test x"$ac_system_error_13" = x"yes"; then
1441     AC_DEFINE(HAVE_ENOTSUP, 1, [Define if ENOTSUP exists.])
1442   fi
1443 ])
1444
1445 dnl
1446 dnl Check for what type of C headers to use.
1447 dnl
1448 dnl --enable-cheaders= [does stuff].
1449 dnl --disable-cheaders [does not do anything, really].
1450 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
1451 dnl       Where DEFAULT is either 'c' or 'c_std' or 'c_global'.
1452 dnl
1453 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
1454   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
1455     [construct "C" headers for g++], [permit c|c_std|c_global])
1456   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
1457
1458   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
1459
1460   # Allow overrides to configure.host here.
1461   if test $enable_cheaders = c_global; then
1462      c_compatibility=yes
1463   fi
1464
1465   if test $enable_cheaders = c_global || test $enable_cheaders = c_std; then
1466      c_extra=yes
1467   fi
1468
1469   AC_SUBST(C_INCLUDE_DIR)
1470   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
1471   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
1472   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_GLOBAL, test $enable_cheaders = c_global)
1473   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
1474   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_EXTRA, test $c_extra = yes)
1475 ])
1476
1477
1478 dnl
1479 dnl Check for which locale library to use.  The choice is mapped to
1480 dnl a subdirectory of config/locale.
1481 dnl
1482 dnl Default is generic.
1483 dnl
1484 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
1485   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
1486     [use MODEL for target locale package],
1487     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
1488
1489   # Deal with gettext issues.  Default to not using it (=no) until we detect
1490   # support for it later.  Let the user turn it off via --e/d, but let that
1491   # default to on for easier handling.
1492   USE_NLS=no
1493   AC_ARG_ENABLE(nls,
1494     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1495     [],
1496     [enable_nls=yes])
1497
1498   # Either a known packaage, or "auto"
1499   if test $enable_clocale = no || test $enable_clocale = yes; then
1500      enable_clocale=auto
1501   fi
1502   enable_clocale_flag=$enable_clocale
1503
1504   # Probe for locale model to use if none specified.
1505   # Default to "generic".
1506   if test $enable_clocale_flag = auto; then
1507     case ${target_os} in
1508       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1509         enable_clocale_flag=gnu
1510         ;;
1511       darwin* | freebsd*)
1512         enable_clocale_flag=darwin
1513         ;;
1514       *)
1515         enable_clocale_flag=generic
1516         ;;
1517     esac
1518   fi
1519
1520   # Sanity check model, and test for special functionality.
1521   if test $enable_clocale_flag = gnu; then
1522     AC_EGREP_CPP([_GLIBCXX_ok], [
1523     #include <features.h>
1524     #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1525       _GLIBCXX_ok
1526     #endif
1527     ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1528
1529     if test $enable_clocale = auto; then
1530       # Test for bugs early in glibc-2.2.x series
1531       AC_TRY_RUN([
1532       #define _GNU_SOURCE 1
1533       #include <locale.h>
1534       #include <string.h>
1535       #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1536       extern __typeof(newlocale) __newlocale;
1537       extern __typeof(duplocale) __duplocale;
1538       extern __typeof(strcoll_l) __strcoll_l;
1539       #endif
1540       int main()
1541       {
1542         const char __one[] = "Äuglein Augmen";
1543         const char __two[] = "Äuglein";
1544         int i;
1545         int j;
1546         __locale_t        loc;
1547         __locale_t        loc_dup;
1548         loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1549         loc_dup = __duplocale(loc);
1550         i = __strcoll_l(__one, __two, loc);
1551         j = __strcoll_l(__one, __two, loc_dup);
1552         return 0;
1553       }
1554       ],
1555       [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1556       [enable_clocale_flag=generic])
1557     fi
1558
1559     # Set it to scream when it hurts.
1560     ac_save_CFLAGS="$CFLAGS"
1561     CFLAGS="-Wimplicit-function-declaration -Werror"
1562
1563     # Use strxfrm_l if available.
1564     AC_TRY_COMPILE([#define _GNU_SOURCE 1
1565                     #include <string.h>
1566                     #include <locale.h>],
1567                     [char s[128]; __locale_t loc; strxfrm_l(s, "C", 5, loc);],
1568                     AC_DEFINE(HAVE_STRXFRM_L, 1,
1569                     [Define if strxfrm_l is available in <string.h>.]),)
1570
1571     # Use strerror_l if available.
1572     AC_TRY_COMPILE([#define _GNU_SOURCE 1
1573                     #include <string.h>
1574                     #include <locale.h>],
1575                     [__locale_t loc; strerror_l(5, loc);],
1576                     AC_DEFINE(HAVE_STRERROR_L, 1,
1577                     [Define if strerror_l is available in <string.h>.]),)
1578
1579     CFLAGS="$ac_save_CFLAGS"
1580   fi
1581
1582   # Perhaps use strerror_r if available, and strerror_l isn't.
1583   ac_save_CFLAGS="$CFLAGS"
1584   CFLAGS="-Wimplicit-function-declaration -Werror"
1585   AC_TRY_COMPILE([#define _GNU_SOURCE 1
1586                   #include <string.h>
1587                   #include <locale.h>],
1588                   [char s[128]; strerror_r(5, s, 128);],
1589                   AC_DEFINE(HAVE_STRERROR_R, 1,
1590                   [Define if strerror_r is available in <string.h>.]),)
1591   CFLAGS="$ac_save_CFLAGS"
1592
1593   # Set configure bits for specified locale package
1594   AC_MSG_CHECKING([for C locale to use])
1595   case ${enable_clocale_flag} in
1596     generic)
1597       AC_MSG_RESULT(generic)
1598
1599       CLOCALE_H=config/locale/generic/c_locale.h
1600       CLOCALE_CC=config/locale/generic/c_locale.cc
1601       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1602       CCOLLATE_CC=config/locale/generic/collate_members.cc
1603       CCTYPE_CC=config/locale/generic/ctype_members.cc
1604       CMESSAGES_H=config/locale/generic/messages_members.h
1605       CMESSAGES_CC=config/locale/generic/messages_members.cc
1606       CMONEY_CC=config/locale/generic/monetary_members.cc
1607       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1608       CTIME_H=config/locale/generic/time_members.h
1609       CTIME_CC=config/locale/generic/time_members.cc
1610       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1611       ;;
1612     darwin)
1613       AC_MSG_RESULT(darwin or freebsd)
1614
1615       CLOCALE_H=config/locale/generic/c_locale.h
1616       CLOCALE_CC=config/locale/generic/c_locale.cc
1617       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1618       CCOLLATE_CC=config/locale/generic/collate_members.cc
1619       CCTYPE_CC=config/locale/darwin/ctype_members.cc
1620       CMESSAGES_H=config/locale/generic/messages_members.h
1621       CMESSAGES_CC=config/locale/generic/messages_members.cc
1622       CMONEY_CC=config/locale/generic/monetary_members.cc
1623       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1624       CTIME_H=config/locale/generic/time_members.h
1625       CTIME_CC=config/locale/generic/time_members.cc
1626       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1627       ;;
1628
1629     gnu)
1630       AC_MSG_RESULT(gnu)
1631
1632       # Declare intention to use gettext, and add support for specific
1633       # languages.
1634       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1635       ALL_LINGUAS="de fr"
1636
1637       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1638       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1639       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1640         USE_NLS=yes
1641       fi
1642       # Export the build objects.
1643       for ling in $ALL_LINGUAS; do \
1644         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1645         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1646       done
1647       AC_SUBST(glibcxx_MOFILES)
1648       AC_SUBST(glibcxx_POFILES)
1649
1650       CLOCALE_H=config/locale/gnu/c_locale.h
1651       CLOCALE_CC=config/locale/gnu/c_locale.cc
1652       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1653       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1654       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1655       CMESSAGES_H=config/locale/gnu/messages_members.h
1656       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1657       CMONEY_CC=config/locale/gnu/monetary_members.cc
1658       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1659       CTIME_H=config/locale/gnu/time_members.h
1660       CTIME_CC=config/locale/gnu/time_members.cc
1661       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1662       ;;
1663     ieee_1003.1-2001)
1664       AC_MSG_RESULT(IEEE 1003.1)
1665
1666       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1667       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1668       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1669       CCOLLATE_CC=config/locale/generic/collate_members.cc
1670       CCTYPE_CC=config/locale/generic/ctype_members.cc
1671       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1672       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1673       CMONEY_CC=config/locale/generic/monetary_members.cc
1674       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1675       CTIME_H=config/locale/generic/time_members.h
1676       CTIME_CC=config/locale/generic/time_members.cc
1677       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1678       ;;
1679   esac
1680
1681   # This is where the testsuite looks for locale catalogs, using the
1682   # -DLOCALEDIR define during testsuite compilation.
1683   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1684   AC_SUBST(glibcxx_localedir)
1685
1686   # A standalone libintl (e.g., GNU libintl) may be in use.
1687   if test $USE_NLS = yes; then
1688     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1689     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1690   fi
1691   if test $USE_NLS = yes; then
1692     AC_DEFINE(_GLIBCXX_USE_NLS, 1,
1693               [Define if NLS translations are to be used.])
1694   fi
1695
1696   AC_SUBST(USE_NLS)
1697   AC_SUBST(CLOCALE_H)
1698   AC_SUBST(CMESSAGES_H)
1699   AC_SUBST(CCODECVT_CC)
1700   AC_SUBST(CCOLLATE_CC)
1701   AC_SUBST(CCTYPE_CC)
1702   AC_SUBST(CMESSAGES_CC)
1703   AC_SUBST(CMONEY_CC)
1704   AC_SUBST(CNUMERIC_CC)
1705   AC_SUBST(CTIME_H)
1706   AC_SUBST(CTIME_CC)
1707   AC_SUBST(CLOCALE_CC)
1708   AC_SUBST(CLOCALE_INTERNAL_H)
1709 ])
1710
1711
1712 dnl
1713 dnl Check for which std::allocator base class to use.  The choice is
1714 dnl mapped from a subdirectory of include/ext.
1715 dnl
1716 dnl Default is new.
1717 dnl
1718 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
1719   AC_MSG_CHECKING([for std::allocator base class])
1720   GLIBCXX_ENABLE(libstdcxx-allocator,auto,[=KIND],
1721     [use KIND for target std::allocator base],
1722     [permit new|malloc|mt|bitmap|pool|yes|no|auto])
1723
1724   # If they didn't use this option switch, or if they specified --enable
1725   # with no specific model, we'll have to look for one.  If they
1726   # specified --disable (???), do likewise.
1727   if test $enable_libstdcxx_allocator = no ||
1728      test $enable_libstdcxx_allocator = yes;
1729   then
1730      enable_libstdcxx_allocator=auto
1731   fi
1732
1733   # Either a known package, or "auto". Auto implies the default choice
1734   # for a particular platform.
1735   enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
1736
1737   # Probe for host-specific support if no specific model is specified.
1738   # Default to "new".
1739   if test $enable_libstdcxx_allocator_flag = auto; then
1740     case ${target_os} in
1741       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1742         enable_libstdcxx_allocator_flag=new
1743         ;;
1744       *)
1745         enable_libstdcxx_allocator_flag=new
1746         ;;
1747     esac
1748   fi
1749   AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
1750
1751
1752   # Set configure bits for specified locale package
1753   case ${enable_libstdcxx_allocator_flag} in
1754     bitmap)
1755       ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
1756       ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
1757       ;;
1758     malloc)
1759       ALLOCATOR_H=config/allocator/malloc_allocator_base.h
1760       ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
1761       ;;
1762     mt)
1763       ALLOCATOR_H=config/allocator/mt_allocator_base.h
1764       ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
1765       ;;
1766     new)
1767       ALLOCATOR_H=config/allocator/new_allocator_base.h
1768       ALLOCATOR_NAME=__gnu_cxx::new_allocator
1769       ;;
1770     pool)
1771       ALLOCATOR_H=config/allocator/pool_allocator_base.h
1772       ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
1773       ;;
1774   esac
1775
1776   AC_SUBST(ALLOCATOR_H)
1777   AC_SUBST(ALLOCATOR_NAME)
1778 ])
1779
1780
1781 dnl
1782 dnl Check for whether the Boost-derived checks should be turned on.
1783 dnl
1784 dnl --enable-concept-checks turns them on.
1785 dnl --disable-concept-checks leaves them off.
1786 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1787 dnl       Where DEFAULT is either `yes' or `no'.
1788 dnl
1789 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
1790   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1791   if test $enable_concept_checks = yes; then
1792     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1,
1793               [Define to use concept checking code from the boost libraries.])
1794   fi
1795 ])
1796
1797 dnl
1798 dnl Check for parallel mode pre-requisites, including OpenMP support.
1799 dnl
1800 dnl  +  Usage:  GLIBCXX_ENABLE_PARALLEL
1801 dnl
1802 AC_DEFUN([GLIBCXX_ENABLE_PARALLEL], [
1803
1804   # NB: libstdc++ may be configured before libgomp: can't check for the actual
1805   # dependencies (omp.h and libgomp).
1806   enable_parallel=no;
1807   if test -f $glibcxx_builddir/../libgomp/omp.h; then
1808     enable_parallel=yes;
1809   else
1810     AC_MSG_NOTICE([$glibcxx_builddir/../libgomp/omp.h not found])
1811   fi
1812
1813   # Check to see if it's explicitly disabled.
1814 #  GLIBCXX_ENABLE(libgomp,$1,,[enable code depending on libgomp],
1815 #       [permit yes|no])
1816
1817 #  if test x$enable_libgomp = xno; then
1818 #    enable_parallel=no
1819 #  fi
1820
1821   AC_MSG_CHECKING([for parallel mode support])
1822   AC_MSG_RESULT([$enable_parallel])
1823   GLIBCXX_CONDITIONAL(ENABLE_PARALLEL, test $enable_parallel = yes)
1824 ])
1825
1826
1827 dnl
1828 dnl Check for which I/O library to use:  stdio, or something specific.
1829 dnl
1830 dnl Default is stdio.
1831 dnl
1832 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
1833   AC_MSG_CHECKING([for underlying I/O to use])
1834   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1835     [use target-specific I/O package], [permit stdio])
1836
1837   # Now that libio has been removed, you can have any color you want as long
1838   # as it's black.  This is one big no-op until other packages are added, but
1839   # showing the framework never hurts.
1840   case ${enable_cstdio} in
1841     stdio)
1842       CSTDIO_H=config/io/c_io_stdio.h
1843       BASIC_FILE_H=config/io/basic_file_stdio.h
1844       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1845       AC_MSG_RESULT(stdio)
1846       ;;
1847   esac
1848
1849   AC_SUBST(CSTDIO_H)
1850   AC_SUBST(BASIC_FILE_H)
1851   AC_SUBST(BASIC_FILE_CC)
1852 ])
1853
1854
1855 dnl
1856 dnl Check for "unusual" flags to pass to the compiler while building.
1857 dnl
1858 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1859 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1860 dnl --disable-cxx-flags passes nothing.
1861 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1862 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1863 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1864 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1865 dnl       If "default flags" is an empty string, the effect is the same
1866 dnl       as --disable or --enable=no.
1867 dnl
1868 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
1869   AC_MSG_CHECKING([for extra compiler flags for building])
1870   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1871     [pass compiler FLAGS when building library],
1872     [case "x$enable_cxx_flags" in
1873       xno | x)   enable_cxx_flags= ;;
1874       x-*)       ;;
1875       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1876      esac])
1877
1878   # Run through flags (either default or command-line) and set anything
1879   # extra (e.g., #defines) that must accompany particular g++ options.
1880   if test -n "$enable_cxx_flags"; then
1881     for f in $enable_cxx_flags; do
1882       case "$f" in
1883         -fhonor-std)  ;;
1884         -*)  ;;
1885         *)   # and we're trying to pass /what/ exactly?
1886              AC_MSG_ERROR([compiler flags start with a -]) ;;
1887       esac
1888     done
1889   fi
1890
1891   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1892   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1893   AC_SUBST(EXTRA_CXX_FLAGS)
1894 ])
1895
1896
1897 dnl
1898 dnl Check to see if debugging libraries are to be built.
1899 dnl
1900 dnl --enable-libstdcxx-debug
1901 dnl builds a separate set of debugging libraries in addition to the
1902 dnl normal (shared, static) libstdc++ binaries.
1903 dnl
1904 dnl --disable-libstdcxx-debug
1905 dnl builds only one (non-debug) version of libstdc++.
1906 dnl
1907 dnl --enable-libstdcxx-debug-flags=FLAGS
1908 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1909 dnl
1910 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1911 dnl       Where DEFAULT is either `yes' or `no'.
1912 dnl
1913 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
1914   AC_MSG_CHECKING([for additional debug build])
1915   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1916   AC_MSG_RESULT($enable_libstdcxx_debug)
1917   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1918 ])
1919
1920
1921 dnl
1922 dnl Check for explicit debug flags.
1923 dnl
1924 dnl --enable-libstdcxx-debug-flags='-O1'
1925 dnl is a general method for passing flags to be used when
1926 dnl building debug libraries with --enable-debug.
1927 dnl
1928 dnl --disable-libstdcxx-debug-flags does nothing.
1929 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1930 dnl       If "default flags" is an empty string, the effect is the same
1931 dnl       as --disable or --enable=no.
1932 dnl
1933 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
1934   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1935     [pass compiler FLAGS when building debug library],
1936     [case "x$enable_libstdcxx_debug_flags" in
1937       xno | x)    enable_libstdcxx_debug_flags= ;;
1938       x-*)        ;;
1939       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1940      esac])
1941
1942   # Option parsed, now set things appropriately
1943   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1944   AC_SUBST(DEBUG_FLAGS)
1945
1946   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1947 ])
1948
1949
1950 dnl
1951 dnl Check if the user only wants a freestanding library implementation.
1952 dnl
1953 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1954 dnl installing only the headers required by [17.4.1.3] and the language
1955 dnl support library.  More than that will be built (to keep the Makefiles
1956 dnl conveniently clean), but not installed.
1957 dnl
1958 dnl Sets:
1959 dnl  is_hosted  (yes/no)
1960 dnl
1961 dnl Defines:
1962 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1963 dnl
1964 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
1965   AC_ARG_ENABLE([hosted-libstdcxx],
1966     AC_HELP_STRING([--disable-hosted-libstdcxx],
1967                    [only build freestanding C++ runtime support]),,
1968     [case "$host" in
1969         arm*-*-symbianelf*)
1970             enable_hosted_libstdcxx=no
1971             ;;
1972         *)
1973             enable_hosted_libstdcxx=yes
1974             ;;
1975      esac])
1976   if test "$enable_hosted_libstdcxx" = no; then
1977     AC_MSG_NOTICE([Only freestanding libraries will be built])
1978     is_hosted=no
1979     hosted_define=0
1980     enable_abi_check=no
1981     enable_libstdcxx_pch=no
1982   else
1983     is_hosted=yes
1984     hosted_define=1
1985   fi
1986   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1987   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1988     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1989 ])
1990
1991
1992 dnl
1993 dnl Check for template specializations for the 'long long' type.
1994 dnl The result determines only whether 'long long' I/O is enabled; things
1995 dnl like numeric_limits<> specializations are always available.
1996 dnl
1997 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1998 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1999 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
2000 dnl       Where DEFAULT is either `yes' or `no'.
2001 dnl
2002 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
2003   GLIBCXX_ENABLE(long-long,$1,,[enable template specializations for 'long long'])
2004   if test $enable_long_long = yes; then
2005     AC_DEFINE(_GLIBCXX_USE_LONG_LONG, 1,
2006               [Define if code specialized for long long should be used.])
2007   fi
2008   AC_MSG_CHECKING([for enabled long long specializations])
2009   AC_MSG_RESULT([$enable_long_long])
2010 ])
2011
2012
2013 dnl
2014 dnl Check for template specializations for the 'wchar_t' type.
2015 dnl
2016 dnl --enable-wchar_t defines _GLIBCXX_USE_WCHAR_T
2017 dnl --disable-wchar_t leaves _GLIBCXX_USE_WCHAR_T undefined
2018 dnl  +  Usage:  GLIBCXX_ENABLE_WCHAR_T[(DEFAULT)]
2019 dnl       Where DEFAULT is either `yes' or `no'.
2020 dnl
2021 dnl Necessary support must also be present.
2022 dnl
2023 AC_DEFUN([GLIBCXX_ENABLE_WCHAR_T], [
2024   GLIBCXX_ENABLE(wchar_t,$1,,[enable template specializations for 'wchar_t'])
2025
2026   # Test wchar.h for mbstate_t, which is needed for char_traits and fpos.
2027   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
2028   AC_MSG_CHECKING([for mbstate_t])
2029   AC_TRY_COMPILE([#include <wchar.h>],
2030   [mbstate_t teststate;],
2031   have_mbstate_t=yes, have_mbstate_t=no)
2032   AC_MSG_RESULT($have_mbstate_t)
2033   if test x"$have_mbstate_t" = xyes; then
2034     AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
2035   fi
2036
2037   # Test it always, for use in GLIBCXX_ENABLE_C99, together with
2038   # ac_has_wchar_h.
2039   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
2040
2041   if test x"$enable_wchar_t" = x"yes"; then
2042
2043     AC_LANG_SAVE
2044     AC_LANG_CPLUSPLUS
2045
2046     if test x"$ac_has_wchar_h" = xyes &&
2047        test x"$ac_has_wctype_h" = xyes; then
2048       AC_TRY_COMPILE([#include <wchar.h>
2049                       #include <stddef.h>
2050                       wint_t i;
2051                       long l = WEOF;
2052                       long j = WCHAR_MIN;
2053                       long k = WCHAR_MAX;
2054                       namespace test
2055                       {
2056                         using ::btowc;
2057                         using ::fgetwc;
2058                         using ::fgetws;
2059                         using ::fputwc;
2060                         using ::fputws;
2061                         using ::fwide;
2062                         using ::fwprintf;
2063                         using ::fwscanf;
2064                         using ::getwc;
2065                         using ::getwchar;
2066                         using ::mbrlen;
2067                         using ::mbrtowc;
2068                         using ::mbsinit;
2069                         using ::mbsrtowcs;
2070                         using ::putwc;
2071                         using ::putwchar;
2072                         using ::swprintf;
2073                         using ::swscanf;
2074                         using ::ungetwc;
2075                         using ::vfwprintf;
2076                         using ::vswprintf;
2077                         using ::vwprintf;
2078                         using ::wcrtomb;
2079                         using ::wcscat;
2080                         using ::wcschr;
2081                         using ::wcscmp;
2082                         using ::wcscoll;
2083                         using ::wcscpy;
2084                         using ::wcscspn;
2085                         using ::wcsftime;
2086                         using ::wcslen;
2087                         using ::wcsncat;
2088                         using ::wcsncmp;
2089                         using ::wcsncpy;
2090                         using ::wcspbrk;
2091                         using ::wcsrchr;
2092                         using ::wcsrtombs;
2093                         using ::wcsspn;
2094                         using ::wcsstr;
2095                         using ::wcstod;
2096                         using ::wcstok;
2097                         using ::wcstol;
2098                         using ::wcstoul;
2099                         using ::wcsxfrm;
2100                         using ::wctob;
2101                         using ::wmemchr;
2102                         using ::wmemcmp;
2103                         using ::wmemcpy;
2104                         using ::wmemmove;
2105                         using ::wmemset;
2106                         using ::wprintf;
2107                         using ::wscanf;
2108                       }
2109                      ],[],[], [enable_wchar_t=no])
2110     else
2111       enable_wchar_t=no
2112     fi
2113
2114     AC_LANG_RESTORE
2115   fi
2116
2117   if test x"$enable_wchar_t" = x"yes"; then
2118     AC_DEFINE(_GLIBCXX_USE_WCHAR_T, 1,
2119               [Define if code specialized for wchar_t should be used.])
2120   fi
2121
2122   AC_MSG_CHECKING([for enabled wchar_t specializations])
2123   AC_MSG_RESULT([$enable_wchar_t])
2124 ])
2125
2126
2127 dnl
2128 dnl Check to see if building and using a C++ precompiled header can be done.
2129 dnl
2130 dnl --enable-libstdcxx-pch=yes
2131 dnl default, this shows intent to use stdc++.h.gch If it looks like it
2132 dnl may work, after some light-hearted attempts to puzzle out compiler
2133 dnl support, flip bits on in include/Makefile.am
2134 dnl
2135 dnl --disable-libstdcxx-pch
2136 dnl turns off attempts to use or build stdc++.h.gch.
2137 dnl
2138 dnl Substs:
2139 dnl  glibcxx_PCHFLAGS
2140 dnl
2141 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
2142   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
2143   if test $enable_libstdcxx_pch = yes; then
2144     AC_CACHE_CHECK([for compiler with PCH support],
2145       [glibcxx_cv_prog_CXX_pch],
2146       [ac_save_CXXFLAGS="$CXXFLAGS"
2147        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
2148        AC_LANG_SAVE
2149        AC_LANG_CPLUSPLUS
2150        echo '#include <math.h>' > conftest.h
2151        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
2152                           -o conftest.h.gch 1>&5 2>&1 &&
2153                 echo '#error "pch failed"' > conftest.h &&
2154           echo '#include "conftest.h"' > conftest.cc &&
2155                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
2156        then
2157          glibcxx_cv_prog_CXX_pch=yes
2158        else
2159          glibcxx_cv_prog_CXX_pch=no
2160        fi
2161        rm -f conftest*
2162        CXXFLAGS=$ac_save_CXXFLAGS
2163        AC_LANG_RESTORE
2164       ])
2165     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
2166   fi
2167
2168   AC_MSG_CHECKING([for enabled PCH])
2169   AC_MSG_RESULT([$enable_libstdcxx_pch])
2170
2171   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
2172   if test $enable_libstdcxx_pch = yes; then
2173     glibcxx_PCHFLAGS="-include bits/stdc++.h"
2174   else
2175     glibcxx_PCHFLAGS=""
2176   fi
2177   AC_SUBST(glibcxx_PCHFLAGS)
2178 ])
2179
2180
2181 dnl
2182 dnl Check for atomic builtins.
2183 dnl See:
2184 dnl http://gcc.gnu.org/onlinedocs/gcc/Atomic-Builtins.html#Atomic-Builtins
2185 dnl
2186 dnl This checks to see if the host supports the compiler-generated
2187 dnl builtins for atomic operations. Note, this is intended to be an
2188 dnl all-or-nothing switch, so all the atomic operations that are used
2189 dnl should be checked.
2190 dnl
2191 dnl Note:
2192 dnl libgomp and libgfortran do this with a link test, instead of an asm test.
2193 dnl see: CHECK_SYNC_FETCH_AND_ADD
2194 dnl
2195 dnl Defines:
2196 dnl  _GLIBCXX_ATOMIC_BUILTINS if the compiler on this target supports atomics.
2197 dnl
2198 AC_DEFUN([GLIBCXX_ENABLE_ATOMIC_BUILTINS], [
2199   AC_MSG_CHECKING([for atomic builtins])
2200   AC_LANG_SAVE
2201   AC_LANG_CPLUSPLUS
2202
2203   # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
2204     cat > conftest.$ac_ext << EOF
2205 [#]line __oline__ "configure"
2206 int main()
2207 {
2208   // NB: _Atomic_word not necessarily int.
2209   typedef int atomic_type;
2210   atomic_type c1;
2211   atomic_type c2;
2212   const atomic_type c3(0);
2213   if (__sync_fetch_and_add(&c1, c2) == c3)
2214     {
2215       // Do something.
2216     }
2217    return 0;
2218 }
2219 EOF
2220     old_CXXFLAGS="$CXXFLAGS"
2221     CXXFLAGS=-S
2222     if AC_TRY_EVAL(ac_compile); then
2223       if grep __sync_fetch_and_add conftest.s >/dev/null 2>&1 ; then
2224         enable_atomic_builtins=no
2225       else
2226       AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS, 1,
2227         [Define if builtin atomic operations are supported on this host.])
2228         enable_atomic_builtins=yes
2229         atomicity_dir=cpu/generic/atomicity_builtins
2230       fi
2231     fi
2232     CXXFLAGS="$old_CXXFLAGS"
2233     rm -f conftest*
2234
2235    # Now, if still generic, set to mutex.
2236   if test $atomicity_dir = "cpu/generic" ; then
2237         atomicity_dir=cpu/generic/atomicity_mutex
2238   fi
2239  AC_LANG_RESTORE
2240  AC_MSG_RESULT($enable_atomic_builtins)
2241 ])
2242
2243
2244 dnl
2245 dnl Check for exception handling support.  If an explicit enable/disable
2246 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
2247 dnl target may or may not support call frame exceptions.
2248 dnl
2249 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
2250 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
2251 dnl Neither one forces an attempt at detection.
2252 dnl
2253 dnl Defines:
2254 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
2255 dnl
2256 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
2257   AC_MSG_CHECKING([for exception model to use])
2258   AC_LANG_SAVE
2259   AC_LANG_CPLUSPLUS
2260   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
2261     [force use of builtin_setjmp for exceptions],
2262     [permit yes|no|auto])
2263
2264   if test $enable_sjlj_exceptions = auto; then
2265     # Botheration.  Now we've got to detect the exception model.  Link tests
2266     # against libgcc.a are problematic since we've not been given proper -L
2267     # bits for single-tree newlib and libgloss.
2268     #
2269     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
2270     cat > conftest.$ac_ext << EOF
2271 [#]line __oline__ "configure"
2272 struct S { ~S(); };
2273 void bar();
2274 void foo()
2275 {
2276   S s;
2277   bar();
2278 }
2279 EOF
2280     old_CXXFLAGS="$CXXFLAGS"
2281     CXXFLAGS=-S
2282     if AC_TRY_EVAL(ac_compile); then
2283       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
2284         enable_sjlj_exceptions=yes
2285       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
2286         enable_sjlj_exceptions=no
2287       elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
2288         enable_sjlj_exceptions=no
2289       fi
2290     fi
2291     CXXFLAGS="$old_CXXFLAGS"
2292     rm -f conftest*
2293   fi
2294
2295   # This is a tad weird, for hysterical raisins.  We have to map
2296   # enable/disable to two different models.
2297   case $enable_sjlj_exceptions in
2298     yes)
2299       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
2300         [Define if the compiler is configured for setjmp/longjmp exceptions.])
2301       ac_exception_model_name=sjlj
2302       ;;
2303     no)
2304       ac_exception_model_name="call frame"
2305       ;;
2306     *)
2307       AC_MSG_ERROR([unable to detect exception model])
2308       ;;
2309   esac
2310  AC_LANG_RESTORE
2311  AC_MSG_RESULT($ac_exception_model_name)
2312 ])
2313
2314
2315 dnl
2316 dnl Allow visibility attributes to be used on namespaces, objects, etc.
2317 dnl
2318 dnl --enable-visibility enables attempt to use visibility attributes.
2319 dnl --disable-visibility turns off all use of visibility attributes.
2320 dnl  +  Usage:  GLIBCXX_ENABLE_VISIBILITY[(DEFAULT)]
2321 dnl       Where DEFAULT is 'yes'.
2322 dnl
2323 AC_DEFUN([GLIBCXX_ENABLE_VISIBILITY], [
2324 GLIBCXX_ENABLE(visibility,$1,,[enables visibility safe usage])
2325
2326 if test x$enable_visibility = xyes ; then
2327   dnl all hail libgfortran
2328   dnl Check whether the target supports hidden visibility.
2329   AC_CACHE_CHECK([whether the target supports hidden visibility],
2330                  have_attribute_visibility, [
2331   save_CFLAGS="$CFLAGS"
2332   CFLAGS="$CFLAGS -Werror"
2333   AC_TRY_COMPILE([void __attribute__((visibility("hidden"))) foo(void) { }],
2334                  [], have_attribute_visibility=yes,
2335                  have_attribute_visibility=no)
2336   CFLAGS="$save_CFLAGS"])
2337   if test $have_attribute_visibility = no; then
2338     enable_visibility=no
2339   fi
2340 fi
2341
2342 GLIBCXX_CONDITIONAL(ENABLE_VISIBILITY, test $enable_visibility = yes)
2343 AC_MSG_NOTICE([visibility supported: $enable_visibility])
2344 ])
2345
2346
2347 dnl
2348 dnl Add version tags to symbols in shared library (or not), additionally
2349 dnl marking other symbols as private/local (or not).
2350 dnl
2351 dnl --enable-symvers=style adds a version script to the linker call when
2352 dnl       creating the shared library.  The choice of version script is
2353 dnl       controlled by 'style'.
2354 dnl --disable-symvers does not.
2355 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
2356 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
2357 dnl       choose a default style based on linker characteristics.  Passing
2358 dnl       'no' disables versioning.
2359 dnl
2360 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
2361
2362 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
2363   [enables symbol versioning of the shared library],
2364   [permit yes|no|gnu|gnu-versioned-namespace|darwin|darwin-export])
2365
2366 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
2367 # don't know enough about $LD to do tricks...
2368 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
2369
2370 # Turn a 'yes' into a suitable default.
2371 if test x$enable_symvers = xyes ; then
2372   if test $enable_shared = no || test "x$LD" = x || test x$gcc_no_link = xyes; then
2373     enable_symvers=no
2374   else
2375     if test $with_gnu_ld = yes ; then
2376       enable_symvers=gnu
2377     else
2378       case ${target_os} in
2379         darwin*)
2380           enable_symvers=darwin ;;
2381         *)
2382           enable_symvers=no ;;
2383       esac
2384     fi
2385   fi
2386 fi
2387
2388 # Check to see if 'darwin' or 'darwin-export' can win.
2389 if test x$enable_symvers = xdarwin-export ; then
2390     enable_symvers=darwin
2391 fi
2392
2393 # Check to see if 'gnu' can win.
2394 if test $enable_symvers = gnu || test $enable_symvers = gnu-versioned-namespace; then
2395   # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
2396   AC_MSG_CHECKING([for shared libgcc])
2397   ac_save_CFLAGS="$CFLAGS"
2398   CFLAGS=' -lgcc_s'
2399   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
2400   CFLAGS="$ac_save_CFLAGS"
2401   if test $glibcxx_shared_libgcc = no; then
2402     cat > conftest.c <<EOF
2403 int main (void) { return 0; }
2404 EOF
2405 changequote(,)dnl
2406     glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
2407                              -shared -shared-libgcc -o conftest.so \
2408                              conftest.c -v 2>&1 >/dev/null \
2409                              | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
2410 changequote([,])dnl
2411     rm -f conftest.c conftest.so
2412     if test x${glibcxx_libgcc_s_suffix+set} = xset; then
2413       CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
2414       AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
2415       CFLAGS="$ac_save_CFLAGS"
2416     fi
2417   fi
2418   AC_MSG_RESULT($glibcxx_shared_libgcc)
2419
2420   # For GNU ld, we need at least this version.  The format is described in
2421   # GLIBCXX_CHECK_LINKER_FEATURES above.
2422   glibcxx_min_gnu_ld_version=21400
2423
2424   # If no shared libgcc, can't win.
2425   if test $glibcxx_shared_libgcc != yes; then
2426       AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
2427       AC_MSG_WARN([=== you are not building a shared libgcc_s.])
2428       AC_MSG_WARN([=== Symbol versioning will be disabled.])
2429       enable_symvers=no
2430   elif test $with_gnu_ld != yes ; then
2431     # just fail for now
2432     AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
2433     AC_MSG_WARN([=== you are not using the GNU linker.])
2434     AC_MSG_WARN([=== Symbol versioning will be disabled.])
2435     enable_symvers=no
2436   elif test $glibcxx_gnu_ld_version -lt $glibcxx_min_gnu_ld_version ; then
2437     # The right tools, the right setup, but too old.  Fallbacks?
2438     AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
2439     AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
2440     AC_MSG_WARN(=== You would need to upgrade your binutils to version)
2441     AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
2442     AC_MSG_WARN([=== Symbol versioning will be disabled.])
2443     enable_symvers=no
2444   fi
2445 fi
2446
2447 # Everything parsed; figure out what file to use.
2448 case $enable_symvers in
2449   no)
2450     SYMVER_FILE=config/abi/pre/none.ver
2451     ;;
2452   gnu)
2453     SYMVER_FILE=config/abi/pre/gnu.ver
2454     AC_DEFINE(_GLIBCXX_SYMVER_GNU, 1,
2455               [Define to use GNU versioning in the shared library.])
2456     ;;
2457   gnu-versioned-namespace)
2458     SYMVER_FILE=config/abi/pre/gnu-versioned-namespace.ver
2459     AC_DEFINE(_GLIBCXX_SYMVER_GNU_NAMESPACE, 1,
2460               [Define to use GNU namespace versioning in the shared library.])
2461     ;;
2462   darwin)
2463     SYMVER_FILE=config/abi/pre/gnu.ver
2464     AC_DEFINE(_GLIBCXX_SYMVER_DARWIN, 1,
2465               [Define to use darwin versioning in the shared library.])
2466     ;;
2467 esac
2468
2469 if test x$enable_symvers != xno ; then
2470   AC_DEFINE(_GLIBCXX_SYMVER, 1,
2471          [Define to use symbol versioning in the shared library.])
2472 fi
2473
2474 AC_SUBST(SYMVER_FILE)
2475 AC_SUBST(port_specific_symbol_files)
2476 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS, test $enable_symvers != no)
2477 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU, test $enable_symvers = gnu)
2478 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU_NAMESPACE, test $enable_symvers = gnu-versioned-namespace)
2479 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_DARWIN, test $enable_symvers = darwin)
2480 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
2481
2482 # Now, set up compatibility support, if any.
2483 # In addition, need this to deal with std::size_t mangling in
2484 # src/compatibility.cc.  In a perfect world, could use
2485 # typeid(std::size_t).name()[0] to do direct substitution.
2486 AC_MSG_CHECKING([for size_t as unsigned int])
2487 ac_save_CFLAGS="$CFLAGS"
2488 CFLAGS="-Werror"
2489 AC_TRY_COMPILE(, [__SIZE_TYPE__* stp; unsigned int* uip; stp = uip;],
2490                  [glibcxx_size_t_is_i=yes], [glibcxx_size_t_is_i=no])
2491 CFLAGS=$ac_save_CFLAGS
2492 if test "$glibcxx_size_t_is_i" = yes; then
2493   AC_DEFINE(_GLIBCXX_SIZE_T_IS_UINT, 1, [Define if size_t is unsigned int.])
2494 fi
2495 AC_MSG_RESULT([$glibcxx_size_t_is_i])
2496
2497 AC_MSG_CHECKING([for ptrdiff_t as int])
2498 ac_save_CFLAGS="$CFLAGS"
2499 CFLAGS="-Werror"
2500 AC_TRY_COMPILE(, [__PTRDIFF_TYPE__* ptp; int* ip; ptp = ip;],
2501                  [glibcxx_ptrdiff_t_is_i=yes], [glibcxx_ptrdiff_t_is_i=no])
2502 CFLAGS=$ac_save_CFLAGS
2503 if test "$glibcxx_ptrdiff_t_is_i" = yes; then
2504   AC_DEFINE(_GLIBCXX_PTRDIFF_T_IS_INT, 1, [Define if ptrdiff_t is int.])
2505 fi
2506 AC_MSG_RESULT([$glibcxx_ptrdiff_t_is_i])
2507 ])
2508
2509
2510 dnl
2511 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
2512 dnl We must stage the required headers so that they will be installed
2513 dnl with the library (unlike libgcc, the STL implementation is provided
2514 dnl solely within headers).  Since we must not inject random user-space
2515 dnl macro names into user-provided C++ code, we first stage into <file>-in
2516 dnl and process to <file> with an output command.  The reason for a two-
2517 dnl stage process here is to correctly handle $srcdir!=$objdir without
2518 dnl having to write complex code (the sed commands to clean the macro
2519 dnl namespace are complex and fragile enough as it is).  We must also
2520 dnl add a relative path so that -I- is supported properly.
2521 dnl
2522 dnl Substs:
2523 dnl  glibcxx_thread_h
2524 dnl
2525 dnl Defines:
2526 dnl  HAVE_GTHR_DEFAULT
2527 dnl
2528 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
2529   AC_MSG_CHECKING([for thread model used by GCC])
2530   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
2531   AC_MSG_RESULT([$target_thread_file])
2532
2533   if test $target_thread_file != single; then
2534     AC_DEFINE(HAVE_GTHR_DEFAULT, 1,
2535               [Define if gthr-default.h exists
2536               (meaning that threading support is enabled).])
2537   fi
2538
2539   glibcxx_thread_h=gthr-$target_thread_file.h
2540
2541   dnl Check for __GTHREADS define.
2542   gthread_file=${toplevel_srcdir}/gcc/${glibcxx_thread_h}
2543   if grep __GTHREADS $gthread_file >/dev/null 2>&1 ; then
2544     enable_thread=yes
2545   else
2546    enable_thread=no
2547   fi
2548
2549   AC_SUBST(glibcxx_thread_h)
2550 ])
2551
2552
2553 # Check whether LC_MESSAGES is available in <locale.h>.
2554 # Ulrich Drepper <drepper@cygnus.com>, 1995.
2555 #
2556 # This file file be copied and used freely without restrictions.  It can
2557 # be used in projects which are not available under the GNU Public License
2558 # but which still want to provide support for the GNU gettext functionality.
2559 # Please note that the actual code is *not* freely available.
2560 AC_DEFUN([AC_LC_MESSAGES], [
2561   AC_CHECK_HEADER(locale.h, [
2562     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
2563       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
2564        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
2565     if test $ac_cv_val_LC_MESSAGES = yes; then
2566       AC_DEFINE(HAVE_LC_MESSAGES, 1,
2567                 [Define if LC_MESSAGES is available in <locale.h>.])
2568     fi
2569   ])
2570 ])
2571
2572 # Macros from the top-level gcc directory.
2573 m4_include([../config/tls.m4])
2574