gcc/ada/par-ch2.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              P A R . C H 2                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 pragma Style_Checks (All_Checks);
  27 --  Turn off subprogram body ordering check. Subprograms are in order
  28 --  by RM section rather than alphabetical
  29
  30 separate (Par)
  31 package body Ch2 is
  32
  33    --  Local functions, used only in this chapter
  34
  35    procedure Scan_Pragma_Argument_Association
  36      (Identifier_Seen : in out Boolean;
  37       Association     : out Node_Id);
  38    --  Scans out a pragma argument association. Identifier_Seen is true on
  39    --  entry if a previous association had an identifier, and gets set True if
  40    --  the scanned association has an identifier (this is used to check the
  41    --  rule that no associations without identifiers can follow an association
  42    --  which has an identifier). The result is returned in Association.
  43
  44    ---------------------
  45    -- 2.3  Identifier --
  46    ---------------------
  47
  48    --  IDENTIFIER ::= LETTER {[UNDERLINE] LETTER_OR_DIGIT}
  49
  50    --  LETTER_OR_DIGIT ::= IDENTIFIER_LETTER | DIGIT
  51
  52    --  An IDENTIFIER shall not be a reserved word
  53
  54    --  Error recovery: can raise Error_Resync (cannot return Error)
  55
  56    function P_Identifier (C : Id_Check := None) return Node_Id is
  57       Ident_Node : Node_Id;
  58
  59    begin
  60       --  All set if we do indeed have an identifier
  61
  62       if Token = Tok_Identifier then
  63
  64          --  Ada 2005 (AI-284): Compiling in Ada95 mode we warn that INTERFACE,
  65          --  OVERRIDING, and SYNCHRONIZED are new reserved words.
  66
  67          if Ada_Version = Ada_95
  68            and then Warn_On_Ada_2005_Compatibility
  69          then
  70             if Token_Name = Name_Overriding
  71               or else Token_Name = Name_Synchronized
  72               or else (Token_Name = Name_Interface
  73                         and then Prev_Token /= Tok_Pragma)
  74             then
  75                Error_Msg_N ("& is a reserved word in Ada 2005?", Token_Node);
  76             end if;
  77          end if;
  78
  79          Ident_Node := Token_Node;
  80          Scan; -- past Identifier
  81          return Ident_Node;
  82
  83       --  If we have a reserved identifier, manufacture an identifier with
  84       --  a corresponding name after posting an appropriate error message
  85
  86       elsif Is_Reserved_Identifier (C) then
  87          Scan_Reserved_Identifier (Force_Msg => False);
  88          Ident_Node := Token_Node;
  89          Scan; -- past the node
  90          return Ident_Node;
  91
  92       --  Otherwise we have junk that cannot be interpreted as an identifier
  93
  94       else
  95          T_Identifier; -- to give message
  96          raise Error_Resync;
  97       end if;
  98    end P_Identifier;
  99
 100    --------------------------
 101    -- 2.3  Letter Or Digit --
 102    --------------------------
 103
 104    --  Parsed by P_Identifier (2.3)
 105
 106    --------------------------
 107    -- 2.4  Numeric Literal --
 108    --------------------------
 109
 110    --  NUMERIC_LITERAL ::= DECIMAL_LITERAL | BASED_LITERAL
 111
 112    --  Numeric literal is returned by the scanner as either
 113    --  Tok_Integer_Literal or Tok_Real_Literal
 114
 115    ----------------------------
 116    -- 2.4.1  Decimal Literal --
 117    ----------------------------
 118
 119    --  DECIMAL_LITERAL ::= NUMERAL [.NUMERAL] [EXPONENT]
 120
 121    --  Handled by scanner as part of numeric lIteral handing (see 2.4)
 122
 123    --------------------
 124    -- 2.4.1  Numeral --
 125    --------------------
 126
 127    --  NUMERAL ::= DIGIT {[UNDERLINE] DIGIT}
 128
 129    --  Handled by scanner as part of numeric literal handling (see 2.4)
 130
 131    ---------------------
 132    -- 2.4.1  Exponent --
 133    ---------------------
 134
 135    --  EXPONENT ::= E [+] NUMERAL | E - NUMERAL
 136
 137    --  Handled by scanner as part of numeric literal handling (see 2.4)
 138
 139    --------------------------
 140    -- 2.4.2  Based Literal --
 141    --------------------------
 142
 143    --  BASED_LITERAL ::=
 144    --   BASE # BASED_NUMERAL [.BASED_NUMERAL] # [EXPONENT]
 145
 146    --  Handled by scanner as part of numeric literal handling (see 2.4)
 147
 148    -----------------
 149    -- 2.4.2  Base --
 150    -----------------
 151
 152    --  BASE ::= NUMERAL
 153
 154    --  Handled by scanner as part of numeric literal handling (see 2.4)
 155
 156    --------------------------
 157    -- 2.4.2  Based Numeral --
 158    --------------------------
 159
 160    --  BASED_NUMERAL ::=
 161    --    EXTENDED_DIGIT {[UNDERLINE] EXTENDED_DIGIT}
 162
 163    --  Handled by scanner as part of numeric literal handling (see 2.4)
 164
 165    ---------------------------
 166    -- 2.4.2  Extended Digit --
 167    ---------------------------
 168
 169    --  EXTENDED_DIGIT ::= DIGIT | A | B | C | D | E | F
 170
 171    --  Handled by scanner as part of numeric literal handling (see 2.4)
 172
 173    ----------------------------
 174    -- 2.5  Character Literal --
 175    ----------------------------
 176
 177    --  CHARACTER_LITERAL ::= ' GRAPHIC_CHARACTER '
 178
 179    --  Handled by the scanner and returned as Tok_Char_Literal
 180
 181    -------------------------
 182    -- 2.6  String Literal --
 183    -------------------------
 184
 185    --  STRING LITERAL ::= "{STRING_ELEMENT}"
 186
 187    --  Handled by the scanner and returned as Tok_String_Literal
 188    --  or if the string looks like an operator as Tok_Operator_Symbol.
 189
 190    -------------------------
 191    -- 2.6  String Element --
 192    -------------------------
 193
 194    --  STRING_ELEMENT ::= "" | non-quotation_mark_GRAPHIC_CHARACTER
 195
 196    --  A STRING_ELEMENT is either a pair of quotation marks ("),
 197    --  or a single GRAPHIC_CHARACTER other than a quotation mark.
 198
 199    --  Handled by scanner as part of string literal handling (see 2.4)
 200
 201    ------------------
 202    -- 2.7  Comment --
 203    ------------------
 204
 205    --  A COMMENT starts with two adjacent hyphens and extends up to the
 206    --  end of the line. A COMMENT may appear on any line of a program.
 207
 208    --  Handled by the scanner which simply skips past encountered comments
 209
 210    -----------------
 211    -- 2.8  Pragma --
 212    -----------------
 213
 214    --  PRAGMA ::= pragma IDENTIFIER
 215    --    [(PRAGMA_ARGUMENT_ASSOCIATION {, PRAGMA_ARGUMENT_ASSOCIATION})];
 216
 217    --  The caller has checked that the initial token is PRAGMA
 218
 219    --  Error recovery: cannot raise Error_Resync
 220
 221    --  One special piece of processing is needed in this routine. As described
 222    --  in the section on "Handling semicolon used in place of IS" in module
 223    --  Parse, the parser detects the case of missing subprogram bodies to
 224    --  allow recovery from this syntactic error. Pragma INTERFACE (and, for
 225    --  Ada 95, pragma IMPORT) can appear in place of the body. The parser must
 226    --  recognize the use of these two pragmas in this context, otherwise it
 227    --  will think there are missing bodies, and try to change ; to IS, when
 228    --  in fact the bodies ARE present, supplied by these pragmas.
 229
 230    function P_Pragma return Node_Id is
 231
 232       Interface_Check_Required : Boolean := False;
 233       --  Set True if check of pragma INTERFACE is required
 234
 235       Import_Check_Required : Boolean := False;
 236       --  Set True if check of pragma IMPORT is required
 237
 238       Arg_Count : Int := 0;
 239       --  Number of argument associations processed
 240
 241       Identifier_Seen : Boolean := False;
 242       --  Set True if an identifier is encountered for a pragma argument. Used
 243       --  to check that there are no more arguments without identifiers.
 244
 245       Pragma_Node   : Node_Id;
 246       Pragma_Name   : Name_Id;
 247       Semicolon_Loc : Source_Ptr;
 248       Ident_Node    : Node_Id;
 249       Assoc_Node    : Node_Id;
 250       Result        : Node_Id;
 251
 252       procedure Skip_Pragma_Semicolon;
 253       --  Skip past semicolon at end of pragma
 254
 255       ---------------------------
 256       -- Skip_Pragma_Semicolon --
 257       ---------------------------
 258
 259       procedure Skip_Pragma_Semicolon is
 260       begin
 261          if Token /= Tok_Semicolon then
 262             T_Semicolon;
 263             Resync_Past_Semicolon;
 264          else
 265             Scan; -- past semicolon
 266          end if;
 267       end Skip_Pragma_Semicolon;
 268
 269    --  Start of processing for P_Pragma
 270
 271    begin
 272       Pragma_Node := New_Node (N_Pragma, Token_Ptr);
 273       Scan; -- past PRAGMA
 274       Pragma_Name := Token_Name;
 275
 276       if Style_Check then
 277          Style.Check_Pragma_Name;
 278       end if;
 279
 280       --  Ada 2005 (AI-284): INTERFACE is a new reserved word but it is
 281       --  allowed as a pragma name.
 282
 283       if Ada_Version >= Ada_05
 284         and then Token = Tok_Interface
 285       then
 286          Pragma_Name := Name_Interface;
 287          Ident_Node  := Token_Node;
 288          Scan; -- past INTERFACE
 289       else
 290          Ident_Node := P_Identifier;
 291          Delete_Node (Ident_Node);
 292       end if;
 293
 294       Set_Chars (Pragma_Node, Pragma_Name);
 295
 296       --  See if special INTERFACE/IMPORT check is required
 297
 298       if SIS_Entry_Active then
 299          Interface_Check_Required := (Pragma_Name = Name_Interface);
 300          Import_Check_Required    := (Pragma_Name = Name_Import);
 301       else
 302          Interface_Check_Required := False;
 303          Import_Check_Required    := False;
 304       end if;
 305
 306       --  Scan arguments. We assume that arguments are present if there is
 307       --  a left paren, or if a semicolon is missing and there is another
 308       --  token on the same line as the pragma name.
 309
 310       if Token = Tok_Left_Paren
 311         or else (Token /= Tok_Semicolon
 312                    and then not Token_Is_At_Start_Of_Line)
 313       then
 314          Set_Pragma_Argument_Associations (Pragma_Node, New_List);
 315          T_Left_Paren;
 316
 317          loop
 318             Arg_Count := Arg_Count + 1;
 319             Scan_Pragma_Argument_Association (Identifier_Seen, Assoc_Node);
 320
 321             if Arg_Count = 2
 322               and then (Interface_Check_Required or else Import_Check_Required)
 323             then
 324                --  Here is where we cancel the SIS active status if this pragma
 325                --  supplies a body for the currently active subprogram spec.
 326
 327                if Nkind (Expression (Assoc_Node)) in N_Direct_Name
 328                  and then Chars (Expression (Assoc_Node)) = Chars (SIS_Labl)
 329                then
 330                   SIS_Entry_Active := False;
 331                end if;
 332             end if;
 333
 334             Append (Assoc_Node, Pragma_Argument_Associations (Pragma_Node));
 335             exit when Token /= Tok_Comma;
 336             Scan; -- past comma
 337          end loop;
 338
 339          --  If we have := for pragma Debug, it is worth special casing
 340          --  the error message (it is easy to think of pragma Debug as
 341          --  taking a statement, and an assignment statement is the most
 342          --  likely candidate for this error)
 343
 344          if Token = Tok_Colon_Equal and then Pragma_Name = Name_Debug then
 345             Error_Msg_SC ("argument for pragma Debug must be procedure call");
 346             Resync_To_Semicolon;
 347
 348          --  Normal case, we expect a right paren here
 349
 350          else
 351             T_Right_Paren;
 352          end if;
 353       end if;
 354
 355       Semicolon_Loc := Token_Ptr;
 356
 357       --  Now we have two tasks left, we need to scan out the semicolon
 358       --  following the pragma, and we have to call Par.Prag to process
 359       --  the pragma. Normally we do them in this order, however, there
 360       --  is one exception namely pragma Style_Checks where we like to
 361       --  skip the semicolon after processing the pragma, since that way
 362       --  the style checks for the scanning of the semicolon follow the
 363       --  settings of the pragma.
 364
 365       --  You might think we could just unconditionally do things in
 366       --  the opposite order, but there are other pragmas, notably the
 367       --  case of pragma Source_File_Name, which assume the semicolon
 368       --  is already scanned out.
 369
 370       if Chars (Pragma_Node) = Name_Style_Checks then
 371          Result := Par.Prag (Pragma_Node, Semicolon_Loc);
 372          Skip_Pragma_Semicolon;
 373          return Result;
 374       else
 375          Skip_Pragma_Semicolon;
 376          return Par.Prag (Pragma_Node, Semicolon_Loc);
 377       end if;
 378
 379    exception
 380       when Error_Resync =>
 381          Resync_Past_Semicolon;
 382          return Error;
 383
 384    end P_Pragma;
 385
 386    --  This routine is called if a pragma is encountered in an inappropriate
 387    --  position, the pragma is scanned out and control returns to continue.
 388
 389    --  The caller has checked that the initial token is pragma
 390
 391    --  Error recovery: cannot raise Error_Resync
 392
 393    procedure P_Pragmas_Misplaced is
 394    begin
 395       while Token = Tok_Pragma loop
 396          Error_Msg_SC ("pragma not allowed here");
 397          Discard_Junk_Node (P_Pragma);
 398       end loop;
 399    end P_Pragmas_Misplaced;
 400
 401    --  This function is called to scan out an optional sequence of pragmas.
 402    --  If no pragmas are found, then No_List is returned.
 403
 404    --  Error recovery: Cannot raise Error_Resync
 405
 406    function P_Pragmas_Opt return List_Id is
 407       L : List_Id;
 408
 409    begin
 410       if Token = Tok_Pragma then
 411          L := New_List;
 412          P_Pragmas_Opt (L);
 413          return L;
 414
 415       else
 416          return No_List;
 417       end if;
 418    end P_Pragmas_Opt;
 419
 420    --  This procedure is called to scan out an optional sequence of pragmas.
 421    --  Any pragmas found are appended to the list provided as an argument.
 422
 423    --  Error recovery: Cannot raise Error_Resync
 424
 425    procedure P_Pragmas_Opt (List : List_Id) is
 426       P : Node_Id;
 427
 428    begin
 429       while Token = Tok_Pragma loop
 430          P := P_Pragma;
 431
 432          if Chars (P) = Name_Assert or else Chars (P) = Name_Debug then
 433             Error_Msg_Name_1 := Chars (P);
 434             Error_Msg_N
 435               ("pragma% must be in declaration/statement context", P);
 436          else
 437             Append (P, List);
 438          end if;
 439       end loop;
 440    end P_Pragmas_Opt;
 441
 442    --------------------------------------
 443    -- 2.8  Pragma_Argument Association --
 444    --------------------------------------
 445
 446    --  PRAGMA_ARGUMENT_ASSOCIATION ::=
 447    --    [pragma_argument_IDENTIFIER =>] NAME
 448    --  | [pragma_argument_IDENTIFIER =>] EXPRESSION
 449
 450    --  Error recovery: cannot raise Error_Resync
 451
 452    procedure Scan_Pragma_Argument_Association
 453      (Identifier_Seen : in out Boolean;
 454       Association     : out Node_Id)
 455    is
 456       Scan_State      : Saved_Scan_State;
 457       Identifier_Node : Node_Id;
 458
 459    begin
 460       Association := New_Node (N_Pragma_Argument_Association, Token_Ptr);
 461       Set_Chars (Association, No_Name);
 462
 463       if Token = Tok_Identifier then
 464          Identifier_Node := Token_Node;
 465          Save_Scan_State (Scan_State); -- at Identifier
 466          Scan; -- past Identifier
 467
 468          if Token = Tok_Arrow then
 469             Identifier_Seen := True;
 470             Scan; -- past arrow
 471             Set_Chars (Association, Chars (Identifier_Node));
 472             Delete_Node (Identifier_Node);
 473
 474             --  Case of argument with no identifier
 475
 476          else
 477             Restore_Scan_State (Scan_State); -- to Identifier
 478
 479             if Identifier_Seen then
 480                Error_Msg_SC
 481                  ("|pragma argument identifier required here (RM 2.8(4))");
 482             end if;
 483          end if;
 484       end if;
 485
 486       Set_Expression (Association, P_Expression);
 487    end Scan_Pragma_Argument_Association;
 488
 489 end Ch2;