gcc/ada/mlib-tgt-linux.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             M L I B . T G T                              --
   6 --                           (GNU/Linux Version)                            --
   7 --                                                                          --
   8 --                                 B o d y                                  --
   9 --                                                                          --
  10 --              Copyright (C) 2001-2005, Free Software Foundation, Inc.     --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  21 -- Boston, MA 02110-1301, USA.                                              --
  22 --                                                                          --
  23 -- GNAT was originally developed  by the GNAT team at  New York University. --
  24 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  25 --                                                                          --
  26 ------------------------------------------------------------------------------
  27
  28 --  This package provides a set of target dependent routines to build
  29 --  static, dynamic and shared libraries.
  30
  31 --  This is the GNU/Linux version of the body.
  32
  33 with MLib.Fil;
  34 with MLib.Utl;
  35 with Namet;  use Namet;
  36 with Opt;
  37 with Output; use Output;
  38 with Prj.Com;
  39 with System;
  40
  41 package body MLib.Tgt is
  42
  43    use GNAT;
  44    use MLib;
  45
  46    ---------------------
  47    -- Archive_Builder --
  48    ---------------------
  49
  50    function Archive_Builder return String is
  51    begin
  52       return "ar";
  53    end Archive_Builder;
  54
  55    -----------------------------
  56    -- Archive_Builder_Options --
  57    -----------------------------
  58
  59    function Archive_Builder_Options return String_List_Access is
  60    begin
  61       return new String_List'(1 => new String'("cr"));
  62    end Archive_Builder_Options;
  63
  64    -----------------
  65    -- Archive_Ext --
  66    -----------------
  67
  68    function Archive_Ext return  String is
  69    begin
  70       return "a";
  71    end Archive_Ext;
  72
  73    ---------------------
  74    -- Archive_Indexer --
  75    ---------------------
  76
  77    function Archive_Indexer return String is
  78    begin
  79       return "ranlib";
  80    end Archive_Indexer;
  81
  82    -----------------------------
  83    -- Archive_Indexer_Options --
  84    -----------------------------
  85
  86    function Archive_Indexer_Options return String_List_Access is
  87    begin
  88       return new String_List (1 .. 0);
  89    end Archive_Indexer_Options;
  90
  91    ---------------------------
  92    -- Build_Dynamic_Library --
  93    ---------------------------
  94
  95    procedure Build_Dynamic_Library
  96      (Ofiles       : Argument_List;
  97       Foreign      : Argument_List;
  98       Afiles       : Argument_List;
  99       Options      : Argument_List;
 100       Options_2    : Argument_List;
 101       Interfaces   : Argument_List;
 102       Lib_Filename : String;
 103       Lib_Dir      : String;
 104       Symbol_Data  : Symbol_Record;
 105       Driver_Name  : Name_Id := No_Name;
 106       Lib_Version  : String  := "";
 107       Auto_Init    : Boolean := False)
 108    is
 109       pragma Unreferenced (Foreign);
 110       pragma Unreferenced (Afiles);
 111       pragma Unreferenced (Interfaces);
 112       pragma Unreferenced (Symbol_Data);
 113       pragma Unreferenced (Auto_Init);
 114       --  Initialization is done through the contructor mechanism
 115
 116       Lib_File : constant String :=
 117                    Lib_Dir & Directory_Separator & "lib" &
 118                    Fil.Ext_To (Lib_Filename, DLL_Ext);
 119
 120       Version_Arg          : String_Access;
 121       Symbolic_Link_Needed : Boolean := False;
 122
 123    begin
 124       if Opt.Verbose_Mode then
 125          Write_Str ("building relocatable shared library ");
 126          Write_Line (Lib_File);
 127       end if;
 128
 129       if Lib_Version = "" then
 130          Utl.Gcc
 131            (Output_File => Lib_File,
 132             Objects     => Ofiles,
 133             Options     => Options,
 134             Driver_Name => Driver_Name,
 135             Options_2   => Options_2);
 136
 137       else
 138          Version_Arg := new String'("-Wl,-soname," & Lib_Version);
 139
 140          if Is_Absolute_Path (Lib_Version) then
 141             Utl.Gcc
 142               (Output_File => Lib_Version,
 143                Objects     => Ofiles,
 144                Options     => Options & Version_Arg,
 145                Driver_Name => Driver_Name,
 146                Options_2   => Options_2);
 147             Symbolic_Link_Needed := Lib_Version /= Lib_File;
 148
 149          else
 150             Utl.Gcc
 151               (Output_File => Lib_Dir & Directory_Separator & Lib_Version,
 152                Objects     => Ofiles,
 153                Options     => Options & Version_Arg,
 154                Driver_Name => Driver_Name,
 155                Options_2   => Options_2);
 156             Symbolic_Link_Needed :=
 157               Lib_Dir & Directory_Separator & Lib_Version /= Lib_File;
 158          end if;
 159
 160          if Symbolic_Link_Needed then
 161             declare
 162                Success : Boolean;
 163                Oldpath : String (1 .. Lib_Version'Length + 1);
 164                Newpath : String (1 .. Lib_File'Length + 1);
 165
 166                Result : Integer;
 167                pragma Unreferenced (Result);
 168
 169                function Symlink
 170                  (Oldpath : System.Address;
 171                   Newpath : System.Address) return Integer;
 172                pragma Import (C, Symlink, "__gnat_symlink");
 173
 174             begin
 175                Oldpath (1 .. Lib_Version'Length) := Lib_Version;
 176                Oldpath (Oldpath'Last)            := ASCII.NUL;
 177                Newpath (1 .. Lib_File'Length)    := Lib_File;
 178                Newpath (Newpath'Last)            := ASCII.NUL;
 179
 180                Delete_File (Lib_File, Success);
 181
 182                Result := Symlink (Oldpath'Address, Newpath'Address);
 183             end;
 184          end if;
 185       end if;
 186    end Build_Dynamic_Library;
 187
 188    -------------
 189    -- DLL_Ext --
 190    -------------
 191
 192    function DLL_Ext return String is
 193    begin
 194       return "so";
 195    end DLL_Ext;
 196
 197    --------------------
 198    -- Dynamic_Option --
 199    --------------------
 200
 201    function Dynamic_Option return String is
 202    begin
 203       return "-shared";
 204    end Dynamic_Option;
 205
 206    -------------------
 207    -- Is_Object_Ext --
 208    -------------------
 209
 210    function Is_Object_Ext (Ext : String) return Boolean is
 211    begin
 212       return Ext = ".o";
 213    end Is_Object_Ext;
 214
 215    --------------
 216    -- Is_C_Ext --
 217    --------------
 218
 219    function Is_C_Ext (Ext : String) return Boolean is
 220    begin
 221       return Ext = ".c";
 222    end Is_C_Ext;
 223
 224    --------------------
 225    -- Is_Archive_Ext --
 226    --------------------
 227
 228    function Is_Archive_Ext (Ext : String) return Boolean is
 229    begin
 230       return Ext = ".a" or else Ext = ".so";
 231    end Is_Archive_Ext;
 232
 233    -------------
 234    -- Libgnat --
 235    -------------
 236
 237    function Libgnat return String is
 238    begin
 239       return "libgnat.a";
 240    end Libgnat;
 241
 242    ------------------------
 243    -- Library_Exists_For --
 244    ------------------------
 245
 246    function Library_Exists_For
 247      (Project : Project_Id; In_Tree : Project_Tree_Ref) return Boolean
 248    is
 249    begin
 250       if not In_Tree.Projects.Table (Project).Library then
 251          Prj.Com.Fail ("INTERNAL ERROR: Library_Exists_For called " &
 252                        "for non library project");
 253          return False;
 254
 255       else
 256          declare
 257             Lib_Dir : constant String :=
 258               Get_Name_String
 259                 (In_Tree.Projects.Table (Project).Library_Dir);
 260             Lib_Name : constant String :=
 261               Get_Name_String
 262                 (In_Tree.Projects.Table (Project).Library_Name);
 263
 264          begin
 265             if In_Tree.Projects.Table (Project).Library_Kind =
 266                  Static
 267             then
 268                return Is_Regular_File
 269                  (Lib_Dir & Directory_Separator & "lib" &
 270                   Fil.Ext_To (Lib_Name, Archive_Ext));
 271
 272             else
 273                return Is_Regular_File
 274                  (Lib_Dir & Directory_Separator & "lib" &
 275                   Fil.Ext_To (Lib_Name, DLL_Ext));
 276             end if;
 277          end;
 278       end if;
 279    end Library_Exists_For;
 280
 281    ---------------------------
 282    -- Library_File_Name_For --
 283    ---------------------------
 284
 285    function Library_File_Name_For
 286      (Project : Project_Id;
 287       In_Tree : Project_Tree_Ref) return Name_Id
 288    is
 289    begin
 290       if not In_Tree.Projects.Table (Project).Library then
 291          Prj.Com.Fail ("INTERNAL ERROR: Library_File_Name_For called " &
 292                        "for non library project");
 293          return No_Name;
 294
 295       else
 296          declare
 297             Lib_Name : constant String :=
 298               Get_Name_String
 299                 (In_Tree.Projects.Table (Project).Library_Name);
 300
 301          begin
 302             Name_Len := 3;
 303             Name_Buffer (1 .. Name_Len) := "lib";
 304
 305             if In_Tree.Projects.Table (Project).Library_Kind =
 306                  Static
 307             then
 308                Add_Str_To_Name_Buffer (Fil.Ext_To (Lib_Name, Archive_Ext));
 309
 310             else
 311                Add_Str_To_Name_Buffer (Fil.Ext_To (Lib_Name, DLL_Ext));
 312             end if;
 313
 314             return Name_Find;
 315          end;
 316       end if;
 317    end Library_File_Name_For;
 318
 319    ----------------
 320    -- Object_Ext --
 321    ----------------
 322
 323    function Object_Ext return String is
 324    begin
 325       return "o";
 326    end Object_Ext;
 327
 328    ----------------
 329    -- PIC_Option --
 330    ----------------
 331
 332    function PIC_Option return String is
 333    begin
 334       return "-fPIC";
 335    end PIC_Option;
 336
 337    -----------------------------------------------
 338    -- Standalone_Library_Auto_Init_Is_Supported --
 339    -----------------------------------------------
 340
 341    function Standalone_Library_Auto_Init_Is_Supported return Boolean is
 342    begin
 343       return True;
 344    end Standalone_Library_Auto_Init_Is_Supported;
 345
 346    ---------------------------
 347    -- Support_For_Libraries --
 348    ---------------------------
 349
 350    function Support_For_Libraries return Library_Support is
 351    begin
 352       return Full;
 353    end Support_For_Libraries;
 354
 355 end MLib.Tgt;