gcc/ada/par-load.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             P A R . L O A D                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  The Par.Load procedure loads all units that are definitely required before
  27 --  it makes any sense at all to proceed with semantic analysis, including
  28 --  with'ed units, corresponding specs for bodies, parents of child specs,
  29 --  and parents of subunits. All these units are loaded and pointers installed
  30 --  in the tree as described in the spec of package Lib.
  31
  32 with Fname.UF; use Fname.UF;
  33 with Lib.Load; use Lib.Load;
  34 with Uname;    use Uname;
  35 with Osint;    use Osint;
  36 with Sinput.L; use Sinput.L;
  37 with Stylesw;  use Stylesw;
  38 with Validsw;  use Validsw;
  39
  40 with GNAT.Spelling_Checker; use GNAT.Spelling_Checker;
  41
  42 separate (Par)
  43 procedure Load is
  44
  45    File_Name : File_Name_Type;
  46    --  Name of file for current unit, derived from unit name
  47
  48    Cur_Unum : constant Unit_Number_Type := Current_Source_Unit;
  49    --  Unit number of unit that we just finished parsing. Note that we need
  50    --  to capture this, because Source_Unit will change as we parse new
  51    --  source files in the multiple main source file case.
  52
  53    Curunit : constant Node_Id := Cunit (Cur_Unum);
  54    --  Compilation unit node for current compilation unit
  55
  56    Loc : Source_Ptr := Sloc (Curunit);
  57    --  Source location for compilation unit node
  58
  59    Save_Style_Check  : Boolean;
  60    Save_Style_Checks : Style_Check_Options;
  61    --  Save style check so it can be restored later
  62
  63    Save_Validity_Check  : Boolean;
  64    Save_Validity_Checks : Validity_Check_Options;
  65    --  Save validity check so it can be restored later
  66
  67    With_Cunit : Node_Id;
  68    --  Compilation unit node for withed unit
  69
  70    Context_Node : Node_Id;
  71    --  Next node in context items list
  72
  73    With_Node : Node_Id;
  74    --  N_With_Clause node
  75
  76    Spec_Name : Unit_Name_Type;
  77    --  Unit name of required spec
  78
  79    Body_Name : Unit_Name_Type;
  80    --  Unit name of corresponding body
  81
  82    Unum : Unit_Number_Type;
  83    --  Unit number of loaded unit
  84
  85    Limited_With_Found : Boolean := False;
  86    --  We load the context items in two rounds: the first round handles normal
  87    --  withed units and the second round handles Ada 2005 limited-withed units.
  88    --  This is required to allow the low-level circuitry that detects circular
  89    --  dependencies of units the correct notification of errors (see comment
  90    --  bellow). This variable is used to indicate that the second round is
  91    --  required.
  92
  93    function Same_File_Name_Except_For_Case
  94      (Expected_File_Name : File_Name_Type;
  95       Actual_File_Name   : File_Name_Type) return Boolean;
  96    --  Given an actual file name and an expected file name (the latter being
  97    --  derived from the unit name), determine if they are the same except for
  98    --  possibly different casing of letters.
  99
 100    ------------------------------------
 101    -- Same_File_Name_Except_For_Case --
 102    ------------------------------------
 103
 104    function Same_File_Name_Except_For_Case
 105      (Expected_File_Name : File_Name_Type;
 106       Actual_File_Name   : File_Name_Type) return Boolean
 107    is
 108    begin
 109       Get_Name_String (Actual_File_Name);
 110       Canonical_Case_File_Name (Name_Buffer (1 .. Name_Len));
 111
 112       declare
 113          Lower_Case_Actual_File_Name : String (1 .. Name_Len);
 114
 115       begin
 116          Lower_Case_Actual_File_Name := Name_Buffer (1 .. Name_Len);
 117          Get_Name_String (Expected_File_Name);
 118          Canonical_Case_File_Name (Name_Buffer (1 .. Name_Len));
 119          return Lower_Case_Actual_File_Name = Name_Buffer (1 .. Name_Len);
 120       end;
 121
 122    end Same_File_Name_Except_For_Case;
 123
 124 --  Start of processing for Load
 125
 126 begin
 127    --  Don't do any loads if we already had a fatal error
 128
 129    if Fatal_Error (Cur_Unum) then
 130       return;
 131    end if;
 132
 133    Save_Style_Check_Options (Save_Style_Checks);
 134    Save_Style_Check := Opt.Style_Check;
 135
 136    Save_Validity_Check_Options (Save_Validity_Checks);
 137    Save_Validity_Check := Opt.Validity_Checks_On;
 138
 139    --  If main unit, set Main_Unit_Entity (this will get overwritten if
 140    --  the main unit has a separate spec, that happens later on in Load)
 141
 142    if Cur_Unum = Main_Unit then
 143       Main_Unit_Entity := Cunit_Entity (Main_Unit);
 144    end if;
 145
 146    --  If we have no unit name, things are seriously messed up by previous
 147    --  errors, and we should not try to continue compilation.
 148
 149    if Unit_Name (Cur_Unum) = No_Unit_Name then
 150       raise Unrecoverable_Error;
 151    end if;
 152
 153    --  Next step, make sure that the unit name matches the file name
 154    --  and issue a warning message if not. We only output this for the
 155    --  main unit, since for other units it is more serious and is
 156    --  caught in a separate test below. We also inhibit the message in
 157    --  multiple unit per file mode, because in this case the relation
 158    --  between file name and unit name is broken.
 159
 160    File_Name :=
 161      Get_File_Name
 162        (Unit_Name (Cur_Unum),
 163         Subunit => Nkind (Unit (Cunit (Cur_Unum))) = N_Subunit);
 164
 165    if Cur_Unum = Main_Unit
 166      and then Multiple_Unit_Index = 0
 167      and then File_Name /= Unit_File_Name (Cur_Unum)
 168      and then (File_Names_Case_Sensitive
 169                 or not Same_File_Name_Except_For_Case
 170                          (File_Name, Unit_File_Name (Cur_Unum)))
 171    then
 172       Error_Msg_File_1 := File_Name;
 173       Error_Msg
 174         ("?file name does not match unit name, should be{", Sloc (Curunit));
 175    end if;
 176
 177    --  For units other than the main unit, the expected unit name is set and
 178    --  must be the same as the actual unit name, or we are in big trouble, and
 179    --  abandon the compilation since there are situations where this really
 180    --  gets us into bad trouble (e.g. some subunit situations).
 181
 182    if Cur_Unum /= Main_Unit
 183      and then Expected_Unit (Cur_Unum) /= Unit_Name (Cur_Unum)
 184    then
 185       Loc := Error_Location (Cur_Unum);
 186       Error_Msg_File_1 := Unit_File_Name (Cur_Unum);
 187       Get_Name_String (Error_Msg_File_1);
 188
 189       --  Check for predefined file case
 190
 191       if Name_Len > 1
 192         and then Name_Buffer (2) = '-'
 193         and then (Name_Buffer (1) = 'a'
 194                     or else
 195                   Name_Buffer (1) = 's'
 196                     or else
 197                   Name_Buffer (1) = 'i'
 198                     or else
 199                   Name_Buffer (1) = 'g')
 200       then
 201          declare
 202             Expect_Name : constant Unit_Name_Type := Expected_Unit (Cur_Unum);
 203             Actual_Name : constant Unit_Name_Type := Unit_Name (Cur_Unum);
 204
 205          begin
 206             Error_Msg_Unit_1 := Expect_Name;
 207             Error_Msg ("$$ is not a predefined library unit!", Loc);
 208
 209             --  In the predefined file case, we know the user did not
 210             --  construct their own package, but we got the wrong one.
 211             --  This means that the name supplied by the user crunched
 212             --  to something we recognized, but then the file did not
 213             --  contain the unit expected. Most likely this is due to
 214             --  a misspelling, e.g.
 215
 216             --    with Ada.Calender;
 217
 218             --  This crunches to a-calend, which indeed contains the unit
 219             --  Ada.Calendar, and we can diagnose the misspelling. This
 220             --  is a simple heuristic, but it catches many common cases
 221             --  of misspelling of predefined unit names without needing
 222             --  a full list of them.
 223
 224             --  Before actually issuing the message, we will check that the
 225             --  unit name is indeed a plausible misspelling of the one we got.
 226
 227             if Is_Bad_Spelling_Of
 228               (Found  => Get_Name_String (Expect_Name),
 229                Expect => Get_Name_String (Actual_Name))
 230             then
 231                Error_Msg_Unit_1 := Actual_Name;
 232                Error_Msg ("possible misspelling of $$!", Loc);
 233             end if;
 234          end;
 235
 236       --  Non-predefined file name case. In this case we generate a message
 237       --  and then we quit, because we are in big trouble, and if we try
 238       --  to continue compilation, we get into some nasty situations
 239       --  (for example in some subunit cases).
 240
 241       else
 242          Error_Msg ("file { does not contain expected unit!", Loc);
 243          Error_Msg_Unit_1 := Expected_Unit (Cur_Unum);
 244          Error_Msg ("\\expected unit $!", Loc);
 245          Error_Msg_Unit_1 := Unit_Name (Cur_Unum);
 246          Error_Msg ("\\found unit $!", Loc);
 247       end if;
 248
 249       --  In both cases, remove the unit if it is the last unit (which it
 250       --  normally (always?) will be) so that it is out of the way later.
 251
 252       Remove_Unit (Cur_Unum);
 253    end if;
 254
 255    --  If current unit is a body, load its corresponding spec
 256
 257    if Nkind (Unit (Curunit)) = N_Package_Body
 258      or else Nkind (Unit (Curunit)) = N_Subprogram_Body
 259    then
 260       Spec_Name := Get_Spec_Name (Unit_Name (Cur_Unum));
 261       Unum :=
 262         Load_Unit
 263           (Load_Name  => Spec_Name,
 264            Required   => False,
 265            Subunit    => False,
 266            Error_Node => Curunit,
 267            Corr_Body  => Cur_Unum);
 268
 269       --  If we successfully load the unit, then set the spec pointer. Once
 270       --  again note that if the loaded unit has a fatal error, Load will
 271       --  have set our Fatal_Error flag to propagate this condition.
 272
 273       if Unum /= No_Unit then
 274          Set_Library_Unit (Curunit, Cunit (Unum));
 275
 276          --  If this is a separate spec for the main unit, then we reset
 277          --  Main_Unit_Entity to point to the entity for this separate spec
 278
 279          if Cur_Unum = Main_Unit then
 280             Main_Unit_Entity := Cunit_Entity (Unum);
 281          end if;
 282
 283       --  If we don't find the spec, then if we have a subprogram body, we
 284       --  are still OK, we just have a case of a body acting as its own spec
 285
 286       elsif Nkind (Unit (Curunit)) = N_Subprogram_Body then
 287          Set_Acts_As_Spec (Curunit, True);
 288          Set_Library_Unit (Curunit, Curunit);
 289
 290       --  Otherwise we do have an error, repeat the load request for the spec
 291       --  with Required set True to generate an appropriate error message.
 292
 293       else
 294          Unum :=
 295            Load_Unit
 296              (Load_Name  => Spec_Name,
 297               Required   => True,
 298               Subunit    => False,
 299               Error_Node => Curunit);
 300          return;
 301       end if;
 302
 303    --  If current unit is a child unit spec, load its parent. If the child unit
 304    --  is loaded through a limited with, the parent must be as well.
 305
 306    elsif     Nkind (Unit (Curunit)) =  N_Package_Declaration
 307      or else Nkind (Unit (Curunit)) =  N_Subprogram_Declaration
 308      or else Nkind (Unit (Curunit)) in N_Generic_Declaration
 309      or else Nkind (Unit (Curunit)) in N_Generic_Instantiation
 310      or else Nkind (Unit (Curunit)) in N_Renaming_Declaration
 311    then
 312       --  Turn style and validity checks off for parent unit
 313
 314       if not GNAT_Mode then
 315          Reset_Style_Check_Options;
 316          Reset_Validity_Check_Options;
 317       end if;
 318
 319       Spec_Name := Get_Parent_Spec_Name (Unit_Name (Cur_Unum));
 320
 321       if Spec_Name /= No_Unit_Name then
 322          Unum :=
 323            Load_Unit
 324              (Load_Name  => Spec_Name,
 325               Required   => True,
 326               Subunit    => False,
 327               Error_Node => Curunit);
 328
 329          if Unum /= No_Unit then
 330             Set_Parent_Spec (Unit (Curunit), Cunit (Unum));
 331          end if;
 332       end if;
 333
 334    --  If current unit is a subunit, then load its parent body
 335
 336    elsif Nkind (Unit (Curunit)) = N_Subunit then
 337       Body_Name := Get_Parent_Body_Name (Unit_Name (Cur_Unum));
 338       Unum :=
 339         Load_Unit
 340           (Load_Name  => Body_Name,
 341            Required   => True,
 342            Subunit    => True,
 343            Error_Node => Name (Unit (Curunit)));
 344
 345       if Unum /= No_Unit then
 346          Set_Library_Unit (Curunit, Cunit (Unum));
 347       end if;
 348    end if;
 349
 350    --  Now we load with'ed units, with style/validity checks turned off
 351
 352    if not GNAT_Mode then
 353       Reset_Style_Check_Options;
 354       Reset_Validity_Check_Options;
 355    end if;
 356
 357    --  Load the context items in two rounds: the first round handles normal
 358    --  withed units and the second round handles Ada 2005 limited-withed units.
 359    --  This is required to allow the low-level circuitry that detects circular
 360    --  dependencies of units the correct notification of the following error:
 361
 362    --       limited with D;
 363    --       with D;                  with C;
 364    --       package C is ...         package D is ...
 365
 366    for Round in 1 .. 2 loop
 367       Context_Node := First (Context_Items (Curunit));
 368       while Present (Context_Node) loop
 369
 370          --  During the first round we check if there is some limited-with
 371          --  context clause; otherwise the second round will be skipped
 372
 373          if Nkind (Context_Node) = N_With_Clause
 374            and then Round = 1
 375            and then Limited_Present (Context_Node)
 376          then
 377             Limited_With_Found := True;
 378          end if;
 379
 380          if Nkind (Context_Node) = N_With_Clause
 381            and then ((Round = 1 and then not Limited_Present (Context_Node))
 382                         or else
 383                      (Round = 2 and then Limited_Present (Context_Node)))
 384          then
 385             With_Node := Context_Node;
 386             Spec_Name := Get_Unit_Name (With_Node);
 387
 388             Unum :=
 389               Load_Unit
 390                 (Load_Name  => Spec_Name,
 391                  Required   => False,
 392                  Subunit    => False,
 393                  Error_Node => With_Node,
 394                  Renamings  => True,
 395                  With_Node  => Context_Node);
 396
 397             --  If we find the unit, then set spec pointer in the N_With_Clause
 398             --  to point to the compilation unit for the spec. Remember that
 399             --  the Load routine itself sets our Fatal_Error flag if the loaded
 400             --  unit gets a fatal error, so we don't need to worry about that.
 401
 402             if Unum /= No_Unit then
 403                Set_Library_Unit (With_Node, Cunit (Unum));
 404
 405             --  If the spec isn't found, then try finding the corresponding
 406             --  body, since it is possible that we have a subprogram body
 407             --  that is acting as a spec (since no spec is present).
 408
 409             else
 410                Body_Name := Get_Body_Name (Spec_Name);
 411                Unum :=
 412                  Load_Unit
 413                    (Load_Name  => Body_Name,
 414                     Required   => False,
 415                     Subunit    => False,
 416                     Error_Node => With_Node,
 417                     Renamings  => True);
 418
 419                --  If we got a subprogram body, then mark that we are using
 420                --  the body as a spec in the file table, and set the spec
 421                --  pointer in the N_With_Clause to point to the body entity.
 422
 423                if Unum /= No_Unit
 424                  and then Nkind (Unit (Cunit (Unum))) = N_Subprogram_Body
 425                then
 426                   With_Cunit := Cunit (Unum);
 427                   Set_Library_Unit (With_Node, With_Cunit);
 428                   Set_Acts_As_Spec (With_Cunit, True);
 429                   Set_Library_Unit (With_Cunit, With_Cunit);
 430
 431                --  If we couldn't find the body, or if it wasn't a body spec
 432                --  then we are in trouble. We make one more call to Load to
 433                --  require the spec. We know it will fail of course, the
 434                --  purpose is to generate the required error message (we prefer
 435                --  that this message refer to the missing spec, not the body)
 436
 437                else
 438                   Unum :=
 439                     Load_Unit
 440                       (Load_Name  => Spec_Name,
 441                        Required   => True,
 442                        Subunit    => False,
 443                        Error_Node => With_Node,
 444                        Renamings  => True);
 445
 446                   --  Here we create a dummy package unit for the missing unit
 447
 448                   Unum := Create_Dummy_Package_Unit (With_Node, Spec_Name);
 449                   Set_Library_Unit (With_Node, Cunit (Unum));
 450                end if;
 451             end if;
 452          end if;
 453
 454          Next (Context_Node);
 455       end loop;
 456
 457       exit when not Limited_With_Found;
 458    end loop;
 459
 460    --  Restore style/validity check mode for main unit
 461
 462    Set_Style_Check_Options (Save_Style_Checks);
 463    Opt.Style_Check := Save_Style_Check;
 464    Set_Validity_Check_Options (Save_Validity_Checks);
 465    Opt.Validity_Checks_On := Save_Validity_Check;
 466 end Load;