gcc/ada/a-cihase.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                      A D A . C O N T A I N E R S .                       --
   6 --               I N D E F I N I T E _ H A S H E D _ S E T S                --
   7 --                                                                          --
   8 --                                 S p e c                                  --
   9 --                                                                          --
  10 --          Copyright (C) 2004-2005 Free Software Foundation, Inc.          --
  11 --                                                                          --
  12 -- This specification is derived from the Ada Reference Manual for use with --
  13 -- GNAT. The copyright notice above, and the license provisions that follow --
  14 -- apply solely to the  contents of the part following the private keyword. --
  15 --                                                                          --
  16 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  17 -- terms of the  GNU General Public License as published  by the Free Soft- --
  18 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  19 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  20 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  21 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  22 -- for  more details.  You should have  received  a copy of the GNU General --
  23 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  24 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  25 -- Boston, MA 02110-1301, USA.                                              --
  26 --                                                                          --
  27 -- As a special exception,  if other files  instantiate  generics from this --
  28 -- unit, or you link  this unit with other files  to produce an executable, --
  29 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  30 -- covered  by the  GNU  General  Public  License.  This exception does not --
  31 -- however invalidate  any other reasons why  the executable file  might be --
  32 -- covered by the  GNU Public License.                                      --
  33 --                                                                          --
  34 -- This unit was originally developed by Matthew J Heaney.                  --
  35 ------------------------------------------------------------------------------
  36
  37 with Ada.Containers.Hash_Tables;
  38 with Ada.Streams;
  39 with Ada.Finalization;
  40
  41 generic
  42    type Element_Type (<>) is private;
  43
  44    with function Hash (Element : Element_Type) return Hash_Type;
  45
  46    with function Equivalent_Elements (Left, Right : Element_Type)
  47                                      return Boolean;
  48
  49    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  50
  51 package Ada.Containers.Indefinite_Hashed_Sets is
  52    pragma Preelaborate;
  53
  54    type Set is tagged private;
  55
  56    type Cursor is private;
  57
  58    Empty_Set : constant Set;
  59
  60    No_Element : constant Cursor;
  61
  62    function "=" (Left, Right : Set) return Boolean;
  63
  64    function Equivalent_Sets (Left, Right : Set) return Boolean;
  65
  66    function Capacity (Container : Set) return Count_Type;
  67
  68    procedure Reserve_Capacity
  69      (Container : in out Set;
  70       Capacity  : Count_Type);
  71
  72    function Length (Container : Set) return Count_Type;
  73
  74    function Is_Empty (Container : Set) return Boolean;
  75
  76    procedure Clear (Container : in out Set);
  77
  78    function Element (Position : Cursor) return Element_Type;
  79
  80    procedure Replace_Element
  81      (Container : in out Set;
  82       Position  : Cursor;
  83       New_Item  : Element_Type);
  84
  85    procedure Query_Element
  86      (Position : Cursor;
  87       Process  : not null access procedure (Element : Element_Type));
  88
  89    procedure Move
  90      (Target : in out Set;
  91       Source : in out Set);
  92
  93    procedure Insert
  94      (Container : in out Set;
  95       New_Item  : Element_Type;
  96       Position  : out Cursor;
  97       Inserted  : out Boolean);
  98
  99    procedure Insert  (Container : in out Set; New_Item : Element_Type);
 100
 101    procedure Include (Container : in out Set; New_Item : Element_Type);
 102
 103    procedure Replace (Container : in out Set; New_Item : Element_Type);
 104
 105    procedure Exclude (Container : in out Set; Item : Element_Type);
 106
 107    procedure Delete  (Container : in out Set; Item : Element_Type);
 108
 109    procedure Delete (Container : in out Set; Position  : in out Cursor);
 110
 111    procedure Union (Target : in out Set; Source : Set);
 112
 113    function Union (Left, Right : Set) return Set;
 114
 115    function "or" (Left, Right : Set) return Set renames Union;
 116
 117    procedure Intersection (Target : in out Set; Source : Set);
 118
 119    function Intersection (Left, Right : Set) return Set;
 120
 121    function "and" (Left, Right : Set) return Set renames Intersection;
 122
 123    procedure Difference (Target : in out Set; Source : Set);
 124
 125    function Difference (Left, Right : Set) return Set;
 126
 127    function "-" (Left, Right : Set) return Set renames Difference;
 128
 129    procedure Symmetric_Difference (Target : in out Set; Source : Set);
 130
 131    function Symmetric_Difference (Left, Right : Set) return Set;
 132
 133    function "xor" (Left, Right : Set) return Set
 134      renames Symmetric_Difference;
 135
 136    function Overlap (Left, Right : Set) return Boolean;
 137
 138    function Is_Subset (Subset : Set; Of_Set : Set) return Boolean;
 139
 140    function First (Container : Set) return Cursor;
 141
 142    function Next (Position : Cursor) return Cursor;
 143
 144    procedure Next (Position : in out Cursor);
 145
 146    function Find (Container : Set; Item : Element_Type) return Cursor;
 147
 148    function Contains (Container : Set; Item : Element_Type) return Boolean;
 149
 150    function Has_Element (Position : Cursor) return Boolean;
 151
 152    function Equivalent_Elements (Left, Right : Cursor) return Boolean;
 153
 154    function Equivalent_Elements
 155      (Left  : Cursor;
 156       Right : Element_Type) return Boolean;
 157
 158    function Equivalent_Elements
 159      (Left  : Element_Type;
 160       Right : Cursor) return Boolean;
 161
 162    procedure Iterate
 163      (Container : Set;
 164       Process   : not null access procedure (Position : Cursor));
 165
 166    generic
 167       type Key_Type (<>) is private;
 168
 169       with function Key (Element : Element_Type) return Key_Type;
 170
 171       with function Hash (Key : Key_Type) return Hash_Type;
 172
 173       with function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
 174
 175    package Generic_Keys is
 176
 177       function Key (Position : Cursor) return Key_Type;
 178
 179       function Element (Container : Set; Key : Key_Type) return Element_Type;
 180
 181       procedure Replace           -- TODO: ask Randy why this is still here
 182         (Container : in out Set;
 183          Key       : Key_Type;
 184          New_Item  : Element_Type);
 185
 186       procedure Exclude (Container : in out Set; Key : Key_Type);
 187
 188       procedure Delete (Container : in out Set; Key : Key_Type);
 189
 190       function Find (Container : Set; Key : Key_Type) return Cursor;
 191
 192       function Contains (Container : Set; Key : Key_Type) return Boolean;
 193
 194       procedure Update_Element_Preserving_Key
 195         (Container : in out Set;
 196          Position  : Cursor;
 197          Process   : not null access
 198                        procedure (Element : in out Element_Type));
 199
 200    end Generic_Keys;
 201
 202 private
 203    type Node_Type;
 204    type Node_Access is access Node_Type;
 205
 206    type Element_Access is access Element_Type;
 207
 208    type Node_Type is
 209       limited record
 210          Element : Element_Access;
 211          Next    : Node_Access;
 212       end record;
 213
 214    package HT_Types is new Hash_Tables.Generic_Hash_Table_Types
 215      (Node_Type,
 216       Node_Access);
 217
 218    type Set is new Ada.Finalization.Controlled with record
 219       HT : HT_Types.Hash_Table_Type;
 220    end record;
 221
 222    procedure Adjust (Container : in out Set);
 223
 224    procedure Finalize (Container : in out Set);
 225
 226    use HT_Types;
 227    use Ada.Finalization;
 228
 229    type Set_Access is access all Set;
 230    for Set_Access'Storage_Size use 0;
 231
 232    type Cursor is
 233       record
 234          Container : Set_Access;
 235          Node      : Node_Access;
 236       end record;
 237
 238    No_Element : constant Cursor :=
 239                   (Container => null,
 240                    Node      => null);
 241
 242    use Ada.Streams;
 243
 244    procedure Write
 245      (Stream    : access Root_Stream_Type'Class;
 246       Container : Set);
 247
 248    for Set'Write use Write;
 249
 250    procedure Read
 251      (Stream    : access Root_Stream_Type'Class;
 252       Container : out Set);
 253
 254    for Set'Read use Read;
 255
 256    Empty_Set : constant Set := (Controlled with HT => (null, 0, 0, 0));
 257
 258 end Ada.Containers.Indefinite_Hashed_Sets;