libbacktrace/configure.ac

   1 # configure.ac -- Backtrace configure script.
   2 # Copyright (C) 2012 Free Software Foundation, Inc.
   3
   4 # Redistribution and use in source and binary forms, with or without
   5 # modification, are permitted provided that the following conditions are
   6 # met:
   7
   8 #     (1) Redistributions of source code must retain the above copyright
   9 #     notice, this list of conditions and the following disclaimer.
  10
  11 #     (2) Redistributions in binary form must reproduce the above copyright
  12 #     notice, this list of conditions and the following disclaimer in
  13 #     the documentation and/or other materials provided with the
  14 #     distribution.
  15
  16 #     (3) The name of the author may not be used to
  17 #     endorse or promote products derived from this software without
  18 #     specific prior written permission.
  19
  20 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  21 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  22 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  23 # DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT,
  24 # INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  25 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  26 # SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
  28 # STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING
  29 # IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  30 # POSSIBILITY OF SUCH DAMAGE.
  31
  32 AC_PREREQ(2.64)
  33 AC_INIT(package-unused, version-unused,, libbacktrace)
  34 AC_CONFIG_SRCDIR(backtrace.h)
  35 AC_CONFIG_HEADER(config.h)
  36
  37 AC_CANONICAL_SYSTEM
  38 target_alias=${target_alias-$host_alias}
  39
  40 AC_USE_SYSTEM_EXTENSIONS
  41
  42 libtool_VERSION=1:0:0
  43 AC_SUBST(libtool_VERSION)
  44
  45 # 1.11.1: Require that version of automake.
  46 # foreign: Don't require README, INSTALL, NEWS, etc.
  47 # no-define: Don't define PACKAGE and VERSION.
  48 # no-dependencies: Don't generate automatic dependencies.
  49 #    (because it breaks when using bootstrap-lean, since some of the
  50 #    headers are gone at "make install" time).
  51 # -Wall: Issue all automake warnings.
  52 # -Wno-portability: Don't warn about constructs supported by GNU make.
  53 #    (because GCC requires GNU make anyhow).
  54 AM_INIT_AUTOMAKE([1.11.1 foreign no-dist no-define no-dependencies -Wall -Wno-portability])
  55
  56 AM_MAINTAINER_MODE
  57
  58 AC_ARG_WITH(target-subdir,
  59 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  60
  61 # We must force CC to /not/ be precious variables; otherwise
  62 # the wrong, non-multilib-adjusted value will be used in multilibs.
  63 # As a side effect, we have to subst CFLAGS ourselves.
  64 m4_rename([_AC_ARG_VAR_PRECIOUS],[backtrace_PRECIOUS])
  65 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  66 AC_PROG_CC
  67 m4_rename_force([backtrace_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  68
  69 AC_SUBST(CFLAGS)
  70
  71 AC_PROG_RANLIB
  72
  73 AC_PROG_AWK
  74 case "$AWK" in
  75 "") AC_MSG_ERROR([can't build without awk]) ;;
  76 esac
  77
  78 LT_INIT([disable-shared])
  79 AM_PROG_LIBTOOL
  80
  81 backtrace_supported=yes
  82
  83 if test -n "${with_target_subdir}"; then
  84   # We are compiling a GCC library.  We can assume that the unwind
  85   # library exists.
  86   AM_ENABLE_MULTILIB(, ..)
  87   BACKTRACE_FILE="backtrace.lo simple.lo"
  88 else
  89   AC_CHECK_HEADER([unwind.h],
  90     [AC_CHECK_FUNC([_Unwind_Backtrace],
  91                    [BACKTRACE_FILE="backtrace.lo simple.lo"],
  92                    [BACKTRACE_FILE="nounwind.lo"
  93                     backtrace_supported=no])],
  94     [BACKTRACE_FILE="nounwind.lo"
  95      backtrace_supported=no])
  96 fi
  97 AC_SUBST(BACKTRACE_FILE)
  98
  99 EXTRA_FLAGS=
 100 if test "x$GCC" = "xyes"; then
 101   EXTRA_FLAGS=-funwind-tables
 102 fi
 103 AC_SUBST(EXTRA_FLAGS)
 104
 105 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
 106                           -Wmissing-prototypes -Wold-style-definition \
 107                           -Wmissing-format-attribute -Wcast-qual],
 108                           [WARN_FLAGS])
 109
 110 if test "x$GCC" = "xyes"; then
 111   WARN_FLAGS="$WARN_FLAGS -Werror"
 112 fi
 113
 114 AC_SUBST(WARN_FLAGS)
 115
 116 if test -n "${with_target_subdir}"; then
 117   GCC_CHECK_UNWIND_GETIPINFO
 118 else
 119   AC_CHECK_FUNC(_Unwind_GetIPInfo, [have_unwind_getipinfo=yes],
 120                 [have_unwind_getipinfo=no])
 121   if test "$have_unwind_getipinfo" = "yes"; then
 122     AC_DEFINE(HAVE_GETIPINFO, 1, [Define if _Unwind_GetIPInfo is available.])
 123   fi
 124 fi
 125
 126 # When building as a target library, shared libraries may want to link
 127 # this in.  We don't want to provide another shared library to
 128 # complicate dependencies.  Instead, we just compile with -fPIC.
 129 PIC_FLAG=
 130 if test -n "${with_target_subdir}"; then
 131   PIC_FLAG=-fPIC
 132 fi
 133 AC_SUBST(PIC_FLAG)
 134
 135 # Test for __sync support.
 136 AC_CACHE_CHECK([__sync extensions],
 137 [libbacktrace_cv_sys_sync],
 138 [if test -n "${with_target_subdir}"; then
 139    libbacktrace_cv_sys_sync=yes
 140  else
 141    AC_LINK_IFELSE(
 142      [AC_LANG_PROGRAM([int i;],
 143                       [__sync_bool_compare_and_swap (&i, i, i);
 144                        __sync_lock_test_and_set (&i, 1);
 145                        __sync_lock_release (&i);])],
 146      [libbacktrace_cv_sys_sync=yes],
 147      [libbacktrace_cv_sys_sync=no])
 148  fi])
 149 BACKTRACE_SUPPORTS_THREADS=0
 150 if test "$libbacktrace_cv_sys_sync" = "yes"; then
 151   BACKTRACE_SUPPORTS_THREADS=1
 152   AC_DEFINE([HAVE_SYNC_FUNCTIONS], 1,
 153             [Define to 1 if you have the __sync functions])
 154 fi
 155 AC_SUBST(BACKTRACE_SUPPORTS_THREADS)
 156
 157 # The library needs to be able to read the executable itself.  Compile
 158 # a file to determine the executable format.  The awk script
 159 # filetype.awk prints out the file type.
 160 AC_CACHE_CHECK([output filetype],
 161 [libbacktrace_cv_sys_filetype],
 162 [filetype=
 163 AC_COMPILE_IFELSE(
 164   [AC_LANG_PROGRAM([int i;], [int j;])],
 165   [filetype=`${AWK} -f $srcdir/filetype.awk conftest.$ac_objext`],
 166   [AC_MSG_FAILURE([compiler failed])])
 167 libbacktrace_cv_sys_filetype=$filetype])
 168
 169 # Match the file type to decide what files to compile.
 170 FORMAT_FILE=
 171 case "$libbacktrace_cv_sys_filetype" in
 172 elf*) FORMAT_FILE="elf.lo" ;;
 173 *) AC_MSG_WARN([could not determine output file type])
 174    FORMAT_FILE="unknown.lo"
 175    backtrace_supported=no
 176    ;;
 177 esac
 178 AC_SUBST(FORMAT_FILE)
 179
 180 # ELF defines.
 181 elfsize=
 182 case "$libbacktrace_cv_sys_filetype" in
 183 elf32) elfsize=32 ;;
 184 elf64) elfsize=64 ;;
 185 esac
 186 AC_DEFINE_UNQUOTED([BACKTRACE_ELF_SIZE], [$elfsize], [ELF size: 32 or 64])
 187
 188 BACKTRACE_SUPPORTED=0
 189 if test "$backtrace_supported" = "yes"; then
 190   BACKTRACE_SUPPORTED=1
 191 fi
 192 AC_SUBST(BACKTRACE_SUPPORTED)
 193
 194 GCC_HEADER_STDINT(gstdint.h)
 195
 196 AC_CHECK_HEADERS(sys/mman.h)
 197 if test "$ac_cv_header_sys_mman_h" = "no"; then
 198   have_mmap=no
 199 else
 200   if test -n "${with_target_subdir}"; then
 201     # When built as a GCC target library, we can't do a link test.  We
 202     # simply assume that if we have mman.h, we have mmap.
 203     have_mmap=yes
 204   else
 205     AC_CHECK_FUNC(mmap, [have_mmap=yes], [have_mmap=no])
 206   fi
 207 fi
 208 if test "$have_mmap" = "no"; then
 209   VIEW_FILE=read.lo
 210   ALLOC_FILE=alloc.lo
 211 else
 212   VIEW_FILE=mmapio.lo
 213   AC_PREPROC_IFELSE([
 214 #include <sys/mman.h>
 215 #if !defined(MAP_ANONYMOUS) && !defined(MAP_ANON)
 216   #error no MAP_ANONYMOUS
 217 #endif
 218 ], [ALLOC_FILE=mmap.lo], [ALLOC_FILE=alloc.lo])
 219 fi
 220 AC_SUBST(VIEW_FILE)
 221 AC_SUBST(ALLOC_FILE)
 222
 223 BACKTRACE_USES_MALLOC=0
 224 if test "$ALLOC_FILE" = "alloc.lo"; then
 225   BACKTRACE_USES_MALLOC=1
 226 fi
 227 AC_SUBST(BACKTRACE_USES_MALLOC)
 228
 229 # Check for the fcntl function.
 230 if test -n "${with_target_subdir}"; then
 231    case "${host}" in
 232    *-*-mingw*) have_fcntl=no ;;
 233    *) have_fcntl=yes ;;
 234    esac
 235 else
 236   AC_CHECK_FUNC(fcntl, [have_fcntl=yes], [have_fcntl=no])
 237 fi
 238 if test "$have_fcntl" = "yes"; then
 239   AC_DEFINE([HAVE_FCNTL], 1,
 240             [Define to 1 if you have the fcntl function])
 241 fi
 242
 243 AC_CHECK_DECLS(strnlen)
 244
 245 AC_CACHE_CHECK([whether tests can run],
 246   [libbacktrace_cv_sys_native],
 247   [AC_RUN_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 248      [libbacktrace_cv_sys_native=yes],
 249      [libbacktrace_cv_sys_native=no],
 250      [libbacktrace_cv_sys_native=no])])
 251 AM_CONDITIONAL(NATIVE, test "$libbacktrace_cv_sys_native" = "yes")
 252
 253 if test "${multilib}" = "yes"; then
 254   multilib_arg="--enable-multilib"
 255 else
 256   multilib_arg=
 257 fi
 258
 259 AC_CONFIG_FILES(Makefile backtrace-supported.h)
 260
 261 # We need multilib support, but only if configuring for the target.
 262 AC_CONFIG_COMMANDS([default],
 263 [if test -n "$CONFIG_FILES"; then
 264    if test -n "${with_target_subdir}"; then
 265      # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 266      # that multilib installs will end up installed in the correct place.
 267      # The testsuite needs it for multilib-aware ABI baseline files.
 268      # To work around this not being passed down from config-ml.in ->
 269      # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 270      # append it here.  Only modify Makefiles that have just been created.
 271      #
 272      # Also, get rid of this simulated-VPATH thing that automake does.
 273      cat > vpsed << \_EOF
 274   s!`test -f '$<' || echo '$(srcdir)/'`!!
 275 _EOF
 276      for i in $SUBDIRS; do
 277       case $CONFIG_FILES in
 278        *${i}/Makefile*)
 279          #echo "Adding MULTISUBDIR to $i/Makefile"
 280          sed -f vpsed $i/Makefile > tmp
 281          grep '^MULTISUBDIR =' Makefile >> tmp
 282          mv tmp $i/Makefile
 283          ;;
 284       esac
 285      done
 286      rm vpsed
 287    fi
 288  fi
 289 ],
 290 [
 291 # Variables needed in config.status (file generation) which aren't already
 292 # passed by autoconf.
 293 SUBDIRS="$SUBDIRS"
 294 ])
 295
 296 AC_OUTPUT