configure.ac

   1 # nbdkit
   2 # Copyright (C) 2013-2019 Red Hat Inc.
   3 #
   4 # Redistribution and use in source and binary forms, with or without
   5 # modification, are permitted provided that the following conditions are
   6 # met:
   7 #
   8 # * Redistributions of source code must retain the above copyright
   9 # notice, this list of conditions and the following disclaimer.
  10 #
  11 # * Redistributions in binary form must reproduce the above copyright
  12 # notice, this list of conditions and the following disclaimer in the
  13 # documentation and/or other materials provided with the distribution.
  14 #
  15 # * Neither the name of Red Hat nor the names of its contributors may be
  16 # used to endorse or promote products derived from this software without
  17 # specific prior written permission.
  18 #
  19 # THIS SOFTWARE IS PROVIDED BY RED HAT AND CONTRIBUTORS ''AS IS'' AND
  20 # ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
  21 # THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A
  22 # PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL RED HAT OR
  23 # CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  24 # SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  25 # LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF
  26 # USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
  27 # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
  28 # OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
  29 # OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30 # SUCH DAMAGE.
  31
  32 AC_INIT([nbdkit], [1.13.4])
  33 AC_CONFIG_MACRO_DIR([m4])
  34 m4_ifdef([AC_USE_SYSTEM_EXTENSIONS],[],
  35          [m4_define([AC_USE_SYSTEM_EXTENSIONS],[])])
  36 AC_USE_SYSTEM_EXTENSIONS
  37 AC_SYS_LARGEFILE
  38
  39 dnl NB: Do not [quote] this parameter.
  40 AM_INIT_AUTOMAKE(foreign)
  41 AC_PROG_LIBTOOL
  42 LT_INIT
  43
  44 AC_CANONICAL_HOST
  45
  46 AC_PROG_SED
  47
  48 dnl Check for basic C environment.
  49 AC_PROG_CC_STDC
  50 AC_PROG_INSTALL
  51 AC_PROG_CPP
  52 AC_CANONICAL_HOST
  53
  54 AC_C_PROTOTYPES
  55 test "x$U" != "x" && AC_MSG_ERROR([Compiler not ANSI compliant])
  56
  57 AM_PROG_CC_C_O
  58
  59 dnl Check for C++ (optional, we just use this to test the header
  60 dnl can be included from C++ code).
  61 AC_PROG_CXX
  62
  63 dnl The C++ compiler test is pretty useless because even if it fails
  64 dnl it sets CXX=g++.  So test the compiler actually works.
  65 AC_MSG_CHECKING([if the C++ compiler really really works])
  66 AS_IF([$CXX --version >&AS_MESSAGE_LOG_FD 2>&1],[have_cxx=yes],[have_cxx=no])
  67 AC_MSG_RESULT([$have_cxx])
  68 AM_CONDITIONAL([HAVE_CXX], [test "$have_cxx" = "yes"])
  69
  70 AC_ARG_ENABLE([gcc-warnings],
  71     [AS_HELP_STRING([--enable-gcc-warnings],
  72                     [turn on lots of GCC warnings (for developers)])],
  73      [case $enableval in
  74       yes|no) ;;
  75       *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  76       esac
  77       gcc_warnings=$enableval],
  78       [gcc_warnings=no]
  79 )
  80 if test "x$gcc_warnings" = "xyes"; then
  81     WARNINGS_CFLAGS="-Wall -Werror"
  82     AC_SUBST([WARNINGS_CFLAGS])
  83 fi
  84
  85 dnl Check if the compiler supports -std=c90 flag.  This is only used
  86 dnl during a test.  OpenBSD GCC does not support this flag so we skip
  87 dnl that test.
  88 AC_MSG_CHECKING([if the compiler supports -std=c90 for ANSI C test])
  89 old_CFLAGS="$CFLAGS"
  90 CFLAGS="$CFLAGS -std=c90"
  91 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
  92     [supports_std_c90=yes],
  93     [supports_std_c90=no])
  94 CFLAGS="$old_CFLAGS"
  95 AC_MSG_RESULT([$supports_std_c90])
  96 AM_CONDITIONAL([CAN_TEST_ANSI_C], [test "x$supports_std_c90" = "xyes"])
  97
  98 dnl On Haiku we must use BSD-compatibility headers to get the endian
  99 dnl macros we use.
 100 AC_MSG_CHECKING(whether OS-dependent include paths are required)
 101 AS_CASE([$host_os],
 102   [haiku*], [CFLAGS="$CFLAGS -I`findpaths -p /system B_FIND_PATH_HEADERS_DIRECTORY`/bsd"; AC_MSG_RESULT(yes)],
 103   [AC_MSG_RESULT(no)]
 104 )
 105
 106 dnl On Linux /tmp is often tmpfs which is not large enough, so use /var/tmp.
 107 dnl But Haiku only has /tmp.
 108 AC_MSG_CHECKING([for temporary directory for large files])
 109 AS_CASE([$host_os],
 110   [haiku*], [LARGE_TMPDIR=/tmp],
 111   [LARGE_TMPDIR=/var/tmp]
 112 )
 113 AC_MSG_RESULT([$LARGE_TMPDIR])
 114 AC_DEFINE_UNQUOTED([LARGE_TMPDIR],["$LARGE_TMPDIR"],
 115                    [Temporary directory for large files])
 116
 117 dnl Check if libc has program_invocation_short_name.
 118 AC_CHECK_DECLS([program_invocation_short_name], [], [], [#include <errno.h>])
 119
 120 AX_PTHREAD
 121
 122 dnl Check if __attribute__((cleanup(...))) works.
 123 dnl Set -Werror, otherwise gcc will only emit a warning for attributes
 124 dnl that it doesn't understand.
 125 acx_nbdkit_save_CFLAGS="${CFLAGS}"
 126 CFLAGS="${CFLAGS} -Werror"
 127 AC_MSG_CHECKING([if __attribute__((cleanup(...))) works with this compiler])
 128 AC_COMPILE_IFELSE([
 129 AC_LANG_SOURCE([[
 130 #include <stdio.h>
 131 #include <stdlib.h>
 132
 133 void
 134 freep (void *ptr)
 135 {
 136   exit (EXIT_SUCCESS);
 137 }
 138
 139 void
 140 test (void)
 141 {
 142   __attribute__((cleanup(freep))) char *ptr = malloc (100);
 143 }
 144
 145 int
 146 main (int argc, char *argv[])
 147 {
 148   test ();
 149   exit (EXIT_FAILURE);
 150 }
 151 ]])
 152     ],[
 153     AC_MSG_RESULT([yes])
 154     ],[
 155     AC_MSG_RESULT([no])
 156     AC_MSG_ERROR(
 157 ['__attribute__((cleanup(...)))' does not work.
 158
 159 You may not be using a sufficiently recent version of GCC or CLANG, or
 160 you may be using a C compiler which does not support this attribute,
 161 or the configure test may be wrong.
 162
 163 This code requires the attribute to work for proper locking between threads.])])
 164 CFLAGS="${acx_nbdkit_save_CFLAGS}"
 165
 166 dnl Check for __auto_type (GCC extension).
 167 AC_MSG_CHECKING([if __auto_type is available in this compiler])
 168 AC_COMPILE_IFELSE([
 169 AC_LANG_SOURCE([[
 170 static int
 171 test (int a)
 172 {
 173   __auto_type at = a;
 174   return at;
 175 }
 176 ]])
 177     ],[
 178     AC_MSG_RESULT([yes])
 179     AC_DEFINE([HAVE_AUTO_TYPE],[1],[__auto_type is available])
 180     ],[
 181     AC_MSG_RESULT([no])
 182     ]
 183 )
 184
 185 dnl Check for other headers, all optional.
 186 AC_CHECK_HEADERS([\
 187         alloca.h \
 188         byteswap.h \
 189         endian.h \
 190         sys/endian.h \
 191         sys/prctl.h \
 192         sys/procctl.h])
 193
 194 dnl Check for functions in libc, all optional.
 195 AC_CHECK_FUNCS([\
 196         fdatasync \
 197         get_current_dir_name \
 198         mkostemp \
 199         posix_fadvise])
 200
 201 dnl Check whether printf("%m") works
 202 AC_CACHE_CHECK([whether the printf family supports %m],
 203   [nbdkit_cv_func_printf_percent_m],
 204   [AC_RUN_IFELSE(
 205     [AC_LANG_PROGRAM([[
 206 #include <stdio.h>
 207 #include <string.h>
 208 #include <errno.h>
 209     ]], [[
 210     char buf[200] = "";
 211     errno = EINVAL;
 212     snprintf(buf, sizeof buf, "%m");
 213     return !!strcmp (buf, strerror (EINVAL));
 214     ]])],
 215     [nbdkit_cv_func_printf_percent_m=yes],
 216     [nbdkit_cv_func_printf_percent_m=no],
 217     [[
 218     case "$host_os" in
 219       *-gnu* | gnu*) nbdkit_cv_func_printf_percent_m=yes;;
 220       *) nbdkit_cv_func_printf_percent_m="guessing no";;
 221     esac
 222     ]])])
 223 AS_IF([test "x$nbdkit_cv_func_printf_percent_m" = xyes],
 224   [AC_DEFINE([HAVE_VFPRINTF_PERCENT_M],[1],
 225     [Define to 1 if vfprintf supports %m.])])
 226
 227 old_LIBS="$LIBS"
 228 AC_SEARCH_LIBS([dlsym], [dl dld], [
 229         AS_IF([test "x$ac_cv_search_dlsym" != "xnone required"],
 230             [DL_LIBS="$ac_cv_search_dlsym"], [DL_LIBS=])
 231         AC_SUBST([DL_LIBS])
 232     ], [AC_MSG_ERROR([unable to find the dlsym() function])
 233 ])
 234 LIBS="$old_LIBS"
 235
 236 dnl Test if <iconv.h> header can build working binaries.
 237 dnl
 238 dnl On FreeBSD: iconv and libiconv both exist, both can be installed
 239 dnl simultaneously, <iconv.h> can exist in two separate places, and
 240 dnl if you get the wrong header/library mix everything breaks.
 241 dnl
 242 dnl On Haiku: libiconv is required to link to iconv_* functions.
 243 AC_ARG_WITH([iconv],
 244     [AS_HELP_STRING([--without-iconv],
 245                     [don't try to link against iconv @<:@default=check@:>@])],
 246     [],
 247     [with_iconv=check])
 248 AS_IF([test "x$with_iconv" != "xno"],[
 249     AC_CHECK_HEADER([iconv.h],[
 250         AC_MSG_CHECKING([if <iconv.h> can be used to link a program])
 251         AC_LINK_IFELSE([
 252 AC_LANG_SOURCE([[
 253 #include <stdio.h>
 254 #include <stdlib.h>
 255 #include <iconv.h>
 256 int
 257 main (int argc, char *argv[])
 258 {
 259   iconv_t ic = iconv_open ("", "");
 260   iconv_close (ic);
 261   exit (0);
 262 }
 263 ]])
 264             ],[
 265             AC_MSG_RESULT([yes])
 266             iconv_working=yes
 267             ],[
 268             AC_MSG_RESULT([no])
 269             ])
 270         ])
 271     ])
 272 AM_CONDITIONAL([HAVE_ICONV], [test "x$iconv_working" = "xyes"])
 273
 274 dnl Don't use linker script for the server on FreeBSD because
 275 dnl FreeBSD's linker is broken.  See eg:
 276 dnl https://bugs.freebsd.org/bugzilla/show_bug.cgi?id=190851
 277 AC_MSG_CHECKING([if we should use a linker script for the server])
 278 AS_CASE([$host_os],
 279   [freebsd*], [use_linker_script_for_server=no],
 280   [use_linker_script_for_server=yes]
 281 )
 282 AC_MSG_RESULT([$use_linker_script_for_server])
 283 AM_CONDITIONAL([USE_LINKER_SCRIPT_FOR_SERVER],
 284                [test "x$use_linker_script_for_server" = "xyes"])
 285
 286 dnl Check if -rdynamic linker flag works.
 287 acx_nbdkit_save_LDFLAGS="${LDFLAGS}"
 288 LDFLAGS="${LDFLAGS} -rdynamic"
 289 AC_MSG_CHECKING([if linker supports -rdynamic])
 290 AC_LINK_IFELSE([
 291 AC_LANG_SOURCE([[
 292 #include <stdlib.h>
 293 int
 294 main (int argc, char *argv[])
 295 {
 296   exit (EXIT_SUCCESS);
 297 }
 298 ]])
 299     ],[
 300     AC_MSG_RESULT([yes])
 301     DL_LDFLAGS=-rdynamic
 302     ],[
 303     AC_MSG_RESULT([no])
 304 ])
 305 dnl restore CFLAGS
 306 LDFLAGS="${acx_nbdkit_save_LDFLAGS}"
 307 AC_SUBST([DL_LDFLAGS])
 308
 309 dnl Check for dladdr in -ldl, optional.  This is a glibc extension.
 310 old_LIBS="$LIBS"
 311 LIBS="$DL_LIBS $LIBS"
 312 AC_CHECK_FUNCS([dladdr])
 313 LIBS="$old_LIBS"
 314
 315 AC_SEARCH_LIBS([getaddrinfo], [network socket])
 316
 317 dnl Check for SELinux socket labelling (optional).
 318 PKG_CHECK_MODULES([LIBSELINUX], [libselinux], [
 319     AC_SUBST([LIBSELINUX_CFLAGS])
 320     AC_SUBST([LIBSELINUX_LIBS])
 321     AC_DEFINE([HAVE_LIBSELINUX],[1],[libselinux found at compile time.])
 322 ], [
 323     AC_MSG_WARN([libselinux not found, SELinux socket labelling support will be disabled.])
 324 ])
 325
 326 dnl Check for GnuTLS (optional, for TLS support).
 327 PKG_CHECK_MODULES([GNUTLS], [gnutls >= 3.3.0], [
 328     AC_SUBST([GNUTLS_CFLAGS])
 329     AC_SUBST([GNUTLS_LIBS])
 330     AC_DEFINE([HAVE_GNUTLS],[1],[gnutls found at compile time.])
 331 ], [
 332     AC_MSG_WARN([gnutls not found or < 3.3.0, TLS support will be disabled.])
 333 ])
 334
 335 AS_IF([test "$GNUTLS_LIBS" != ""],[
 336     AC_MSG_CHECKING([for default TLS session priority string])
 337     AC_ARG_WITH([tls-priority],
 338         [AS_HELP_STRING([--with-tls-priority],
 339                         [default TLS session priority string @<:@default=NORMAL@:>@])],
 340         [tls_priority=$withval],
 341         [tls_priority=NORMAL])
 342     AC_MSG_RESULT([$tls_priority])
 343     AC_DEFINE_UNQUOTED([TLS_PRIORITY],["$tls_priority"],
 344                        [Default TLS session priority string])
 345
 346     # Check for APIs which may not be present.
 347     old_LIBS="$LIBS"
 348     LIBS="$GNUTLS_LIBS $LIBS"
 349     AC_CHECK_FUNCS([\
 350         gnutls_base64_decode2 \
 351         gnutls_certificate_set_known_dh_params \
 352         gnutls_session_set_verify_cert])
 353     LIBS="$old_LIBS"
 354 ])
 355
 356 dnl Check for valgrind.
 357 AC_CHECK_PROG([VALGRIND],[valgrind],[valgrind],[no])
 358
 359 dnl If valgrind headers are available (optional).
 360 dnl Since this is only useful for developers, you have to enable
 361 dnl it explicitly using --enable-valgrind.
 362 AC_ARG_ENABLE([valgrind],
 363     [AS_HELP_STRING([--enable-valgrind],
 364                     [enable Valgrind extensions (for developers)])],
 365     [enable_valgrind=yes],
 366     [enable_valgrind=no])
 367 AS_IF([test "x$enable_valgrind" = "xyes"],[
 368     PKG_CHECK_MODULES([VALGRIND], [valgrind], [
 369         AC_SUBST([VALGRIND_CFLAGS])
 370         AC_SUBST([VALGRIND_LIBS])
 371         AC_DEFINE([HAVE_VALGRIND],[1],[Valgrind headers found at compile time])
 372     ],[
 373         AC_MSG_ERROR([--enable-valgrind given, but Valgrind headers are not available])
 374     ])
 375 ])
 376
 377 dnl Bash completion.
 378 PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0], [
 379     bash_completion=yes
 380     AC_MSG_CHECKING([for bash-completions directory])
 381     m4_ifdef([PKG_CHECK_VAR],[
 382         PKG_CHECK_VAR(bashcompdir, [bash-completion], [completionsdir])
 383     ])
 384     AS_IF([test -z "$bashcompdir"], [
 385         bashcompdir="${sysconfdir}/bash_completion.d"
 386     ])
 387     AC_MSG_RESULT([$bashcompdir])
 388     AC_SUBST([bashcompdir])
 389 ],[
 390     bash_completion=no
 391     AC_MSG_WARN([bash-completion not installed])
 392 ])
 393 AM_CONDITIONAL([HAVE_BASH_COMPLETION],[test "x$bash_completion" = "xyes"])
 394
 395 dnl Check we have enough to run podwrapper.
 396 AC_CHECK_PROG([PERL],[perl],[perl],[no])
 397 AS_IF([test "x$PERL" != "xno"],[
 398     AC_MSG_CHECKING([if we have perl Pod::Man and Pod::Simple])
 399     AS_IF([$PERL -MPod::Man -MPod::Simple -e 1 >&AS_MESSAGE_LOG_FD 2>&1],[
 400         enable_pod=yes
 401     ],[
 402         enable_pod=no
 403     ])
 404     AC_MSG_RESULT([$enable_pod])
 405 ])
 406 AM_CONDITIONAL([HAVE_POD],
 407                [test "x$PERL" != "xno" && test "x$enable_pod" = "xyes"])
 408
 409 dnl Define the path to the podwrapper program.
 410 PODWRAPPER="$PERL $(pwd)/podwrapper.pl"
 411 AC_SUBST([PODWRAPPER])
 412
 413 dnl Allow all plugins and filters to be disabled.
 414 AC_ARG_ENABLE([plugins],
 415     [AS_HELP_STRING([--disable-plugins],
 416                     [disable all bundled plugins and filters])])
 417 AM_CONDITIONAL([HAVE_PLUGINS], [test "x$enable_plugins" != "xno"])
 418
 419 dnl Check for Perl, for embedding in the perl plugin.
 420 dnl Note that the perl binary is checked above.
 421 AC_ARG_ENABLE([perl],
 422     [AS_HELP_STRING([--disable-perl], [disable Perl embed plugin])],
 423     [],
 424     [enable_perl=yes])
 425 AS_IF([test "x$PERL" != "xno" && test "x$enable_perl" != "xno"],[
 426     dnl Check for Perl archlib.
 427     AC_MSG_CHECKING([for Perl embed archlib])
 428     PERL_ARCHLIB="$($PERL -MConfig -e 'print $Config{archlib}')"
 429     AS_IF([ test -n "$PERL_ARCHLIB" ],[
 430         AC_MSG_RESULT([$PERL_ARCHLIB])
 431     ],[
 432         AC_MSG_NOTICE([Perl embed module disabled])
 433         enable_perl=no
 434     ])
 435
 436     dnl Check for Perl CFLAGS.
 437     AC_MSG_CHECKING([for Perl embed CFLAGS])
 438     PERL_CFLAGS="$($PERL -MExtUtils::Embed -e 'ccflags')"
 439     AS_IF([ test -n "$PERL_CFLAGS" ],[
 440         AC_MSG_RESULT([$PERL_CFLAGS])
 441     ],[
 442         AC_MSG_NOTICE([Perl embed module disabled])
 443         enable_perl=no
 444     ])
 445
 446     dnl Check for Perl LDOPTS.
 447     AC_MSG_CHECKING([for Perl embed LDOPTS])
 448     PERL_LDOPTS="$($PERL -MExtUtils::Embed -e 'ldopts')"
 449     AC_MSG_RESULT([$PERL_LDOPTS])
 450
 451     dnl XXX Could check these actually work.
 452 ])
 453 AM_CONDITIONAL([HAVE_PERL],[test "x$enable_perl" != "xno" && test "x$PERL" != "xno"])
 454 AC_SUBST([PERL_ARCHLIB])
 455 AC_SUBST([PERL_CFLAGS])
 456 AC_SUBST([PERL_LDOPTS])
 457
 458 dnl Check for Python, for embedding in the python plugin.
 459 AC_CHECK_PROG([PYTHON],[python],[python],[no])
 460 AC_ARG_ENABLE([python],
 461     [AS_HELP_STRING([--disable-python], [disable Python embed plugin])],
 462     [],
 463     [enable_python=yes])
 464 AS_IF([test "x$PYTHON" != "xno" && test "x$enable_python" != "xno"],[
 465     AC_MSG_CHECKING([version of $PYTHON])
 466     PYTHON_VERSION_MAJOR=`$PYTHON -c "import sys; print (sys.version_info@<:@0@:>@)"`
 467     PYTHON_VERSION_MINOR=`$PYTHON -c "import sys; print (sys.version_info@<:@1@:>@)"`
 468     PYTHON_VERSION="$PYTHON_VERSION_MAJOR.$PYTHON_VERSION_MINOR"
 469     AS_IF([test -n "$PYTHON_VERSION"],[
 470         AC_MSG_RESULT([$PYTHON_VERSION])
 471     ],[
 472         AC_MSG_NOTICE([Python embed module disabled])
 473         enable_python=no
 474     ])
 475
 476     dnl Check for Python CFLAGS, libraries.
 477     dnl On Debian: python-X.Y.pc
 478     PKG_CHECK_MODULES([PYTHON], [python-"$PYTHON_VERSION"], [
 479         AC_SUBST([PYTHON_CFLAGS])
 480         AC_SUBST([PYTHON_LIBS])
 481         AC_SUBST([PYTHON_VERSION])
 482         AC_DEFINE([HAVE_PYTHON],[1],[Python library found at compile time])
 483     ],[
 484         dnl On Fedora: python.pc
 485         PKG_CHECK_MODULES([PYTHON], [python], [
 486             AC_SUBST([PYTHON_CFLAGS])
 487             AC_SUBST([PYTHON_LIBS])
 488             AC_SUBST([PYTHON_VERSION])
 489             AC_DEFINE([HAVE_PYTHON],[1],[Python library found at compile time])
 490         ],[
 491             AC_MSG_WARN([python $PYTHON_VERSION not found])
 492             enable_python=no
 493         ])
 494     ])
 495
 496     dnl Check for various functions needed by the bindings.
 497     old_LIBS="$LIBS"
 498
 499     PYTHON_BLDLIBRARY=`$PYTHON -c "import distutils.sysconfig; \
 500         print (distutils.sysconfig.get_config_var('BLDLIBRARY'))"`
 501     AC_CHECK_LIB([c],[PyString_FromString],
 502                  [AC_DEFINE([HAVE_PYSTRING_FROMSTRING],1,
 503                             [Found PyString_FromString in libpython.])],
 504                  [],[$PYTHON_BLDLIBRARY])
 505     AC_CHECK_LIB([c],[PyString_AsString],
 506                  [AC_DEFINE([HAVE_PYSTRING_ASSTRING],1,
 507                             [Found PyString_AsString in libpython.])],
 508                  [],[$PYTHON_BLDLIBRARY])
 509     AC_CHECK_LIB([c],[PyUnicode_AsUTF8],
 510                  [AC_DEFINE([HAVE_PYUNICODE_ASUTF8],1,
 511                             [Found PyUnicode_AsUTF8 in libpython.])],
 512                  [],[$PYTHON_BLDLIBRARY])
 513
 514     LIBS="$old_LIBS"
 515
 516 ])
 517 AM_CONDITIONAL([HAVE_PYTHON],[test "x$enable_python" != "xno" && test "x$PYTHON" != "xno"])
 518 AC_SUBST([PYTHON_CFLAGS])
 519 AC_SUBST([PYTHON_LIBS])
 520 AC_SUBST([PYTHON_LDFLAGS])
 521
 522 dnl For the OCaml plugin, you can set OCAMLOPTFLAGS before running
 523 dnl ./configure to specify any extra flags you want to pass to
 524 dnl ocamlopt.
 525 AC_SUBST([OCAMLOPTFLAGS])
 526
 527 dnl Check for OCaml, for embedding in the ocaml plugin.
 528 AC_PROG_OCAML
 529 AC_ARG_ENABLE([ocaml],
 530     [AS_HELP_STRING([--disable-ocaml], [disable OCaml embed plugin])],
 531     [],
 532     [enable_ocaml=yes])
 533 AS_IF([test "x$OCAMLOPT" != "xno" && test "x$enable_ocaml" != "xno"],[
 534     dnl Check OCaml can create a shared library (see README for details).
 535     AC_MSG_CHECKING([if $OCAMLOPT can create a shared library])
 536     echo 'print_endline "test"' > conftest.ml
 537     AS_IF([$OCAMLOPT $OCAMLOPTFLAGS -output-obj -runtime-variant _pic -o conftest.so conftest.ml >&AS_MESSAGE_LOG_FD 2>&1],[
 538         AC_MSG_RESULT([yes])
 539         ocaml_link_shared=yes
 540     ],[
 541         AC_MSG_RESULT([no])
 542     ])
 543     rm -f conftest.ml conftest.cmi conftest.cmx conftest.so conftest.o
 544 ])
 545 AM_CONDITIONAL([HAVE_OCAML],[test "x$OCAMLOPT" != "xno" &&
 546                              test "x$ocaml_link_shared" = "xyes"])
 547
 548 dnl For developing plugins in Rust, optional.
 549 AC_CHECK_PROG([CARGO],[cargo],[cargo],[no])
 550 AC_ARG_ENABLE([rust],
 551     [AS_HELP_STRING([--disable-rust], [disable Rust plugin])],
 552     [],
 553     [enable_rust=yes])
 554 AM_CONDITIONAL([HAVE_RUST],
 555                [test "x$CARGO" != "xno" && test "x$enable_rust" != "xno"])
 556
 557 dnl Check for Ruby, for embedding in the Ruby plugin.
 558 AC_CHECK_PROG([RUBY],[ruby],[ruby],[no])
 559 AC_ARG_ENABLE([ruby],
 560     [AS_HELP_STRING([--disable-ruby], [disable Ruby plugin])],
 561     [],
 562     [enable_ruby=yes])
 563 AS_IF([test "x$RUBY" != "xno" && test "x$enable_ruby" != "xno"],[
 564     PKG_CHECK_MODULES([RUBY], [ruby], [
 565         AC_SUBST([RUBY_CFLAGS])
 566         AC_SUBST([RUBY_LIBS])
 567     ],[
 568         AC_MSG_WARN([ruby not found])
 569         enable_ruby=no
 570     ])
 571 ])
 572 AM_CONDITIONAL([HAVE_RUBY],[test "x$RUBY" != "xno" &&
 573                             test "x$enable_ruby" = "xyes"])
 574
 575 dnl Check for Tcl, for embedding in the Tcl plugin.
 576 AC_ARG_ENABLE([tcl],
 577     [AS_HELP_STRING([--disable-tcl], [disable Tcl plugin])],
 578     [],
 579     [enable_tcl=yes])
 580 AS_IF([test "x$enable_tcl" != "xno"],[
 581     PKG_CHECK_MODULES([TCL], [tcl], [
 582         AC_SUBST([TCL_CFLAGS])
 583         AC_SUBST([TCL_LIBS])
 584     ],[
 585         AC_MSG_WARN([Tcl not found])
 586         enable_tcl=no
 587     ])
 588 ])
 589 AM_CONDITIONAL([HAVE_TCL],[test "x$enable_tcl" = "xyes"])
 590
 591 dnl Check for Lua, for embedding in the Lua plugin.
 592 AC_ARG_ENABLE([lua],
 593     [AS_HELP_STRING([--disable-lua], [disable Lua plugin])],
 594     [],
 595     [enable_lua=yes])
 596 AS_IF([test "x$enable_lua" != "xno"],[
 597     PKG_CHECK_MODULES([LUA], [lua], [
 598         AC_SUBST([LUA_CFLAGS])
 599         AC_SUBST([LUA_LIBS])
 600
 601         dnl Lua 5.1 used by RHEL 7 does not have lua_isinteger.
 602         old_LIBS="$LIBS"
 603         LIBS="$LUA_LIBS $LIBS"
 604         AC_CHECK_FUNCS([lua_isinteger])
 605         LIBS="$old_LIBS"
 606     ],[
 607         AC_MSG_WARN([Lua not found])
 608         enable_lua=no
 609     ])
 610 ])
 611 AM_CONDITIONAL([HAVE_LUA],[test "x$enable_lua" = "xyes"])
 612
 613 dnl Check for curl (only if you want to compile the curl plugin).
 614 AC_ARG_WITH([curl],
 615     [AS_HELP_STRING([--without-curl],
 616                     [disable curl plugin @<:@default=check@:>@])],
 617     [],
 618     [with_curl=check])
 619 AS_IF([test "$with_curl" != "no"],[
 620     PKG_CHECK_MODULES([CURL], [libcurl],[
 621         AC_SUBST([CURL_CFLAGS])
 622         AC_SUBST([CURL_LIBS])
 623         AC_DEFINE([HAVE_CURL],[1],[curl found at compile time.])
 624         AC_CHECK_DECL([CURLOPT_UNIX_SOCKET_PATH], [
 625             AC_DEFINE([HAVE_CURLOPT_UNIX_SOCKET_PATH],[1],
 626                       [CURLOPT_UNIX_SOCKET_PATH found at compile time.])
 627             ], [], [#include <curl/curl.h>])
 628     ],
 629     [AC_MSG_WARN([curl not found, curl plugin will be disabled])])
 630 ])
 631 AM_CONDITIONAL([HAVE_CURL],[test "x$CURL_LIBS" != "x"])
 632
 633 dnl Check for libssh (only if you want to compile the ssh plugin).
 634 AC_ARG_WITH([ssh],
 635     [AS_HELP_STRING([--without-ssh],
 636                     [disable ssh plugin @<:@default=check@:>@])],
 637     [],
 638     [with_ssh=check])
 639 AS_IF([test "$with_ssh" != "no"],[
 640     PKG_CHECK_MODULES([SSH], [libssh >= 0.8.0],[
 641         AC_SUBST([SSH_CFLAGS])
 642         AC_SUBST([SSH_LIBS])
 643     ],
 644     [AC_MSG_WARN([libssh not found, ssh plugin will be disabled])])
 645 ])
 646 AM_CONDITIONAL([HAVE_SSH],[test "x$SSH_LIBS" != "x"])
 647
 648 dnl Check for genisoimage or mkisofs
 649 dnl (only if you want to compile the iso plugin).
 650 ISOPROG="no"
 651 AC_ARG_WITH([iso],
 652     [AS_HELP_STRING([--without-iso],
 653                     [disable iso plugin @<:@default=check@:>@])],
 654     [],
 655     [with_iso=check])
 656 AS_IF([test "$with_iso" != "no"],[
 657     AC_CHECK_PROG([GENISOIMAGE],[genisoimage],[genisoimage],[no])
 658     AC_CHECK_PROG([MKISOFS],[mkisofs],[mkisofs],[no])
 659     AS_IF([test "x$GENISOIMAGE" != "xno"],[
 660         ISOPROG="$GENISOIMAGE"
 661     ],[
 662         AS_IF([test "x$MKISOFS" != "xno"],[
 663             ISOPROG="$MKISOFS"
 664         ])
 665     ])
 666     AS_IF([test "x$ISOPROG" != "xno"],[
 667         AC_DEFINE_UNQUOTED([ISOPROG],["$ISOPROG"],
 668                            [Program used by iso plugin to make ISOs.])
 669     ])
 670 ])
 671 AC_SUBST([ISOPROG])
 672 AM_CONDITIONAL([HAVE_ISO],[test "x$ISOPROG" != "xno"])
 673
 674 dnl Check for libvirt (only if you want to compile the libvirt plugin).
 675 AC_ARG_WITH([libvirt],
 676     [AS_HELP_STRING([--without-libvirt],
 677                     [disable libvirt plugin @<:@default=check@:>@])],
 678     [],
 679     [with_libvirt=check])
 680 AS_IF([test "$with_libvirt" != "no"],[
 681     PKG_CHECK_MODULES([LIBVIRT], [libvirt],[
 682         AC_SUBST([LIBVIRT_CFLAGS])
 683         AC_SUBST([LIBVIRT_LIBS])
 684         AC_DEFINE([HAVE_LIBVIRT],[1],[libvirt found at compile time.])
 685     ],
 686     [AC_MSG_WARN([libvirt not found, libvirt plugin will be disabled])])
 687 ])
 688 AM_CONDITIONAL([HAVE_LIBVIRT],[test "x$LIBVIRT_LIBS" != "x"])
 689
 690 dnl Check for zlib (only if you want to compile the gzip plugin).
 691 AC_ARG_WITH([zlib],
 692     [AS_HELP_STRING([--without-zlib],
 693                     [disable gzip plugin @<:@default=check@:>@])],
 694     [],
 695     [with_zlib=check])
 696 AS_IF([test "$with_zlib" != "no"],[
 697     PKG_CHECK_MODULES([ZLIB], [zlib >= 1.2.3.5],[
 698         AC_SUBST([ZLIB_CFLAGS])
 699         AC_SUBST([ZLIB_LIBS])
 700         AC_DEFINE([HAVE_ZLIB],[1],[zlib found at compile time.])
 701     ],
 702     [AC_MSG_WARN([zlib >= 1.2.3.5 not found, gzip plugin will be disabled])])
 703 ])
 704 AM_CONDITIONAL([HAVE_ZLIB],[test "x$ZLIB_LIBS" != "x"])
 705
 706 dnl Check for liblzma (only if you want to compile the xz filter).
 707 AC_ARG_WITH([liblzma],
 708     [AS_HELP_STRING([--without-liblzma],
 709                     [disable xz filter @<:@default=check@:>@])],
 710     [],
 711     [with_liblzma=check])
 712 AS_IF([test "$with_liblzma" != "no"],[
 713     PKG_CHECK_MODULES([LIBLZMA], [liblzma],[
 714         AC_SUBST([LIBLZMA_CFLAGS])
 715         AC_SUBST([LIBLZMA_LIBS])
 716         AC_DEFINE([HAVE_LIBLZMA],[1],[liblzma found at compile time.])
 717     ],
 718     [AC_MSG_WARN([liblzma not found, xz filter will be disabled])])
 719 ])
 720 AM_CONDITIONAL([HAVE_LIBLZMA],[test "x$LIBLZMA_LIBS" != "x"])
 721
 722 dnl Check for libguestfs (only for the guestfs plugin and the test suite).
 723 AC_ARG_WITH([libguestfs],
 724     [AS_HELP_STRING([--without-libguestfs],
 725                     [disable guestfs plugin and tests @<:@default=check@:>@])],
 726     [],
 727     [with_libguestfs=check])
 728 AS_IF([test "$with_libguestfs" != "no"],[
 729     PKG_CHECK_MODULES([LIBGUESTFS], [libguestfs],[
 730         # Although the library was found, we want to make sure it supports nbd
 731         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 732 #include <guestfs.h>
 733         ]], [[
 734 #ifndef GUESTFS_ADD_DRIVE_OPTS_PROTOCOL
 735 #error unsupported
 736 #endif
 737         ]])], [
 738         AC_SUBST([LIBGUESTFS_CFLAGS])
 739         AC_SUBST([LIBGUESTFS_LIBS])
 740         AC_DEFINE([HAVE_LIBGUESTFS],[1],[libguestfs found at compile time.])
 741         ],[
 742         LIBGUESTFS_LIBS=
 743         AC_MSG_WARN([libguestfs too old, guestfs plugin and tests will be disabled])])
 744     ],
 745     [AC_MSG_WARN([libguestfs not found, guestfs plugin and tests will be disabled])])
 746 ])
 747 AM_CONDITIONAL([HAVE_LIBGUESTFS],[test "x$LIBGUESTFS_LIBS" != "x"])
 748
 749 dnl Check for guestfish (only needed for some of the tests).
 750 AC_CHECK_PROG([GUESTFISH], [guestfish], [guestfish], [no])
 751 AM_CONDITIONAL([HAVE_GUESTFISH], [test "x$GUESTFISH" != "xno"])
 752
 753 dnl Check for ext2fs and com_err, for the ext2 plugin.
 754 AC_ARG_WITH([ext2],
 755     [AS_HELP_STRING([--without-ext2],
 756                     [disable ext2 plugin @<:@default=check@:>@])],
 757     [],
 758     [with_ext2=check])
 759 AS_IF([test "$with_ext2" != "no"], [
 760     PKG_CHECK_MODULES([EXT2FS], [ext2fs], [
 761         AC_SUBST([EXT2FS_CFLAGS])
 762         AC_SUBST([EXT2FS_LIBS])
 763         AC_DEFINE([HAVE_EXT2FS],[1],[ext2fs found at compile time.])
 764     ],
 765     [AC_MSG_WARN([ext2fs not found, ext2 plugin will be disabled])])
 766     PKG_CHECK_MODULES([COM_ERR], [com_err], [
 767         AC_SUBST([COM_ERR_CFLAGS])
 768         AC_SUBST([COM_ERR_LIBS])
 769         AC_DEFINE([HAVE_COM_ERR],[1],[com_err found at compile time.])
 770     ],
 771     [AC_MSG_WARN([com_err not found, ext2 plugin will be disabled])])
 772 ])
 773 AM_CONDITIONAL([HAVE_EXT2],
 774                [test "x$EXT2FS_LIBS" != "x" && test "x$COM_ERR_LIBS" != "x"])
 775
 776 dnl Check if the user wants to disable VDDK support.
 777 dnl See plugins/vddk/README.VDDK.
 778 AC_ARG_ENABLE([vddk],
 779     [AS_HELP_STRING([--disable-vddk],
 780                     [disable VMware VDDK plugin])],
 781     [],
 782     [enable_vddk=yes])
 783 AM_CONDITIONAL([HAVE_VDDK], [test "x$enable_vddk" = "xyes"])
 784
 785 dnl List of plugins and filters.
 786 lang_plugins="\
 787         lua \
 788         ocaml \
 789         perl \
 790         python \
 791         ruby \
 792         rust \
 793         sh \
 794         tcl \
 795         "
 796 non_lang_plugins="\
 797         curl \
 798         data \
 799         example1 \
 800         example2 \
 801         example3 \
 802         example4 \
 803         ext2 \
 804         file \
 805         floppy \
 806         full \
 807         guestfs \
 808         gzip \
 809         iso \
 810         libvirt \
 811         linuxdisk \
 812         memory \
 813         nbd \
 814         null \
 815         partitioning \
 816         pattern \
 817         random \
 818         split \
 819         ssh \
 820         streaming \
 821         tar \
 822         vddk \
 823         zero \
 824         "
 825 plugins="$(echo $(printf %s\\n $lang_plugins $non_lang_plugins | sort -u))"
 826 filters="\
 827         blocksize \
 828         cache \
 829         cow \
 830         delay \
 831         error \
 832         fua \
 833         log \
 834         nocache \
 835         noextents \
 836         noparallel \
 837         nozero \
 838         offset \
 839         partition \
 840         rate \
 841         readahead \
 842         stats \
 843         truncate \
 844         xz \
 845         "
 846 AC_SUBST([plugins])
 847 AC_SUBST([lang_plugins])
 848 AC_SUBST([non_lang_plugins])
 849 AC_SUBST([filters])
 850
 851 dnl Produce output files.
 852 AC_CONFIG_HEADERS([config.h])
 853 AC_CONFIG_FILES([podwrapper.pl],
 854                 [chmod +x,-w podwrapper.pl])
 855 AC_CONFIG_FILES([Makefile
 856                  bash/Makefile
 857                  common/bitmap/Makefile
 858                  common/gpt/Makefile
 859                  common/include/Makefile
 860                  common/protocol/Makefile
 861                  common/regions/Makefile
 862                  common/sparse/Makefile
 863                  common/utils/Makefile
 864                  docs/Makefile
 865                  include/Makefile
 866                  plugins/Makefile
 867                  plugins/curl/Makefile
 868                  plugins/data/Makefile
 869                  plugins/example1/Makefile
 870                  plugins/example2/Makefile
 871                  plugins/example3/Makefile
 872                  plugins/example4/Makefile
 873                  plugins/ext2/Makefile
 874                  plugins/file/Makefile
 875                  plugins/floppy/Makefile
 876                  plugins/full/Makefile
 877                  plugins/guestfs/Makefile
 878                  plugins/gzip/Makefile
 879                  plugins/iso/Makefile
 880                  plugins/libvirt/Makefile
 881                  plugins/linuxdisk/Makefile
 882                  plugins/lua/Makefile
 883                  plugins/memory/Makefile
 884                  plugins/nbd/Makefile
 885                  plugins/null/Makefile
 886                  plugins/ocaml/Makefile
 887                  plugins/partitioning/Makefile
 888                  plugins/pattern/Makefile
 889                  plugins/perl/Makefile
 890                  plugins/python/Makefile
 891                  plugins/random/Makefile
 892                  plugins/ruby/Makefile
 893                  plugins/rust/Cargo.toml
 894                  plugins/rust/Makefile
 895                  plugins/sh/Makefile
 896                  plugins/ssh/Makefile
 897                  plugins/split/Makefile
 898                  plugins/streaming/Makefile
 899                  plugins/tar/Makefile
 900                  plugins/tcl/Makefile
 901                  plugins/vddk/Makefile
 902                  plugins/zero/Makefile
 903                  filters/Makefile
 904                  filters/blocksize/Makefile
 905                  filters/cache/Makefile
 906                  filters/cow/Makefile
 907                  filters/delay/Makefile
 908                  filters/error/Makefile
 909                  filters/fua/Makefile
 910                  filters/log/Makefile
 911                  filters/nocache/Makefile
 912                  filters/noextents/Makefile
 913                  filters/noparallel/Makefile
 914                  filters/nozero/Makefile
 915                  filters/offset/Makefile
 916                  filters/partition/Makefile
 917                  filters/rate/Makefile
 918                  filters/readahead/Makefile
 919                  filters/stats/Makefile
 920                  filters/truncate/Makefile
 921                  filters/xz/Makefile
 922                  fuzzing/Makefile
 923                  server/Makefile
 924                  server/nbdkit.pc
 925                  tests/functions.sh
 926                  tests/Makefile
 927                  valgrind/Makefile])
 928
 929 AC_OUTPUT
 930
 931 dnl Summary.
 932 echo
 933 echo
 934 echo "----------------------------------------------------------------------"
 935 echo "Thank you for downloading $PACKAGE_STRING"
 936 echo
 937 echo "This is how we have configured the optional components for you today:"
 938 echo
 939
 940 feature ()
 941 {
 942     echo -n "    $1"
 943     shift
 944     if $@; then echo "yes"; else echo "no"; fi
 945 }
 946
 947 echo "Optional server features:"
 948 echo
 949 feature "bash-completion ........................ " \
 950         test "x$HAVE_BASH_COMPLETION_TRUE" = "x"
 951 feature "manual pages ........................... " \
 952         test "x$HAVE_POD_TRUE" = "x"
 953 feature "SELinux ................................ " \
 954         test "x$LIBSELINUX_LIBS" != "x"
 955 feature "TLS .................................... " \
 956         test "x$GNUTLS_LIBS" != "x"
 957
 958 echo
 959 echo "Optional plugins:"
 960 echo
 961 feature "curl ................................... " \
 962         test "x$HAVE_CURL_TRUE" = "x"
 963 feature "example4 ............................... " \
 964         test "x$HAVE_PERL_TRUE" = "x"
 965 feature "ext2 ................................... " \
 966         test "x$HAVE_EXT2_TRUE" = "x"
 967 feature "floppy ................................. " \
 968         test "x$HAVE_ICONV_TRUE" = "x"
 969 feature "guestfs ................................ " \
 970         test "x$HAVE_LIBGUESTFS_TRUE" = "x"
 971 feature "gzip ................................... " \
 972         test "x$HAVE_ZLIB_TRUE" = "x"
 973 feature "iso .................................... " \
 974         test "x$HAVE_ISO_TRUE" = "x"
 975 feature "libvirt ................................ " \
 976         test "x$HAVE_LIBVIRT_TRUE" = "x"
 977 feature "ssh .................................... " \
 978         test "x$HAVE_SSH_TRUE" = "x"
 979 feature "tar .................................... " \
 980         test "x$HAVE_PERL_TRUE" = "x"
 981 feature "vddk ................................... " \
 982         test "x$HAVE_VDDK_TRUE" = "x"
 983
 984
 985 echo
 986 echo "Languages:"
 987 echo
 988 feature "lua .................................... " \
 989         test "x$HAVE_LUA_TRUE" = "x"
 990 feature "ocaml .................................. " \
 991         test "x$HAVE_OCAML_TRUE" = "x"
 992 feature "perl ................................... " \
 993         test "x$HAVE_PERL_TRUE" = "x"
 994 feature "python ................................. " \
 995         test "x$HAVE_PYTHON_TRUE" = "x"
 996 feature "ruby ................................... " \
 997         test "x$HAVE_RUBY_TRUE" = "x"
 998 feature "rust ................................... " \
 999         test "x$HAVE_RUST_TRUE" = "x"
1000 feature "tcl .................................... " \
1001         test "x$HAVE_TCL_TRUE" = "x"
1002
1003
1004 echo
1005 echo "Optional filters:"
1006 echo
1007 feature "xz ..................................... " \
1008         test "x$HAVE_LIBLZMA_TRUE" = "x"
1009
1010 echo
1011 echo "If any optional component is configured ‘no’ when you expected ‘yes’"
1012 echo "then you should check the preceding messages and README."
1013 echo
1014 echo "Please report bugs back to the mailing list:"
1015 echo "http://www.redhat.com/mailman/listinfo/libguestfs"
1016 echo
1017 echo "Next you should type 'make' to build the package,"
1018 echo "then 'make check' to run the tests."