libobjc/configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1994-2023 Free Software Foundation, Inc.
   3 #   Originally contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of GCC.
   6 #
   7 #GCC is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 3, or (at your option)
  10 #any later version.
  11 #
  12 #GCC is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU General Public License
  18 #along with GCC; see the file COPYING3.  If not see
  19 #<http://www.gnu.org/licenses/>.
  20
  21 AC_INIT(package-unused, version-unused,, libobjc)
  22 AC_CONFIG_SRCDIR([objc/objc.h])
  23 AC_CONFIG_MACRO_DIRS([../config] [..])
  24 GCC_TOPLEV_SUBDIRS
  25
  26 # We need the following definitions because AC_PROG_LIBTOOL relies on them
  27 PACKAGE=libobjc
  28 # Version is pulled out to make it a bit easier to change using sed.
  29 VERSION=4:0:0
  30 AC_SUBST(VERSION)
  31
  32 # This works around the fact that libtool configuration may change LD
  33 # for this particular configuration, but some shells, instead of
  34 # keeping the changes in LD private, export them just because LD is
  35 # exported.
  36 ORIGINAL_LD_FOR_MULTILIBS=$LD
  37
  38 # -------
  39 # Options
  40 # -------
  41
  42 # We use these options to decide which functions to include.
  43 AC_ARG_WITH(target-subdir,
  44 [  --with-target-subdir=SUBDIR
  45                            configuring in a subdirectory])
  46 AC_ARG_WITH(cross-host,
  47 [  --with-cross-host=HOST  configuring with a cross compiler])
  48
  49 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  50 AC_ARG_ENABLE(version-specific-runtime-libs,
  51 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  52 [case "$enableval" in
  53  yes) version_specific_libs=yes ;;
  54  no)  version_specific_libs=no ;;
  55  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  56  esac],
  57 [version_specific_libs=no])
  58 AC_MSG_RESULT($version_specific_libs)
  59
  60 # -----------
  61 # Directories
  62 # -----------
  63
  64 # Find the rest of the source tree framework.
  65 AM_ENABLE_MULTILIB(, ..)
  66
  67 AC_CANONICAL_SYSTEM
  68 ACX_NONCANONICAL_TARGET
  69
  70 # Export source directory.
  71 # These need to be absolute paths, yet at the same time need to
  72 # canonicalize only relative paths, because then amd will not unmount
  73 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  74 case $srcdir in
  75   [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
  76   *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  77 esac
  78 AC_SUBST(glibcpp_srcdir)
  79
  80 GCC_WITH_TOOLEXECLIBDIR
  81
  82 # Calculate toolexeclibdir
  83 # Also toolexecdir, though it's only used in toolexeclibdir
  84 case ${version_specific_libs} in
  85   yes)
  86     # Need the gcc compiler version to know where to install libraries
  87     # and header files if --enable-version-specific-runtime-libs option
  88     # is selected.
  89     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
  90     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  91     ;;
  92   no)
  93     if test -n "$with_cross_host" &&
  94        test x"$with_cross_host" != x"no"; then
  95       # Install a library built with a cross compiler in tooldir, not libdir.
  96       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
  97       case ${with_toolexeclibdir} in
  98         no)
  99           toolexeclibdir='$(toolexecdir)/lib'
 100           ;;
 101         *)
 102           toolexeclibdir=${with_toolexeclibdir}
 103           ;;
 104       esac
 105     else
 106       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 107       toolexeclibdir='$(libdir)'
 108     fi
 109     multi_os_directory=`$CC -print-multi-os-directory`
 110     case $multi_os_directory in
 111       .) ;; # Avoid trailing /.
 112       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 113     esac
 114     ;;
 115 esac
 116 AC_SUBST(toolexecdir)
 117 AC_SUBST(toolexeclibdir)
 118
 119 # Figure out if we want to name the include directory and the
 120 #  library name changes differently.
 121 includedirname=include
 122 libsuffix=
 123 case "${host}" in
 124   *-darwin*)
 125     # Darwin is the only target so far that needs a different include directory.
 126     includedirname=include-gnu-runtime
 127     libsuffix=-gnu
 128     ;;
 129 esac
 130 AC_SUBST(includedirname)
 131 AC_SUBST(libsuffix)
 132
 133 AC_CONFIG_HEADERS(config.h)
 134
 135 # --------
 136 # Programs
 137 # --------
 138
 139 GCC_NO_EXECUTABLES
 140
 141 # We must force CC to /not/ be a precious variable; otherwise
 142 # the wrong, non-multilib-adjusted value will be used in multilibs.
 143 # As a side effect, we have to subst CFLAGS ourselves.
 144 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 145 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 146 AC_PROG_CC
 147 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 148
 149 # extra LD Flags which are required for targets
 150 ACX_LT_HOST_FLAGS
 151 case "${host}" in
 152   *-darwin*)
 153     # Darwin needs -single_module when linking libobjc
 154     extra_ldflags_libobjc='$(lt_host_flags) -Wl,-single_module'
 155     ;;
 156   *-cygwin*|*-mingw*)
 157     # Tell libtool to build DLLs on Windows
 158     extra_ldflags_libobjc='$(lt_host_flags)'
 159     ;;
 160 esac
 161 AC_SUBST(extra_ldflags_libobjc)
 162
 163 # Add CET specific flags if CET is enabled
 164 GCC_CET_FLAGS(CET_FLAGS)
 165 XCFLAGS="$XCFLAGS $CET_FLAGS"
 166
 167 AC_SUBST(CFLAGS)
 168 AC_SUBST(XCFLAGS)
 169
 170 AC_CHECK_TOOL(AS, as)
 171 AC_CHECK_TOOL(AR, ar)
 172 AC_CHECK_TOOL(RANLIB, ranlib, :)
 173 AC_PROG_INSTALL
 174
 175 AM_MAINTAINER_MODE
 176
 177 # Enable Win32 DLL on MS Windows - FIXME
 178 AC_LIBTOOL_WIN32_DLL
 179
 180 AC_PROG_LIBTOOL
 181
 182 AM_PROG_CC_C_O
 183
 184 AC_PROG_MAKE_SET
 185
 186 # -------
 187 # Headers
 188 # -------
 189
 190 # Sanity check for the cross-compilation case:
 191 AC_CHECK_HEADER(stdio.h,:,
 192   [AC_MSG_ERROR([Can't find stdio.h.
 193 You must have a usable C system for the target already installed, at least
 194 including headers and, preferably, the library, before you can configure
 195 the Objective C runtime system.  If necessary, install gcc now with
 196 \`LANGUAGES=c', then the target library, then build with \`LANGUAGES=objc'.])])
 197
 198 AC_HEADER_STDC
 199
 200 AC_CHECK_HEADERS(sched.h)
 201
 202 # -----------
 203 # Miscellanea
 204 # -----------
 205
 206 # Check if we have thread-local storage
 207 GCC_CHECK_TLS
 208
 209 gt_BITFIELD_TYPE_MATTERS
 210
 211 # -----------
 212 # boehm-gc
 213 # -----------
 214
 215 AC_ARG_ENABLE(objc-gc,
 216 [AS_HELP_STRING([--enable-objc-gc],
 217                 [enable use of Boehm's garbage collector with the
 218                  GNU Objective-C runtime])],,enable_objc_gc=no)
 219 AC_ARG_WITH([target-bdw-gc],
 220 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
 221                 [specify prefix directory for installed bdw-gc package.
 222                  Equivalent to --with-target-bdw-gc-include=PATH/include
 223                  plus --with-target-bdw-gc-lib=PATH/lib])])
 224 AC_ARG_WITH([target-bdw-gc-include],
 225 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
 226                 [specify directories for installed bdw-gc include files])])
 227 AC_ARG_WITH([target-bdw-gc-lib],
 228 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
 229                 [specify directories for installed bdw-gc library])])
 230
 231 case "$enable_objc_gc" in
 232 no)
 233   use_bdw_gc=no
 234   ;;
 235 *)
 236   AC_MSG_CHECKING([for bdw garbage collector])
 237   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
 238     dnl no bdw-gw options, assuming bdw-gc in default locations
 239     BDW_GC_CFLAGS=
 240     BDW_GC_LIBS="-lgc"
 241   else
 242     dnl bdw-gw options passed by configure flags
 243     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
 244       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
 245     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
 246       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
 247     else
 248       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
 249     fi
 250     mldir=`${CC-gcc} --print-multi-directory 2>/dev/null`
 251     bdw_val=
 252     if test "x$with_target_bdw_gc" != x; then
 253       for i in `echo $with_target_bdw_gc | tr ',' ' '`; do
 254         case "$i" in
 255           *=*) sd=${i%%=*}; d=${i#*=} ;;
 256           *) sd=.; d=$i ;;
 257         esac
 258         if test "$mldir" = "$sd"; then
 259           bdw_val=$d
 260         fi
 261       done
 262       if test "x$bdw_val" = x; then
 263         AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc])
 264       fi
 265       bdw_inc_dir="$bdw_val/include"
 266       bdw_lib_dir="$bdw_val/lib"
 267     fi
 268     bdw_val=
 269     if test "x$with_target_bdw_gc_include" != x; then
 270       for i in `echo $with_target_bdw_gc_include | tr ',' ' '`; do
 271         case "$i" in
 272           *=*) sd=${i%%=*}; d=${i#*=} ;;
 273           *) sd=.; d=$i; fallback=$i ;;
 274         esac
 275         if test "$mldir" = "$sd"; then
 276           bdw_val=$d
 277         fi
 278       done
 279       if test "x$bdw_val" = x && test "x$bdw_inc_dir" = x && test "x$fallback" != x; then
 280         bdw_inc_dir="$fallback"
 281       elif test "x$bdw_val" = x; then
 282         AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-include])
 283       else
 284         bdw_inc_dir="$bdw_val"
 285       fi
 286     fi
 287     bdw_val=
 288     if test "x$with_target_bdw_gc_lib" != x; then
 289       for i in `echo $with_target_bdw_gc_lib | tr ',' ' '`; do
 290         case "$i" in
 291           *=*) sd=${i%%=*}; d=${i#*=} ;;
 292           *) sd=.; d=$i ;;
 293         esac
 294         if test "$mldir" = "$sd"; then
 295           bdw_val=$d
 296         fi
 297       done
 298       if test "x$bdw_val" = x; then
 299         AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-lib])
 300       fi
 301       bdw_lib_dir="$bdw_val"
 302     fi
 303     if test "x$bdw_inc_dir" = x; then
 304       AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-include])
 305     fi
 306     if test "x$bdw_lib_dir" = x; then
 307       AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-lib])
 308     fi
 309     BDW_GC_CFLAGS="-I$bdw_inc_dir"
 310     if test -f $bdw_lib_dir/libgc.la; then
 311       BDW_GC_LIBS="$bdw_lib_dir/libgc.la"
 312     else
 313       BDW_GC_LIBS="-L$bdw_lib_dir -lgc"
 314     fi
 315     AC_MSG_RESULT([found])
 316   fi
 317
 318   case "$BDW_GC_LIBS" in
 319   *libgc.la)
 320     use_bdw_gc=yes
 321     ;;
 322   *)
 323     AC_MSG_CHECKING([for system boehm-gc])
 324     save_CFLAGS=$CFLAGS
 325     save_LIBS=$LIBS
 326     CFLAGS="$CFLAGS $BDW_GC_CFLAGS"
 327     LIBS="$LIBS $BDW_GC_LIBS"
 328     dnl the link test is not good enough for ARM32 multilib detection,
 329     dnl first check to link, then to run
 330     AC_LINK_IFELSE(
 331       [AC_LANG_PROGRAM([#include <gc/gc.h>],[GC_init()])],
 332       [
 333         AC_RUN_IFELSE([AC_LANG_SOURCE([[
 334           #include <gc/gc.h>
 335           int main() {
 336             GC_init();
 337             return 0;
 338           }
 339           ]])],
 340           [system_bdw_gc_found=yes],
 341           [system_bdw_gc_found=no],
 342           dnl assume no system boehm-gc for cross builds ...
 343           [system_bdw_gc_found=no]
 344         )
 345       ],
 346       [system_bdw_gc_found=no])
 347     CFLAGS=$save_CFLAGS
 348     LIBS=$save_LIBS
 349     if test x$enable_objc_gc = xauto && test x$system_bdw_gc_found = xno; then
 350       AC_MSG_WARN([system bdw-gc not found, not building libobjc_gc])
 351       use_bdw_gc=no
 352     elif test x$enable_objc_gc = xyes && test x$system_bdw_gc_found = xno; then
 353       AC_MSG_ERROR([system bdw-gc required but not found])
 354     else
 355       use_bdw_gc=yes
 356       AC_MSG_RESULT([found])
 357     fi
 358   esac
 359 esac
 360
 361 if test "$use_bdw_gc" = no; then
 362   OBJC_GCFLAGS=''
 363   OBJC_BOEHM_GC=''
 364   OBJC_BOEHM_GC_INCLUDES=''
 365   OBJC_BOEHM_GC_LIBS=''
 366 else
 367   OBJC_GCFLAGS='-DOBJC_WITH_GC=1'
 368   OBJC_BOEHM_GC='libobjc_gc$(libsuffix).la'
 369   OBJC_BOEHM_GC_INCLUDES=$BDW_GC_CFLAGS
 370   OBJC_BOEHM_GC_LIBS=$BDW_GC_LIBS
 371 fi
 372 AC_SUBST(OBJC_GCFLAGS)
 373 AC_SUBST(OBJC_BOEHM_GC)
 374 AC_SUBST(OBJC_BOEHM_GC_INCLUDES)
 375 AC_SUBST(OBJC_BOEHM_GC_LIBS)
 376
 377 # Determine what GCC version number to use in filesystem paths.
 378 GCC_BASE_VER
 379
 380 # ------
 381 # Output
 382 # ------
 383
 384 if test ${multilib} = yes; then
 385   multilib_arg="--enable-multilib"
 386 else
 387   multilib_arg=
 388 fi
 389
 390 AC_CONFIG_FILES([Makefile])
 391 AC_OUTPUT