www-client/netsurf/netsurf-3.2.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 NETSURF_COMPONENT_TYPE=binary
   6 NETSURF_BUILDSYSTEM="buildsystem-1.2"
   7
   8 inherit netsurf
   9
  10 DESCRIPTION="a free, open source web browser"
  11 HOMEPAGE="http://www.netsurf-browser.org/"
  12 SRC_URI="http://download.netsurf-browser.org/netsurf/releases/source/${P}-src.tar.gz
  13         http://xmw.de/mirror/netsurf-fb.modes-example.gz
  14         ${NETSURF_BUILDSYSTEM_SRC_URI}"
  15
  16 LICENSE="GPL-2 MIT"
  17 SLOT="0"
  18 KEYWORDS="~amd64 ~arm"
  19 IUSE="+bmp fbcon truetype +gif gstreamer gtk javascript +jpeg +mng pdf-writer
  20         +png +rosprite +svg +svgtiny +webp fbcon_frontend_able fbcon_frontend_linux
  21         fbcon_frontend_sdl fbcon_frontend_vnc fbcon_frontend_x"
  22
  23 REQUIRED_USE="|| ( fbcon gtk )
  24         amd64? ( abi_x86_32? (
  25                 !gstreamer !javascript !pdf-writer svg? ( svgtiny ) !truetype ) )
  26         fbcon? ( ^^ ( fbcon_frontend_able fbcon_frontend_linux fbcon_frontend_sdl
  27                 fbcon_frontend_vnc fbcon_frontend_x ) )"
  28
  29 RDEPEND="dev-libs/libxml2
  30         net-misc/curl
  31         >=dev-libs/libcss-0.4.0[${MULTILIB_USEDEP}]
  32         >=net-libs/libhubbub-0.3.0[${MULTILIB_USEDEP}]
  33         bmp? ( >=media-libs/libnsbmp-0.1.1[${MULTILIB_USEDEP}] )
  34         fbcon? ( >=dev-libs/libnsfb-0.1.2[${MULTILIB_USEDEP}]
  35                 truetype? ( media-fonts/dejavu
  36                         >=media-libs/freetype-2.5.0.1[${MULTILIB_USEDEP}] )
  37         )
  38         gif? ( >=media-libs/libnsgif-0.1.1[${MULTILIB_USEDEP}] )
  39         gtk? ( >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
  40                 gnome-base/libglade:2.0
  41                 >=media-libs/lcms-1.19-r1:0[${MULTILIB_USEDEP}]
  42                 >=x11-libs/gtk+-2.24.23:2[${MULTILIB_USEDEP}] )
  43         gstreamer? ( media-libs/gstreamer:0.10 )
  44         javascript? ( >=dev-libs/nsgenbind-0.1.0 =dev-lang/spidermonkey-1.8.5-r4[${MULTILIB_USEDEP}] )
  45         jpeg? ( >=virtual/jpeg-0-r2[${MULTILIB_USEDEP}] )
  46         mng? ( >=media-libs/libmng-1.0.10-r2[${MULTILIB_USEDEP}] )
  47         pdf-writer? ( media-libs/libharu )
  48         png? ( >=media-libs/libpng-1.2.51[${MULTILIB_USEDEP}] )
  49         svg? ( svgtiny? ( >=media-libs/libsvgtiny-0.1.2[${MULTILIB_USEDEP}] )
  50                 !svgtiny? ( gnome-base/librsvg:2 ) )
  51         webp? ( >=media-libs/libwebp-0.3.0[${MULTILIB_USEDEP}] )"
  52 DEPEND="${RDEPEND}
  53         javascript? ( >=dev-libs/nsgenbind-0.1.1 )
  54         rosprite? ( >=media-libs/librosprite-0.1.1[${MULTILIB_USEDEP}] )"
  55
  56 PATCHES=( "${FILESDIR}"/${P}-CFLAGS.patch
  57         "${FILESDIR}"/${P}-framebuffer-pkgconfig.patch
  58         "${FILESDIR}"/${P}-add-mona-family.patch
  59         "${FILESDIR}"/${P}-reenable-glib-deprecated.patch
  60 )
  61 DOCS=( fb.modes README Docs/USING-Framebuffer
  62         Docs/ideas/{cache,css-engine,render-library}.txt )
  63
  64 src_prepare() {
  65         rm -rf amiga atari beos cocoa monkey riscos windows  || die
  66
  67         mv "${WORKDIR}"/netsurf-fb.modes-example fb.modes
  68
  69         netsurf_src_prepare
  70 }
  71
  72 src_configure() {
  73         netsurf_src_configure
  74
  75         netsurf_makeconf+=(
  76                 NETSURF_USE_BMP=$(usex bmp YES NO)
  77                 NETSURF_USE_GIF=$(usex gif YES NO)
  78                 NETSURF_USE_JPEG=$(usex jpeg YES NO)
  79                 NETSURF_USE_PNG=$(usex png YES NO)
  80                 NETSURF_USE_PNG=$(usex png YES NO)
  81                 NETSURF_USE_MNG=$(usex mng YES NO)
  82                 NETSURF_USE_WEBP=$(usex webp YES NO)
  83                 NETSURF_USE_VIDEO=$(usex gstreamer YES NO)
  84                 NETSURF_USE_MOZJS=$(usex javascript YES NO)
  85                 NETSURF_USE_JS=NO
  86                 NETSURF_USE_HARU_PDF=$(usex pdf-writer YES NO)
  87                 NETSURF_USE_NSSVG=$(usex svg $(usex svgtiny YES NO) NO)
  88                 NETSURF_USE_RSVG=$(usex svg $(usex svgtiny NO YES) NO)
  89                 NETSURF_USE_ROSPRITE=$(usex rosprite YES NO)
  90                 PKG_CONFIG=$(tc-getPKG_CONFIG)
  91                 $(usex fbcon_frontend_able  NETSURF_FB_FRONTEND=able  "")
  92                 $(usex fbcon_frontend_linux NETSURF_FB_FRONTEND=linux "")
  93                 $(usex fbcon_frontend_sdl   NETSURF_FB_FRONTEND=sdl   "")
  94                 $(usex fbcon_frontend_vnc   NETSURF_FB_FRONTEND=vnc   "")
  95                 $(usex fbcon_frontend_x     NETSURF_FB_FRONTEND=x     "")
  96                 NETSURF_FB_FONTLIB=$(usex truetype freetype internal)
  97                 NETSURF_FB_FONTPATH=${EROOT}usr/share/fonts/dejavu
  98                 TARGET=dummy
  99         )
 100 }
 101
 102 src_compile() {
 103         if use fbcon ; then
 104                 netsurf_makeconf=( "${netsurf_makeconf[@]/TARGET=*/TARGET=framebuffer}" )
 105                 netsurf_src_compile
 106         fi
 107         if use gtk ; then
 108                 netsurf_makeconf=( "${netsurf_makeconf[@]/TARGET=*/TARGET=gtk}" )
 109                 netsurf_src_compile
 110         fi
 111 }
 112
 113 src_install() {
 114         sed -e '1iexit;' \
 115                 -i "${WORKDIR}"/*/utils/git-testament.pl || die
 116
 117         if use fbcon ; then
 118                 netsurf_makeconf=( "${netsurf_makeconf[@]/TARGET=*/TARGET=framebuffer}" )
 119                 netsurf_src_install
 120                 elog "framebuffer binary has been installed as netsurf-fb"
 121                 mv -v "${ED}"usr/bin/netsurf{,-fb} || die
 122                 make_desktop_entry "${EROOT}"usr/bin/netsurf-fb NetSurf-framebuffer netsurf "Network;WebBrowser"
 123
 124                 elog "In order to setup the framebuffer console, netsurf needs an /etc/fb.modes"
 125                 elog "You can use an example from /usr/share/doc/${PF}/fb.modes.* (bug 427092)."
 126                 elog "Please make /etc/input/mice readable to the account using netsurf-fb."
 127                 elog "Either use chmod a+r /etc/input/mice (security!!!) or use an group."
 128         fi
 129         if use gtk ; then
 130                 netsurf_makeconf=( "${netsurf_makeconf[@]/TARGET=*/TARGET=gtk}" )
 131                 netsurf_src_install
 132                 elog "netsurf gtk version has been installed as netsurf-gtk"
 133                 mv -v "${ED}"/usr/bin/netsurf{,-gtk} || die
 134                 make_desktop_entry "${EROOT}"usr/bin/netsurf-gtk NetSurf-gtk netsurf "Network;WebBrowser"
 135         fi
 136
 137         insinto /usr/share/pixmaps
 138         doins gtk/res/netsurf.xpm
 139 }