configure.in

   1 AC_INIT(configure.in)
   2
   3 AM_CONFIG_HEADER(config.h)
   4 AM_INIT_AUTOMAKE(ncmpcpp, 0.6_pre)
   5
   6 AC_PREREQ(2.59)
   7
   8 AC_LANG_CPLUSPLUS
   9 AC_PROG_CXX
  10 AM_PROG_LIBTOOL
  11
  12 AC_ARG_ENABLE(outputs, AS_HELP_STRING([--enable-outputs], [Enable outputs screen @<:@default=no@:>@]), [outputs=$enableval], [outputs=no])
  13 AC_ARG_ENABLE(visualizer, AS_HELP_STRING([--enable-visualizer], [Enable music visualizer screen @<:@default=no@:>@]), [visualizer=$enableval], [visualizer=no])
  14 AC_ARG_ENABLE(clock, AS_HELP_STRING([--enable-clock], [Enable clock screen @<:@default=no@:>@]), [clock=$enableval], [clock=no])
  15 AC_ARG_ENABLE(unicode, AS_HELP_STRING([--enable-unicode], [Enable utf8 support @<:@default=yes@:>@]), [unicode=$enableval], [unicode=yes])
  16 AC_ARG_WITH(curl, AS_HELP_STRING([--with-curl], [Enable fetching lyrics from the Internet @<:@default=auto@:>@]), [curl=$withval], [curl=auto])
  17 AC_ARG_WITH(fftw, AS_HELP_STRING([--with-fftw], [Enable fftw support (required for frequency spectrum vizualization) @<:@default=auto@:>@]), [fftw=$withval], [fftw=auto])
  18 AC_ARG_WITH(pdcurses, AS_HELP_STRING([--with-pdcurses[=LIBNAME]], [Link against pdcurses instead of ncurses @<:@default=XCurses@:>@]), [pdcurses=$withval], [pdcurses=no])
  19 AC_ARG_WITH(taglib, AS_HELP_STRING([--with-taglib], [Enable tag editor @<:@default=auto@:>@]), [taglib=$withval], [taglib=auto])
  20
  21 if test "$outputs" = "yes"; then
  22         AC_DEFINE([ENABLE_OUTPUTS], [1], [enables outputs screen])
  23 fi
  24
  25 if test "$clock" = "yes"; then
  26         AC_DEFINE([ENABLE_CLOCK], [1], [enables clock screen])
  27 fi
  28
  29 dnl ================================
  30 dnl = checking for -std=c++0x flag =
  31 dnl ================================
  32 AC_MSG_CHECKING([whether compiler supports -std=c++0x])
  33 old_CXXFLAGS="$CXXFLAGS"
  34 CXXFLAGS="-std=c++0x"
  35 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ ]])],
  36         AC_MSG_RESULT([yes])
  37                 std_cpp0x="-std=c++0x",
  38         AC_MSG_RESULT([no])
  39                 AC_MSG_ERROR([[Your compiler doesn't seem to support C++0x, please upgrade (GCC >= 4.5)]])
  40 )
  41 CXXFLAGS="$old_CXXFLAGS $std_cpp0x"
  42
  43 dnl ==========================================
  44 dnl = checking for initializer lists support =
  45 dnl ==========================================
  46 AC_MSG_CHECKING([whether compiler supports initializer lists])
  47 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <vector>], [[std::vector<int> test = { 1, 2, 3 }; test.push_back(4);]])],
  48         AC_MSG_RESULT([yes]),
  49         AC_MSG_RESULT([no])
  50                 AC_MSG_ERROR([[Your compiler doesn't seem to support initializer lists, please upgrade (GCC >= 4.5)]])
  51 )
  52
  53 dnl =====================================
  54 dnl = checking for auto keyword support =
  55 dnl =====================================
  56 AC_MSG_CHECKING([whether compiler supports auto keyword])
  57 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[auto test = new int; *test = 1;]])],
  58         AC_MSG_RESULT([yes]),
  59         AC_MSG_RESULT([no])
  60                 AC_MSG_ERROR([[Your compiler doesn't seem to support auto keyword, please upgrade (GCC >= 4.5)]])
  61 )
  62
  63 dnl =========================================
  64 dnl = checking for lambda functions support =
  65 dnl =========================================
  66 AC_MSG_CHECKING([whether compiler supports lambda functions])
  67 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <functional>], [[int a = 5; std::function<int(int)> f = [&a](int b) { return a + b; }; f(8);]])],
  68         AC_MSG_RESULT([yes]),
  69         AC_MSG_RESULT([no])
  70                 AC_MSG_ERROR([[Your compiler doesn't seem to support lambda functions, please upgrade (GCC >= 4.5)]])
  71 )
  72
  73 dnl =========================================
  74 dnl = checking for override keyword support =
  75 dnl =========================================
  76 AH_TEMPLATE([OVERRIDE], [override keyword used in C++11])
  77 AC_MSG_CHECKING([whether compiler supports override keyword])
  78 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[struct A { virtual void foo() { } }; struct B : public A { virtual void foo() override { } };]], [])],
  79         AC_MSG_RESULT([yes])
  80                 AC_DEFINE([OVERRIDE], [override]),
  81         AC_MSG_RESULT([no])
  82                 AC_DEFINE([OVERRIDE], []),
  83 )
  84
  85 dnl =============================
  86 dnl = setting boost environment =
  87 dnl =============================
  88 AS_IF([test -z "${BOOST_LIB_SUFFIX+x}"], [BOOST_LIB_SUFFIX=-mt])
  89 AC_ARG_VAR([BOOST_LIB_SUFFIX], [Boost library name suffix [default=-mt]])
  90
  91 dnl =============================
  92 dnl = checking for boost.locale =
  93 dnl =============================
  94 AC_CHECK_HEADERS([boost/locale/encoding.hpp], ,
  95         AC_MSG_ERROR(boost/locale/encoding.hpp is missing)
  96 )
  97 AC_CHECK_LIB(boost_locale$BOOST_LIB_SUFFIX, main, LDFLAGS="$LDFLAGS -lboost_locale$BOOST_LIB_SUFFIX",
  98         AC_MSG_ERROR([no boost.locale library found])
  99 )
 100
 101 dnl ==============================
 102 dnl = checking for regex (win32) =
 103 dnl ==============================
 104 AC_CHECK_LIB(regex, regcomp, LDFLAGS="$LDFLAGS -lregex", )
 105
 106 dnl ================================
 107 dnl = checking for various headers =
 108 dnl ================================
 109 AC_CHECK_HEADERS([dirent.h regex.h], , AC_MSG_ERROR(vital headers missing))
 110 AC_CHECK_HEADERS([langinfo.h], , AC_MSG_WARN(locale detection disabled))
 111
 112 dnl ==============================
 113 dnl = checking for libmpdclient2 =
 114 dnl ==============================
 115 PKG_CHECK_MODULES([libmpdclient], [libmpdclient >= 2.8], [
 116         AC_SUBST(libmpdclient_LIBS)
 117         AC_SUBST(libmpdclient_CFLAGS)
 118         CPPFLAGS="$CPPFLAGS $libmpdclient_CFLAGS"
 119         AC_CHECK_HEADERS([mpd/client.h],
 120                 LDFLAGS="$LDFLAGS $libmpdclient_LIBS"
 121         ,
 122                 AC_MSG_ERROR([missing mpd/client.h header])
 123         )
 124 ],
 125         AC_MSG_ERROR([libmpdclient >= 2.8 is required!])
 126 )
 127
 128 dnl ========================
 129 dnl = checking for pthread =
 130 dnl ========================
 131 AC_CHECK_HEADERS([pthread.h],
 132         AC_CHECK_LIB(pthread, pthread_create, LDFLAGS="$LDFLAGS -lpthread",
 133                 AC_MSG_ERROR([pthread.h found but there is no pthread library to make use of])
 134         ),
 135 )
 136
 137 dnl ========================
 138 dnl = checking for ncurses =
 139 dnl ========================
 140 if test "$pdcurses" = "no" ; then
 141         if test "$unicode" = "yes" ; then
 142                 curses_config_bin="ncursesw6-config ncursesw5-config"
 143                 AC_DEFINE([NCMPCPP_UNICODE], [1], [enables unicode support])
 144         else
 145                 curses_config_bin="ncurses6-config ncurses5-config"
 146         fi
 147 else
 148         if test "$pdcurses" = "yes" ; then
 149                 pdcurses_lib=XCurses
 150                 curses_config_bin=xcurses-config
 151         else
 152                 pdcurses_lib=$pdcurses
 153         fi
 154         AC_DEFINE([USE_PDCURSES], [1], [enables pdcurses support])
 155 fi
 156 AC_PATH_PROGS(CURSES_CONFIG, $curses_config_bin)
 157 if test "$CURSES_CONFIG" != "" ; then
 158         CPPFLAGS="$CPPFLAGS `$CURSES_CONFIG --cflags`"
 159         LDFLAGS="$LDFLAGS `$CURSES_CONFIG --libs`"
 160 fi
 161 if test "$pdcurses" = "no" ; then
 162         AC_CHECK_LIB(ncursesw, initscr,
 163                 curses_lib=ncursesw,
 164                 curses_lib=ncurses
 165         )
 166 else
 167         curses_lib=$pdcurses_lib
 168 fi
 169 AC_CHECK_LIB($curses_lib, initscr,
 170         if test "$CURSES_CONFIG" = "" ; then
 171                 LDFLAGS="$LDFLAGS -l$curses_lib"
 172         fi
 173         ,
 174         AC_MSG_ERROR([$curses_lib library is required])
 175         )
 176 if test "$pdcurses" != "no" ; then
 177         AC_CHECK_LIB($curses_lib, Xinitscr, AC_DEFINE([XCURSES], [1], [x11 pdcurses available]), )
 178 fi
 179 AC_CHECK_HEADERS([curses.h], , AC_MSG_ERROR([missing curses.h header]))
 180
 181 dnl ======================
 182 dnl = checking for fftw3 =
 183 dnl ======================
 184 if test "$visualizer" = "yes" ; then
 185         if test "$fftw" != "no" ; then
 186                 PKG_CHECK_MODULES([fftw3], [fftw3 >= 3], [
 187                         AC_SUBST(fftw3_LIBS)
 188                         AC_SUBST(fftw3_CFLAGS)
 189                         CPPFLAGS="$CPPFLAGS $fftw3_CFLAGS"
 190                         AC_CHECK_HEADERS([fftw3.h],
 191                                 LDFLAGS="$LDFLAGS $fftw3_LIBS"
 192                         ,
 193                                 if test "$fftw" = "yes" ; then
 194                                         AC_MSG_ERROR([missing fftw3.h header])
 195                                 fi
 196                         )
 197                 ],
 198                         if test "$fftw" = "yes" ; then
 199                                 AC_MSG_ERROR([fftw3 library is required!])
 200                         fi
 201                 )
 202         fi
 203         AC_DEFINE([ENABLE_VISUALIZER], [1], [enables music visualizer screen])
 204 fi
 205
 206 dnl =====================
 207 dnl = checking for curl =
 208 dnl =====================
 209 if test "$curl" != "no" ; then
 210         AC_PATH_PROG(CURL_CONFIG, curl-config)
 211         if test "$CURL_CONFIG" != "" ; then
 212                 CPPFLAGS="$CPPFLAGS `$CURL_CONFIG --cflags`"
 213                 AC_CHECK_LIB(curl, curl_easy_init, LDFLAGS="$LDFLAGS `$CURL_CONFIG --libs`",
 214                         if test "$curl" = "yes" ; then
 215                                 AC_MSG_ERROR([curl library is required])
 216                         fi
 217                 )
 218                 AC_CHECK_HEADERS([curl/curl.h], ,
 219                         if test "$curl" = "yes" ; then
 220                                 AC_MSG_ERROR([missing curl.h header])
 221                         fi
 222                 )
 223         else
 224                 AC_CHECK_LIB(curl, curl_easy_init, LDFLAGS="$LDFLAGS -lcurl",
 225                         if test "$curl" = "yes" ; then
 226                                 AC_MSG_ERROR([curl library is required])
 227                         fi
 228                 )
 229         fi
 230 fi
 231
 232 dnl =======================
 233 dnl = checking for taglib =
 234 dnl =======================
 235 if test "$taglib" != "no" ; then
 236         AC_PATH_PROG(TAGLIB_CONFIG, taglib-config)
 237         if test "$TAGLIB_CONFIG" != "" ; then
 238                 CPPFLAGS="$CPPFLAGS `$TAGLIB_CONFIG --cflags`"
 239                 LDFLAGS="$LDFLAGS `$TAGLIB_CONFIG --libs`"
 240                 AC_CHECK_HEADERS([taglib.h], ,
 241                         if test "$taglib" = "yes" ; then
 242                                 AC_MSG_ERROR([missing taglib.h header])
 243                         fi
 244                 )
 245         else
 246                 if test "$taglib" = "yes" ; then
 247                         AC_MSG_ERROR([taglib-config executable is missing])
 248                 fi
 249         fi
 250 fi
 251
 252 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile])
 253 AC_OUTPUT