gcc/ada/sinput.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               S I N P U T                                --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2006, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This package contains the input routines used for reading the
  35 --  input source file. The actual I/O routines are in OS_Interface,
  36 --  with this module containing only the system independent processing.
  37
  38 --  General Note: throughout the compiler, we use the term line or source
  39 --  line to refer to a physical line in the source, terminated by the end of
  40 --  physical line sequence.
  41
  42 --  There are two distinct concepts of line terminator in GNAT
  43
  44 --    A logical line terminator is what corresponds to the "end of a line" as
  45 --    described in RM 2.2 (13). Any of the characters FF, LF, CR or VT or any
  46 --    wide character that is a Line or Paragraph Separator acts as an end of
  47 --    logical line in this sense, and it is essentially irrelevant whether one
  48 --    or more appears in sequence (since if sequence of such characters is
  49 --    regarded as separate ends of line, then the intervening logical lines
  50 --    are null in any case).
  51
  52 --    A physical line terminator is a sequence of format effectors that is
  53 --    treated as ending a physical line. Physical lines have no Ada semantic
  54 --    significance, but they are significant for error reporting purposes,
  55 --    since errors are identified by line and column location.
  56
  57 --  In GNAT, a physical line is ended by any of the sequences LF, CR/LF, CR or
  58 --  LF/CR. LF is used in typical Unix systems, CR/LF in DOS systems, and CR
  59 --  alone in System 7. We don't know of any system using LF/CR, but it seems
  60 --  reasonable to include this case for consistency. In addition, we recognize
  61 --  any of these sequences in any of the operating systems, for better
  62 --  behavior in treating foreign files (e.g. a Unix file with LF terminators
  63 --  transferred to a DOS system). Finally, wide character codes in cagtegories
  64 --  Separator, Line and Separator, Paragraph are considered to be physical
  65 --  line terminators.
  66
  67 with Alloc;
  68 with Casing; use Casing;
  69 with Table;
  70 with Types;  use Types;
  71
  72 package Sinput is
  73
  74    type Type_Of_File is (
  75    --  Indicates type of file being read
  76
  77       Src,
  78       --  Normal Ada source file
  79
  80       Config,
  81       --  Configuration pragma file
  82
  83       Def,
  84       --  Preprocessing definition file
  85
  86       Preproc);
  87       --  Source file with preprocessing commands to be preprocessed
  88
  89    ----------------------------
  90    -- Source License Control --
  91    ----------------------------
  92
  93    --  The following type indicates the license state of a source if it
  94    --  is known.
  95
  96    type License_Type is
  97      (Unknown,
  98       --  Licensing status of this source unit is unknown
  99
 100       Restricted,
 101       --  This is a non-GPL'ed unit that is restricted from depending
 102       --  on GPL'ed units (e.g. proprietary code is in this category)
 103
 104       GPL,
 105       --  This file is licensed under the unmodified GPL. It is not allowed
 106       --  to depend on Non_GPL units, and Non_GPL units may not depend on
 107       --  this source unit.
 108
 109       Modified_GPL,
 110       --  This file is licensed under the GNAT modified GPL (see header of
 111       --  This file for wording of the modification). It may depend on other
 112       --  Modified_GPL units or on unrestricted units.
 113
 114       Unrestricted);
 115       --  The license on this file is permitted to depend on any other
 116       --  units, or have other units depend on it, without violating the
 117       --  license of this unit. Examples are public domain units, and
 118       --  units defined in the RM).
 119
 120    --  The above license status is checked when the appropriate check is
 121    --  activated and one source depends on another, and the licensing state
 122    --  of both files is known:
 123
 124    --  The prohibited combinations are:
 125
 126    --    Restricted file may not depend on GPL file
 127
 128    --    GPL file may not depend on Restricted file
 129
 130    --    Modified GPL file may not depend on Restricted file
 131    --    Modified_GPL file may not depend on GPL file
 132
 133    --  The reason for the last restriction here is that a client depending
 134    --  on a modified GPL file must be sure that the license condition is
 135    --  correct considered transitively.
 136
 137    --  The licensing status is determined either by the presence of a
 138    --  specific pragma License, or by scanning the header for a predefined
 139    --  file, or any file if compiling in -gnatg mode.
 140
 141    -----------------------
 142    -- Source File Table --
 143    -----------------------
 144
 145    --  The source file table has an entry for each source file read in for
 146    --  this run of the compiler. This table is (default) initialized when
 147    --  the compiler is loaded, and simply accumulates entries as compilation
 148    --  proceeds and various routines in Sinput and its child packages are
 149    --  called to load required source files.
 150
 151    --  Virtual entries are also created for generic templates when they are
 152    --  instantiated, as described in a separate section later on.
 153
 154    --  In the case where there are multiple main units (e.g. in the case of
 155    --  the cross-reference tool), this table is not reset between these units,
 156    --  so that a given source file is only read once if it is used by two
 157    --  separate main units.
 158
 159    --  The entries in the table are accessed using a Source_File_Index that
 160    --  ranges from 1 to Last_Source_File. Each entry has the following fields
 161
 162    --  Note: fields marked read-only are set by Sinput or one of its child
 163    --  packages when a source file table entry is created, and cannot be
 164    --  subsqently modified, or alternatively are set only by very special
 165    --  circumstances, documented in the comments.
 166
 167    --  File_Name : File_Name_Type (read-only)
 168    --    Name of the source file (simple name with no directory information)
 169
 170    --  Full_File_Name : File_Name_Type (read-only)
 171    --    Full file name (full name with directory info), used for generation
 172    --    of error messages, etc.
 173
 174    --  File_Type : Type_Of_File (read-only)
 175    --    Indicates type of file (source file, configuration pragmas file,
 176    --    preprocessor definition file, preprocessor input file).
 177
 178    --  Reference_Name : File_Name_Type (read-only)
 179    --    Name to be used for source file references in error messages where
 180    --    only the simple name of the file is required. Identical to File_Name
 181    --    unless pragma Source_Reference is used to change it. Only processing
 182    --    for the Source_Reference pragma circuit may set this field.
 183
 184    --  Full_Ref_Name : File_Name_Type (read-only)
 185    --    Name to be used for source file references in error messages where
 186    --    the full name of the file is required. Identical to Full_File_Name
 187    --    unless pragma Source_Reference is used to change it. Only processing
 188    --    for the Source_Reference pragma may set this field.
 189
 190    --  Debug_Source_Name : File_Name_Type (read-only)
 191    --    Name to be used for source file references in debugging information
 192    --    where only the simple name of the file is required. Identical to
 193    --    Reference_Name unless the -gnatD (debug source file) switch is used.
 194    --    Only processing in Sprint that generates this file is permitted to
 195    --    set this field.
 196
 197    --  Full_Debug_Name : File_Name_Type (read-only)
 198    --    Name to be used for source file references in debugging information
 199    --    where the full name of the file is required. This is identical to
 200    --    Full_Ref_Name unless the -gnatD (debug source file) switch is used.
 201    --    Only processing in Sprint that generates this file is permitted to
 202    --    set this field.
 203
 204    --  License : License_Type;
 205    --    License status of source file
 206
 207    --  Num_SRef_Pragmas : Nat;
 208    --    Number of source reference pragmas present in source file
 209
 210    --  First_Mapped_Line : Logical_Line_Number;
 211    --    This field stores logical line number of the first line in the
 212    --    file that is not a Source_Reference pragma. If no source reference
 213    --    pragmas are used, then the value is set to No_Line_Number.
 214
 215    --  Source_Text : Source_Buffer_Ptr (read-only)
 216    --    Text of source file. Note that every source file has a distinct set
 217    --    of non-overlapping logical bounds, so it is possible to determine
 218    --    which file is referenced from a given subscript (Source_Ptr) value.
 219
 220    --  Source_First : Source_Ptr; (read-only)
 221    --    Subscript of first character in Source_Text. Note that this cannot
 222    --    be obtained as Source_Text'First, because we use virtual origin
 223    --    addressing.
 224
 225    --  Source_Last : Source_Ptr; (read-only)
 226    --    Subscript of last character in Source_Text. Note that this cannot
 227    --    be obtained as Source_Text'Last, because we use virtual origin
 228    --    addressing, so this value is always Source_Ptr'Last.
 229
 230    --  Time_Stamp : Time_Stamp_Type; (read-only)
 231    --    Time stamp of the source file
 232
 233    --  Source_Checksum : Word;
 234    --    Computed checksum for contents of source file. See separate section
 235    --    later on in this spec for a description of the checksum algorithm.
 236
 237    --  Last_Source_Line : Physical_Line_Number;
 238    --    Physical line number of last source line. Whlie a file is being
 239    --    read, this refers to the last line scanned. Once a file has been
 240    --    completely scanned, it is the number of the last line in the file,
 241    --    and hence also gives the number of source lines in the file.
 242
 243    --  Keyword_Casing : Casing_Type;
 244    --    Casing style used in file for keyword casing. This is initialized
 245    --    to Unknown, and then set from the first occurrence of a keyword.
 246    --    This value is used only for formatting of error messages.
 247
 248    --  Identifier_Casing : Casing_Type;
 249    --    Casing style used in file for identifier casing. This is initialized
 250    --    to Unknown, and then set from an identifier in the program as soon as
 251    --    one is found whose casing is sufficiently clear to make a decision.
 252    --    This value is used for formatting of error messages, and also is used
 253    --    in the detection of keywords misused as identifiers.
 254
 255    --  Instantiation : Source_Ptr;
 256    --    Source file location of the instantiation if this source file entry
 257    --    represents a generic instantiation. Set to No_Location for the case
 258    --    of a normal non-instantiation entry. See section below for details.
 259    --    This field is read-only for clients.
 260
 261    --  Inlined_Body : Boolean;
 262    --    This can only be set True if Instantiation has a value other than
 263    --    No_Location. If true it indicates that the instantiation is actually
 264    --    an instance of an inlined body.
 265
 266    --  Template : Source_File_Index; (read-only)
 267    --    Source file index of the source file containing the template if this
 268    --    is a generic instantiation. Set to No_Source_File for the normal case
 269    --    of a non-instantiation entry. See Sinput-L for details.
 270
 271    --  Unit : Unit_Number_Type;
 272    --    Identifies the unit contained in this source file. Set by
 273    --    Initialize_Scanner, must not be subsequently altered.
 274
 275    --  The source file table is accessed by clients using the following
 276    --  subprogram interface:
 277
 278    subtype SFI is Source_File_Index;
 279
 280    System_Source_File_Index : SFI;
 281    --  The file system.ads is always read by the compiler to determine the
 282    --  settings of the target parameters in the private part of System. This
 283    --  variable records the source file index of system.ads. Typically this
 284    --  will be 1 since system.ads is read first.
 285
 286    function Debug_Source_Name (S : SFI) return File_Name_Type;
 287    function File_Name         (S : SFI) return File_Name_Type;
 288    function File_Type         (S : SFI) return Type_Of_File;
 289    function First_Mapped_Line (S : SFI) return Logical_Line_Number;
 290    function Full_Debug_Name   (S : SFI) return File_Name_Type;
 291    function Full_File_Name    (S : SFI) return File_Name_Type;
 292    function Full_Ref_Name     (S : SFI) return File_Name_Type;
 293    function Identifier_Casing (S : SFI) return Casing_Type;
 294    function Inlined_Body      (S : SFI) return Boolean;
 295    function Instantiation     (S : SFI) return Source_Ptr;
 296    function Keyword_Casing    (S : SFI) return Casing_Type;
 297    function Last_Source_Line  (S : SFI) return Physical_Line_Number;
 298    function License           (S : SFI) return License_Type;
 299    function Num_SRef_Pragmas  (S : SFI) return Nat;
 300    function Reference_Name    (S : SFI) return File_Name_Type;
 301    function Source_Checksum   (S : SFI) return Word;
 302    function Source_First      (S : SFI) return Source_Ptr;
 303    function Source_Last       (S : SFI) return Source_Ptr;
 304    function Source_Text       (S : SFI) return Source_Buffer_Ptr;
 305    function Template          (S : SFI) return Source_File_Index;
 306    function Unit              (S : SFI) return Unit_Number_Type;
 307    function Time_Stamp        (S : SFI) return Time_Stamp_Type;
 308
 309    procedure Set_Keyword_Casing    (S : SFI; C : Casing_Type);
 310    procedure Set_Identifier_Casing (S : SFI; C : Casing_Type);
 311    procedure Set_License           (S : SFI; L : License_Type);
 312    procedure Set_Unit              (S : SFI; U : Unit_Number_Type);
 313
 314    function Last_Source_File return Source_File_Index;
 315    --  Index of last source file table entry
 316
 317    function Num_Source_Files return Nat;
 318    --  Number of source file table entries
 319
 320    procedure Initialize;
 321    --  Initialize internal tables
 322
 323    procedure Lock;
 324    --  Lock internal tables
 325
 326    Main_Source_File : Source_File_Index := No_Source_File;
 327    --  This is set to the source file index of the main unit
 328
 329    -----------------------------
 330    -- Source_File_Index_Table --
 331    -----------------------------
 332
 333    --  The Get_Source_File_Index function is called very frequently. Earlier
 334    --  versions cached a single entry, but then reverted to a serial search,
 335    --  and this proved to be a significant source of inefficiency. To get
 336    --  around this, we use the following directly indexed array. The space
 337    --  of possible input values is a value of type Source_Ptr which is simply
 338    --  an Int value. The values in this space are allocated sequentially as
 339    --  new units are loaded.
 340
 341    --  The following table has an entry for each 4K range of possible
 342    --  Source_Ptr values. The value in the table is the lowest value
 343    --  Source_File_Index whose Source_Ptr range contains value in the
 344    --  range.
 345
 346    --  For example, the entry with index 4 in this table represents Source_Ptr
 347    --  values in the range 4*4096 .. 5*4096-1. The Source_File_Index value
 348    --  stored would be the lowest numbered source file with at least one byte
 349    --  in this range.
 350
 351    --  The algorithm used in Get_Source_File_Index is simply to access this
 352    --  table and then do a serial search starting at the given position. This
 353    --  will almost always terminate with one or two checks.
 354
 355    --  Note that this array is pretty large, but in most operating systems
 356    --  it will not be allocated in physical memory unless it is actually used.
 357
 358    Chunk_Power : constant := 12;
 359    Chunk_Size  : constant := 2 ** Chunk_Power;
 360    --  Change comments above if value changed. Note that Chunk_Size must
 361    --  be a power of 2 (to allow for efficient access to the table).
 362
 363    Source_File_Index_Table :
 364      array (Int range 0 .. Int'Last / Chunk_Size) of Source_File_Index;
 365
 366    procedure Set_Source_File_Index_Table (Xnew : Source_File_Index);
 367    --  Sets entries in the Source_File_Index_Table for the newly created
 368    --  Source_File table entry whose index is Xnew. The Source_First and
 369    --  Source_Last fields of this entry must be set before the call.
 370
 371    -----------------------
 372    -- Checksum Handling --
 373    -----------------------
 374
 375    --  As a source file is scanned, a checksum is computed by taking all the
 376    --  non-blank characters in the file, excluding comment characters, the
 377    --  minus-minus sequence starting a comment, and all control characters
 378    --  except ESC.
 379
 380    --  The checksum algorithm used is the standard CRC-32 algorithm, as
 381    --  implemented by System.CRC32, except that we do not bother with the
 382    --  final XOR with all 1 bits.
 383
 384    --  This algorithm ensures that the checksum includes all semantically
 385    --  significant aspects of the program represented by the source file,
 386    --  but is insensitive to layout, presence or contents of comments, wide
 387    --  character representation method, or casing conventions outside strings.
 388
 389    --  Scans.Checksum is initialized appropriately at the start of scanning
 390    --  a file, and copied into the Source_Checksum field of the file table
 391    --  entry when the end of file is encountered.
 392
 393    -------------------------------------
 394    -- Handling Generic Instantiations --
 395    -------------------------------------
 396
 397    --  As described in Sem_Ch12, a generic instantiation involves making a
 398    --  copy of the tree of the generic template. The source locations in
 399    --  this tree directly reference the source of the template. However it
 400    --  is also possible to find the location of the instantiation.
 401
 402    --  This is achieved as follows. When an instantiation occurs, a new entry
 403    --  is made in the source file table. This entry points to the same source
 404    --  text, i.e. the file that contains the instantiation, but has a distinct
 405    --  set of Source_Ptr index values. The separate range of Sloc values avoids
 406    --  confusion, and means that the Sloc values can still be used to uniquely
 407    --  identify the source file table entry. It is possible for both entries
 408    --  to point to the same text, because of the virtual origin pointers used
 409    --  in the source table.
 410
 411    --  The Instantiation field of this source file index entry, usually set
 412    --  to No_Source_File, instead contains the Sloc of the instantiation. In
 413    --  the case of nested instantiations, this Sloc may itself refer to an
 414    --  instantiation, so the complete chain can be traced.
 415
 416    --  Two routines are used to build these special entries in the source
 417    --  file table. Create_Instantiation_Source is first called to build
 418    --  the virtual source table entry for the instantiation, and then the
 419    --  Sloc values in the copy are adjusted using Adjust_Instantiation_Sloc.
 420    --  See child unit Sinput.L for details on these two routines.
 421
 422    -----------------
 423    -- Global Data --
 424    -----------------
 425
 426    Current_Source_File : Source_File_Index;
 427    --  Source_File table index of source file currently being scanned
 428
 429    Current_Source_Unit : Unit_Number_Type;
 430    --  Unit number of source file currently being scanned. The special value
 431    --  of No_Unit indicates that the configuration pragma file is currently
 432    --  being scanned (this has no entry in the unit table).
 433
 434    Source_gnat_adc : Source_File_Index := No_Source_File;
 435    --  This is set if a gnat.adc file is present to reference this file
 436
 437    Source : Source_Buffer_Ptr;
 438    --  Current source (copy of Source_File.Table (Current_Source_Unit).Source)
 439
 440    Internal_Source : aliased Source_Buffer (1 .. 81);
 441    --  This buffer is used internally in the compiler when the lexical analyzer
 442    --  is used to scan a string from within the compiler. The procedure is to
 443    --  establish Internal_Source_Ptr as the value of Source, set the string to
 444    --  be scanned, appropriately terminated, in this buffer, and set Scan_Ptr
 445    --  to point to the start of the buffer. It is a fatal error if the scanner
 446    --  signals an error while scanning a token in this internal buffer.
 447
 448    Internal_Source_Ptr : constant Source_Buffer_Ptr :=
 449                            Internal_Source'Unrestricted_Access;
 450    --  Pointer to internal source buffer
 451
 452    -----------------
 453    -- Subprograms --
 454    -----------------
 455
 456    procedure Backup_Line (P : in out Source_Ptr);
 457    --  Back up the argument pointer to the start of the previous line. On
 458    --  entry, P points to the start of a physical line in the source buffer.
 459    --  On return, P is updated to point to the start of the previous line.
 460    --  The caller has checked that a Line_Terminator character precedes P so
 461    --  that there definitely is a previous line in the source buffer.
 462
 463    procedure Build_Location_String (Loc : Source_Ptr);
 464    --  This function builds a string literal of the form "name:line",
 465    --  where name is the file name corresponding to Loc, and line is
 466    --  the line number. In the event that instantiations are involved,
 467    --  additional suffixes of the same form are appended after the
 468    --  separating string " instantiated at ". The returned string is
 469    --  stored in Name_Buffer, terminated by ASCII.Nul, with Name_Length
 470    --  indicating the length not including the terminating Nul.
 471
 472    function Get_Column_Number (P : Source_Ptr) return Column_Number;
 473    --  The ones-origin column number of the specified Source_Ptr value is
 474    --  determined and returned. Tab characters if present are assumed to
 475    --  represent the standard 1,9,17.. spacing pattern.
 476
 477    function Get_Logical_Line_Number
 478      (P : Source_Ptr) return Logical_Line_Number;
 479    --  The line number of the specified source position is obtained by
 480    --  doing a binary search on the source positions in the lines table
 481    --  for the unit containing the given source position. The returned
 482    --  value is the logical line number, already adjusted for the effect
 483    --  of source reference pragmas. If P refers to the line of a source
 484    --  reference pragma itself, then No_Line is returned. If no source
 485    --  reference pragmas have been encountered, the value returned is
 486    --  the same as the physical line number.
 487
 488    function Get_Physical_Line_Number
 489      (P : Source_Ptr) return Physical_Line_Number;
 490    --  The line number of the specified source position is obtained by
 491    --  doing a binary search on the source positions in the lines table
 492    --  for the unit containing the given source position. The returned
 493    --  value is the physical line number in the source being compiled.
 494
 495    function Get_Source_File_Index (S : Source_Ptr) return Source_File_Index;
 496    --  Return file table index of file identified by given source pointer
 497    --  value. This call must always succeed, since any valid source pointer
 498    --  value belongs to some previously loaded source file.
 499
 500    function Instantiation_Depth (S : Source_Ptr) return Nat;
 501    --  Determine instantiation depth for given Sloc value. A value of
 502    --  zero means that the given Sloc is not in an instantiation.
 503
 504    function Line_Start (P : Source_Ptr) return Source_Ptr;
 505    --  Finds the source position of the start of the line containing the
 506    --  given source location.
 507
 508    function Line_Start
 509      (L : Physical_Line_Number;
 510       S : Source_File_Index) return Source_Ptr;
 511    --  Finds the source position of the start of the given line in the
 512    --  given source file, using a physical line number to identify the line.
 513
 514    function Num_Source_Lines (S : Source_File_Index) return Nat;
 515    --  Returns the number of source lines (this is equivalent to reading
 516    --  the value of Last_Source_Line, but returns Nat rathern than a
 517    --  physical line number.
 518
 519    procedure Register_Source_Ref_Pragma
 520      (File_Name          : Name_Id;
 521       Stripped_File_Name : Name_Id;
 522       Mapped_Line        : Nat;
 523       Line_After_Pragma  : Physical_Line_Number);
 524    --  Register a source reference pragma, the parameter File_Name is the
 525    --  file name from the pragma, and Stripped_File_Name is this name with
 526    --  the directory information stripped. Both these parameters are set
 527    --  to No_Name if no file name parameter was given in the pragma.
 528    --  (which can only happen for the second and subsequent pragmas).
 529    --  Mapped_Line is the line number parameter from the pragma, and
 530    --  Line_After_Pragma is the physical line number of the line that
 531    --  follows the line containing the Source_Reference pragma.
 532
 533    function Original_Location (S : Source_Ptr) return Source_Ptr;
 534    --  Given a source pointer S, returns the corresponding source pointer
 535    --  value ignoring instantiation copies. For locations that do not
 536    --  correspond to instantiation copies of templates, the argument is
 537    --  returned unchanged. For locations that do correspond to copies of
 538    --  templates from instantiations, the location within the original
 539    --  template is returned. This is useful in canonicalizing locations.
 540
 541    function Instantiation_Location (S : Source_Ptr) return Source_Ptr;
 542    pragma Inline (Instantiation_Location);
 543    --  Given a source pointer S, returns the corresponding source pointer
 544    --  value of the instantiation if this location is within an instance.
 545    --  If S is not within an instance, then this returns No_Location.
 546
 547    function Top_Level_Location (S : Source_Ptr) return Source_Ptr;
 548    --  Given a source pointer S, returns the argument unchanged if it is
 549    --  not in an instantiation. If S is in an instantiation, then it returns
 550    --  the location of the top level instantiation, i.e. the outer level
 551    --  instantiation in the nested case.
 552
 553    function Physical_To_Logical
 554      (Line : Physical_Line_Number;
 555       S    : Source_File_Index) return Logical_Line_Number;
 556    --  Given a physical line number in source file whose source index is S,
 557    --  return the corresponding logical line number. If the physical line
 558    --  number is one containing a Source_Reference pragma, the result will
 559    --  be No_Line_Number.
 560
 561    procedure Skip_Line_Terminators
 562      (P        : in out Source_Ptr;
 563       Physical : out Boolean);
 564    --  On entry, P points to a line terminator that has been encountered,
 565    --  which is one of FF,LF,VT,CR or a wide character sequence whose value is
 566    --  in category Separator,Line or Separator,Paragraph. The purpose of this
 567    --  P points just past the character that was scanned. The purpose of this
 568    --  routine is to distinguish physical and logical line endings. A physical
 569    --  line ending is one of:
 570    --
 571    --     CR on its own (MAC System 7)
 572    --     LF on its own (Unix and unix-like systems)
 573    --     CR/LF (DOS, Windows)
 574    --     LF/CR (not used, but recognized in any case)
 575    --     Wide character in Separator,Line or Separator,Paragraph category
 576    --
 577    --  A logical line ending (that is not a physical line ending) is one of:
 578    --
 579    --     VT on its own
 580    --     FF on its own
 581    --
 582    --  On return, P is bumped past the line ending sequence (one of the above
 583    --  seven possibilities). Physical is set to True to indicate that a
 584    --  physical end of line was encountered, in which case this routine also
 585    --  makes sure that the lines table for the current source file has an
 586    --  appropriate entry for the start of the new physical line.
 587
 588    function Source_Offset (S : Source_Ptr) return Nat;
 589    --  Returns the zero-origin offset of the given source location from the
 590    --  start of its corresponding unit. This is used for creating canonical
 591    --  names in some situations.
 592
 593    procedure Write_Location (P : Source_Ptr);
 594    --  Writes out a string of the form fff:nn:cc, where fff, nn, cc are the
 595    --  file name, line number and column corresponding to the given source
 596    --  location. No_Location and Standard_Location appear as the strings
 597    --  <no location> and <standard location>. If the location is within an
 598    --  instantiation, then the instance location is appended, enclosed in
 599    --  square brackets (which can nest if necessary). Note that this routine
 600    --  is used only for internal compiler debugging output purposes (which
 601    --  is why the somewhat cryptic use of brackets is acceptable).
 602
 603    procedure wl (P : Source_Ptr);
 604    pragma Export (Ada, wl);
 605    --  Equivalent to Write_Location (P); Write_Eol; for calls from GDB
 606
 607    procedure Write_Time_Stamp (S : Source_File_Index);
 608    --  Writes time stamp of specified file in YY-MM-DD HH:MM.SS format
 609
 610    procedure Tree_Read;
 611    --  Initializes internal tables from current tree file using the relevant
 612    --  Table.Tree_Read routines.
 613
 614    procedure Tree_Write;
 615    --  Writes out internal tables to current tree file using the relevant
 616    --  Table.Tree_Write routines.
 617
 618 private
 619    pragma Inline (File_Name);
 620    pragma Inline (First_Mapped_Line);
 621    pragma Inline (Full_File_Name);
 622    pragma Inline (Identifier_Casing);
 623    pragma Inline (Instantiation);
 624    pragma Inline (Keyword_Casing);
 625    pragma Inline (Last_Source_Line);
 626    pragma Inline (Last_Source_File);
 627    pragma Inline (License);
 628    pragma Inline (Num_SRef_Pragmas);
 629    pragma Inline (Num_Source_Files);
 630    pragma Inline (Num_Source_Lines);
 631    pragma Inline (Reference_Name);
 632    pragma Inline (Set_Keyword_Casing);
 633    pragma Inline (Set_Identifier_Casing);
 634    pragma Inline (Source_First);
 635    pragma Inline (Source_Last);
 636    pragma Inline (Source_Text);
 637    pragma Inline (Template);
 638    pragma Inline (Time_Stamp);
 639
 640    -------------------------
 641    -- Source_Lines Tables --
 642    -------------------------
 643
 644    type Lines_Table_Type is
 645      array (Physical_Line_Number) of Source_Ptr;
 646    --  Type used for lines table. The entries are indexed by physical line
 647    --  numbers. The values are the starting Source_Ptr values for the start
 648    --  of the corresponding physical line. Note that we make this a bogus
 649    --  big array, sized as required, so that we avoid the use of fat pointers.
 650
 651    type Lines_Table_Ptr is access all Lines_Table_Type;
 652    --  Type used for pointers to line tables
 653
 654    type Logical_Lines_Table_Type is
 655      array (Physical_Line_Number) of Logical_Line_Number;
 656    --  Type used for logical lines table. This table is used if a source
 657    --  reference pragma is present. It is indexed by physical line numbers,
 658    --  and contains the corresponding logical line numbers. An entry that
 659    --  corresponds to a source reference pragma is set to No_Line_Number.
 660    --  Note that we make this a bogus big array, sized as required, so that
 661    --  we avoid the use of fat pointers.
 662
 663    type Logical_Lines_Table_Ptr is access all Logical_Lines_Table_Type;
 664    --  Type used for pointers to logical line tables
 665
 666    -----------------------
 667    -- Source_File Table --
 668    -----------------------
 669
 670    --  See earlier descriptions for meanings of public fields
 671
 672    type Source_File_Record is record
 673
 674       File_Name         : File_Name_Type;
 675       File_Type         : Type_Of_File;
 676       Reference_Name    : File_Name_Type;
 677       Debug_Source_Name : File_Name_Type;
 678       Full_Debug_Name   : File_Name_Type;
 679       Full_File_Name    : File_Name_Type;
 680       Full_Ref_Name     : File_Name_Type;
 681       Inlined_Body      : Boolean;
 682       License           : License_Type;
 683       Num_SRef_Pragmas  : Nat;
 684       First_Mapped_Line : Logical_Line_Number;
 685       Source_Text       : Source_Buffer_Ptr;
 686       Source_First      : Source_Ptr;
 687       Source_Last       : Source_Ptr;
 688       Time_Stamp        : Time_Stamp_Type;
 689       Source_Checksum   : Word;
 690       Last_Source_Line  : Physical_Line_Number;
 691       Keyword_Casing    : Casing_Type;
 692       Identifier_Casing : Casing_Type;
 693       Instantiation     : Source_Ptr;
 694       Template          : Source_File_Index;
 695       Unit              : Unit_Number_Type;
 696
 697       --  The following fields are for internal use only (i.e. only in the
 698       --  body of Sinput or its children, with no direct access by clients).
 699
 700       Sloc_Adjust : Source_Ptr;
 701       --  A value to be added to Sloc values for this file to reference the
 702       --  corresponding lines table. This is zero for the non-instantiation
 703       --  case, and set so that the adition references the ultimate template
 704       --  for the instantiation case. See Sinput-L for further details.
 705
 706       Lines_Table : Lines_Table_Ptr;
 707       --  Pointer to lines table for this source. Updated as additional
 708       --  lines are accessed using the Skip_Line_Terminators procedure.
 709       --  Note: the lines table for an instantiation entry refers to the
 710       --  original line numbers of the template see Sinput-L for details.
 711
 712       Logical_Lines_Table : Logical_Lines_Table_Ptr;
 713       --  Pointer to logical lines table for this source. Non-null only if
 714       --  a source reference pragma has been processed. Updated as lines
 715       --  are accessed using the Skip_Line_Terminators procedure.
 716
 717       Lines_Table_Max : Physical_Line_Number;
 718       --  Maximum subscript values for currently allocated Lines_Table
 719       --  and (if present) the allocated Logical_Lines_Table. The value
 720       --  Max_Source_Line gives the maximum used value, this gives the
 721       --  maximum allocated value.
 722
 723    end record;
 724
 725    package Source_File is new Table.Table (
 726      Table_Component_Type => Source_File_Record,
 727      Table_Index_Type     => Source_File_Index,
 728      Table_Low_Bound      => 1,
 729      Table_Initial        => Alloc.Source_File_Initial,
 730      Table_Increment      => Alloc.Source_File_Increment,
 731      Table_Name           => "Source_File");
 732
 733    -----------------
 734    -- Subprograms --
 735    -----------------
 736
 737    procedure Alloc_Line_Tables
 738      (S       : in out Source_File_Record;
 739       New_Max : Nat);
 740    --  Allocate or reallocate the lines table for the given source file so
 741    --  that it can accommodate at least New_Max lines. Also allocates or
 742    --  reallocates logical lines table if source ref pragmas are present.
 743
 744    procedure Add_Line_Tables_Entry
 745      (S : in out Source_File_Record;
 746       P : Source_Ptr);
 747    --  Increment line table size by one (reallocating the lines table if
 748    --  needed) and set the new entry to contain the value P. Also bumps
 749    --  the Source_Line_Count field. If source reference pragmas are
 750    --  present, also increments logical lines table size by one, and
 751    --  sets new entry.
 752
 753    procedure Trim_Lines_Table (S : Source_File_Index);
 754    --  Set lines table size for entry S in the source file table to
 755    --  correspond to the current value of Num_Source_Lines, releasing
 756    --  any unused storage. This is used by Sinput.L and Sinput.D.
 757
 758 end Sinput;