gcc/ada/scans.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                S C A N S                                 --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2006, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Types;  use Types;
  35 with Uintp;  use Uintp;
  36 with Urealp; use Urealp;
  37
  38 package Scans is
  39
  40 --  The scanner maintains a current state in the global variables defined
  41 --  in this package. The call to the Scan routine advances this state to
  42 --  the next token. The state is initialized by the call to one of the
  43 --  initialization routines in Sinput.
  44
  45    --  The following type is used to identify token types returned by Scan.
  46    --  The class column in this table indicates the token classes which
  47    --  apply to the token, as defined by subsquent subtype declarations.
  48
  49    --  Note: Namet.Is_Keyword_Name depends on the fact that the first entry in
  50    --  this type declaration is *not* for a reserved word. For details on why
  51    --  there is this requirement, see Scans.Initialize_Ada_Keywords.
  52
  53    type Token_Type is (
  54
  55       --  Token name          Token type   Class(es)
  56
  57       Tok_Integer_Literal, -- numeric lit  Literal, Lit_Or_Name
  58
  59       Tok_Real_Literal,    -- numeric lit  Literal, Lit_Or_Name
  60
  61       Tok_String_Literal,  -- string lit   Literal. Lit_Or_Name
  62
  63       Tok_Char_Literal,    -- char lit     Name, Literal. Lit_Or_Name
  64
  65       Tok_Operator_Symbol, -- op symbol    Name, Literal, Lit_Or_Name, Desig
  66
  67       Tok_Identifier,      -- identifer    Name, Lit_Or_Name, Desig
  68
  69       Tok_Double_Asterisk, -- **
  70
  71       Tok_Ampersand,       -- &            Binary_Addop
  72       Tok_Minus,           -- -            Binary_Addop, Unary_Addop
  73       Tok_Plus,            -- +            Binary_Addop, Unary_Addop
  74
  75       Tok_Asterisk,        -- *            Mulop
  76       Tok_Mod,             -- MOD          Mulop
  77       Tok_Rem,             -- REM          Mulop
  78       Tok_Slash,           -- /            Mulop
  79
  80       Tok_New,             -- NEW
  81
  82       Tok_Abs,             -- ABS
  83       Tok_Others,          -- OTHERS
  84       Tok_Null,            -- NULL
  85
  86       Tok_Dot,             -- .            Namext
  87       Tok_Apostrophe,      -- '            Namext
  88
  89       Tok_Left_Paren,      -- (            Namext, Consk
  90
  91       Tok_Delta,           -- DELTA        Atkwd, Sterm, Consk
  92       Tok_Digits,          -- DIGITS       Atkwd, Sterm, Consk
  93       Tok_Range,           -- RANGE        Atkwd, Sterm, Consk
  94
  95       Tok_Right_Paren,     -- )            Sterm
  96       Tok_Comma,           -- ,            Sterm
  97
  98       Tok_And,             -- AND          Logop, Sterm
  99       Tok_Or,              -- OR           Logop, Sterm
 100       Tok_Xor,             -- XOR          Logop, Sterm
 101
 102       Tok_Less,            -- <            Relop, Sterm
 103       Tok_Equal,           -- =            Relop, Sterm
 104       Tok_Greater,         -- >            Relop, Sterm
 105       Tok_Not_Equal,       -- /=           Relop, Sterm
 106       Tok_Greater_Equal,   -- >=           Relop, Sterm
 107       Tok_Less_Equal,      -- <=           Relop, Sterm
 108
 109       Tok_In,              -- IN           Relop, Sterm
 110       Tok_Not,             -- NOT          Relop, Sterm
 111
 112       Tok_Box,             -- <>           Relop, Eterm, Sterm
 113       Tok_Colon_Equal,     -- :=           Eterm, Sterm
 114       Tok_Colon,           -- :            Eterm, Sterm
 115       Tok_Greater_Greater, -- >>           Eterm, Sterm
 116
 117       Tok_Abstract,        -- ABSTRACT     Eterm, Sterm
 118       Tok_Access,          -- ACCESS       Eterm, Sterm
 119       Tok_Aliased,         -- ALIASED      Eterm, Sterm
 120       Tok_All,             -- ALL          Eterm, Sterm
 121       Tok_Array,           -- ARRAY        Eterm, Sterm
 122       Tok_At,              -- AT           Eterm, Sterm
 123       Tok_Body,            -- BODY         Eterm, Sterm
 124       Tok_Constant,        -- CONSTANT     Eterm, Sterm
 125       Tok_Do,              -- DO           Eterm, Sterm
 126       Tok_Is,              -- IS           Eterm, Sterm
 127       Tok_Interface,       -- INTERFACE    Eterm, Sterm
 128       Tok_Limited,         -- LIMITED      Eterm, Sterm
 129       Tok_Of,              -- OF           Eterm, Sterm
 130       Tok_Out,             -- OUT          Eterm, Sterm
 131       Tok_Record,          -- RECORD       Eterm, Sterm
 132       Tok_Renames,         -- RENAMES      Eterm, Sterm
 133       Tok_Reverse,         -- REVERSE      Eterm, Sterm
 134       Tok_Tagged,          -- TAGGED       Eterm, Sterm
 135       Tok_Then,            -- THEN         Eterm, Sterm
 136
 137       Tok_Less_Less,       -- <<           Eterm, Sterm, After_SM
 138
 139       Tok_Abort,           -- ABORT        Eterm, Sterm, After_SM
 140       Tok_Accept,          -- ACCEPT       Eterm, Sterm, After_SM
 141       Tok_Case,            -- CASE         Eterm, Sterm, After_SM
 142       Tok_Delay,           -- DELAY        Eterm, Sterm, After_SM
 143       Tok_Else,            -- ELSE         Eterm, Sterm, After_SM
 144       Tok_Elsif,           -- ELSIF        Eterm, Sterm, After_SM
 145       Tok_End,             -- END          Eterm, Sterm, After_SM
 146       Tok_Exception,       -- EXCEPTION    Eterm, Sterm, After_SM
 147       Tok_Exit,            -- EXIT         Eterm, Sterm, After_SM
 148       Tok_Goto,            -- GOTO         Eterm, Sterm, After_SM
 149       Tok_If,              -- IF           Eterm, Sterm, After_SM
 150       Tok_Pragma,          -- PRAGMA       Eterm, Sterm, After_SM
 151       Tok_Raise,           -- RAISE        Eterm, Sterm, After_SM
 152       Tok_Requeue,         -- REQUEUE      Eterm, Sterm, After_SM
 153       Tok_Return,          -- RETURN       Eterm, Sterm, After_SM
 154       Tok_Select,          -- SELECT       Eterm, Sterm, After_SM
 155       Tok_Terminate,       -- TERMINATE    Eterm, Sterm, After_SM
 156       Tok_Until,           -- UNTIL        Eterm, Sterm, After_SM
 157       Tok_When,            -- WHEN         Eterm, Sterm, After_SM
 158
 159       Tok_Begin,           -- BEGIN        Eterm, Sterm, After_SM, Labeled_Stmt
 160       Tok_Declare,         -- DECLARE      Eterm, Sterm, After_SM, Labeled_Stmt
 161       Tok_For,             -- FOR          Eterm, Sterm, After_SM, Labeled_Stmt
 162       Tok_Loop,            -- LOOP         Eterm, Sterm, After_SM, Labeled_Stmt
 163       Tok_While,           -- WHILE        Eterm, Sterm, After_SM, Labeled_Stmt
 164
 165       Tok_Entry,           -- ENTRY        Eterm, Sterm, Declk, Deckn, After_SM
 166       Tok_Protected,       -- PROTECTED    Eterm, Sterm, Declk, Deckn, After_SM
 167       Tok_Task,            -- TASK         Eterm, Sterm, Declk, Deckn, After_SM
 168       Tok_Type,            -- TYPE         Eterm, Sterm, Declk, Deckn, After_SM
 169       Tok_Subtype,         -- SUBTYPE      Eterm, Sterm, Declk, Deckn, After_SM
 170       Tok_Overriding,      -- OVERRIDING   Eterm, Sterm, Declk, Declk, After_SM
 171       Tok_Synchronized,    -- SYNCHRONIZED Eterm, Sterm, Declk, Deckn, After_SM
 172       Tok_Use,             -- USE          Eterm, Sterm, Declk, Deckn, After_SM
 173
 174       Tok_Function,        -- FUNCTION     Eterm, Sterm, Cunit, Declk, After_SM
 175       Tok_Generic,         -- GENERIC      Eterm, Sterm, Cunit, Declk, After_SM
 176       Tok_Package,         -- PACKAGE      Eterm, Sterm, Cunit, Declk, After_SM
 177       Tok_Procedure,       -- PROCEDURE    Eterm, Sterm, Cunit, Declk, After_SM
 178
 179       Tok_Private,         -- PRIVATE      Eterm, Sterm, Cunit, After_SM
 180       Tok_With,            -- WITH         Eterm, Sterm, Cunit, After_SM
 181       Tok_Separate,        -- SEPARATE     Eterm, Sterm, Cunit, After_SM
 182
 183       Tok_EOF,             -- End of file  Eterm, Sterm, Cterm, After_SM
 184
 185       Tok_Semicolon,       -- ;            Eterm, Sterm, Cterm
 186
 187       Tok_Arrow,           -- =>           Sterm, Cterm, Chtok
 188
 189       Tok_Vertical_Bar,    -- |            Cterm, Sterm, Chtok
 190
 191       Tok_Dot_Dot,         -- ..           Sterm, Chtok
 192
 193       Tok_Project,
 194       Tok_Extends,
 195       Tok_External,
 196       --  These three entries represent keywords for the project file language
 197       --  and can be returned only in the case of scanning project files.
 198
 199       Tok_Comment,
 200       --  This entry is used when scanning project files (where it represents
 201       --  an entire comment), and in preprocessing with the -C switch set
 202       --  (where it represents just the "--" of a comment). For the project
 203       --  file case, the text of the comment is stored in
 204
 205       Tok_End_Of_Line,
 206       --  Represents an end of line. Not used during normal compilation scans
 207       --  where end of line is ignored. Active for preprocessor scanning and
 208       --  also when scanning project files (where it is neede because of ???)
 209
 210       Tok_Special,
 211       --  Used only in preprocessor scanning (to represent one of the
 212       --  characters '#', '$', '?', '@', '`', '\', '^', '~', or '_'. The
 213       --  character value itself is stored in Scans.Special_Character.
 214
 215       No_Token);
 216       --  No_Token is used for initializing Token values to indicate that
 217       --  no value has been set yet.
 218
 219    --  Note: in the RM, operator symbol is a special case of string literal.
 220    --  We distinguish at the lexical level in this compiler, since there are
 221    --  many syntactic situations in which only an operator symbol is allowed.
 222
 223    --  The following subtype declarations group the token types into classes.
 224    --  These are used for class tests in the parser.
 225
 226    subtype Token_Class_Numeric_Literal is
 227      Token_Type range Tok_Integer_Literal .. Tok_Real_Literal;
 228    --  Numeric literal
 229
 230    subtype Token_Class_Literal is
 231      Token_Type range Tok_Integer_Literal .. Tok_Operator_Symbol;
 232    --  Literal
 233
 234    subtype Token_Class_Lit_Or_Name is
 235      Token_Type range Tok_Integer_Literal .. Tok_Identifier;
 236
 237    subtype Token_Class_Binary_Addop is
 238      Token_Type range Tok_Ampersand .. Tok_Plus;
 239    --  Binary adding operator (& + -)
 240
 241    subtype Token_Class_Unary_Addop is
 242      Token_Type range Tok_Minus .. Tok_Plus;
 243    --  Unary adding operator (+ -)
 244
 245    subtype Token_Class_Mulop is
 246      Token_Type range Tok_Asterisk .. Tok_Slash;
 247    --  Multiplying operator
 248
 249    subtype Token_Class_Logop is
 250      Token_Type range Tok_And .. Tok_Xor;
 251    --  Logical operator (and, or, xor)
 252
 253    subtype Token_Class_Relop is
 254      Token_Type range Tok_Less .. Tok_Box;
 255    --  Relational operator (= /= < <= > >= not, in plus <> to catch misuse
 256    --  of Pascal style not equal operator).
 257
 258    subtype Token_Class_Name is
 259      Token_Type range Tok_Char_Literal .. Tok_Identifier;
 260    --  First token of name (4.1),
 261    --    (identifier, char literal, operator symbol)
 262
 263    subtype Token_Class_Desig is
 264      Token_Type range Tok_Operator_Symbol .. Tok_Identifier;
 265    --  Token which can be a Designator (identifier, operator symbol)
 266
 267    subtype Token_Class_Namext is
 268      Token_Type range Tok_Dot .. Tok_Left_Paren;
 269    --  Name extension tokens. These are tokens which can appear immediately
 270    --  after a name to extend it recursively (period, quote, left paren)
 271
 272    subtype Token_Class_Consk is
 273      Token_Type range Tok_Left_Paren .. Tok_Range;
 274    --  Keywords which can start constraint
 275    --    (left paren, delta, digits, range)
 276
 277    subtype Token_Class_Eterm is
 278      Token_Type range Tok_Colon_Equal .. Tok_Semicolon;
 279    --  Expression terminators. These tokens can never appear within a simple
 280    --  expression. This is used for error recovery purposes (if we encounter
 281    --  an error in an expression, we simply scan to the next Eterm token).
 282
 283    subtype Token_Class_Sterm is
 284      Token_Type range Tok_Delta .. Tok_Dot_Dot;
 285    --  Simple_Expression terminators. A Simple_Expression must be followed
 286    --  by a token in this class, or an error message is issued complaining
 287    --  about a missing binary operator.
 288
 289    subtype Token_Class_Atkwd is
 290      Token_Type range Tok_Delta .. Tok_Range;
 291    --  Attribute keywords. This class includes keywords which can be used
 292    --  as an Attribute_Designator, namely DELTA, DIGITS and RANGE
 293
 294    subtype Token_Class_Cterm is
 295      Token_Type range Tok_EOF .. Tok_Vertical_Bar;
 296    --  Choice terminators. These tokens terminate a choice. This is used for
 297    --  error recovery purposes (if we encounter an error in a Choice, we
 298    --  simply scan to the next Cterm token).
 299
 300    subtype Token_Class_Chtok is
 301      Token_Type range Tok_Arrow .. Tok_Dot_Dot;
 302    --  Choice tokens. These tokens signal a choice when used in an Aggregate
 303
 304    subtype Token_Class_Cunit is
 305      Token_Type range Tok_Function .. Tok_Separate;
 306    --  Tokens which can begin a compilation unit
 307
 308    subtype Token_Class_Declk is
 309      Token_Type range Tok_Entry .. Tok_Procedure;
 310    --  Keywords which start a declaration
 311
 312    subtype Token_Class_Deckn is
 313      Token_Type range Tok_Entry .. Tok_Use;
 314    --  Keywords which start a declaration but can't start a compilation unit
 315
 316    subtype Token_Class_After_SM is
 317      Token_Type range Tok_Less_Less .. Tok_EOF;
 318    --  Tokens which always, or almost always, appear after a semicolon. Used
 319    --  in the Resync_Past_Semicolon routine to avoid gobbling up stuff when
 320    --  a semicolon is missing. Of significance only for error recovery.
 321
 322    subtype Token_Class_Labeled_Stmt is
 323      Token_Type range Tok_Begin .. Tok_While;
 324    --  Tokens which start labeled statements
 325
 326    type Token_Flag_Array is array (Token_Type) of Boolean;
 327    Is_Reserved_Keyword : constant Token_Flag_Array :=
 328                            Token_Flag_Array'
 329                              (Tok_Mod      .. Tok_Rem      => True,
 330                               Tok_New      .. Tok_Null     => True,
 331                               Tok_Delta    .. Tok_Range    => True,
 332                               Tok_And      .. Tok_Xor      => True,
 333                               Tok_In       .. Tok_Not      => True,
 334                               Tok_Abstract .. Tok_Then     => True,
 335                               Tok_Abort    .. Tok_Separate => True,
 336                               others                       => False);
 337    --  Flag array used to test for reserved word
 338
 339    procedure Initialize_Ada_Keywords;
 340    --  Set up Token_Type values in Names table entries for Ada reserved
 341    --  words.
 342
 343    --------------------------
 344    -- Scan State Variables --
 345    --------------------------
 346
 347    --  Note: these variables can only be referenced during the parsing of a
 348    --  file. Reference to any of them from Sem or the expander is wrong.
 349
 350    Scan_Ptr : Source_Ptr;
 351    --  Current scan pointer location. After a call to Scan, this points
 352    --  just past the end of the token just scanned.
 353
 354    Token : Token_Type;
 355    --  Type of current token
 356
 357    Token_Ptr : Source_Ptr;
 358    --  Pointer to first character of current token
 359
 360    Current_Line_Start : Source_Ptr;
 361    --  Pointer to first character of line containing current token
 362
 363    Start_Column : Column_Number;
 364    --  Starting column number (zero origin) of the first non-blank character
 365    --  on the line containing the current token. This is used for error
 366    --  recovery circuits which depend on looking at the column line up.
 367
 368    Checksum : Word;
 369    --  Used to accumulate a CRC representing the tokens in the source
 370    --  file being compiled. This CRC includes only program tokens, and
 371    --  excludes comments.
 372
 373    First_Non_Blank_Location : Source_Ptr;
 374    --  Location of first non-blank character on the line containing the
 375    --  current token (i.e. the location of the character whose column number
 376    --  is stored in Start_Column).
 377
 378    Token_Node : Node_Id := Empty;
 379    --  Node table Id for the current token. This is set only if the current
 380    --  token is one for which the scanner constructs a node (i.e. it is an
 381    --  identifier, operator symbol, or literal. For other token types,
 382    --  Token_Node is undefined.
 383
 384    Token_Name : Name_Id := No_Name;
 385    --  For identifiers, this is set to the Name_Id of the identifier scanned.
 386    --  For all other tokens, Token_Name is set to Error_Name. Note that it
 387    --  would be possible for the caller to extract this information from
 388    --  Token_Node. We set Token_Name separately for two reasons. First it
 389    --  allows a quicker test for a specific identifier. Second, it allows
 390    --  a version of the parser to be built that does not build tree nodes,
 391    --  usable as a syntax checker.
 392
 393    Prev_Token : Token_Type := No_Token;
 394    --  Type of previous token
 395
 396    Prev_Token_Ptr : Source_Ptr;
 397    --  Pointer to first character of previous token
 398
 399    Version_To_Be_Found : Boolean;
 400    --  This flag is True if the scanner is still looking for an RCS version
 401    --  number in a comment. Normally it is initialized to False so that this
 402    --  circuit is not activated. If the -dv switch is set, then this flag is
 403    --  initialized to True, and then reset when the version number is found.
 404    --  We do things this way to minimize the impact on comment scanning.
 405
 406    Character_Code : Char_Code;
 407    --  Valid only when Token is Tok_Char_Literal
 408
 409    Real_Literal_Value : Ureal;
 410    --  Valid only when Token is Tok_Real_Literal
 411
 412    Int_Literal_Value : Uint;
 413    --  Valid only when Token = Tok_Integer_Literal;
 414
 415    String_Literal_Id : String_Id;
 416    --  Id for currently scanned string value.
 417    --  Valid only when Token = Tok_String_Literal or Tok_Operator_Symbol.
 418
 419    Wide_Character_Found : Boolean := False;
 420    --  Set True if wide character found.
 421    --  Valid only when Token = Tok_String_Literal.
 422
 423    Special_Character : Character;
 424    --  Valid only when Token = Tok_Special. Returns one of the characters
 425    --  '#', '$', '?', '@', '`', '\', '^', '~', or '_'.
 426    --
 427    --  Why only this set? What about wide characters???
 428
 429    Comment_Id : Name_Id := No_Name;
 430    --  Valid only when Token = Tok_Comment. Store the string that follows
 431    --  the "--" of a comment when scanning project files.
 432    --
 433    --  Is it really right for this to be a Name rather than a String, what
 434    --  about the case of Wide_Wide_Characters???
 435
 436    --------------------------------------------------------
 437    -- Procedures for Saving and Restoring the Scan State --
 438    --------------------------------------------------------
 439
 440    --  The following procedures can be used to save and restore the entire
 441    --  scan state. They are used in cases where it is necessary to backup
 442    --  the scan during the parse.
 443
 444    type Saved_Scan_State is private;
 445    --  Used for saving and restoring the scan state
 446
 447    procedure Save_Scan_State (Saved_State : out Saved_Scan_State);
 448    pragma Inline (Save_Scan_State);
 449    --  Saves the current scan state for possible later restoration. Note that
 450    --  there is no harm in saving the state and then never restoring it.
 451
 452    procedure Restore_Scan_State (Saved_State : Saved_Scan_State);
 453    pragma Inline (Restore_Scan_State);
 454    --  Restores a scan state saved by a call to Save_Scan_State.
 455    --  The saved scan state must refer to the current source file.
 456
 457 private
 458    type Saved_Scan_State is record
 459       Save_Scan_Ptr                 : Source_Ptr;
 460       Save_Token                    : Token_Type;
 461       Save_Token_Ptr                : Source_Ptr;
 462       Save_Current_Line_Start       : Source_Ptr;
 463       Save_Start_Column             : Column_Number;
 464       Save_Checksum                 : Word;
 465       Save_First_Non_Blank_Location : Source_Ptr;
 466       Save_Token_Node               : Node_Id;
 467       Save_Token_Name               : Name_Id;
 468       Save_Prev_Token               : Token_Type;
 469       Save_Prev_Token_Ptr           : Source_Ptr;
 470    end record;
 471
 472 end Scans;