trafgen_lexer.l

   1 /*
   2  * netsniff-ng - the packet sniffing beast
   3  * By Daniel Borkmann <daniel@netsniff-ng.org>
   4  * Copyright 2012 Daniel Borkmann <dborkma@tik.ee.ethz.ch>,
   5  * Swiss federal institute of technology (ETH Zurich)
   6  * Subject to the GPL, version 2.
   7  */
   8
   9 /* lex-func-prefix: yy */
  10
  11 %{
  12
  13 #include <stdio.h>
  14 #include <stdlib.h>
  15 #include <string.h>
  16 #include <ctype.h>
  17 #include <stdbool.h>
  18 #include <arpa/inet.h>
  19
  20 #include "trafgen_parser.tab.h"
  21 #include "xmalloc.h"
  22 #include "built_in.h"
  23 #include "str.h"
  24
  25 extern void yyerror(const char *);
  26
  27 static char *try_convert_shellcode(char *sstr)
  28 {
  29         bool found_any = false;
  30         char *bstr, *ostr = sstr, *hay, *orig = sstr;
  31         size_t j = 0, blen, slen = strlen(sstr), tot = 0;
  32         const char *needle = "\\x";
  33
  34         sstr++;
  35         slen -= 2;
  36
  37         if (slen % 4 != 0)
  38                 return orig;
  39
  40         blen = slen / 4;
  41         hay = sstr;
  42         while ((hay = strstr(hay, needle)) != NULL ) {
  43                 hay += strlen(needle) + 2;
  44                 found_any = true;
  45                 tot++;
  46         }
  47
  48         if (blen != tot || !found_any)
  49                 return orig;
  50
  51         blen += 2;
  52         bstr = xzmalloc(blen);
  53
  54         bstr[j++] = '\"';
  55         while (j < blen - 1)
  56                 bstr[j++] = (uint8_t) strtoul(sstr + 2, &sstr, 16);
  57         bstr[j++] = '\"';
  58
  59         xfree(ostr);
  60         return bstr;
  61 }
  62
  63 %}
  64
  65 %option align
  66 %option nounput
  67 %option noyywrap
  68 %option noreject
  69 %option 8bit
  70 %option caseless
  71 %option noinput
  72 %option nodefault
  73
  74 number_oct      ([0][0-9]+)
  75 number_hex      ([0]?[x][a-fA-F0-9]+)
  76 number_bin      ([0]?[b][0-1]+)
  77 number_dec      (([0])|([1-9][0-9]*))
  78 number_ascii    ([a-zA-Z])
  79
  80 mac_hex         ([a-fA-F0-9]+)
  81 mac             ({mac_hex}:{mac_hex}:{mac_hex}:{mac_hex}:{mac_hex}:{mac_hex})
  82 ip_addr         ([0-9]+\.[0-9]+\.[0-9]+\.[0-9]+)
  83
  84 %%
  85
  86 "cpu"           { return K_CPU; }
  87 "fill"          { return K_FILL; }
  88 "rnd"           { return K_RND; }
  89 "csum16"        { return K_CSUMIP; }
  90 "csumip"        { return K_CSUMIP; }
  91 "csumip4"       { return K_CSUMIP; }
  92 "csumicmp"      { return K_CSUMIP; }
  93 "csumicmp4"     { return K_CSUMIP; }
  94 "csumudp"       { return K_CSUMUDP; }
  95 "csumtcp"       { return K_CSUMTCP; }
  96 "csumudp6"      { return K_CSUMUDP6; }
  97 "csumtcp6"      { return K_CSUMTCP6; }
  98 "drnd"          { return K_DRND; }
  99 "dinc"          { return K_DINC; }
 100 "ddec"          { return K_DDEC; }
 101 "seqinc"        { return K_SEQINC; }
 102 "seqdec"        { return K_SEQDEC; }
 103 "const8"|"c8"   { return K_CONST8; }
 104 "const16"|"c16" { return K_CONST16; }
 105 "const32"|"c32" { return K_CONST32; }
 106 "const64"|"c64" { return K_CONST64; }
 107
 108 "daddr"|"da"    { return K_DADDR; }
 109 "saddr"|"sa"    { return K_SADDR; }
 110 "prot"[o]?      { return K_PROT; }
 111
 112 "sha"|"smac"    { return K_SHA; }
 113 "spa"|"sip"     { return K_SPA; }
 114 "tha"|"tmac"    { return K_THA; }
 115 "tpa"|"tip"     { return K_TPA; }
 116 "req"|"request" { return K_REQUEST; }
 117 "reply"         { return K_REPLY; }
 118 "op"|"oper"     { return K_OPER; }
 119 "htype"         { return K_HTYPE; }
 120 "ptype"         { return K_PTYPE; }
 121
 122 "ihl"           { return K_IHL; }
 123 "ver"|"version" { return K_VER; }
 124 "ttl"           { return K_TTL; }
 125 "dscp"          { return K_DSCP; }
 126 "ecn"           { return K_ECN; }
 127 "tos"           { return K_TOS; }
 128 "len"|"length"  { return K_LEN; }
 129 "id"            { return K_ID; }
 130 "flags"         { return K_FLAGS; }
 131 "frag"          { return K_FRAG; }
 132 "csum"          { return K_CSUM; }
 133 "df"            { return K_DF; }
 134 "mf"            { return K_MF; }
 135
 136 "eth"           { return K_ETH; }
 137 "arp"           { return K_ARP; }
 138 "ip4"|"ipv4"    { return K_IP4; }
 139
 140 [ ]*"-"[ ]*     { return '-'; }
 141 [ ]*"+"[ ]*     { return '+'; }
 142 [ ]*"*"[ ]*     { return '*'; }
 143 [ ]*"/"[ ]*     { return '/'; }
 144 [ ]*"%"[ ]*     { return '%'; }
 145 [ ]*"&"[ ]*     { return '&'; }
 146 [ ]*"|"[ ]*     { return '|'; }
 147 [ ]*"<"[ ]*     { return '<'; }
 148 [ ]*">"[ ]*     { return '>'; }
 149 [ ]*"^"[ ]*     { return '^'; }
 150 "{"             { return '{'; }
 151 "}"             { return '}'; }
 152 "("             { return '('; }
 153 ")"             { return ')'; }
 154 "["             { return '['; }
 155 "]"             { return ']'; }
 156 ","             { return ','; }
 157 ":"             { return ':'; }
 158 "="             { return '='; }
 159
 160 "\n"            { yylineno++; }
 161
 162 "\""[^\"]+"\""  { yylval.str = try_convert_shellcode(xstrdup(yytext));
 163                   return string; }
 164
 165 ([ \t\n]+)?     { return K_WHITE; }
 166
 167 "/*"([^\*]|\*[^/])*"*/" { return K_COMMENT; }
 168
 169 "#"[^\n]*       { return K_COMMENT; }
 170
 171 {number_hex}    { yylval.number = strtoul(yytext + (yytext[0] == 'x' ? 1 : 0),
 172                                           NULL, 16);
 173                   return number; }
 174
 175 {number_dec}    { yylval.number = strtol(yytext, NULL, 10);
 176                   return number; }
 177
 178 {number_oct}    { yylval.number = strtol(yytext + 1, NULL, 8);
 179                   return number; }
 180
 181 {number_bin}    { yylval.number = strtol(yytext + (yytext[0] == 'b' ? 1 : 2),
 182                                          NULL, 2);
 183                   return number; }
 184
 185 {number_ascii}  { yylval.number = (uint8_t) (*yytext);
 186                   return number; }
 187
 188 {mac}           { if (str2mac(yytext, yylval.bytes, 256))
 189                         panic("Failed to parse MAC address %s\n", yytext);
 190                   return mac; }
 191
 192 {ip_addr}       { if (inet_pton(AF_INET, yytext, &yylval.ip_addr) != 1)
 193                         panic("Failed to parse IPv4 address %s\n", yytext);
 194                   return ip_addr; };
 195
 196 "'\\x"[a-fA-F0-9]{2}"'" { yylval.number = strtol(yytext + 3, NULL, 16);
 197                   return number; }
 198
 199 "'"."'"         { yylval.number = (uint8_t) (*(yytext + 1));
 200                   return number; }
 201
 202 ";"[^\n]*       {/* NOP */}
 203 .               { printf("Unknown character '%s'", yytext);
 204                   yyerror("lex Unknown character"); }
 205
 206 %%