configure.in

   1 dnl Process this file with autoconf 2.61 or later to produce
   2 dnl a configure script.
   3 AC_PREREQ(2.61)
   4 AC_INIT(config.h.in)
   5 AC_CONFIG_HEADERS(config.h)
   6
   7 dnl Check for broken VPATH handling on older NetBSD makes.
   8 AC_DEFUN(AC_PROG_MAKE_VPATHOK,
   9 [AC_MSG_CHECKING(whether ${MAKE-make} has sane VPATH handling)
  10 set dummy ${MAKE-make}; ac_make=`echo "[$]2" | sed 'y%./+-%__p_%'`
  11 AC_CACHE_VAL(ac_cv_prog_make_vpathok,
  12 [mkdir conftestdir
  13 cat > conftestdir/conftestmake <<\EOF
  14 VPATH = ..
  15 conftestfoo: conftestbar
  16         @echo ac_make2temp=ok
  17 conftestbar: conftestbaz
  18         @echo ac_maketemp=broken
  19         @touch conftestbar
  20 EOF
  21 echo > conftestbaz # these two lines need to be...
  22 echo > conftestbar # ... in this order not the other
  23 changequote(, )dnl
  24 unset ac_maketemp
  25 unset ac_make2temp
  26 # GNU make sometimes prints "make[1]: Entering...", which would confuse us.
  27 eval `cd conftestdir; ${MAKE-make} -f conftestmake 2>/dev/null | grep temp=`
  28 changequote([, ])dnl
  29 if test -n "$ac_maketemp"; then
  30   ac_cv_prog_make_vpathok=no
  31 else
  32   if test -n "$ac_make2temp"; then
  33     ac_cv_prog_make_vpathok=yes
  34   else
  35     ac_cv_prog_make_vpathok=no
  36   fi
  37 fi
  38 rm -rf conftestdir
  39 rm -f conftestbar conftestbaz])dnl
  40 if test $ac_cv_prog_make_vpathok = yes; then
  41   AC_MSG_RESULT(yes)
  42 else
  43   AC_MSG_RESULT(no)
  44 fi
  45 ])
  46
  47 AC_PREFIX_PROGRAM(nasm)
  48
  49 dnl Checks for programs.
  50 dnl Consider AC_USE_SYSTEM_EXTENSIONS if autoconf 2.61 is OK in the future
  51 AC_USE_SYSTEM_EXTENSIONS
  52 AC_PROG_CC
  53 AC_PROG_LN_S
  54 AC_PROG_MAKE_SET
  55 if test -f nasm.c; then
  56   # we're building in the source dir, so we don't need this check at all
  57   ac_cv_prog_make_vpathok=yes
  58 else
  59   AC_PROG_MAKE_VPATHOK
  60 fi
  61 AC_PROG_INSTALL
  62
  63 dnl If we have gcc, add appropriate options
  64 PA_ADD_CFLAGS([-W])
  65 PA_ADD_CFLAGS([-Wall])
  66 PA_ADD_CFLAGS([-std=c99])
  67 PA_ADD_CFLAGS([-pedantic])
  68
  69 dnl Look for "nroff" or "groff"
  70 AC_CHECK_PROGS(NROFF, nroff, echo)
  71 AC_SUBST(NROFF)
  72
  73 dnl Checks for header files.
  74 AC_HEADER_STDC
  75 if test $ac_cv_header_stdc = no; then
  76   AC_MSG_ERROR([NASM requires ANSI C header files to compile])
  77 fi
  78
  79 AC_CHECK_HEADERS(limits.h)
  80 if test $ac_cv_header_limits_h = no; then
  81   AC_MSG_ERROR([NASM requires '<limits.h>' to compile])
  82 fi
  83
  84 dnl Check for <inttypes.h> or add a substitute version
  85 AC_CHECK_HEADERS(inttypes.h, , CFLAGS="$CFLAGS -I\$(top_srcdir)/inttypes")
  86
  87 dnl The standard header for str*casecmp is <strings.h>
  88 AC_CHECK_HEADERS(strings.h)
  89
  90 dnl Look for <stdbool.h>
  91 AC_CHECK_HEADERS(stdbool.h)
  92
  93 dnl Checks for typedefs, structures, and compiler characteristics.
  94 AC_C_CONST
  95 AC_C_INLINE
  96 AC_C_RESTRICT
  97 AC_TYPE_SIZE_T
  98 AC_C_BIGENDIAN(AC_DEFINE(WORDS_BIGENDIAN),AC_DEFINE(WORDS_LITTLEENDIAN))
  99 AH_TEMPLATE(WORDS_BIGENDIAN,
 100 [Define to 1 if your processor stores words with the most significant
 101 byte first (like Motorola and SPARC, unlike Intel and VAX).])
 102 AH_TEMPLATE(WORDS_LITTLEENDIAN,
 103 [Define to 1 if your processor stores words with the least significant
 104 byte first (like Intel and VAX, unlike Motorola and SPARC).])
 105
 106 dnl Checks for library functions.
 107 AC_SUBST(XOBJS)
 108
 109 AC_CHECK_FUNCS(strcspn, ,
 110   AC_MSG_ERROR([NASM requires ANSI C (specifically, "strcspn")]))
 111
 112 AC_CHECK_FUNCS(strspn, ,
 113   AC_MSG_ERROR([NASM requires ANSI C (specifically, "strspn")]))
 114
 115 missing=true
 116 AC_CHECK_FUNCS([vsnprintf _vsnprintf], missing=false)
 117 if $missing; then
 118    XOBJS="$XOBJS lib/vsnprintf.o"
 119 fi
 120
 121 missing=true
 122 AC_CHECK_FUNCS([snprintf _snprintf], missing=false)
 123 if $missing; then
 124    XOBJS="$XOBJS lib/snprintf.o"
 125 fi
 126
 127 AC_CHECK_FUNCS(strcasecmp stricmp)
 128 AC_CHECK_FUNCS(strncasecmp strnicmp)
 129 AC_CHECK_FUNCS(strsep)
 130
 131 AC_CHECK_FUNCS(getuid)
 132 AC_CHECK_FUNCS(getgid)
 133
 134 dnl Check for functions that might not be declared in the headers for
 135 dnl various idiotic reasons (mostly because of library authors
 136 dnl abusing the meaning of __STRICT_ANSI__)
 137 AC_CHECK_DECLS(strcasecmp)
 138 AC_CHECK_DECLS(stricmp)
 139 AC_CHECK_DECLS(strncasecmp)
 140 AC_CHECK_DECLS(strnicmp)
 141 AC_CHECK_DECLS(strsep)
 142
 143 if test $ac_cv_prog_make_vpathok = no; then
 144   echo Copying generated srcs into build directory to compensate for VPATH breakage
 145   for file in macros.c insnsa.c insnsd.c insnsn.c insnsi.h version.h version.mac; do
 146     if test ! -f $file; then cp -p ${srcdir}/${file} .; fi
 147   done
 148 fi
 149
 150 AC_OUTPUT_COMMANDS([mkdir -p output])
 151 AC_OUTPUT(Makefile rdoff/Makefile doc/Makefile)