boehm-gc/configure.in

   1 # Copyright (c) 1999-2001 by Red Hat, Inc. All rights reserved.
   2 #
   3 # THIS MATERIAL IS PROVIDED AS IS, WITH ABSOLUTELY NO WARRANTY EXPRESSED
   4 # OR IMPLIED.  ANY USE IS AT YOUR OWN RISK.
   5 #
   6 # Permission is hereby granted to use or copy this program
   7 # for any purpose,  provided the above notices are retained on all copies.
   8 # Permission to modify the code and to distribute modified code is granted,
   9 # provided the above notices are retained, and a notice that the code was
  10 # modified is included with the above copyright notice.
  11 #
  12 # Original author: Tom Tromey
  13
  14 dnl Process this file with autoconf to produce configure.
  15
  16 AC_INIT(gcj_mlc.c)
  17
  18 dnl Can't be done in GC_CONFIGURE because that confuses automake.
  19 AC_CONFIG_AUX_DIR(.)
  20
  21 GC_CONFIGURE(.)
  22
  23 AM_PROG_LIBTOOL
  24
  25 dnl We use these options to decide which functions to include.
  26 AC_ARG_WITH(target-subdir,
  27 [  --with-target-subdir=SUBDIR
  28                           configuring with a cross compiler])
  29 AC_ARG_WITH(cross-host,
  30 [  --with-cross-host=HOST  configuring with a cross compiler])
  31
  32 AM_MAINTAINER_MODE
  33 # automake wants to see AC_EXEEXT.  But we don't need it.  And having
  34 # it is actually a problem, because the compiler we're passed can't
  35 # necessarily do a full link.  So we fool automake here.
  36 if false; then
  37   # autoconf 2.50 runs AC_EXEEXT by default, and the macro expands
  38   # to nothing, so nothing would remain between `then' and `fi' if it
  39   # were not for the `:' below.
  40   :
  41   AC_EXEEXT
  42 fi
  43
  44 AC_MSG_CHECKING([for thread model used by GCC])
  45 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
  46 if test -z "$THREADS"; then
  47    THREADS=no
  48 fi
  49 AC_MSG_RESULT([$THREADS])
  50
  51 AC_ARG_ENABLE(parallel-mark,
  52 [  --enable-parallel-mark       parallelize marking and free list construction],
  53    [case "$THREADS" in
  54       no | none | single)
  55         AC_MSG_ERROR([Parallel mark requires --enable-threads=x spec])
  56         ;;
  57     esac]
  58 )
  59
  60 INCLUDES=-I${srcdir}/include
  61 THREADLIBS=
  62 case "$THREADS" in
  63  no | none | single)
  64     THREADS=none
  65     ;;
  66  posix | pthreads)
  67     THREADS=posix
  68     THREADLIBS=-lpthread
  69     case "$host" in
  70      x86-*-linux* | ia64-*-linux* | i586-*-linux* | i686-*-linux*)
  71         AC_DEFINE(GC_LINUX_THREADS)
  72         AC_DEFINE(_REENTRANT)
  73         if test "${enable_parallel_mark}"; then
  74           AC_DEFINE(PARALLEL_MARK)
  75         fi
  76         AC_DEFINE(THREAD_LOCAL_ALLOC)
  77         ;;
  78      *-*-linux*)
  79         AC_DEFINE(GC_LINUX_THREADS)
  80         AC_DEFINE(_REENTRANT)
  81         ;;
  82      *-*-hpux*)
  83         AC_MSG_WARN("Only HP/UX 11 threads are supported.")
  84         AC_DEFINE(GC_HPUX_THREADS)
  85         AC_DEFINE(_POSIX_C_SOURCE,199506L)
  86         if test "${enable_parallel_mark}" = yes; then
  87           AC_DEFINE(PARALLEL_MARK)
  88         fi
  89         AC_DEFINE(THREAD_LOCAL_ALLOC)
  90         THREADLIBS="-lpthread -lrt"
  91         ;;
  92      *-*-freebsd*)
  93         AC_MSG_WARN("Threaded GC is prone to deadlock before FreeBSD 4.5.")
  94         AC_MSG_WARN("Related symptom is pthread_join returns spurious EINTR.")
  95         AC_DEFINE(GC_FREEBSD_THREADS)
  96         INCLUDES="$INCLUDES -pthread"
  97         THREADLIBS=-pthread
  98         ;;
  99      *-*-solaris*)
 100         AC_DEFINE(GC_SOLARIS_THREADS)
 101         AC_DEFINE(GC_SOLARIS_PTHREADS)
 102         ;;
 103      *-*-irix*)
 104         AC_DEFINE(GC_IRIX_THREADS)
 105         ;;
 106      *-*-cygwin*)
 107         THREADLIBS=
 108         ;;
 109     esac
 110     ;;
 111  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 112     AC_MSG_ERROR(thread package $THREADS not yet supported)
 113     ;;
 114  *)
 115     AC_MSG_ERROR($THREADS is an unknown thread package)
 116     ;;
 117 esac
 118 AC_SUBST(THREADLIBS)
 119
 120 AC_CHECK_LIB(dl, dlopen, EXTRA_TEST_LIBS="$EXTRA_TEST_LIBS -ldl")
 121 AC_SUBST(EXTRA_TEST_LIBS)
 122
 123 target_all=libgcjgc.la
 124 AC_SUBST(target_all)
 125 AC_SUBST(target_alias)
 126
 127 dnl If the target is an eCos system, use the appropriate eCos
 128 dnl I/O routines.
 129 dnl FIXME: this should not be a local option but a global target
 130 dnl system; at present there is no eCos target.
 131 TARGET_ECOS="no"
 132 AC_ARG_WITH(ecos,
 133 [  --with-ecos             enable runtime eCos target support],
 134 TARGET_ECOS="$with_ecos"
 135 )
 136
 137 addobjs=
 138 CXXINCLUDES=
 139 case "$TARGET_ECOS" in
 140    no)
 141       ;;
 142    *)
 143       AC_DEFINE(ECOS)
 144       CXXINCLUDES="-I${TARGET_ECOS}/include"
 145       addobjs="$addobjs ecos.lo"
 146       ;;
 147 esac
 148 AC_SUBST(CXX)
 149
 150 AC_SUBST(INCLUDES)
 151 AC_SUBST(CXXINCLUDES)
 152
 153 machdep=
 154 case "$host" in
 155  alpha*-*-*)
 156     machdep="alpha_mach_dep.lo"
 157     ;;
 158  alpha-*-openbsd*)
 159     if test x"${ac_cv_lib_dl_dlopen}" != xyes ; then
 160        AC_MSG_WARN(OpenBSD/Alpha without dlopen(). Shared library support is disabled)
 161        AM_DISABLE_SHARED
 162     fi
 163     ;;
 164  i?86-*-solaris2.[[89]]*)
 165     AC_DEFINE(SOLARIS25_PROC_VDB_BUG_FIXED)
 166     ;;
 167  mipstx39-*-elf*)
 168     machdep="mips_ultrix_mach_dep.lo"
 169     AC_DEFINE(STACKBASE, __stackbase)
 170     AC_DEFINE(DATASTART_IS_ETEXT)
 171     ;;
 172  mips-dec-ultrix*)
 173     machdep="mips_ultrix_mach-dep.lo"
 174     ;;
 175  mips-*-*)
 176     machdep="mips_sgi_mach_dep.lo"
 177     AC_DEFINE(NO_EXECUTE_PERMISSION)
 178     ;;
 179  sparc-sun-solaris2.3*)
 180     AC_DEFINE(SUNOS53_SHARED_LIB)
 181     ;;
 182  ia64-*-hpux*)
 183     machdep="mach_dep.lo ia64_save_regs_in_stack.lo"
 184     ;;
 185 esac
 186 if test x"$machdep" = x; then
 187    machdep="mach_dep.lo"
 188 fi
 189 addobjs="$addobjs $machdep"
 190 AC_SUBST(addobjs)
 191
 192 dnl As of 4.13a2, the collector will not properly work on Solaris when
 193 dnl built with gcc and -O.  So we remove -O in the appropriate case.
 194 case "$host" in
 195  sparc-sun-solaris2*)
 196     if test "$GCC" = yes; then
 197        new_CFLAGS=
 198        for i in $CFLAGS; do
 199           case "$i" in
 200            -O*)
 201               ;;
 202            *)
 203               new_CFLAGS="$new_CFLAGS $i"
 204               ;;
 205           esac
 206        done
 207        CFLAGS="$new_CFLAGS"
 208     fi
 209     ;;
 210 esac
 211
 212 dnl We need to override the top-level CFLAGS.  This is how we do it.
 213 MY_CFLAGS="$CFLAGS"
 214 AC_SUBST(MY_CFLAGS)
 215
 216 dnl Include defines that have become de facto standard.
 217 dnl ALL_INTERIOR_POINTERS can be overridden in startup code.
 218 AC_DEFINE(SILENT)
 219 AC_DEFINE(NO_SIGNALS)
 220 AC_DEFINE(NO_EXECUTE_PERMISSION)
 221 AC_DEFINE(ALL_INTERIOR_POINTERS)
 222
 223 dnl By default, make the library as general as possible.
 224 AC_DEFINE(JAVA_FINALIZATION)
 225 AC_DEFINE(GC_GCJ_SUPPORT)
 226 AC_DEFINE(ATOMIC_UNCOLLECTABLE)
 227
 228 dnl This is something of a hack.  When cross-compiling we turn off
 229 dnl some functionality.  We also enable the "small" configuration.
 230 dnl These is only correct when targetting an embedded system.  FIXME.
 231 if test -n "${with_cross_host}"; then
 232    AC_DEFINE(NO_SIGSET)
 233    AC_DEFINE(NO_CLOCK)
 234    AC_DEFINE(SMALL_CONFIG)
 235    AC_DEFINE(NO_DEBUGGING)
 236 fi
 237
 238 AC_ARG_ENABLE(full-debug,
 239 [  --enable-full-debug  include full support for pointer backtracing etc.],
 240 [ if test "$enable_full_debug" = "yes"; then
 241     AC_MSG_WARN("Must define GC_DEBUG and use debug alloc. in clients.")
 242     AC_DEFINE(KEEP_BACK_PTRS)
 243     AC_DEFINE(DBG_HDRS_ALL)
 244     case $host in
 245       x86-*-linux* | i586-*-linux* | i686-*-linux* )
 246         AC_MSG_WARN("Client must not use -fomit-frame-pointer.")
 247         AC_DEFINE(SAVE_CALL_COUNT, 8)
 248       ;;
 249     esac ]
 250   fi)
 251
 252 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 253
 254 if test "${multilib}" = "yes"; then
 255   multilib_arg="--enable-multilib"
 256 else
 257   multilib_arg=
 258 fi
 259
 260 AC_OUTPUT(Makefile include/Makefile, [
 261 dnl Put all the -D options in a file.
 262 echo "$DEFS" > boehm-cflags
 263
 264 if test -n "$CONFIG_FILES"; then
 265   ac_file=Makefile . ${gc_basedir}/../config-ml.in
 266 fi],
 267 srcdir=${srcdir}
 268 host=${host}
 269 target=${target}
 270 with_multisubdir=${with_multisubdir}
 271 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 272 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 273 gc_basedir=${gc_basedir}
 274 CC="${CC}"
 275 DEFS="$DEFS"
 276 )