gcc/ada/s-imglli.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                       S Y S T E M . I M G _ L L I                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --           Copyright (C) 1992-2005 Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 package body System.Img_LLI is
  35
  36    -----------------------------
  37    -- Image_Long_Long_Integer --
  38    -----------------------------
  39
  40    function Image_Long_Long_Integer (V : Long_Long_Integer) return String is
  41       P : Natural;
  42       S : String (1 .. Long_Long_Integer'Width);
  43
  44    begin
  45       if V >= 0 then
  46          P := 1;
  47          S (P) := ' ';
  48       else
  49          P := 0;
  50       end if;
  51
  52       Set_Image_Long_Long_Integer (V, S, P);
  53       return S (1 .. P);
  54    end Image_Long_Long_Integer;
  55
  56    ---------------------------------
  57    -- Set_Image_Long_Long_Integer --
  58    ---------------------------------
  59
  60    procedure Set_Image_Long_Long_Integer
  61      (V : Long_Long_Integer;
  62       S : out String;
  63       P : in out Natural)
  64    is
  65       procedure Set_Digits (T : Long_Long_Integer);
  66       --  Set digits of absolute value of T, which is zero or negative. We work
  67       --  with the negative of the value so that the largest negative number is
  68       --  not a special case.
  69
  70       procedure Set_Digits (T : Long_Long_Integer) is
  71       begin
  72          if T <= -10 then
  73             Set_Digits (T / 10);
  74             P := P + 1;
  75             S (P) := Character'Val (48 - (T rem 10));
  76
  77          else
  78             P := P + 1;
  79             S (P) := Character'Val (48 - T);
  80          end if;
  81       end Set_Digits;
  82
  83    --  Start of processing for Set_Image_Long_Long_Integer
  84
  85    begin
  86       if V >= 0 then
  87          Set_Digits (-V);
  88
  89       else
  90          P := P + 1;
  91          S (P) := '-';
  92          Set_Digits (V);
  93       end if;
  94
  95    end Set_Image_Long_Long_Integer;
  96
  97 end System.Img_LLI;