libcpp/configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT(cpplib, [ ], gcc-bugs@gcc.gnu.org, cpplib)
   6 AC_CONFIG_SRCDIR(ucnid.h)
   7 AC_CONFIG_MACRO_DIR(../config)
   8 AC_CANONICAL_SYSTEM
   9
  10 # Checks for programs.
  11 AC_PROG_MAKE_SET
  12 AC_PROG_INSTALL
  13 AC_PROG_CC
  14 AC_PROG_RANLIB
  15
  16 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
  17 AC_CHECK_PROGS([ACLOCAL], [aclocal], [$MISSING aclocal])
  18 AC_CHECK_PROGS([AUTOCONF], [autoconf], [$MISSING autoconf])
  19 AC_CHECK_PROGS([AUTOHEADER], [autoheader], [$MISSING autoheader])
  20
  21 # Figure out what compiler warnings we can enable.
  22 # See config/warnings.m4 for details.
  23
  24 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
  25                           -Wmissing-prototypes -Wold-style-definition \
  26                           -Wmissing-format-attribute])
  27 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long])
  28
  29 # Only enable with --enable-werror-always until existing warnings are
  30 # corrected.
  31 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual])
  32
  33 # Dependency checking.
  34 ZW_CREATE_DEPDIR
  35 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  36
  37 # Checks for header files.
  38 AC_HEADER_TIME
  39 ACX_HEADER_STRING
  40 AC_CHECK_HEADERS(iconv.h locale.h fcntl.h limits.h stddef.h \
  41         stdlib.h strings.h string.h sys/file.h unistd.h)
  42
  43 # Checks for typedefs, structures, and compiler characteristics.
  44 AC_C_CONST
  45 AC_C_INLINE
  46 AC_FUNC_OBSTACK
  47 AC_TYPE_OFF_T
  48 AC_TYPE_SIZE_T
  49 AC_STRUCT_TM
  50 AC_CHECK_SIZEOF(int)
  51 AC_CHECK_SIZEOF(long)
  52 define(libcpp_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
  53   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
  54   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
  55   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
  56   putchar_unlocked putc_unlocked)
  57 AC_CHECK_FUNCS(libcpp_UNLOCKED_FUNCS)
  58 AC_CHECK_DECLS(m4_split(m4_normalize(abort asprintf basename errno getopt \
  59   libcpp_UNLOCKED_FUNCS vasprintf)))
  60
  61 # Checks for library functions.
  62 AC_FUNC_ALLOCA
  63 AC_HEADER_STDC
  64 AM_LANGINFO_CODESET
  65 ZW_GNU_GETTEXT_SISTER_DIR
  66
  67 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
  68 [AC_TRY_COMPILE([
  69 #include <sys/types.h>
  70 ],
  71 [if ((uchar *)0) return 0;
  72  if (sizeof(uchar)) return 0;],
  73 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
  74 if test $ac_cv_type_uchar = yes; then
  75   AC_DEFINE(HAVE_UCHAR, 1,
  76   [Define if <sys/types.h> defines \`uchar'.])
  77 fi
  78
  79 AM_ICONV
  80
  81 # More defines and substitutions.
  82 PACKAGE="$PACKAGE_TARNAME"
  83 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Define to the name of this package.])
  84 AC_SUBST(PACKAGE)
  85
  86 if test "x$enable_nls" != xno; then
  87   USED_CATALOGS='$(CATALOGS)'
  88 else
  89   USED_CATALOGS=
  90 fi
  91 AC_SUBST(USED_CATALOGS)
  92
  93 AC_ARG_ENABLE(maintainer-mode,
  94 [  --enable-maintainer-mode enable rules only needed by maintainers],,
  95 enable_maintainer_mode=no)
  96
  97 if test "x$enable_maintainer_mode" = xno; then
  98   MAINT='#'
  99 else
 100   MAINT=
 101 fi
 102 AC_SUBST(MAINT)
 103
 104 AC_ARG_ENABLE(checking,
 105 [  --enable-checking      enable expensive run-time checks],,
 106 enable_checking=no)
 107
 108 if test $enable_checking != no ; then
 109   AC_DEFINE(ENABLE_CHECKING, 1,
 110 [Define if you want more run-time sanity checks.])
 111 fi
 112
 113 m4_changequote(,)
 114 case $target in
 115         alpha*-*-* | \
 116         arm*-*-*eabi* | \
 117         arm*-*-symbianelf* | \
 118         x86_64-*-* | \
 119         ia64-*-* | \
 120         hppa*64*-*-* | parisc*64*-*-* | \
 121         i[34567]86-*-solaris2.1[0-9]* | \
 122         mips*-*-* | \
 123         mmix-*-* | \
 124         powerpc*-*-* | \
 125         rs6000*-*-* | \
 126         s390*-*-* | \
 127         sparc64*-*-* | ultrasparc-*-freebsd* | \
 128         sparcv9-*-solaris2* | \
 129         sparc-*-solaris2.[789] | sparc-*-solaris2.1[0-9]* | \
 130         sh[123456789l]*-*-*)
 131                 need_64bit_hwint=yes ;;
 132         *)
 133                 need_64bit_hwint=no ;;
 134 esac
 135
 136 case $need_64bit_hwint:$ac_cv_sizeof_long in
 137         *:8 | no:*) host_wide_int=long ;;
 138         *) host_wide_int='long long' ;;
 139 esac
 140 m4_changequote([,])
 141
 142 AC_DEFINE_UNQUOTED(HOST_WIDE_INT, $host_wide_int,
 143 [Define to the widest efficient host integer type at least
 144    as wide as the target's size_t type.])
 145
 146 # Output.
 147
 148 AC_CONFIG_HEADERS(config.h:config.in, [echo timestamp > stamp-h1])
 149 AC_CONFIG_FILES(Makefile)
 150 AC_OUTPUT