configure.ac

   1 dnl Process this file with autoconf 2.63 or later to produce
   2 dnl a configure script.
   3 AC_PREREQ(2.63)
   4 AC_INIT(config/config.h.in)
   5 AC_CONFIG_HEADERS(config/config.h)
   6
   7 AC_PREFIX_PROGRAM(nasm)
   8
   9 dnl Save initial CFLAGS, to see if -g -O2 came from configure or not
  10 pa_init_cflags="$CFLAGS"
  11
  12 dnl This prevents us from running Wine and thinking we are not
  13 dnl cross-compiling when in fact we are; running Wine here is at
  14 dnl the best very slow and doesn't buy us a single thing at all.
  15 WINELOADER=/dev/null
  16 export WINELOADER
  17
  18 dnl Checks for programs and enable necessary CC extensions
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_SYS_LARGEFILE
  21 AC_PROG_CC
  22 AC_PROG_CC_STDC
  23 AC_PROG_LN_S
  24 AC_PROG_MAKE_SET
  25 AC_PROG_INSTALL
  26
  27 dnl If the user did not specify a CFLAGS default, change default -O2
  28 dnl to either -O3 (normal) or -O0 (for debugging)
  29 PA_ARG_DISABLED([optimization],
  30  [compile without optimization (-O0) to help debugging],
  31  [pa_optimize=-O0], [pa_optimize=-O3])
  32 AS_IF([test x"$pa_init_cflags" = x],
  33       [CFLAGS=`echo "$CFLAGS" | sed -e "s/-O2/$pa_optimize/"`])
  34
  35 dnl Compile and link with dwarf debug
  36 PA_ARG_ENABLED([gdb],
  37  [disable optimization and compile with extra debug information for GDB debugger],
  38  [CFLAGS=`echo "$CFLAGS" | sed -e "s/\(-O2\|-O3\)/-O0/"`
  39    PA_ADD_CLDFLAGS([-ggdb3])])
  40
  41 dnl Check for library extension
  42 PA_LIBEXT
  43
  44 dnl Checks for typedefs, structures, and compiler characteristics.
  45 AC_C_CONST
  46 AC_C_INLINE
  47 AC_C_RESTRICT
  48 AC_TYPE_SIZE_T
  49 AC_C_BIGENDIAN(AC_DEFINE(WORDS_BIGENDIAN),AC_DEFINE(WORDS_LITTLEENDIAN),,)
  50 AH_TEMPLATE(WORDS_BIGENDIAN,
  51 [Define to 1 if your processor stores words with the most significant
  52 byte first (like Motorola and SPARC, unlike Intel and VAX).])
  53 AH_TEMPLATE(WORDS_LITTLEENDIAN,
  54 [Define to 1 if your processor stores words with the least significant
  55 byte first (like Intel and VAX, unlike Motorola and SPARC).])
  56
  57 dnl Force gcc and gcc-compatible compilers treat signed integers
  58 dnl as 2's complement
  59 PA_ADD_CFLAGS([-fwrapv])
  60
  61 dnl Some environments abuse __STRICT_ANSI__ to disable some
  62 dnl function declarations
  63 PA_ADD_CFLAGS([-U__STRICT_ANSI__])
  64
  65 dnl Don't put things in common if we can avoid it.  We don't want to
  66 dnl assume all compilers support common, and this will help find those
  67 dnl problems.  This also works around an OSX linker problem.
  68 PA_ADD_CFLAGS([-fno-common])
  69
  70 dnl Look for programs...
  71 AC_CHECK_PROGS(NROFF,    nroff,    false)
  72 AC_CHECK_PROGS(ASCIIDOC, asciidoc, false)
  73 AC_CHECK_PROGS(XMLTO,    xmlto,    false)
  74
  75 dnl Check for progs needed for manpage generation
  76 AS_IF([test $ASCIIDOC = false],
  77   [AC_MSG_WARN([No asciidoc package found])]
  78 )
  79 AS_IF([test $XMLTO = false],
  80   [AC_MSG_WARN([No xmlto package found])]
  81 )
  82
  83 dnl Check for host compiler tools
  84 AC_CHECK_TOOL(AR, ar)
  85 AC_CHECK_TOOL(RANLIB, ranlib, :)
  86 AC_CHECK_TOOL(STRIP, strip)
  87
  88 dnl Checks for header files.
  89 AC_HEADER_STDC
  90 AC_CHECK_HEADERS(inttypes.h)
  91 AC_CHECK_HEADERS(strings.h)
  92 AC_HEADER_STDBOOL
  93 AC_CHECK_HEADERS(stdnoreturn.h)
  94 AC_CHECK_HEADERS(io.h)
  95 AC_CHECK_HEADERS(fcntl.h)
  96 AC_CHECK_HEADERS(unistd.h)
  97 AC_CHECK_HEADERS(endian.h sys/endian.h machine/endian.h)
  98 AC_CHECK_HEADERS(sys/mman.h)
  99 AC_CHECK_HEADERS(sys/types.h)
 100 AC_CHECK_HEADERS(sys/stat.h)
 101
 102 dnl Checks for library functions.
 103 AC_CHECK_FUNCS(strcasecmp stricmp)
 104 AC_CHECK_FUNCS(strncasecmp strnicmp)
 105 AC_CHECK_FUNCS(strsep)
 106 AC_CHECK_FUNCS(strnlen)
 107
 108 AC_CHECK_FUNCS(getuid)
 109 AC_CHECK_FUNCS(getgid)
 110
 111 AC_CHECK_FUNCS(realpath)
 112 AC_CHECK_FUNCS(canonicalize_file_name)
 113 AC_CHECK_FUNCS(_fullpath)
 114 AC_CHECK_FUNCS(pathconf)
 115
 116 AC_FUNC_FSEEKO
 117 AC_CHECK_FUNCS([_fseeki64])
 118 AC_CHECK_FUNCS([ftruncate _chsize _chsize_s])
 119 AC_CHECK_FUNCS([fileno _fileno])
 120
 121 AC_CHECK_FUNCS(_filelengthi64)
 122 AC_FUNC_MMAP
 123 AC_CHECK_FUNCS(getpagesize)
 124 AC_CHECK_FUNCS(sysconf)
 125
 126 AC_CHECK_FUNCS([access _access faccessat])
 127
 128 PA_HAVE_FUNC(__builtin_expect, (1,1))
 129
 130 dnl ilog2() building blocks
 131 PA_ADD_HEADERS(intrin.h)
 132 PA_HAVE_FUNC(__builtin_clz, (0U))
 133 PA_HAVE_FUNC(__builtin_clzl, (0UL))
 134 PA_HAVE_FUNC(__builtin_clzll, (0ULL))
 135 PA_HAVE_FUNC(_BitScanReverse, (0))
 136 PA_HAVE_FUNC(_BitScanReverse64, (0))
 137
 138 dnl Functions for which we have replacements available in lib/
 139 AC_CHECK_FUNCS([vsnprintf _vsnprintf])
 140 AC_CHECK_FUNCS([snprintf _snprintf])
 141 AC_CHECK_FUNCS([strlcpy])
 142
 143 dnl These types are POSIX-specific, and Windows does it differently...
 144 AC_CHECK_TYPES([struct _stati64])
 145 AC_CHECK_TYPES([struct stat])
 146 AC_CHECK_FUNCS([stat _stati64])
 147 AC_CHECK_FUNCS([fstat _fstati64])
 148
 149 dnl Check for functions that might not be declared in the headers for
 150 dnl various idiotic reasons (mostly because of library authors
 151 dnl abusing the meaning of __STRICT_ANSI__)
 152 AC_CHECK_DECLS(strcasecmp)
 153 AC_CHECK_DECLS(stricmp)
 154 AC_CHECK_DECLS(strncasecmp)
 155 AC_CHECK_DECLS(strnicmp)
 156 AC_CHECK_DECLS(strsep)
 157 AC_CHECK_DECLS(strlcpy)
 158 AC_CHECK_DECLS(strnlen)
 159
 160 dnl Check for missing types
 161 AC_TYPE_UINTPTR_T
 162
 163 dnl Documentation: should we generate an uncompressed PDF?  It is
 164 dnl about twice as big, but it can be externally compressed (e.g. with xz)
 165 dnl and becomes significantly smaller than the original.
 166 PA_ARG_DISABLED([pdf-compression],
 167   [generate an uncompressed documentation PDF],
 168   [PDFOPT='-nocompress'])
 169 AC_SUBST([PDFOPT])
 170
 171 dnl
 172 dnl Look for byte-swapping support...
 173 dnl
 174 PA_HAVE_FUNC(cpu_to_le16, (0))
 175 PA_HAVE_FUNC(cpu_to_le32, (0))
 176 PA_HAVE_FUNC(cpu_to_le64, (0))
 177 PA_HAVE_FUNC(__cpu_to_le16, (0))
 178 PA_HAVE_FUNC(__cpu_to_le32, (0))
 179 PA_HAVE_FUNC(__cpu_to_le64, (0))
 180 PA_HAVE_FUNC(htole16, (0))
 181 PA_HAVE_FUNC(htole32, (0))
 182 PA_HAVE_FUNC(htole64, (0))
 183 PA_HAVE_FUNC(__bswap_16, (0))
 184 PA_HAVE_FUNC(__bswap_32, (0))
 185 PA_HAVE_FUNC(__bswap_64, (0))
 186 PA_HAVE_FUNC(__builtin_bswap16, (0))
 187 PA_HAVE_FUNC(__builtin_bswap32, (0))
 188 PA_HAVE_FUNC(__builtin_bswap64, (0))
 189 PA_HAVE_FUNC(_byteswap_ushort, (0))
 190 PA_HAVE_FUNC(_byteswap_ulong, (0))
 191 PA_HAVE_FUNC(_byteswap_uint64, (0))
 192
 193 dnl
 194 dnl Check for supported gcc attributes; some compilers (e.g. Sun CC)
 195 dnl support these, but don't define __GNUC__ as they don't support
 196 dnl some other features of gcc.
 197 dnl
 198 PA_ADD_CFLAGS([-Werror=attributes])
 199 PA_FUNC_ATTRIBUTE(noreturn)
 200 PA_FUNC_ATTRIBUTE(returns_nonnull)
 201 PA_FUNC_ATTRIBUTE(malloc)
 202 PA_FUNC_ATTRIBUTE(alloc_size, (1))
 203 PA_FUNC_ATTRIBUTE(format, [(printf,1,2)], int, [const char *, ...], ["%d",1])
 204 PA_FUNC_ATTRIBUTE(const)
 205 PA_FUNC_ATTRIBUTE(pure)
 206 PA_FUNC_ATTRIBUTE_ERROR
 207
 208 dnl
 209 dnl support function sections
 210 dnl
 211 PA_ARG_ENABLED([sections],
 212  [compile with function/data section support],
 213  [PA_ADD_CLDFLAGS([-ffunction-sections])
 214   PA_ADD_CLDFLAGS([-fdata-sections])
 215   PA_ADD_CLDFLAGS([-Wl,--gc-sections])],
 216  [])
 217 dnl
 218 dnl support LTO
 219 dnl
 220 PA_ARG_ENABLED([lto],
 221  [compile with gcc-style link time optimization],
 222  [PA_ADD_CLDFLAGS([-flto])
 223   dnl Note: we use _PROG rather than _TOOL since we are prepending the full
 224   dnl CC name which ought to already contain the host triplet if needed
 225   ccbase=`echo "$CC" | awk '{ print $1; }'`
 226   AC_CHECK_PROGS(CC_AR, [${ccbase}-ar], [$ac_cv_prog_AR])
 227   AR="$CC_AR"
 228   AC_CHECK_PROGS(CC_RANLIB, [${ccbase}-ranlib], [$ac_cv_prog_RANLIB])
 229   RANLIB="$CC_RANLIB"], [])
 230
 231 dnl If we have gcc, add appropriate code cleanliness options
 232 PA_ADD_CFLAGS([-W])
 233 PA_ADD_CFLAGS([-Wall])
 234 PA_ADD_CFLAGS([-pedantic])
 235 dnl LLVM doesn't error out on invalid -W options unless this option is
 236 dnl specified first.  Enable this so this script can actually discover
 237 dnl which -W options are possible for this compiler.
 238 PA_ADD_CFLAGS([-Werror=unknown-warning-option])
 239 dnl Suppress format warning on Windows targets due to their <inttypes.h>
 240 PA_ADD_CFLAGS([-Wpedantic-ms-format],[-Wno-pedantic-ms-format])
 241 PA_ADD_CFLAGS([-Wc90-c99-compat])
 242 PA_ADD_CFLAGS([-Wlong-long],[-Wno-long-long])
 243 dnl PA_ADD_CFLAGS([-Wwrite-strings])
 244 PA_ARG_ENABLED([werror],
 245  [compile with -Werror to error out on any warning],
 246  [PA_ADD_CFLAGS([-Werror])],
 247  [PA_ADD_CFLAGS([-Werror=implicit])
 248   PA_ADD_CFLAGS([-Werror=missing-braces])
 249   PA_ADD_CFLAGS([-Werror=return-type])
 250   PA_ADD_CFLAGS([-Werror=trigraphs])
 251   PA_ADD_CFLAGS([-Werror=pointer-arith])
 252   PA_ADD_CFLAGS([-Werror=strict-prototypes])
 253   PA_ADD_CFLAGS([-Werror=missing-prototypes])
 254   PA_ADD_CFLAGS([-Werror=missing-declarations])
 255   PA_ADD_CFLAGS([-Werror=comment])
 256   PA_ADD_CFLAGS([-Werror=vla])]
 257 )
 258
 259 dnl
 260 dnl support ccache
 261 dnl
 262 PA_ARG_ENABLED([ccache], [compile with ccache], [CC="ccache $CC"], [])
 263
 264 AC_OUTPUT_COMMANDS([mkdir -p config nasmlib nsis output stdlib x86 asm disasm rdoff macros common])
 265 AC_OUTPUT(Makefile doc/Makefile)