boehm-gc/configure.in

   1 # Copyright (c) 1999-2001 by Red Hat, Inc. All rights reserved.
   2 #
   3 # THIS MATERIAL IS PROVIDED AS IS, WITH ABSOLUTELY NO WARRANTY EXPRESSED
   4 # OR IMPLIED.  ANY USE IS AT YOUR OWN RISK.
   5 #
   6 # Permission is hereby granted to use or copy this program
   7 # for any purpose,  provided the above notices are retained on all copies.
   8 # Permission to modify the code and to distribute modified code is granted,
   9 # provided the above notices are retained, and a notice that the code was
  10 # modified is included with the above copyright notice.
  11 #
  12 # Original author: Tom Tromey
  13
  14 dnl Process this file with autoconf to produce configure.
  15
  16 AC_INIT(gcj_mlc.c)
  17
  18 dnl Can't be done in GC_CONFIGURE because that confuses automake.
  19 AC_CONFIG_AUX_DIR(.)
  20
  21 GC_CONFIGURE(.)
  22
  23 AM_PROG_LIBTOOL
  24
  25 dnl We use these options to decide which functions to include.
  26 AC_ARG_WITH(target-subdir,
  27 [  --with-target-subdir=SUBDIR
  28                           configuring with a cross compiler])
  29 AC_ARG_WITH(cross-host,
  30 [  --with-cross-host=HOST  configuring with a cross compiler])
  31
  32 AM_MAINTAINER_MODE
  33 # automake wants to see AC_EXEEXT.  But we don't need it.  And having
  34 # it is actually a problem, because the compiler we're passed can't
  35 # necessarily do a full link.  So we fool automake here.
  36 if false; then
  37   # autoconf 2.50 runs AC_EXEEXT by default, and the macro expands
  38   # to nothing, so nothing would remain between `then' and `fi' if it
  39   # were not for the `:' below.
  40   :
  41   AC_EXEEXT
  42 fi
  43
  44 AC_MSG_CHECKING([for thread model used by GCC])
  45 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
  46 if test -z "$THREADS"; then
  47    THREADS=no
  48 fi
  49 AC_MSG_RESULT([$THREADS])
  50
  51 AC_ARG_ENABLE(parallel-mark,
  52 [  --enable-parallel-mark       parallelize marking and free list construction],
  53    [case "$THREADS" in
  54       no | none | single)
  55         AC_MSG_ERROR([Parallel mark requires --enable-threads=x spec])
  56         ;;
  57     esac]
  58 )
  59
  60 INCLUDES=-I${srcdir}/include
  61 THREADLIBS=
  62 case "$THREADS" in
  63  no | none | single)
  64     THREADS=none
  65     ;;
  66  posix | pthreads)
  67     THREADS=posix
  68     THREADLIBS=-lpthread
  69     case "$host" in
  70      x86-*-linux* | ia64-*-linux* | i586-*-linux* | i686-*-linux*)
  71         AC_DEFINE(GC_LINUX_THREADS)
  72         AC_DEFINE(_REENTRANT)
  73         if test "${enable_parallel_mark}"; then
  74           AC_DEFINE(PARALLEL_MARK)
  75         fi
  76         AC_DEFINE(THREAD_LOCAL_ALLOC)
  77         ;;
  78      *-*-linux*)
  79         AC_DEFINE(GC_LINUX_THREADS)
  80         AC_DEFINE(_REENTRANT)
  81         ;;
  82      *-*-hpux*)
  83         AC_MSG_WARN("Only HP/UX 11 threads are supported.")
  84         AC_DEFINE(GC_HPUX_THREADS)
  85         AC_DEFINE(_POSIX_C_SOURCE,199506L)
  86         if test "${enable_parallel_mark}" = yes; then
  87           AC_DEFINE(PARALLEL_MARK)
  88         fi
  89         AC_DEFINE(THREAD_LOCAL_ALLOC)
  90         THREADLIBS="-lpthread -lrt"
  91         ;;
  92      *-*-freebsd*)
  93         AC_MSG_WARN("FreeBSD does not yet fully support threads with Boehm GC.")
  94         AC_DEFINE(GC_FREEBSD_THREADS)
  95         INCLUDES="$INCLUDES -pthread"
  96         THREADLIBS=-pthread
  97         ;;
  98      *-*-solaris*)
  99         AC_DEFINE(GC_SOLARIS_THREADS)
 100         AC_DEFINE(GC_SOLARIS_PTHREADS)
 101         ;;
 102      *-*-irix*)
 103         AC_DEFINE(GC_IRIX_THREADS)
 104         ;;
 105      *-*-cygwin*)
 106         THREADLIBS=
 107         ;;
 108     esac
 109     ;;
 110  win32)
 111     AC_DEFINE(GC_WIN32_THREADS)
 112     AC_DEFINE(NO_GETENV)
 113     ;;
 114  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 115     AC_MSG_ERROR(thread package $THREADS not yet supported)
 116     ;;
 117  *)
 118     AC_MSG_ERROR($THREADS is an unknown thread package)
 119     ;;
 120 esac
 121 AC_SUBST(THREADLIBS)
 122
 123 AC_CHECK_LIB(dl, dlopen, EXTRA_TEST_LIBS="$EXTRA_TEST_LIBS -ldl")
 124 AC_SUBST(EXTRA_TEST_LIBS)
 125
 126 target_all=libgcjgc.la
 127 AC_SUBST(target_all)
 128 AC_SUBST(target_alias)
 129
 130 dnl If the target is an eCos system, use the appropriate eCos
 131 dnl I/O routines.
 132 dnl FIXME: this should not be a local option but a global target
 133 dnl system; at present there is no eCos target.
 134 TARGET_ECOS="no"
 135 AC_ARG_WITH(ecos,
 136 [  --with-ecos             enable runtime eCos target support],
 137 TARGET_ECOS="$with_ecos"
 138 )
 139
 140 addobjs=
 141 CXXINCLUDES=
 142 case "$TARGET_ECOS" in
 143    no)
 144       ;;
 145    *)
 146       AC_DEFINE(ECOS)
 147       CXXINCLUDES="-I${TARGET_ECOS}/include"
 148       addobjs="$addobjs ecos.lo"
 149       ;;
 150 esac
 151 AC_SUBST(CXX)
 152
 153 AC_SUBST(INCLUDES)
 154 AC_SUBST(CXXINCLUDES)
 155
 156 machdep=
 157 case "$host" in
 158  alpha*-*-openbsd*)
 159     machdep="alpha_mach_dep.lo"
 160     if test x"${ac_cv_lib_dl_dlopen}" != xyes ; then
 161        AC_MSG_WARN(OpenBSD/Alpha without dlopen(). Shared library support is disabled)
 162        AM_DISABLE_SHARED
 163     fi
 164     ;;
 165  alpha*-*-*)
 166     machdep="alpha_mach_dep.lo"
 167     ;;
 168  i?86-*-solaris2.[[89]]*)
 169     AC_DEFINE(SOLARIS25_PROC_VDB_BUG_FIXED)
 170     ;;
 171  mipstx39-*-elf*)
 172     machdep="mips_ultrix_mach_dep.lo"
 173     AC_DEFINE(STACKBASE, __stackbase)
 174     AC_DEFINE(DATASTART_IS_ETEXT)
 175     ;;
 176  mips-dec-ultrix*)
 177     machdep="mips_ultrix_mach-dep.lo"
 178     ;;
 179  mips-*-*)
 180     machdep="mips_sgi_mach_dep.lo"
 181     AC_DEFINE(NO_EXECUTE_PERMISSION)
 182     ;;
 183  sparc-sun-solaris2.3*)
 184     machdep="sparc_mach_dep.lo"
 185     AC_DEFINE(SUNOS53_SHARED_LIB)
 186     ;;
 187  sparc-sun-solaris2.*)
 188     machdep="sparc_mach_dep.lo"
 189     ;;
 190  ia64-*-*)
 191     machdep="mach_dep.lo ia64_save_regs_in_stack.lo"
 192     ;;
 193 esac
 194 if test x"$machdep" = x; then
 195    machdep="mach_dep.lo"
 196 fi
 197 addobjs="$addobjs $machdep"
 198 AC_SUBST(addobjs)
 199
 200 dnl As of 4.13a2, the collector will not properly work on Solaris when
 201 dnl built with gcc and -O.  So we remove -O in the appropriate case.
 202 case "$host" in
 203  sparc-sun-solaris2*)
 204     if test "$GCC" = yes; then
 205        new_CFLAGS=
 206        for i in $CFLAGS; do
 207           case "$i" in
 208            -O*)
 209               ;;
 210            *)
 211               new_CFLAGS="$new_CFLAGS $i"
 212               ;;
 213           esac
 214        done
 215        CFLAGS="$new_CFLAGS"
 216     fi
 217     ;;
 218 esac
 219
 220 dnl We need to override the top-level CFLAGS.  This is how we do it.
 221 MY_CFLAGS="$CFLAGS"
 222 AC_SUBST(MY_CFLAGS)
 223
 224 dnl Include defines that have become de facto standard.
 225 dnl ALL_INTERIOR_POINTERS can be overridden in startup code.
 226 AC_DEFINE(SILENT)
 227 AC_DEFINE(NO_SIGNALS)
 228 AC_DEFINE(NO_EXECUTE_PERMISSION)
 229 AC_DEFINE(ALL_INTERIOR_POINTERS)
 230
 231 dnl By default, make the library as general as possible.
 232 AC_DEFINE(JAVA_FINALIZATION)
 233 AC_DEFINE(GC_GCJ_SUPPORT)
 234 AC_DEFINE(ATOMIC_UNCOLLECTABLE)
 235
 236 dnl This is something of a hack.  When cross-compiling we turn off
 237 dnl some functionality. These is only correct when targetting an
 238 dnl embedded system.  FIXME.
 239 if test -n "${with_cross_host}"; then
 240    AC_DEFINE(NO_SIGSET)
 241    AC_DEFINE(NO_DEBUGGING)
 242 fi
 243
 244 AC_ARG_ENABLE(full-debug,
 245 [  --enable-full-debug  include full support for pointer backtracing etc.],
 246 [ if test "$enable_full_debug" = "yes"; then
 247     AC_MSG_WARN("Must define GC_DEBUG and use debug alloc. in clients.")
 248     AC_DEFINE(KEEP_BACK_PTRS)
 249     AC_DEFINE(DBG_HDRS_ALL)
 250     case $host in
 251       ia64-*-linux* )
 252         AC_DEFINE(MAKE_BACK_GRAPH)
 253       ;;
 254       x86-*-linux* | i586-*-linux* | i686-*-linux* )
 255         AC_DEFINE(MAKE_BACK_GRAPH)
 256         AC_MSG_WARN("Client must not use -fomit-frame-pointer.")
 257         AC_DEFINE(SAVE_CALL_COUNT, 8)
 258       ;;
 259     esac ]
 260   fi)
 261
 262 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 263
 264 if test "${multilib}" = "yes"; then
 265   multilib_arg="--enable-multilib"
 266 else
 267   multilib_arg=
 268 fi
 269
 270 AC_OUTPUT(Makefile include/Makefile, [
 271 dnl Put all the -D options in a file.
 272 echo "$DEFS" > boehm-cflags
 273
 274 if test -n "$CONFIG_FILES"; then
 275   ac_file=Makefile . ${gc_basedir}/../config-ml.in
 276 fi],
 277 srcdir=${srcdir}
 278 host=${host}
 279 target=${target}
 280 with_multisubdir=${with_multisubdir}
 281 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 282 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 283 gc_basedir=${gc_basedir}
 284 CC="${CC}"
 285 DEFS="$DEFS"
 286 )