gcc/ada/s-valwch.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                     S Y S T E M . V A L _ W C H A R                      --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2006, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Interfaces;      use Interfaces;
  35 with System.Val_Util; use System.Val_Util;
  36 with System.WCh_Cnv;  use System.WCh_Cnv;
  37 with System.WCh_Con;  use System.WCh_Con;
  38
  39 package body System.Val_WChar is
  40
  41    --------------------------
  42    -- Value_Wide_Character --
  43    --------------------------
  44
  45    function Value_Wide_Character
  46      (Str : String;
  47       EM  : System.WCh_Con.WC_Encoding_Method) return Wide_Character
  48    is
  49       WC : constant Wide_Wide_Character := Value_Wide_Wide_Character (Str, EM);
  50       WV : constant Unsigned_32         := Wide_Wide_Character'Pos (WC);
  51    begin
  52       if WV > 16#FFFF# then
  53          raise Constraint_Error
  54            with "out of range character for Value attribute";
  55       else
  56          return Wide_Character'Val (WV);
  57       end if;
  58    end Value_Wide_Character;
  59
  60    -------------------------------
  61    -- Value_Wide_Wide_Character --
  62    -------------------------------
  63
  64    function Value_Wide_Wide_Character
  65      (Str : String;
  66       EM  : System.WCh_Con.WC_Encoding_Method) return Wide_Wide_Character
  67    is
  68       F : Natural;
  69       L : Natural;
  70       S : String (Str'Range) := Str;
  71
  72    begin
  73       Normalize_String (S, F, L);
  74
  75       --  Character literal case
  76
  77       if S (F) = ''' and then S (L) = ''' then
  78
  79          --  Must be at least three characters
  80
  81          if L - F < 2 then
  82             raise Constraint_Error;
  83
  84          --  If just three characters, simple character case
  85
  86          elsif L - F = 2 then
  87             return Wide_Wide_Character'Val (Character'Pos (S (F + 1)));
  88
  89          --  Only other possibility for quoted string is wide char sequence
  90
  91          else
  92             declare
  93                P : Natural;
  94                W : Wide_Wide_Character;
  95
  96                function In_Char return Character;
  97                --  Function for instantiations of Char_Sequence_To_UTF_32
  98
  99                -------------
 100                -- In_Char --
 101                -------------
 102
 103                function In_Char return Character is
 104                begin
 105                   P := P + 1;
 106
 107                   if P = Str'Last then
 108                      raise Constraint_Error;
 109                   end if;
 110
 111                   return Str (P);
 112                end In_Char;
 113
 114                function UTF_32 is
 115                  new Char_Sequence_To_UTF_32 (In_Char);
 116
 117             begin
 118                P := F + 1;
 119
 120                --  Brackets encoding
 121
 122                if S (F + 1) = '[' then
 123                   W := Wide_Wide_Character'Val (UTF_32 ('[', WCEM_Brackets));
 124
 125                else
 126                   W := Wide_Wide_Character'Val (UTF_32 (S (F + 1), EM));
 127                end if;
 128
 129                if P /= L - 1 then
 130                   raise Constraint_Error;
 131                end if;
 132
 133                return W;
 134             end;
 135          end if;
 136
 137       --  Deal with Hex_hhhhhhhh cases for wide_[wide_]character cases
 138
 139       elsif Str'Length = 12
 140         and then Str (Str'First .. Str'First + 3) = "Hex_"
 141       then
 142          declare
 143             W : Unsigned_32 := 0;
 144
 145          begin
 146             for J in Str'First + 4 .. Str'First + 11 loop
 147                W := W * 16 + Character'Pos (Str (J));
 148
 149                if Str (J) in '0' .. '9' then
 150                   W := W - Character'Pos ('0');
 151                elsif Str (J) in 'A' .. 'F' then
 152                   W := W - Character'Pos ('A') + 10;
 153                elsif Str (J) in 'a' .. 'f' then
 154                   W := W - Character'Pos ('a') + 10;
 155                else
 156                   raise Constraint_Error;
 157                end if;
 158             end loop;
 159
 160             if W > 16#7FFF_FFFF# then
 161                raise Constraint_Error;
 162             else
 163                return Wide_Wide_Character'Val (W);
 164             end if;
 165          end;
 166
 167       --  Otherwise must be one of the special names for Character
 168
 169       else
 170          return
 171            Wide_Wide_Character'Val (Character'Pos (Character'Value (Str)));
 172       end if;
 173
 174    exception
 175       when Constraint_Error =>
 176          raise Constraint_Error with "invalid string for value attribute";
 177    end Value_Wide_Wide_Character;
 178
 179 end System.Val_WChar;