gcc/ada/a-cohama.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --            A D A . C O N T A I N E R S . H A S H E D _ M A P S           --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  24 -- Boston, MA 02110-1301, USA.                                              --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- This unit was originally developed by Matthew J Heaney.                  --
  34 ------------------------------------------------------------------------------
  35
  36 with Ada.Containers.Hash_Tables;
  37 with Ada.Streams;
  38 with Ada.Finalization;
  39
  40 generic
  41    type Key_Type is private;
  42    type Element_Type is private;
  43
  44    with function Hash (Key : Key_Type) return Hash_Type;
  45    with function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
  46    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  47
  48 package Ada.Containers.Hashed_Maps is
  49    pragma Preelaborate;
  50    pragma Remote_Types;
  51
  52    type Map is tagged private;
  53    pragma Preelaborable_Initialization (Map);
  54
  55    type Cursor is private;
  56    pragma Preelaborable_Initialization (Cursor);
  57
  58    Empty_Map : constant Map;
  59
  60    No_Element : constant Cursor;
  61
  62    function "=" (Left, Right : Map) return Boolean;
  63
  64    function Capacity (Container : Map) return Count_Type;
  65
  66    procedure Reserve_Capacity (Container : in out Map;
  67                                Capacity  : Count_Type);
  68
  69    function Length (Container : Map) return Count_Type;
  70
  71    function Is_Empty (Container : Map) return Boolean;
  72
  73    procedure Clear (Container : in out Map);
  74
  75    function Key (Position : Cursor) return Key_Type;
  76
  77    function Element (Position : Cursor) return Element_Type;
  78
  79    procedure Replace_Element
  80      (Container : in out Map;
  81       Position  : Cursor;
  82       New_Item  : Element_Type);
  83
  84    procedure Query_Element
  85      (Position : Cursor;
  86       Process  : not null access
  87                    procedure (Key : Key_Type; Element : Element_Type));
  88
  89    procedure Update_Element
  90      (Container : in out Map;
  91       Position  : Cursor;
  92       Process   : not null access
  93                    procedure (Key : Key_Type; Element : in out Element_Type));
  94
  95    procedure Move (Target : in out Map; Source : in out Map);
  96
  97    procedure Insert
  98      (Container : in out Map;
  99       Key       : Key_Type;
 100       New_Item  : Element_Type;
 101       Position  : out Cursor;
 102       Inserted  : out Boolean);
 103
 104    procedure Insert
 105      (Container : in out Map;
 106       Key       : Key_Type;
 107       Position  : out Cursor;
 108       Inserted  : out Boolean);
 109
 110    procedure Insert
 111      (Container : in out Map;
 112       Key       : Key_Type;
 113       New_Item  : Element_Type);
 114
 115    procedure Include
 116      (Container : in out Map;
 117       Key       : Key_Type;
 118       New_Item  : Element_Type);
 119
 120    procedure Replace
 121      (Container : in out Map;
 122       Key       : Key_Type;
 123       New_Item  : Element_Type);
 124
 125    procedure Exclude (Container : in out Map; Key : Key_Type);
 126
 127    procedure Delete (Container : in out Map; Key : Key_Type);
 128
 129    procedure Delete (Container : in out Map; Position : in out Cursor);
 130
 131    function First (Container : Map) return Cursor;
 132
 133    function Next (Position : Cursor) return Cursor;
 134
 135    procedure Next (Position : in out Cursor);
 136
 137    function Find (Container : Map; Key : Key_Type) return Cursor;
 138
 139    function Contains (Container : Map; Key : Key_Type) return Boolean;
 140
 141    function Element (Container : Map; Key : Key_Type) return Element_Type;
 142
 143    function Has_Element (Position : Cursor) return Boolean;
 144
 145    function Equivalent_Keys (Left, Right : Cursor) return Boolean;
 146
 147    function Equivalent_Keys (Left : Cursor; Right : Key_Type) return Boolean;
 148
 149    function Equivalent_Keys (Left : Key_Type; Right : Cursor) return Boolean;
 150
 151    procedure Iterate
 152      (Container : Map;
 153       Process   : not null access procedure (Position : Cursor));
 154
 155 private
 156    pragma Inline ("=");
 157    pragma Inline (Length);
 158    pragma Inline (Is_Empty);
 159    pragma Inline (Clear);
 160    pragma Inline (Key);
 161    pragma Inline (Element);
 162    pragma Inline (Move);
 163    pragma Inline (Contains);
 164    pragma Inline (Capacity);
 165    pragma Inline (Reserve_Capacity);
 166    pragma Inline (Has_Element);
 167    pragma Inline (Equivalent_Keys);
 168    pragma Inline (Next);
 169
 170    type Node_Type;
 171    type Node_Access is access Node_Type;
 172
 173    type Node_Type is limited record
 174       Key     : Key_Type;
 175       Element : Element_Type;
 176       Next    : Node_Access;
 177    end record;
 178
 179    package HT_Types is new Hash_Tables.Generic_Hash_Table_Types
 180      (Node_Type,
 181       Node_Access);
 182
 183    type Map is new Ada.Finalization.Controlled with record
 184       HT : HT_Types.Hash_Table_Type;
 185    end record;
 186
 187    use HT_Types;
 188    use Ada.Finalization;
 189
 190    procedure Adjust (Container : in out Map);
 191
 192    procedure Finalize (Container : in out Map);
 193
 194    use Ada.Streams;
 195
 196    procedure Write
 197      (Stream    : not null access Root_Stream_Type'Class;
 198       Container : Map);
 199
 200    for Map'Write use Write;
 201
 202    procedure Read
 203      (Stream    : not null access Root_Stream_Type'Class;
 204       Container : out Map);
 205
 206    for Map'Read use Read;
 207
 208    type Map_Access is access constant Map;
 209    for Map_Access'Storage_Size use 0;
 210
 211    type Cursor is
 212       record
 213          Container : Map_Access;
 214          Node      : Node_Access;
 215       end record;
 216
 217    procedure Read
 218      (Stream : not null access Root_Stream_Type'Class;
 219       Item   : out Cursor);
 220
 221    for Cursor'Read use Read;
 222
 223    procedure Write
 224      (Stream : not null access Root_Stream_Type'Class;
 225       Item   : Cursor);
 226
 227    for Cursor'Write use Write;
 228
 229    Empty_Map : constant Map := (Controlled with HT => (null, 0, 0, 0));
 230
 231    No_Element : constant Cursor := (Container => null, Node => null);
 232
 233 end Ada.Containers.Hashed_Maps;