gcc/ada/s-os_lib.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                        S Y S T E M . O S _ L I B                         --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1995-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  Operating system interface facilities
  33
  34 --  This package contains types and procedures for interfacing to the
  35 --  underlying OS. It is used by the GNAT compiler and by tools associated
  36 --  with the GNAT compiler, and therefore works for the various operating
  37 --  systems to which GNAT has been ported. This package will undoubtedly grow
  38 --  as new services are needed by various tools.
  39
  40 --  This package tends to use fairly low-level Ada in order to not bring in
  41 --  large portions of the RTL. For example, functions return access to string
  42 --  as part of avoiding functions returning unconstrained types.
  43
  44 --  Except where specifically noted, these routines are portable across all
  45 --  GNAT implementations on all supported operating systems.
  46
  47 --  Note: this package is in the System hierarchy so that it can be directly
  48 --  be used by other predefined packages. User access to this package is via
  49 --  a renaming of this package in GNAT.OS_Lib (file g-os_lib.ads).
  50
  51 pragma Compiler_Unit;
  52
  53 with System;
  54 with System.Strings;
  55
  56 package System.OS_Lib is
  57    pragma Elaborate_Body (OS_Lib);
  58
  59    -----------------------
  60    -- String Operations --
  61    -----------------------
  62
  63    --  These are reexported from package Strings (which was introduced to
  64    --  avoid different packages declaring different types unnecessarily).
  65    --  See package System.Strings for details.
  66
  67    subtype String_Access is Strings.String_Access;
  68
  69    function "=" (Left, Right : String_Access) return Boolean
  70      renames Strings."=";
  71
  72    procedure Free (X : in out String_Access) renames Strings.Free;
  73
  74    subtype String_List is Strings.String_List;
  75
  76    function "=" (Left, Right : String_List) return Boolean
  77      renames Strings."=";
  78
  79    function "&" (Left : String_Access; Right : String_Access)
  80      return String_List renames Strings."&";
  81    function "&" (Left : String_Access; Right : String_List)
  82      return String_List renames Strings."&";
  83    function "&" (Left : String_List; Right : String_Access)
  84      return String_List renames Strings."&";
  85    function "&" (Left : String_List; Right : String_List)
  86      return String_List renames Strings."&";
  87
  88    subtype String_List_Access is Strings.String_List_Access;
  89
  90    function "=" (Left, Right : String_List_Access) return Boolean
  91      renames Strings."=";
  92
  93    procedure Free (Arg : in out String_List_Access)
  94      renames Strings.Free;
  95
  96    ---------------------
  97    -- Time/Date Stuff --
  98    ---------------------
  99
 100    type OS_Time is private;
 101    --  The OS's notion of time is represented by the private type OS_Time.
 102    --  This is the type returned by the File_Time_Stamp functions to obtain
 103    --  the time stamp of a specified file. Functions and a procedure (modeled
 104    --  after the similar subprograms in package Calendar) are provided for
 105    --  extracting information from a value of this type. Although these are
 106    --  called GM, the intention is not that they provide GMT times in all
 107    --  cases but rather the actual (time-zone independent) time stamp of the
 108    --  file (of course in Unix systems, this *is* in GMT form).
 109
 110    Invalid_Time : constant OS_Time;
 111    --  A special unique value used to flag an invalid time stamp value
 112
 113    subtype Year_Type   is Integer range 1900 .. 2099;
 114    subtype Month_Type  is Integer range    1 ..   12;
 115    subtype Day_Type    is Integer range    1 ..   31;
 116    subtype Hour_Type   is Integer range    0 ..   23;
 117    subtype Minute_Type is Integer range    0 ..   59;
 118    subtype Second_Type is Integer range    0 ..   59;
 119    --  Declarations similar to those in Calendar, breaking down the time
 120
 121    function Current_Time return OS_Time;
 122    --  Return the system clock value as OS_Time
 123
 124    function GM_Year    (Date : OS_Time) return Year_Type;
 125    function GM_Month   (Date : OS_Time) return Month_Type;
 126    function GM_Day     (Date : OS_Time) return Day_Type;
 127    function GM_Hour    (Date : OS_Time) return Hour_Type;
 128    function GM_Minute  (Date : OS_Time) return Minute_Type;
 129    function GM_Second  (Date : OS_Time) return Second_Type;
 130    --  Functions to extract information from OS_Time value
 131
 132    function "<"  (X, Y : OS_Time) return Boolean;
 133    function ">"  (X, Y : OS_Time) return Boolean;
 134    function ">=" (X, Y : OS_Time) return Boolean;
 135    function "<=" (X, Y : OS_Time) return Boolean;
 136    --  Basic comparison operators on OS_Time with obvious meanings. Note that
 137    --  these have Intrinsic convention, so for example it is not permissible
 138    --  to create accesses to any of these functions.
 139
 140    procedure GM_Split
 141      (Date   : OS_Time;
 142       Year   : out Year_Type;
 143       Month  : out Month_Type;
 144       Day    : out Day_Type;
 145       Hour   : out Hour_Type;
 146       Minute : out Minute_Type;
 147       Second : out Second_Type);
 148    --  Analogous to the Split routine in Ada.Calendar, takes an OS_Time and
 149    --  provides a representation of it as a set of component parts, to be
 150    --  interpreted as a date point in UTC.
 151
 152    ----------------
 153    -- File Stuff --
 154    ----------------
 155
 156    --  These routines give access to the open/creat/close/read/write level of
 157    --  I/O routines in the typical C library (these functions are not part of
 158    --  the ANSI C standard, but are typically available in all systems). See
 159    --  also package Interfaces.C_Streams for access to the stream level
 160    --  routines.
 161
 162    --  Note on file names. If a file name is passed as type String in any of
 163    --  the following specifications, then the name is a normal Ada string and
 164    --  need not be NUL-terminated. However, a trailing NUL character is
 165    --  permitted, and will be ignored (more accurately, the NUL and any
 166    --  characters that follow it will be ignored).
 167
 168    type File_Descriptor is new Integer;
 169    --  Corresponds to the int file handle values used in the C routines
 170
 171    Standin  : constant File_Descriptor := 0;
 172    Standout : constant File_Descriptor := 1;
 173    Standerr : constant File_Descriptor := 2;
 174    --  File descriptors for standard input output files
 175
 176    Invalid_FD : constant File_Descriptor := -1;
 177    --  File descriptor returned when error in opening/creating file;
 178
 179    type Mode is (Binary, Text);
 180    for Mode'Size use Integer'Size;
 181    for Mode use (Binary => 0, Text => 1);
 182    --  Used in all the Open and Create calls to specify if the file is to be
 183    --  opened in binary mode or text mode. In systems like Unix, this has no
 184    --  effect, but in systems capable of text mode translation, the use of
 185    --  Text as the mode parameter causes the system to do CR/LF translation
 186    --  and also to recognize the DOS end of file character on input. The use
 187    --  of Text where appropriate allows programs to take a portable Unix view
 188    --  of DOS-format files and process them appropriately.
 189
 190    function Open_Read
 191      (Name  : String;
 192       Fmode : Mode) return File_Descriptor;
 193    --  Open file Name for reading, returning file descriptor File descriptor
 194    --  returned is Invalid_FD if file cannot be opened.
 195
 196    function Open_Read_Write
 197      (Name  : String;
 198       Fmode : Mode) return File_Descriptor;
 199    --  Open file Name for both reading and writing, returning file descriptor.
 200    --  File descriptor returned is Invalid_FD if file cannot be opened.
 201
 202    function Create_File
 203      (Name  : String;
 204       Fmode : Mode) return File_Descriptor;
 205    --  Creates new file with given name for writing, returning file descriptor
 206    --  for subsequent use in Write calls. File descriptor returned is
 207    --  Invalid_FD if file cannot be successfully created.
 208
 209    function Create_Output_Text_File (Name : String) return File_Descriptor;
 210    --  Creates new text file with given name suitable to redirect standard
 211    --  output, returning file descriptor. File descriptor returned is
 212    --  Invalid_FD if file cannot be successfully created.
 213
 214    function Create_New_File
 215      (Name  : String;
 216       Fmode : Mode) return File_Descriptor;
 217    --  Create new file with given name for writing, returning file descriptor
 218    --  for subsequent use in Write calls. This differs from Create_File in
 219    --  that it fails if the file already exists. File descriptor returned is
 220    --  Invalid_FD if the file exists or cannot be created.
 221
 222    Temp_File_Len : constant Integer := 12;
 223    --  Length of name returned by Create_Temp_File call (GNAT-XXXXXX & NUL)
 224
 225    subtype Temp_File_Name is String (1 .. Temp_File_Len);
 226    --  String subtype set by Create_Temp_File
 227
 228    procedure Create_Temp_File
 229      (FD   : out File_Descriptor;
 230       Name : out Temp_File_Name);
 231    --  Create and open for writing a temporary file in the current working
 232    --  directory. The name of the file and the File Descriptor are returned.
 233    --  The File Descriptor returned is Invalid_FD in the case of failure. No
 234    --  mode parameter is provided. Since this is a temporary file, there is no
 235    --  point in doing text translation on it.
 236    --
 237    --  On some operating systems, the maximum number of temp files that can be
 238    --  created with this procedure may be limited. When the maximum is reached,
 239    --  this procedure returns Invalid_FD. On some operating systems, there may
 240    --  be a race condition between processes trying to create temp files at the
 241    --  same time in the same directory using this procedure.
 242
 243    procedure Create_Temp_File
 244      (FD   : out File_Descriptor;
 245       Name : out String_Access);
 246    --  Create and open for writing a temporary file in the current working
 247    --  directory. The name of the file and the File Descriptor are returned.
 248    --  It is the responsibility of the caller to deallocate the access value
 249    --  returned in Name.
 250    --
 251    --  The file is opened in binary mode (no text translation).
 252    --
 253    --  This procedure will always succeed if the current working directory is
 254    --  writable. If the current working directory is not writable, then
 255    --  Invalid_FD is returned for the file descriptor and null for the Name.
 256    --  There is no race condition problem between processes trying to create
 257    --  temp files at the same time in the same directory.
 258
 259    procedure Create_Temp_Output_File
 260      (FD   : out File_Descriptor;
 261       Name : out String_Access);
 262    --  Create and open for writing a temporary file in the current working
 263    --  directory suitable to redirect standard output. The name of the file and
 264    --  the File Descriptor are returned. It is the responsibility of the caller
 265    --  to deallocate the access value returned in Name.
 266    --
 267    --  The file is opened in text mode
 268    --
 269    --  This procedure will always succeed if the current working directory is
 270    --  writable. If the current working directory is not writable, then
 271    --  Invalid_FD is returned for the file descriptor and null for the Name.
 272    --  There is no race condition problem between processes trying to create
 273    --  temp files at the same time in the same directory.
 274
 275    procedure Close (FD : File_Descriptor; Status : out Boolean);
 276    --  Close file referenced by FD. Status is False if the underlying service
 277    --  failed. Reasons for failure include: disk full, disk quotas exceeded
 278    --  and invalid file descriptor (the file may have been closed twice).
 279
 280    procedure Close (FD : File_Descriptor);
 281    --  Close file referenced by FD. This form is used when the caller wants to
 282    --  ignore any possible error (see above for error cases).
 283
 284    procedure Set_Close_On_Exec
 285      (FD            : File_Descriptor;
 286       Close_On_Exec : Boolean;
 287       Status        : out Boolean);
 288    --  When Close_On_Exec is True, mark FD to be closed automatically when new
 289    --  program is executed by the calling process (i.e. prevent FD from being
 290    --  inherited by child processes). When Close_On_Exec is False, mark FD to
 291    --  not be closed on exec (i.e. allow it to be inherited). Status is False
 292    --  if the operation could not be performed.
 293
 294    procedure Delete_File (Name : String; Success : out Boolean);
 295    --  Deletes file. Success is set True or False indicating if the delete is
 296    --  successful.
 297
 298    procedure Rename_File
 299      (Old_Name : String;
 300       New_Name : String;
 301       Success  : out Boolean);
 302    --  Rename a file. Success is set True or False indicating if the rename is
 303    --  successful or not.
 304
 305    --  The following defines the mode for the Copy_File procedure below. Note
 306    --  that "time stamps and other file attributes" in the descriptions below
 307    --  refers to the creation and last modification times, and also the file
 308    --  access (read/write/execute) status flags.
 309
 310    type Copy_Mode is
 311      (Copy,
 312       --  Copy the file. It is an error if the target file already exists. The
 313       --  time stamps and other file attributes are preserved in the copy.
 314
 315       Overwrite,
 316       --  If the target file exists, the file is replaced otherwise the file
 317       --  is just copied. The time stamps and other file attributes are
 318       --  preserved in the copy.
 319
 320       Append);
 321       --  If the target file exists, the contents of the source file is
 322       --  appended at the end. Otherwise the source file is just copied. The
 323       --  time stamps and other file attributes are preserved if the
 324       --  destination file does not exist.
 325
 326    type Attribute is
 327      (Time_Stamps,
 328       --  Copy time stamps from source file to target file. All other
 329       --  attributes are set to normal default values for file creation.
 330
 331       Full,
 332       --  All attributes are copied from the source file to the target file.
 333       --  This includes the timestamps, and for example also includes
 334       --  read/write/execute attributes in Unix systems.
 335
 336       None);
 337       --  No attributes are copied. All attributes including the time stamp
 338       --  values are set to normal default values for file creation.
 339
 340    --  Note: The default is Time_Stamps, which corresponds to the normal
 341    --  default on Windows style systems. Full corresponds to the typical
 342    --  effect of "cp -p" on Unix systems, and None corresponds to the typical
 343    --  effect of "cp" on Unix systems.
 344
 345    --  Note: Time_Stamps and Full are not supported on VMS and VxWorks
 346
 347    procedure Copy_File
 348      (Name     : String;
 349       Pathname : String;
 350       Success  : out Boolean;
 351       Mode     : Copy_Mode := Copy;
 352       Preserve : Attribute := Time_Stamps);
 353    --  Copy a file. Name must designate a single file (no wild cards allowed).
 354    --  Pathname can be a filename or directory name. In the latter case Name
 355    --  is copied into the directory preserving the same file name. Mode
 356    --  defines the kind of copy, see above with the default being a normal
 357    --  copy in which the target file must not already exist. Success is set to
 358    --  True or False indicating if the copy is successful (depending on the
 359    --  specified Mode).
 360    --
 361    --  Note: this procedure is only supported to a very limited extent on VMS.
 362    --  The only supported mode is Overwrite, and the only supported value for
 363    --  Preserve is None, resulting in the default action which for Overwrite
 364    --  is to leave attributes unchanged. Furthermore, the copy only works for
 365    --  simple text files.
 366
 367    procedure Copy_Time_Stamps (Source, Dest : String; Success : out Boolean);
 368    --  Copy Source file time stamps (last modification and last access time
 369    --  stamps) to Dest file. Source and Dest must be valid filenames,
 370    --  furthermore Dest must be writable. Success will be set to True if the
 371    --  operation was successful and False otherwise.
 372    --
 373    --  Note: this procedure is not supported on VMS and VxWorks. On these
 374    --  platforms, Success is always set to False.
 375
 376    function Read
 377      (FD : File_Descriptor;
 378       A  : System.Address;
 379       N  : Integer) return Integer;
 380    --  Read N bytes to address A from file referenced by FD. Returned value is
 381    --  count of bytes actually read, which can be less than N at EOF.
 382
 383    function Write
 384      (FD : File_Descriptor;
 385       A  : System.Address;
 386       N  : Integer) return Integer;
 387    --  Write N bytes from address A to file referenced by FD. The returned
 388    --  value is the number of bytes written, which can be less than N if a
 389    --  disk full condition was detected.
 390
 391    Seek_Cur : constant := 1;
 392    Seek_End : constant := 2;
 393    Seek_Set : constant := 0;
 394    --  Used to indicate origin for Lseek call
 395
 396    procedure Lseek
 397      (FD     : File_Descriptor;
 398       offset : Long_Integer;
 399       origin : Integer);
 400    pragma Import (C, Lseek, "__gnat_lseek");
 401    --  Sets the current file pointer to the indicated offset value, relative
 402    --  to the current position (origin = SEEK_CUR), end of file (origin =
 403    --  SEEK_END), or start of file (origin = SEEK_SET).
 404
 405    function File_Length (FD : File_Descriptor) return Long_Integer;
 406    pragma Import (C, File_Length, "__gnat_file_length");
 407    --  Get length of file from file descriptor FD
 408
 409    function File_Time_Stamp (Name : String) return OS_Time;
 410    --  Given the name of a file or directory, Name, obtains and returns the
 411    --  time stamp. This function can be used for an unopened file. Returns
 412    --  Invalid_Time is Name doesn't correspond to an existing file.
 413
 414    function File_Time_Stamp (FD : File_Descriptor) return OS_Time;
 415    --  Get time stamp of file from file descriptor FD Returns Invalid_Time is
 416    --  FD doesn't correspond to an existing file.
 417
 418    function Normalize_Pathname
 419      (Name           : String;
 420       Directory      : String  := "";
 421       Resolve_Links  : Boolean := True;
 422       Case_Sensitive : Boolean := True) return String;
 423    --  Returns a file name as an absolute path name, resolving all relative
 424    --  directories, and symbolic links. The parameter Directory is a fully
 425    --  resolved path name for a directory, or the empty string (the default).
 426    --  Name is the name of a file, which is either relative to the given
 427    --  directory name, if Directory is non-null, or to the current working
 428    --  directory if Directory is null. The result returned is the normalized
 429    --  name of the file. For most cases, if two file names designate the same
 430    --  file through different paths, Normalize_Pathname will return the same
 431    --  canonical name in both cases. However, there are cases when this is not
 432    --  true; for example, this is not true in Unix for two hard links
 433    --  designating the same file.
 434    --
 435    --  On Windows, the returned path will start with a drive letter except
 436    --  when Directory is not empty and does not include a drive letter. If
 437    --  Directory is empty (the default) and Name is a relative path or an
 438    --  absolute path without drive letter, the letter of the current drive
 439    --  will start the returned path. If Case_Sensitive is True (the default),
 440    --  then this drive letter will be forced to upper case ("C:\...").
 441    --
 442    --  If Resolve_Links is set to True, then the symbolic links, on systems
 443    --  that support them, will be fully converted to the name of the file or
 444    --  directory pointed to. This is slightly less efficient, since it
 445    --  requires system calls.
 446    --
 447    --  If Name cannot be resolved or is null on entry (for example if there is
 448    --  symbolic link circularity, e.g. A is a symbolic link for B, and B is a
 449    --  symbolic link for A), then Normalize_Pathname returns an empty  string.
 450    --
 451    --  In VMS, if Name follows the VMS syntax file specification, it is first
 452    --  converted into Unix syntax. If the conversion fails, Normalize_Pathname
 453    --  returns an empty string.
 454    --
 455    --  For case-sensitive file systems, the value of Case_Sensitive parameter
 456    --  is ignored. For file systems that are not case-sensitive, such as
 457    --  Windows and OpenVMS, if this parameter is set to False, then the file
 458    --  and directory names are folded to lower case. This allows checking
 459    --  whether two files are the same by applying this function to their names
 460    --  and comparing the results. If Case_Sensitive is set to True, this
 461    --  function does not change the casing of file and directory names.
 462
 463    function Is_Absolute_Path (Name : String) return Boolean;
 464    --  Returns True if Name is an absolute path name, i.e. it designates a
 465    --  file or directory absolutely rather than relative to another directory.
 466
 467    function Is_Regular_File (Name : String) return Boolean;
 468    --  Determines if the given string, Name, is the name of an existing
 469    --  regular file. Returns True if so, False otherwise. Name may be an
 470    --  absolute path name or a relative path name, including a simple file
 471    --  name. If it is a relative path name, it is relative to the current
 472    --  working directory.
 473
 474    function Is_Directory (Name : String) return Boolean;
 475    --  Determines if the given string, Name, is the name of a directory.
 476    --  Returns True if so, False otherwise. Name may be an absolute path
 477    --  name or a relative path name, including a simple file name. If it is
 478    --  a relative path name, it is relative to the current working directory.
 479
 480    function Is_Readable_File (Name : String) return Boolean;
 481    --  Determines if the given string, Name, is the name of an existing file
 482    --  that is readable. Returns True if so, False otherwise. Note that this
 483    --  function simply interrogates the file attributes (e.g. using the C
 484    --  function stat), so it does not indicate a situation in which a file may
 485    --  not actually be readable due to some other process having exclusive
 486    --  access.
 487
 488    function Is_Executable_File (Name : String) return Boolean;
 489    --  Determines if the given string, Name, is the name of an existing file
 490    --  that is executable. Returns True if so, False otherwise. Note that this
 491    --  function simply interrogates the file attributes (e.g. using the C
 492    --  function stat), so it does not indicate a situation in which a file may
 493    --  not actually be readable due to some other process having exclusive
 494    --  access.
 495
 496    function Is_Writable_File (Name : String) return Boolean;
 497    --  Determines if the given string, Name, is the name of an existing file
 498    --  that is writable. Returns True if so, False otherwise. Note that this
 499    --  function simply interrogates the file attributes (e.g. using the C
 500    --  function stat), so it does not indicate a situation in which a file may
 501    --  not actually be writeable due to some other process having exclusive
 502    --  access.
 503
 504    function Is_Symbolic_Link (Name : String) return Boolean;
 505    --  Determines if the given string, Name, is the path of a symbolic link on
 506    --  systems that support it. Returns True if so, False if the path is not a
 507    --  symbolic link or if the system does not support symbolic links.
 508    --
 509    --  A symbolic link is an indirect pointer to a file; its directory entry
 510    --  contains the name of the file to which it is linked. Symbolic links may
 511    --  span file systems and may refer to directories.
 512
 513    procedure Set_Writable (Name : String);
 514    --  Change permissions on the named file to make it writable for its owner
 515
 516    procedure Set_Non_Writable (Name : String);
 517    --  Change permissions on the named file to make it non-writable for its
 518    --  owner. The readable and executable permissions are not modified.
 519
 520    procedure Set_Read_Only (Name : String) renames Set_Non_Writable;
 521    --  This renaming is provided for backwards compatibility with previous
 522    --  versions. The use of Set_Non_Writable is preferred (clearer name).
 523
 524    procedure Set_Executable (Name : String);
 525    --  Change permissions on the named file to make it executable for its owner
 526
 527    procedure Set_Readable (Name : String);
 528    --  Change permissions on the named file to make it readable for its
 529    --  owner.
 530
 531    procedure Set_Non_Readable (Name : String);
 532    --  Change permissions on the named file to make it non-readable for
 533    --  its owner. The writable and executable permissions are not
 534    --  modified.
 535
 536    function Locate_Exec_On_Path
 537      (Exec_Name : String) return String_Access;
 538    --  Try to locate an executable whose name is given by Exec_Name in the
 539    --  directories listed in the environment Path. If the Exec_Name does not
 540    --  have the executable suffix, it will be appended before the search.
 541    --  Otherwise works like Locate_Regular_File below. If the executable is
 542    --  not found, null is returned.
 543    --
 544    --  Note that this function allocates memory for the returned value. This
 545    --  memory needs to be deallocated after use.
 546
 547    function Locate_Regular_File
 548      (File_Name : String;
 549       Path      : String) return String_Access;
 550    --  Try to locate a regular file whose name is given by File_Name in the
 551    --  directories listed in Path. If a file is found, its full pathname is
 552    --  returned; otherwise, a null pointer is returned. If the File_Name given
 553    --  is an absolute pathname, then Locate_Regular_File just checks that the
 554    --  file exists and is a regular file. Otherwise, if the File_Name given
 555    --  includes directory information, Locate_Regular_File first checks if the
 556    --  file exists relative to the current directory. If it does not, or if
 557    --  the File_Name given is a simple file name, the Path argument is parsed
 558    --  according to OS conventions, and for each directory in the Path a check
 559    --  is made if File_Name is a relative pathname of a regular file from that
 560    --  directory.
 561    --
 562    --  Note that this function allocates some memory for the returned value.
 563    --  This memory needs to be deallocated after use.
 564
 565    function Get_Debuggable_Suffix return String_Access;
 566    --  Return the debuggable suffix convention. Usually this is the same as
 567    --  the convention for Get_Executable_Suffix. The result is allocated on
 568    --  the heap and should be freed after use to avoid storage leaks.
 569
 570    function Get_Target_Debuggable_Suffix return String_Access;
 571    --  Return the target debuggable suffix convention. Usually this is the same
 572    --  as the convention for Get_Executable_Suffix. The result is allocated on
 573    --  the heap and should be freed after use to avoid storage leaks.
 574
 575    function Get_Executable_Suffix return String_Access;
 576    --  Return the executable suffix convention. The result is allocated on the
 577    --  heap and should be freed after use to avoid storage leaks.
 578
 579    function Get_Object_Suffix return String_Access;
 580    --  Return the object suffix convention. The result is allocated on the heap
 581    --  and should be freed after use to avoid storage leaks.
 582
 583    function Get_Target_Executable_Suffix return String_Access;
 584    --  Return the target executable suffix convention. The result is allocated
 585    --  on the heap and should be freed after use to avoid storage leaks.
 586
 587    function Get_Target_Object_Suffix return String_Access;
 588    --  Return the target object suffix convention. The result is allocated on
 589    --  the heap and should be freed after use to avoid storage leaks.
 590
 591    --  The following section contains low-level routines using addresses to
 592    --  pass file name and executable name. In each routine the name must be
 593    --  Nul-Terminated. For complete documentation refer to the equivalent
 594    --  routine (using String in place of C_File_Name) defined above.
 595
 596    subtype C_File_Name is System.Address;
 597    --  This subtype is used to document that a parameter is the address of a
 598    --  null-terminated string containing the name of a file.
 599
 600    --  All the following functions need comments ???
 601
 602    function Open_Read
 603      (Name  : C_File_Name;
 604       Fmode : Mode) return File_Descriptor;
 605
 606    function Open_Read_Write
 607      (Name  : C_File_Name;
 608       Fmode : Mode) return File_Descriptor;
 609
 610    function Create_File
 611      (Name  : C_File_Name;
 612       Fmode : Mode) return File_Descriptor;
 613
 614    function Create_New_File
 615      (Name  : C_File_Name;
 616       Fmode : Mode) return File_Descriptor;
 617
 618    procedure Delete_File (Name : C_File_Name; Success : out Boolean);
 619
 620    procedure Rename_File
 621      (Old_Name : C_File_Name;
 622       New_Name : C_File_Name;
 623       Success  : out Boolean);
 624
 625    procedure Copy_File
 626      (Name     : C_File_Name;
 627       Pathname : C_File_Name;
 628       Success  : out Boolean;
 629       Mode     : Copy_Mode := Copy;
 630       Preserve : Attribute := Time_Stamps);
 631
 632    procedure Copy_Time_Stamps
 633      (Source, Dest : C_File_Name;
 634       Success      : out Boolean);
 635
 636    function File_Time_Stamp (Name : C_File_Name) return OS_Time;
 637    --  Returns Invalid_Time is Name doesn't correspond to an existing file
 638
 639    function Is_Regular_File (Name : C_File_Name) return Boolean;
 640    function Is_Directory (Name : C_File_Name) return Boolean;
 641    function Is_Readable_File (Name : C_File_Name) return Boolean;
 642    function Is_Executable_File (Name : C_File_Name) return Boolean;
 643    function Is_Writable_File (Name : C_File_Name) return Boolean;
 644    function Is_Symbolic_Link (Name : C_File_Name) return Boolean;
 645
 646    function Locate_Regular_File
 647      (File_Name : C_File_Name;
 648       Path      : C_File_Name) return String_Access;
 649
 650    ------------------
 651    -- Subprocesses --
 652    ------------------
 653
 654    subtype Argument_List is String_List;
 655    --  Type used for argument list in call to Spawn. The lower bound of the
 656    --  array should be 1, and the length of the array indicates the number of
 657    --  arguments.
 658
 659    subtype Argument_List_Access is String_List_Access;
 660    --  Type used to return Argument_List without dragging in secondary stack.
 661    --  Note that there is a Free procedure declared for this subtype which
 662    --  frees the array and all referenced strings.
 663
 664    procedure Normalize_Arguments (Args : in out Argument_List);
 665    --  Normalize all arguments in the list. This ensure that the argument list
 666    --  is compatible with the running OS and will works fine with Spawn and
 667    --  Non_Blocking_Spawn for example. If Normalize_Arguments is called twice
 668    --  on the same list it will do nothing the second time. Note that Spawn
 669    --  and Non_Blocking_Spawn call Normalize_Arguments automatically, but
 670    --  since there is a guarantee that a second call does nothing, this
 671    --  internal call will have no effect if Normalize_Arguments is called
 672    --  before calling Spawn. The call to Normalize_Arguments assumes that the
 673    --  individual referenced arguments in Argument_List are on the heap, and
 674    --  may free them and reallocate if they are modified.
 675
 676    procedure Spawn
 677      (Program_Name : String;
 678       Args         : Argument_List;
 679       Success      : out Boolean);
 680    --  This procedure spawns a program with a given list of arguments. The
 681    --  first parameter of is the name of the executable. The second parameter
 682    --  contains the arguments to be passed to this program. Success is False
 683    --  if the named program could not be spawned or its execution completed
 684    --  unsuccessfully. Note that the caller will be blocked until the
 685    --  execution of the spawned program is complete. For maximum portability,
 686    --  use a full path name for the Program_Name argument. On some systems
 687    --  (notably Unix systems) a simple file name may also work (if the
 688    --  executable can be located in the path).
 689    --
 690    --  "Spawn" should be avoided in tasking applications, since there are
 691    --  subtle interactions between creating a process and signals/locks
 692    --  that can cause troubles.
 693    --
 694    --  Note: Arguments in Args that contain spaces and/or quotes such as
 695    --  "--GCC=gcc -v" or "--GCC=""gcc -v""" are not portable across all
 696    --  operating systems, and would not have the desired effect if they were
 697    --  passed directly to the operating system. To avoid this problem, Spawn
 698    --  makes an internal call to Normalize_Arguments, which ensures that such
 699    --  arguments are modified in a manner that ensures that the desired effect
 700    --  is obtained on all operating systems. The caller may call
 701    --  Normalize_Arguments explicitly before the call (e.g. to print out the
 702    --  exact form of arguments passed to the operating system). In this case
 703    --  the guarantee a second call to Normalize_Arguments has no effect
 704    --  ensures that the internal call will not affect the result. Note that
 705    --  the implicit call to Normalize_Arguments may free and reallocate some
 706    --  of the individual arguments.
 707    --
 708    --  This function will always set Success to False under VxWorks and other
 709    --  similar operating systems which have no notion of the concept of
 710    --  dynamically executable file.
 711
 712    function Spawn
 713      (Program_Name : String;
 714       Args         : Argument_List) return Integer;
 715    --  Similar to the above procedure, but returns the actual status returned
 716    --  by the operating system, or -1 under VxWorks and any other similar
 717    --  operating systems which have no notion of separately spawnable programs.
 718    --
 719    --  "Spawn" should not be used in tasking applications.
 720
 721    procedure Spawn
 722      (Program_Name           : String;
 723       Args                   : Argument_List;
 724       Output_File_Descriptor : File_Descriptor;
 725       Return_Code            : out Integer;
 726       Err_To_Out             : Boolean := True);
 727    --  Similar to the procedure above, but redirects the output to the file
 728    --  designated by Output_File_Descriptor. If Err_To_Out is True, then the
 729    --  Standard Error output is also redirected.
 730    --  Return_Code is set to the status code returned by the operating system
 731    --
 732    --  "Spawn" should not be used in tasking applications.
 733
 734    procedure Spawn
 735      (Program_Name : String;
 736       Args         : Argument_List;
 737       Output_File  : String;
 738       Success      : out Boolean;
 739       Return_Code  : out Integer;
 740       Err_To_Out   : Boolean := True);
 741    --  Similar to the procedure above, but saves the output of the command to
 742    --  a file with the name Output_File.
 743    --
 744    --  Success is set to True if the command is executed and its output
 745    --  successfully written to the file. If Success is True, then Return_Code
 746    --  will be set to the status code returned by the operating system.
 747    --  Otherwise, Return_Code is undefined.
 748    --
 749    --  "Spawn" should not be used in tasking applications.
 750
 751    type Process_Id is private;
 752    --  A private type used to identify a process activated by the following
 753    --  non-blocking calls. The only meaningful operation on this type is a
 754    --  comparison for equality.
 755
 756    Invalid_Pid : constant Process_Id;
 757    --  A special value used to indicate errors, as described below
 758
 759    function Pid_To_Integer (Pid : Process_Id) return Integer;
 760    --  Convert a process id to an Integer. Useful for writing hash functions
 761    --  for type Process_Id or to compare two Process_Id (e.g. for sorting).
 762
 763    function Non_Blocking_Spawn
 764      (Program_Name : String;
 765       Args         : Argument_List) return Process_Id;
 766    --  This is a non blocking call. The Process_Id of the spawned process is
 767    --  returned. Parameters are to be used as in Spawn. If Invalid_Pid is
 768    --  returned the program could not be spawned.
 769    --
 770    --  "Non_Blocking_Spawn" should not be used in tasking applications.
 771    --
 772    --  This function will always return Invalid_Pid under VxWorks, since there
 773    --  is no notion of executables under this OS.
 774
 775    function Non_Blocking_Spawn
 776      (Program_Name           : String;
 777       Args                   : Argument_List;
 778       Output_File_Descriptor : File_Descriptor;
 779       Err_To_Out             : Boolean := True) return Process_Id;
 780    --  Similar to the procedure above, but redirects the output to the file
 781    --  designated by Output_File_Descriptor. If Err_To_Out is True, then the
 782    --  Standard Error output is also redirected. Invalid_Pid is returned
 783    --  if the program could not be spawned successfully.
 784    --
 785    --  "Non_Blocking_Spawn" should not be used in tasking applications.
 786    --
 787    --  This function will always return Invalid_Pid under VxWorks, since there
 788    --  is no notion of executables under this OS.
 789
 790    function Non_Blocking_Spawn
 791      (Program_Name : String;
 792       Args         : Argument_List;
 793       Output_File  : String;
 794       Err_To_Out   : Boolean := True) return Process_Id;
 795    --  Similar to the procedure above, but saves the output of the command to
 796    --  a file with the name Output_File.
 797    --
 798    --  Success is set to True if the command is executed and its output
 799    --  successfully written to the file. Invalid_Pid is returned if the output
 800    --  file could not be created or if the program could not be spawned
 801    --  successfully.
 802    --
 803    --  "Non_Blocking_Spawn" should not be used in tasking applications.
 804    --
 805    --  This function will always return Invalid_Pid under VxWorks, since there
 806    --  is no notion of executables under this OS.
 807
 808    procedure Wait_Process (Pid : out Process_Id; Success : out Boolean);
 809    --  Wait for the completion of any of the processes created by previous
 810    --  calls to Non_Blocking_Spawn. The caller will be suspended until one of
 811    --  these processes terminates (normally or abnormally). If any of these
 812    --  subprocesses terminates prior to the call to Wait_Process (and has not
 813    --  been returned by a previous call to Wait_Process), then the call to
 814    --  Wait_Process is immediate. Pid identifies the process that has
 815    --  terminated (matching the value returned from Non_Blocking_Spawn).
 816    --  Success is set to True if this sub-process terminated successfully. If
 817    --  Pid = Invalid_Pid, there were no subprocesses left to wait on.
 818    --
 819    --  This function will always set success to False under VxWorks, since
 820    --  there is no notion of executables under this OS.
 821
 822    function Argument_String_To_List
 823      (Arg_String : String) return Argument_List_Access;
 824    --  Take a string that is a program and its arguments and parse it into an
 825    --  Argument_List. Note that the result is allocated on the heap, and must
 826    --  be freed by the programmer (when it is no longer needed) to avoid
 827    --  memory leaks.
 828
 829    -------------------
 830    -- Miscellaneous --
 831    -------------------
 832
 833    function Getenv (Name : String) return String_Access;
 834    --  Get the value of the environment variable. Returns an access to the
 835    --  empty string if the environment variable does not exist or has an
 836    --  explicit null value (in some operating systems these are distinct
 837    --  cases, in others they are not; this interface abstracts away that
 838    --  difference. The argument is allocated on the heap (even in the null
 839    --  case), and needs to be freed explicitly when no longer needed to avoid
 840    --  memory leaks.
 841
 842    procedure Setenv (Name : String; Value : String);
 843    --  Set the value of the environment variable Name to Value. This call
 844    --  modifies the current environment, but does not modify the parent
 845    --  process environment. After a call to Setenv, Getenv (Name) will always
 846    --  return a String_Access referencing the same String as Value. This is
 847    --  true also for the null string case (the actual effect may be to either
 848    --  set an explicit null as the value, or to remove the entry, this is
 849    --  operating system dependent). Note that any following calls to Spawn
 850    --  will pass an environment to the spawned process that includes the
 851    --  changes made by Setenv calls. This procedure is not available on VMS.
 852
 853    procedure OS_Exit (Status : Integer);
 854    pragma No_Return (OS_Exit);
 855
 856    --  Exit to OS with given status code (program is terminated). Note that
 857    --  this is abrupt termination. All tasks are immediately terminated. There
 858    --  are no finalization or other Ada-specific cleanup actions performed. On
 859    --  systems with atexit handlers (such as Unix and Windows), atexit handlers
 860    --  are called.
 861
 862    type OS_Exit_Subprogram is access procedure (Status : Integer);
 863
 864    procedure OS_Exit_Default (Status : Integer);
 865    pragma No_Return (OS_Exit_Default);
 866    --  Default implementation of procedure OS_Exit
 867
 868    OS_Exit_Ptr : OS_Exit_Subprogram := OS_Exit_Default'Access;
 869    --  OS_Exit is implemented through this access value. It it then possible to
 870    --  change the implementation of OS_Exit by redirecting OS_Exit_Ptr to an
 871    --  other implementation.
 872
 873    procedure OS_Abort;
 874    pragma Import (C, OS_Abort, "abort");
 875    pragma No_Return (OS_Abort);
 876    --  Exit to OS signalling an abort (traceback or other appropriate
 877    --  diagnostic information should be given if possible, or entry made to
 878    --  the debugger if that is possible).
 879
 880    function Errno return Integer;
 881    pragma Import (C, Errno, "__get_errno");
 882    --  Return the task-safe last error number
 883
 884    procedure Set_Errno (Errno : Integer);
 885    pragma Import (C, Set_Errno, "__set_errno");
 886    --  Set the task-safe error number
 887
 888    Directory_Separator : constant Character;
 889    --  The character that is used to separate parts of a pathname
 890
 891    Path_Separator : constant Character;
 892    --  The character to separate paths in an environment variable value
 893
 894 private
 895    pragma Import (C, Path_Separator, "__gnat_path_separator");
 896    pragma Import (C, Directory_Separator, "__gnat_dir_separator");
 897    pragma Import (C, Current_Time, "__gnat_current_time");
 898
 899    type OS_Time is
 900      range -(2 ** (Standard'Address_Size - Integer'(1))) ..
 901            +(2 ** (Standard'Address_Size - Integer'(1)) - 1);
 902    --  Type used for timestamps in the compiler. This type is used to hold
 903    --  time stamps, but may have a different representation than C's time_t.
 904    --  This type needs to match the declaration of OS_Time in adaint.h.
 905
 906    --  Add pragma Inline statements for comparison operations on OS_Time. It
 907    --  would actually be nice to use pragma Import (Intrinsic) here, but this
 908    --  was not properly supported till GNAT 3.15a, so that would cause
 909    --  bootstrap path problems. To be changed later ???
 910
 911    Invalid_Time : constant OS_Time := -1;
 912    --  This value should match the return value from __gnat_file_time_*
 913
 914    pragma Inline ("<");
 915    pragma Inline (">");
 916    pragma Inline ("<=");
 917    pragma Inline (">=");
 918
 919    type Process_Id is new Integer;
 920    Invalid_Pid : constant Process_Id := -1;
 921
 922 end System.OS_Lib;