configure.ac

   1 # nbdkit
   2 # Copyright (C) 2013-2019 Red Hat Inc.
   3 #
   4 # Redistribution and use in source and binary forms, with or without
   5 # modification, are permitted provided that the following conditions are
   6 # met:
   7 #
   8 # * Redistributions of source code must retain the above copyright
   9 # notice, this list of conditions and the following disclaimer.
  10 #
  11 # * Redistributions in binary form must reproduce the above copyright
  12 # notice, this list of conditions and the following disclaimer in the
  13 # documentation and/or other materials provided with the distribution.
  14 #
  15 # * Neither the name of Red Hat nor the names of its contributors may be
  16 # used to endorse or promote products derived from this software without
  17 # specific prior written permission.
  18 #
  19 # THIS SOFTWARE IS PROVIDED BY RED HAT AND CONTRIBUTORS ''AS IS'' AND
  20 # ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
  21 # THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A
  22 # PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL RED HAT OR
  23 # CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  24 # SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  25 # LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF
  26 # USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
  27 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
  28 # OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
  29 # OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30 # SUCH DAMAGE.
  31
  32 AC_INIT([nbdkit], [1.13.5])
  33 AC_CONFIG_MACRO_DIR([m4])
  34 m4_ifdef([AC_USE_SYSTEM_EXTENSIONS],[],
  35          [m4_define([AC_USE_SYSTEM_EXTENSIONS],[])])
  36 AC_USE_SYSTEM_EXTENSIONS
  37 AC_SYS_LARGEFILE
  38
  39 dnl NB: Do not [quote] this parameter.
  40 AM_INIT_AUTOMAKE(foreign)
  41 AC_PROG_LIBTOOL
  42 LT_INIT
  43
  44 AC_CANONICAL_HOST
  45
  46 AC_PROG_SED
  47
  48 dnl Check for basic C environment.
  49 AC_PROG_CC_STDC
  50 AC_PROG_INSTALL
  51 AC_PROG_CPP
  52 AC_CANONICAL_HOST
  53
  54 AC_C_PROTOTYPES
  55 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
  56
  57 AM_PROG_CC_C_O
  58
  59 dnl Check for C++ (optional, we just use this to test the header
  60 dnl can be included from C++ code).
  61 AC_PROG_CXX
  62
  63 dnl The C++ compiler test is pretty useless because even if it fails
  64 dnl it sets CXX=g++.  So test the compiler actually works.
  65 AC_MSG_CHECKING([if the C++ compiler really really works])
  66 AS_IF([$CXX --version >&AS_MESSAGE_LOG_FD 2>&1],[have_cxx=yes],[have_cxx=no])
  67 AC_MSG_RESULT([$have_cxx])
  68 AM_CONDITIONAL([HAVE_CXX], [test "$have_cxx" = "yes"])
  69
  70 AC_ARG_ENABLE([gcc-warnings],
  71     [AS_HELP_STRING([--enable-gcc-warnings],
  72                     [turn on lots of GCC warnings (for developers)])],
  73      [case $enableval in
  74       yes|no) ;;
  75       *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  76       esac
  77       gcc_warnings=$enableval],
  78       [gcc_warnings=no]
  79 )
  80 if test "x$gcc_warnings" = "xyes"; then
  81     WARNINGS_CFLAGS="-Wall -Werror"
  82     AC_SUBST([WARNINGS_CFLAGS])
  83 fi
  84
  85 dnl Check if the compiler supports -std=c90 flag.  This is only used
  86 dnl during a test.  OpenBSD GCC does not support this flag so we skip
  87 dnl that test.
  88 AC_MSG_CHECKING([if the compiler supports -std=c90 for ANSI C test])
  89 old_CFLAGS="$CFLAGS"
  90 CFLAGS="$CFLAGS -std=c90"
  91 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
  92     [supports_std_c90=yes],
  93     [supports_std_c90=no])
  94 CFLAGS="$old_CFLAGS"
  95 AC_MSG_RESULT([$supports_std_c90])
  96 AM_CONDITIONAL([CAN_TEST_ANSI_C], [test "x$supports_std_c90" = "xyes"])
  97
  98 dnl On Haiku we must use BSD-compatibility headers to get the endian
  99 dnl macros we use.
 100 AC_MSG_CHECKING(whether OS-dependent include paths are required)
 101 AS_CASE([$host_os],
 102   [haiku*], [CFLAGS="$CFLAGS -I`findpaths -p /system B_FIND_PATH_HEADERS_DIRECTORY`/bsd"; AC_MSG_RESULT(yes)],
 103   [AC_MSG_RESULT(no)]
 104 )
 105
 106 dnl On Linux /tmp is often tmpfs which is not large enough, so use /var/tmp.
 107 dnl But Haiku only has /tmp.
 108 AC_MSG_CHECKING([for temporary directory for large files])
 109 AS_CASE([$host_os],
 110   [haiku*], [LARGE_TMPDIR=/tmp],
 111   [LARGE_TMPDIR=/var/tmp]
 112 )
 113 AC_MSG_RESULT([$LARGE_TMPDIR])
 114 AC_DEFINE_UNQUOTED([LARGE_TMPDIR],["$LARGE_TMPDIR"],
 115                    [Temporary directory for large files])
 116
 117 dnl Check if libc has program_invocation_short_name.
 118 AC_CHECK_DECLS([program_invocation_short_name], [], [], [#include <errno.h>])
 119
 120 AX_PTHREAD
 121
 122 dnl Check if __attribute__((cleanup(...))) works.
 123 dnl Set -Werror, otherwise gcc will only emit a warning for attributes
 124 dnl that it doesn't understand.
 125 acx_nbdkit_save_CFLAGS="${CFLAGS}"
 126 CFLAGS="${CFLAGS} -Werror"
 127 AC_MSG_CHECKING([if __attribute__((cleanup(...))) works with this compiler])
 128 AC_COMPILE_IFELSE([
 129 AC_LANG_SOURCE([[
 130 #include <stdio.h>
 131 #include <stdlib.h>
 132
 133 void
 134 freep (void *ptr)
 135 {
 136   exit (EXIT_SUCCESS);
 137 }
 138
 139 void
 140 test (void)
 141 {
 142   __attribute__((cleanup(freep))) char *ptr = malloc (100);
 143 }
 144
 145 int
 146 main (int argc, char *argv[])
 147 {
 148   test ();
 149   exit (EXIT_FAILURE);
 150 }
 151 ]])
 152     ],[
 153     AC_MSG_RESULT([yes])
 154     ],[
 155     AC_MSG_RESULT([no])
 156     AC_MSG_ERROR(
 157 ['__attribute__((cleanup(...)))' does not work.
 158
 159 You may not be using a sufficiently recent version of GCC or CLANG, or
 160 you may be using a C compiler which does not support this attribute,
 161 or the configure test may be wrong.
 162
 163 This code requires the attribute to work for proper locking between threads.])])
 164 CFLAGS="${acx_nbdkit_save_CFLAGS}"
 165
 166 dnl Check for __auto_type (GCC extension).
 167 AC_MSG_CHECKING([if __auto_type is available in this compiler])
 168 AC_COMPILE_IFELSE([
 169 AC_LANG_SOURCE([[
 170 static int
 171 test (int a)
 172 {
 173   __auto_type at = a;
 174   return at;
 175 }
 176 ]])
 177     ],[
 178     AC_MSG_RESULT([yes])
 179     AC_DEFINE([HAVE_AUTO_TYPE],[1],[__auto_type is available])
 180     ],[
 181     AC_MSG_RESULT([no])
 182     ]
 183 )
 184
 185 dnl Check for other headers, all optional.
 186 AC_CHECK_HEADERS([\
 187         alloca.h \
 188         byteswap.h \
 189         endian.h \
 190         sys/endian.h \
 191         sys/prctl.h \
 192         sys/procctl.h])
 193
 194 dnl Check for functions in libc, all optional.
 195 AC_CHECK_FUNCS([\
 196         fdatasync \
 197         get_current_dir_name \
 198         mkostemp \
 199         posix_fadvise])
 200
 201 dnl Check whether printf("%m") works
 202 AC_CACHE_CHECK([whether the printf family supports %m],
 203   [nbdkit_cv_func_printf_percent_m],
 204   [AC_RUN_IFELSE(
 205     [AC_LANG_PROGRAM([[
 206 #include <stdio.h>
 207 #include <string.h>
 208 #include <errno.h>
 209     ]], [[
 210     char buf[200] = "";
 211     errno = EINVAL;
 212     snprintf(buf, sizeof buf, "%m");
 213     return !!strcmp (buf, strerror (EINVAL));
 214     ]])],
 215     [nbdkit_cv_func_printf_percent_m=yes],
 216     [nbdkit_cv_func_printf_percent_m=no],
 217     [[
 218     case "$host_os" in
 219       *-gnu* | gnu*) nbdkit_cv_func_printf_percent_m=yes;;
 220       *) nbdkit_cv_func_printf_percent_m="guessing no";;
 221     esac
 222     ]])])
 223 AS_IF([test "x$nbdkit_cv_func_printf_percent_m" = xyes],
 224   [AC_DEFINE([HAVE_VFPRINTF_PERCENT_M],[1],
 225     [Define to 1 if vfprintf supports %m.])])
 226
 227 old_LIBS="$LIBS"
 228 AC_SEARCH_LIBS([dlsym], [dl dld], [
 229         AS_IF([test "x$ac_cv_search_dlsym" != "xnone required"],
 230             [DL_LIBS="$ac_cv_search_dlsym"], [DL_LIBS=])
 231         AC_SUBST([DL_LIBS])
 232     ], [AC_MSG_ERROR([unable to find the dlsym() function])
 233 ])
 234 LIBS="$old_LIBS"
 235
 236 dnl Test if <iconv.h> header can build working binaries.
 237 dnl
 238 dnl On FreeBSD: iconv and libiconv both exist, both can be installed
 239 dnl simultaneously, <iconv.h> can exist in two separate places, and
 240 dnl if you get the wrong header/library mix everything breaks.
 241 dnl
 242 dnl On Haiku: libiconv is required to link to iconv_* functions.
 243 AC_ARG_WITH([iconv],
 244     [AS_HELP_STRING([--without-iconv],
 245                     [don't try to link against iconv @<:@default=check@:>@])],
 246     [],
 247     [with_iconv=check])
 248 AS_IF([test "x$with_iconv" != "xno"],[
 249     AC_CHECK_HEADER([iconv.h],[
 250         AC_MSG_CHECKING([if <iconv.h> can be used to link a program])
 251         AC_LINK_IFELSE([
 252 AC_LANG_SOURCE([[
 253 #include <stdio.h>
 254 #include <stdlib.h>
 255 #include <iconv.h>
 256 int
 257 main (int argc, char *argv[])
 258 {
 259   iconv_t ic = iconv_open ("", "");
 260   iconv_close (ic);
 261   exit (0);
 262 }
 263 ]])
 264             ],[
 265             AC_MSG_RESULT([yes])
 266             iconv_working=yes
 267             ],[
 268             AC_MSG_RESULT([no])
 269             ])
 270         ])
 271     ])
 272 AM_CONDITIONAL([HAVE_ICONV], [test "x$iconv_working" = "xyes"])
 273
 274 dnl Don't use linker script for the server on FreeBSD because
 275 dnl FreeBSD's linker is broken.  See eg:
 276 dnl https://bugs.freebsd.org/bugzilla/show_bug.cgi?id=190851
 277 AC_MSG_CHECKING([if we should use a linker script for the server])
 278 AS_CASE([$host_os],
 279   [freebsd*], [use_linker_script_for_server=no],
 280   [use_linker_script_for_server=yes]
 281 )
 282 AC_MSG_RESULT([$use_linker_script_for_server])
 283 AM_CONDITIONAL([USE_LINKER_SCRIPT_FOR_SERVER],
 284                [test "x$use_linker_script_for_server" = "xyes"])
 285
 286 dnl Check if -rdynamic linker flag works.
 287 acx_nbdkit_save_LDFLAGS="${LDFLAGS}"
 288 LDFLAGS="${LDFLAGS} -rdynamic"
 289 AC_MSG_CHECKING([if linker supports -rdynamic])
 290 AC_LINK_IFELSE([
 291 AC_LANG_SOURCE([[
 292 #include <stdlib.h>
 293 int
 294 main (int argc, char *argv[])
 295 {
 296   exit (EXIT_SUCCESS);
 297 }
 298 ]])
 299     ],[
 300     AC_MSG_RESULT([yes])
 301     DL_LDFLAGS=-rdynamic
 302     ],[
 303     AC_MSG_RESULT([no])
 304 ])
 305 dnl restore CFLAGS
 306 LDFLAGS="${acx_nbdkit_save_LDFLAGS}"
 307 AC_SUBST([DL_LDFLAGS])
 308
 309 dnl Check for dladdr in -ldl, optional.  This is a glibc extension.
 310 old_LIBS="$LIBS"
 311 LIBS="$DL_LIBS $LIBS"
 312 AC_CHECK_FUNCS([dladdr])
 313 LIBS="$old_LIBS"
 314
 315 AC_SEARCH_LIBS([getaddrinfo], [network socket])
 316
 317 dnl Check for SELinux socket labelling (optional).
 318 PKG_CHECK_MODULES([LIBSELINUX], [libselinux], [
 319     AC_SUBST([LIBSELINUX_CFLAGS])
 320     AC_SUBST([LIBSELINUX_LIBS])
 321     AC_DEFINE([HAVE_LIBSELINUX],[1],[libselinux found at compile time.])
 322 ], [
 323     AC_MSG_WARN([libselinux not found, SELinux socket labelling support will be disabled.])
 324 ])
 325
 326 dnl Check for GnuTLS (optional, for TLS support).
 327 PKG_CHECK_MODULES([GNUTLS], [gnutls >= 3.3.0], [
 328     AC_SUBST([GNUTLS_CFLAGS])
 329     AC_SUBST([GNUTLS_LIBS])
 330     AC_DEFINE([HAVE_GNUTLS],[1],[gnutls found at compile time.])
 331 ], [
 332     AC_MSG_WARN([gnutls not found or < 3.3.0, TLS support will be disabled.])
 333 ])
 334
 335 AS_IF([test "$GNUTLS_LIBS" != ""],[
 336     AC_MSG_CHECKING([for default TLS session priority string])
 337     AC_ARG_WITH([tls-priority],
 338         [AS_HELP_STRING([--with-tls-priority],
 339                         [default TLS session priority string @<:@default=NORMAL@:>@])],
 340         [tls_priority=$withval],
 341         [tls_priority=NORMAL])
 342     AC_MSG_RESULT([$tls_priority])
 343     AC_DEFINE_UNQUOTED([TLS_PRIORITY],["$tls_priority"],
 344                        [Default TLS session priority string])
 345
 346     # Check for APIs which may not be present.
 347     old_LIBS="$LIBS"
 348     LIBS="$GNUTLS_LIBS $LIBS"
 349     AC_CHECK_FUNCS([\
 350         gnutls_base64_decode2 \
 351         gnutls_certificate_set_known_dh_params \
 352         gnutls_session_set_verify_cert])
 353     LIBS="$old_LIBS"
 354 ])
 355
 356 dnl Check for valgrind.
 357 AC_CHECK_PROG([VALGRIND],[valgrind],[valgrind],[no])
 358
 359 dnl If valgrind headers are available (optional).
 360 dnl Since this is only useful for developers, you have to enable
 361 dnl it explicitly using --enable-valgrind.
 362 AC_ARG_ENABLE([valgrind],
 363     [AS_HELP_STRING([--enable-valgrind],
 364                     [enable Valgrind extensions (for developers)])],
 365     [enable_valgrind=yes],
 366     [enable_valgrind=no])
 367 AS_IF([test "x$enable_valgrind" = "xyes"],[
 368     PKG_CHECK_MODULES([VALGRIND], [valgrind], [
 369         AC_SUBST([VALGRIND_CFLAGS])
 370         AC_SUBST([VALGRIND_LIBS])
 371         AC_DEFINE([HAVE_VALGRIND],[1],[Valgrind headers found at compile time])
 372     ],[
 373         AC_MSG_ERROR([--enable-valgrind given, but Valgrind headers are not available])
 374     ])
 375 ])
 376
 377 dnl Bash completion.
 378 PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0], [
 379     bash_completion=yes
 380     AC_MSG_CHECKING([for bash-completions directory])
 381     m4_ifdef([PKG_CHECK_VAR],[
 382         PKG_CHECK_VAR(bashcompdir, [bash-completion], [completionsdir])
 383     ])
 384     AS_IF([test -z "$bashcompdir"], [
 385         bashcompdir="${sysconfdir}/bash_completion.d"
 386     ])
 387     AC_MSG_RESULT([$bashcompdir])
 388     AC_SUBST([bashcompdir])
 389 ],[
 390     bash_completion=no
 391     AC_MSG_WARN([bash-completion not installed])
 392 ])
 393 AM_CONDITIONAL([HAVE_BASH_COMPLETION],[test "x$bash_completion" = "xyes"])
 394
 395 dnl Check we have enough to run podwrapper.
 396 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 397 AS_IF([test "x$PERL" != "xno"],[
 398     AC_MSG_CHECKING([if we have perl Pod::Man and Pod::Simple])
 399     AS_IF([$PERL -MPod::Man -MPod::Simple -e 1 >&AS_MESSAGE_LOG_FD 2>&1],[
 400         enable_pod=yes
 401     ],[
 402         enable_pod=no
 403     ])
 404     AC_MSG_RESULT([$enable_pod])
 405 ])
 406 AM_CONDITIONAL([HAVE_POD],
 407                [test "x$PERL" != "xno" && test "x$enable_pod" = "xyes"])
 408
 409 dnl Define the path to the podwrapper program.
 410 PODWRAPPER="$PERL $(pwd)/podwrapper.pl"
 411 AC_SUBST([PODWRAPPER])
 412
 413 dnl Allow all plugins and filters to be disabled.
 414 AC_ARG_ENABLE([plugins],
 415     [AS_HELP_STRING([--disable-plugins],
 416                     [disable all bundled plugins and filters])])
 417 AM_CONDITIONAL([HAVE_PLUGINS], [test "x$enable_plugins" != "xno"])
 418
 419 dnl Check for Perl, for embedding in the perl plugin.
 420 dnl Note that the perl binary is checked above.
 421 AC_ARG_ENABLE([perl],
 422     [AS_HELP_STRING([--disable-perl], [disable Perl embed plugin])],
 423     [],
 424     [enable_perl=yes])
 425 AS_IF([test "x$PERL" != "xno" && test "x$enable_perl" != "xno"],[
 426     dnl Check for Perl archlib.
 427     AC_MSG_CHECKING([for Perl embed archlib])
 428     PERL_ARCHLIB="$($PERL -MConfig -e 'print $Config{archlib}')"
 429     AS_IF([ test -n "$PERL_ARCHLIB" ],[
 430         AC_MSG_RESULT([$PERL_ARCHLIB])
 431     ],[
 432         AC_MSG_NOTICE([Perl embed module disabled])
 433         enable_perl=no
 434     ])
 435
 436     dnl Check for Perl CFLAGS.
 437     AC_MSG_CHECKING([for Perl embed CFLAGS])
 438     PERL_CFLAGS="$($PERL -MExtUtils::Embed -e 'ccflags')"
 439     AS_IF([ test -n "$PERL_CFLAGS" ],[
 440         AC_MSG_RESULT([$PERL_CFLAGS])
 441     ],[
 442         AC_MSG_NOTICE([Perl embed module disabled])
 443         enable_perl=no
 444     ])
 445
 446     dnl Check for Perl LDOPTS.
 447     AC_MSG_CHECKING([for Perl embed LDOPTS])
 448     PERL_LDOPTS="$($PERL -MExtUtils::Embed -e 'ldopts')"
 449     AC_MSG_RESULT([$PERL_LDOPTS])
 450
 451     dnl XXX Could check these actually work.
 452 ])
 453 AM_CONDITIONAL([HAVE_PERL],[test "x$enable_perl" != "xno" && test "x$PERL" != "xno"])
 454 AC_SUBST([PERL_ARCHLIB])
 455 AC_SUBST([PERL_CFLAGS])
 456 AC_SUBST([PERL_LDOPTS])
 457
 458 dnl Check for Python, for embedding in the python plugin.
 459 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 460 AC_ARG_ENABLE([python],
 461     [AS_HELP_STRING([--disable-python], [disable Python embed plugin])],
 462     [],
 463     [enable_python=yes])
 464 AS_IF([test "x$PYTHON" != "xno" && test "x$enable_python" != "xno"],[
 465     AC_MSG_CHECKING([version of $PYTHON])
 466     PYTHON_VERSION_MAJOR=`$PYTHON -c "import sys; print (sys.version_info@<:@0@:>@)"`
 467     PYTHON_VERSION_MINOR=`$PYTHON -c "import sys; print (sys.version_info@<:@1@:>@)"`
 468     PYTHON_VERSION="$PYTHON_VERSION_MAJOR.$PYTHON_VERSION_MINOR"
 469     AS_IF([test -n "$PYTHON_VERSION"],[
 470         AC_MSG_RESULT([$PYTHON_VERSION])
 471     ],[
 472         AC_MSG_NOTICE([Python embed module disabled])
 473         enable_python=no
 474     ])
 475
 476     dnl Check for Python CFLAGS, libraries.
 477     dnl For Python >= 3.8 we have to use python-embed.pc, see:
 478     dnl https://docs.python.org/3.8/whatsnew/3.8.html#debug-build-uses-the-same-abi-as-release-build
 479     dnl The python.pc is called python-<VERSION>.pc on Debian and
 480     dnl later versions of Fedora, and python.pc on older versions
 481     dnl of Fedora.
 482     PKG_CHECK_MODULES([PYTHON], [python-embed-"$PYTHON_VERSION"], [
 483         AC_SUBST([PYTHON_CFLAGS])
 484         AC_SUBST([PYTHON_LIBS])
 485         AC_SUBST([PYTHON_VERSION])
 486         AC_DEFINE([HAVE_PYTHON],[1],[Python library found at compile time])
 487     ],[
 488     PKG_CHECK_MODULES([PYTHON], [python-embed], [
 489         AC_SUBST([PYTHON_CFLAGS])
 490         AC_SUBST([PYTHON_LIBS])
 491         AC_SUBST([PYTHON_VERSION])
 492         AC_DEFINE([HAVE_PYTHON],[1],[Python library found at compile time])
 493     ],[
 494     PKG_CHECK_MODULES([PYTHON], [python-"$PYTHON_VERSION"], [
 495         AC_SUBST([PYTHON_CFLAGS])
 496         AC_SUBST([PYTHON_LIBS])
 497         AC_SUBST([PYTHON_VERSION])
 498         AC_DEFINE([HAVE_PYTHON],[1],[Python library found at compile time])
 499     ],[
 500     PKG_CHECK_MODULES([PYTHON], [python], [
 501         AC_SUBST([PYTHON_CFLAGS])
 502         AC_SUBST([PYTHON_LIBS])
 503         AC_SUBST([PYTHON_VERSION])
 504         AC_DEFINE([HAVE_PYTHON],[1],[Python library found at compile time])
 505     ],[
 506         AC_MSG_WARN([python $PYTHON_VERSION not found])
 507         enable_python=no
 508     ])])])])
 509
 510     dnl Check for various functions needed by the bindings.
 511     old_LIBS="$LIBS"
 512
 513     PYTHON_BLDLIBRARY=`$PYTHON -c "import distutils.sysconfig; \
 514         print (distutils.sysconfig.get_config_var('BLDLIBRARY'))"`
 515     AC_CHECK_LIB([c],[PyString_FromString],
 516                  [AC_DEFINE([HAVE_PYSTRING_FROMSTRING],1,
 517                             [Found PyString_FromString in libpython.])],
 518                  [],[$PYTHON_BLDLIBRARY])
 519     AC_CHECK_LIB([c],[PyString_AsString],
 520                  [AC_DEFINE([HAVE_PYSTRING_ASSTRING],1,
 521                             [Found PyString_AsString in libpython.])],
 522                  [],[$PYTHON_BLDLIBRARY])
 523     AC_CHECK_LIB([c],[PyUnicode_AsUTF8],
 524                  [AC_DEFINE([HAVE_PYUNICODE_ASUTF8],1,
 525                             [Found PyUnicode_AsUTF8 in libpython.])],
 526                  [],[$PYTHON_BLDLIBRARY])
 527
 528     LIBS="$old_LIBS"
 529
 530 ])
 531 AM_CONDITIONAL([HAVE_PYTHON],[test "x$enable_python" != "xno" && test "x$PYTHON" != "xno"])
 532 AC_SUBST([PYTHON_CFLAGS])
 533 AC_SUBST([PYTHON_LIBS])
 534 AC_SUBST([PYTHON_LDFLAGS])
 535
 536 dnl For the OCaml plugin, you can set OCAMLOPTFLAGS before running
 537 dnl ./configure to specify any extra flags you want to pass to
 538 dnl ocamlopt.
 539 AC_SUBST([OCAMLOPTFLAGS])
 540
 541 dnl Check for OCaml, for embedding in the ocaml plugin.
 542 AC_PROG_OCAML
 543 AC_ARG_ENABLE([ocaml],
 544     [AS_HELP_STRING([--disable-ocaml], [disable OCaml embed plugin])],
 545     [],
 546     [enable_ocaml=yes])
 547 AS_IF([test "x$OCAMLOPT" != "xno" && test "x$enable_ocaml" != "xno"],[
 548     dnl Check OCaml can create a shared library (see README for details).
 549     AC_MSG_CHECKING([if $OCAMLOPT can create a shared library])
 550     echo 'print_endline "test"' > conftest.ml
 551     AS_IF([$OCAMLOPT $OCAMLOPTFLAGS -output-obj -runtime-variant _pic -o conftest.so conftest.ml >&AS_MESSAGE_LOG_FD 2>&1],[
 552         AC_MSG_RESULT([yes])
 553         ocaml_link_shared=yes
 554     ],[
 555         AC_MSG_RESULT([no])
 556     ])
 557     rm -f conftest.ml conftest.cmi conftest.cmx conftest.so conftest.o
 558 ])
 559 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLOPT" != "xno" &&
 560                              test "x$ocaml_link_shared" = "xyes"])
 561
 562 dnl For developing plugins in Rust, optional.
 563 AC_CHECK_PROG([CARGO],[cargo],[cargo],[no])
 564 AC_ARG_ENABLE([rust],
 565     [AS_HELP_STRING([--disable-rust], [disable Rust plugin])],
 566     [],
 567     [enable_rust=yes])
 568 AM_CONDITIONAL([HAVE_RUST],
 569                [test "x$CARGO" != "xno" && test "x$enable_rust" != "xno"])
 570
 571 dnl Check for Ruby, for embedding in the Ruby plugin.
 572 AC_CHECK_PROG([RUBY],[ruby],[ruby],[no])
 573 AC_ARG_ENABLE([ruby],
 574     [AS_HELP_STRING([--disable-ruby], [disable Ruby plugin])],
 575     [],
 576     [enable_ruby=yes])
 577 AS_IF([test "x$RUBY" != "xno" && test "x$enable_ruby" != "xno"],[
 578     PKG_CHECK_MODULES([RUBY], [ruby], [
 579         AC_SUBST([RUBY_CFLAGS])
 580         AC_SUBST([RUBY_LIBS])
 581     ],[
 582         AC_MSG_WARN([ruby not found])
 583         enable_ruby=no
 584     ])
 585 ])
 586 AM_CONDITIONAL([HAVE_RUBY],[test "x$RUBY" != "xno" &&
 587                             test "x$enable_ruby" = "xyes"])
 588
 589 dnl Check for Tcl, for embedding in the Tcl plugin.
 590 AC_ARG_ENABLE([tcl],
 591     [AS_HELP_STRING([--disable-tcl], [disable Tcl plugin])],
 592     [],
 593     [enable_tcl=yes])
 594 AS_IF([test "x$enable_tcl" != "xno"],[
 595     PKG_CHECK_MODULES([TCL], [tcl], [
 596         AC_SUBST([TCL_CFLAGS])
 597         AC_SUBST([TCL_LIBS])
 598     ],[
 599         AC_MSG_WARN([Tcl not found])
 600         enable_tcl=no
 601     ])
 602 ])
 603 AM_CONDITIONAL([HAVE_TCL],[test "x$enable_tcl" = "xyes"])
 604
 605 dnl Check for Lua, for embedding in the Lua plugin.
 606 AC_ARG_ENABLE([lua],
 607     [AS_HELP_STRING([--disable-lua], [disable Lua plugin])],
 608     [],
 609     [enable_lua=yes])
 610 AS_IF([test "x$enable_lua" != "xno"],[
 611     PKG_CHECK_MODULES([LUA], [lua], [
 612         AC_SUBST([LUA_CFLAGS])
 613         AC_SUBST([LUA_LIBS])
 614
 615         dnl Lua 5.1 used by RHEL 7 does not have lua_isinteger.
 616         old_LIBS="$LIBS"
 617         LIBS="$LUA_LIBS $LIBS"
 618         AC_CHECK_FUNCS([lua_isinteger])
 619         LIBS="$old_LIBS"
 620     ],[
 621         AC_MSG_WARN([Lua not found])
 622         enable_lua=no
 623     ])
 624 ])
 625 AM_CONDITIONAL([HAVE_LUA],[test "x$enable_lua" = "xyes"])
 626
 627 dnl Check for curl (only if you want to compile the curl plugin).
 628 AC_ARG_WITH([curl],
 629     [AS_HELP_STRING([--without-curl],
 630                     [disable curl plugin @<:@default=check@:>@])],
 631     [],
 632     [with_curl=check])
 633 AS_IF([test "$with_curl" != "no"],[
 634     PKG_CHECK_MODULES([CURL], [libcurl],[
 635         AC_SUBST([CURL_CFLAGS])
 636         AC_SUBST([CURL_LIBS])
 637         AC_DEFINE([HAVE_CURL],[1],[curl found at compile time.])
 638         AC_CHECK_DECL([CURLOPT_UNIX_SOCKET_PATH], [
 639             AC_DEFINE([HAVE_CURLOPT_UNIX_SOCKET_PATH],[1],
 640                       [CURLOPT_UNIX_SOCKET_PATH found at compile time.])
 641             ], [], [#include <curl/curl.h>])
 642     ],
 643     [AC_MSG_WARN([curl not found, curl plugin will be disabled])])
 644 ])
 645 AM_CONDITIONAL([HAVE_CURL],[test "x$CURL_LIBS" != "x"])
 646
 647 dnl Check for libssh (only if you want to compile the ssh plugin).
 648 AC_ARG_WITH([ssh],
 649     [AS_HELP_STRING([--without-ssh],
 650                     [disable ssh plugin @<:@default=check@:>@])],
 651     [],
 652     [with_ssh=check])
 653 AS_IF([test "$with_ssh" != "no"],[
 654     PKG_CHECK_MODULES([SSH], [libssh >= 0.8.0],[
 655         AC_SUBST([SSH_CFLAGS])
 656         AC_SUBST([SSH_LIBS])
 657     ],
 658     [AC_MSG_WARN([libssh not found, ssh plugin will be disabled])])
 659 ])
 660 AM_CONDITIONAL([HAVE_SSH],[test "x$SSH_LIBS" != "x"])
 661
 662 dnl Check for genisoimage or mkisofs
 663 dnl (only if you want to compile the iso plugin).
 664 ISOPROG="no"
 665 AC_ARG_WITH([iso],
 666     [AS_HELP_STRING([--without-iso],
 667                     [disable iso plugin @<:@default=check@:>@])],
 668     [],
 669     [with_iso=check])
 670 AS_IF([test "$with_iso" != "no"],[
 671     AC_CHECK_PROG([GENISOIMAGE],[genisoimage],[genisoimage],[no])
 672     AC_CHECK_PROG([MKISOFS],[mkisofs],[mkisofs],[no])
 673     AS_IF([test "x$GENISOIMAGE" != "xno"],[
 674         ISOPROG="$GENISOIMAGE"
 675     ],[
 676         AS_IF([test "x$MKISOFS" != "xno"],[
 677             ISOPROG="$MKISOFS"
 678         ])
 679     ])
 680     AS_IF([test "x$ISOPROG" != "xno"],[
 681         AC_DEFINE_UNQUOTED([ISOPROG],["$ISOPROG"],
 682                            [Program used by iso plugin to make ISOs.])
 683     ])
 684 ])
 685 AC_SUBST([ISOPROG])
 686 AM_CONDITIONAL([HAVE_ISO],[test "x$ISOPROG" != "xno"])
 687
 688 dnl Check for libvirt (only if you want to compile the libvirt plugin).
 689 AC_ARG_WITH([libvirt],
 690     [AS_HELP_STRING([--without-libvirt],
 691                     [disable libvirt plugin @<:@default=check@:>@])],
 692     [],
 693     [with_libvirt=check])
 694 AS_IF([test "$with_libvirt" != "no"],[
 695     PKG_CHECK_MODULES([LIBVIRT], [libvirt],[
 696         AC_SUBST([LIBVIRT_CFLAGS])
 697         AC_SUBST([LIBVIRT_LIBS])
 698         AC_DEFINE([HAVE_LIBVIRT],[1],[libvirt found at compile time.])
 699     ],
 700     [AC_MSG_WARN([libvirt not found, libvirt plugin will be disabled])])
 701 ])
 702 AM_CONDITIONAL([HAVE_LIBVIRT],[test "x$LIBVIRT_LIBS" != "x"])
 703
 704 dnl Check for zlib (only if you want to compile the gzip plugin).
 705 AC_ARG_WITH([zlib],
 706     [AS_HELP_STRING([--without-zlib],
 707                     [disable gzip plugin @<:@default=check@:>@])],
 708     [],
 709     [with_zlib=check])
 710 AS_IF([test "$with_zlib" != "no"],[
 711     PKG_CHECK_MODULES([ZLIB], [zlib >= 1.2.3.5],[
 712         AC_SUBST([ZLIB_CFLAGS])
 713         AC_SUBST([ZLIB_LIBS])
 714         AC_DEFINE([HAVE_ZLIB],[1],[zlib found at compile time.])
 715     ],
 716     [AC_MSG_WARN([zlib >= 1.2.3.5 not found, gzip plugin will be disabled])])
 717 ])
 718 AM_CONDITIONAL([HAVE_ZLIB],[test "x$ZLIB_LIBS" != "x"])
 719
 720 dnl Check for liblzma (only if you want to compile the xz filter).
 721 AC_ARG_WITH([liblzma],
 722     [AS_HELP_STRING([--without-liblzma],
 723                     [disable xz filter @<:@default=check@:>@])],
 724     [],
 725     [with_liblzma=check])
 726 AS_IF([test "$with_liblzma" != "no"],[
 727     PKG_CHECK_MODULES([LIBLZMA], [liblzma],[
 728         AC_SUBST([LIBLZMA_CFLAGS])
 729         AC_SUBST([LIBLZMA_LIBS])
 730         AC_DEFINE([HAVE_LIBLZMA],[1],[liblzma found at compile time.])
 731     ],
 732     [AC_MSG_WARN([liblzma not found, xz filter will be disabled])])
 733 ])
 734 AM_CONDITIONAL([HAVE_LIBLZMA],[test "x$LIBLZMA_LIBS" != "x"])
 735
 736 dnl Check for libguestfs (only for the guestfs plugin and the test suite).
 737 AC_ARG_WITH([libguestfs],
 738     [AS_HELP_STRING([--without-libguestfs],
 739                     [disable guestfs plugin and tests @<:@default=check@:>@])],
 740     [],
 741     [with_libguestfs=check])
 742 AS_IF([test "$with_libguestfs" != "no"],[
 743     PKG_CHECK_MODULES([LIBGUESTFS], [libguestfs],[
 744         # Although the library was found, we want to make sure it supports nbd
 745         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 746 #include <guestfs.h>
 747         ]], [[
 748 #ifndef GUESTFS_ADD_DRIVE_OPTS_PROTOCOL
 749 #error unsupported
 750 #endif
 751         ]])], [
 752         AC_SUBST([LIBGUESTFS_CFLAGS])
 753         AC_SUBST([LIBGUESTFS_LIBS])
 754         AC_DEFINE([HAVE_LIBGUESTFS],[1],[libguestfs found at compile time.])
 755         ],[
 756         LIBGUESTFS_LIBS=
 757         AC_MSG_WARN([libguestfs too old, guestfs plugin and tests will be disabled])])
 758     ],
 759     [AC_MSG_WARN([libguestfs not found, guestfs plugin and tests will be disabled])])
 760 ])
 761 AM_CONDITIONAL([HAVE_LIBGUESTFS],[test "x$LIBGUESTFS_LIBS" != "x"])
 762
 763 dnl Check for guestfish (only needed for some of the tests).
 764 AC_CHECK_PROG([GUESTFISH], [guestfish], [guestfish], [no])
 765 AM_CONDITIONAL([HAVE_GUESTFISH], [test "x$GUESTFISH" != "xno"])
 766
 767 dnl Check for ext2fs and com_err, for the ext2 plugin.
 768 AC_ARG_WITH([ext2],
 769     [AS_HELP_STRING([--without-ext2],
 770                     [disable ext2 plugin @<:@default=check@:>@])],
 771     [],
 772     [with_ext2=check])
 773 AS_IF([test "$with_ext2" != "no"], [
 774     PKG_CHECK_MODULES([EXT2FS], [ext2fs], [
 775         AC_SUBST([EXT2FS_CFLAGS])
 776         AC_SUBST([EXT2FS_LIBS])
 777         AC_DEFINE([HAVE_EXT2FS],[1],[ext2fs found at compile time.])
 778     ],
 779     [AC_MSG_WARN([ext2fs not found, ext2 plugin will be disabled])])
 780     PKG_CHECK_MODULES([COM_ERR], [com_err], [
 781         AC_SUBST([COM_ERR_CFLAGS])
 782         AC_SUBST([COM_ERR_LIBS])
 783         AC_DEFINE([HAVE_COM_ERR],[1],[com_err found at compile time.])
 784     ],
 785     [AC_MSG_WARN([com_err not found, ext2 plugin will be disabled])])
 786 ])
 787 AM_CONDITIONAL([HAVE_EXT2],
 788                [test "x$EXT2FS_LIBS" != "x" && test "x$COM_ERR_LIBS" != "x"])
 789
 790 dnl Check if the user wants to disable VDDK support.
 791 dnl See plugins/vddk/README.VDDK.
 792 AC_ARG_ENABLE([vddk],
 793     [AS_HELP_STRING([--disable-vddk],
 794                     [disable VMware VDDK plugin])],
 795     [],
 796     [enable_vddk=yes])
 797 AM_CONDITIONAL([HAVE_VDDK], [test "x$enable_vddk" = "xyes"])
 798
 799 dnl List of plugins and filters.
 800 lang_plugins="\
 801         lua \
 802         ocaml \
 803         perl \
 804         python \
 805         ruby \
 806         rust \
 807         sh \
 808         tcl \
 809         "
 810 non_lang_plugins="\
 811         curl \
 812         data \
 813         example1 \
 814         example2 \
 815         example3 \
 816         example4 \
 817         ext2 \
 818         file \
 819         floppy \
 820         full \
 821         guestfs \
 822         gzip \
 823         iso \
 824         libvirt \
 825         linuxdisk \
 826         memory \
 827         nbd \
 828         null \
 829         partitioning \
 830         pattern \
 831         random \
 832         split \
 833         ssh \
 834         streaming \
 835         tar \
 836         vddk \
 837         zero \
 838         "
 839 plugins="$(echo $(printf %s\\n $lang_plugins $non_lang_plugins | sort -u))"
 840 filters="\
 841         blocksize \
 842         cache \
 843         cow \
 844         delay \
 845         error \
 846         fua \
 847         log \
 848         nocache \
 849         noextents \
 850         noparallel \
 851         nozero \
 852         offset \
 853         partition \
 854         rate \
 855         readahead \
 856         stats \
 857         truncate \
 858         xz \
 859         "
 860 AC_SUBST([plugins])
 861 AC_SUBST([lang_plugins])
 862 AC_SUBST([non_lang_plugins])
 863 AC_SUBST([filters])
 864
 865 dnl Produce output files.
 866 AC_CONFIG_HEADERS([config.h])
 867 AC_CONFIG_FILES([podwrapper.pl],
 868                 [chmod +x,-w podwrapper.pl])
 869 AC_CONFIG_FILES([Makefile
 870                  bash/Makefile
 871                  common/bitmap/Makefile
 872                  common/gpt/Makefile
 873                  common/include/Makefile
 874                  common/protocol/Makefile
 875                  common/regions/Makefile
 876                  common/sparse/Makefile
 877                  common/utils/Makefile
 878                  docs/Makefile
 879                  include/Makefile
 880                  plugins/Makefile
 881                  plugins/curl/Makefile
 882                  plugins/data/Makefile
 883                  plugins/example1/Makefile
 884                  plugins/example2/Makefile
 885                  plugins/example3/Makefile
 886                  plugins/example4/Makefile
 887                  plugins/ext2/Makefile
 888                  plugins/file/Makefile
 889                  plugins/floppy/Makefile
 890                  plugins/full/Makefile
 891                  plugins/guestfs/Makefile
 892                  plugins/gzip/Makefile
 893                  plugins/iso/Makefile
 894                  plugins/libvirt/Makefile
 895                  plugins/linuxdisk/Makefile
 896                  plugins/lua/Makefile
 897                  plugins/memory/Makefile
 898                  plugins/nbd/Makefile
 899                  plugins/null/Makefile
 900                  plugins/ocaml/Makefile
 901                  plugins/partitioning/Makefile
 902                  plugins/pattern/Makefile
 903                  plugins/perl/Makefile
 904                  plugins/python/Makefile
 905                  plugins/random/Makefile
 906                  plugins/ruby/Makefile
 907                  plugins/rust/Cargo.toml
 908                  plugins/rust/Makefile
 909                  plugins/sh/Makefile
 910                  plugins/ssh/Makefile
 911                  plugins/split/Makefile
 912                  plugins/streaming/Makefile
 913                  plugins/tar/Makefile
 914                  plugins/tcl/Makefile
 915                  plugins/vddk/Makefile
 916                  plugins/zero/Makefile
 917                  filters/Makefile
 918                  filters/blocksize/Makefile
 919                  filters/cache/Makefile
 920                  filters/cow/Makefile
 921                  filters/delay/Makefile
 922                  filters/error/Makefile
 923                  filters/fua/Makefile
 924                  filters/log/Makefile
 925                  filters/nocache/Makefile
 926                  filters/noextents/Makefile
 927                  filters/noparallel/Makefile
 928                  filters/nozero/Makefile
 929                  filters/offset/Makefile
 930                  filters/partition/Makefile
 931                  filters/rate/Makefile
 932                  filters/readahead/Makefile
 933                  filters/stats/Makefile
 934                  filters/truncate/Makefile
 935                  filters/xz/Makefile
 936                  fuzzing/Makefile
 937                  server/Makefile
 938                  server/nbdkit.pc
 939                  tests/functions.sh
 940                  tests/Makefile
 941                  valgrind/Makefile])
 942
 943 AC_OUTPUT
 944
 945 dnl Summary.
 946 echo
 947 echo
 948 echo "----------------------------------------------------------------------"
 949 echo "Thank you for downloading $PACKAGE_STRING"
 950 echo
 951 echo "This is how we have configured the optional components for you today:"
 952 echo
 953
 954 feature ()
 955 {
 956     echo -n "    $1"
 957     shift
 958     if $@; then echo "yes"; else echo "no"; fi
 959 }
 960
 961 echo "Optional server features:"
 962 echo
 963 feature "bash-completion ........................ " \
 964         test "x$HAVE_BASH_COMPLETION_TRUE" = "x"
 965 feature "manual pages ........................... " \
 966         test "x$HAVE_POD_TRUE" = "x"
 967 feature "SELinux ................................ " \
 968         test "x$LIBSELINUX_LIBS" != "x"
 969 feature "TLS .................................... " \
 970         test "x$GNUTLS_LIBS" != "x"
 971
 972 echo
 973 echo "Optional plugins:"
 974 echo
 975 feature "curl ................................... " \
 976         test "x$HAVE_CURL_TRUE" = "x"
 977 feature "example4 ............................... " \
 978         test "x$HAVE_PERL_TRUE" = "x"
 979 feature "ext2 ................................... " \
 980         test "x$HAVE_EXT2_TRUE" = "x"
 981 feature "floppy ................................. " \
 982         test "x$HAVE_ICONV_TRUE" = "x"
 983 feature "guestfs ................................ " \
 984         test "x$HAVE_LIBGUESTFS_TRUE" = "x"
 985 feature "gzip ................................... " \
 986         test "x$HAVE_ZLIB_TRUE" = "x"
 987 feature "iso .................................... " \
 988         test "x$HAVE_ISO_TRUE" = "x"
 989 feature "libvirt ................................ " \
 990         test "x$HAVE_LIBVIRT_TRUE" = "x"
 991 feature "ssh .................................... " \
 992         test "x$HAVE_SSH_TRUE" = "x"
 993 feature "tar .................................... " \
 994         test "x$HAVE_PERL_TRUE" = "x"
 995 feature "vddk ................................... " \
 996         test "x$HAVE_VDDK_TRUE" = "x"
 997
 998
 999 echo
1000 echo "Languages:"
1001 echo
1002 feature "lua .................................... " \
1003         test "x$HAVE_LUA_TRUE" = "x"
1004 feature "ocaml .................................. " \
1005         test "x$HAVE_OCAML_TRUE" = "x"
1006 feature "perl ................................... " \
1007         test "x$HAVE_PERL_TRUE" = "x"
1008 feature "python ................................. " \
1009         test "x$HAVE_PYTHON_TRUE" = "x"
1010 feature "ruby ................................... " \
1011         test "x$HAVE_RUBY_TRUE" = "x"
1012 feature "rust ................................... " \
1013         test "x$HAVE_RUST_TRUE" = "x"
1014 feature "tcl .................................... " \
1015         test "x$HAVE_TCL_TRUE" = "x"
1016
1017
1018 echo
1019 echo "Optional filters:"
1020 echo
1021 feature "xz ..................................... " \
1022         test "x$HAVE_LIBLZMA_TRUE" = "x"
1023
1024 echo
1025 echo "If any optional component is configured ‘no’ when you expected ‘yes’"
1026 echo "then you should check the preceding messages and README."
1027 echo
1028 echo "Please report bugs back to the mailing list:"
1029 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
1030 echo
1031 echo "Next you should type 'make' to build the package,"
1032 echo "then 'make check' to run the tests."