gcc/ada/s-stausa.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                GNU ADA RUN-TIME LIBRARY (GNARL) COMPONENTS               --
   4 --                                                                          --
   5 --                   S Y S T E M - S T A C K _ U S A G E                    --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --         Copyright (C) 2004-2009, Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNARL was developed by the GNARL team at Florida State University.       --
  28 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 with System;
  33 with System.Storage_Elements;
  34 with System.Address_To_Access_Conversions;
  35 with Interfaces;
  36
  37 package System.Stack_Usage is
  38    pragma Preelaborate;
  39
  40    package SSE renames System.Storage_Elements;
  41
  42    subtype Stack_Address is SSE.Integer_Address;
  43    --  Address on the stack
  44
  45    function To_Stack_Address
  46      (Value : System.Address) return Stack_Address
  47       renames System.Storage_Elements.To_Integer;
  48
  49    Task_Name_Length : constant := 32;
  50    --  The maximum length of task name displayed.
  51    --  ??? Consider merging this variable with Max_Task_Image_Length.
  52
  53    type Task_Result is record
  54       Task_Name : String (1 .. Task_Name_Length);
  55
  56       Value : Natural;
  57       --  Amount of stack used. The value is calculated on the basis of the
  58       --  mechanism used by GNAT to allocate it, and it is NOT a precise value.
  59
  60       Variation : Natural;
  61       --  Possible variation in the amount of used stack. The real stack usage
  62       --  may vary in the range Value +/- Variation
  63
  64       Max_Size : Natural;
  65    end record;
  66
  67    type Result_Array_Type is array (Positive range <>) of Task_Result;
  68
  69    type Stack_Analyzer is private;
  70    --  Type of the stack analyzer tool. It is used to fill a portion of the
  71    --  stack with Pattern, and to compute the stack used after some execution.
  72
  73    --  Usage:
  74
  75    --  A typical use of the package is something like:
  76
  77    --  A : Stack_Analyzer;
  78
  79    --  task T is
  80    --     pragma Storage_Size (A_Storage_Size);
  81    --  end T;
  82
  83    --  [...]
  84
  85    --     Bottom_Of_Stack : aliased Integer;
  86    --     --  Bottom_Of_Stack'Address will be used as an approximation of
  87    --     --  the bottom of stack. A good practise is to avoid allocating
  88    --     --  other local variables on this stack, as it would degrade
  89    --     --  the quality of this approximation.
  90
  91    --  begin
  92    --     Initialize_Analyzer (A,
  93    --                          "Task t",
  94    --                          A_Storage_Size - A_Guard,
  95    --                          A_Guard
  96    --                          To_Stack_Address (Bottom_Of_Stack'Address));
  97    --     Fill_Stack (A);
  98    --     Some_User_Code;
  99    --     Compute_Result (A);
 100    --     Report_Result (A);
 101    --  end T;
 102
 103    --  Errors:
 104    --
 105    --  We are instrumenting the code to measure the stack used by the user
 106    --  code. This method has a number of systematic errors, but several methods
 107    --  can be used to evaluate or reduce those errors. Here are those errors
 108    --  and the strategy that we use to deal with them:
 109
 110    --  Bottom offset:
 111
 112    --     Description: The procedure used to fill the stack with a given
 113    --       pattern will itself have a stack frame. The value of the stack
 114    --       pointer in this procedure is, therefore, different from the value
 115    --       before the call to the instrumentation procedure.
 116
 117    --     Strategy: The user of this package should measure the bottom of stack
 118    --       before the call to Fill_Stack and pass it in parameter.
 119
 120    --  Instrumentation threshold at writing:
 121
 122    --     Description: The procedure used to fill the stack with a given
 123    --       pattern will itself have a stack frame.  Therefore, it will
 124    --       fill the stack after this stack frame. This part of the stack will
 125    --       appear as used in the final measure.
 126
 127    --     Strategy: As the user passes the value of the bottom of stack to
 128    --       the instrumentation to deal with the bottom offset error, and as
 129    --       the instrumentation procedure knows where the pattern filling start
 130    --       on the stack, the difference between the two values is the minimum
 131    --       stack usage that the method can measure. If, when the results are
 132    --       computed, the pattern zone has been left untouched, we conclude
 133    --       that the stack usage is inferior to this minimum stack usage.
 134
 135    --  Instrumentation threshold at reading:
 136
 137    --    Description: The procedure used to read the stack at the end of the
 138    --      execution clobbers the stack by allocating its stack frame. If this
 139    --      stack frame is bigger than the total stack used by the user code at
 140    --      this point, it will increase the measured stack size.
 141
 142    --    Strategy: We could augment this stack frame and see if it changes the
 143    --      measure. However, this error should be negligible.
 144
 145    --   Pattern zone overflow:
 146
 147    --     Description: The stack grows outer than the topmost bound of the
 148    --       pattern zone. In that case, the topmost region modified in the
 149    --       pattern is not the maximum value of the stack pointer during the
 150    --       execution.
 151
 152    --     Strategy: At the end of the execution, the difference between the
 153    --       topmost memory region modified in the pattern zone and the
 154    --       topmost bound of the pattern zone can be understood as the
 155    --       biggest allocation that the method could have detect, provided
 156    --       that there is no "Untouched allocated zone" error and no "Pattern
 157    --       usage in user code" error. If no object in the user code is likely
 158    --       to have this size, this is not likely to happen.
 159
 160    --   Pattern usage in user code:
 161
 162    --     Description: The pattern can be found in the object of the user code.
 163    --       Therefore, the address space where this object has been allocated
 164    --       will appear as untouched.
 165
 166    --     Strategy: Choose a pattern that is uncommon. 16#0000_0000# is the
 167    --       worst choice; 16#DEAD_BEEF# can be a good one. A good choice is an
 168    --       address which is not a multiple of 2, and which is not in the
 169    --       target address space. You can also change the pattern to see if it
 170    --       changes the measure. Note that this error *very* rarely influence
 171    --       the measure of the total stack usage: to have some influence, the
 172    --       pattern has to be used in the object that has been allocated on the
 173    --       topmost address of the used stack.
 174
 175    --   Stack overflow:
 176
 177    --     Description: The pattern zone does not fit on the stack. This may
 178    --       lead to an erroneous execution.
 179
 180    --     Strategy: Specify a storage size that is bigger than the size of the
 181    --       pattern. 2 times bigger should be enough.
 182
 183    --   Augmentation of the user stack frames:
 184
 185    --     Description: The use of instrumentation object or procedure may
 186    --       augment the stack frame of the caller.
 187
 188    --     Strategy: Do *not* inline the instrumentation procedures. Do *not*
 189    --       allocate the Stack_Analyzer object on the stack.
 190
 191    --   Untouched allocated zone:
 192
 193    --     Description: The user code may allocate objects that it will never
 194    --       touch. In that case, the pattern will not be changed.
 195
 196    --     Strategy: There are no way to detect this error. Fortunately, this
 197    --       error is really rare, and it is most probably a bug in the user
 198    --       code, e.g. some uninitialized variable. It is (most of the time)
 199    --       harmless: it influences the measure only if the untouched allocated
 200    --       zone happens to be located at the topmost value of the stack
 201    --       pointer for the whole execution.
 202
 203    procedure Initialize (Buffer_Size : Natural);
 204    pragma Export (C, Initialize, "__gnat_stack_usage_initialize");
 205    --  Initializes the size of the buffer that stores the results. Only the
 206    --  first Buffer_Size results are stored. Any results that do not fit in
 207    --  this buffer will be displayed on the fly.
 208
 209    procedure Fill_Stack (Analyzer : in out Stack_Analyzer);
 210    --  Fill an area of the stack with the pattern Analyzer.Pattern. The size
 211    --  of this area is Analyzer.Size. After the call to this procedure,
 212    --  the memory will look like that:
 213    --
 214    --                                                             Stack growing
 215    --  ----------------------------------------------------------------------->
 216    --  |<---------------------->|<----------------------------------->|
 217    --  |  Stack frame           | Memory filled with Analyzer.Pattern |
 218    --  |  of Fill_Stack         |                                     |
 219    --  |  (deallocated at       |                                     |
 220    --  |  the end of the call)  |                                     |
 221    --  ^                        |                                     |
 222    --  Analyzer.Bottom_Of_Stack ^                                     |
 223    --                    Analyzer.Bottom_Pattern_Mark                 ^
 224    --                                            Analyzer.Top_Pattern_Mark
 225
 226    procedure Initialize_Analyzer
 227      (Analyzer         : in out Stack_Analyzer;
 228       Task_Name        : String;
 229       My_Stack_Size    : Natural;
 230       Max_Pattern_Size : Natural;
 231       Bottom           : Stack_Address;
 232       Pattern          : Interfaces.Unsigned_32 := 16#DEAD_BEEF#);
 233    --  Should be called before any use of a Stack_Analyzer, to initialize it.
 234    --  Max_Pattern_Size is the size of the pattern zone, might be smaller than
 235    --  the full stack size in order to take into account e.g. the secondary
 236    --  stack and a guard against overflow. The actual size taken will be
 237    --  readjusted with data already used at the time the stack is actually
 238    --  filled.
 239
 240    Is_Enabled : Boolean := False;
 241    --  When this flag is true, then stack analysis is enabled
 242
 243    procedure Compute_Result (Analyzer : in out Stack_Analyzer);
 244    --  Read the pattern zone and deduce the stack usage. It should be called
 245    --  from the same frame as Fill_Stack. If Analyzer.Probe is not null, an
 246    --  array of Unsigned_32 with Analyzer.Probe elements is allocated on
 247    --  Compute_Result's stack frame. Probe can be used to detect  the error:
 248    --  "instrumentation threshold at reading". See above. After the call
 249    --  to this procedure, the memory will look like:
 250    --
 251    --                                                             Stack growing
 252    --  ----------------------------------------------------------------------->
 253    --  |<---------------------->|<-------------->|<--------->|<--------->|
 254    --  |  Stack frame           | Array of       | used      |  Memory   |
 255    --  |  of Compute_Result     | Analyzer.Probe | during    |   filled  |
 256    --  |  (deallocated at       | elements       |  the      |    with   |
 257    --  |  the end of the call)  |                | execution |  pattern  |
 258    --  |                        ^                |           |           |
 259    --  |                   Bottom_Pattern_Mark   |           |           |
 260    --  |                                                     |           |
 261    --  |<---------------------------------------------------->           |
 262    --                  Stack used                                        ^
 263    --                                                     Top_Pattern_Mark
 264
 265    procedure Report_Result (Analyzer : Stack_Analyzer);
 266    --  Store the results of the computation in memory, at the address
 267    --  corresponding to the symbol __gnat_stack_usage_results. This is not
 268    --  done inside Compute_Result in order to use as less stack as possible
 269    --  within a task.
 270
 271    procedure Output_Results;
 272    --  Print the results computed so far on the standard output. Should be
 273    --  called when all tasks are dead.
 274
 275    pragma Export (C, Output_Results, "__gnat_stack_usage_output_results");
 276
 277 private
 278
 279    package Unsigned_32_Addr is
 280      new System.Address_To_Access_Conversions (Interfaces.Unsigned_32);
 281
 282    subtype Pattern_Type is Interfaces.Unsigned_32;
 283    Bytes_Per_Pattern : constant := Pattern_Type'Object_Size / Storage_Unit;
 284
 285    type Stack_Analyzer is record
 286       Task_Name : String (1 .. Task_Name_Length);
 287       --  Name of the task
 288
 289       Stack_Size : Natural;
 290       --  Entire size of the analyzed stack
 291
 292       Pattern_Size : Natural;
 293       --  Size of the pattern zone
 294
 295       Pattern : Pattern_Type;
 296       --  Pattern used to recognize untouched memory
 297
 298       Bottom_Pattern_Mark : Stack_Address;
 299       --  Bound of the pattern area on the stack closest to the bottom
 300
 301       Top_Pattern_Mark : Stack_Address;
 302       --  Topmost bound of the pattern area on the stack
 303
 304       Topmost_Touched_Mark : Stack_Address;
 305       --  Topmost address of the pattern area whose value it is pointing
 306       --  at has been modified during execution. If the systematic error are
 307       --  compensated, it is the topmost value of the stack pointer during
 308       --  the execution.
 309
 310       Bottom_Of_Stack : Stack_Address;
 311       --  Address of the bottom of the stack, as given by the caller of
 312       --  Initialize_Analyzer.
 313
 314       Stack_Overlay_Address : System.Address;
 315       --  Address of the stack abstraction object we overlay over a
 316       --  task's real stack, typically a pattern-initialized array.
 317
 318       Result_Id : Positive;
 319       --  Id of the result. If less than value given to gnatbind -u corresponds
 320       --  to the location in the result array of result for the current task.
 321    end record;
 322
 323    Environment_Task_Analyzer : Stack_Analyzer;
 324
 325    Compute_Environment_Task  : Boolean;
 326
 327    type Result_Array_Ptr is access all Result_Array_Type;
 328
 329    Result_Array : Result_Array_Ptr;
 330    pragma Export (C, Result_Array, "__gnat_stack_usage_results");
 331    --  Exported in order to have an easy accessible symbol in when debugging
 332
 333    Next_Id : Positive := 1;
 334    --  Id of the next stack analyzer
 335
 336    function Stack_Size
 337      (SP_Low  : Stack_Address;
 338       SP_High : Stack_Address) return Natural;
 339    pragma Inline (Stack_Size);
 340    --  Return the size of a portion of stack delimited by SP_High and SP_Low
 341    --  (), i.e. the difference between SP_High and SP_Low. The storage element
 342    --  pointed by SP_Low is not included in the size. Inlined to reduce the
 343    --  size of the stack used by the instrumentation code.
 344
 345 end System.Stack_Usage;