gcc/ada/ali.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                  A L I                                   --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  This package defines the internal data structures used for representation
  27 --  of Ada Library Information (ALI) acquired from the ALI files generated
  28 --  by the front end.
  29
  30 with Casing;  use Casing;
  31 with Gnatvsn; use Gnatvsn;
  32 with Namet;   use Namet;
  33 with Rident;  use Rident;
  34 with Table;
  35 with Types;   use Types;
  36
  37 with GNAT.HTable; use GNAT.HTable;
  38
  39 package ALI is
  40
  41    --------------
  42    -- Id Types --
  43    --------------
  44
  45    --  The various entries are stored in tables with distinct subscript
  46    --  ranges. The following type definitions indicate the ranges used
  47    --  for the subscripts (Id values) for the various tables.
  48
  49    type ALI_Id is range 0 .. 999_999;
  50    --  Id values used for ALIs table entries
  51
  52    type Unit_Id is range 1_000_000 .. 1_999_999;
  53    --  Id values used for Unit table entries
  54
  55    type With_Id is range 2_000_000 .. 2_999_999;
  56    --  Id values used for Withs table entries
  57
  58    type Arg_Id is range 3_000_000 .. 3_999_999;
  59    --  Id values used for argument table entries
  60
  61    type Sdep_Id is range 4_000_000 .. 4_999_999;
  62    --  Id values used for Sdep table entries
  63
  64    type Source_Id is range 5_000_000 .. 5_999_999;
  65    --  Id values used for Source table entries
  66
  67    type Interrupt_State_Id is range 6_000_000 .. 6_999_999;
  68    --  Id values used for Interrupt_State table entries
  69
  70    type Priority_Specific_Dispatching_Id is range 7_000_000 .. 7_999_999;
  71    --  Id values used for Priority_Specific_Dispatching table entries
  72
  73    --------------------
  74    -- ALI File Table --
  75    --------------------
  76
  77    --  Each ALI file read generates an entry in the ALIs table
  78
  79    No_ALI_Id : constant ALI_Id := ALI_Id'First;
  80    --  Special value indicating no ALI entry
  81
  82    First_ALI_Entry : constant ALI_Id := No_ALI_Id + 1;
  83    --  Id of first actual entry in table
  84
  85    type Main_Program_Type is (None, Proc, Func);
  86    --  Indicator of whether unit can be used as main program
  87
  88    type ALIs_Record is record
  89
  90       Afile : File_Name_Type;
  91       --  Name of ALI file
  92
  93       Ofile_Full_Name : File_Name_Type;
  94       --  Full name of object file corresponding to the ALI file
  95
  96       Sfile : File_Name_Type;
  97       --  Name of source file that generates this ALI file (which is equal
  98       --  to the name of the source file in the first unit table entry for
  99       --  this ALI file, since the body if present is always first).
 100
 101       Ver : String (1 .. Ver_Len_Max);
 102       --  Value of library version (V line in ALI file). Not set if
 103       --  V lines are ignored as a result of the Ignore_Lines parameter.
 104
 105       Ver_Len : Natural;
 106       --  Length of characters stored in Ver. Not set if V lines are
 107       --  ignored as a result of the Ignore_Lines parameter.
 108
 109       SAL_Interface : Boolean;
 110       --  Set True when this is an interface to a standalone library
 111
 112       First_Unit : Unit_Id;
 113       --  Id of first Unit table entry for this file
 114
 115       Last_Unit : Unit_Id;
 116       --  Id of last Unit table entry for this file
 117
 118       First_Sdep : Sdep_Id;
 119       --  Id of first Sdep table entry for this file
 120
 121       Last_Sdep : Sdep_Id;
 122       --  Id of last Sdep table entry for this file
 123
 124       Main_Program : Main_Program_Type;
 125       --  Indicator of whether first unit can be used as main program.
 126       --  Not set if 'M' appears in Ignore_Lines.
 127
 128       Main_Priority : Int;
 129       --  Indicates priority value if Main_Program field indicates that
 130       --  this can be a main program. A value of -1 (No_Main_Priority)
 131       --  indicates that no parameter was found, or no M line was present.
 132       --  Not set if 'M' appears in Ignore_Lines.
 133
 134       Time_Slice_Value : Int;
 135       --  Indicates value of time slice parameter from T=xxx on main program
 136       --  line. A value of -1 indicates that no T=xxx parameter was found,
 137       --  or no M line was present.
 138       --  Not set if 'M' appears in Ignore_Lines.
 139
 140       WC_Encoding : Character;
 141       --  Wide character encoding if main procedure. Otherwise not relevant.
 142       --  Not set if 'M' appears in Ignore_Lines.
 143
 144       Locking_Policy : Character;
 145       --  Indicates locking policy for units in this file. Space means
 146       --  tasking was not used, or that no Locking_Policy pragma was
 147       --  present or that this is a language defined unit. Otherwise set
 148       --  to first character (upper case) of policy name.
 149       --  Not set if 'P' appears in Ignore_Lines.
 150
 151       Queuing_Policy : Character;
 152       --  Indicates queuing policy for units in this file. Space means
 153       --  tasking was not used, or that no Queuing_Policy pragma was
 154       --  present or that this is a language defined unit. Otherwise set
 155       --  to first character (upper case) of policy name.
 156       --  Not set if 'P' appears in Ignore_Lines.
 157
 158       Task_Dispatching_Policy : Character;
 159       --  Indicates task dispatching policy for units in this file. Space
 160       --  means tasking was not used, or that no Task_Dispatching_Policy
 161       --  pragma was present or that this is a language defined unit.
 162       --  Otherwise set to first character (upper case) of policy name.
 163       --  Not set if 'P' appears in Ignore_Lines.
 164
 165       Compile_Errors : Boolean;
 166       --  Set to True if compile errors for unit. Note that No_Object
 167       --  will always be set as well in this case.
 168       --  Not set if 'P' appears in Ignore_Lines.
 169
 170       Float_Format : Character;
 171       --  Set to float format (set to I if no float-format given).
 172       --  Not set if 'P' appears in Ignore_Lines.
 173
 174       No_Object : Boolean;
 175       --  Set to True if no object file generated.
 176       --  Not set if 'P' appears in Ignore_Lines.
 177
 178       Normalize_Scalars : Boolean;
 179       --  Set to True if file was compiled with Normalize_Scalars.
 180       --  Not set if 'P' appears in Ignore_Lines.
 181
 182       Unit_Exception_Table : Boolean;
 183       --  Set to True if unit exception table pointer generated.
 184       --  Not set if 'P' appears in Ignore_Lines.
 185
 186       Zero_Cost_Exceptions : Boolean;
 187       --  Set to True if file was compiled with zero cost exceptions.
 188       --  Not set if 'P' appears in Ignore_Lines.
 189
 190       Restrictions : Restrictions_Info;
 191       --  Restrictions information reconstructed from R lines
 192
 193       First_Interrupt_State : Interrupt_State_Id;
 194       Last_Interrupt_State  : Interrupt_State_Id'Base;
 195       --  These point to the first and last entries in the interrupt
 196       --  state table for this unit. If there are no entries, then
 197       --  Last_Interrupt_State = First_Interrupt_State - 1 (that's
 198       --  why the 'Base reference is there, it can be one less than
 199       --  the lower bound of the subtype).
 200       --  Not set if 'I' appears in Ignore_Lines
 201
 202       First_Specific_Dispatching : Priority_Specific_Dispatching_Id;
 203       Last_Specific_Dispatching  : Priority_Specific_Dispatching_Id'Base;
 204       --  These point to the first and last entries in the priority specific
 205       --  dispatching table for this unit. If there are no entries, then
 206       --  Last_Specific_Dispatching = First_Specific_Dispatching - 1. That
 207       --  is why the 'Base reference is there, it can be one less than the
 208       --  lower bound of the subtype. Not set if 'S' appears in Ignore_Lines.
 209
 210    end record;
 211
 212    No_Main_Priority : constant Int := -1;
 213    --  Code for no main priority set
 214
 215    package ALIs is new Table.Table (
 216      Table_Component_Type => ALIs_Record,
 217      Table_Index_Type     => ALI_Id,
 218      Table_Low_Bound      => First_ALI_Entry,
 219      Table_Initial        => 500,
 220      Table_Increment      => 200,
 221      Table_Name           => "ALIs");
 222
 223    ----------------
 224    -- Unit Table --
 225    ----------------
 226
 227    --  Each unit within an ALI file generates an entry in the unit table
 228
 229    No_Unit_Id : constant Unit_Id := Unit_Id'First;
 230    --  Special value indicating no unit table entry
 231
 232    First_Unit_Entry : constant Unit_Id := No_Unit_Id + 1;
 233    --  Id of first actual entry in table
 234
 235    type Unit_Type is (Is_Spec, Is_Body, Is_Spec_Only, Is_Body_Only);
 236    --  Indicates type of entry, if both body and spec appear in the ALI file,
 237    --  then the first unit is marked Is_Body, and the second is marked Is_Spec.
 238    --  If only a spec appears, then it is marked as Is_Spec_Only, and if only
 239    --  a body appears, then it is marked Is_Body_Only).
 240
 241    subtype Version_String is String (1 .. 8);
 242    --  Version string, taken from unit record
 243
 244    type Unit_Record is record
 245
 246       My_ALI : ALI_Id;
 247       --  Corresponding ALI entry
 248
 249       Uname : Unit_Name_Type;
 250       --  Name of Unit
 251
 252       Sfile : File_Name_Type;
 253       --  Name of source file
 254
 255       Preelab : Boolean;
 256       --  Indicates presence of PR parameter for a preelaborated package
 257
 258       No_Elab : Boolean;
 259       --  Indicates presence of NE parameter for a unit that has does not
 260       --  have an elaboration routine (since it has no elaboration code).
 261
 262       Pure : Boolean;
 263       --  Indicates presence of PU parameter for a package having pragma Pure
 264
 265       Dynamic_Elab : Boolean;
 266       --  Set to True if the unit was compiled with dynamic elaboration checks
 267       --  (i.e. either -gnatE or pragma Elaboration_Checks (RM) was used to
 268       --  compile the unit).
 269
 270       Elaborate_Body : Boolean;
 271       --  Indicates presence of EB parameter for a package which has a pragma
 272       --  Elaborate_Body, and also for generic package instantiations.
 273
 274       Set_Elab_Entity : Boolean;
 275       --  Indicates presence of EE parameter for a unit which has an
 276       --  elaboration entity which must be set true as part of the
 277       --  elaboration of the entity.
 278
 279       Has_RACW : Boolean;
 280       --  Indicates presence of RA parameter for a package that declares at
 281       --  least one Remote Access to Class_Wide (RACW) object.
 282
 283       Remote_Types : Boolean;
 284       --  Indicates presence of RT parameter for a package which has a
 285       --  pragma Remote_Types.
 286
 287       Shared_Passive : Boolean;
 288       --  Indicates presence of SP parameter for a package which has a pragma
 289       --  Shared_Passive.
 290
 291       RCI : Boolean;
 292       --  Indicates presence of RC parameter for a package which has a pragma
 293       --  Remote_Call_Interface.
 294
 295       Predefined : Boolean;
 296       --  Indicates if unit is language predefined (or a child of such a unit)
 297
 298       Internal : Boolean;
 299       --  Indicates if unit is an internal unit (or a child of such a unit)
 300
 301       First_With : With_Id;
 302       --  Id of first withs table entry for this file
 303
 304       Last_With : With_Id;
 305       --  Id of last withs table entry for this file
 306
 307       First_Arg : Arg_Id;
 308       --  Id of first args table entry for this file
 309
 310       Last_Arg : Arg_Id;
 311       --  Id of last args table entry for this file
 312
 313       Utype : Unit_Type;
 314       --  Type of entry
 315
 316       Is_Generic : Boolean;
 317       --  True for generic unit (i.e. a generic declaration, or a generic
 318       --  body). False for a non-generic unit.
 319
 320       Unit_Kind : Character;
 321       --  Indicates the nature of the unit. 'p' for Packages and 's' for
 322       --  subprograms.
 323
 324       Version : Version_String;
 325       --  Version of unit
 326
 327       Icasing : Casing_Type;
 328       --  Indicates casing of identifiers in source file for this unit. This
 329       --  is used for informational output, and also for constructing the main
 330       --  unit if it is being built in Ada.
 331
 332       Kcasing : Casing_Type;
 333       --  Indicates casing of keywords in source file for this unit. This is
 334       --  used for informational output, and also for constructing the main
 335       --  unit if it is being built in Ada.
 336
 337       Elab_Position : aliased Natural;
 338       --  Initialized to zero. Set non-zero when a unit is chosen and
 339       --  placed in the elaboration order. The value represents the
 340       --  ordinal position in the elaboration order.
 341
 342       Init_Scalars : Boolean;
 343       --  Set True if IS qualifier appears in ALI file, indicating that
 344       --  an Initialize_Scalars pragma applies to the unit.
 345
 346       SAL_Interface : Boolean;
 347       --  Set True when this is an interface to a standalone library
 348
 349       Body_Needed_For_SAL : Boolean;
 350       --  Indicates that the source for the body of the unit (subprogram,
 351       --  package, or generic unit) must be included in a standalone library.
 352
 353       Elaborate_Body_Desirable : Boolean;
 354       --  Indicates that the front end elaboration circuitry decided that it
 355       --  would be a good idea if this package had Elaborate_Body. The binder
 356       --  will attempt, but does not promise, to place the elaboration call
 357       --  for the body right after the call for the spec, or at least as close
 358       --  together as possible.
 359
 360    end record;
 361
 362    package Units is new Table.Table (
 363      Table_Component_Type => Unit_Record,
 364      Table_Index_Type     => Unit_Id,
 365      Table_Low_Bound      => First_Unit_Entry,
 366      Table_Initial        => 100,
 367      Table_Increment      => 200,
 368      Table_Name           => "Unit");
 369
 370    ---------------------------
 371    -- Interrupt State Table --
 372    ---------------------------
 373
 374    --  An entry is made in this table for each I (interrupt state) line
 375    --  encountered in the input ALI file. The First/Last_Interrupt_Id
 376    --  fields of the ALI file entry show the range of entries defined
 377    --  within a particular ALI file.
 378
 379    type Interrupt_State_Record is record
 380       Interrupt_Id : Nat;
 381       --  Id from interrupt state entry
 382
 383       Interrupt_State : Character;
 384       --  State from interrupt state entry ('u'/'r'/'s')
 385
 386       IS_Pragma_Line : Nat;
 387       --  Line number of Interrupt_State pragma
 388    end record;
 389
 390    package Interrupt_States is new Table.Table (
 391      Table_Component_Type => Interrupt_State_Record,
 392      Table_Index_Type     => Interrupt_State_Id'Base,
 393      Table_Low_Bound      => Interrupt_State_Id'First,
 394      Table_Initial        => 100,
 395      Table_Increment      => 200,
 396      Table_Name           => "Interrupt_States");
 397
 398    -----------------------------------------
 399    -- Priority Specific Dispatching Table --
 400    -----------------------------------------
 401
 402    --  An entry is made in this table for each S (priority specific
 403    --  dispatching) line encountered in the input ALI file. The
 404    --  First/Last_Specific_Dispatching_Id fields of the ALI file
 405    --  entry show the range of entries defined within a particular
 406    --  ALI file.
 407
 408    type Specific_Dispatching_Record is record
 409       Dispatching_Policy : Character;
 410       --  First character (upper case) of the corresponding policy name
 411
 412       First_Priority     : Nat;
 413       --  Lower bound of the priority range to which the specified dispatching
 414       --  policy applies.
 415
 416       Last_Priority      : Nat;
 417       --  Upper bound of the priority range to which the specified dispatching
 418       --  policy applies.
 419
 420       PSD_Pragma_Line : Nat;
 421       --  Line number of Priority_Specific_Dispatching pragma
 422    end record;
 423
 424    package Specific_Dispatching is new Table.Table (
 425      Table_Component_Type => Specific_Dispatching_Record,
 426      Table_Index_Type     => Priority_Specific_Dispatching_Id'Base,
 427      Table_Low_Bound      => Priority_Specific_Dispatching_Id'First,
 428      Table_Initial        => 100,
 429      Table_Increment      => 200,
 430      Table_Name           => "Priority_Specific_Dispatching");
 431
 432    --------------
 433    -- Switches --
 434    --------------
 435
 436    --  These switches record status information about ali files that
 437    --  have been read, for quick reference without searching tables.
 438
 439    --  Note: a switch will be left set at its default value if the line
 440    --  which might otherwise set it is ignored (from Ignore_Lines).
 441
 442    Dynamic_Elaboration_Checks_Specified : Boolean := False;
 443    --  Set to False by Initialize_ALI. Set to True if Scan_ALI reads
 444    --  a unit for which dynamic elaboration checking is enabled.
 445
 446    Float_Format_Specified : Character := ' ';
 447    --  Set to blank by Initialize_ALI. Set to appropriate float format
 448    --  character (V or I, see Opt.Float_Format) if an an ali file that
 449    --  is read contains an F line setting the floating point format.
 450
 451    Initialize_Scalars_Used : Boolean := False;
 452    --  Set True if an ali file contains the Initialize_Scalars flag
 453
 454    Locking_Policy_Specified : Character := ' ';
 455    --  Set to blank by Initialize_ALI. Set to the appropriate locking policy
 456    --  character if an ali file contains a P line setting the locking policy.
 457
 458    No_Normalize_Scalars_Specified : Boolean := False;
 459    --  Set to False by Initialize_ALI. Set to True if an ali file indicates
 460    --  that the file was compiled without normalize scalars.
 461
 462    No_Object_Specified : Boolean := False;
 463    --  Set to False by Initialize_ALI. Set to True if an ali file contains
 464    --  the No_Object flag.
 465
 466    Normalize_Scalars_Specified : Boolean := False;
 467    --  Set to False by Initialize_ALI. Set to True if an ali file indicates
 468    --  that the file was compiled in Normalize_Scalars mode.
 469
 470    Queuing_Policy_Specified : Character := ' ';
 471    --  Set to blank by Initialize_ALI. Set to the appropriate queuing policy
 472    --  character if an ali file contains a P line setting the queuing policy.
 473
 474    Cumulative_Restrictions : Restrictions_Info := No_Restrictions;
 475    --  This variable records the cumulative contributions of R lines in all
 476    --  ali files, showing whether a restriction pragma exists anywhere, and
 477    --  accumulating the aggregate knowledge of violations.
 478
 479    Static_Elaboration_Model_Used : Boolean := False;
 480    --  Set to False by Initialize_ALI. Set to True if any ALI file for a
 481    --  non-internal unit compiled with the static elaboration model is
 482    --  encountered.
 483
 484    Task_Dispatching_Policy_Specified : Character := ' ';
 485    --  Set to blank by Initialize_ALI. Set to the appropriate task dispatching
 486    --  policy character if an ali file contains a P line setting the
 487    --  task dispatching policy.
 488
 489    Unreserve_All_Interrupts_Specified : Boolean := False;
 490    --  Set to False by Initialize_ALI. Set to True if an ali file is read that
 491    --  has  P line specifying unreserve all interrupts mode.
 492
 493    Zero_Cost_Exceptions_Specified : Boolean := False;
 494    --  Set to False by Initialize_ALI. Set to True if an ali file is read that
 495    --  has a P line specifying the generation of zero cost exceptions.
 496
 497    -----------------
 498    -- Withs Table --
 499    -----------------
 500
 501    --  Each With line (W line) in an ALI file generates a Withs table entry
 502
 503    --  Note: there will be no entries in this table if 'W' lines are ignored
 504
 505    No_With_Id : constant With_Id := With_Id'First;
 506    --  Special value indicating no withs table entry
 507
 508    First_With_Entry : constant With_Id := No_With_Id + 1;
 509    --  Id of first actual entry in table
 510
 511    type With_Record is record
 512
 513       Uname : Unit_Name_Type;
 514       --  Name of Unit
 515
 516       Sfile : File_Name_Type;
 517       --  Name of source file, set to No_File in generic case
 518
 519       Afile : File_Name_Type;
 520       --  Name of ALI file, set to No_File in generic case
 521
 522       Elaborate : Boolean;
 523       --  Indicates presence of E parameter
 524
 525       Elaborate_All : Boolean;
 526       --  Indicates presence of EA parameter
 527
 528       Elab_All_Desirable : Boolean;
 529       --  Indicates presence of AD parameter
 530
 531       Elab_Desirable     : Boolean;
 532       --  Indicates presence of ED parameter
 533
 534       SAL_Interface : Boolean := False;
 535       --  True if the Unit is an Interface of a Stand-Alone Library
 536
 537    end record;
 538
 539    package Withs is new Table.Table (
 540      Table_Component_Type => With_Record,
 541      Table_Index_Type     => With_Id,
 542      Table_Low_Bound      => First_With_Entry,
 543      Table_Initial        => 5000,
 544      Table_Increment      => 200,
 545      Table_Name           => "Withs");
 546
 547    ---------------------
 548    -- Arguments Table --
 549    ---------------------
 550
 551    --  Each Arg line (A line) in an ALI file generates an Args table entry
 552
 553    --  Note: there will be no entries in this table if 'A' lines are ignored
 554
 555    No_Arg_Id : constant Arg_Id := Arg_Id'First;
 556    --  Special value indicating no args table entry
 557
 558    First_Arg_Entry : constant Arg_Id := No_Arg_Id + 1;
 559    --  Id of first actual entry in table
 560
 561    package Args is new Table.Table (
 562      Table_Component_Type => String_Ptr,
 563      Table_Index_Type     => Arg_Id,
 564      Table_Low_Bound      => First_Arg_Entry,
 565      Table_Initial        => 1000,
 566      Table_Increment      => 100,
 567      Table_Name           => "Args");
 568
 569    --------------------------
 570    -- Linker_Options Table --
 571    --------------------------
 572
 573    --  If an ALI file has one of more Linker_Options lines, then a single
 574    --  entry is made in this table. If more than one Linker_Options lines
 575    --  appears in a given ALI file, then the arguments are concatenated
 576    --  to form the entry in this table, using a NUL character as the
 577    --  separator, and a final NUL character is appended to the end.
 578
 579    --  Note: there will be no entries in this table if 'L' lines are ignored
 580
 581    type Linker_Option_Record is record
 582       Name : Name_Id;
 583       --  Name entry containing concatenated list of Linker_Options
 584       --  arguments separated by NUL and ended by NUL as described above.
 585
 586       Unit : Unit_Id;
 587       --  Unit_Id for the entry
 588
 589       Internal_File : Boolean;
 590       --  Set True if the linker options are from an internal file. This is
 591       --  used to insert certain standard entries after all the user entries
 592       --  but before the entries from the run-time.
 593
 594       Original_Pos : Positive;
 595       --  Keep track of original position in the linker options table. This
 596       --  is used to implement a stable sort when we sort the linker options
 597       --  table.
 598    end record;
 599
 600    --  Declare the Linker_Options Table
 601
 602    --  The indexes of active entries in this table range from 1 to the
 603    --  value of Linker_Options.Last. The zero'th element is for sort call.
 604
 605    package Linker_Options is new Table.Table (
 606      Table_Component_Type => Linker_Option_Record,
 607      Table_Index_Type     => Integer,
 608      Table_Low_Bound      => 0,
 609      Table_Initial        => 200,
 610      Table_Increment      => 400,
 611      Table_Name           => "Linker_Options");
 612
 613    -------------------------------------------
 614    -- External Version Reference Hash Table --
 615    -------------------------------------------
 616
 617    --  This hash table keeps track of external version reference strings
 618    --  as read from E lines in the ali file. The stored values do not
 619    --  include the terminating quote characters.
 620
 621    --  Note: there will be no entries in this table if 'E' lines are ignored
 622
 623    type Vindex is range 0 .. 98;
 624    --  Type to define range of headers
 625
 626    function SHash (S : String_Ptr) return Vindex;
 627    --  Hash function for this table
 628
 629    function SEq (F1, F2 : String_Ptr) return Boolean;
 630    --  Equality function for this table
 631
 632    package Version_Ref is new Simple_HTable (
 633      Header_Num => Vindex,
 634      Element    => Boolean,
 635      No_Element => False,
 636      Key        => String_Ptr,
 637      Hash       => SHash,
 638      Equal      => SEq);
 639
 640    -------------------------
 641    -- No_Dependency Table --
 642    -------------------------
 643
 644    --  Each R line for a No_Dependency Restriction generates an entry in
 645    --  this No_Dependency table.
 646
 647    type No_Dep_Record is record
 648       ALI_File : ALI_Id;
 649       --  ALI File containing the entry
 650
 651       No_Dep_Unit : Name_Id;
 652       --  Id for names table entry including entire name, including periods
 653    end record;
 654
 655    package No_Deps is new Table.Table (
 656      Table_Component_Type => No_Dep_Record,
 657      Table_Index_Type     => Integer,
 658      Table_Low_Bound      => 0,
 659      Table_Initial        => 200,
 660      Table_Increment      => 400,
 661      Table_Name           => "No_Deps");
 662
 663    ------------------------------------
 664    -- Sdep (Source Dependency) Table --
 665    ------------------------------------
 666
 667    --  Each source dependency (D line) in an ALI file generates an
 668    --  entry in the Sdep table.
 669
 670    --  Note: there will be no entries in this table if 'D' lines are ignored
 671
 672    No_Sdep_Id : constant Sdep_Id := Sdep_Id'First;
 673    --  Special value indicating no Sdep table entry
 674
 675    First_Sdep_Entry : Sdep_Id := No_Sdep_Id + 1;
 676    --  Id of first Sdep entry for current ali file. This is initialized to
 677    --  the first Sdep entry in the table, and then incremented appropriately
 678    --  as successive ALI files are scanned.
 679
 680    type Sdep_Record is record
 681
 682       Sfile : File_Name_Type;
 683       --  Name of source file
 684
 685       Stamp : Time_Stamp_Type;
 686       --  Time stamp value. Note that this will be all zero characters
 687       --  for the dummy entries for missing or non-dependent files.
 688
 689       Checksum : Word;
 690       --  Checksum value. Note that this will be all zero characters
 691       --  for the dummy entries for missing or non-dependent files
 692
 693       Dummy_Entry : Boolean;
 694       --  Set True for dummy entries that correspond to missing files
 695       --  or files where no dependency relationship exists.
 696
 697       Subunit_Name : Name_Id;
 698       --  Name_Id for subunit name if present, else No_Name
 699
 700       Rfile : File_Name_Type;
 701       --  Reference file name. Same as Sfile unless a Source_Reference
 702       --  pragma was used, in which case it reflects the name used in
 703       --  the pragma.
 704
 705       Start_Line : Nat;
 706       --  Starting line number in file. Always 1, unless a Source_Reference
 707       --  pragma was used, in which case it reflects the line number value
 708       --  given in the pragma.
 709
 710    end record;
 711
 712    package Sdep is new Table.Table (
 713      Table_Component_Type => Sdep_Record,
 714      Table_Index_Type     => Sdep_Id,
 715      Table_Low_Bound      => First_Sdep_Entry,
 716      Table_Initial        => 5000,
 717      Table_Increment      => 200,
 718      Table_Name           => "Sdep");
 719
 720    ----------------------------
 721    -- Use of Name Table Info --
 722    ----------------------------
 723
 724    --  All unit names and file names are entered into the Names table. The
 725    --  Info fields of these entries are used as follows:
 726
 727    --    Unit name           Info field has Unit_Id of unit table entry
 728    --    ALI file name       Info field has ALI_Id of ALI table entry
 729    --    Source file name    Info field has Source_Id of source table entry
 730
 731    --------------------------
 732    -- Cross-Reference Data --
 733    --------------------------
 734
 735    --  The following table records cross-reference sections, there is one
 736    --  entry for each X header line in the ALI file for an xref section.
 737
 738    --  Note: there will be no entries in this table if 'X' lines are ignored
 739
 740    type Xref_Section_Record is record
 741       File_Num : Sdep_Id;
 742       --  Dependency number for file (entry in Sdep.Table)
 743
 744       File_Name : File_Name_Type;
 745       --  Name of file
 746
 747       First_Entity : Nat;
 748       --  First entry in Xref_Entity table
 749
 750       Last_Entity : Nat;
 751       --  Last entry in Xref_Entity table
 752    end record;
 753
 754    package Xref_Section is new Table.Table (
 755      Table_Component_Type => Xref_Section_Record,
 756      Table_Index_Type     => Nat,
 757      Table_Low_Bound      => 1,
 758      Table_Initial        => 50,
 759      Table_Increment      => 300,
 760      Table_Name           => "Xref_Section");
 761
 762    --  The following is used to indicate whether a typeref field is present
 763    --  for the entity, and if so what kind of typeref field.
 764
 765    type Tref_Kind is (
 766      Tref_None,    --  No typeref present
 767      Tref_Access,  --  Access type typeref (points to designated type)
 768      Tref_Derived, --  Derived type typeref (points to parent type)
 769      Tref_Type);   --  All other cases
 770
 771    --  The following table records entities for which xrefs are recorded
 772
 773    type Xref_Entity_Record is record
 774       Line : Pos;
 775       --  Line number of definition
 776
 777       Etype : Character;
 778       --  Set to the identification character for the entity. See section
 779       --  "Cross-Reference Entity Identifiers" in lib-xref.ads for details.
 780
 781       Col : Pos;
 782       --  Column number of definition
 783
 784       Lib : Boolean;
 785       --  True if entity is library level entity
 786
 787       Entity : Name_Id;
 788       --  Name of entity
 789
 790       Iref_File_Num : Sdep_Id;
 791       --  This field is set to the dependency reference for the file containing
 792       --  the generic entity that this one instantiates, or to No_Sdep_Id if
 793       --  the current entity is not an instantiation
 794
 795       Iref_Line : Nat;
 796       --  This field is set to the line number in Iref_File_Num of the generic
 797       --  entity that this one instantiates, or to zero if the current entity
 798       --  is not an instantiation.
 799
 800       Rref_Line : Nat;
 801       --  This field is set to the line number of a renaming reference if
 802       --  one is present, or to zero if no renaming reference is present
 803
 804       Rref_Col : Nat;
 805       --  This field is set to the column number of a renaming reference
 806       --  if one is present, or to zero if no renaming reference is present.
 807
 808       Tref : Tref_Kind;
 809       --  Indicates if a typeref is present, and if so what kind. Set to
 810       --  Tref_None if no typeref field is present.
 811
 812       Tref_File_Num : Sdep_Id;
 813       --  This field is set to No_Sdep_Id if no typeref is present, or
 814       --  if the typeref refers to an entity in standard. Otherwise it
 815       --  it is the dependency reference for the file containing the
 816       --  declaration of the typeref entity.
 817
 818       Tref_Line : Nat;
 819       --  This field is set to zero if no typeref is present, or if the
 820       --  typeref refers to an entity in standard. Otherwise it contains
 821       --  the line number of the declaration of the typeref entity.
 822
 823       Tref_Type : Character;
 824       --  This field is set to blank if no typeref is present, or if the
 825       --  typeref refers to an entity in standard. Otherwise it contains
 826       --  the identification character for the typeref entity. See section
 827       --  "Cross-Reference Entity Identifiers" in lib-xref.ads for details.
 828
 829       Tref_Col : Nat;
 830       --  This field is set to zero if no typeref is present, or if the
 831       --  typeref refers to an entity in standard. Otherwise it contains
 832       --  the column number of the declaration of the parent type.
 833
 834       Tref_Standard_Entity : Name_Id;
 835       --  This field is set to No_Name if no typeref is present or if the
 836       --  typeref refers to a declared entity rather than an entity in
 837       --  package Standard. If there is a typeref that references an
 838       --  entity in package Standard, then this field is a Name_Id
 839       --  reference for the entity name.
 840
 841       Oref_File_Num : Sdep_Id;
 842       --  This field is set to No_Sdep_Id if the entity doesn't override any
 843       --  other entity, or to the dependency reference for the overriden
 844       --  entity.
 845
 846       Oref_Line : Nat;
 847       Oref_Col  : Nat;
 848       --  These two fields are set to the line and column of the overriden
 849       --  entity.
 850
 851       First_Xref : Nat;
 852       --  Index into Xref table of first cross-reference
 853
 854       Last_Xref : Nat;
 855       --  Index into Xref table of last cross-reference. The value in
 856       --  Last_Xref can be less than the First_Xref value to indicate
 857       --  that no entries are present in the Xref Table.
 858    end record;
 859
 860    package Xref_Entity is new Table.Table (
 861      Table_Component_Type => Xref_Entity_Record,
 862      Table_Index_Type     => Nat,
 863      Table_Low_Bound      => 1,
 864      Table_Initial        => 500,
 865      Table_Increment      => 300,
 866      Table_Name           => "Xref_Entity");
 867
 868    --  The following table records actual cross-references
 869
 870    type Xref_Record is record
 871       File_Num : Sdep_Id;
 872       --  Set to the file dependency number for the cross-reference. Note
 873       --  that if no file entry is present explicitly, this is just a copy
 874       --  of the reference for the current cross-reference section.
 875
 876       Line : Pos;
 877       --  Line number for the reference
 878
 879       Rtype : Character;
 880       --  Indicates type of reference, using code used in ALI file:
 881       --    r = reference
 882       --    m = modification
 883       --    b = body entity
 884       --    c = completion of private or incomplete type
 885       --    x = type extension
 886       --    i = implicit reference
 887       --  See description in lib-xref.ads for further details
 888
 889       Col : Nat;
 890       --  Column number for the reference
 891
 892       --  Note: for instantiation references, Rtype is set to ' ', and Col is
 893       --  set to zero. One or more such entries can follow any other reference.
 894       --  When there is more than one such entry, this is to be read as:
 895       --     e.g. ref1  ref2  ref3
 896       --     ref1 is a reference to an entity that was instantied at ref2.
 897       --     ref2 itself is also the result of an instantiation, that took
 898       --     place at ref3
 899    end record;
 900
 901    package Xref is new Table.Table (
 902      Table_Component_Type => Xref_Record,
 903      Table_Index_Type     => Nat,
 904      Table_Low_Bound      => 1,
 905      Table_Initial        => 2000,
 906      Table_Increment      => 300,
 907      Table_Name           => "Xref");
 908
 909    --------------------------------------
 910    -- Subprograms for Reading ALI File --
 911    --------------------------------------
 912
 913    procedure Initialize_ALI;
 914    --  Initialize the ALI tables. Also resets all switch values to defaults
 915
 916    function Scan_ALI
 917      (F             : File_Name_Type;
 918       T             : Text_Buffer_Ptr;
 919       Ignore_ED     : Boolean;
 920       Err           : Boolean;
 921       Read_Xref     : Boolean := False;
 922       Read_Lines    : String  := "";
 923       Ignore_Lines  : String  := "X";
 924       Ignore_Errors : Boolean := False) return ALI_Id;
 925    --  Given the text, T, of an ALI file, F, scan and store the information
 926    --  from the file, and return the Id of the resulting entry in the ALI
 927    --  table. Switch settings may be modified as described above in the
 928    --  switch description settings.
 929    --
 930    --    Ignore_ED is normally False. If set to True, it indicates that
 931    --    all AD/ED (elaboration desirable) indications in the ALI file are
 932    --    to be ignored. This parameter is obsolete now that the -f switch
 933    --    is removed from gnatbind, and should be removed ???
 934    --
 935    --    Err determines the action taken on an incorrectly formatted file.
 936    --    If Err is False, then an error message is output, and the program
 937    --    is terminated. If Err is True, then no error message is output,
 938    --    and No_ALI_Id is returned.
 939    --
 940    --    Ignore_Lines requests that Scan_ALI ignore any lines that start
 941    --    with any given key character. The default value of X causes all
 942    --    Xref lines to be ignored. The corresponding data in the ALI
 943    --    tables will not be filled in in this case. It is not possible
 944    --    to ignore U (unit) lines, they are always read.
 945    --
 946    --    Read_Lines requests that Scan_ALI process only lines that start
 947    --    with one of the given characters. The corresponding data in the
 948    --    ALI file for any characters not given in the list will not be
 949    --    set. The default value of the null string indicates that all
 950    --    lines should be read (unless Ignore_Lines is specified). U
 951    --    (unit) lines are always read regardless of the value of this
 952    --    parameter.
 953    --
 954    --    Note: either Ignore_Lines or Read_Lines should be non-null.
 955    --    but not both. If both are given then only the Read_Lines
 956    --    value is processed, and the Ignore_Lines parameter is
 957    --    not processed.
 958    --
 959    --    Read_XREF is set True to read and acquire the cross-reference
 960    --    information. If Read_XREF is set to True, then the effect is
 961    --    to ignore all lines other than U, W, D and X lines and the
 962    --    Ignore_Lines and Read_Lines parameters are ignored (i.e. the
 963    --    use of True for Read_XREF is equivalent to specifying an
 964    --    argument of "UWDX" for Read_Lines.
 965    --
 966    --    Ignore_Errors is normally False. If it is set True, then Scan_ALI
 967    --    will do its best to scan through a file and extract all information
 968    --    it can, even if there are errors. In this case Err is only set if
 969    --    Scan_ALI was completely unable to process the file (e.g. it did not
 970    --    look like an ALI file at all). Ignore_Errors is intended to improve
 971    --    the downward compatibility of new compilers with old tools.
 972
 973 end ALI;