usr.bin/mkcsmapper/lex.l

   1 /*      $NetBSD: lex.l,v 1.5 2009/10/28 22:09:02 christos Exp $ */
   2
   3 %{
   4 /*-
   5  * Copyright (c)2003 Citrus Project,
   6  * All rights reserved.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  */
  29
  30 #if HAVE_NBTOOL_CONFIG_H
  31 #include "nbtool_config.h"
  32 #endif
  33
  34 #include <sys/cdefs.h>
  35 #if !defined(lint)
  36 __RCSID("$NetBSD: lex.l,v 1.5 2009/10/28 22:09:02 christos Exp $");
  37 #endif /* not lint */
  38
  39 #include <assert.h>
  40 #include <errno.h>
  41 #include <limits.h>
  42 #include <stdio.h>
  43 #include <stdlib.h>
  44 #include <string.h>
  45 #include <machine/endian.h>
  46
  47 #include "ldef.h"
  48 #include "yacc.h"
  49
  50 int line_number = 1;
  51
  52
  53 %}
  54
  55 %option noinput nounput
  56
  57 %x      COMMENT
  58
  59 %%
  60
  61 [ \t]+  { }
  62 #.*[\n]|"//".*[\n]|[\n] { line_number++; return (R_LN); }
  63
  64 "/*"            { BEGIN COMMENT; }
  65 <COMMENT>"*/"   { BEGIN 0; }
  66 <COMMENT>[\n]   { line_number++; }
  67 <COMMENT>.      { }
  68 <COMMENT><<EOF>>        {
  69                 yyerror("unexpected file end (unterminate comment)\n");
  70                 exit(1);
  71         }
  72
  73 "="|"/"|"-"     { return (int)yytext[0]; }
  74
  75 ([1-9][0-9]*)|(0[0-9]*)|(0[xX][0-9A-Fa-f]+)     {
  76                 yylval.i_value = strtoul(yytext, NULL, 0);
  77                 return L_IMM;
  78         }
  79
  80 "TYPE"          { return (R_TYPE); }
  81 "NAME"          { return (R_NAME); }
  82 "SRC_ZONE"      { return (R_SRC_ZONE); }
  83 "DST_INVALID"   { return (R_DST_INVALID); }
  84 "DST_ILSEQ"     { return (R_DST_ILSEQ); }
  85 "DST_UNIT_BITS" { return (R_DST_UNIT_BITS); }
  86 "BEGIN_MAP"     { return (R_BEGIN_MAP); }
  87 "END_MAP"       { return (R_END_MAP); }
  88 "INVALID"       { return (R_INVALID); }
  89 "ILSEQ"         { return (R_ILSEQ); }
  90 "OOB_MODE"      { return (R_OOB_MODE); }
  91 "ROWCOL"        { return (R_ROWCOL); }
  92
  93 \"([^\"\n]*(\\\")?)*\"|\'([^\'\n]*(\\\')?)*\'   {
  94                 size_t len;
  95                 len = strlen(yytext);
  96                 yylval.s_value = malloc(len-1);
  97                 strlcpy(yylval.s_value, yytext+1, len-1);
  98                 return L_STRING;
  99         }
 100 [^ =/\-0-9\t\n][^ \t\n]*        {
 101                 yylval.s_value = strdup(yytext);
 102                 return L_STRING;
 103         }
 104
 105 %%
 106
 107 #ifndef yywrap
 108 int
 109 yywrap(void)
 110 {
 111         return (1);
 112 }
 113 #endif