lisp/muse-blosxom.el

   1 ;;; muse-blosxom.el --- Publish a document tree for serving by (py)Blosxom
   2
   3 ;; Copyright (C) 2004, 2005  Free Software Foundation, Inc.
   4
   5 ;; Date: Wed, 23 March 2005
   6 ;; Author: Michael Olson (mwolson AT gnu DOT org)
   7 ;; Maintainer: Michael Olson (mwolson AT gnu DOT org)
   8
   9 ;; This file is not part of GNU Emacs.
  10
  11 ;; This is free software; you can redistribute it and/or modify it under
  12 ;; the terms of the GNU General Public License as published by the Free
  13 ;; Software Foundation; either version 2, or (at your option) any later
  14 ;; version.
  15 ;;
  16 ;; This is distributed in the hope that it will be useful, but WITHOUT
  17 ;; ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 ;; FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  19 ;; for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; The Blosxom publishing style publishes a tree of categorised files
  29 ;; to a mirrored tree of stories to be served by blosxom.cgi or
  30 ;; pyblosxom.cgi.
  31 ;;
  32 ;; Serving entries with (py)blosxom
  33 ;; --------------------------------
  34 ;;
  35 ;; Each Blosxom file must include `#date yyyy-mm-dd', or optionally
  36 ;; the longer `#date yyyy-mm-dd-hh-mm', a title (using the `#title'
  37 ;; directive) plus whatever normal content is desired.
  38 ;;
  39 ;; The date directive is not used directly by (py)blosxom or this
  40 ;; program.  You need to find two additional items to make use of this
  41 ;; feature.
  42 ;;
  43 ;;  1. A script to gather date directives from the entire blog tree
  44 ;;     into a single file.  The file must associate a blog entry with
  45 ;;     a date.
  46 ;;
  47 ;;  2. A plugin for (py)blosxom that reads this file.
  48 ;;
  49 ;; These 2 things are provided for pyblosxom in the contrib/pyblosxom
  50 ;; subdirectory.  `getstamps.py' provides the 1st service, while
  51 ;; `hardcodedates.py' provides the second service.  Eventually it is
  52 ;; hoped that a blosxom plugin and script will be found/written.
  53 ;;
  54 ;; Creating new blog entries
  55 ;; -------------------------
  56 ;;
  57 ;; There is a function called `muse-blosxom-new-entry' that will
  58 ;; automate the process of making a new blog entry.  To make use of
  59 ;; it, do the following.
  60 ;;
  61 ;;  - Customize `muse-blosxom-base-directory' to the location that
  62 ;;    your blog entries are stored.
  63 ;;
  64 ;;  - Assign the `muse-blosxom-new-entry' function to a key sequence.
  65 ;;    I use the following code to assign this function to `C-c p l'.
  66 ;;
  67 ;;    (global-set-key "\C-cpl" 'muse-blosxom-new-entry)
  68 ;;
  69 ;;  - You should create your directory structure ahead of time under
  70 ;;    your base directory.  These directories, which correspond with
  71 ;;    category names, may be nested.
  72 ;;
  73 ;;  - When you enter this key sequence, you will be prompted for the
  74 ;;    category of your entry and its title.  Upon entering this
  75 ;;    information, a new file will be created that corresponds with
  76 ;;    the title, but in lowercase letters and having special
  77 ;;    characters converted to underscores.  The title and date
  78 ;;    directives will be inserted automatically.
  79
  80 ;;; Contributors:
  81
  82 ;; Gary Vaughan (gary AT gnu DOT org) is the original author of
  83 ;; `emacs-wiki-blosxom.el', which is the ancestor of this file.
  84
  85 ;; Brad Collins (brad AT chenla DOT org) ported this file to Muse.
  86
  87 ;; Michael Olson (mwolson AT gnu DOT org) further adapted this file to
  88 ;; Muse and continues to maintain it.
  89
  90 ;;; Code:
  91
  92 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  93 ;;
  94 ;; Muse Blosxom Publishing
  95 ;;
  96 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  97
  98 (require 'muse-project)
  99 (require 'muse-publish)
 100 (require 'muse-html)
 101
 102 (defgroup muse-blosxom nil
 103   "Options controlling the behavior of Muse Blosxom publishing.
 104 See `muse-blosxom' for more information."
 105   :group 'muse-publish)
 106
 107 (defcustom muse-blosxom-extension ".txt"
 108   "Default file extension for publishing Blosxom files."
 109   :type 'string
 110   :group 'muse-blosxom)
 111
 112 (defcustom muse-blosxom-header
 113   "<lisp>(muse-publishing-directive \"title\")</lisp>\n"
 114   "Header used for publishing Blosxom files."
 115   :type '(choice string file)
 116   :group 'muse-blosxom)
 117
 118 (defcustom muse-blosxom-footer ""
 119   "Footer used for publishing Blosxom files."
 120   :type '(choice string file)
 121   :group 'muse-blosxom)
 122
 123 ;; Maintain (published-file . date) alist
 124
 125 (defvar muse-blosxom-page-date-alist nil)
 126
 127 ;; This isn't really used for anything, but it may be someday
 128 (defun muse-blosxom-markup-date-directive ()
 129   "Add a date entry to `muse-blosxom-page-date-alist' for this page."
 130   (let ((date (match-string 1)))
 131     (save-match-data
 132       (add-to-list
 133        'muse-blosxom-page-date-alist
 134        `(,muse-publishing-current-file . ,date))))
 135   "")
 136
 137 ;; Enter a new blog entry
 138
 139 (defcustom muse-blosxom-base-directory "~/Blog"
 140   "Base directory of blog entries, used by `muse-blosxom-new-entry'.
 141 This is the top-level directory where your blog entries may be found
 142 locally."
 143   :type 'directory
 144   :group 'muse-blosxom)
 145
 146 (defun muse-blosxom-get-categories (&optional base)
 147   "Retrieve all of the categories from a Blosxom project.
 148 The base directory is specified by BASE, and defaults to
 149 `muse-blosxom-base-directory'.
 150
 151 Directories starting with \".\" will be ignored."
 152   (unless base (setq base muse-blosxom-base-directory))
 153   (let (list dir)
 154     (dolist (file (directory-files base t "^[^.]"))
 155       (when (file-directory-p file)     ; must be a directory
 156         (setq dir (file-name-nondirectory file))
 157         (push dir list)
 158         (nconc list (mapcar #'(lambda (item)
 159                                 (concat dir "/" item))
 160                             (muse-blosxom-get-categories file)))))
 161     list))
 162
 163 (defun muse-blosxom-title-to-file (title)
 164   "Derive a file name from the given TITLE.
 165
 166 Feel free to overwrite this if you have a different concept of what
 167 should be allowed in a filename."
 168   (muse-replace-regexp-in-string (concat "[^-." muse-regexp-alnum "]")
 169                                  "_" (downcase title)))
 170
 171 (defun muse-blosxom-new-entry (category title)
 172   "Start a new blog entry with given CATEGORY.
 173 The filename of the blog entry is derived from TITLE.
 174 The page will be initialized with the current date and TITLE."
 175   (interactive
 176    (list
 177     (completing-read "Category: " (muse-blosxom-get-categories))
 178     (read-string "Title: ")))
 179   (let ((file (muse-blosxom-title-to-file title)))
 180     (muse-project-find-file
 181      file "blosxom" nil
 182      (concat (directory-file-name muse-blosxom-base-directory)
 183              "/" category)))
 184   (goto-char (point-min))
 185   (insert "#date " (format-time-string "%4Y-%2m-%2d-%2H-%2M")
 186           "\n#title " title
 187           "\n\n")
 188   (forward-line 2))
 189
 190 ;; Make it easier to specify the muse-project-alist entry
 191 (defun muse-blosxom-project-alist-entry (entry-dir output-dir style)
 192   (cons `(:base ,style :path ,(expand-file-name output-dir)
 193                 :include ,(concat "/" (file-name-nondirectory entry-dir)
 194                                   "/[^/]+$"))
 195         (mapcar (lambda (dir);
 196                   `(:base ,style
 197                           :path ,(expand-file-name dir output-dir)
 198                           :include ,(concat "/" dir "/")))
 199                 (muse-blosxom-get-categories entry-dir))))
 200
 201 ;; Register the Blosxom Publisher
 202
 203 (unless (assoc "blosxom-html" muse-publishing-styles)
 204   (muse-derive-style "blosxom-html" "html"
 205                      :suffix    'muse-blosxom-extension
 206                      :header    'muse-blosxom-header
 207                      :footer    'muse-blosxom-footer)
 208
 209   (muse-derive-style "blosxom-xhtml" "xhtml"
 210                      :suffix    'muse-blosxom-extension
 211                      :header    'muse-blosxom-header
 212                      :footer    'muse-blosxom-footer))
 213
 214 (provide 'muse-blosxom)
 215
 216 ;;; muse-blosxom.el ends here