libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=6:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist -Wall -Wno-portability])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  46 AC_SUBST(CC_FOR_BUILD)
  47
  48 AC_PROG_AWK
  49
  50 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  51 AC_SUBST(WARN_FLAGS)
  52
  53 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  54                                       [turns on -Werror @<:@default=yes@:>@])])
  55 if test "x$enable_werror" != "xno"; then
  56   WERROR="-Werror"
  57 fi
  58 AC_SUBST(WERROR)
  59
  60 glibgo_toolexecdir=no
  61 glibgo_toolexeclibdir=no
  62
  63 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  64 AC_ARG_ENABLE([version-specific-runtime-libs],
  65   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  66                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  67   [case "$enableval" in
  68     yes) version_specific_libs=yes ;;
  69     no)  version_specific_libs=no ;;
  70     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  71    esac],
  72   [version_specific_libs=no])
  73 AC_MSG_RESULT($version_specific_libs)
  74
  75 # Version-specific runtime libs processing.
  76 if test $version_specific_libs = yes; then
  77   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  78   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  79 fi
  80
  81 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  82 # Install a library built with a cross compiler in tooldir, not libdir.
  83 if test -n "$with_cross_host" &&
  84    test x"$with_cross_host" != x"no"; then
  85   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  86   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  87 else
  88   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  89   nover_glibgo_toolexeclibdir='${libdir}'
  90 fi
  91 multi_os_directory=`$GOC -print-multi-os-directory`
  92 case $multi_os_directory in
  93   .) ;; # Avoid trailing /.
  94   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
  95 esac
  96
  97 if test x"$glibgo_toolexecdir" = x"no"; then
  98   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
  99   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 100 fi
 101
 102 AC_SUBST(glibgo_toolexecdir)
 103 AC_SUBST(glibgo_toolexeclibdir)
 104 AC_SUBST(nover_glibgo_toolexeclibdir)
 105
 106 # See if the user wants to configure without libffi.  Some
 107 # architectures don't support it.  FIXME: We should set a default
 108 # based on the host.
 109 AC_ARG_WITH(libffi,
 110   AS_HELP_STRING([--without-libffi],
 111                  [don't use libffi]),
 112   [:],
 113   [with_libffi=${with_libffi_default-yes}])
 114
 115 LIBFFI=
 116 LIBFFIINCS=
 117 if test "$with_libffi" != no; then
 118    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 119    LIBFFI=../libffi/libffi_convenience.la
 120    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 121 fi
 122 AC_SUBST(LIBFFI)
 123 AC_SUBST(LIBFFIINCS)
 124
 125 # See if the user wants to configure without libatomic. This is useful if we are
 126 # on an architecture for which libgo does not need an atomic support library and
 127 # libatomic does not support our C compiler.
 128 AC_ARG_WITH(libatomic,
 129   AS_HELP_STRING([--without-libatomic],
 130                  [don't use libatomic]),
 131   [:],
 132   [with_libatomic=${with_libatomic_default-yes}])
 133
 134 LIBATOMIC=
 135 if test "$with_libatomic" != no; then
 136    LIBATOMIC=../libatomic/libatomic_convenience.la
 137 fi
 138 AC_SUBST(LIBATOMIC)
 139
 140 # Used to tell GNU make to include a file without telling automake to
 141 # include it.
 142 go_include="-include"
 143 AC_SUBST(go_include)
 144
 145 is_darwin=no
 146 is_freebsd=no
 147 is_irix=no
 148 is_linux=no
 149 is_netbsd=no
 150 is_openbsd=no
 151 is_dragonfly=no
 152 is_rtems=no
 153 is_solaris=no
 154 GOOS=unknown
 155 case ${host} in
 156   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 157   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 158   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 159   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 160   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 161   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 162   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 163   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 164   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 165 esac
 166 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 167 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 168 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 169 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 170 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 171 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 172 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 173 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 174 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 175 AC_SUBST(GOOS)
 176
 177 dnl Test whether we need to use DejaGNU or whether we can use the
 178 dnl simpler gotest approach.  We can only use gotest for a native
 179 dnl build.
 180 USE_DEJAGNU=no
 181 case ${host} in
 182   *-*-rtems*) USE_DEJAGNU=yes ;;
 183   ${build}) ;;
 184   *) USE_DEJAGNU=yes ;;
 185 esac
 186 AC_SUBST(USE_DEJAGNU)
 187
 188 dnl N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 189 is_386=no
 190 is_alpha=no
 191 is_arm=no
 192 is_arm64=no
 193 is_m68k=no
 194 mips_abi=unknown
 195 is_ppc=no
 196 is_ppc64=no
 197 is_s390=no
 198 is_s390x=no
 199 is_sparc=no
 200 is_sparc64=no
 201 is_x86_64=no
 202 GOARCH=unknown
 203 case ${host} in
 204   alpha*-*-*)
 205     is_alpha=yes
 206     GOARCH=alpha
 207     ;;
 208   aarch64-*-*)
 209     is_arm64=yes
 210     GOARCH=arm64
 211     ;;
 212   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 213     is_arm=yes
 214     GOARCH=arm
 215     ;;
 216 changequote(,)dnl
 217   i[34567]86-*-* | x86_64-*-*)
 218 changequote([,])dnl
 219     AC_COMPILE_IFELSE([
 220 #ifdef __x86_64__
 221 #error 64-bit
 222 #endif],
 223 [is_386=yes], [is_x86_64=yes])
 224     if test "$is_386" = "yes"; then
 225       GOARCH=386
 226     else
 227       GOARCH=amd64
 228     fi
 229     ;;
 230   m68k*-*-*)
 231     is_m68k=yes
 232     GOARCH=m68k
 233     ;;
 234   mips*-*-*)
 235     AC_COMPILE_IFELSE([
 236 #if _MIPS_SIM != _ABIO32
 237 #error not o32
 238 #endif],
 239 [mips_abi="o32"],
 240         [AC_COMPILE_IFELSE([
 241 #if _MIPS_SIM != _ABIN32
 242 #error not n32
 243 #endif],
 244 [mips_abi="n32"],
 245         [AC_COMPILE_IFELSE([
 246 #if _MIPS_SIM != _ABI64
 247 #error not n64
 248 #endif],
 249 [mips_abi="n64"],
 250         [AC_COMPILE_IFELSE([
 251 #if _MIPS_SIM != _ABIO64
 252 #error not o64
 253 #endif],
 254 [mips_abi="o64"],
 255         [AC_MSG_ERROR([unknown MIPS ABI])
 256 [mips_abi="n32"]])])])])
 257     case "$mips_abi" in
 258     "o32") GOARCH=mipso32 ;;
 259     "n32") GOARCH=mipsn32 ;;
 260     "n64") GOARCH=mipsn64 ;;
 261     "o64") GOARCH=mipso64 ;;
 262     esac
 263     ;;
 264   rs6000*-*-* | powerpc*-*-*)
 265     AC_COMPILE_IFELSE([
 266 #ifdef _ARCH_PPC64
 267 #error 64-bit
 268 #endif],
 269 [is_ppc=yes], [is_ppc64=yes])
 270     if test "$is_ppc" = "yes"; then
 271       GOARCH=ppc
 272     else
 273       GOARCH=ppc64
 274     fi
 275     ;;
 276   s390*-*-*)
 277     AC_COMPILE_IFELSE([
 278 #if defined(__s390x__)
 279 #error 64-bit
 280 #endif],
 281 [is_s390=yes], [is_s390x=yes])
 282     if test "$is_s390" = "yes"; then
 283       GOARCH=s390
 284     else
 285       GOARCH=s390x
 286     fi
 287     ;;
 288   sparc*-*-*)
 289     AC_COMPILE_IFELSE([
 290 #if defined(__sparcv9) || defined(__arch64__)
 291 #error 64-bit
 292 #endif],
 293 [is_sparc=yes], [is_sparc64=yes])
 294     if test "$is_sparc" = "yes"; then
 295       GOARCH=sparc
 296     else
 297       GOARCH=sparc64
 298     fi
 299     ;;
 300 esac
 301 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
 302 AM_CONDITIONAL(LIBGO_IS_ALPHA, test $is_alpha = yes)
 303 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
 304 AM_CONDITIONAL(LIBGO_IS_ARM64, test $is_arm64 = yes)
 305 AM_CONDITIONAL(LIBGO_IS_M68K, test $is_m68k = yes)
 306 AM_CONDITIONAL(LIBGO_IS_MIPS, test $mips_abi != unknown)
 307 AM_CONDITIONAL(LIBGO_IS_MIPSO32, test $mips_abi = o32)
 308 AM_CONDITIONAL(LIBGO_IS_MIPSN32, test $mips_abi = n32)
 309 AM_CONDITIONAL(LIBGO_IS_MIPSN64, test $mips_abi = n64)
 310 AM_CONDITIONAL(LIBGO_IS_MIPSO64, test $mips_abi = o64)
 311 AM_CONDITIONAL(LIBGO_IS_PPC, test $is_ppc = yes)
 312 AM_CONDITIONAL(LIBGO_IS_PPC64, test $is_ppc64 = yes)
 313 AM_CONDITIONAL(LIBGO_IS_S390, test $is_s390 = yes)
 314 AM_CONDITIONAL(LIBGO_IS_S390X, test $is_s390x = yes)
 315 AM_CONDITIONAL(LIBGO_IS_SPARC, test $is_sparc = yes)
 316 AM_CONDITIONAL(LIBGO_IS_SPARC64, test $is_sparc64 = yes)
 317 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
 318 AC_SUBST(GOARCH)
 319
 320 dnl Some files are only present when needed for specific architectures.
 321 GO_LIBCALL_OS_FILE=
 322 GO_LIBCALL_OS_ARCH_FILE=
 323 GO_SYSCALL_OS_FILE=
 324 GO_SYSCALL_OS_ARCH_FILE=
 325 if test -f "${srcdir}/go/syscall/libcall_${GOOS}.go"; then
 326   GO_LIBCALL_OS_FILE="go/syscall/libcall_${GOOS}.go"
 327 fi
 328 if test -f "${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go"; then
 329   GO_LIBCALL_OS_ARCH_FILE="go/syscall/libcall_${GOOS}_${GOARCH}.go"
 330 fi
 331 if test -f "${srcdir}/go/syscall/syscall_${GOOS}.go"; then
 332   GO_SYSCALL_OS_FILE="go/syscall/syscall_${GOOS}.go"
 333 fi
 334 if test -f "${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go"; then
 335   GO_SYSCALL_OS_ARCH_FILE="go/syscall/syscall_${GOOS}_${GOARCH}.go"
 336 fi
 337 AC_SUBST(GO_LIBCALL_OS_FILE)
 338 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 339 AC_SUBST(GO_SYSCALL_OS_FILE)
 340 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 341
 342 dnl Special flags used to generate sysinfo.go.
 343 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 344 case "$target" in
 345     mips-sgi-irix6.5*)
 346         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 347         # msghdr in <sys/socket.h>.
 348         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 349         ;;
 350     *-*-solaris2.1[[01]])
 351         # Solaris 10+ needs this so struct msghdr gets the msg_control
 352         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 353         # above doesn't work with C99.
 354         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 355         ;;
 356 esac
 357 AC_SUBST(OSCFLAGS)
 358
 359 dnl Use -fsplit-stack when compiling C code if available.
 360 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 361 [libgo_cv_c_split_stack_supported],
 362 [CFLAGS_hold=$CFLAGS
 363 CFLAGS="$CFLAGS -fsplit-stack"
 364 AC_COMPILE_IFELSE([[int i;]],
 365 [libgo_cv_c_split_stack_supported=yes],
 366 [libgo_cv_c_split_stack_supported=no])
 367 CFLAGS=$CFLAGS_hold])
 368 if test "$libgo_cv_c_split_stack_supported" = yes; then
 369   SPLIT_STACK=-fsplit-stack
 370   AC_DEFINE(USING_SPLIT_STACK, 1,
 371                 [Define if the compiler supports -fsplit-stack])
 372 else
 373   SPLIT_STACK=
 374 fi
 375 AC_SUBST(SPLIT_STACK)
 376 AM_CONDITIONAL(USING_SPLIT_STACK,
 377         test "$libgo_cv_c_split_stack_supported" = yes)
 378
 379 dnl Check whether the linker does stack munging when calling from
 380 dnl split-stack into non-split-stack code.  We check this by looking
 381 dnl at the --help output.  FIXME: This is only half right: it's
 382 dnl possible for the linker to support this for some targets but not
 383 dnl others.
 384 AC_CACHE_CHECK([whether linker supports split stack],
 385 [libgo_cv_c_linker_supports_split_stack],
 386 [libgo_cv_c_linker_supports_split_stack=no
 387 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 388   libgo_cv_c_linker_supports_split_stack=yes
 389 fi])
 390 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 391   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 392             [Define if the linker support split stack adjustments])
 393 fi
 394
 395 dnl Test for the -lm library.
 396 MATH_LIBS=
 397 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 398 AC_SUBST(MATH_LIBS)
 399
 400 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 401 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 402   [libgo_cv_lib_sockets=
 403    libgo_check_both=no
 404    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 405    if test "$libgo_check_socket" = "yes"; then
 406      unset ac_cv_func_connect
 407      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 408                   libgo_check_both=yes)
 409    fi
 410    if test "$libgo_check_both" = "yes"; then
 411      libgo_old_libs=$LIBS
 412      LIBS="$LIBS -lsocket -lnsl"
 413      unset ac_cv_func_accept
 414      AC_CHECK_FUNC(accept,
 415                    [libgo_check_nsl=no
 416                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 417      unset ac_cv_func_accept
 418      LIBS=$libgo_old_libs
 419    fi
 420    unset ac_cv_func_gethostbyname
 421    libgo_old_libs="$LIBS"
 422    AC_CHECK_FUNC(gethostbyname, ,
 423                  [AC_CHECK_LIB(nsl, main,
 424                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 425    unset ac_cv_func_gethostbyname
 426    LIBS=$libgo_old_libs
 427 ])
 428 NET_LIBS="$libgo_cv_lib_sockets"
 429 AC_SUBST(NET_LIBS)
 430
 431 dnl Test whether the compiler supports the -pthread option.
 432 AC_CACHE_CHECK([whether -pthread is supported],
 433 [libgo_cv_lib_pthread],
 434 [CFLAGS_hold=$CFLAGS
 435 CFLAGS="$CFLAGS -pthread"
 436 AC_COMPILE_IFELSE([[int i;]],
 437 [libgo_cv_lib_pthread=yes],
 438 [libgo_cv_lib_pthread=no])
 439 CFLAGS=$CFLAGS_hold])
 440 PTHREAD_CFLAGS=
 441 if test "$libgo_cv_lib_pthread" = yes; then
 442   PTHREAD_CFLAGS=-pthread
 443 fi
 444 AC_SUBST(PTHREAD_CFLAGS)
 445
 446 dnl Test for the -lpthread library.
 447 PTHREAD_LIBS=
 448 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 449 AC_SUBST(PTHREAD_LIBS)
 450
 451 dnl Test if -lrt is required for sched_yield and/or nanosleep.
 452 AC_SEARCH_LIBS([sched_yield], [rt])
 453 AC_SEARCH_LIBS([nanosleep], [rt])
 454
 455 AC_C_BIGENDIAN
 456
 457 GCC_CHECK_UNWIND_GETIPINFO
 458
 459 AC_ARG_ENABLE(sjlj-exceptions,
 460   AC_HELP_STRING([--enable-sjlj-exceptions],
 461                  [force use of builtin_setjmp for exceptions]),
 462   [case "$enableval" in
 463    yes|no|auto) ;;
 464    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 465    esac],
 466   [enable_sjlj_exceptions=auto])
 467
 468 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 469 [libgo_cv_lib_sjlj_exceptions],
 470 [AC_LANG_CONFTEST(
 471   [AC_LANG_SOURCE([
 472 void bar ();
 473 void clean (int *);
 474 void foo ()
 475 {
 476   int i __attribute__ ((cleanup (clean)));
 477   bar();
 478 }
 479 ])])
 480 CFLAGS_hold=$CFLAGS
 481 CFLAGS="--save-temps -fexceptions"
 482 libgo_cv_lib_sjlj_exceptions=unknown
 483 AS_IF([ac_fn_c_try_compile],
 484   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 485     libgo_cv_lib_sjlj_exceptions=yes
 486   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 487     libgo_cv_lib_sjlj_exceptions=no
 488   fi])
 489 CFLAGS=$CFLAGS_hold
 490 rm -f conftest*
 491 ])
 492
 493 if test "$enable_sjlj_exceptions" = "auto"; then
 494   enable_sjlj_exceptions=$libgo_cv_lib_sjlj_exceptions
 495 fi
 496
 497 case $enable_sjlj_exceptions in
 498 yes)
 499   AC_DEFINE(LIBGO_SJLJ_EXCEPTIONS, 1,
 500         [Define if the C++ compiler is configured for setjmp/longjmp exceptions.])
 501   ;;
 502 no)
 503   ;;
 504 *)
 505   AC_MSG_ERROR([unable to detect exception model])
 506   ;;
 507 esac
 508
 509 AC_CHECK_HEADERS(sched.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/reboot.h netinet/icmp6.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 510
 511 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 512 [#ifdef HAVE_SYS_SOCKET_H
 513 #include <sys/socket.h>
 514 #endif
 515 ])
 516
 517 AC_CACHE_CHECK([whether <ustat.h> can be used],
 518 [libgo_cv_c_ustat_h],
 519 [CFLAGS_hold=$CFLAGS
 520 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE $OSCFLAGS"
 521 AC_COMPILE_IFELSE(
 522 [AC_LANG_SOURCE([
 523 #include <sys/types.h>
 524 #ifdef HAVE_LINUX_FILTER_H
 525 #include <linux/filter.h>
 526 #endif
 527 #include <ustat.h>
 528 ])], [libgo_cv_c_ustat_h=yes], [libgo_cv_c_ustat_h=no])
 529 CFLAGS=$CFLAGS_hold])
 530 if test $libgo_cv_c_ustat_h = yes; then
 531   AC_DEFINE(HAVE_USTAT_H, 1,
 532     [Define to 1 if you have the <ustat.h> header file and it works.])
 533 fi
 534
 535 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 536
 537 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv dl_iterate_phdr)
 538 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 539 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 540
 541 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice tee unlinkat unshare utimensat)
 542 AC_TYPE_OFF_T
 543 AC_CHECK_TYPES([loff_t])
 544
 545 LIBS_hold="$LIBS"
 546 LIBS="$LIBS -lm"
 547 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 548 LIBS="$LIBS_hold"
 549
 550 CFLAGS_hold="$CFLAGS"
 551 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 552 LIBS_hold="$LIBS"
 553 LIBS="$LIBS $PTHREAD_LIBS"
 554 AC_CHECK_FUNCS(sem_timedwait)
 555 CFLAGS="$CFLAGS_hold"
 556 LIBS="$LIBS_hold"
 557
 558 LIBS_hold="$LIBS"
 559 LIBS="$LIBS $MATH_LIBS"
 560 AC_CHECK_FUNCS(matherr)
 561 LIBS="$LIBS_hold"
 562
 563 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 564 [libgo_cv_func___sync_bool_compare_and_swap_4],
 565 [AC_LINK_IFELSE([
 566 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 567 uint32 i;
 568 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 569 ],
 570 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 571 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 572 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 573   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 574     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 575 fi
 576
 577 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_8],
 578 [libgo_cv_func___sync_bool_compare_and_swap_8],
 579 [AC_LINK_IFELSE([
 580 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 581 uint64 i;
 582 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 583 ],
 584 [libgo_cv_func___sync_bool_compare_and_swap_8=yes],
 585 [libgo_cv_func___sync_bool_compare_and_swap_8=no])])
 586 if test "$libgo_cv_func___sync_bool_compare_and_swap_8" = "yes"; then
 587   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_8, 1,
 588     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint64])
 589 fi
 590
 591 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 592 [libgo_cv_func___sync_fetch_and_add_4],
 593 [AC_LINK_IFELSE([
 594 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 595 uint32 i;
 596 int main() { return __sync_fetch_and_add (&i, 1); }
 597 ],
 598 [libgo_cv_func___sync_fetch_and_add_4=yes],
 599 [libgo_cv_func___sync_fetch_and_add_4=no])])
 600 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 601   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 602     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 603 fi
 604
 605 AC_CACHE_CHECK([for __sync_add_and_fetch_8],
 606 [libgo_cv_func___sync_add_and_fetch_8],
 607 [AC_LINK_IFELSE([
 608 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 609 uint64 i;
 610 int main() { return __sync_add_and_fetch (&i, 1); }
 611 ],
 612 [libgo_cv_func___sync_add_and_fetch_8=yes],
 613 [libgo_cv_func___sync_add_and_fetch_8=no])])
 614 if test "$libgo_cv_func___sync_add_and_fetch_8" = "yes"; then
 615   AC_DEFINE(HAVE_SYNC_ADD_AND_FETCH_8, 1,
 616     [Define to 1 if the compiler provides the __sync_add_and_fetch function for uint64])
 617 fi
 618
 619 dnl For x86 we want to use the -minline-all-stringops option to avoid
 620 dnl forcing a stack split when calling memcpy and friends.
 621 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 622 [libgo_cv_c_stringops],
 623 [CFLAGS_hold=$CFLAGS
 624 CFLAGS="$CFLAGS -minline-all-stringops"
 625 AC_COMPILE_IFELSE([int i;],
 626 [libgo_cv_c_stringops=yes],
 627 [libgo_cv_c_stringops=no])
 628 CFLAGS=$CFLAGS_hold])
 629 STRINGOPS_FLAG=
 630 if test "$libgo_cv_c_stringops" = yes; then
 631   STRINGOPS_FLAG=-minline-all-stringops
 632 fi
 633 AC_SUBST(STRINGOPS_FLAG)
 634
 635 dnl For x86 we want to compile the math library with -mfancy-math-387
 636 dnl -funsafe-math-optimizations so that we can use the builtin
 637 dnl instructions directly.
 638 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 639 [libgo_cv_c_fancymath],
 640 [CFLAGS_hold=$CFLAGS
 641 CFLAGS="$CFLAGS -mfancy-math-387"
 642 AC_COMPILE_IFELSE([int i;],
 643 [libgo_cv_c_fancymath=yes],
 644 [libgo_cv_c_fancymath=no])
 645 CFLAGS=$CFLAGS_hold])
 646 MATH_FLAG=
 647 if test "$libgo_cv_c_fancymath" = yes; then
 648   MATH_FLAG="-mfancy-math-387 -funsafe-math-optimizations"
 649 else
 650   MATH_FLAG="-ffp-contract=off"
 651 fi
 652 AC_SUBST(MATH_FLAG)
 653
 654 CFLAGS_hold=$CFLAGS
 655 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 656 AC_CHECK_TYPES([off64_t])
 657 CFLAGS=$CFLAGS_hold
 658
 659 dnl Work out the size of the epoll_events struct on GNU/Linux.
 660 AC_CACHE_CHECK([epoll_event size],
 661 [libgo_cv_c_epoll_event_size],
 662 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 663 [sizeof (struct epoll_event)],
 664 [#include <sys/epoll.h>],
 665 [libgo_cv_c_epoll_event_size=0])])
 666 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 667 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 668
 669 dnl Work out the offset of the fd field in the epoll_events struct on
 670 dnl GNU/Linux.
 671 AC_CACHE_CHECK([epoll_event data.fd offset],
 672 [libgo_cv_c_epoll_event_fd_offset],
 673 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 674 [offsetof (struct epoll_event, data.fd)],
 675 [#include <stddef.h>
 676 #include <sys/epoll.h>],
 677 [libgo_cv_c_epoll_event_fd_offset=0])])
 678 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 679 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 680
 681 dnl See if struct exception is defined in <math.h>.
 682 AC_CHECK_TYPE([struct exception],
 683 [libgo_has_struct_exception=yes],
 684 [libgo_has_struct_exception=no],
 685 [#include <math.h>])
 686 if test "$libgo_has_struct_exception" = "yes"; then
 687   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 688             [Define to 1 if <math.h> defines struct exception])
 689 fi
 690
 691 dnl See whether setcontext changes the value of TLS variables.
 692 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 693 [libgo_cv_lib_setcontext_clobbers_tls],
 694 [CFLAGS_hold="$CFLAGS"
 695 CFLAGS="$PTHREAD_CFLAGS"
 696 LIBS_hold="$LIBS"
 697 LIBS="$LIBS $PTHREAD_LIBS"
 698 AC_CHECK_SIZEOF([void *])
 699 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 700 AC_RUN_IFELSE(
 701   [AC_LANG_SOURCE([
 702 #include <pthread.h>
 703 #include <stdlib.h>
 704 #include <ucontext.h>
 705 #include <unistd.h>
 706
 707 __thread int tls;
 708
 709 static char stack[[10 * 1024 * 1024]];
 710 static ucontext_t c;
 711
 712 /* Called via makecontext/setcontext.  */
 713
 714 static void
 715 cfn (void)
 716 {
 717   exit (tls);
 718 }
 719
 720 /* Called via pthread_create.  */
 721
 722 static void *
 723 tfn (void *dummy)
 724 {
 725   /* The thread should still see this value after calling
 726      setcontext.  */
 727   tls = 0;
 728
 729   setcontext (&c);
 730
 731   /* The call to setcontext should not return.  */
 732   abort ();
 733 }
 734
 735 int
 736 main ()
 737 {
 738   pthread_t tid;
 739
 740   /* The thread should not see this value.  */
 741   tls = 1;
 742
 743   if (getcontext (&c) < 0)
 744     abort ();
 745
 746   c.uc_stack.ss_sp = stack;
 747 #ifdef MAKECONTEXT_STACK_TOP
 748   c.uc_stack.ss_sp += sizeof stack;
 749 #endif
 750   c.uc_stack.ss_flags = 0;
 751   c.uc_stack.ss_size = sizeof stack;
 752   c.uc_link = NULL;
 753   makecontext (&c, cfn, 0);
 754
 755   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 756     abort ();
 757
 758   if (pthread_join (tid, NULL) != 0)
 759     abort ();
 760
 761   /* The thread should have called exit.  */
 762   abort ();
 763 }
 764 ])],
 765 [libgo_cv_lib_setcontext_clobbers_tls=no],
 766 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 767 [case "$target:$ptr_type_size" in
 768   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 769     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 770   *)
 771     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 772  esac
 773 ])
 774 CFLAGS="$CFLAGS_hold"
 775 LIBS="$LIBS_hold"
 776 ])
 777 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 778   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 779             [Define if setcontext clobbers TLS variables])
 780 fi
 781
 782 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 783 libgo_cv_ro_eh_frame, [
 784 libgo_cv_ro_eh_frame=no
 785 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 786 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 787   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 788     libgo_cv_ro_eh_frame=yes
 789   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 790        | grep -v '#write' > /dev/null; then
 791     libgo_cv_ro_eh_frame=yes
 792   fi
 793 fi
 794 rm -f conftest.*
 795 ])
 796 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 797   AC_DEFINE(EH_FRAME_FLAGS, "a",
 798             [Define to the flags needed for the .section .eh_frame directive.])
 799 else
 800   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 801             [Define to the flags needed for the .section .eh_frame directive.])
 802 fi
 803
 804 AC_CACHE_CHECK([if compiler supports -Qunused-arguments],
 805 [libgo_cv_c_unused_arguments],
 806 [CFLAGS_hold=$CFLAGS
 807 CFLAGS="$CFLAGS -Qunused-arguments"
 808 AC_COMPILE_IFELSE([[int i;]],
 809 [libgo_cv_c_unused_arguments=yes],
 810 [libgo_cv_c_unused_arguments=no])
 811 CFLAGS=$CFLAGS_hold])
 812
 813 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 814 libgo_cv_as_comdat_gnu, [
 815 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 816 CFLAGS_hold=$CFLAGS
 817 if test "$libgo_cv_c_unused_arguments" = yes; then
 818   CFLAGS="$CFLAGS -Qunused-arguments"
 819 fi
 820 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 821   libgo_cv_as_comdat_gnu=yes
 822 else
 823   libgo_cv_as_comdat_gnu=no
 824 fi
 825 CFLAGS=$CFLAGS_hold
 826 ])
 827 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 828   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 829             [Define if your assembler supports GNU comdat group syntax.])
 830 fi
 831
 832 AC_CACHE_CHECK([assembler supports pc related relocs],
 833 libgo_cv_as_x86_pcrel, [
 834 libgo_cv_as_x86_pcrel=yes
 835 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 836 CFLAGS_hold=$CFLAGS
 837 if test "$libgo_cv_c_unused_arguments" = yes; then
 838   CFLAGS="$CFLAGS -Qunused-arguments"
 839 fi
 840 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 841     libgo_cv_as_x86_pcrel=no
 842 fi
 843 CFLAGS=$CFLAGS_hold
 844 ])
 845 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 846   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 847             [Define if your assembler supports PC relative relocs.])
 848 fi
 849
 850 AC_CACHE_CHECK([assembler supports unwind section type],
 851 libgo_cv_as_x86_64_unwind_section_type, [
 852 libgo_cv_as_x86_64_unwind_section_type=yes
 853 echo '.section .eh_frame,"a",@unwind' > conftest.s
 854 CFLAGS_hold=$CFLAGS
 855 if test "$libgo_cv_c_unused_arguments" = yes; then
 856   CFLAGS="$CFLAGS -Qunused-arguments"
 857 fi
 858 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 859     libgo_cv_as_x86_64_unwind_section_type=no
 860 fi
 861 CFLAGS=$CFLAGS_hold
 862 ])
 863 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 864   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 865             [Define if your assembler supports unwind section type.])
 866 fi
 867
 868 AC_CACHE_SAVE
 869
 870 if test ${multilib} = yes; then
 871   multilib_arg="--enable-multilib"
 872 else
 873   multilib_arg=
 874 fi
 875
 876 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 877
 878 AC_CONFIG_COMMANDS([default],
 879 [if test -n "$CONFIG_FILES"; then
 880    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 881    # that multilib installs will end up installed in the correct place.
 882    # The testsuite needs it for multilib-aware ABI baseline files.
 883    # To work around this not being passed down from config-ml.in ->
 884    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 885    # append it here.  Only modify Makefiles that have just been created.
 886    #
 887    # Also, get rid of this simulated-VPATH thing that automake does.
 888    cat > vpsed << \_EOF
 889 s!`test -f '$<' || echo '$(srcdir)/'`!!
 890 _EOF
 891    for i in $SUBDIRS; do
 892     case $CONFIG_FILES in
 893      *${i}/Makefile*)
 894        #echo "Adding MULTISUBDIR to $i/Makefile"
 895        sed -f vpsed $i/Makefile > tmp
 896        grep '^MULTISUBDIR =' Makefile >> tmp
 897        mv tmp $i/Makefile
 898        ;;
 899     esac
 900    done
 901    rm vpsed
 902  fi
 903 ],
 904 [
 905 # Variables needed in config.status (file generation) which aren't already
 906 # passed by autoconf.
 907 SUBDIRS="$SUBDIRS"
 908 ])
 909
 910 AC_OUTPUT