gcc/ada/par-util.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             P A R . U T I L                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2004, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Csets;   use Csets;
  28 with Stylesw; use Stylesw;
  29 with Uintp;   use Uintp;
  30
  31 with GNAT.Spelling_Checker; use GNAT.Spelling_Checker;
  32
  33 separate (Par)
  34 package body Util is
  35
  36    ---------------------
  37    -- Bad_Spelling_Of --
  38    ---------------------
  39
  40    function Bad_Spelling_Of (T : Token_Type) return Boolean is
  41       Tname : constant String := Token_Type'Image (T);
  42       --  Characters of token name
  43
  44       S : String (1 .. Tname'Last - 4);
  45       --  Characters of token name folded to lower case, omitting TOK_ at start
  46
  47       M1 : String (1 .. 42) := "incorrect spelling of keyword ************";
  48       M2 : String (1 .. 44) := "illegal abbreviation of keyword ************";
  49       --  Buffers used to construct error message
  50
  51       P1 : constant := 30;
  52       P2 : constant := 32;
  53       --  Starting subscripts in M1, M2 for keyword name
  54
  55       SL : constant Natural := S'Length;
  56       --  Length of expected token name excluding TOK_ at start
  57
  58    begin
  59       if Token /= Tok_Identifier then
  60          return False;
  61       end if;
  62
  63       for J in S'Range loop
  64          S (J) := Fold_Lower (Tname (Integer (J) + 4));
  65       end loop;
  66
  67       Get_Name_String (Token_Name);
  68
  69       --  A special check for case of PROGRAM used for PROCEDURE
  70
  71       if T = Tok_Procedure
  72         and then Name_Len = 7
  73         and then Name_Buffer (1 .. 7) = "program"
  74       then
  75          Error_Msg_SC ("PROCEDURE expected");
  76          Token := T;
  77          return True;
  78
  79       --  A special check for an illegal abbrevation
  80
  81       elsif Name_Len < S'Length
  82         and then Name_Len >= 4
  83         and then Name_Buffer (1 .. Name_Len) = S (1 .. Name_Len)
  84       then
  85          for J in 1 .. S'Last loop
  86             M2 (P2 + J - 1) := Fold_Upper (S (J));
  87          end loop;
  88
  89          Error_Msg_SC (M2 (1 .. P2 - 1 + S'Last));
  90          Token := T;
  91          return True;
  92       end if;
  93
  94       --  Now we go into the full circuit to check for a misspelling
  95
  96       --  Never consider something a misspelling if either the actual or
  97       --  expected string is less than 3 characters (before this check we
  98       --  used to consider i to be a misspelled if in some cases!)
  99
 100       if SL < 3 or else Name_Len < 3 then
 101          return False;
 102
 103       --  Special case: prefix matches, i.e. the leading characters of the
 104       --  token that we have exactly match the required keyword. If there
 105       --  are at least two characters left over, assume that we have a case
 106       --  of two keywords joined together which should not be joined.
 107
 108       elsif Name_Len > SL + 1
 109         and then S = Name_Buffer (1 .. SL)
 110       then
 111          Scan_Ptr := Token_Ptr + S'Length;
 112          Error_Msg_S ("missing space");
 113          Token := T;
 114          return True;
 115       end if;
 116
 117       if Is_Bad_Spelling_Of (Name_Buffer (1 .. Name_Len), S) then
 118          for J in 1 .. S'Last loop
 119             M1 (P1 + J - 1) := Fold_Upper (S (J));
 120          end loop;
 121
 122          Error_Msg_SC (M1 (1 .. P1 - 1 + S'Last));
 123          Token := T;
 124          return True;
 125
 126       else
 127          return False;
 128       end if;
 129    end Bad_Spelling_Of;
 130
 131    ----------------------
 132    -- Check_95_Keyword --
 133    ----------------------
 134
 135    --  On entry, the caller has checked that current token is an identifier
 136    --  whose name matches the name of the 95 keyword New_Tok.
 137
 138    procedure Check_95_Keyword (Token_95, Next : Token_Type) is
 139       Scan_State : Saved_Scan_State;
 140
 141    begin
 142       Save_Scan_State (Scan_State); -- at identifier/keyword
 143       Scan; -- past identifier/keyword
 144
 145       if Token = Next then
 146          Restore_Scan_State (Scan_State); -- to identifier
 147          Error_Msg_Name_1 := Token_Name;
 148          Error_Msg_SC ("(Ada 83) keyword* cannot be used!");
 149          Token := Token_95;
 150       else
 151          Restore_Scan_State (Scan_State); -- to identifier
 152       end if;
 153    end Check_95_Keyword;
 154
 155    ----------------------
 156    -- Check_Bad_Layout --
 157    ----------------------
 158
 159    procedure Check_Bad_Layout is
 160    begin
 161       if Style.RM_Column_Check and then Token_Is_At_Start_Of_Line
 162         and then Start_Column <= Scope.Table (Scope.Last).Ecol
 163       then
 164          Error_Msg_BC ("(style) incorrect layout");
 165       end if;
 166    end Check_Bad_Layout;
 167
 168    --------------------------
 169    -- Check_Misspelling_Of --
 170    --------------------------
 171
 172    procedure Check_Misspelling_Of (T : Token_Type) is
 173    begin
 174       if Bad_Spelling_Of (T) then
 175          null;
 176       end if;
 177    end Check_Misspelling_Of;
 178
 179    -----------------------------
 180    -- Check_Simple_Expression --
 181    -----------------------------
 182
 183    procedure Check_Simple_Expression (E : Node_Id) is
 184    begin
 185       if Expr_Form = EF_Non_Simple then
 186          Error_Msg_N ("this expression must be parenthesized", E);
 187       end if;
 188    end Check_Simple_Expression;
 189
 190    ---------------------------------------
 191    -- Check_Simple_Expression_In_Ada_83 --
 192    ---------------------------------------
 193
 194    procedure Check_Simple_Expression_In_Ada_83 (E : Node_Id) is
 195    begin
 196       if Expr_Form = EF_Non_Simple then
 197          if Ada_Version = Ada_83 then
 198             Error_Msg_N ("(Ada 83) this expression must be parenthesized!", E);
 199          end if;
 200       end if;
 201    end Check_Simple_Expression_In_Ada_83;
 202
 203    ------------------------
 204    -- Check_Subtype_Mark --
 205    ------------------------
 206
 207    function Check_Subtype_Mark (Mark : Node_Id) return Node_Id is
 208    begin
 209       if Nkind (Mark) = N_Identifier
 210         or else Nkind (Mark) = N_Selected_Component
 211         or else (Nkind (Mark) = N_Attribute_Reference
 212                   and then Is_Type_Attribute_Name (Attribute_Name (Mark)))
 213         or else Mark = Error
 214       then
 215          return Mark;
 216       else
 217          Error_Msg ("subtype mark expected", Sloc (Mark));
 218          return Error;
 219       end if;
 220    end Check_Subtype_Mark;
 221
 222    -------------------
 223    -- Comma_Present --
 224    -------------------
 225
 226    function Comma_Present return Boolean is
 227       Scan_State  : Saved_Scan_State;
 228       Paren_Count : Nat;
 229
 230    begin
 231       --  First check, if a comma is present, then a comma is present!
 232
 233       if Token = Tok_Comma then
 234          T_Comma;
 235          return True;
 236
 237       --  If we have a right paren, then that is taken as ending the list
 238       --  i.e. no comma is present.
 239
 240       elsif Token = Tok_Right_Paren then
 241          return False;
 242
 243       --  If pragmas, then get rid of them and make a recursive call
 244       --  to process what follows these pragmas.
 245
 246       elsif Token = Tok_Pragma then
 247          P_Pragmas_Misplaced;
 248          return Comma_Present;
 249
 250       --  At this stage we have an error, and the goal is to decide on whether
 251       --  or not we should diagnose an error and report a (non-existent)
 252       --  comma as being present, or simply to report no comma is present
 253
 254       --  If we are a semicolon, then the question is whether we have a missing
 255       --  right paren, or whether the semicolon should have been a comma. To
 256       --  guess the right answer, we scan ahead keeping track of the paren
 257       --  level, looking for a clue that helps us make the right decision.
 258
 259       --  This approach is highly accurate in the single error case, and does
 260       --  not make bad mistakes in the multiple error case (indeed we can't
 261       --  really make a very bad decision at this point in any case).
 262
 263       elsif Token = Tok_Semicolon then
 264          Save_Scan_State (Scan_State);
 265          Scan; -- past semicolon
 266
 267          --  Check for being followed by identifier => which almost certainly
 268          --  means we are still in a parameter list and the comma should have
 269          --  been a semicolon (such a sequence could not follow a semicolon)
 270
 271          if Token = Tok_Identifier then
 272             Scan;
 273
 274             if Token = Tok_Arrow then
 275                goto Assume_Comma;
 276             end if;
 277          end if;
 278
 279          --  If that test didn't work, loop ahead looking for a comma or
 280          --  semicolon at the same parenthesis level. Always remember that
 281          --  we can't go badly wrong in an error situation like this!
 282
 283          Paren_Count := 0;
 284
 285          --  Here is the look ahead loop, Paren_Count tells us whether the
 286          --  token we are looking at is at the same paren level as the
 287          --  suspicious semicolon that we are trying to figure out.
 288
 289          loop
 290
 291             --  If we hit another semicolon or an end of file, and we have
 292             --  not seen a right paren or another comma on the way, then
 293             --  probably the semicolon did end the list. Indeed that is
 294             --  certainly the only single error correction possible here.
 295
 296             if Token = Tok_Semicolon or else Token = Tok_EOF then
 297                Restore_Scan_State (Scan_State);
 298                return False;
 299
 300             --  A comma at the same paren level as the semicolon is a strong
 301             --  indicator that the semicolon should have been a comma, indeed
 302             --  again this is the only possible single error correction.
 303
 304             elsif Token = Tok_Comma then
 305                exit when Paren_Count = 0;
 306
 307             --  A left paren just bumps the paren count
 308
 309             elsif Token = Tok_Left_Paren then
 310                Paren_Count := Paren_Count + 1;
 311
 312             --  A right paren that is at the same paren level as the semicolon
 313             --  also means that the only possible single error correction is
 314             --  to assume that the semicolon should have been a comma. If we
 315             --  are not at the same paren level, then adjust the paren level.
 316
 317             elsif Token = Tok_Right_Paren then
 318                exit when Paren_Count = 0;
 319                Paren_Count := Paren_Count - 1;
 320             end if;
 321
 322             --  Keep going, we haven't made a decision yet
 323
 324             Scan;
 325          end loop;
 326
 327          --  If we fall through the loop, it means that we found a terminating
 328          --  right paren or another comma. In either case it is reasonable to
 329          --  assume that the semicolon was really intended to be a comma. Also
 330          --  come here for the identifier arrow case.
 331
 332          <<Assume_Comma>>
 333             Restore_Scan_State (Scan_State);
 334             Error_Msg_SC (""";"" illegal here, replaced by "",""");
 335             Scan; -- past the semicolon
 336             return True;
 337
 338       --  If we are not at semicolon or a right paren, then we base the
 339       --  decision on whether or not the next token can be part of an
 340       --  expression. If not, then decide that no comma is present (the
 341       --  caller will eventually generate a missing right parent message)
 342
 343       elsif Token in Token_Class_Eterm then
 344          return False;
 345
 346       --  Otherwise we assume a comma is present, even if none is present,
 347       --  since the next token must be part of an expression, so if we were
 348       --  at the end of the list, then there is more than one error present.
 349
 350       else
 351          T_Comma; -- to give error
 352          return True;
 353       end if;
 354    end Comma_Present;
 355
 356    -----------------------
 357    -- Discard_Junk_List --
 358    -----------------------
 359
 360    procedure Discard_Junk_List (L : List_Id) is
 361       pragma Warnings (Off, L);
 362    begin
 363       null;
 364    end Discard_Junk_List;
 365
 366    -----------------------
 367    -- Discard_Junk_Node --
 368    -----------------------
 369
 370    procedure Discard_Junk_Node (N : Node_Id) is
 371       pragma Warnings (Off, N);
 372    begin
 373       null;
 374    end Discard_Junk_Node;
 375
 376    ------------
 377    -- Ignore --
 378    ------------
 379
 380    procedure Ignore (T : Token_Type) is
 381    begin
 382       if Token = T then
 383          if T = Tok_Comma then
 384             Error_Msg_SC ("unexpected "","" ignored");
 385
 386          elsif T = Tok_Left_Paren then
 387             Error_Msg_SC ("unexpected ""("" ignored");
 388
 389          elsif T = Tok_Right_Paren then
 390             Error_Msg_SC ("unexpected "")"" ignored");
 391
 392          elsif T = Tok_Semicolon then
 393             Error_Msg_SC ("unexpected "";"" ignored");
 394
 395          else
 396             declare
 397                Tname : constant String := Token_Type'Image (Token);
 398                Msg   : String := "unexpected keyword ????????????????????????";
 399
 400             begin
 401                --  Loop to copy characters of keyword name (ignoring Tok_)
 402
 403                for J in 5 .. Tname'Last loop
 404                   Msg (J + 14) := Fold_Upper (Tname (J));
 405                end loop;
 406
 407                Msg (Tname'Last + 15 .. Tname'Last + 22) := " ignored";
 408                Error_Msg_SC (Msg (1 .. Tname'Last + 22));
 409             end;
 410          end if;
 411
 412          Scan; -- Scan past ignored token
 413       end if;
 414    end Ignore;
 415
 416    ----------------------------
 417    -- Is_Reserved_Identifier --
 418    ----------------------------
 419
 420    function Is_Reserved_Identifier (C : Id_Check := None) return Boolean is
 421    begin
 422       if not Is_Reserved_Keyword (Token) then
 423          return False;
 424
 425       else
 426          declare
 427             Ident_Casing : constant Casing_Type :=
 428                              Identifier_Casing (Current_Source_File);
 429
 430             Key_Casing   : constant Casing_Type :=
 431                              Keyword_Casing (Current_Source_File);
 432
 433          begin
 434             --  If the casing of identifiers and keywords is different in
 435             --  this source file, and the casing of this token matches the
 436             --  keyword casing, then we return False, since it is pretty
 437             --  clearly intended to be a keyword.
 438
 439             if Ident_Casing = Unknown
 440               or else Key_Casing = Unknown
 441               or else Ident_Casing = Key_Casing
 442               or else Determine_Token_Casing /= Key_Casing
 443             then
 444                return True;
 445
 446             --  Here we have a keyword written clearly with keyword casing.
 447             --  In default mode, we would not be willing to consider this as
 448             --  a reserved identifier, but if C is set, we may still accept it
 449
 450             elsif C /= None then
 451                declare
 452                   Scan_State  : Saved_Scan_State;
 453                   OK_Next_Tok : Boolean;
 454
 455                begin
 456                   Save_Scan_State (Scan_State);
 457                   Scan;
 458
 459                   if Token_Is_At_Start_Of_Line then
 460                      return False;
 461                   end if;
 462
 463                   case C is
 464                      when None =>
 465                         raise Program_Error;
 466
 467                      when C_Comma_Right_Paren =>
 468                         OK_Next_Tok :=
 469                           Token = Tok_Comma or else Token = Tok_Right_Paren;
 470
 471                      when C_Comma_Colon =>
 472                         OK_Next_Tok :=
 473                           Token = Tok_Comma or else Token = Tok_Colon;
 474
 475                      when C_Do =>
 476                         OK_Next_Tok :=
 477                           Token = Tok_Do;
 478
 479                      when C_Dot =>
 480                         OK_Next_Tok :=
 481                           Token = Tok_Dot;
 482
 483                      when C_Greater_Greater =>
 484                         OK_Next_Tok :=
 485                           Token = Tok_Greater_Greater;
 486
 487                      when C_In =>
 488                         OK_Next_Tok :=
 489                           Token = Tok_In;
 490
 491                      when C_Is =>
 492                         OK_Next_Tok :=
 493                           Token = Tok_Is;
 494
 495                      when C_Left_Paren_Semicolon =>
 496                         OK_Next_Tok :=
 497                           Token = Tok_Left_Paren or else Token = Tok_Semicolon;
 498
 499                      when C_Use =>
 500                         OK_Next_Tok :=
 501                           Token = Tok_Use;
 502
 503                      when C_Vertical_Bar_Arrow =>
 504                         OK_Next_Tok :=
 505                           Token = Tok_Vertical_Bar or else Token = Tok_Arrow;
 506                   end case;
 507
 508                   Restore_Scan_State (Scan_State);
 509
 510                   if OK_Next_Tok then
 511                      return True;
 512                   end if;
 513                end;
 514             end if;
 515          end;
 516       end if;
 517
 518       --  If we fall through it is not a reserved identifier
 519
 520       return False;
 521    end Is_Reserved_Identifier;
 522
 523    ----------------------
 524    -- Merge_Identifier --
 525    ----------------------
 526
 527    procedure Merge_Identifier (Prev : Node_Id; Nxt : Token_Type) is
 528    begin
 529       if Token /= Tok_Identifier then
 530          return;
 531       end if;
 532
 533       declare
 534          S : Saved_Scan_State;
 535          T : Token_Type;
 536
 537       begin
 538          Save_Scan_State (S);
 539          Scan;
 540          T := Token;
 541          Restore_Scan_State (S);
 542
 543          if T /= Nxt then
 544             return;
 545          end if;
 546       end;
 547
 548       --  Check exactly one space between identifiers
 549
 550       if Source (Token_Ptr - 1) /= ' '
 551         or else Int (Token_Ptr) /=
 552                   Int (Prev_Token_Ptr) + Length_Of_Name (Chars (Prev)) + 1
 553       then
 554          return;
 555       end if;
 556
 557       --  Do the merge
 558
 559       Get_Name_String (Chars (Token_Node));
 560
 561       declare
 562          Buf : constant String (1 .. Name_Len) :=
 563                  Name_Buffer (1 .. Name_Len);
 564
 565       begin
 566          Get_Name_String (Chars (Prev));
 567          Add_Char_To_Name_Buffer ('_');
 568          Add_Str_To_Name_Buffer (Buf);
 569          Set_Chars (Prev, Name_Find);
 570       end;
 571
 572       Error_Msg_Node_1 := Prev;
 573       Error_Msg_SC
 574         ("unexpected identifier, possibly & was meant here");
 575       Scan;
 576    end Merge_Identifier;
 577
 578    -------------------
 579    -- No_Constraint --
 580    -------------------
 581
 582    procedure No_Constraint is
 583    begin
 584       if Token in Token_Class_Consk then
 585          Error_Msg_SC ("constraint not allowed here");
 586          Discard_Junk_Node (P_Constraint_Opt);
 587       end if;
 588    end No_Constraint;
 589
 590    --------------------
 591    -- No_Right_Paren --
 592    --------------------
 593
 594    function No_Right_Paren (Expr : Node_Id) return Node_Id is
 595    begin
 596       if Token = Tok_Right_Paren then
 597          Error_Msg_SC ("unexpected right parenthesis");
 598          Resync_Expression;
 599          return Error;
 600       else
 601          return Expr;
 602       end if;
 603    end No_Right_Paren;
 604
 605    ---------------------
 606    -- Pop_Scope_Stack --
 607    ---------------------
 608
 609    procedure Pop_Scope_Stack is
 610    begin
 611       pragma Assert (Scope.Last > 0);
 612       Scope.Decrement_Last;
 613
 614       if Debug_Flag_P then
 615          Error_Msg_Uint_1 := UI_From_Int (Scope.Last);
 616          Error_Msg_SC ("decrement scope stack ptr, new value = ^!");
 617       end if;
 618    end Pop_Scope_Stack;
 619
 620    ----------------------
 621    -- Push_Scope_Stack --
 622    ----------------------
 623
 624    procedure Push_Scope_Stack is
 625    begin
 626       Scope.Increment_Last;
 627
 628       if Style_Check_Max_Nesting_Level
 629         and then Scope.Last = Style_Max_Nesting_Level + 1
 630       then
 631          Error_Msg
 632            ("(style) maximum nesting level exceeded",
 633             First_Non_Blank_Location);
 634       end if;
 635
 636       Scope.Table (Scope.Last).Junk := False;
 637       Scope.Table (Scope.Last).Node := Empty;
 638
 639       if Debug_Flag_P then
 640          Error_Msg_Uint_1 := UI_From_Int (Scope.Last);
 641          Error_Msg_SC ("increment scope stack ptr, new value = ^!");
 642       end if;
 643    end Push_Scope_Stack;
 644
 645    ----------------------
 646    -- Separate_Present --
 647    ----------------------
 648
 649    function Separate_Present return Boolean is
 650       Scan_State : Saved_Scan_State;
 651
 652    begin
 653       if Token = Tok_Separate then
 654          return True;
 655
 656       elsif Token /= Tok_Identifier then
 657          return False;
 658
 659       else
 660          Save_Scan_State (Scan_State);
 661          Scan; -- past identifier
 662
 663          if Token = Tok_Semicolon then
 664             Restore_Scan_State (Scan_State);
 665             return Bad_Spelling_Of (Tok_Separate);
 666
 667          else
 668             Restore_Scan_State (Scan_State);
 669             return False;
 670          end if;
 671       end if;
 672    end Separate_Present;
 673
 674    --------------------------
 675    -- Signal_Bad_Attribute --
 676    --------------------------
 677
 678    procedure Signal_Bad_Attribute is
 679    begin
 680       Error_Msg_N ("unrecognized attribute&", Token_Node);
 681
 682       --  Check for possible misspelling
 683
 684       Get_Name_String (Token_Name);
 685
 686       declare
 687          AN : constant String := Name_Buffer (1 .. Name_Len);
 688
 689       begin
 690          Error_Msg_Name_1 := First_Attribute_Name;
 691          while Error_Msg_Name_1 <= Last_Attribute_Name loop
 692             Get_Name_String (Error_Msg_Name_1);
 693
 694             if Is_Bad_Spelling_Of
 695                  (AN, Name_Buffer (1 .. Name_Len))
 696             then
 697                Error_Msg_N
 698                  ("\possible misspelling of %", Token_Node);
 699                exit;
 700             end if;
 701
 702             Error_Msg_Name_1 := Error_Msg_Name_1 + 1;
 703          end loop;
 704       end;
 705    end Signal_Bad_Attribute;
 706
 707    -----------------------------
 708    -- Token_Is_At_End_Of_Line --
 709    -----------------------------
 710
 711    function Token_Is_At_End_Of_Line return Boolean is
 712       S : Source_Ptr;
 713
 714    begin
 715       --  Skip past blanks and horizontal tabs
 716
 717       S := Scan_Ptr;
 718       while Source (S) = ' ' or else Source (S) = ASCII.HT loop
 719          S := S + 1;
 720       end loop;
 721
 722       --  We are at end of line if at a control character (CR/LF/VT/FF/EOF)
 723       --  or if we are at the start of an end of line comment sequence.
 724
 725       return Source (S) < ' '
 726         or else (Source (S) = '-' and then Source (S + 1) = '-');
 727    end Token_Is_At_End_Of_Line;
 728
 729    -------------------------------
 730    -- Token_Is_At_Start_Of_Line --
 731    -------------------------------
 732
 733    function Token_Is_At_Start_Of_Line return Boolean is
 734    begin
 735       return (Token_Ptr = First_Non_Blank_Location or else Token = Tok_EOF);
 736    end Token_Is_At_Start_Of_Line;
 737
 738 end Util;