lisp/muse-blosxom.el

   1 ;;; muse-blosxom.el --- Publish a document tree for serving by (py)Blosxom
   2
   3 ;; Copyright (C) 2004, 2005  Free Software Foundation, Inc.
   4
   5 ;; Date: Wed, 23 March 2005
   6 ;; Author: Michael Olson (mwolson AT gnu DOT org)
   7 ;; Maintainer: Michael Olson (mwolson AT gnu DOT org)
   8
   9 ;; This file is not part of GNU Emacs.
  10
  11 ;; This is free software; you can redistribute it and/or modify it under
  12 ;; the terms of the GNU General Public License as published by the Free
  13 ;; Software Foundation; either version 2, or (at your option) any later
  14 ;; version.
  15 ;;
  16 ;; This is distributed in the hope that it will be useful, but WITHOUT
  17 ;; ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 ;; FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  19 ;; for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; The Blosxom publishing style publishes a tree of categorised files
  29 ;; to a mirrored tree of stories to be served by blosxom.cgi or
  30 ;; pyblosxom.cgi.
  31 ;;
  32 ;; Serving entries with (py)blosxom
  33 ;; --------------------------------
  34 ;;
  35 ;; Each Blosxom file must include `#date yyyy-mm-dd', or optionally
  36 ;; the longer `#date yyyy-mm-dd-hh-mm', a title (using the `#title'
  37 ;; directive) plus whatever normal content is desired.
  38 ;;
  39 ;; The date directive is not used directly by (py)blosxom or this
  40 ;; program.  You need to find two additional items to make use of this
  41 ;; feature.
  42 ;;
  43 ;;  1. A script to gather date directives from the entire blog tree
  44 ;;     into a single file.  The file must associate a blog entry with
  45 ;;     a date.
  46 ;;
  47 ;;  2. A plugin for (py)blosxom that reads this file.
  48 ;;
  49 ;; These 2 things are provided for pyblosxom in the contrib/pyblosxom
  50 ;; subdirectory.  `getstamps.py' provides the 1st service, while
  51 ;; `hardcodedates.py' provides the second service.  Eventually it is
  52 ;; hoped that a blosxom plugin and script will be found/written.
  53 ;;
  54 ;; Generating a project description
  55 ;; --------------------------------
  56 ;;
  57 ;; Muse-blosxom has some helper functions to make specifying
  58 ;; muse-blosxom projects a lot easier.  An example follows.
  59 ;;
  60 ;; (setq muse-project-alist
  61 ;;       `(("blog"
  62 ;;          (,@(muse-blosxom-project-alist-dirs "~/path/to/blog-entries")
  63 ;;           :default "index")
  64 ;;          ,@(muse-blosxom-project-alist-entry "~/path/to/blog-entries"
  65 ;;                                              "~/public_html/blog"
  66 ;;                                              "blosxom-xhtml")
  67 ;;         )))
  68 ;;
  69 ;; Note that we need a backtick instead of a single quote on the
  70 ;; second line of this example.
  71 ;;
  72 ;; Creating new blog entries
  73 ;; -------------------------
  74 ;;
  75 ;; There is a function called `muse-blosxom-new-entry' that will
  76 ;; automate the process of making a new blog entry.  To make use of
  77 ;; it, do the following.
  78 ;;
  79 ;;  - Customize `muse-blosxom-base-directory' to the location that
  80 ;;    your blog entries are stored.
  81 ;;
  82 ;;  - Assign the `muse-blosxom-new-entry' function to a key sequence.
  83 ;;    I use the following code to assign this function to `C-c p l'.
  84 ;;
  85 ;;    (global-set-key "\C-cpl" 'muse-blosxom-new-entry)
  86 ;;
  87 ;;  - You should create your directory structure ahead of time under
  88 ;;    your base directory.  These directories, which correspond with
  89 ;;    category names, may be nested.
  90 ;;
  91 ;;  - When you enter this key sequence, you will be prompted for the
  92 ;;    category of your entry and its title.  Upon entering this
  93 ;;    information, a new file will be created that corresponds with
  94 ;;    the title, but in lowercase letters and having special
  95 ;;    characters converted to underscores.  The title and date
  96 ;;    directives will be inserted automatically.
  97
  98 ;;; Contributors:
  99
 100 ;; Gary Vaughan (gary AT gnu DOT org) is the original author of
 101 ;; `emacs-wiki-blosxom.el', which is the ancestor of this file.
 102
 103 ;; Brad Collins (brad AT chenla DOT org) ported this file to Muse.
 104
 105 ;; Michael Olson (mwolson AT gnu DOT org) further adapted this file to
 106 ;; Muse and continues to maintain it.
 107
 108 ;;; Code:
 109
 110 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 111 ;;
 112 ;; Muse Blosxom Publishing
 113 ;;
 114 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 115
 116 (require 'muse-project)
 117 (require 'muse-publish)
 118 (require 'muse-html)
 119
 120 (defgroup muse-blosxom nil
 121   "Options controlling the behavior of Muse Blosxom publishing.
 122 See `muse-blosxom' for more information."
 123   :group 'muse-publish)
 124
 125 (defcustom muse-blosxom-extension ".txt"
 126   "Default file extension for publishing Blosxom files."
 127   :type 'string
 128   :group 'muse-blosxom)
 129
 130 (defcustom muse-blosxom-header
 131   "<lisp>(muse-publishing-directive \"title\")</lisp>\n"
 132   "Header used for publishing Blosxom files."
 133   :type '(choice string file)
 134   :group 'muse-blosxom)
 135
 136 (defcustom muse-blosxom-footer ""
 137   "Footer used for publishing Blosxom files."
 138   :type '(choice string file)
 139   :group 'muse-blosxom)
 140
 141 ;; Maintain (published-file . date) alist, which will later be written
 142 ;; to a timestamps file; not implemented yet.
 143
 144 (defvar muse-blosxom-page-date-alist nil)
 145
 146 (defun muse-blosxom-markup-date-directive ()
 147   "Add a date entry to `muse-blosxom-page-date-alist' for this page."
 148   (add-to-list
 149    'muse-blosxom-page-date-alist
 150    `(,muse-publishing-current-file . ,(muse-publishing-directive "date"))))
 151
 152 ;; Enter a new blog entry
 153
 154 (defcustom muse-blosxom-base-directory "~/Blog"
 155   "Base directory of blog entries, used by `muse-blosxom-new-entry'.
 156 This is the top-level directory where your blog entries may be found
 157 locally."
 158   :type 'directory
 159   :group 'muse-blosxom)
 160
 161 (defun muse-blosxom-get-categories (&optional base)
 162   "Retrieve all of the categories from a Blosxom project.
 163 The base directory is specified by BASE, and defaults to
 164 `muse-blosxom-base-directory'.
 165
 166 Directories starting with \".\" will be ignored."
 167   (unless base (setq base muse-blosxom-base-directory))
 168   (let (list dir)
 169     (dolist (file (directory-files base t "^[^.]"))
 170       (when (file-directory-p file)     ; must be a directory
 171         (setq dir (file-name-nondirectory file))
 172         (push dir list)
 173         (nconc list (mapcar #'(lambda (item)
 174                                 (concat dir "/" item))
 175                             (muse-blosxom-get-categories file)))))
 176     list))
 177
 178 (defun muse-blosxom-title-to-file (title)
 179   "Derive a file name from the given TITLE.
 180
 181 Feel free to overwrite this if you have a different concept of what
 182 should be allowed in a filename."
 183   (muse-replace-regexp-in-string (concat "[^-." muse-regexp-alnum "]")
 184                                  "_" (downcase title)))
 185
 186 (defun muse-blosxom-new-entry (category title)
 187   "Start a new blog entry with given CATEGORY.
 188 The filename of the blog entry is derived from TITLE.
 189 The page will be initialized with the current date and TITLE."
 190   (interactive
 191    (list
 192     (completing-read "Category: " (muse-blosxom-get-categories))
 193     (read-string "Title: ")))
 194   (let ((file (muse-blosxom-title-to-file title)))
 195     (muse-project-find-file
 196      file "blosxom" nil
 197      (concat (directory-file-name muse-blosxom-base-directory)
 198              "/" category)))
 199   (goto-char (point-min))
 200   (insert "#date " (format-time-string "%4Y-%2m-%2d-%2H-%2M")
 201           "\n#title " title
 202           "\n\n")
 203   (forward-line 2))
 204
 205 ;; Make it easier to specify the muse-project-alist entry
 206
 207 (defun muse-blosxom-project-alist-entry (entry-dir output-dir style)
 208   "Return a list of styles to use when publishing a muse-blosxom project.
 209 ENTRY-DIR is where your Muse blog entries are kept.
 210 OUTPUT-DIR is where these entries are published.
 211 STYLE is the publishing style to use.
 212
 213 For an example of the use of this function, see
 214 `examples/mwolson/muse-init.el' from the Muse distribution."
 215   (cons `(:base ,style :path ,(expand-file-name output-dir)
 216                 :include ,(concat "/" (file-name-nondirectory entry-dir)
 217                                   "/[^/]+$"))
 218         (mapcar (lambda (dir);
 219                   `(:base ,style
 220                           :path ,(expand-file-name dir output-dir)
 221                           :include ,(concat "/" dir "/")))
 222                 (muse-blosxom-get-categories entry-dir))))
 223
 224 (defun muse-blosxom-project-alist-dirs (entry-dir)
 225   "Return a list of directories to use when publishing a muse-blosxom project.
 226 ENTRY-DIR is where your Muse blog entries are kept.
 227
 228 For an example of the use of this function, see
 229 `examples/mwolson/muse-init.el' from the Muse distribution."
 230   (cons (expand-file-name entry-dir)
 231         (mapcar (lambda (dir) (expand-file-name dir entry-dir))
 232                 (muse-blosxom-get-categories entry-dir))))
 233
 234 ;; Register the Blosxom Publisher
 235
 236 (unless (assoc "blosxom-html" muse-publishing-styles)
 237   (muse-derive-style "blosxom-html" "html"
 238                      :suffix    'muse-blosxom-extension
 239                      :header    'muse-blosxom-header
 240                      :footer    'muse-blosxom-footer
 241                      :after     'muse-blosxom-markup-date-directive)
 242
 243   (muse-derive-style "blosxom-xhtml" "xhtml"
 244                      :suffix    'muse-blosxom-extension
 245                      :header    'muse-blosxom-header
 246                      :footer    'muse-blosxom-footer
 247                      :after     'muse-blosxom-markup-date-directive))
 248
 249 (provide 'muse-blosxom)
 250
 251 ;;; muse-blosxom.el ends here