lisp/muse-publish.el

   1 ;;; muse-publish.el --- base publishing implementation
   2
   3 ;; Copyright (C) 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5 ;; This file is part of Emacs Muse.  It is not part of GNU Emacs.
   6
   7 ;; Emacs Muse is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published
   9 ;; by the Free Software Foundation; either version 2, or (at your
  10 ;; option) any later version.
  11
  12 ;; Emacs Muse is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Emacs Muse; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  20 ;; Boston, MA 02110-1301, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Contributors:
  25
  26 ;; Yann Hodique (yann DOT hodique AT gmail DOT com) fixed an
  27 ;; unnecessary URL description transform in `muse-publish-url'.
  28
  29 ;; Peter K. Lee (saint AT corenova DOT com) provided the
  30 ;; `muse-style-elements-list' function.
  31
  32 ;; Jim Ottaway (j DOT ottaway AT lse DOT ac DOT uk) provided a
  33 ;; reference implementation for nested lists.
  34
  35 ;;; Code:
  36
  37 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  38 ;;
  39 ;; Muse Publishing
  40 ;;
  41 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  42
  43 (require 'muse)
  44 (require 'muse-regexps)
  45
  46 (defgroup muse-publish nil
  47   "Options controlling the general behavior of Muse publishing."
  48   :group 'muse)
  49
  50 (defcustom muse-before-publish-hook nil
  51   "A hook run in the buffer to be published, before it is done."
  52   :type 'hook
  53   :group 'muse-publish)
  54
  55 (defcustom muse-after-publish-hook nil
  56   "A hook run in the buffer to be published, after it is done."
  57   :type 'hook
  58   :group 'muse-publish)
  59
  60 (defcustom muse-publish-url-transforms
  61   '(muse-resolve-url)
  62   "A list of functions used to prepare URLs for publication.
  63 Each is passed the URL.  The transformed URL should be returned."
  64   :type 'hook
  65   :options '(muse-resolve-url)
  66   :group 'muse-publish)
  67
  68 (defcustom muse-publish-desc-transforms nil
  69   "A list of functions used to prepare URL desciptions for publication.
  70 Each is passed the description.  The modified description should
  71 be returned."
  72   :type 'hook
  73   :group 'muse-publish)
  74
  75 (defcustom muse-publish-comments-p nil
  76   "If nil, remove comments before publishing.
  77 If non-nil, publish comments using the markup of the current style."
  78   :type 'boolean
  79   :group 'muse-publish)
  80
  81 (defcustom muse-publish-report-threshhold 100000
  82   "If a file is this size or larger, report publishing progress."
  83   :type 'integer
  84   :group 'muse-publish)
  85
  86 (defcustom muse-publish-markup-regexps
  87   `(;; Remove leading and trailing whitespace from the file
  88     (1000 "\\(\\`\n+\\|\n+\\'\\)" 0 "")
  89
  90     ;; Remove trailing whitespace from all lines
  91     (1100 ,(concat "[" muse-regexp-blank "]+$") 0 "")
  92
  93     ;; Handle any leading #directives
  94     (1200 "\\`#\\([a-zA-Z-]+\\)\\s-+\\(.+\\)\n+" 0 directive)
  95
  96     ;; markup tags
  97     (1300 muse-tag-regexp 0 tag)
  98
  99     ;; commented lines
 100     (1350 "^;\\s-+\\(.+\\)" 0 comment)
 101
 102     ;; prevent emphasis characters in explicit links from being marked
 103     (1400 muse-explicit-link-regexp 0 muse-publish-mark-noemphasis)
 104
 105     ;; define anchor points
 106     (1500 "^\\(\\W*\\)#\\(\\S-+\\)\\s-*" 0 anchor)
 107
 108     ;; emphasized or literal text
 109     (1600 ,(concat "\\(^\\|[-[" muse-regexp-blank
 110                    "<('`\"\n]\\)\\(=[^=" muse-regexp-blank
 111                    "\n]\\|_[^_" muse-regexp-blank
 112                    "\n]\\|\\*+[^*" muse-regexp-blank
 113                    "\n]\\)")
 114           2 word)
 115
 116     ;; headings, outline-mode style
 117     (1700 "^\\(\\*+\\)\\s-+" 0 heading)
 118
 119     ;; ellipses
 120     (1800 "\\.\\.\\.\\." 0 enddots)
 121     (1850 "\\.\\.\\." 0 dots)
 122
 123     ;; horizontal rule, or section separator
 124     (1900 "^----+" 0 rule)
 125
 126     ;; non-breaking space
 127     (1950 "~~" 0 no-break-space)
 128
 129     ;; beginning of footnotes section
 130     (2000 "^Footnotes:?\\s-*" 0 fn-sep)
 131     ;; footnote definition/reference (def if at beginning of line)
 132     (2100 "\\[\\([1-9][0-9]*\\)\\]" 0 footnote)
 133
 134     ;; unnumbered List items begin with a -.  numbered list items
 135     ;; begin with number and a period.  definition lists have a
 136     ;; leading term separated from the body with ::.  centered
 137     ;; paragraphs begin with at least six columns of whitespace; any
 138     ;; other whitespace at the beginning indicates a blockquote.  The
 139     ;; reason all of these rules are handled here, is so that
 140     ;; blockquote detection doesn't interfere with indented list
 141     ;; members.
 142
 143     (2200 ,(format muse-list-item-regexp (concat "[" muse-regexp-blank "]*"))
 144           0 list)
 145
 146     (2400 ,(concat "^\\([" muse-regexp-blank "]+\\).+") 0 quote)
 147
 148     (2500 ,(concat "\\(^\\|[" muse-regexp-blank "]+\\)--\\($\\|["
 149                    muse-regexp-blank "]+\\)")
 150           0 emdash)
 151
 152     ;; "verse" text is indicated the same way as a quoted e-mail
 153     ;; response: "> text", where text may contain initial whitespace
 154     ;; (see below).
 155     (2600 ,(concat "^[" muse-regexp-blank "]*> ") 0 verse)
 156
 157     ;; simple table markup is supported, nothing fancy.  use | to
 158     ;; separate cells, || to separate header cells, and ||| for footer
 159     ;; cells
 160     (2700 ,(concat "\\(\\([" muse-regexp-blank "]*\n\\)?"
 161                    "\\(" muse-table-line-regexp "\\(?:\n\\|\\'\\)\\)\\)+")
 162           0 table)
 163
 164     ;; replace links in the buffer (links to other pages)
 165     (2900 muse-explicit-link-regexp 0 link)
 166
 167     ;; bare URLs
 168     (3000 muse-url-regexp 0 url)
 169
 170     ;; bare email addresses
 171     (3500
 172      "\\([^[]\\)[-a-zA-Z0-9._]+@\\([-a-zA-z0-9_]+\\.\\)+[a-zA-Z0-9]+" 0 email)
 173     )
 174   "List of markup rules for publishing a page with Muse.
 175 The rules given in this variable are invoked first, followed by
 176 whatever rules are specified by the current style.
 177
 178 Each member of the list is either a function, or a list of the form:
 179
 180   (REGEXP/SYMBOL TEXT-BEGIN-GROUP REPLACEMENT-TEXT/FUNCTION/SYMBOL)
 181
 182 REGEXP is a regular expression, or symbol whose value is a regular
 183 expression, which is searched for using `re-search-forward'.
 184 TEXT-BEGIN-GROUP is the matching group within that regexp which
 185 denotes the beginning of the actual text to be marked up.
 186 REPLACEMENT-TEXT is a string that will be passed to `replace-match'.
 187 If it is not a string, but a function, it will be called to determine
 188 what the replacement text should be (it must return a string).  If it
 189 is a symbol, the value of that symbol should be a string.
 190
 191 The replacements are done in order, one rule at a time.  Writing
 192 the regular expressions can be a tricky business.  Note that case
 193 is never ignored.  `case-fold-search' is always bound to nil
 194 while processing the markup rules."
 195   :type '(repeat (choice
 196                   (list :tag "Markup rule"
 197                         integer
 198                         (choice regexp symbol)
 199                         integer
 200                         (choice string function symbol))
 201                   function))
 202   :group 'muse-publish)
 203
 204 (defcustom muse-publish-markup-functions
 205   '((directive . muse-publish-markup-directive)
 206     (comment   . muse-publish-markup-comment)
 207     (anchor    . muse-publish-markup-anchor)
 208     (tag       . muse-publish-markup-tag)
 209     (word      . muse-publish-markup-word)
 210     (emdash    . muse-publish-markup-emdash)
 211     (enddots   . muse-publish-markup-enddots)
 212     (dots      . muse-publish-markup-dots)
 213     (rule      . muse-publish-markup-rule)
 214     (no-break-space . muse-publish-markup-no-break-space)
 215     (heading   . muse-publish-markup-heading)
 216     (footnote  . muse-publish-markup-footnote)
 217     (fn-sep    . muse-publish-markup-fn-sep)
 218     (list      . muse-publish-markup-list)
 219     (quote     . muse-publish-markup-quote)
 220     (verse     . muse-publish-markup-verse)
 221     (table     . muse-publish-markup-table)
 222     (email     . muse-publish-markup-email)
 223     (link      . muse-publish-markup-link)
 224     (url       . muse-publish-markup-url))
 225   "An alist of style types to custom functions for that kind of text.
 226
 227 Each member of the list is of the form:
 228
 229   (SYMBOL FUNCTION)
 230
 231 SYMBOL describes the type of text to associate with this rule.
 232 `muse-publish-markup-regexps' maps regexps to these symbols.
 233
 234 FUNCTION is the function to use to mark up this kind of rule if
 235 no suitable function is found through the :functions tag of the
 236 current style."
 237   :type '(alist :key-type symbol :value-type function)
 238   :group 'muse-publish)
 239
 240 (defcustom muse-publish-markup-tags
 241   '(("contents" nil t   muse-publish-contents-tag)
 242     ("verse"    t   nil muse-publish-verse-tag)
 243     ("example"  t   nil muse-publish-example-tag)
 244     ("code"     t   nil muse-publish-code-tag)
 245     ("quote"    t   nil muse-publish-quote-tag)
 246     ("literal"  t   nil muse-publish-mark-read-only)
 247     ("verbatim" t   nil muse-publish-verbatim-tag)
 248     ("lisp"     t   nil muse-publish-lisp-tag)
 249     ("class"    t   t   muse-publish-class-tag)
 250     ("command"  t   t   muse-publish-command-tag)
 251     ("comment"  t   nil muse-publish-comment-tag))
 252   "A list of tag specifications, for specially marking up text.
 253 XML-style tags are the best way to add custom markup to Muse.
 254 This is easily accomplished by customizing this list of markup tags.
 255
 256 For each entry, the name of the tag is given, whether it expects
 257 a closing tag and/or an optional set of attributes, and a
 258 function that performs whatever action is desired within the
 259 delimited region.
 260
 261 The tags themselves are deleted during publishing, before the
 262 function is called.  The function is called with three arguments,
 263 the beginning and end of the region surrounded by the tags.  If
 264 properties are allowed, they are passed as a third argument in
 265 the form of an alist.  The `end' argument to the function is
 266 always a marker.
 267
 268 Point is always at the beginning of the region within the tags, when
 269 the function is called.  Wherever point is when the function finishes
 270 is where tag markup will resume.
 271
 272 These tag rules are processed once at the beginning of markup, and
 273 once at the end, to catch any tags which may have been inserted
 274 in-between."
 275   :type '(repeat (list (string :tag "Markup tag")
 276                        (boolean :tag "Expect closing tag" :value t)
 277                        (boolean :tag "Parse attributes" :value nil)
 278                        function))
 279   :group 'muse-publish)
 280
 281 (defcustom muse-publish-markup-specials nil
 282   "A table of characters which must be represented specially."
 283   :type '(alist :key-type character :value-type string)
 284   :group 'muse-publish)
 285
 286 (defvar muse-publishing-p nil
 287   "Set to t while a page is being published.")
 288 (defvar muse-batch-publishing-p nil
 289   "Set to t while a page is being batch published.")
 290 (defvar muse-publishing-styles nil
 291   "The publishing styles that Muse recognizes.
 292 This is automatically generated when loading publishing styles.")
 293 (defvar muse-publishing-current-file nil
 294   "The file that is currently being published.")
 295 (defvar muse-publishing-current-output-path nil
 296   "The path where the current file will be published to.")
 297 (defvar muse-publishing-current-style nil
 298   "The style of the file that is currently being published.")
 299 (defvar muse-publishing-directives nil
 300   "An alist of publishing directives from the top of a file.")
 301 (defvar muse-publish-generate-contents nil
 302   "Non-nil if a table of contents should be generated.
 303 If non-nil, it is a cons cell specifying (MARKER . DEPTH), to
 304 tell where the <contents> was seen, and to what depth the
 305 contents were requested.")
 306 (defvar muse-publishing-last-position nil
 307   "Last position of the point when publishing.
 308 This is used to make sure that publishing doesn't get stalled.")
 309
 310 ;; Functions for handling style information
 311
 312 (defsubst muse-style (&optional style)
 313   "Resolve the given STYLE into a Muse style, if it is a string."
 314   (if (null style)
 315       muse-publishing-current-style
 316     (if (stringp style)
 317         (assoc style muse-publishing-styles)
 318       (muse-assert (consp style))
 319       style)))
 320
 321 (defun muse-define-style (name &rest elements)
 322   (let ((entry (assoc name muse-publishing-styles)))
 323     (if entry
 324         (error "There is already a style named %s." name)
 325       (setq muse-publishing-styles
 326             (cons (append (list name) elements)
 327                   muse-publishing-styles)))))
 328
 329 (defun muse-derive-style (new-name base-name &rest elements)
 330   (let ((entry (assoc new-name muse-publishing-styles)))
 331     (if entry
 332         (error "There is already a style named %s." new-name)
 333       (apply 'muse-define-style new-name
 334              (append elements (list :base base-name))))))
 335
 336 (defsubst muse-get-keyword (keyword list &optional direct)
 337   (let ((value (cadr (memq keyword list))))
 338     (if (and (not direct) (symbolp value))
 339         (symbol-value value)
 340       value)))
 341
 342 (defun muse-style-elements-list (elem &optional style)
 343   "Return a list all references to ELEM in STYLE, including base styles.
 344 If STYLE is not specified, use current style."
 345   (let (base elements)
 346     (while style
 347       (setq style (muse-style style))
 348       (setq elements (append elements
 349                              (muse-get-keyword elem style)))
 350       (setq style (muse-get-keyword :base style)))
 351     elements))
 352
 353 (defsubst muse-style-element (elem &optional style direct)
 354   "Search for ELEM in STYLE, including base styles.
 355 If STYLE is not specified, use current style."
 356   (setq style (muse-style style))
 357   (let ((value (muse-get-keyword elem style direct)))
 358     (if value
 359         value
 360       (let ((base (muse-get-keyword :base style)))
 361         (if base
 362             (muse-style-element elem base direct))))))
 363
 364 (defun muse-find-markup-element (keyword ident style)
 365   (let ((def (assq ident (muse-style-element keyword style))))
 366     (if def
 367         (cdr def)
 368       (let ((base (muse-style-element :base style)))
 369         (if base
 370             (muse-find-markup-element keyword ident base))))))
 371
 372 (defun muse-markup-text (ident &rest args)
 373   "Insert ARGS into the text markup associated with IDENT.
 374 If the markup text has sections like %N%, this will be replaced
 375 with the N-1th argument in ARGS.  After that, `format' is applied
 376 to the text with ARGS as parameters."
 377   (let ((text (muse-find-markup-element :strings ident (muse-style))))
 378     (if (and text args)
 379         (progn
 380           (let (start repl-text)
 381             (while (setq start (string-match "%\\([1-9][0-9]*\\)%" text start))
 382               ;; escape '%' in the argument text, since we will be
 383               ;; using format on it
 384               (setq repl-text (muse-replace-regexp-in-string
 385                                "%" "%%"
 386                                (nth (1- (string-to-number
 387                                          (match-string 1 text))) args)
 388                                t t)
 389                     start (+ start (length repl-text))
 390                     text (replace-match repl-text t t text))))
 391           (apply 'format text args))
 392       (or text ""))))
 393
 394 (defun muse-insert-markup (&rest args)
 395   (let ((beg (point)))
 396     (apply 'insert args)
 397     (muse-publish-mark-read-only beg (point))))
 398
 399 (defun muse-find-markup-tag (keyword tagname style)
 400   (let ((def (assoc tagname (muse-style-element keyword style))))
 401     (or def
 402         (let ((base (muse-style-element :base style)))
 403           (if base
 404               (muse-find-markup-tag keyword tagname base))))))
 405
 406 (defsubst muse-markup-tag-info (tagname &rest args)
 407   (let ((tag-info (muse-find-markup-tag :tags tagname (muse-style))))
 408     (or tag-info
 409         (assoc (match-string 1) muse-publish-markup-tags))))
 410
 411 (defsubst muse-markup-function (category)
 412   (let ((func (muse-find-markup-element :functions category (muse-style))))
 413     (or func
 414         (cdr (assq category muse-publish-markup-functions)))))
 415
 416 ;; Publishing routines
 417
 418 (defun muse-publish-markup (name rules)
 419   (let* ((case-fold-search nil)
 420          (inhibit-read-only t)
 421          (limit (* (length rules) (point-max)))
 422          (verbose (and muse-publish-report-threshhold
 423                        (> (point-max) muse-publish-report-threshhold)))
 424          (base 0))
 425     (while rules
 426       (goto-char (point-min))
 427       (let ((regexp (nth 1 (car rules)))
 428             (group (nth 2 (car rules)))
 429             (repl (nth 3 (car rules)))
 430             pos)
 431         (setq muse-publishing-last-position nil)
 432         (if (symbolp regexp)
 433             (setq regexp (symbol-value regexp)))
 434         (if (and verbose (not muse-batch-publishing-p))
 435             (message "Publishing %s...%d%%" name
 436                      (* (/ (float (+ (point) base)) limit) 100)))
 437         (while (and regexp (setq pos (re-search-forward regexp nil t)))
 438           (if (and verbose (not muse-batch-publishing-p))
 439               (message "Publishing %s...%d%%" name
 440                        (* (/ (float (+ (point) base)) limit) 100)))
 441           (unless (and (> (- (match-end 0) (match-beginning 0)) 0)
 442                        (get-text-property (match-beginning group) 'read-only))
 443             (let* (func
 444                    (text (cond
 445                           ((and (symbolp repl)
 446                                 (setq func (muse-markup-function repl)))
 447                            (funcall func))
 448                           ((functionp repl)
 449                            (funcall repl))
 450                           ((symbolp repl)
 451                            (symbol-value repl))
 452                           (t repl))))
 453               (if (stringp text)
 454                   (replace-match text t))))
 455           (if (and muse-publishing-last-position
 456                    (= pos muse-publishing-last-position))
 457               (if (eobp)
 458                   (setq regexp nil)
 459                 (forward-char 1)))
 460           (setq muse-publishing-last-position pos)))
 461       (setq rules (cdr rules)
 462             base (+ base (point-max))))
 463     (if (and verbose (not muse-batch-publishing-p))
 464         (message "Publishing %s...done" name))))
 465
 466 (defun muse-insert-file-or-string (file-or-string &optional title)
 467   (let ((beg (point)) end)
 468     (if (and (not (string-equal file-or-string ""))
 469              (file-readable-p file-or-string))
 470         (setq end (+ beg (cadr (insert-file-contents file-or-string))))
 471       (insert file-or-string)
 472       (setq end (point)))
 473     (save-restriction
 474       (narrow-to-region beg end)
 475       (remove-text-properties (point-min) (point-max)
 476                               '(read-only nil rear-nonsticky nil))
 477       (goto-char (point-min))
 478       (muse-publish-markup (or title "")
 479                            '((100 "<\\(lisp\\)>" 0
 480                               muse-publish-markup-tag))))))
 481
 482 (defun muse-style-run-hooks (keyword style &rest args)
 483   (catch 'handled
 484     (while (and style
 485                 (setq style (muse-style style)))
 486       (let ((func (muse-get-keyword keyword style t)))
 487         (when (and func
 488                    (apply func args))
 489           (throw 'handled t)))
 490       (setq style (muse-style-element :base style)))))
 491
 492 (defun muse-publish-markup-region (beg end title style)
 493   "Apply the given STYLE's markup rules to the given region."
 494   (save-restriction
 495     (narrow-to-region beg end)
 496     (muse-style-run-hooks :before style)
 497     (muse-publish-markup
 498      title
 499      (sort (copy-alist (append muse-publish-markup-regexps
 500                                (muse-style-elements-list :regexps style)))
 501            (function
 502             (lambda (l r)
 503               (< (car l) (car r))))))
 504     (muse-style-run-hooks :before-end style)
 505     (muse-publish-escape-specials (point-min) (point-max) nil 'document)))
 506
 507 (defun muse-publish-markup-buffer (title style)
 508   "Apply the given STYLE's markup rules to the current buffer."
 509   (setq style (muse-style style))
 510   (let ((style-header (muse-style-element :header style))
 511         (style-footer (muse-style-element :footer style))
 512         (muse-publishing-current-style style)
 513         (muse-publishing-directives
 514          (list (cons "title" title)
 515                (cons "author" (user-full-name))
 516                (cons "date" (format-time-string
 517                              "%B %e, %Y"
 518                              (nth 5 (file-attributes
 519                                      muse-publishing-current-file))))))
 520         (muse-publishing-p t)
 521         (inhibit-read-only t))
 522     (run-hooks 'muse-before-publish-hook)
 523     (muse-publish-markup-region (point-min) (point-max) title style)
 524     (goto-char (point-min))
 525     (when style-header
 526       (muse-insert-file-or-string style-header title))
 527     (goto-char (point-max))
 528     (when style-footer
 529       (muse-insert-file-or-string style-footer title))
 530     (muse-style-run-hooks :after style)
 531     (run-hooks 'muse-after-publish-hook)))
 532
 533 (defun muse-publish-markup-string (string &optional style)
 534   "Markup STRING using the given STYLE's markup rules."
 535   (setq style (muse-style style))
 536   (muse-with-temp-buffer
 537     (insert string)
 538     (let ((muse-publishing-current-style style)
 539           (muse-publishing-p t))
 540       (muse-publish-markup "*string*" (muse-style-element :rules style)))
 541     (buffer-string)))
 542
 543 ;; Commands for publishing files
 544
 545 (defsubst muse-publish-get-style ()
 546   (if (= 1 (length muse-publishing-styles))
 547       (car muse-publishing-styles)
 548     (assoc (completing-read "Publish with style: "
 549                             muse-publishing-styles nil t)
 550            muse-publishing-styles)))
 551
 552 (defsubst muse-publish-get-output-dir (style)
 553   (let ((default-directory (or (muse-style-element :path style)
 554                                default-directory)))
 555     (muse-read-directory-name "Publish to directory: " nil default-directory)))
 556
 557 (defsubst muse-publish-get-info ()
 558   (let ((style (muse-publish-get-style)))
 559     (list style (muse-publish-get-output-dir style)
 560           current-prefix-arg)))
 561
 562 (defsubst muse-publish-output-name (&optional file style)
 563   (setq style (muse-style style))
 564   (concat (muse-style-element :prefix style)
 565           (muse-page-name file)
 566           (muse-style-element :suffix style)))
 567
 568 (defsubst muse-publish-output-file (file &optional output-dir style)
 569   (setq style (muse-style style))
 570   (if output-dir
 571       (expand-file-name (muse-publish-output-name file style) output-dir)
 572     (concat (file-name-directory file)
 573             (muse-publish-output-name file style))))
 574
 575 (defsubst muse-publish-link-name (&optional file style)
 576   (setq style (muse-style style))
 577   (concat (muse-style-element :prefix style)
 578           (muse-page-name file)
 579           (or (muse-style-element :link-suffix style)
 580               (muse-style-element :suffix style))))
 581
 582 (defsubst muse-publish-link-file (file &optional output-dir style)
 583   (setq style (muse-style style))
 584   (if output-dir
 585       (expand-file-name (muse-publish-link-name file style) output-dir)
 586     (concat (file-name-directory file)
 587             (muse-publish-link-name file style))))
 588
 589 (defun muse-detect-invalid-style (style)
 590   "Throw an error if STYLE is invalid."
 591   (setq style (muse-style style))
 592   (when (null style)
 593     (error "Invalid style"))
 594   (setq style (muse-style-element :base style))
 595   (when (null style)
 596     (error "Style does not contain a :base value"))
 597   (unless (muse-style style)
 598     (error "Cannot find the %s publishing style" style)))
 599
 600 ;;;###autoload
 601 (defun muse-publish-file (file style &optional output-dir force)
 602   "Publish the given FILE in a particular STYLE to OUTPUT-DIR.
 603 If the argument FORCE is nil, each file is only published if it is
 604 newer than the published version.  If the argument FORCE is non-nil,
 605 the file is published no matter what."
 606   (interactive (cons (read-file-name "Publish file: ")
 607                      (muse-publish-get-info)))
 608   (setq style (muse-style style))
 609   (muse-detect-invalid-style style)
 610   (let* ((output-path (muse-publish-output-file file output-dir style))
 611          (output-suffix (muse-style-element :osuffix style))
 612          (muse-publishing-current-file file)
 613          (muse-publishing-current-output-path output-path)
 614          (target (if output-suffix
 615                      (concat (file-name-sans-extension output-path)
 616                              output-suffix)
 617                    output-path))
 618          (threshhold (nth 7 (file-attributes file))))
 619     (if (not threshhold)
 620         (message "Please save %s before publishing" file)
 621       (when (or force (file-newer-than-file-p file target))
 622         (if (and muse-publish-report-threshhold
 623                  (> threshhold
 624                     muse-publish-report-threshhold))
 625             (message "Publishing %s ..." file))
 626         (muse-with-temp-buffer
 627           (insert-file-contents file)
 628           (muse-publish-markup-buffer (muse-page-name file) style)
 629           (let ((backup-inhibited t))
 630             (write-file output-path))
 631           (muse-style-run-hooks :final style file output-path target))
 632         t))))
 633
 634 ;;;###autoload
 635 (defun muse-publish-this-file (style output-dir &optional force)
 636   "Publish the page in the current file."
 637   (interactive (muse-publish-get-info))
 638   (unless (muse-publish-file buffer-file-name style output-dir force)
 639     (message (concat "The published version is up-to-date; use"
 640                      " C-u C-c C-t to force an update."))))
 641
 642 (defun muse-batch-publish-files ()
 643   "Publish Muse files in batch mode."
 644   (let ((muse-batch-publishing-p t)
 645         style-name style output-dir)
 646     (setq style-name (car command-line-args-left)
 647           style (muse-style style-name)
 648           command-line-args-left (cdr command-line-args-left)
 649           output-dir (car command-line-args-left)
 650           output-dir
 651           (if (string-match "\\`--output-dir=" output-dir)
 652               (prog1
 653                   (substring output-dir (match-end 0))
 654                 (setq command-line-args-left (cdr command-line-args-left)))))
 655     (unless style
 656       (error "There is no style '%s' defined." style-name))
 657     (dolist (file command-line-args-left)
 658       (muse-publish-file file style output-dir t))))
 659
 660 ;; Default publishing rules
 661
 662 (defun muse-publish-section-close (depth)
 663   "Seach forward for the closing tag of given DEPTH."
 664   (let (not-end)
 665     (save-excursion
 666       (while (and (setq not-end (re-search-forward
 667                                  (concat "^\\*\\{1," (number-to-string depth)
 668                                          "\\}\\s-+")
 669                                  nil t))
 670                   (get-text-property (match-beginning 0) 'read-only)))
 671       (if not-end
 672           (forward-line 0)
 673         (goto-char (point-max)))
 674       (cond ((not (eq (char-before) ?\n))
 675              (insert "\n\n"))
 676             ((not (eq (char-before (1- (point))) ?\n))
 677              (insert "\n")))
 678       (muse-insert-markup (muse-markup-text 'section-close depth))
 679       (insert "\n"))))
 680
 681 (defun muse-publish-markup-directive (&optional name value)
 682   (unless name (setq name (match-string 1)))
 683   (unless value (setq value (match-string 2)))
 684   (let ((elem (assoc name muse-publishing-directives)))
 685     (if elem
 686         (setcdr elem value)
 687       (setq muse-publishing-directives
 688             (cons (cons name value)
 689                   muse-publishing-directives))))
 690   ;; Make sure we don't ever try to move the point forward (past the
 691   ;; beginning of buffer) while we're still searching for directives.
 692   (setq muse-publishing-last-position nil)
 693   (delete-region (match-beginning 0) (match-end 0)))
 694
 695 (defun muse-publish-markup-anchor ()
 696   (unless (get-text-property (match-end 1) 'noemphasis)
 697     (let ((text (muse-markup-text 'anchor (match-string 2))))
 698       (unless (string= text "")
 699         (save-match-data
 700           (skip-chars-forward (concat muse-regexp-blank "\n"))
 701           (muse-insert-markup text)))
 702       (match-string 1))))
 703
 704 (defun muse-publish-markup-comment ()
 705   (if (null muse-publish-comments-p)
 706       ""
 707     (goto-char (match-end 0))
 708     (muse-insert-markup (muse-markup-text 'comment-end))
 709     (muse-publish-mark-read-only (match-beginning 1) (match-end 1))
 710     (delete-region (match-beginning 0) (match-beginning 1))
 711     (goto-char (match-beginning 0))
 712     (muse-insert-markup (muse-markup-text 'comment-begin))))
 713
 714 (defun muse-publish-markup-tag ()
 715   (let ((tag-info (muse-markup-tag-info (match-string 1))))
 716     (when (and tag-info
 717                (not (get-text-property (match-beginning 0) 'read-only)))
 718       (let ((closed-tag (match-string 3))
 719             (start (match-beginning 0))
 720             (beg (point))
 721             end attrs)
 722         (when (nth 2 tag-info)
 723           (let ((attrstr (match-string 2)))
 724             (while (and attrstr
 725                         (string-match (concat "\\([^"
 726                                               muse-regexp-blank
 727                                               "=\n]+\\)\\(=\"\\"
 728                                               "([^\"]+\\)\"\\)?")
 729                                       attrstr))
 730               (let ((attr (cons (downcase
 731                                  (muse-match-string-no-properties 1 attrstr))
 732                                 (muse-match-string-no-properties 3 attrstr))))
 733                 (setq attrstr (replace-match "" t t attrstr))
 734                 (if attrs
 735                     (nconc attrs (list attr))
 736                   (setq attrs (list attr)))))))
 737         (if (and (cadr tag-info) (not closed-tag))
 738             (if (search-forward (concat "</" (car tag-info) ">") nil t)
 739                 (delete-region (match-beginning 0) (point))
 740               (setq tag-info nil)))
 741         (when tag-info
 742           (setq end (point-marker))
 743           (delete-region start beg)
 744           (goto-char start)
 745           (let ((args (list start end)))
 746             (if (nth 2 tag-info)
 747                 (nconc args (list attrs)))
 748             (apply (nth 3 tag-info) args))))))
 749   nil)
 750
 751 (defun muse-publish-escape-specials (beg end &optional ignore-read-only context)
 752   "Escape specials from BEG to END using style-specific :specials.
 753 If IGNORE-READ-ONLY is non-nil, ignore the read-only property.
 754 CONTEXT is used to figure out what kind of specials to escape.
 755
 756 The following contexts exist in Muse.
 757 'underline  _underlined text_
 758 'literal    =monospaced text= or <code>region</code> (monospaced, escaped)
 759 'emphasis   *emphasized text*
 760 'email      email@example.com
 761 'url        http://example.com
 762 'url-desc   [[...][description of an extended link]]
 763 'example    <example>region</example> (monospaced, block context, escaped)
 764 'verbatim   <verbatim>region</verbatim> (escaped)
 765 'document   normal text"
 766   (let ((specials (muse-style-element :specials nil t)))
 767     (cond ((functionp specials)
 768            (setq specials (funcall specials context)))
 769           ((symbolp specials)
 770            (setq specials (symbol-value specials))))
 771     (if (functionp specials)
 772         (funcall specials beg end ignore-read-only)
 773       (save-excursion
 774         (save-restriction
 775         (narrow-to-region beg end)
 776         (goto-char (point-min))
 777         (while (< (point) (point-max))
 778           (if (and (not ignore-read-only)
 779                    (get-text-property (point) 'read-only))
 780               (goto-char (or (next-single-property-change (point) 'read-only)
 781                              (point-max)))
 782             (let ((repl (or (assoc (char-after) specials)
 783                             (assoc (char-after)
 784                                    muse-publish-markup-specials))))
 785               (if (null repl)
 786                   (forward-char 1)
 787                 (delete-char 1)
 788                 (insert-before-markers (cdr repl)))))))))))
 789
 790 (defun muse-publish-markup-word ()
 791   (let* ((beg (match-beginning 2))
 792          (end (1- (match-end 2)))
 793          (leader (buffer-substring-no-properties beg end))
 794          open-tag close-tag mark-read-only loc context)
 795     (cond
 796      ((string= leader "_")
 797       (setq context 'underline
 798             open-tag (muse-markup-text 'begin-underline)
 799             close-tag (muse-markup-text 'end-underline)))
 800      ((string= leader "=")
 801       (setq context 'literal
 802             open-tag (muse-markup-text 'begin-literal)
 803             close-tag (muse-markup-text 'end-literal))
 804       (setq mark-read-only t))
 805      (t
 806       (let ((l (length leader)))
 807         (setq context 'emphasis)
 808         (cond
 809          ((= l 1) (setq open-tag (muse-markup-text 'begin-emph)
 810                         close-tag (muse-markup-text 'end-emph)))
 811          ((= l 2) (setq open-tag (muse-markup-text 'begin-more-emph)
 812                         close-tag (muse-markup-text 'end-more-emph)))
 813          ((= l 3) (setq open-tag (muse-markup-text 'begin-most-emph)
 814                         close-tag (muse-markup-text 'end-most-emph)))
 815          (t (setq context nil))))))
 816     (if (and context
 817              (not (get-text-property beg 'noemphasis))
 818              (setq loc (search-forward leader nil t))
 819              (or (eobp) (not (eq (char-syntax (char-after loc)) ?w)))
 820              (not (eq (char-syntax (char-before (point))) ?\ ))
 821              (not (get-text-property (point) 'noemphasis)))
 822         (progn
 823           (replace-match "")
 824           (delete-region beg end)
 825           (setq end (point-marker))
 826           (muse-insert-markup close-tag)
 827           (goto-char beg)
 828           (muse-insert-markup open-tag)
 829           (setq beg (point))
 830           (when mark-read-only
 831             (muse-publish-escape-specials beg end t context)
 832             (muse-publish-mark-read-only beg end)))
 833       (backward-char))
 834     nil))
 835
 836 (defun muse-publish-markup-emdash ()
 837   (delete-region (match-beginning 0) (match-end 0))
 838   (muse-insert-markup (muse-markup-text 'emdash))
 839   (if (eq (char-after) ?\<)
 840       (insert ?\n)))
 841
 842 (defun muse-publish-markup-enddots ()
 843   (unless (get-text-property (match-beginning 0) 'noemphasis)
 844     (delete-region (match-beginning 0) (match-end 0))
 845     (muse-insert-markup (muse-markup-text 'enddots))))
 846
 847 (defun muse-publish-markup-dots ()
 848   (unless (get-text-property (match-beginning 0) 'noemphasis)
 849     (delete-region (match-beginning 0) (match-end 0))
 850     (muse-insert-markup (muse-markup-text 'dots))))
 851
 852 (defun muse-publish-markup-rule ()
 853   (unless (get-text-property (match-beginning 0) 'noemphasis)
 854     (delete-region (match-beginning 0) (match-end 0))
 855     (muse-insert-markup (muse-markup-text 'rule))))
 856
 857 (defun muse-publish-markup-no-break-space ()
 858   (unless (get-text-property (match-beginning 0) 'noemphasis)
 859     (delete-region (match-beginning 0) (match-end 0))
 860     (muse-insert-markup (muse-markup-text 'no-break-space))))
 861
 862 (defun muse-publish-markup-heading ()
 863   (let* ((len (length (match-string 1)))
 864          (start (muse-markup-text
 865                  (cond ((= len 1) 'section)
 866                        ((= len 2) 'subsection)
 867                        ((= len 3) 'subsubsection)
 868                        (t 'section-other))
 869                  len))
 870          (end   (muse-markup-text
 871                  (cond ((= len 1) 'section-end)
 872                        ((= len 2) 'subsection-end)
 873                        ((= len 3) 'subsubsection-end)
 874                        (t 'section-other-end))
 875                  len)))
 876     (delete-region (match-beginning 0) (match-end 0))
 877     (muse-insert-markup start)
 878     (end-of-line)
 879     (when end
 880       (muse-insert-markup end))
 881     (muse-publish-section-close len)))
 882
 883 (defvar muse-publish-footnotes nil)
 884
 885 (defun muse-publish-markup-footnote ()
 886   "Scan ahead and snarf up the footnote body"
 887   (cond
 888    ((get-text-property (match-beginning 0) 'noemphasis)
 889     nil)
 890    ((= (muse-line-beginning-position) (match-beginning 0))
 891     "")
 892    (t
 893     (let ((footnote (save-match-data
 894                       (string-to-number (match-string 1))))
 895           footnotemark)
 896       (delete-region (match-beginning 0) (match-end 0))
 897       (save-excursion
 898         (when (re-search-forward (format "^\\[%d\\]\\s-+" footnote) nil t)
 899           (let* ((start (match-beginning 0))
 900                  (beg (goto-char (match-end 0)))
 901                  (end (save-excursion
 902                         (if (search-forward "\n\n" nil t)
 903                             (copy-marker (match-beginning 0))
 904                           (goto-char (point-max))
 905                           (skip-chars-backward "\n")
 906                           (point-marker)))))
 907             (while (re-search-forward
 908                     (concat "^[" muse-regexp-blank "]+\\([^\n]\\)")
 909                     end t)
 910               (replace-match "\\1" t))
 911             (let ((footnotemark-cmd (muse-markup-text 'footnotemark))
 912                   (footnotemark-end-cmd (muse-markup-text 'footnotemark-end)))
 913               (if (string= "" footnotemark-cmd)
 914                   (setq footnotemark
 915                         (concat (muse-markup-text 'footnote)
 916                                 (buffer-substring-no-properties beg end)
 917                                 (muse-markup-text 'footnote-end)))
 918                 (setq footnotemark (format footnotemark-cmd footnote
 919                                            footnotemark-end-cmd))
 920                 (unless muse-publish-footnotes
 921                   (set (make-local-variable 'muse-publish-footnotes)
 922                        (make-vector 256 nil)))
 923                 (unless (aref muse-publish-footnotes footnote)
 924                   (setq footnotemark
 925                         (concat
 926                          footnotemark
 927                          (concat (format (muse-markup-text 'footnotetext)
 928                                          footnote)
 929                                  (buffer-substring-no-properties beg end)
 930                                  (muse-markup-text 'footnotetext-end))))
 931                   (aset muse-publish-footnotes footnote footnotemark))))
 932             (goto-char end)
 933             (skip-chars-forward "\n")
 934             (delete-region start (point)))))
 935       (muse-insert-markup (or footnotemark footnote))))))
 936
 937 (defun muse-publish-markup-fn-sep ()
 938   (delete-region (match-beginning 0) (match-end 0))
 939   (muse-insert-markup (muse-markup-text 'fn-sep)))
 940
 941 (defun muse-insert-markup-end-list (&rest args)
 942   (let ((beg (point)))
 943     (apply 'insert args)
 944     (add-text-properties beg (point) '(end-list t))
 945     (muse-publish-mark-read-only beg (point))))
 946
 947 (defun muse-publish-surround-dl (indent post-indent)
 948   (let* ((beg-item (muse-markup-text 'begin-dl-item))
 949          (end-item (muse-markup-text 'end-dl-item))
 950          (beg-ddt (muse-markup-text 'begin-ddt)) ;; term
 951          (end-ddt (muse-markup-text 'end-ddt))
 952          (beg-dde (muse-markup-text 'begin-dde)) ;; definition
 953          (end-dde (muse-markup-text 'end-dde))
 954          (continue t)
 955          def-on-same-line beg)
 956     (while continue
 957       ;; envelope this as one term+definitions unit -- HTML does not
 958       ;; need this, but DocBook and Muse's custom XML format do
 959       (muse-insert-markup beg-item)
 960       (when (looking-at muse-dl-term-regexp)
 961         ;; find the term and wrap it with published markup
 962         (setq beg (point))
 963         (goto-char (match-end 1))
 964         (delete-region (point) (match-end 0))
 965         (muse-insert-markup-end-list end-ddt)
 966         ;; if definition is immediately after term, move to next line
 967         (unless (eq (char-after) ?\n)
 968           (insert ?\n))
 969         (save-excursion
 970           (goto-char beg)
 971           (delete-region (point) (match-beginning 1))
 972           (muse-insert-markup beg-ddt)))
 973       (setq beg (point)
 974             ;; move past current item
 975             continue (muse-forward-list-item 'dl-term indent))
 976       (save-restriction
 977         (narrow-to-region beg (point))
 978         (goto-char (point-min))
 979         ;; publish each definition that we find, defaulting to an
 980         ;; empty definition if none are found
 981         (muse-publish-surround-text beg-dde end-dde
 982          (lambda (indent)
 983            (muse-forward-list-item 'dl-entry indent))
 984          nil nil t)
 985         (goto-char (point-max))
 986         (skip-chars-backward (concat muse-regexp-blank "\n"))
 987         (muse-insert-markup-end-list end-item)
 988         (when continue
 989           (goto-char (point-max)))))))
 990
 991 (defun muse-publish-surround-text (beg-tag end-tag move-func &optional indent post-indent determine-indent)
 992   (let ((continue t)
 993         (list-item (format muse-list-item-regexp
 994                            (concat "[" muse-regexp-blank "]*")))
 995         init-indent beg)
 996     (unless indent
 997       (setq indent (concat "[" muse-regexp-blank "]+")))
 998     (if post-indent
 999         (setq post-indent (concat " \\{0," (number-to-string post-indent)
1000                                   "\\}"))
1001       (setq post-indent ""))
1002     (while continue
1003       (muse-insert-markup beg-tag)
1004       (setq beg (point)
1005             ;; move past current item; continue is non-nil if there
1006             ;; are more like items to be processed
1007             continue (funcall move-func indent))
1008       (save-restriction
1009         (when determine-indent
1010           ;; if the caller doesn't know how much indentation
1011           ;; to use, figure it out ourselves
1012           (if (not continue)
1013               (setq indent "")
1014             (save-match-data
1015               ;; snarf all leading whitespace
1016               (let ((this-indent (and (match-beginning 2)
1017                                       (buffer-substring (match-beginning 1)
1018                                                         (match-beginning 2)))))
1019                 (when (and this-indent
1020                            (not (string= this-indent "")))
1021                   (setq indent this-indent
1022                         determine-indent nil))))))
1023         (when continue
1024           ;; remove list markup if we encountered another item of the
1025           ;; same type
1026           (replace-match "" t t nil 1))
1027         (narrow-to-region beg (point))
1028         ;; narrow to current item
1029         (goto-char (point-min))
1030         (forward-line 1)
1031         (let ((list-nested nil)
1032               (indent-found nil)
1033               (post-indent post-indent))
1034           (while (< (point) (point-max))
1035             (when (looking-at list-item)
1036               ;; if we encounter a list item, allow no post-indent
1037               ;; space
1038               (setq list-nested t))
1039             (when (looking-at (concat indent "\\("
1040                                       (or (and list-nested "")
1041                                           post-indent)
1042                                       "\\)"))
1043               ;; if list is not nested, remove indentation
1044               (unless indent-found
1045                 (setq post-indent (match-string 1)
1046                       indent-found t))
1047               (replace-match ""))
1048             (forward-line 1)))
1049         (skip-chars-backward (concat muse-regexp-blank "\n"))
1050         (muse-insert-markup-end-list end-tag)
1051         (when continue
1052           (goto-char (point-max)))))))
1053
1054 (defun muse-publish-markup-list ()
1055   "Markup a list entry.
1056 The reason this function is so funky, is to prevent text properties
1057 like read-only from being inadvertently deleted."
1058   (let* ((str (match-string 1))
1059          (type (muse-list-item-type str))
1060          (indent (buffer-substring (muse-line-beginning-position)
1061                                    (match-beginning 1)))
1062          (post-indent (length str))
1063          (last (match-beginning 0)))
1064     (cond
1065      ((eq type 'ul)
1066       (unless (eq (char-after (match-end 1)) ?-)
1067         (delete-region (match-beginning 0) (match-end 0))
1068         (muse-insert-markup (muse-markup-text 'begin-uli))
1069         (save-excursion
1070           (muse-publish-surround-text
1071            (muse-markup-text 'begin-uli-item)
1072            (muse-markup-text 'end-uli-item)
1073            (lambda (indent)
1074              (muse-forward-list-item 'ul indent))
1075            indent post-indent)
1076           (muse-insert-markup-end-list (muse-markup-text 'end-uli)))
1077         (forward-line 1)))
1078      ((eq type 'ol)
1079       (delete-region (match-beginning 0) (match-end 0))
1080       (muse-insert-markup (muse-markup-text 'begin-oli))
1081       (save-excursion
1082         (muse-publish-surround-text
1083          (muse-markup-text 'begin-oli-item)
1084          (muse-markup-text 'end-oli-item)
1085          (lambda (indent)
1086            (muse-forward-list-item 'ol indent))
1087          indent post-indent)
1088         (muse-insert-markup-end-list (muse-markup-text 'end-oli)))
1089       (forward-line 1))
1090      ((not (string= (match-string 2) ""))
1091       ;; must have an initial term
1092       (goto-char (match-beginning 0))
1093       (muse-insert-markup (muse-markup-text 'begin-dl))
1094       (save-excursion
1095         (muse-publish-surround-dl indent post-indent)
1096         (muse-insert-markup-end-list (muse-markup-text 'end-dl)))
1097       (forward-line 1))))
1098   nil)
1099
1100 (defun muse-publish-markup-quote ()
1101   "Markup a quoted paragraph.
1102 The reason this function is so funky, is to prevent text properties
1103 like read-only from being inadvertently deleted."
1104   (let* ((ws (match-string 1))
1105          (centered (>= (string-width ws) 6))
1106          (begin-elem (if centered 'begin-center 'begin-quote-item))
1107          (end-elem (if centered 'end-center 'end-quote-item)))
1108     (replace-match "" t t nil 1)
1109     (unless centered
1110       (muse-insert-markup (muse-markup-text 'begin-quote)))
1111     (muse-publish-surround-text (muse-markup-text begin-elem)
1112                                 (muse-markup-text end-elem)
1113                                 (function (lambda (indent)
1114                                             (muse-forward-paragraph)
1115                                             nil)))
1116     (unless centered
1117       (muse-insert-markup (muse-markup-text 'end-quote)))))
1118
1119 (defun muse-publish-markup-leading-space (markup-space multiple)
1120   (let (count)
1121     (when (and markup-space
1122                (>= (setq count (skip-chars-forward " ")) 0))
1123       (delete-region (muse-line-beginning-position) (point))
1124       (while (> count 0)
1125         (muse-insert-markup markup-space)
1126         (setq count (- count multiple))))))
1127
1128 (defun muse-publish-markup-verse ()
1129   (let ((leader (match-string 0)))
1130     (goto-char (match-beginning 0))
1131     (muse-insert-markup (muse-markup-text 'begin-verse))
1132     (while (looking-at leader)
1133       (replace-match "")
1134       (muse-publish-markup-leading-space (muse-markup-text 'verse-space) 2)
1135       (let ((beg (point)))
1136         (end-of-line)
1137         (cond
1138          ((bolp)
1139           (let ((text (muse-markup-text 'empty-verse-line)))
1140             (when text (muse-insert-markup text))))
1141          ((save-excursion
1142             (save-match-data
1143               (forward-line 1)
1144               (or (looking-at (concat leader "["
1145                                       muse-regexp-blank
1146                                       "]*$"))
1147                   (not (looking-at leader)))))
1148           (let ((begin-text (muse-markup-text 'begin-last-stanza-line))
1149                 (end-text (muse-markup-text 'end-last-stanza-line)))
1150             (when end-text (muse-insert-markup end-text))
1151             (goto-char beg)
1152             (when begin-text (muse-insert-markup begin-text))
1153             (end-of-line)))
1154          (t
1155           (let ((begin-text (muse-markup-text 'begin-verse-line))
1156                 (end-text (muse-markup-text 'end-verse-line)))
1157             (when end-text (muse-insert-markup end-text))
1158             (goto-char beg)
1159             (when begin-text (muse-insert-markup begin-text))
1160             (end-of-line))))
1161         (forward-line 1))))
1162   (muse-insert-markup (muse-markup-text 'end-verse) ?\n))
1163
1164 (defun muse-publish-table-fields (beg end)
1165   "Parse given region as a table, returning a cons cell.
1166 The car is the length of the longest row.
1167
1168 The cdr is a list of the fields of the table, with the first
1169 element indicating the type of the row:
1170   1: body, 2: header, 3: footer.
1171
1172 The existing region will be removed, except for initial blank lines."
1173   (let ((longest 0)
1174         (left 0)
1175         fields field-list)
1176     (save-restriction
1177       (narrow-to-region beg end)
1178       (goto-char (point-min))
1179       (while (looking-at (concat "^[" muse-regexp-blank "]*$"))
1180         (forward-line 1))
1181       (setq beg (point))
1182       (while (= left 0)
1183         (when (looking-at muse-table-line-regexp)
1184           (setq fields (cons (length (match-string 1))
1185                              (split-string (match-string 0)
1186                                            muse-table-field-regexp))
1187                 field-list (cons fields field-list)
1188                 longest (max (length fields) longest)))
1189         (setq left (forward-line 1))))
1190     (delete-region beg end)
1191     (if (= longest 0)
1192         (cons 0 nil)
1193       (cons (1- longest) (nreverse field-list)))))
1194
1195 (defun muse-publish-markup-table ()
1196   "Style does not support tables.")
1197
1198 (defun muse-publish-escape-specials-in-string (string &optional context)
1199   "Escape specials in STRING using style-specific :specials.
1200 CONTEXT is used to figure out what kind of specials to escape.
1201
1202 See the documentation of the `muse-publish-escape-specials'
1203 function for the list of available contexts."
1204   (unless string
1205     (setq string ""))
1206   (let ((specials (muse-style-element :specials nil t)))
1207     (cond ((functionp specials)
1208            (setq specials (funcall specials context)))
1209           ((symbolp specials)
1210            (setq specials (symbol-value specials))))
1211     (if (functionp specials)
1212         (funcall specials string)
1213       (apply (function concat)
1214              (mapcar
1215               (lambda (ch)
1216                 (let (repl)
1217                   (setq repl (or (assoc ch specials)
1218                                  (assoc ch muse-publish-markup-specials)))
1219                   (if (null repl)
1220                       (char-to-string ch)
1221                     (cdr repl))))
1222               (append string nil))))))
1223
1224 (defun muse-publish-markup-email ()
1225   (let* ((beg (match-end 1))
1226          (addr (buffer-substring-no-properties beg (match-end 0))))
1227     (setq addr (muse-publish-escape-specials-in-string addr 'email))
1228     (goto-char beg)
1229     (delete-region beg (match-end 0))
1230     (if (or (eq (char-before (match-beginning 0)) ?\")
1231             (eq (char-after (match-end 0)) ?\"))
1232         (insert addr)
1233       (insert (format (muse-markup-text 'email-addr) addr addr)))
1234     (muse-publish-mark-read-only beg (point))))
1235
1236 (defun muse-publish-classify-url (target)
1237   "Transform anchors and get published name, if TARGET is a page.
1238 The return value is a cons cell.  The car is the type of link,
1239 the cadr is the page name, and the cddr is the anchor."
1240   (save-match-data
1241     (cond ((or (null target) (string= target ""))
1242            nil)
1243           ((string-match muse-url-regexp target)
1244            (cons 'url (cons target nil)))
1245           ((string-match muse-image-regexp target)
1246            (cons 'image (cons target nil)))
1247           ((string-match muse-file-regexp target)
1248            (cons 'file (cons target nil)))
1249           ((string-match "#" target)
1250            (if (eq (aref target 0) ?\#)
1251               (cons 'anchor-ref (cons nil (substring target 1)))
1252              (cons 'link-and-anchor
1253                    (cons (muse-publish-link-name
1254                           (substring target 0 (match-beginning 0)))
1255                          (substring target (match-end 0))))))
1256           (t
1257            (cons 'link (cons (muse-publish-link-name target) nil))))))
1258
1259 (defun muse-publish-url (url &optional desc explicit)
1260   "Resolve a URL into its final <a href> form."
1261   (let ((orig-url url)
1262         type anchor)
1263     (dolist (transform muse-publish-url-transforms)
1264       (setq url (save-match-data (when url (funcall transform url explicit)))))
1265     (dolist (transform muse-publish-desc-transforms)
1266       (setq desc (save-match-data
1267                    (when desc (funcall transform desc explicit)))))
1268     (when desc
1269       (setq desc (muse-publish-escape-specials-in-string desc 'url-desc)))
1270     (setq orig-url
1271           (muse-publish-escape-specials-in-string orig-url 'url-desc))
1272     (let ((target (muse-publish-classify-url url)))
1273       (setq type (car target)
1274             url (muse-publish-escape-specials-in-string (cadr target) 'url)
1275             anchor (muse-publish-escape-specials-in-string
1276                     (cddr target) 'url)))
1277     (cond ((eq type 'anchor-ref)
1278            (muse-markup-text 'anchor-ref anchor (or desc orig-url)))
1279           ((string= url "")
1280            desc)
1281           ((eq type 'image)
1282            (if desc
1283                (muse-markup-text 'image-with-desc url desc)
1284              (muse-markup-text 'image-link url)))
1285           ((eq type 'link-and-anchor)
1286            (muse-markup-text 'link-and-anchor url anchor
1287                              (or desc orig-url)))
1288           ((and desc (string-match muse-image-regexp desc))
1289            (muse-markup-text 'url-with-image url desc))
1290           ((eq type 'link)
1291            (muse-markup-text 'link url (or desc orig-url)))
1292           (t
1293            (or (and desc
1294                     (let ((text (muse-markup-text 'url-and-desc url desc)))
1295                       (and (not (string= text ""))
1296                            text)))
1297                (muse-markup-text 'url url (or desc orig-url)))))))
1298
1299 (defun muse-publish-insert-url (url &optional desc explicit)
1300   "Resolve a URL into its final <a href> form."
1301   (delete-region (match-beginning 0) (match-end 0))
1302   (let ((text (muse-publish-url url desc explicit)))
1303     (when text
1304       (muse-insert-markup text))))
1305
1306 (defun muse-publish-markup-link ()
1307   (let (desc explicit link)
1308     (setq explicit (save-match-data
1309                      (if (string-match muse-explicit-link-regexp
1310                                        (match-string 0))
1311                          t nil)))
1312     (setq desc (if explicit (match-string 2) (match-string 0)))
1313     (setq link (if explicit
1314                    (muse-handle-explicit-link (match-string 1))
1315                  (muse-handle-implicit-link (match-string 0))))
1316     (when (and link
1317                (or explicit
1318                    (not (or (eq (char-before (match-beginning 0)) ?\")
1319                             (eq (char-after (match-end 0)) ?\")))))
1320       (muse-publish-insert-url link desc explicit))))
1321
1322 (defun muse-publish-markup-url ()
1323   (unless (or (eq (char-before (match-beginning 0)) ?\")
1324               (eq (char-after (match-end 0)) ?\"))
1325     (muse-publish-insert-url (match-string 0))))
1326
1327 ;; Default publishing tags
1328
1329 (defun muse-publish-contents-tag (beg end attrs)
1330   (set (make-local-variable 'muse-publish-generate-contents)
1331        (cons (copy-marker (point) t)
1332              (let ((depth (cdr (assoc "depth" attrs))))
1333                (or (and depth (string-to-number depth)) 2)))))
1334
1335 (defun muse-publish-verse-tag (beg end)
1336   (save-excursion
1337     (save-restriction
1338       (narrow-to-region beg end)
1339       (goto-char (point-min))
1340       (while (eq ?\  (char-syntax (char-after)))
1341         (delete-char 1))
1342       (while (< (point) (point-max))
1343         (insert "> ")
1344         (forward-line))
1345       (if (eq ?\  (char-syntax (char-before)))
1346           (delete-char -1)))))
1347
1348 (defun muse-publish-mark-read-only (beg end)
1349   "Add read-only properties to the given region."
1350   (add-text-properties beg end '(rear-nonsticky (read-only) read-only t))
1351   nil)
1352
1353 (defun muse-publish-mark-noemphasis (&optional beg end)
1354   "Make sure that no emphasis characters are interpreted within
1355 the given region.  If a region is not specified, use the 0th
1356 match data to determine it.
1357
1358 This is usually applied to extended links."
1359   (unless beg (setq beg (match-beginning 0)))
1360   (unless end (setq end (match-end 0)))
1361   (add-text-properties beg end '(noemphasis t))
1362   nil)
1363
1364 (defun muse-publish-quote-tag (beg end)
1365   (save-excursion
1366     (save-restriction
1367       (narrow-to-region beg end)
1368       (muse-insert-markup (muse-markup-text 'begin-quote))
1369       (muse-publish-surround-text (muse-markup-text 'begin-quote-item)
1370                                   (muse-markup-text 'end-quote-item)
1371                                   (function (lambda (indent)
1372                                               (muse-forward-paragraph)
1373                                               (goto-char (match-end 0))
1374                                               (< (point) (point-max)))))
1375       (muse-insert-markup (muse-markup-text 'end-quote)))))
1376
1377 (defun muse-publish-code-tag (beg end)
1378   (muse-publish-escape-specials beg end nil 'literal)
1379   (goto-char beg)
1380   (insert (muse-markup-text 'begin-literal))
1381   (goto-char end)
1382   (insert (muse-markup-text 'end-literal))
1383   (muse-publish-mark-read-only beg (point)))
1384
1385 (defun muse-publish-example-tag (beg end)
1386   (muse-publish-escape-specials beg end nil 'example)
1387   (goto-char beg)
1388   (insert (muse-markup-text 'begin-example))
1389   (goto-char end)
1390   (insert (muse-markup-text 'end-example))
1391   (muse-publish-mark-read-only beg (point)))
1392
1393 (defun muse-publish-verbatim-tag (beg end)
1394   (muse-publish-escape-specials beg end nil 'verbatim)
1395   (muse-publish-mark-read-only beg end))
1396
1397 (defalias 'muse-publish-class-tag 'ignore)
1398
1399 (defun muse-publish-lisp-tag (beg end)
1400   (save-excursion
1401     (let ((str (muse-eval-lisp
1402                 (prog1
1403                     (concat "(progn "
1404                             (buffer-substring-no-properties beg end)
1405                             ")")
1406                   (delete-region beg end)))))
1407       (set-text-properties 0 (length str) nil str)
1408       (insert str))))
1409
1410 (defun muse-publish-command-tag (beg end attrs)
1411   (while (looking-at "\\s-*$")
1412     (forward-line))
1413   (let ((interp (cdr (assoc "interp" attrs))))
1414     (if (null interp)
1415         (shell-command
1416          (prog1
1417              (buffer-substring-no-properties (point) end)
1418            (delete-region beg end)) t)
1419       (shell-command-on-region beg end interp t t))
1420     (muse-publish-mark-read-only beg (point))))
1421
1422 (defun muse-publish-comment-tag (beg end)
1423   (if (null muse-publish-comments-p)
1424       (delete-region beg end)
1425     (goto-char end)
1426     (muse-insert-markup (muse-markup-text 'comment-end))
1427     (muse-publish-mark-read-only beg end)
1428     (goto-char beg)
1429     (muse-insert-markup (muse-markup-text 'comment-begin))))
1430
1431 ;; Miscellaneous helper functions
1432
1433 (defsubst muse-publishing-directive (name)
1434   (cdr (assoc name muse-publishing-directives)))
1435
1436 (defun muse-publish-strip-tags (string)
1437   "Remove all tags from the string."
1438   (while (string-match "<.*?>" string)
1439     (setq string (replace-match "" nil t string)))
1440   string)
1441
1442 (defun muse-publish-markup-type (category default-func)
1443   (let ((rule (muse-find-markup-element :overrides category (muse-style))))
1444     (funcall (or rule default-func))))
1445
1446 (defun muse-published-buffer-contents (buffer)
1447   (with-current-buffer buffer
1448     (goto-char (point-min))
1449     (let ((beg (and (search-forward "Emacs Muse begins here")
1450                     (muse-line-end-position)))
1451           (end (and (search-forward "Emacs Muse ends here")
1452                     (muse-line-beginning-position))))
1453       (buffer-substring-no-properties beg end))))
1454
1455 (defun muse-published-contents (file)
1456   (when (file-readable-p file)
1457     (muse-with-temp-buffer
1458       (insert-file-contents file)
1459       (muse-published-buffer-contents (current-buffer)))))
1460
1461 (defun muse-publish-transform-output
1462   (file temp-file output-path name gen-func &rest cleanup-exts)
1463   "Transform the given TEMP-FILE into the OUTPUT-PATH, using GEN-FUNC."
1464   (setq file (muse-page-name file))
1465   (message "Generating %s output for %s..." name file)
1466   (if (not (funcall gen-func temp-file output-path))
1467       (message "Generating %s from %s...failed" name file)
1468     (message "Generating %s output for %s...done" name file)
1469     (muse-delete-file-if-exists temp-file)
1470     (dolist (ext cleanup-exts)
1471       (muse-delete-file-if-exists
1472        (expand-file-name (concat file ext)
1473                          (file-name-directory output-path))))
1474     (message "Wrote %s" output-path)))
1475
1476 (defun muse-publish-read-only (string)
1477   (let ((end (1- (length string))))
1478     (add-text-properties 0 end
1479                          '(rear-nonsticky (read-only) read-only t)
1480                          string)
1481     string))
1482
1483 (provide 'muse-publish)
1484
1485 ;;; muse-publish.el ends here