configure.ac

   1 AC_INIT(configure.ac)
   2
   3 AC_CONFIG_HEADERS(config.h)
   4 AM_INIT_AUTOMAKE(ncmpcpp, 0.6.5)
   5
   6 AC_PREREQ(2.59)
   7
   8 AC_LANG_CPLUSPLUS
   9 AC_PROG_CXX
  10 AM_PROG_LIBTOOL
  11
  12 AC_ARG_ENABLE(outputs, AS_HELP_STRING([--enable-outputs], [Enable outputs screen @<:@default=no@:>@]), [outputs=$enableval], [outputs=no])
  13 AC_ARG_ENABLE(visualizer, AS_HELP_STRING([--enable-visualizer], [Enable music visualizer screen @<:@default=no@:>@]), [visualizer=$enableval], [visualizer=no])
  14 AC_ARG_ENABLE(clock, AS_HELP_STRING([--enable-clock], [Enable clock screen @<:@default=no@:>@]), [clock=$enableval], [clock=no])
  15 AC_ARG_ENABLE(unicode, AS_HELP_STRING([--enable-unicode], [Enable utf8 support @<:@default=yes@:>@]), [unicode=$enableval], [unicode=yes])
  16 AC_ARG_WITH(curl, AS_HELP_STRING([--with-curl], [Enable fetching lyrics from the Internet @<:@default=auto@:>@]), [curl=$withval], [curl=auto])
  17 AC_ARG_WITH(fftw, AS_HELP_STRING([--with-fftw], [Enable fftw support (required for frequency spectrum vizualization) @<:@default=auto@:>@]), [fftw=$withval], [fftw=auto])
  18 AC_ARG_WITH(pdcurses, AS_HELP_STRING([--with-pdcurses[=LIBNAME]], [Link against pdcurses instead of ncurses @<:@default=XCurses@:>@]), [pdcurses=$withval], [pdcurses=no])
  19 AC_ARG_WITH(taglib, AS_HELP_STRING([--with-taglib], [Enable tag editor @<:@default=auto@:>@]), [taglib=$withval], [taglib=auto])
  20
  21 if test "$outputs" = "yes"; then
  22         AC_DEFINE([ENABLE_OUTPUTS], [1], [enables outputs screen])
  23 fi
  24
  25 if test "$clock" = "yes"; then
  26         AC_DEFINE([ENABLE_CLOCK], [1], [enables clock screen])
  27 fi
  28
  29 dnl ================================
  30 dnl = checking for -std=c++0x flag =
  31 dnl ================================
  32 AC_MSG_CHECKING([whether compiler supports -std=c++0x])
  33 old_CXXFLAGS="$CXXFLAGS"
  34 CXXFLAGS="-std=c++0x"
  35 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ ]])],
  36         AC_MSG_RESULT([yes])
  37                 std_cpp0x="-std=c++0x",
  38         AC_MSG_RESULT([no])
  39                 AC_MSG_ERROR([[Your compiler doesn't seem to support C++0x, please upgrade (GCC >= 4.6)]])
  40 )
  41 CXXFLAGS="$old_CXXFLAGS $std_cpp0x"
  42
  43 dnl ==========================================
  44 dnl = checking for initializer lists support =
  45 dnl ==========================================
  46 AC_MSG_CHECKING([whether compiler supports initializer lists])
  47 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <vector>], [[std::vector<int> test = { 1, 2, 3 }; test.push_back(4);]])],
  48         AC_MSG_RESULT([yes]),
  49         AC_MSG_RESULT([no])
  50                 AC_MSG_ERROR([[Your compiler doesn't seem to support initializer lists, please upgrade (GCC >= 4.6)]])
  51 )
  52
  53 dnl =====================================
  54 dnl = checking for auto keyword support =
  55 dnl =====================================
  56 AC_MSG_CHECKING([whether compiler supports auto keyword])
  57 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[auto test = new int; *test = 1;]])],
  58         AC_MSG_RESULT([yes]),
  59         AC_MSG_RESULT([no])
  60                 AC_MSG_ERROR([[Your compiler doesn't seem to support auto keyword, please upgrade (GCC >= 4.6)]])
  61 )
  62
  63 dnl =========================================
  64 dnl = checking for lambda functions support =
  65 dnl =========================================
  66 AC_MSG_CHECKING([whether compiler supports lambda functions])
  67 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <functional>], [[int a = 5; std::function<int(int)> f = [&a](int b) { return a + b; }; f(8);]])],
  68         AC_MSG_RESULT([yes]),
  69         AC_MSG_RESULT([no])
  70                 AC_MSG_ERROR([[Your compiler doesn't seem to support lambda functions, please upgrade (GCC >= 4.6)]])
  71 )
  72
  73 dnl ================================================================
  74 dnl = checking whether calling derived member function of object   =
  75 dnl = passed to lambda without explicit 'this' usage works         =
  76 dnl ================================================================
  77 AC_MSG_CHECKING([whether calling derived member function passed to lambda without explicit this usage works ])
  78 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <functional>], [[struct A { void foo() { } };  struct B : public A { void bar() { std::function<void()> f = [this]() { foo(); }; f();  } } foo; foo.bar();]])],
  79         AC_MSG_RESULT([yes]),
  80         AC_MSG_RESULT([no])
  81                 AC_MSG_ERROR([[Your compiler doesn't seem to support calling derived member function of an object passed to lambda as 'this' without explicit 'this' usage, please upgrade (GCC >= 4.6)]])
  82 )
  83
  84 dnl =========================================
  85 dnl = checking for override keyword support =
  86 dnl =========================================
  87 AH_TEMPLATE([OVERRIDE], [override keyword used in C++11])
  88 AC_MSG_CHECKING([whether compiler supports override keyword])
  89 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[struct A { virtual void foo() { } }; struct B : public A { virtual void foo() override { } };]], [])],
  90         AC_MSG_RESULT([yes])
  91                 AC_DEFINE([OVERRIDE], [override]),
  92         AC_MSG_RESULT([no])
  93                 AC_DEFINE([OVERRIDE], []),
  94 )
  95
  96 dnl =============================
  97 dnl = setting boost environment =
  98 dnl =============================
  99 AS_IF([test -z "${BOOST_LIB_SUFFIX+x}"], [BOOST_LIB_SUFFIX=-mt])
 100 AC_ARG_VAR([BOOST_LIB_SUFFIX], [Boost library name suffix [default=-mt]])
 101
 102 dnl ======================================
 103 dnl = checking for various boost headers =
 104 dnl ======================================
 105 AC_CHECK_HEADERS([boost/bind.hpp], ,
 106         AC_MSG_ERROR(boost/bind.hpp is missing))
 107 AC_CHECK_HEADERS([boost/lexical_cast.hpp], ,
 108         AC_MSG_ERROR(boost/lexical_cast.hpp is missing))
 109 AC_CHECK_HEADERS([boost/algorithm/string.hpp], ,
 110         AC_MSG_ERROR(boost/algorithm/string.hpp is missing))
 111
 112 dnl =================================
 113 dnl = checking for boost.filesystem =
 114 dnl =================================
 115 AC_CHECK_HEADERS([boost/filesystem.hpp], ,
 116         AC_MSG_ERROR(boost/filesystem.hpp is missing)
 117 )
 118 AC_CHECK_LIB(boost_filesystem$BOOST_LIB_SUFFIX, main, LDFLAGS="$LDFLAGS -lboost_filesystem$BOOST_LIB_SUFFIX",
 119         AC_MSG_ERROR([no boost.filesystem library found])
 120 )
 121 AC_CHECK_LIB(boost_system$BOOST_LIB_SUFFIX, main, LDFLAGS="$LDFLAGS -lboost_system$BOOST_LIB_SUFFIX",
 122         AC_MSG_ERROR([no boost.system library found])
 123 )
 124
 125 dnl =============================
 126 dnl = checking for boost.format =
 127 dnl =============================
 128 AC_CHECK_HEADERS([boost/format.hpp], ,
 129         AC_MSG_ERROR(boost/format.hpp is missing)
 130 )
 131
 132 dnl =============================
 133 dnl = checking for boost.locale =
 134 dnl =============================
 135 AC_CHECK_HEADERS([boost/locale.hpp], ,
 136         AC_MSG_ERROR(boost/locale.hpp is missing)
 137 )
 138 AC_CHECK_LIB(boost_locale$BOOST_LIB_SUFFIX, main, LDFLAGS="$LDFLAGS -lboost_locale$BOOST_LIB_SUFFIX",
 139         AC_MSG_ERROR([no boost.locale library found])
 140 )
 141
 142 dnl =================================
 143 dnl = checking for boost.posix_time =
 144 dnl =================================
 145 AC_CHECK_HEADERS([boost/date_time/posix_time/posix_time.hpp], ,
 146         AC_MSG_ERROR(boost/date_time/posix_time/posix_time.hpp is missing)
 147 )
 148
 149 dnl ======================================
 150 dnl = checking for boost.program_options =
 151 dnl ======================================
 152 AC_CHECK_HEADERS([boost/program_options.hpp], ,
 153         AC_MSG_ERROR(boost/program_options.hpp is missing)
 154 )
 155 AC_CHECK_LIB(boost_program_options$BOOST_LIB_SUFFIX, main, LDFLAGS="$LDFLAGS -lboost_program_options$BOOST_LIB_SUFFIX",
 156         AC_MSG_ERROR([no boost.program_options library found])
 157 )
 158
 159 dnl ============================
 160 dnl = checking for boost.regex =
 161 dnl ============================
 162 AC_CHECK_HEADERS([boost/regex.hpp], ,
 163         AC_MSG_ERROR(boost/regex.hpp is missing)
 164 )
 165 AC_CHECK_LIB(boost_regex$BOOST_LIB_SUFFIX, main, LDFLAGS="$LDFLAGS -lboost_regex$BOOST_LIB_SUFFIX",
 166         AC_MSG_ERROR([no boost.regex library found])
 167 )
 168
 169 dnl =============================
 170 dnl = checking for boost.thread =
 171 dnl =============================
 172 AC_DEFINE([BOOST_THREAD_VERSION], [3], [require boost.thread v3])
 173 AC_CHECK_HEADERS([boost/thread.hpp], ,
 174         AC_MSG_ERROR([boost/thread.hpp is missing or your boost version is too old (boost.thread v3 is required)])
 175 )
 176 AC_CHECK_LIB(boost_thread$BOOST_LIB_SUFFIX, main, LDFLAGS="$LDFLAGS -lboost_thread$BOOST_LIB_SUFFIX",
 177         AC_MSG_ERROR([no boost.thread library found])
 178 )
 179
 180 dnl ==============================
 181 dnl = checking for regex (win32) =
 182 dnl ==============================
 183 AC_CHECK_LIB(regex, regcomp, LDFLAGS="$LDFLAGS -lregex", )
 184
 185 dnl ================================
 186 dnl = checking for various headers =
 187 dnl ================================
 188 AC_CHECK_HEADERS([netinet/tcp.h netinet/in.h], , AC_MSG_ERROR(vital headers missing))
 189 AC_CHECK_HEADERS([langinfo.h], , AC_MSG_WARN(locale detection disabled))
 190
 191 dnl ==============================
 192 dnl = checking for libmpdclient2 =
 193 dnl ==============================
 194 PKG_CHECK_MODULES([libmpdclient], [libmpdclient >= 2.8], [
 195         AC_SUBST(libmpdclient_LIBS)
 196         AC_SUBST(libmpdclient_CFLAGS)
 197         CPPFLAGS="$CPPFLAGS $libmpdclient_CFLAGS"
 198         AC_CHECK_HEADERS([mpd/client.h],
 199                 LDFLAGS="$LDFLAGS $libmpdclient_LIBS"
 200         ,
 201                 AC_MSG_ERROR([missing mpd/client.h header])
 202         )
 203 ],
 204         AC_MSG_ERROR([libmpdclient >= 2.8 is required!])
 205 )
 206
 207 dnl =========================
 208 dnl = checking for readline =
 209 dnl =========================
 210 AC_CHECK_HEADERS([readline/readline.h readline/history.h],
 211         AC_CHECK_LIB(readline, rl_initialize, LDFLAGS="$LDFLAGS -lreadline",
 212                 AC_MSG_ERROR([readline headers found but there is no readline library to make use of])
 213         ),
 214         AC_MSG_ERROR([no readline/readline.h header file found])
 215 )
 216
 217
 218 dnl ========================
 219 dnl = checking for pthread =
 220 dnl ========================
 221 AC_CHECK_HEADERS([pthread.h],
 222         AC_CHECK_LIB(pthread, pthread_create, LDFLAGS="$LDFLAGS -lpthread",
 223                 AC_MSG_ERROR([pthread.h found but there is no pthread library to make use of])
 224         ),
 225         AC_MSG_ERROR([no pthread.h header header file found])
 226 )
 227
 228 dnl ========================
 229 dnl = checking for ncurses =
 230 dnl ========================
 231 if test "$pdcurses" = "no" ; then
 232         if test "$unicode" = "yes" ; then
 233                 curses_config_bin="ncursesw6-config ncursesw5-config"
 234                 AC_DEFINE([NCMPCPP_UNICODE], [1], [enables unicode support])
 235         else
 236                 curses_config_bin="ncurses6-config ncurses5-config"
 237         fi
 238 else
 239         if test "$pdcurses" = "yes" ; then
 240                 pdcurses_lib=XCurses
 241                 curses_config_bin=xcurses-config
 242         else
 243                 pdcurses_lib=$pdcurses
 244         fi
 245         AC_DEFINE([USE_PDCURSES], [1], [enables pdcurses support])
 246 fi
 247 AC_PATH_PROGS(CURSES_CONFIG, $curses_config_bin)
 248 if test "$CURSES_CONFIG" != "" ; then
 249         CPPFLAGS="$CPPFLAGS `$CURSES_CONFIG --cflags`"
 250         LDFLAGS="$LDFLAGS `$CURSES_CONFIG --libs`"
 251 fi
 252 if test "$pdcurses" = "no" ; then
 253         AC_CHECK_LIB(ncursesw, initscr,
 254                 curses_lib=ncursesw,
 255                 curses_lib=ncurses
 256         )
 257 else
 258         curses_lib=$pdcurses_lib
 259 fi
 260 AC_CHECK_LIB($curses_lib, initscr,
 261         if test "$CURSES_CONFIG" = "" ; then
 262                 LDFLAGS="$LDFLAGS -l$curses_lib"
 263         fi
 264         ,
 265         AC_MSG_ERROR([$curses_lib library is required])
 266         )
 267 if test "$pdcurses" != "no" ; then
 268         AC_CHECK_LIB($curses_lib, Xinitscr, AC_DEFINE([XCURSES], [1], [x11 pdcurses available]), )
 269 fi
 270 AC_CHECK_HEADERS([curses.h], , AC_MSG_ERROR([missing curses.h header]))
 271
 272 dnl ======================
 273 dnl = checking for fftw3 =
 274 dnl ======================
 275 if test "$visualizer" = "yes" ; then
 276         if test "$fftw" != "no" ; then
 277                 PKG_CHECK_MODULES([fftw3], [fftw3 >= 3], [
 278                         AC_SUBST(fftw3_LIBS)
 279                         AC_SUBST(fftw3_CFLAGS)
 280                         CPPFLAGS="$CPPFLAGS $fftw3_CFLAGS"
 281                         AC_CHECK_HEADERS([fftw3.h],
 282                                 LDFLAGS="$LDFLAGS $fftw3_LIBS"
 283                         ,
 284                                 if test "$fftw" = "yes" ; then
 285                                         AC_MSG_ERROR([missing fftw3.h header])
 286                                 fi
 287                         )
 288                 ],
 289                         if test "$fftw" = "yes" ; then
 290                                 AC_MSG_ERROR([fftw3 library is required!])
 291                         fi
 292                 )
 293         fi
 294         AC_DEFINE([ENABLE_VISUALIZER], [1], [enables music visualizer screen])
 295 fi
 296
 297 dnl =====================
 298 dnl = checking for curl =
 299 dnl =====================
 300 if test "$curl" != "no" ; then
 301         AC_PATH_PROG(CURL_CONFIG, curl-config)
 302         if test "$CURL_CONFIG" != "" ; then
 303                 CPPFLAGS="$CPPFLAGS `$CURL_CONFIG --cflags`"
 304                 AC_CHECK_LIB(curl, curl_easy_init, LDFLAGS="$LDFLAGS `$CURL_CONFIG --libs`",
 305                         if test "$curl" = "yes" ; then
 306                                 AC_MSG_ERROR([curl library is required])
 307                         fi
 308                 )
 309                 AC_CHECK_HEADERS([curl/curl.h], ,
 310                         if test "$curl" = "yes" ; then
 311                                 AC_MSG_ERROR([missing curl.h header])
 312                         fi
 313                 )
 314         else
 315                 AC_CHECK_LIB(curl, curl_easy_init, LDFLAGS="$LDFLAGS -lcurl",
 316                         if test "$curl" = "yes" ; then
 317                                 AC_MSG_ERROR([curl library is required])
 318                         fi
 319                 )
 320         fi
 321 fi
 322
 323 dnl =======================
 324 dnl = checking for taglib =
 325 dnl =======================
 326 if test "$taglib" != "no" ; then
 327         AC_PATH_PROG(TAGLIB_CONFIG, taglib-config)
 328         if test "$TAGLIB_CONFIG" != "" ; then
 329                 CPPFLAGS="$CPPFLAGS `$TAGLIB_CONFIG --cflags`"
 330                 LDFLAGS="$LDFLAGS `$TAGLIB_CONFIG --libs`"
 331                 AC_CHECK_HEADERS([taglib.h], ,
 332                         if test "$taglib" = "yes" ; then
 333                                 AC_MSG_ERROR([missing taglib.h header])
 334                         fi
 335                 )
 336         else
 337                 if test "$taglib" = "yes" ; then
 338                         AC_MSG_ERROR([taglib-config executable is missing])
 339                 fi
 340         fi
 341 fi
 342
 343 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile])
 344 AC_OUTPUT