gcc/ada/exp_pakd.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             E X P _ P A K D                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Errout;   use Errout;
  30 with Exp_Dbug; use Exp_Dbug;
  31 with Exp_Util; use Exp_Util;
  32 with Layout;   use Layout;
  33 with Namet;    use Namet;
  34 with Nlists;   use Nlists;
  35 with Nmake;    use Nmake;
  36 with Opt;      use Opt;
  37 with Rtsfind;  use Rtsfind;
  38 with Sem;      use Sem;
  39 with Sem_Aux;  use Sem_Aux;
  40 with Sem_Ch3;  use Sem_Ch3;
  41 with Sem_Ch8;  use Sem_Ch8;
  42 with Sem_Ch13; use Sem_Ch13;
  43 with Sem_Eval; use Sem_Eval;
  44 with Sem_Res;  use Sem_Res;
  45 with Sem_Util; use Sem_Util;
  46 with Sinfo;    use Sinfo;
  47 with Snames;   use Snames;
  48 with Stand;    use Stand;
  49 with Targparm; use Targparm;
  50 with Tbuild;   use Tbuild;
  51 with Ttypes;   use Ttypes;
  52 with Uintp;    use Uintp;
  53
  54 package body Exp_Pakd is
  55
  56    ---------------------------
  57    -- Endian Considerations --
  58    ---------------------------
  59
  60    --  As described in the specification, bit numbering in a packed array
  61    --  is consistent with bit numbering in a record representation clause,
  62    --  and hence dependent on the endianness of the machine:
  63
  64    --    For little-endian machines, element zero is at the right hand end
  65    --    (low order end) of a bit field.
  66
  67    --    For big-endian machines, element zero is at the left hand end
  68    --    (high order end) of a bit field.
  69
  70    --  The shifts that are used to right justify a field therefore differ
  71    --  in the two cases. For the little-endian case, we can simply use the
  72    --  bit number (i.e. the element number * element size) as the count for
  73    --  a right shift. For the big-endian case, we have to subtract the shift
  74    --  count from an appropriate constant to use in the right shift. We use
  75    --  rotates instead of shifts (which is necessary in the store case to
  76    --  preserve other fields), and we expect that the backend will be able
  77    --  to change the right rotate into a left rotate, avoiding the subtract,
  78    --  if the architecture provides such an instruction.
  79
  80    ----------------------------------------------
  81    -- Entity Tables for Packed Access Routines --
  82    ----------------------------------------------
  83
  84    --  For the cases of component size = 3,5-7,9-15,17-31,33-63 we call
  85    --  library routines. This table is used to obtain the entity for the
  86    --  proper routine.
  87
  88    type E_Array is array (Int range 01 .. 63) of RE_Id;
  89
  90    --  Array of Bits_nn entities. Note that we do not use library routines
  91    --  for the 8-bit and 16-bit cases, but we still fill in the table, using
  92    --  entries from System.Unsigned, because we also use this table for
  93    --  certain special unchecked conversions in the big-endian case.
  94
  95    Bits_Id : constant E_Array :=
  96      (01 => RE_Bits_1,
  97       02 => RE_Bits_2,
  98       03 => RE_Bits_03,
  99       04 => RE_Bits_4,
 100       05 => RE_Bits_05,
 101       06 => RE_Bits_06,
 102       07 => RE_Bits_07,
 103       08 => RE_Unsigned_8,
 104       09 => RE_Bits_09,
 105       10 => RE_Bits_10,
 106       11 => RE_Bits_11,
 107       12 => RE_Bits_12,
 108       13 => RE_Bits_13,
 109       14 => RE_Bits_14,
 110       15 => RE_Bits_15,
 111       16 => RE_Unsigned_16,
 112       17 => RE_Bits_17,
 113       18 => RE_Bits_18,
 114       19 => RE_Bits_19,
 115       20 => RE_Bits_20,
 116       21 => RE_Bits_21,
 117       22 => RE_Bits_22,
 118       23 => RE_Bits_23,
 119       24 => RE_Bits_24,
 120       25 => RE_Bits_25,
 121       26 => RE_Bits_26,
 122       27 => RE_Bits_27,
 123       28 => RE_Bits_28,
 124       29 => RE_Bits_29,
 125       30 => RE_Bits_30,
 126       31 => RE_Bits_31,
 127       32 => RE_Unsigned_32,
 128       33 => RE_Bits_33,
 129       34 => RE_Bits_34,
 130       35 => RE_Bits_35,
 131       36 => RE_Bits_36,
 132       37 => RE_Bits_37,
 133       38 => RE_Bits_38,
 134       39 => RE_Bits_39,
 135       40 => RE_Bits_40,
 136       41 => RE_Bits_41,
 137       42 => RE_Bits_42,
 138       43 => RE_Bits_43,
 139       44 => RE_Bits_44,
 140       45 => RE_Bits_45,
 141       46 => RE_Bits_46,
 142       47 => RE_Bits_47,
 143       48 => RE_Bits_48,
 144       49 => RE_Bits_49,
 145       50 => RE_Bits_50,
 146       51 => RE_Bits_51,
 147       52 => RE_Bits_52,
 148       53 => RE_Bits_53,
 149       54 => RE_Bits_54,
 150       55 => RE_Bits_55,
 151       56 => RE_Bits_56,
 152       57 => RE_Bits_57,
 153       58 => RE_Bits_58,
 154       59 => RE_Bits_59,
 155       60 => RE_Bits_60,
 156       61 => RE_Bits_61,
 157       62 => RE_Bits_62,
 158       63 => RE_Bits_63);
 159
 160    --  Array of Get routine entities. These are used to obtain an element
 161    --  from a packed array. The N'th entry is used to obtain elements from
 162    --  a packed array whose component size is N. RE_Null is used as a null
 163    --  entry, for the cases where a library routine is not used.
 164
 165    Get_Id : constant E_Array :=
 166      (01 => RE_Null,
 167       02 => RE_Null,
 168       03 => RE_Get_03,
 169       04 => RE_Null,
 170       05 => RE_Get_05,
 171       06 => RE_Get_06,
 172       07 => RE_Get_07,
 173       08 => RE_Null,
 174       09 => RE_Get_09,
 175       10 => RE_Get_10,
 176       11 => RE_Get_11,
 177       12 => RE_Get_12,
 178       13 => RE_Get_13,
 179       14 => RE_Get_14,
 180       15 => RE_Get_15,
 181       16 => RE_Null,
 182       17 => RE_Get_17,
 183       18 => RE_Get_18,
 184       19 => RE_Get_19,
 185       20 => RE_Get_20,
 186       21 => RE_Get_21,
 187       22 => RE_Get_22,
 188       23 => RE_Get_23,
 189       24 => RE_Get_24,
 190       25 => RE_Get_25,
 191       26 => RE_Get_26,
 192       27 => RE_Get_27,
 193       28 => RE_Get_28,
 194       29 => RE_Get_29,
 195       30 => RE_Get_30,
 196       31 => RE_Get_31,
 197       32 => RE_Null,
 198       33 => RE_Get_33,
 199       34 => RE_Get_34,
 200       35 => RE_Get_35,
 201       36 => RE_Get_36,
 202       37 => RE_Get_37,
 203       38 => RE_Get_38,
 204       39 => RE_Get_39,
 205       40 => RE_Get_40,
 206       41 => RE_Get_41,
 207       42 => RE_Get_42,
 208       43 => RE_Get_43,
 209       44 => RE_Get_44,
 210       45 => RE_Get_45,
 211       46 => RE_Get_46,
 212       47 => RE_Get_47,
 213       48 => RE_Get_48,
 214       49 => RE_Get_49,
 215       50 => RE_Get_50,
 216       51 => RE_Get_51,
 217       52 => RE_Get_52,
 218       53 => RE_Get_53,
 219       54 => RE_Get_54,
 220       55 => RE_Get_55,
 221       56 => RE_Get_56,
 222       57 => RE_Get_57,
 223       58 => RE_Get_58,
 224       59 => RE_Get_59,
 225       60 => RE_Get_60,
 226       61 => RE_Get_61,
 227       62 => RE_Get_62,
 228       63 => RE_Get_63);
 229
 230    --  Array of Get routine entities to be used in the case where the packed
 231    --  array is itself a component of a packed structure, and therefore may
 232    --  not be fully aligned. This only affects the even sizes, since for the
 233    --  odd sizes, we do not get any fixed alignment in any case.
 234
 235    GetU_Id : constant E_Array :=
 236      (01 => RE_Null,
 237       02 => RE_Null,
 238       03 => RE_Get_03,
 239       04 => RE_Null,
 240       05 => RE_Get_05,
 241       06 => RE_GetU_06,
 242       07 => RE_Get_07,
 243       08 => RE_Null,
 244       09 => RE_Get_09,
 245       10 => RE_GetU_10,
 246       11 => RE_Get_11,
 247       12 => RE_GetU_12,
 248       13 => RE_Get_13,
 249       14 => RE_GetU_14,
 250       15 => RE_Get_15,
 251       16 => RE_Null,
 252       17 => RE_Get_17,
 253       18 => RE_GetU_18,
 254       19 => RE_Get_19,
 255       20 => RE_GetU_20,
 256       21 => RE_Get_21,
 257       22 => RE_GetU_22,
 258       23 => RE_Get_23,
 259       24 => RE_GetU_24,
 260       25 => RE_Get_25,
 261       26 => RE_GetU_26,
 262       27 => RE_Get_27,
 263       28 => RE_GetU_28,
 264       29 => RE_Get_29,
 265       30 => RE_GetU_30,
 266       31 => RE_Get_31,
 267       32 => RE_Null,
 268       33 => RE_Get_33,
 269       34 => RE_GetU_34,
 270       35 => RE_Get_35,
 271       36 => RE_GetU_36,
 272       37 => RE_Get_37,
 273       38 => RE_GetU_38,
 274       39 => RE_Get_39,
 275       40 => RE_GetU_40,
 276       41 => RE_Get_41,
 277       42 => RE_GetU_42,
 278       43 => RE_Get_43,
 279       44 => RE_GetU_44,
 280       45 => RE_Get_45,
 281       46 => RE_GetU_46,
 282       47 => RE_Get_47,
 283       48 => RE_GetU_48,
 284       49 => RE_Get_49,
 285       50 => RE_GetU_50,
 286       51 => RE_Get_51,
 287       52 => RE_GetU_52,
 288       53 => RE_Get_53,
 289       54 => RE_GetU_54,
 290       55 => RE_Get_55,
 291       56 => RE_GetU_56,
 292       57 => RE_Get_57,
 293       58 => RE_GetU_58,
 294       59 => RE_Get_59,
 295       60 => RE_GetU_60,
 296       61 => RE_Get_61,
 297       62 => RE_GetU_62,
 298       63 => RE_Get_63);
 299
 300    --  Array of Set routine entities. These are used to assign an element
 301    --  of a packed array. The N'th entry is used to assign elements for
 302    --  a packed array whose component size is N. RE_Null is used as a null
 303    --  entry, for the cases where a library routine is not used.
 304
 305    Set_Id : constant E_Array :=
 306      (01 => RE_Null,
 307       02 => RE_Null,
 308       03 => RE_Set_03,
 309       04 => RE_Null,
 310       05 => RE_Set_05,
 311       06 => RE_Set_06,
 312       07 => RE_Set_07,
 313       08 => RE_Null,
 314       09 => RE_Set_09,
 315       10 => RE_Set_10,
 316       11 => RE_Set_11,
 317       12 => RE_Set_12,
 318       13 => RE_Set_13,
 319       14 => RE_Set_14,
 320       15 => RE_Set_15,
 321       16 => RE_Null,
 322       17 => RE_Set_17,
 323       18 => RE_Set_18,
 324       19 => RE_Set_19,
 325       20 => RE_Set_20,
 326       21 => RE_Set_21,
 327       22 => RE_Set_22,
 328       23 => RE_Set_23,
 329       24 => RE_Set_24,
 330       25 => RE_Set_25,
 331       26 => RE_Set_26,
 332       27 => RE_Set_27,
 333       28 => RE_Set_28,
 334       29 => RE_Set_29,
 335       30 => RE_Set_30,
 336       31 => RE_Set_31,
 337       32 => RE_Null,
 338       33 => RE_Set_33,
 339       34 => RE_Set_34,
 340       35 => RE_Set_35,
 341       36 => RE_Set_36,
 342       37 => RE_Set_37,
 343       38 => RE_Set_38,
 344       39 => RE_Set_39,
 345       40 => RE_Set_40,
 346       41 => RE_Set_41,
 347       42 => RE_Set_42,
 348       43 => RE_Set_43,
 349       44 => RE_Set_44,
 350       45 => RE_Set_45,
 351       46 => RE_Set_46,
 352       47 => RE_Set_47,
 353       48 => RE_Set_48,
 354       49 => RE_Set_49,
 355       50 => RE_Set_50,
 356       51 => RE_Set_51,
 357       52 => RE_Set_52,
 358       53 => RE_Set_53,
 359       54 => RE_Set_54,
 360       55 => RE_Set_55,
 361       56 => RE_Set_56,
 362       57 => RE_Set_57,
 363       58 => RE_Set_58,
 364       59 => RE_Set_59,
 365       60 => RE_Set_60,
 366       61 => RE_Set_61,
 367       62 => RE_Set_62,
 368       63 => RE_Set_63);
 369
 370    --  Array of Set routine entities to be used in the case where the packed
 371    --  array is itself a component of a packed structure, and therefore may
 372    --  not be fully aligned. This only affects the even sizes, since for the
 373    --  odd sizes, we do not get any fixed alignment in any case.
 374
 375    SetU_Id : constant E_Array :=
 376      (01 => RE_Null,
 377       02 => RE_Null,
 378       03 => RE_Set_03,
 379       04 => RE_Null,
 380       05 => RE_Set_05,
 381       06 => RE_SetU_06,
 382       07 => RE_Set_07,
 383       08 => RE_Null,
 384       09 => RE_Set_09,
 385       10 => RE_SetU_10,
 386       11 => RE_Set_11,
 387       12 => RE_SetU_12,
 388       13 => RE_Set_13,
 389       14 => RE_SetU_14,
 390       15 => RE_Set_15,
 391       16 => RE_Null,
 392       17 => RE_Set_17,
 393       18 => RE_SetU_18,
 394       19 => RE_Set_19,
 395       20 => RE_SetU_20,
 396       21 => RE_Set_21,
 397       22 => RE_SetU_22,
 398       23 => RE_Set_23,
 399       24 => RE_SetU_24,
 400       25 => RE_Set_25,
 401       26 => RE_SetU_26,
 402       27 => RE_Set_27,
 403       28 => RE_SetU_28,
 404       29 => RE_Set_29,
 405       30 => RE_SetU_30,
 406       31 => RE_Set_31,
 407       32 => RE_Null,
 408       33 => RE_Set_33,
 409       34 => RE_SetU_34,
 410       35 => RE_Set_35,
 411       36 => RE_SetU_36,
 412       37 => RE_Set_37,
 413       38 => RE_SetU_38,
 414       39 => RE_Set_39,
 415       40 => RE_SetU_40,
 416       41 => RE_Set_41,
 417       42 => RE_SetU_42,
 418       43 => RE_Set_43,
 419       44 => RE_SetU_44,
 420       45 => RE_Set_45,
 421       46 => RE_SetU_46,
 422       47 => RE_Set_47,
 423       48 => RE_SetU_48,
 424       49 => RE_Set_49,
 425       50 => RE_SetU_50,
 426       51 => RE_Set_51,
 427       52 => RE_SetU_52,
 428       53 => RE_Set_53,
 429       54 => RE_SetU_54,
 430       55 => RE_Set_55,
 431       56 => RE_SetU_56,
 432       57 => RE_Set_57,
 433       58 => RE_SetU_58,
 434       59 => RE_Set_59,
 435       60 => RE_SetU_60,
 436       61 => RE_Set_61,
 437       62 => RE_SetU_62,
 438       63 => RE_Set_63);
 439
 440    -----------------------
 441    -- Local Subprograms --
 442    -----------------------
 443
 444    procedure Compute_Linear_Subscript
 445      (Atyp   : Entity_Id;
 446       N      : Node_Id;
 447       Subscr : out Node_Id);
 448    --  Given a constrained array type Atyp, and an indexed component node
 449    --  N referencing an array object of this type, build an expression of
 450    --  type Standard.Integer representing the zero-based linear subscript
 451    --  value. This expression includes any required range checks.
 452
 453    procedure Convert_To_PAT_Type (Aexp : Node_Id);
 454    --  Given an expression of a packed array type, builds a corresponding
 455    --  expression whose type is the implementation type used to represent
 456    --  the packed array. Aexp is analyzed and resolved on entry and on exit.
 457
 458    procedure Get_Base_And_Bit_Offset
 459      (N      : Node_Id;
 460       Base   : out Node_Id;
 461       Offset : out Node_Id);
 462    --  Given a node N for a name which involves a packed array reference,
 463    --  return the base object of the reference and build an expression of
 464    --  type Standard.Integer representing the zero-based offset in bits
 465    --  from Base'Address to the first bit of the reference.
 466
 467    function Known_Aligned_Enough (Obj : Node_Id; Csiz : Nat) return Boolean;
 468    --  There are two versions of the Set routines, the ones used when the
 469    --  object is known to be sufficiently well aligned given the number of
 470    --  bits, and the ones used when the object is not known to be aligned.
 471    --  This routine is used to determine which set to use. Obj is a reference
 472    --  to the object, and Csiz is the component size of the packed array.
 473    --  True is returned if the alignment of object is known to be sufficient,
 474    --  defined as 1 for odd bit sizes, 4 for bit sizes divisible by 4, and
 475    --  2 otherwise.
 476
 477    function Make_Shift_Left (N : Node_Id; S : Node_Id) return Node_Id;
 478    --  Build a left shift node, checking for the case of a shift count of zero
 479
 480    function Make_Shift_Right (N : Node_Id; S : Node_Id) return Node_Id;
 481    --  Build a right shift node, checking for the case of a shift count of zero
 482
 483    function RJ_Unchecked_Convert_To
 484      (Typ  : Entity_Id;
 485       Expr : Node_Id) return Node_Id;
 486    --  The packed array code does unchecked conversions which in some cases
 487    --  may involve non-discrete types with differing sizes. The semantics of
 488    --  such conversions is potentially endian dependent, and the effect we
 489    --  want here for such a conversion is to do the conversion in size as
 490    --  though numeric items are involved, and we extend or truncate on the
 491    --  left side. This happens naturally in the little-endian case, but in
 492    --  the big endian case we can get left justification, when what we want
 493    --  is right justification. This routine does the unchecked conversion in
 494    --  a stepwise manner to ensure that it gives the expected result. Hence
 495    --  the name (RJ = Right justified). The parameters Typ and Expr are as
 496    --  for the case of a normal Unchecked_Convert_To call.
 497
 498    procedure Setup_Enumeration_Packed_Array_Reference (N : Node_Id);
 499    --  This routine is called in the Get and Set case for arrays that are
 500    --  packed but not bit-packed, meaning that they have at least one
 501    --  subscript that is of an enumeration type with a non-standard
 502    --  representation. This routine modifies the given node to properly
 503    --  reference the corresponding packed array type.
 504
 505    procedure Setup_Inline_Packed_Array_Reference
 506      (N      : Node_Id;
 507       Atyp   : Entity_Id;
 508       Obj    : in out Node_Id;
 509       Cmask  : out Uint;
 510       Shift  : out Node_Id);
 511    --  This procedure performs common processing on the N_Indexed_Component
 512    --  parameter given as N, whose prefix is a reference to a packed array.
 513    --  This is used for the get and set when the component size is 1,2,4
 514    --  or for other component sizes when the packed array type is a modular
 515    --  type (i.e. the cases that are handled with inline code).
 516    --
 517    --  On entry:
 518    --
 519    --    N is the N_Indexed_Component node for the packed array reference
 520    --
 521    --    Atyp is the constrained array type (the actual subtype has been
 522    --    computed if necessary to obtain the constraints, but this is still
 523    --    the original array type, not the Packed_Array_Type value).
 524    --
 525    --    Obj is the object which is to be indexed. It is always of type Atyp.
 526    --
 527    --  On return:
 528    --
 529    --    Obj is the object containing the desired bit field. It is of type
 530    --    Unsigned, Long_Unsigned, or Long_Long_Unsigned, and is either the
 531    --    entire value, for the small static case, or the proper selected byte
 532    --    from the array in the large or dynamic case. This node is analyzed
 533    --    and resolved on return.
 534    --
 535    --    Shift is a node representing the shift count to be used in the
 536    --    rotate right instruction that positions the field for access.
 537    --    This node is analyzed and resolved on return.
 538    --
 539    --    Cmask is a mask corresponding to the width of the component field.
 540    --    Its value is 2 ** Csize - 1 (e.g. 2#1111# for component size of 4).
 541    --
 542    --  Note: in some cases the call to this routine may generate actions
 543    --  (for handling multi-use references and the generation of the packed
 544    --  array type on the fly). Such actions are inserted into the tree
 545    --  directly using Insert_Action.
 546
 547    ------------------------------
 548    -- Compute_Linear_Subscript --
 549    ------------------------------
 550
 551    procedure Compute_Linear_Subscript
 552      (Atyp   : Entity_Id;
 553       N      : Node_Id;
 554       Subscr : out Node_Id)
 555    is
 556       Loc    : constant Source_Ptr := Sloc (N);
 557       Oldsub : Node_Id;
 558       Newsub : Node_Id;
 559       Indx   : Node_Id;
 560       Styp   : Entity_Id;
 561
 562    begin
 563       Subscr := Empty;
 564
 565       --  Loop through dimensions
 566
 567       Indx   := First_Index (Atyp);
 568       Oldsub := First (Expressions (N));
 569
 570       while Present (Indx) loop
 571          Styp := Etype (Indx);
 572          Newsub := Relocate_Node (Oldsub);
 573
 574          --  Get expression for the subscript value. First, if Do_Range_Check
 575          --  is set on a subscript, then we must do a range check against the
 576          --  original bounds (not the bounds of the packed array type). We do
 577          --  this by introducing a subtype conversion.
 578
 579          if Do_Range_Check (Newsub)
 580            and then Etype (Newsub) /= Styp
 581          then
 582             Newsub := Convert_To (Styp, Newsub);
 583          end if;
 584
 585          --  Now evolve the expression for the subscript. First convert
 586          --  the subscript to be zero based and of an integer type.
 587
 588          --  Case of integer type, where we just subtract to get lower bound
 589
 590          if Is_Integer_Type (Styp) then
 591
 592             --  If length of integer type is smaller than standard integer,
 593             --  then we convert to integer first, then do the subtract
 594
 595             --  Integer (subscript) - Integer (Styp'First)
 596
 597             if Esize (Styp) < Esize (Standard_Integer) then
 598                Newsub :=
 599                  Make_Op_Subtract (Loc,
 600                    Left_Opnd => Convert_To (Standard_Integer, Newsub),
 601                  Right_Opnd =>
 602                    Convert_To (Standard_Integer,
 603                      Make_Attribute_Reference (Loc,
 604                        Prefix         => New_Occurrence_Of (Styp, Loc),
 605                        Attribute_Name => Name_First)));
 606
 607             --  For larger integer types, subtract first, then convert to
 608             --  integer, this deals with strange long long integer bounds.
 609
 610             --    Integer (subscript - Styp'First)
 611
 612             else
 613                Newsub :=
 614                  Convert_To (Standard_Integer,
 615                    Make_Op_Subtract (Loc,
 616                      Left_Opnd => Newsub,
 617                    Right_Opnd =>
 618                      Make_Attribute_Reference (Loc,
 619                        Prefix         => New_Occurrence_Of (Styp, Loc),
 620                        Attribute_Name => Name_First)));
 621             end if;
 622
 623          --  For the enumeration case, we have to use 'Pos to get the value
 624          --  to work with before subtracting the lower bound.
 625
 626          --    Integer (Styp'Pos (subscr)) - Integer (Styp'Pos (Styp'First));
 627
 628          --  This is not quite right for bizarre cases where the size of the
 629          --  enumeration type is > Integer'Size bits due to rep clause ???
 630
 631          else
 632             pragma Assert (Is_Enumeration_Type (Styp));
 633
 634             Newsub :=
 635               Make_Op_Subtract (Loc,
 636                 Left_Opnd => Convert_To (Standard_Integer,
 637                   Make_Attribute_Reference (Loc,
 638                     Prefix         => New_Occurrence_Of (Styp, Loc),
 639                     Attribute_Name => Name_Pos,
 640                     Expressions    => New_List (Newsub))),
 641
 642                 Right_Opnd =>
 643                   Convert_To (Standard_Integer,
 644                     Make_Attribute_Reference (Loc,
 645                       Prefix         => New_Occurrence_Of (Styp, Loc),
 646                       Attribute_Name => Name_Pos,
 647                       Expressions    => New_List (
 648                         Make_Attribute_Reference (Loc,
 649                           Prefix         => New_Occurrence_Of (Styp, Loc),
 650                           Attribute_Name => Name_First)))));
 651          end if;
 652
 653          Set_Paren_Count (Newsub, 1);
 654
 655          --  For the first subscript, we just copy that subscript value
 656
 657          if No (Subscr) then
 658             Subscr := Newsub;
 659
 660          --  Otherwise, we must multiply what we already have by the current
 661          --  stride and then add in the new value to the evolving subscript.
 662
 663          else
 664             Subscr :=
 665               Make_Op_Add (Loc,
 666                 Left_Opnd =>
 667                   Make_Op_Multiply (Loc,
 668                     Left_Opnd  => Subscr,
 669                     Right_Opnd =>
 670                       Make_Attribute_Reference (Loc,
 671                         Attribute_Name => Name_Range_Length,
 672                         Prefix         => New_Occurrence_Of (Styp, Loc))),
 673                 Right_Opnd => Newsub);
 674          end if;
 675
 676          --  Move to next subscript
 677
 678          Next_Index (Indx);
 679          Next (Oldsub);
 680       end loop;
 681    end Compute_Linear_Subscript;
 682
 683    -------------------------
 684    -- Convert_To_PAT_Type --
 685    -------------------------
 686
 687    --  The PAT is always obtained from the actual subtype
 688
 689    procedure Convert_To_PAT_Type (Aexp : Node_Id) is
 690       Act_ST : Entity_Id;
 691
 692    begin
 693       Convert_To_Actual_Subtype (Aexp);
 694       Act_ST := Underlying_Type (Etype (Aexp));
 695       Create_Packed_Array_Type (Act_ST);
 696
 697       --  Just replace the etype with the packed array type. This works because
 698       --  the expression will not be further analyzed, and Gigi considers the
 699       --  two types equivalent in any case.
 700
 701       --  This is not strictly the case ??? If the reference is an actual in
 702       --  call, the expansion of the prefix is delayed, and must be reanalyzed,
 703       --  see Reset_Packed_Prefix. On the other hand, if the prefix is a simple
 704       --  array reference, reanalysis can produce spurious type errors when the
 705       --  PAT type is replaced again with the original type of the array. Same
 706       --  for the case of a dereference. The following is correct and minimal,
 707       --  but the handling of more complex packed expressions in actuals is
 708       --  confused. Probably the problem only remains for actuals in calls.
 709
 710       Set_Etype (Aexp, Packed_Array_Type (Act_ST));
 711
 712       if Is_Entity_Name (Aexp)
 713         or else
 714            (Nkind (Aexp) = N_Indexed_Component
 715              and then Is_Entity_Name (Prefix (Aexp)))
 716         or else Nkind (Aexp) = N_Explicit_Dereference
 717       then
 718          Set_Analyzed (Aexp);
 719       end if;
 720    end Convert_To_PAT_Type;
 721
 722    ------------------------------
 723    -- Create_Packed_Array_Type --
 724    ------------------------------
 725
 726    procedure Create_Packed_Array_Type (Typ : Entity_Id) is
 727       Loc      : constant Source_Ptr := Sloc (Typ);
 728       Ctyp     : constant Entity_Id  := Component_Type (Typ);
 729       Csize    : constant Uint       := Component_Size (Typ);
 730
 731       Ancest   : Entity_Id;
 732       PB_Type  : Entity_Id;
 733       PASize   : Uint;
 734       Decl     : Node_Id;
 735       PAT      : Entity_Id;
 736       Len_Dim  : Node_Id;
 737       Len_Expr : Node_Id;
 738       Len_Bits : Uint;
 739       Bits_U1  : Node_Id;
 740       PAT_High : Node_Id;
 741       Btyp     : Entity_Id;
 742       Lit      : Node_Id;
 743
 744       procedure Install_PAT;
 745       --  This procedure is called with Decl set to the declaration for the
 746       --  packed array type. It creates the type and installs it as required.
 747
 748       procedure Set_PB_Type;
 749       --  Sets PB_Type to Packed_Bytes{1,2,4} as required by the alignment
 750       --  requirements (see documentation in the spec of this package).
 751
 752       -----------------
 753       -- Install_PAT --
 754       -----------------
 755
 756       procedure Install_PAT is
 757          Pushed_Scope : Boolean := False;
 758
 759       begin
 760          --  We do not want to put the declaration we have created in the tree
 761          --  since it is often hard, and sometimes impossible to find a proper
 762          --  place for it (the impossible case arises for a packed array type
 763          --  with bounds depending on the discriminant, a declaration cannot
 764          --  be put inside the record, and the reference to the discriminant
 765          --  cannot be outside the record).
 766
 767          --  The solution is to analyze the declaration while temporarily
 768          --  attached to the tree at an appropriate point, and then we install
 769          --  the resulting type as an Itype in the packed array type field of
 770          --  the original type, so that no explicit declaration is required.
 771
 772          --  Note: the packed type is created in the scope of its parent
 773          --  type. There are at least some cases where the current scope
 774          --  is deeper, and so when this is the case, we temporarily reset
 775          --  the scope for the definition. This is clearly safe, since the
 776          --  first use of the packed array type will be the implicit
 777          --  reference from the corresponding unpacked type when it is
 778          --  elaborated.
 779
 780          if Is_Itype (Typ) then
 781             Set_Parent (Decl, Associated_Node_For_Itype (Typ));
 782          else
 783             Set_Parent (Decl, Declaration_Node (Typ));
 784          end if;
 785
 786          if Scope (Typ) /= Current_Scope then
 787             Push_Scope (Scope (Typ));
 788             Pushed_Scope := True;
 789          end if;
 790
 791          Set_Is_Itype (PAT, True);
 792          Set_Packed_Array_Type (Typ, PAT);
 793          Analyze (Decl, Suppress => All_Checks);
 794
 795          if Pushed_Scope then
 796             Pop_Scope;
 797          end if;
 798
 799          --  Set Esize and RM_Size to the actual size of the packed object
 800          --  Do not reset RM_Size if already set, as happens in the case of
 801          --  a modular type.
 802
 803          if Unknown_Esize (PAT) then
 804             Set_Esize (PAT, PASize);
 805          end if;
 806
 807          if Unknown_RM_Size (PAT) then
 808             Set_RM_Size (PAT, PASize);
 809          end if;
 810
 811          Adjust_Esize_Alignment (PAT);
 812
 813          --  Set remaining fields of packed array type
 814
 815          Init_Alignment                (PAT);
 816          Set_Parent                    (PAT, Empty);
 817          Set_Associated_Node_For_Itype (PAT, Typ);
 818          Set_Is_Packed_Array_Type      (PAT, True);
 819          Set_Original_Array_Type       (PAT, Typ);
 820
 821          --  We definitely do not want to delay freezing for packed array
 822          --  types. This is of particular importance for the itypes that
 823          --  are generated for record components depending on discriminants
 824          --  where there is no place to put the freeze node.
 825
 826          Set_Has_Delayed_Freeze (PAT, False);
 827          Set_Has_Delayed_Freeze (Etype (PAT), False);
 828
 829          --  If we did allocate a freeze node, then clear out the reference
 830          --  since it is obsolete (should we delete the freeze node???)
 831
 832          Set_Freeze_Node (PAT, Empty);
 833          Set_Freeze_Node (Etype (PAT), Empty);
 834       end Install_PAT;
 835
 836       -----------------
 837       -- Set_PB_Type --
 838       -----------------
 839
 840       procedure Set_PB_Type is
 841       begin
 842          --  If the user has specified an explicit alignment for the
 843          --  type or component, take it into account.
 844
 845          if Csize <= 2 or else Csize = 4 or else Csize mod 2 /= 0
 846            or else Alignment (Typ) = 1
 847            or else Component_Alignment (Typ) = Calign_Storage_Unit
 848          then
 849             PB_Type := RTE (RE_Packed_Bytes1);
 850
 851          elsif Csize mod 4 /= 0
 852            or else Alignment (Typ) = 2
 853          then
 854             PB_Type := RTE (RE_Packed_Bytes2);
 855
 856          else
 857             PB_Type := RTE (RE_Packed_Bytes4);
 858          end if;
 859       end Set_PB_Type;
 860
 861    --  Start of processing for Create_Packed_Array_Type
 862
 863    begin
 864       --  If we already have a packed array type, nothing to do
 865
 866       if Present (Packed_Array_Type (Typ)) then
 867          return;
 868       end if;
 869
 870       --  If our immediate ancestor subtype is constrained, and it already
 871       --  has a packed array type, then just share the same type, since the
 872       --  bounds must be the same. If the ancestor is not an array type but
 873       --  a private type, as can happen with multiple instantiations, create
 874       --  a new packed type, to avoid privacy issues.
 875
 876       if Ekind (Typ) = E_Array_Subtype then
 877          Ancest := Ancestor_Subtype (Typ);
 878
 879          if Present (Ancest)
 880            and then Is_Array_Type (Ancest)
 881            and then Is_Constrained (Ancest)
 882            and then Present (Packed_Array_Type (Ancest))
 883          then
 884             Set_Packed_Array_Type (Typ, Packed_Array_Type (Ancest));
 885             return;
 886          end if;
 887       end if;
 888
 889       --  We preset the result type size from the size of the original array
 890       --  type, since this size clearly belongs to the packed array type. The
 891       --  size of the conceptual unpacked type is always set to unknown.
 892
 893       PASize := RM_Size (Typ);
 894
 895       --  Case of an array where at least one index is of an enumeration
 896       --  type with a non-standard representation, but the component size
 897       --  is not appropriate for bit packing. This is the case where we
 898       --  have Is_Packed set (we would never be in this unit otherwise),
 899       --  but Is_Bit_Packed_Array is false.
 900
 901       --  Note that if the component size is appropriate for bit packing,
 902       --  then the circuit for the computation of the subscript properly
 903       --  deals with the non-standard enumeration type case by taking the
 904       --  Pos anyway.
 905
 906       if not Is_Bit_Packed_Array (Typ) then
 907
 908          --  Here we build a declaration:
 909
 910          --    type tttP is array (index1, index2, ...) of component_type
 911
 912          --  where index1, index2, are the index types. These are the same
 913          --  as the index types of the original array, except for the non-
 914          --  standard representation enumeration type case, where we have
 915          --  two subcases.
 916
 917          --  For the unconstrained array case, we use
 918
 919          --    Natural range <>
 920
 921          --  For the constrained case, we use
 922
 923          --    Natural range Enum_Type'Pos (Enum_Type'First) ..
 924          --                  Enum_Type'Pos (Enum_Type'Last);
 925
 926          PAT :=
 927            Make_Defining_Identifier (Loc,
 928              Chars => New_External_Name (Chars (Typ), 'P'));
 929
 930          Set_Packed_Array_Type (Typ, PAT);
 931
 932          declare
 933             Indexes   : constant List_Id := New_List;
 934             Indx      : Node_Id;
 935             Indx_Typ  : Entity_Id;
 936             Enum_Case : Boolean;
 937             Typedef   : Node_Id;
 938
 939          begin
 940             Indx := First_Index (Typ);
 941
 942             while Present (Indx) loop
 943                Indx_Typ := Etype (Indx);
 944
 945                Enum_Case := Is_Enumeration_Type (Indx_Typ)
 946                               and then Has_Non_Standard_Rep (Indx_Typ);
 947
 948                --  Unconstrained case
 949
 950                if not Is_Constrained (Typ) then
 951                   if Enum_Case then
 952                      Indx_Typ := Standard_Natural;
 953                   end if;
 954
 955                   Append_To (Indexes, New_Occurrence_Of (Indx_Typ, Loc));
 956
 957                --  Constrained case
 958
 959                else
 960                   if not Enum_Case then
 961                      Append_To (Indexes, New_Occurrence_Of (Indx_Typ, Loc));
 962
 963                   else
 964                      Append_To (Indexes,
 965                        Make_Subtype_Indication (Loc,
 966                          Subtype_Mark =>
 967                            New_Occurrence_Of (Standard_Natural, Loc),
 968                          Constraint =>
 969                            Make_Range_Constraint (Loc,
 970                              Range_Expression =>
 971                                Make_Range (Loc,
 972                                  Low_Bound =>
 973                                    Make_Attribute_Reference (Loc,
 974                                      Prefix         =>
 975                                        New_Occurrence_Of (Indx_Typ, Loc),
 976                                      Attribute_Name => Name_Pos,
 977                                      Expressions    => New_List (
 978                                        Make_Attribute_Reference (Loc,
 979                                          Prefix         =>
 980                                            New_Occurrence_Of (Indx_Typ, Loc),
 981                                          Attribute_Name => Name_First))),
 982
 983                                  High_Bound =>
 984                                    Make_Attribute_Reference (Loc,
 985                                      Prefix         =>
 986                                        New_Occurrence_Of (Indx_Typ, Loc),
 987                                      Attribute_Name => Name_Pos,
 988                                      Expressions    => New_List (
 989                                        Make_Attribute_Reference (Loc,
 990                                          Prefix         =>
 991                                            New_Occurrence_Of (Indx_Typ, Loc),
 992                                          Attribute_Name => Name_Last)))))));
 993
 994                   end if;
 995                end if;
 996
 997                Next_Index (Indx);
 998             end loop;
 999
1000             if not Is_Constrained (Typ) then
1001                Typedef :=
1002                  Make_Unconstrained_Array_Definition (Loc,
1003                    Subtype_Marks => Indexes,
1004                    Component_Definition =>
1005                      Make_Component_Definition (Loc,
1006                        Aliased_Present    => False,
1007                        Subtype_Indication =>
1008                           New_Occurrence_Of (Ctyp, Loc)));
1009
1010             else
1011                Typedef :=
1012                   Make_Constrained_Array_Definition (Loc,
1013                     Discrete_Subtype_Definitions => Indexes,
1014                     Component_Definition =>
1015                       Make_Component_Definition (Loc,
1016                         Aliased_Present    => False,
1017                         Subtype_Indication =>
1018                           New_Occurrence_Of (Ctyp, Loc)));
1019             end if;
1020
1021             Decl :=
1022               Make_Full_Type_Declaration (Loc,
1023                 Defining_Identifier => PAT,
1024                 Type_Definition => Typedef);
1025          end;
1026
1027          --  Set type as packed array type and install it
1028
1029          Set_Is_Packed_Array_Type (PAT);
1030          Install_PAT;
1031          return;
1032
1033       --  Case of bit-packing required for unconstrained array. We create
1034       --  a subtype that is equivalent to use Packed_Bytes{1,2,4} as needed.
1035
1036       elsif not Is_Constrained (Typ) then
1037          PAT :=
1038            Make_Defining_Identifier (Loc,
1039              Chars => Make_Packed_Array_Type_Name (Typ, Csize));
1040
1041          Set_Packed_Array_Type (Typ, PAT);
1042          Set_PB_Type;
1043
1044          Decl :=
1045            Make_Subtype_Declaration (Loc,
1046              Defining_Identifier => PAT,
1047                Subtype_Indication => New_Occurrence_Of (PB_Type, Loc));
1048          Install_PAT;
1049          return;
1050
1051       --  Remaining code is for the case of bit-packing for constrained array
1052
1053       --  The name of the packed array subtype is
1054
1055       --    ttt___Xsss
1056
1057       --  where sss is the component size in bits and ttt is the name of
1058       --  the parent packed type.
1059
1060       else
1061          PAT :=
1062            Make_Defining_Identifier (Loc,
1063              Chars => Make_Packed_Array_Type_Name (Typ, Csize));
1064
1065          Set_Packed_Array_Type (Typ, PAT);
1066
1067          --  Build an expression for the length of the array in bits.
1068          --  This is the product of the length of each of the dimensions
1069
1070          declare
1071             J : Nat := 1;
1072
1073          begin
1074             Len_Expr := Empty; -- suppress junk warning
1075
1076             loop
1077                Len_Dim :=
1078                  Make_Attribute_Reference (Loc,
1079                    Attribute_Name => Name_Length,
1080                    Prefix         => New_Occurrence_Of (Typ, Loc),
1081                    Expressions    => New_List (
1082                      Make_Integer_Literal (Loc, J)));
1083
1084                if J = 1 then
1085                   Len_Expr := Len_Dim;
1086
1087                else
1088                   Len_Expr :=
1089                     Make_Op_Multiply (Loc,
1090                       Left_Opnd  => Len_Expr,
1091                       Right_Opnd => Len_Dim);
1092                end if;
1093
1094                J := J + 1;
1095                exit when J > Number_Dimensions (Typ);
1096             end loop;
1097          end;
1098
1099          --  Temporarily attach the length expression to the tree and analyze
1100          --  and resolve it, so that we can test its value. We assume that the
1101          --  total length fits in type Integer. This expression may involve
1102          --  discriminants, so we treat it as a default/per-object expression.
1103
1104          Set_Parent (Len_Expr, Typ);
1105          Preanalyze_Spec_Expression (Len_Expr, Standard_Long_Long_Integer);
1106
1107          --  Use a modular type if possible. We can do this if we have
1108          --  static bounds, and the length is small enough, and the length
1109          --  is not zero. We exclude the zero length case because the size
1110          --  of things is always at least one, and the zero length object
1111          --  would have an anomalous size.
1112
1113          if Compile_Time_Known_Value (Len_Expr) then
1114             Len_Bits := Expr_Value (Len_Expr) * Csize;
1115
1116             --  Check for size known to be too large
1117
1118             if Len_Bits >
1119               Uint_2 ** (Standard_Integer_Size - 1) * System_Storage_Unit
1120             then
1121                if System_Storage_Unit = 8 then
1122                   Error_Msg_N
1123                     ("packed array size cannot exceed " &
1124                      "Integer''Last bytes", Typ);
1125                else
1126                   Error_Msg_N
1127                     ("packed array size cannot exceed " &
1128                      "Integer''Last storage units", Typ);
1129                end if;
1130
1131                --  Reset length to arbitrary not too high value to continue
1132
1133                Len_Expr := Make_Integer_Literal (Loc, 65535);
1134                Analyze_And_Resolve (Len_Expr, Standard_Long_Long_Integer);
1135             end if;
1136
1137             --  We normally consider small enough to mean no larger than the
1138             --  value of System_Max_Binary_Modulus_Power, checking that in the
1139             --  case of values longer than word size, we have long shifts.
1140
1141             if Len_Bits > 0
1142               and then
1143                 (Len_Bits <= System_Word_Size
1144                    or else (Len_Bits <= System_Max_Binary_Modulus_Power
1145                               and then Support_Long_Shifts_On_Target))
1146             then
1147                --  We can use the modular type, it has the form:
1148
1149                --    subtype tttPn is btyp
1150                --      range 0 .. 2 ** ((Typ'Length (1)
1151                --                * ... * Typ'Length (n)) * Csize) - 1;
1152
1153                --  The bounds are statically known, and btyp is one of the
1154                --  unsigned types, depending on the length.
1155
1156                if Len_Bits <= Standard_Short_Short_Integer_Size then
1157                   Btyp := RTE (RE_Short_Short_Unsigned);
1158
1159                elsif Len_Bits <= Standard_Short_Integer_Size then
1160                   Btyp := RTE (RE_Short_Unsigned);
1161
1162                elsif Len_Bits <= Standard_Integer_Size then
1163                   Btyp := RTE (RE_Unsigned);
1164
1165                elsif Len_Bits <= Standard_Long_Integer_Size then
1166                   Btyp := RTE (RE_Long_Unsigned);
1167
1168                else
1169                   Btyp := RTE (RE_Long_Long_Unsigned);
1170                end if;
1171
1172                Lit := Make_Integer_Literal (Loc, 2 ** Len_Bits - 1);
1173                Set_Print_In_Hex (Lit);
1174
1175                Decl :=
1176                  Make_Subtype_Declaration (Loc,
1177                    Defining_Identifier => PAT,
1178                      Subtype_Indication =>
1179                        Make_Subtype_Indication (Loc,
1180                          Subtype_Mark => New_Occurrence_Of (Btyp, Loc),
1181
1182                          Constraint =>
1183                            Make_Range_Constraint (Loc,
1184                              Range_Expression =>
1185                                Make_Range (Loc,
1186                                  Low_Bound =>
1187                                    Make_Integer_Literal (Loc, 0),
1188                                  High_Bound => Lit))));
1189
1190                if PASize = Uint_0 then
1191                   PASize := Len_Bits;
1192                end if;
1193
1194                Install_PAT;
1195
1196                --  Propagate a given alignment to the modular type. This can
1197                --  cause it to be under-aligned, but that's OK.
1198
1199                if Present (Alignment_Clause (Typ)) then
1200                   Set_Alignment (PAT, Alignment (Typ));
1201                end if;
1202
1203                return;
1204             end if;
1205          end if;
1206
1207          --  Could not use a modular type, for all other cases, we build
1208          --  a packed array subtype:
1209
1210          --    subtype tttPn is
1211          --      System.Packed_Bytes{1,2,4} (0 .. (Bits + 7) / 8 - 1);
1212
1213          --  Bits is the length of the array in bits
1214
1215          Set_PB_Type;
1216
1217          Bits_U1 :=
1218            Make_Op_Add (Loc,
1219              Left_Opnd =>
1220                Make_Op_Multiply (Loc,
1221                  Left_Opnd  =>
1222                    Make_Integer_Literal (Loc, Csize),
1223                  Right_Opnd => Len_Expr),
1224
1225              Right_Opnd =>
1226                Make_Integer_Literal (Loc, 7));
1227
1228          Set_Paren_Count (Bits_U1, 1);
1229
1230          PAT_High :=
1231            Make_Op_Subtract (Loc,
1232              Left_Opnd =>
1233                Make_Op_Divide (Loc,
1234                  Left_Opnd => Bits_U1,
1235                  Right_Opnd => Make_Integer_Literal (Loc, 8)),
1236              Right_Opnd => Make_Integer_Literal (Loc, 1));
1237
1238          Decl :=
1239            Make_Subtype_Declaration (Loc,
1240              Defining_Identifier => PAT,
1241                Subtype_Indication =>
1242                  Make_Subtype_Indication (Loc,
1243                    Subtype_Mark => New_Occurrence_Of (PB_Type, Loc),
1244                    Constraint =>
1245                      Make_Index_Or_Discriminant_Constraint (Loc,
1246                        Constraints => New_List (
1247                          Make_Range (Loc,
1248                            Low_Bound =>
1249                              Make_Integer_Literal (Loc, 0),
1250                            High_Bound =>
1251                              Convert_To (Standard_Integer, PAT_High))))));
1252
1253          Install_PAT;
1254
1255          --  Currently the code in this unit requires that packed arrays
1256          --  represented by non-modular arrays of bytes be on a byte
1257          --  boundary for bit sizes handled by System.Pack_nn units.
1258          --  That's because these units assume the array being accessed
1259          --  starts on a byte boundary.
1260
1261          if Get_Id (UI_To_Int (Csize)) /= RE_Null then
1262             Set_Must_Be_On_Byte_Boundary (Typ);
1263          end if;
1264       end if;
1265    end Create_Packed_Array_Type;
1266
1267    -----------------------------------
1268    -- Expand_Bit_Packed_Element_Set --
1269    -----------------------------------
1270
1271    procedure Expand_Bit_Packed_Element_Set (N : Node_Id) is
1272       Loc : constant Source_Ptr := Sloc (N);
1273       Lhs : constant Node_Id    := Name (N);
1274
1275       Ass_OK : constant Boolean := Assignment_OK (Lhs);
1276       --  Used to preserve assignment OK status when assignment is rewritten
1277
1278       Rhs : Node_Id := Expression (N);
1279       --  Initially Rhs is the right hand side value, it will be replaced
1280       --  later by an appropriate unchecked conversion for the assignment.
1281
1282       Obj    : Node_Id;
1283       Atyp   : Entity_Id;
1284       PAT    : Entity_Id;
1285       Ctyp   : Entity_Id;
1286       Csiz   : Int;
1287       Cmask  : Uint;
1288
1289       Shift : Node_Id;
1290       --  The expression for the shift value that is required
1291
1292       Shift_Used : Boolean := False;
1293       --  Set True if Shift has been used in the generated code at least
1294       --  once, so that it must be duplicated if used again
1295
1296       New_Lhs : Node_Id;
1297       New_Rhs : Node_Id;
1298
1299       Rhs_Val_Known : Boolean;
1300       Rhs_Val       : Uint;
1301       --  If the value of the right hand side as an integer constant is
1302       --  known at compile time, Rhs_Val_Known is set True, and Rhs_Val
1303       --  contains the value. Otherwise Rhs_Val_Known is set False, and
1304       --  the Rhs_Val is undefined.
1305
1306       function Get_Shift return Node_Id;
1307       --  Function used to get the value of Shift, making sure that it
1308       --  gets duplicated if the function is called more than once.
1309
1310       ---------------
1311       -- Get_Shift --
1312       ---------------
1313
1314       function Get_Shift return Node_Id is
1315       begin
1316          --  If we used the shift value already, then duplicate it. We
1317          --  set a temporary parent in case actions have to be inserted.
1318
1319          if Shift_Used then
1320             Set_Parent (Shift, N);
1321             return Duplicate_Subexpr_No_Checks (Shift);
1322
1323          --  If first time, use Shift unchanged, and set flag for first use
1324
1325          else
1326             Shift_Used := True;
1327             return Shift;
1328          end if;
1329       end Get_Shift;
1330
1331    --  Start of processing for Expand_Bit_Packed_Element_Set
1332
1333    begin
1334       pragma Assert (Is_Bit_Packed_Array (Etype (Prefix (Lhs))));
1335
1336       Obj := Relocate_Node (Prefix (Lhs));
1337       Convert_To_Actual_Subtype (Obj);
1338       Atyp := Etype (Obj);
1339       PAT  := Packed_Array_Type (Atyp);
1340       Ctyp := Component_Type (Atyp);
1341       Csiz := UI_To_Int (Component_Size (Atyp));
1342
1343       --  We convert the right hand side to the proper subtype to ensure
1344       --  that an appropriate range check is made (since the normal range
1345       --  check from assignment will be lost in the transformations). This
1346       --  conversion is analyzed immediately so that subsequent processing
1347       --  can work with an analyzed Rhs (and e.g. look at its Etype)
1348
1349       --  If the right-hand side is a string literal, create a temporary for
1350       --  it, constant-folding is not ready to wrap the bit representation
1351       --  of a string literal.
1352
1353       if Nkind (Rhs) = N_String_Literal then
1354          declare
1355             Decl : Node_Id;
1356          begin
1357             Decl :=
1358               Make_Object_Declaration (Loc,
1359                 Defining_Identifier => Make_Temporary (Loc, 'T', Rhs),
1360                 Object_Definition   => New_Occurrence_Of (Ctyp, Loc),
1361                 Expression          => New_Copy_Tree (Rhs));
1362
1363             Insert_Actions (N, New_List (Decl));
1364             Rhs := New_Occurrence_Of (Defining_Identifier (Decl), Loc);
1365          end;
1366       end if;
1367
1368       Rhs := Convert_To (Ctyp, Rhs);
1369       Set_Parent (Rhs, N);
1370
1371       --  If we are building the initialization procedure for a packed array,
1372       --  and Initialize_Scalars is enabled, each component assignment is an
1373       --  out-of-range value by design.  Compile this value without checks,
1374       --  because a call to the array init_proc must not raise an exception.
1375
1376       if Within_Init_Proc
1377         and then Initialize_Scalars
1378       then
1379          Analyze_And_Resolve (Rhs, Ctyp, Suppress => All_Checks);
1380       else
1381          Analyze_And_Resolve (Rhs, Ctyp);
1382       end if;
1383
1384       --  For the AAMP target, indexing of certain packed array is passed
1385       --  through to the back end without expansion, because the expansion
1386       --  results in very inefficient code on that target. This allows the
1387       --  GNAAMP back end to generate specialized macros that support more
1388       --  efficient indexing of packed arrays with components having sizes
1389       --  that are small powers of two.
1390
1391       if AAMP_On_Target
1392         and then (Csiz = 1 or else Csiz = 2 or else Csiz = 4)
1393       then
1394          return;
1395       end if;
1396
1397       --  Case of component size 1,2,4 or any component size for the modular
1398       --  case. These are the cases for which we can inline the code.
1399
1400       if Csiz = 1 or else Csiz = 2 or else Csiz = 4
1401         or else (Present (PAT) and then Is_Modular_Integer_Type (PAT))
1402       then
1403          Setup_Inline_Packed_Array_Reference (Lhs, Atyp, Obj, Cmask, Shift);
1404
1405          --  The statement to be generated is:
1406
1407          --    Obj := atyp!((Obj and Mask1) or (shift_left (rhs, shift)))
1408
1409          --      where mask1 is obtained by shifting Cmask left Shift bits
1410          --      and then complementing the result.
1411
1412          --      the "and Mask1" is omitted if rhs is constant and all 1 bits
1413
1414          --      the "or ..." is omitted if rhs is constant and all 0 bits
1415
1416          --      rhs is converted to the appropriate type
1417
1418          --      The result is converted back to the array type, since
1419          --      otherwise we lose knowledge of the packed nature.
1420
1421          --  Determine if right side is all 0 bits or all 1 bits
1422
1423          if Compile_Time_Known_Value (Rhs) then
1424             Rhs_Val       := Expr_Rep_Value (Rhs);
1425             Rhs_Val_Known := True;
1426
1427          --  The following test catches the case of an unchecked conversion
1428          --  of an integer literal. This results from optimizing aggregates
1429          --  of packed types.
1430
1431          elsif Nkind (Rhs) = N_Unchecked_Type_Conversion
1432            and then Compile_Time_Known_Value (Expression (Rhs))
1433          then
1434             Rhs_Val       := Expr_Rep_Value (Expression (Rhs));
1435             Rhs_Val_Known := True;
1436
1437          else
1438             Rhs_Val       := No_Uint;
1439             Rhs_Val_Known := False;
1440          end if;
1441
1442          --  Some special checks for the case where the right hand value
1443          --  is known at compile time. Basically we have to take care of
1444          --  the implicit conversion to the subtype of the component object.
1445
1446          if Rhs_Val_Known then
1447
1448             --  If we have a biased component type then we must manually do
1449             --  the biasing, since we are taking responsibility in this case
1450             --  for constructing the exact bit pattern to be used.
1451
1452             if Has_Biased_Representation (Ctyp) then
1453                Rhs_Val := Rhs_Val - Expr_Rep_Value (Type_Low_Bound (Ctyp));
1454             end if;
1455
1456             --  For a negative value, we manually convert the twos complement
1457             --  value to a corresponding unsigned value, so that the proper
1458             --  field width is maintained. If we did not do this, we would
1459             --  get too many leading sign bits later on.
1460
1461             if Rhs_Val < 0 then
1462                Rhs_Val := 2 ** UI_From_Int (Csiz) + Rhs_Val;
1463             end if;
1464          end if;
1465
1466          --  Now create copies removing side effects. Note that in some
1467          --  complex cases, this may cause the fact that we have already
1468          --  set a packed array type on Obj to get lost. So we save the
1469          --  type of Obj, and make sure it is reset properly.
1470
1471          declare
1472             T : constant Entity_Id := Etype (Obj);
1473          begin
1474             New_Lhs := Duplicate_Subexpr (Obj, True);
1475             New_Rhs := Duplicate_Subexpr_No_Checks (Obj);
1476             Set_Etype (Obj, T);
1477             Set_Etype (New_Lhs, T);
1478             Set_Etype (New_Rhs, T);
1479          end;
1480
1481          --  First we deal with the "and"
1482
1483          if not Rhs_Val_Known or else Rhs_Val /= Cmask then
1484             declare
1485                Mask1 : Node_Id;
1486                Lit   : Node_Id;
1487
1488             begin
1489                if Compile_Time_Known_Value (Shift) then
1490                   Mask1 :=
1491                     Make_Integer_Literal (Loc,
1492                       Modulus (Etype (Obj)) - 1 -
1493                                  (Cmask * (2 ** Expr_Value (Get_Shift))));
1494                   Set_Print_In_Hex (Mask1);
1495
1496                else
1497                   Lit := Make_Integer_Literal (Loc, Cmask);
1498                   Set_Print_In_Hex (Lit);
1499                   Mask1 :=
1500                     Make_Op_Not (Loc,
1501                       Right_Opnd => Make_Shift_Left (Lit, Get_Shift));
1502                end if;
1503
1504                New_Rhs :=
1505                  Make_Op_And (Loc,
1506                    Left_Opnd  => New_Rhs,
1507                    Right_Opnd => Mask1);
1508             end;
1509          end if;
1510
1511          --  Then deal with the "or"
1512
1513          if not Rhs_Val_Known or else Rhs_Val /= 0 then
1514             declare
1515                Or_Rhs : Node_Id;
1516
1517                procedure Fixup_Rhs;
1518                --  Adjust Rhs by bias if biased representation for components
1519                --  or remove extraneous high order sign bits if signed.
1520
1521                procedure Fixup_Rhs is
1522                   Etyp : constant Entity_Id := Etype (Rhs);
1523
1524                begin
1525                   --  For biased case, do the required biasing by simply
1526                   --  converting to the biased subtype (the conversion
1527                   --  will generate the required bias).
1528
1529                   if Has_Biased_Representation (Ctyp) then
1530                      Rhs := Convert_To (Ctyp, Rhs);
1531
1532                   --  For a signed integer type that is not biased, generate
1533                   --  a conversion to unsigned to strip high order sign bits.
1534
1535                   elsif Is_Signed_Integer_Type (Ctyp) then
1536                      Rhs := Unchecked_Convert_To (RTE (Bits_Id (Csiz)), Rhs);
1537                   end if;
1538
1539                   --  Set Etype, since it can be referenced before the
1540                   --  node is completely analyzed.
1541
1542                   Set_Etype (Rhs, Etyp);
1543
1544                   --  We now need to do an unchecked conversion of the
1545                   --  result to the target type, but it is important that
1546                   --  this conversion be a right justified conversion and
1547                   --  not a left justified conversion.
1548
1549                   Rhs := RJ_Unchecked_Convert_To (Etype (Obj), Rhs);
1550
1551                end Fixup_Rhs;
1552
1553             begin
1554                if Rhs_Val_Known
1555                  and then Compile_Time_Known_Value (Get_Shift)
1556                then
1557                   Or_Rhs :=
1558                     Make_Integer_Literal (Loc,
1559                       Rhs_Val * (2 ** Expr_Value (Get_Shift)));
1560                   Set_Print_In_Hex (Or_Rhs);
1561
1562                else
1563                   --  We have to convert the right hand side to Etype (Obj).
1564                   --  A special case arises if what we have now is a Val
1565                   --  attribute reference whose expression type is Etype (Obj).
1566                   --  This happens for assignments of fields from the same
1567                   --  array. In this case we get the required right hand side
1568                   --  by simply removing the inner attribute reference.
1569
1570                   if Nkind (Rhs) = N_Attribute_Reference
1571                     and then Attribute_Name (Rhs) = Name_Val
1572                     and then Etype (First (Expressions (Rhs))) = Etype (Obj)
1573                   then
1574                      Rhs := Relocate_Node (First (Expressions (Rhs)));
1575                      Fixup_Rhs;
1576
1577                   --  If the value of the right hand side is a known integer
1578                   --  value, then just replace it by an untyped constant,
1579                   --  which will be properly retyped when we analyze and
1580                   --  resolve the expression.
1581
1582                   elsif Rhs_Val_Known then
1583
1584                      --  Note that Rhs_Val has already been normalized to
1585                      --  be an unsigned value with the proper number of bits.
1586
1587                      Rhs :=
1588                        Make_Integer_Literal (Loc, Rhs_Val);
1589
1590                   --  Otherwise we need an unchecked conversion
1591
1592                   else
1593                      Fixup_Rhs;
1594                   end if;
1595
1596                   Or_Rhs := Make_Shift_Left (Rhs, Get_Shift);
1597                end if;
1598
1599                if Nkind (New_Rhs) = N_Op_And then
1600                   Set_Paren_Count (New_Rhs, 1);
1601                end if;
1602
1603                New_Rhs :=
1604                  Make_Op_Or (Loc,
1605                    Left_Opnd  => New_Rhs,
1606                    Right_Opnd => Or_Rhs);
1607             end;
1608          end if;
1609
1610          --  Now do the rewrite
1611
1612          Rewrite (N,
1613            Make_Assignment_Statement (Loc,
1614              Name       => New_Lhs,
1615              Expression =>
1616                Unchecked_Convert_To (Etype (New_Lhs), New_Rhs)));
1617          Set_Assignment_OK (Name (N), Ass_OK);
1618
1619       --  All other component sizes for non-modular case
1620
1621       else
1622          --  We generate
1623
1624          --    Set_nn (Arr'address, Subscr, Bits_nn!(Rhs))
1625
1626          --  where Subscr is the computed linear subscript
1627
1628          declare
1629             Bits_nn : constant Entity_Id := RTE (Bits_Id (Csiz));
1630             Set_nn  : Entity_Id;
1631             Subscr  : Node_Id;
1632             Atyp    : Entity_Id;
1633
1634          begin
1635             if No (Bits_nn) then
1636
1637                --  Error, most likely High_Integrity_Mode restriction
1638
1639                return;
1640             end if;
1641
1642             --  Acquire proper Set entity. We use the aligned or unaligned
1643             --  case as appropriate.
1644
1645             if Known_Aligned_Enough (Obj, Csiz) then
1646                Set_nn := RTE (Set_Id (Csiz));
1647             else
1648                Set_nn := RTE (SetU_Id (Csiz));
1649             end if;
1650
1651             --  Now generate the set reference
1652
1653             Obj := Relocate_Node (Prefix (Lhs));
1654             Convert_To_Actual_Subtype (Obj);
1655             Atyp := Etype (Obj);
1656             Compute_Linear_Subscript (Atyp, Lhs, Subscr);
1657
1658             --  Below we must make the assumption that Obj is
1659             --  at least byte aligned, since otherwise its address
1660             --  cannot be taken. The assumption holds since the
1661             --  only arrays that can be misaligned are small packed
1662             --  arrays which are implemented as a modular type, and
1663             --  that is not the case here.
1664
1665             Rewrite (N,
1666               Make_Procedure_Call_Statement (Loc,
1667                   Name => New_Occurrence_Of (Set_nn, Loc),
1668                   Parameter_Associations => New_List (
1669                     Make_Attribute_Reference (Loc,
1670                       Prefix         => Obj,
1671                       Attribute_Name => Name_Address),
1672                     Subscr,
1673                     Unchecked_Convert_To (Bits_nn,
1674                       Convert_To (Ctyp, Rhs)))));
1675
1676          end;
1677       end if;
1678
1679       Analyze (N, Suppress => All_Checks);
1680    end Expand_Bit_Packed_Element_Set;
1681
1682    -------------------------------------
1683    -- Expand_Packed_Address_Reference --
1684    -------------------------------------
1685
1686    procedure Expand_Packed_Address_Reference (N : Node_Id) is
1687       Loc    : constant Source_Ptr := Sloc (N);
1688       Base   : Node_Id;
1689       Offset : Node_Id;
1690
1691    begin
1692       --  We build an expression that has the form
1693
1694       --    outer_object'Address
1695       --      + (linear-subscript * component_size  for each array reference
1696       --      +  field'Bit_Position                 for each record field
1697       --      +  ...
1698       --      +  ...) / Storage_Unit;
1699
1700       Get_Base_And_Bit_Offset (Prefix (N), Base, Offset);
1701
1702       Rewrite (N,
1703         Unchecked_Convert_To (RTE (RE_Address),
1704           Make_Op_Add (Loc,
1705             Left_Opnd =>
1706               Unchecked_Convert_To (RTE (RE_Integer_Address),
1707                 Make_Attribute_Reference (Loc,
1708                   Prefix         => Base,
1709                   Attribute_Name => Name_Address)),
1710
1711             Right_Opnd =>
1712               Unchecked_Convert_To (RTE (RE_Integer_Address),
1713                 Make_Op_Divide (Loc,
1714                   Left_Opnd => Offset,
1715                   Right_Opnd =>
1716                     Make_Integer_Literal (Loc, System_Storage_Unit))))));
1717
1718       Analyze_And_Resolve (N, RTE (RE_Address));
1719    end Expand_Packed_Address_Reference;
1720
1721    ---------------------------------
1722    -- Expand_Packed_Bit_Reference --
1723    ---------------------------------
1724
1725    procedure Expand_Packed_Bit_Reference (N : Node_Id) is
1726       Loc    : constant Source_Ptr := Sloc (N);
1727       Base   : Node_Id;
1728       Offset : Node_Id;
1729
1730    begin
1731       --  We build an expression that has the form
1732
1733       --    (linear-subscript * component_size      for each array reference
1734       --      +  field'Bit_Position                 for each record field
1735       --      +  ...
1736       --      +  ...) mod Storage_Unit;
1737
1738       Get_Base_And_Bit_Offset (Prefix (N), Base, Offset);
1739
1740       Rewrite (N,
1741         Unchecked_Convert_To (Universal_Integer,
1742           Make_Op_Mod (Loc,
1743             Left_Opnd => Offset,
1744             Right_Opnd => Make_Integer_Literal (Loc, System_Storage_Unit))));
1745
1746       Analyze_And_Resolve (N, Universal_Integer);
1747    end Expand_Packed_Bit_Reference;
1748
1749    ------------------------------------
1750    -- Expand_Packed_Boolean_Operator --
1751    ------------------------------------
1752
1753    --  This routine expands "a op b" for the packed cases
1754
1755    procedure Expand_Packed_Boolean_Operator (N : Node_Id) is
1756       Loc : constant Source_Ptr := Sloc (N);
1757       Typ : constant Entity_Id  := Etype (N);
1758       L   : constant Node_Id    := Relocate_Node (Left_Opnd  (N));
1759       R   : constant Node_Id    := Relocate_Node (Right_Opnd (N));
1760
1761       Ltyp : Entity_Id;
1762       Rtyp : Entity_Id;
1763       PAT  : Entity_Id;
1764
1765    begin
1766       Convert_To_Actual_Subtype (L);
1767       Convert_To_Actual_Subtype (R);
1768
1769       Ensure_Defined (Etype (L), N);
1770       Ensure_Defined (Etype (R), N);
1771
1772       Apply_Length_Check (R, Etype (L));
1773
1774       Ltyp := Etype (L);
1775       Rtyp := Etype (R);
1776
1777       --  Deal with silly case of XOR where the subcomponent has a range
1778       --  True .. True where an exception must be raised.
1779
1780       if Nkind (N) = N_Op_Xor then
1781          Silly_Boolean_Array_Xor_Test (N, Rtyp);
1782       end if;
1783
1784       --  Now that that silliness is taken care of, get packed array type
1785
1786       Convert_To_PAT_Type (L);
1787       Convert_To_PAT_Type (R);
1788
1789       PAT := Etype (L);
1790
1791       --  For the modular case, we expand a op b into
1792
1793       --    rtyp!(pat!(a) op pat!(b))
1794
1795       --  where rtyp is the Etype of the left operand. Note that we do not
1796       --  convert to the base type, since this would be unconstrained, and
1797       --  hence not have a corresponding packed array type set.
1798
1799       --  Note that both operands must be modular for this code to be used
1800
1801       if Is_Modular_Integer_Type (PAT)
1802            and then
1803          Is_Modular_Integer_Type (Etype (R))
1804       then
1805          declare
1806             P : Node_Id;
1807
1808          begin
1809             if Nkind (N) = N_Op_And then
1810                P := Make_Op_And (Loc, L, R);
1811
1812             elsif Nkind (N) = N_Op_Or then
1813                P := Make_Op_Or  (Loc, L, R);
1814
1815             else -- Nkind (N) = N_Op_Xor
1816                P := Make_Op_Xor (Loc, L, R);
1817             end if;
1818
1819             Rewrite (N, Unchecked_Convert_To (Ltyp, P));
1820          end;
1821
1822       --  For the array case, we insert the actions
1823
1824       --    Result : Ltype;
1825
1826       --    System.Bit_Ops.Bit_And/Or/Xor
1827       --     (Left'Address,
1828       --      Ltype'Length * Ltype'Component_Size;
1829       --      Right'Address,
1830       --      Rtype'Length * Rtype'Component_Size
1831       --      Result'Address);
1832
1833       --  where Left and Right are the Packed_Bytes{1,2,4} operands and
1834       --  the second argument and fourth arguments are the lengths of the
1835       --  operands in bits. Then we replace the expression by a reference
1836       --  to Result.
1837
1838       --  Note that if we are mixing a modular and array operand, everything
1839       --  works fine, since we ensure that the modular representation has the
1840       --  same physical layout as the array representation (that's what the
1841       --  left justified modular stuff in the big-endian case is about).
1842
1843       else
1844          declare
1845             Result_Ent : constant Entity_Id := Make_Temporary (Loc, 'T');
1846             E_Id       : RE_Id;
1847
1848          begin
1849             if Nkind (N) = N_Op_And then
1850                E_Id := RE_Bit_And;
1851
1852             elsif Nkind (N) = N_Op_Or then
1853                E_Id := RE_Bit_Or;
1854
1855             else -- Nkind (N) = N_Op_Xor
1856                E_Id := RE_Bit_Xor;
1857             end if;
1858
1859             Insert_Actions (N, New_List (
1860
1861               Make_Object_Declaration (Loc,
1862                 Defining_Identifier => Result_Ent,
1863                 Object_Definition => New_Occurrence_Of (Ltyp, Loc)),
1864
1865               Make_Procedure_Call_Statement (Loc,
1866                 Name => New_Occurrence_Of (RTE (E_Id), Loc),
1867                   Parameter_Associations => New_List (
1868
1869                     Make_Byte_Aligned_Attribute_Reference (Loc,
1870                       Prefix         => L,
1871                       Attribute_Name => Name_Address),
1872
1873                     Make_Op_Multiply (Loc,
1874                       Left_Opnd =>
1875                         Make_Attribute_Reference (Loc,
1876                           Prefix         =>
1877                             New_Occurrence_Of
1878                               (Etype (First_Index (Ltyp)), Loc),
1879                           Attribute_Name => Name_Range_Length),
1880
1881                       Right_Opnd =>
1882                         Make_Integer_Literal (Loc, Component_Size (Ltyp))),
1883
1884                     Make_Byte_Aligned_Attribute_Reference (Loc,
1885                       Prefix         => R,
1886                       Attribute_Name => Name_Address),
1887
1888                     Make_Op_Multiply (Loc,
1889                       Left_Opnd =>
1890                         Make_Attribute_Reference (Loc,
1891                           Prefix         =>
1892                             New_Occurrence_Of
1893                               (Etype (First_Index (Rtyp)), Loc),
1894                           Attribute_Name => Name_Range_Length),
1895
1896                       Right_Opnd =>
1897                         Make_Integer_Literal (Loc, Component_Size (Rtyp))),
1898
1899                     Make_Byte_Aligned_Attribute_Reference (Loc,
1900                       Prefix => New_Occurrence_Of (Result_Ent, Loc),
1901                       Attribute_Name => Name_Address)))));
1902
1903             Rewrite (N,
1904               New_Occurrence_Of (Result_Ent, Loc));
1905          end;
1906       end if;
1907
1908       Analyze_And_Resolve (N, Typ, Suppress => All_Checks);
1909    end Expand_Packed_Boolean_Operator;
1910
1911    -------------------------------------
1912    -- Expand_Packed_Element_Reference --
1913    -------------------------------------
1914
1915    procedure Expand_Packed_Element_Reference (N : Node_Id) is
1916       Loc   : constant Source_Ptr := Sloc (N);
1917       Obj   : Node_Id;
1918       Atyp  : Entity_Id;
1919       PAT   : Entity_Id;
1920       Ctyp  : Entity_Id;
1921       Csiz  : Int;
1922       Shift : Node_Id;
1923       Cmask : Uint;
1924       Lit   : Node_Id;
1925       Arg   : Node_Id;
1926
1927    begin
1928       --  If not bit packed, we have the enumeration case, which is easily
1929       --  dealt with (just adjust the subscripts of the indexed component)
1930
1931       --  Note: this leaves the result as an indexed component, which is
1932       --  still a variable, so can be used in the assignment case, as is
1933       --  required in the enumeration case.
1934
1935       if not Is_Bit_Packed_Array (Etype (Prefix (N))) then
1936          Setup_Enumeration_Packed_Array_Reference (N);
1937          return;
1938       end if;
1939
1940       --  Remaining processing is for the bit-packed case
1941
1942       Obj := Relocate_Node (Prefix (N));
1943       Convert_To_Actual_Subtype (Obj);
1944       Atyp := Etype (Obj);
1945       PAT  := Packed_Array_Type (Atyp);
1946       Ctyp := Component_Type (Atyp);
1947       Csiz := UI_To_Int (Component_Size (Atyp));
1948
1949       --  For the AAMP target, indexing of certain packed array is passed
1950       --  through to the back end without expansion, because the expansion
1951       --  results in very inefficient code on that target. This allows the
1952       --  GNAAMP back end to generate specialized macros that support more
1953       --  efficient indexing of packed arrays with components having sizes
1954       --  that are small powers of two.
1955
1956       if AAMP_On_Target
1957         and then (Csiz = 1 or else Csiz = 2 or else Csiz = 4)
1958       then
1959          return;
1960       end if;
1961
1962       --  Case of component size 1,2,4 or any component size for the modular
1963       --  case. These are the cases for which we can inline the code.
1964
1965       if Csiz = 1 or else Csiz = 2 or else Csiz = 4
1966         or else (Present (PAT) and then Is_Modular_Integer_Type (PAT))
1967       then
1968          Setup_Inline_Packed_Array_Reference (N, Atyp, Obj, Cmask, Shift);
1969          Lit := Make_Integer_Literal (Loc, Cmask);
1970          Set_Print_In_Hex (Lit);
1971
1972          --  We generate a shift right to position the field, followed by a
1973          --  masking operation to extract the bit field, and we finally do an
1974          --  unchecked conversion to convert the result to the required target.
1975
1976          --  Note that the unchecked conversion automatically deals with the
1977          --  bias if we are dealing with a biased representation. What will
1978          --  happen is that we temporarily generate the biased representation,
1979          --  but almost immediately that will be converted to the original
1980          --  unbiased component type, and the bias will disappear.
1981
1982          Arg :=
1983            Make_Op_And (Loc,
1984              Left_Opnd  => Make_Shift_Right (Obj, Shift),
1985              Right_Opnd => Lit);
1986
1987          --  We needed to analyze this before we do the unchecked convert
1988          --  below, but we need it temporarily attached to the tree for
1989          --  this analysis (hence the temporary Set_Parent call).
1990
1991          Set_Parent (Arg, Parent (N));
1992          Analyze_And_Resolve (Arg);
1993
1994          Rewrite (N,
1995            RJ_Unchecked_Convert_To (Ctyp, Arg));
1996
1997       --  All other component sizes for non-modular case
1998
1999       else
2000          --  We generate
2001
2002          --    Component_Type!(Get_nn (Arr'address, Subscr))
2003
2004          --  where Subscr is the computed linear subscript
2005
2006          declare
2007             Get_nn : Entity_Id;
2008             Subscr : Node_Id;
2009
2010          begin
2011             --  Acquire proper Get entity. We use the aligned or unaligned
2012             --  case as appropriate.
2013
2014             if Known_Aligned_Enough (Obj, Csiz) then
2015                Get_nn := RTE (Get_Id (Csiz));
2016             else
2017                Get_nn := RTE (GetU_Id (Csiz));
2018             end if;
2019
2020             --  Now generate the get reference
2021
2022             Compute_Linear_Subscript (Atyp, N, Subscr);
2023
2024             --  Below we make the assumption that Obj is at least byte
2025             --  aligned, since otherwise its address cannot be taken.
2026             --  The assumption holds since the only arrays that can be
2027             --  misaligned are small packed arrays which are implemented
2028             --  as a modular type, and that is not the case here.
2029
2030             Rewrite (N,
2031               Unchecked_Convert_To (Ctyp,
2032                 Make_Function_Call (Loc,
2033                   Name => New_Occurrence_Of (Get_nn, Loc),
2034                   Parameter_Associations => New_List (
2035                     Make_Attribute_Reference (Loc,
2036                       Prefix         => Obj,
2037                       Attribute_Name => Name_Address),
2038                     Subscr))));
2039          end;
2040       end if;
2041
2042       Analyze_And_Resolve (N, Ctyp, Suppress => All_Checks);
2043
2044    end Expand_Packed_Element_Reference;
2045
2046    ----------------------
2047    -- Expand_Packed_Eq --
2048    ----------------------
2049
2050    --  Handles expansion of "=" on packed array types
2051
2052    procedure Expand_Packed_Eq (N : Node_Id) is
2053       Loc : constant Source_Ptr := Sloc (N);
2054       L   : constant Node_Id    := Relocate_Node (Left_Opnd  (N));
2055       R   : constant Node_Id    := Relocate_Node (Right_Opnd (N));
2056
2057       LLexpr : Node_Id;
2058       RLexpr : Node_Id;
2059
2060       Ltyp : Entity_Id;
2061       Rtyp : Entity_Id;
2062       PAT  : Entity_Id;
2063
2064    begin
2065       Convert_To_Actual_Subtype (L);
2066       Convert_To_Actual_Subtype (R);
2067       Ltyp := Underlying_Type (Etype (L));
2068       Rtyp := Underlying_Type (Etype (R));
2069
2070       Convert_To_PAT_Type (L);
2071       Convert_To_PAT_Type (R);
2072       PAT := Etype (L);
2073
2074       LLexpr :=
2075         Make_Op_Multiply (Loc,
2076           Left_Opnd =>
2077             Make_Attribute_Reference (Loc,
2078               Prefix         => New_Occurrence_Of (Ltyp, Loc),
2079               Attribute_Name => Name_Length),
2080           Right_Opnd =>
2081             Make_Integer_Literal (Loc, Component_Size (Ltyp)));
2082
2083       RLexpr :=
2084         Make_Op_Multiply (Loc,
2085           Left_Opnd =>
2086             Make_Attribute_Reference (Loc,
2087               Prefix         => New_Occurrence_Of (Rtyp, Loc),
2088               Attribute_Name => Name_Length),
2089           Right_Opnd =>
2090             Make_Integer_Literal (Loc, Component_Size (Rtyp)));
2091
2092       --  For the modular case, we transform the comparison to:
2093
2094       --    Ltyp'Length = Rtyp'Length and then PAT!(L) = PAT!(R)
2095
2096       --  where PAT is the packed array type. This works fine, since in the
2097       --  modular case we guarantee that the unused bits are always zeroes.
2098       --  We do have to compare the lengths because we could be comparing
2099       --  two different subtypes of the same base type.
2100
2101       if Is_Modular_Integer_Type (PAT) then
2102          Rewrite (N,
2103            Make_And_Then (Loc,
2104              Left_Opnd =>
2105                Make_Op_Eq (Loc,
2106                  Left_Opnd  => LLexpr,
2107                  Right_Opnd => RLexpr),
2108
2109              Right_Opnd =>
2110                Make_Op_Eq (Loc,
2111                  Left_Opnd => L,
2112                  Right_Opnd => R)));
2113
2114       --  For the non-modular case, we call a runtime routine
2115
2116       --    System.Bit_Ops.Bit_Eq
2117       --      (L'Address, L_Length, R'Address, R_Length)
2118
2119       --  where PAT is the packed array type, and the lengths are the lengths
2120       --  in bits of the original packed arrays. This routine takes care of
2121       --  not comparing the unused bits in the last byte.
2122
2123       else
2124          Rewrite (N,
2125            Make_Function_Call (Loc,
2126              Name => New_Occurrence_Of (RTE (RE_Bit_Eq), Loc),
2127              Parameter_Associations => New_List (
2128                Make_Byte_Aligned_Attribute_Reference (Loc,
2129                  Prefix         => L,
2130                  Attribute_Name => Name_Address),
2131
2132                LLexpr,
2133
2134                Make_Byte_Aligned_Attribute_Reference (Loc,
2135                  Prefix         => R,
2136                  Attribute_Name => Name_Address),
2137
2138                RLexpr)));
2139       end if;
2140
2141       Analyze_And_Resolve (N, Standard_Boolean, Suppress => All_Checks);
2142    end Expand_Packed_Eq;
2143
2144    -----------------------
2145    -- Expand_Packed_Not --
2146    -----------------------
2147
2148    --  Handles expansion of "not" on packed array types
2149
2150    procedure Expand_Packed_Not (N : Node_Id) is
2151       Loc  : constant Source_Ptr := Sloc (N);
2152       Typ  : constant Entity_Id  := Etype (N);
2153       Opnd : constant Node_Id    := Relocate_Node (Right_Opnd (N));
2154
2155       Rtyp : Entity_Id;
2156       PAT  : Entity_Id;
2157       Lit  : Node_Id;
2158
2159    begin
2160       Convert_To_Actual_Subtype (Opnd);
2161       Rtyp := Etype (Opnd);
2162
2163       --  Deal with silly False..False and True..True subtype case
2164
2165       Silly_Boolean_Array_Not_Test (N, Rtyp);
2166
2167       --  Now that the silliness is taken care of, get packed array type
2168
2169       Convert_To_PAT_Type (Opnd);
2170       PAT := Etype (Opnd);
2171
2172       --  For the case where the packed array type is a modular type,
2173       --  not A expands simply into:
2174
2175       --     rtyp!(PAT!(A) xor mask)
2176
2177       --  where PAT is the packed array type, and mask is a mask of all
2178       --  one bits of length equal to the size of this packed type and
2179       --  rtyp is the actual subtype of the operand
2180
2181       Lit := Make_Integer_Literal (Loc, 2 ** RM_Size (PAT) - 1);
2182       Set_Print_In_Hex (Lit);
2183
2184       if not Is_Array_Type (PAT) then
2185          Rewrite (N,
2186            Unchecked_Convert_To (Rtyp,
2187              Make_Op_Xor (Loc,
2188                Left_Opnd  => Opnd,
2189                Right_Opnd => Lit)));
2190
2191       --  For the array case, we insert the actions
2192
2193       --    Result : Typ;
2194
2195       --    System.Bit_Ops.Bit_Not
2196       --     (Opnd'Address,
2197       --      Typ'Length * Typ'Component_Size;
2198       --      Result'Address);
2199
2200       --  where Opnd is the Packed_Bytes{1,2,4} operand and the second
2201       --  argument is the length of the operand in bits. Then we replace
2202       --  the expression by a reference to Result.
2203
2204       else
2205          declare
2206             Result_Ent : constant Entity_Id := Make_Temporary (Loc, 'T');
2207
2208          begin
2209             Insert_Actions (N, New_List (
2210
2211               Make_Object_Declaration (Loc,
2212                 Defining_Identifier => Result_Ent,
2213                 Object_Definition => New_Occurrence_Of (Rtyp, Loc)),
2214
2215               Make_Procedure_Call_Statement (Loc,
2216                 Name => New_Occurrence_Of (RTE (RE_Bit_Not), Loc),
2217                   Parameter_Associations => New_List (
2218
2219                     Make_Byte_Aligned_Attribute_Reference (Loc,
2220                       Prefix         => Opnd,
2221                       Attribute_Name => Name_Address),
2222
2223                     Make_Op_Multiply (Loc,
2224                       Left_Opnd =>
2225                         Make_Attribute_Reference (Loc,
2226                           Prefix         =>
2227                             New_Occurrence_Of
2228                               (Etype (First_Index (Rtyp)), Loc),
2229                           Attribute_Name => Name_Range_Length),
2230
2231                       Right_Opnd =>
2232                         Make_Integer_Literal (Loc, Component_Size (Rtyp))),
2233
2234                     Make_Byte_Aligned_Attribute_Reference (Loc,
2235                       Prefix => New_Occurrence_Of (Result_Ent, Loc),
2236                       Attribute_Name => Name_Address)))));
2237
2238             Rewrite (N,
2239               New_Occurrence_Of (Result_Ent, Loc));
2240          end;
2241       end if;
2242
2243       Analyze_And_Resolve (N, Typ, Suppress => All_Checks);
2244
2245    end Expand_Packed_Not;
2246
2247    -----------------------------
2248    -- Get_Base_And_Bit_Offset --
2249    -----------------------------
2250
2251    procedure Get_Base_And_Bit_Offset
2252      (N      : Node_Id;
2253       Base   : out Node_Id;
2254       Offset : out Node_Id)
2255    is
2256       Loc    : Source_Ptr;
2257       Term   : Node_Id;
2258       Atyp   : Entity_Id;
2259       Subscr : Node_Id;
2260
2261    begin
2262       Base   := N;
2263       Offset := Empty;
2264
2265       --  We build up an expression serially that has the form
2266
2267       --    linear-subscript * component_size       for each array reference
2268       --      +  field'Bit_Position                 for each record field
2269       --      +  ...
2270
2271       loop
2272          Loc := Sloc (Base);
2273
2274          if Nkind (Base) = N_Indexed_Component then
2275             Convert_To_Actual_Subtype (Prefix (Base));
2276             Atyp := Etype (Prefix (Base));
2277             Compute_Linear_Subscript (Atyp, Base, Subscr);
2278
2279             Term :=
2280               Make_Op_Multiply (Loc,
2281                 Left_Opnd => Subscr,
2282                 Right_Opnd =>
2283                  Make_Attribute_Reference (Loc,
2284                    Prefix         => New_Occurrence_Of (Atyp, Loc),
2285                    Attribute_Name => Name_Component_Size));
2286
2287          elsif Nkind (Base) = N_Selected_Component then
2288             Term :=
2289               Make_Attribute_Reference (Loc,
2290                 Prefix         => Selector_Name (Base),
2291                 Attribute_Name => Name_Bit_Position);
2292
2293          else
2294             return;
2295          end if;
2296
2297          if No (Offset) then
2298             Offset := Term;
2299
2300          else
2301             Offset :=
2302               Make_Op_Add (Loc,
2303                 Left_Opnd  => Offset,
2304                 Right_Opnd => Term);
2305          end if;
2306
2307          Base := Prefix (Base);
2308       end loop;
2309    end Get_Base_And_Bit_Offset;
2310
2311    -------------------------------------
2312    -- Involves_Packed_Array_Reference --
2313    -------------------------------------
2314
2315    function Involves_Packed_Array_Reference (N : Node_Id) return Boolean is
2316    begin
2317       if Nkind (N) = N_Indexed_Component
2318         and then Is_Bit_Packed_Array (Etype (Prefix (N)))
2319       then
2320          return True;
2321
2322       elsif Nkind (N) = N_Selected_Component then
2323          return Involves_Packed_Array_Reference (Prefix (N));
2324
2325       else
2326          return False;
2327       end if;
2328    end Involves_Packed_Array_Reference;
2329
2330    --------------------------
2331    -- Known_Aligned_Enough --
2332    --------------------------
2333
2334    function Known_Aligned_Enough (Obj : Node_Id; Csiz : Nat) return Boolean is
2335       Typ : constant Entity_Id := Etype (Obj);
2336
2337       function In_Partially_Packed_Record (Comp : Entity_Id) return Boolean;
2338       --  If the component is in a record that contains previous packed
2339       --  components, consider it unaligned because the back-end might
2340       --  choose to pack the rest of the record. Lead to less efficient code,
2341       --  but safer vis-a-vis of back-end choices.
2342
2343       --------------------------------
2344       -- In_Partially_Packed_Record --
2345       --------------------------------
2346
2347       function In_Partially_Packed_Record (Comp : Entity_Id) return Boolean is
2348          Rec_Type  : constant Entity_Id := Scope (Comp);
2349          Prev_Comp : Entity_Id;
2350
2351       begin
2352          Prev_Comp := First_Entity (Rec_Type);
2353          while Present (Prev_Comp) loop
2354             if Is_Packed (Etype (Prev_Comp)) then
2355                return True;
2356
2357             elsif Prev_Comp = Comp then
2358                return False;
2359             end if;
2360
2361             Next_Entity (Prev_Comp);
2362          end loop;
2363
2364          return False;
2365       end  In_Partially_Packed_Record;
2366
2367    --  Start of processing for Known_Aligned_Enough
2368
2369    begin
2370       --  Odd bit sizes don't need alignment anyway
2371
2372       if Csiz mod 2 = 1 then
2373          return True;
2374
2375       --  If we have a specified alignment, see if it is sufficient, if not
2376       --  then we can't possibly be aligned enough in any case.
2377
2378       elsif Known_Alignment (Etype (Obj)) then
2379          --  Alignment required is 4 if size is a multiple of 4, and
2380          --  2 otherwise (e.g. 12 bits requires 4, 10 bits requires 2)
2381
2382          if Alignment (Etype (Obj)) < 4 - (Csiz mod 4) then
2383             return False;
2384          end if;
2385       end if;
2386
2387       --  OK, alignment should be sufficient, if object is aligned
2388
2389       --  If object is strictly aligned, then it is definitely aligned
2390
2391       if Strict_Alignment (Typ) then
2392          return True;
2393
2394       --  Case of subscripted array reference
2395
2396       elsif Nkind (Obj) = N_Indexed_Component then
2397
2398          --  If we have a pointer to an array, then this is definitely
2399          --  aligned, because pointers always point to aligned versions.
2400
2401          if Is_Access_Type (Etype (Prefix (Obj))) then
2402             return True;
2403
2404          --  Otherwise, go look at the prefix
2405
2406          else
2407             return Known_Aligned_Enough (Prefix (Obj), Csiz);
2408          end if;
2409
2410       --  Case of record field
2411
2412       elsif Nkind (Obj) = N_Selected_Component then
2413
2414          --  What is significant here is whether the record type is packed
2415
2416          if Is_Record_Type (Etype (Prefix (Obj)))
2417            and then Is_Packed (Etype (Prefix (Obj)))
2418          then
2419             return False;
2420
2421          --  Or the component has a component clause which might cause
2422          --  the component to become unaligned (we can't tell if the
2423          --  backend is doing alignment computations).
2424
2425          elsif Present (Component_Clause (Entity (Selector_Name (Obj)))) then
2426             return False;
2427
2428          elsif In_Partially_Packed_Record (Entity (Selector_Name (Obj))) then
2429             return False;
2430
2431          --  In all other cases, go look at prefix
2432
2433          else
2434             return Known_Aligned_Enough (Prefix (Obj), Csiz);
2435          end if;
2436
2437       elsif Nkind (Obj) = N_Type_Conversion then
2438          return Known_Aligned_Enough (Expression (Obj), Csiz);
2439
2440       --  For a formal parameter, it is safer to assume that it is not
2441       --  aligned, because the formal may be unconstrained while the actual
2442       --  is constrained. In this situation, a small constrained packed
2443       --  array, represented in modular form, may be unaligned.
2444
2445       elsif Is_Entity_Name (Obj) then
2446          return not Is_Formal (Entity (Obj));
2447       else
2448
2449       --  If none of the above, must be aligned
2450          return True;
2451       end if;
2452    end Known_Aligned_Enough;
2453
2454    ---------------------
2455    -- Make_Shift_Left --
2456    ---------------------
2457
2458    function Make_Shift_Left (N : Node_Id; S : Node_Id) return Node_Id is
2459       Nod : Node_Id;
2460
2461    begin
2462       if Compile_Time_Known_Value (S) and then Expr_Value (S) = 0 then
2463          return N;
2464       else
2465          Nod :=
2466            Make_Op_Shift_Left (Sloc (N),
2467              Left_Opnd  => N,
2468              Right_Opnd => S);
2469          Set_Shift_Count_OK (Nod, True);
2470          return Nod;
2471       end if;
2472    end Make_Shift_Left;
2473
2474    ----------------------
2475    -- Make_Shift_Right --
2476    ----------------------
2477
2478    function Make_Shift_Right (N : Node_Id; S : Node_Id) return Node_Id is
2479       Nod : Node_Id;
2480
2481    begin
2482       if Compile_Time_Known_Value (S) and then Expr_Value (S) = 0 then
2483          return N;
2484       else
2485          Nod :=
2486            Make_Op_Shift_Right (Sloc (N),
2487              Left_Opnd  => N,
2488              Right_Opnd => S);
2489          Set_Shift_Count_OK (Nod, True);
2490          return Nod;
2491       end if;
2492    end Make_Shift_Right;
2493
2494    -----------------------------
2495    -- RJ_Unchecked_Convert_To --
2496    -----------------------------
2497
2498    function RJ_Unchecked_Convert_To
2499      (Typ  : Entity_Id;
2500       Expr : Node_Id) return Node_Id
2501    is
2502       Source_Typ : constant Entity_Id := Etype (Expr);
2503       Target_Typ : constant Entity_Id := Typ;
2504
2505       Src : Node_Id := Expr;
2506
2507       Source_Siz : Nat;
2508       Target_Siz : Nat;
2509
2510    begin
2511       Source_Siz := UI_To_Int (RM_Size (Source_Typ));
2512       Target_Siz := UI_To_Int (RM_Size (Target_Typ));
2513
2514       --  First step, if the source type is not a discrete type, then we
2515       --  first convert to a modular type of the source length, since
2516       --  otherwise, on a big-endian machine, we get left-justification.
2517       --  We do it for little-endian machines as well, because there might
2518       --  be junk bits that are not cleared if the type is not numeric.
2519
2520       if Source_Siz /= Target_Siz
2521         and then  not Is_Discrete_Type (Source_Typ)
2522       then
2523          Src := Unchecked_Convert_To (RTE (Bits_Id (Source_Siz)), Src);
2524       end if;
2525
2526       --  In the big endian case, if the lengths of the two types differ,
2527       --  then we must worry about possible left justification in the
2528       --  conversion, and avoiding that is what this is all about.
2529
2530       if Bytes_Big_Endian and then Source_Siz /= Target_Siz then
2531
2532          --  Next step. If the target is not a discrete type, then we first
2533          --  convert to a modular type of the target length, since
2534          --  otherwise, on a big-endian machine, we get left-justification.
2535
2536          if not Is_Discrete_Type (Target_Typ) then
2537             Src := Unchecked_Convert_To (RTE (Bits_Id (Target_Siz)), Src);
2538          end if;
2539       end if;
2540
2541       --  And now we can do the final conversion to the target type
2542
2543       return Unchecked_Convert_To (Target_Typ, Src);
2544    end RJ_Unchecked_Convert_To;
2545
2546    ----------------------------------------------
2547    -- Setup_Enumeration_Packed_Array_Reference --
2548    ----------------------------------------------
2549
2550    --  All we have to do here is to find the subscripts that correspond
2551    --  to the index positions that have non-standard enumeration types
2552    --  and insert a Pos attribute to get the proper subscript value.
2553
2554    --  Finally the prefix must be uncheck converted to the corresponding
2555    --  packed array type.
2556
2557    --  Note that the component type is unchanged, so we do not need to
2558    --  fiddle with the types (Gigi always automatically takes the packed
2559    --  array type if it is set, as it will be in this case).
2560
2561    procedure Setup_Enumeration_Packed_Array_Reference (N : Node_Id) is
2562       Pfx   : constant Node_Id   := Prefix (N);
2563       Typ   : constant Entity_Id := Etype (N);
2564       Exprs : constant List_Id   := Expressions (N);
2565       Expr  : Node_Id;
2566
2567    begin
2568       --  If the array is unconstrained, then we replace the array
2569       --  reference with its actual subtype. This actual subtype will
2570       --  have a packed array type with appropriate bounds.
2571
2572       if not Is_Constrained (Packed_Array_Type (Etype (Pfx))) then
2573          Convert_To_Actual_Subtype (Pfx);
2574       end if;
2575
2576       Expr := First (Exprs);
2577       while Present (Expr) loop
2578          declare
2579             Loc      : constant Source_Ptr := Sloc (Expr);
2580             Expr_Typ : constant Entity_Id := Etype (Expr);
2581
2582          begin
2583             if Is_Enumeration_Type (Expr_Typ)
2584               and then Has_Non_Standard_Rep (Expr_Typ)
2585             then
2586                Rewrite (Expr,
2587                  Make_Attribute_Reference (Loc,
2588                    Prefix         => New_Occurrence_Of (Expr_Typ, Loc),
2589                    Attribute_Name => Name_Pos,
2590                    Expressions    => New_List (Relocate_Node (Expr))));
2591                Analyze_And_Resolve (Expr, Standard_Natural);
2592             end if;
2593          end;
2594
2595          Next (Expr);
2596       end loop;
2597
2598       Rewrite (N,
2599         Make_Indexed_Component (Sloc (N),
2600           Prefix      =>
2601             Unchecked_Convert_To (Packed_Array_Type (Etype (Pfx)), Pfx),
2602           Expressions => Exprs));
2603
2604       Analyze_And_Resolve (N, Typ);
2605
2606    end Setup_Enumeration_Packed_Array_Reference;
2607
2608    -----------------------------------------
2609    -- Setup_Inline_Packed_Array_Reference --
2610    -----------------------------------------
2611
2612    procedure Setup_Inline_Packed_Array_Reference
2613      (N      : Node_Id;
2614       Atyp   : Entity_Id;
2615       Obj    : in out Node_Id;
2616       Cmask  : out Uint;
2617       Shift  : out Node_Id)
2618    is
2619       Loc    : constant Source_Ptr := Sloc (N);
2620       PAT    : Entity_Id;
2621       Otyp   : Entity_Id;
2622       Csiz   : Uint;
2623       Osiz   : Uint;
2624
2625    begin
2626       Csiz := Component_Size (Atyp);
2627
2628       Convert_To_PAT_Type (Obj);
2629       PAT := Etype (Obj);
2630
2631       Cmask := 2 ** Csiz - 1;
2632
2633       if Is_Array_Type (PAT) then
2634          Otyp := Component_Type (PAT);
2635          Osiz := Component_Size (PAT);
2636
2637       else
2638          Otyp := PAT;
2639
2640          --  In the case where the PAT is a modular type, we want the actual
2641          --  size in bits of the modular value we use. This is neither the
2642          --  Object_Size nor the Value_Size, either of which may have been
2643          --  reset to strange values, but rather the minimum size. Note that
2644          --  since this is a modular type with full range, the issue of
2645          --  biased representation does not arise.
2646
2647          Osiz := UI_From_Int (Minimum_Size (Otyp));
2648       end if;
2649
2650       Compute_Linear_Subscript (Atyp, N, Shift);
2651
2652       --  If the component size is not 1, then the subscript must be
2653       --  multiplied by the component size to get the shift count.
2654
2655       if Csiz /= 1 then
2656          Shift :=
2657            Make_Op_Multiply (Loc,
2658              Left_Opnd => Make_Integer_Literal (Loc, Csiz),
2659              Right_Opnd => Shift);
2660       end if;
2661
2662       --  If we have the array case, then this shift count must be broken
2663       --  down into a byte subscript, and a shift within the byte.
2664
2665       if Is_Array_Type (PAT) then
2666
2667          declare
2668             New_Shift : Node_Id;
2669
2670          begin
2671             --  We must analyze shift, since we will duplicate it
2672
2673             Set_Parent (Shift, N);
2674             Analyze_And_Resolve
2675               (Shift, Standard_Integer, Suppress => All_Checks);
2676
2677             --  The shift count within the word is
2678             --    shift mod Osiz
2679
2680             New_Shift :=
2681               Make_Op_Mod (Loc,
2682                 Left_Opnd  => Duplicate_Subexpr (Shift),
2683                 Right_Opnd => Make_Integer_Literal (Loc, Osiz));
2684
2685             --  The subscript to be used on the PAT array is
2686             --    shift / Osiz
2687
2688             Obj :=
2689               Make_Indexed_Component (Loc,
2690                 Prefix => Obj,
2691                 Expressions => New_List (
2692                   Make_Op_Divide (Loc,
2693                     Left_Opnd => Duplicate_Subexpr (Shift),
2694                     Right_Opnd => Make_Integer_Literal (Loc, Osiz))));
2695
2696             Shift := New_Shift;
2697          end;
2698
2699       --  For the modular integer case, the object to be manipulated is
2700       --  the entire array, so Obj is unchanged. Note that we will reset
2701       --  its type to PAT before returning to the caller.
2702
2703       else
2704          null;
2705       end if;
2706
2707       --  The one remaining step is to modify the shift count for the
2708       --  big-endian case. Consider the following example in a byte:
2709
2710       --     xxxxxxxx  bits of byte
2711       --     vvvvvvvv  bits of value
2712       --     33221100  little-endian numbering
2713       --     00112233  big-endian numbering
2714
2715       --  Here we have the case of 2-bit fields
2716
2717       --  For the little-endian case, we already have the proper shift
2718       --  count set, e.g. for element 2, the shift count is 2*2 = 4.
2719
2720       --  For the big endian case, we have to adjust the shift count,
2721       --  computing it as (N - F) - shift, where N is the number of bits
2722       --  in an element of the array used to implement the packed array,
2723       --  F is the number of bits in a source level array element, and
2724       --  shift is the count so far computed.
2725
2726       if Bytes_Big_Endian then
2727          Shift :=
2728            Make_Op_Subtract (Loc,
2729              Left_Opnd  => Make_Integer_Literal (Loc, Osiz - Csiz),
2730              Right_Opnd => Shift);
2731       end if;
2732
2733       Set_Parent (Shift, N);
2734       Set_Parent (Obj, N);
2735       Analyze_And_Resolve (Obj,   Otyp,             Suppress => All_Checks);
2736       Analyze_And_Resolve (Shift, Standard_Integer, Suppress => All_Checks);
2737
2738       --  Make sure final type of object is the appropriate packed type
2739
2740       Set_Etype (Obj, Otyp);
2741
2742    end Setup_Inline_Packed_Array_Reference;
2743
2744 end Exp_Pakd;