lisp/muse-latex.el

   1 ;;; muse-latex.el --- publish entries in LaTex or PDF format
   2
   3 ;; Copyright (C) 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5 ;; This file is part of Emacs Muse.  It is not part of GNU Emacs.
   6
   7 ;; Emacs Muse is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published
   9 ;; by the Free Software Foundation; either version 2, or (at your
  10 ;; option) any later version.
  11
  12 ;; Emacs Muse is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Emacs Muse; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  20 ;; Boston, MA 02110-1301, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Contributors:
  25
  26 ;; Li Daobing (lidaobing AT gmail DOT com) provided CJK support.
  27
  28 ;; Trent Buck (trentbuck AT gmail DOT com) gave valuable advice for
  29 ;; how to treat LaTeX specials and the like.
  30
  31 ;;; Code:
  32
  33 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  34 ;;
  35 ;; Muse LaTeX Publishing
  36 ;;
  37 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  38
  39 (require 'muse-publish)
  40
  41 (defgroup muse-latex nil
  42   "Rules for marking up a Muse file as a LaTeX article."
  43   :group 'muse-publish)
  44
  45 (defcustom muse-latex-extension ".tex"
  46   "Default file extension for publishing LaTeX files."
  47   :type 'string
  48   :group 'muse-latex)
  49
  50 (defcustom muse-latex-pdf-extension ".pdf"
  51   "Default file extension for publishing LaTeX files to PDF."
  52   :type 'string
  53   :group 'muse-latex)
  54
  55 (defcustom muse-latex-header
  56   "\\documentclass{article}
  57
  58 \\usepackage[english]{babel}
  59 \\usepackage[latin1]{inputenc}
  60 \\usepackage[T1]{fontenc}
  61 \\usepackage{hyperref}
  62 \\usepackage[pdftex]{graphicx}
  63
  64 \\newcommand{\\comment}[1]{}
  65
  66 \\begin{document}
  67
  68 \\title{<lisp>(muse-publishing-directive \"title\")</lisp>}
  69 \\author{<lisp>(muse-publishing-directive \"author\")</lisp>}
  70 \\date{<lisp>(muse-publishing-directive \"date\")</lisp>}
  71
  72 \\maketitle
  73
  74 <lisp>(and muse-publish-generate-contents
  75            \"\\\\tableofcontents\n\\\\newpage\")</lisp>\n\n"
  76   "Header used for publishing LaTeX files.  This may be text or a filename."
  77   :type 'string
  78   :group 'muse-latex)
  79
  80 (defcustom muse-latex-footer "\n\\end{document}\n"
  81   "Footer used for publishing LaTeX files.  This may be text or a filename."
  82   :type 'string
  83   :group 'muse-latex)
  84
  85 (defcustom muse-latexcjk-header
  86   "\\documentclass{article}
  87
  88 \\usepackage{CJK}
  89 \\usepackage{indentfirst}
  90 \\usepackage[CJKbookmarks=true]{hyperref}
  91 \\usepackage[pdftex]{graphicx}
  92
  93 \\begin{document}
  94 \\begin{CJK*}<lisp>(muse-latexcjk-encoding)</lisp>
  95
  96 \\title{<lisp>(muse-publishing-directive \"title\")</lisp>}
  97 \\author{<lisp>(muse-publishing-directive \"author\")</lisp>}
  98 \\date{<lisp>(muse-publishing-directive \"date\")</lisp>}
  99
 100 \\maketitle
 101
 102 <lisp>(and muse-publish-generate-contents
 103            \"\\\\tableofcontents\n\\\\newpage\")</lisp>\n\n"
 104   "Header used for publishing LaTeX files (CJK).  This may be text or a
 105 filename."
 106   :type 'string
 107   :group 'muse-latex)
 108
 109 (defcustom muse-latexcjk-footer
 110   "\n\\end{CJK*}
 111 \\end{document}\n"
 112   "Footer used for publishing LaTeX files (CJK).  This may be text or a
 113 filename."
 114   :type 'string
 115   :group 'muse-latex)
 116
 117 (defcustom muse-latex-markup-regexps
 118   `(;; numeric ranges
 119     (10000 "\\([0-9]+\\)-\\([0-9]+\\)" 0 "\\1--\\2")
 120
 121     ;; be careful of closing quote pairs
 122     (10100 "\"'" 0 "\"\\\\-'"))
 123   "List of markup regexps for identifying regions in a Muse page.
 124 For more on the structure of this list, see `muse-publish-markup-regexps'."
 125   :type '(repeat (choice
 126                   (list :tag "Markup rule"
 127                         integer
 128                         (choice regexp symbol)
 129                         integer
 130                         (choice string function symbol))
 131                   function))
 132   :group 'muse-latex)
 133
 134 (defcustom muse-latex-markup-functions
 135   '((table . muse-latex-markup-table))
 136   "An alist of style types to custom functions for that kind of text.
 137 For more on the structure of this list, see
 138 `muse-publish-markup-functions'."
 139   :type '(alist :key-type symbol :value-type function)
 140   :group 'muse-latex)
 141
 142 (defcustom muse-latex-markup-strings
 143   '((image-with-desc . "\\includegraphics[width=\\textwidth]{%s}")
 144     (image-link      . "\\includegraphics[width=\\textwidth]{%s}")
 145     (url-with-image  . "%% %s\n\\includegraphics[width=\\textwidth]{%s}")
 146     (anchor-ref      . "\\ref{%s}")
 147     (url             . "\\url{%s}")
 148     (url-and-desc    . "\\href{%s}{%s}\\footnote{%1%}")
 149     (link            . "\\href{%s}{%s}\\footnote{%1%}")
 150     (link-and-anchor . "\\href{%1%}{%3%}\\footnote{%1%}")
 151     (email-addr      . "\\verb|%s|")
 152     (anchor          . "\\label{%s}")
 153     (emdash          . "---")
 154     (comment-begin   . "\\comment{")
 155     (comment-end     . "}")
 156     (rule            . "\\bigskip")
 157     (no-break-space  . "~")
 158     (enddots         . "\\ldots{}")
 159     (dots            . "\\dots{}")
 160     (part            . "\\part{")
 161     (part-end        . "}")
 162     (chapter         . "\\chapter{")
 163     (chapter-end     . "}")
 164     (section         . "\\section{")
 165     (section-end     . "}")
 166     (subsection      . "\\subsection{")
 167     (subsection-end  . "}")
 168     (subsubsection   . "\\subsubsection{")
 169     (subsubsection-end . "}")
 170     (section-other   . "\\paragraph{")
 171     (section-other-end . "}")
 172     (footnote        . "\\footnote{")
 173     (footnote-end    . "}")
 174     (footnotetext    . "\\footnotetext[%d]{")
 175     (begin-underline . "\\underline{")
 176     (end-underline   . "}")
 177     (begin-literal   . "\\texttt{")
 178     (end-literal     . "}")
 179     (begin-emph      . "\\emph{")
 180     (end-emph        . "}")
 181     (begin-more-emph . "\\textbf{")
 182     (end-more-emph   . "}")
 183     (begin-most-emph . "\\textbf{\\emph{")
 184     (end-most-emph   . "}}")
 185     (begin-verse     . "\\begin{verse}\n")
 186     (end-verse-line  . " \\\\")
 187     (verse-space     . "~~~~")
 188     (end-verse       . "\n\\end{verse}")
 189     (begin-example   . "\\begin{quote}\n\\begin{verbatim}")
 190     (end-example     . "\\end{verbatim}\n\\end{quote}")
 191     (begin-center    . "\\begin{center}\n")
 192     (end-center      . "\n\\end{center}")
 193     (begin-quote     . "\\begin{quote}\n")
 194     (end-quote       . "\n\\end{quote}")
 195     (begin-uli       . "\\begin{itemize}\n")
 196     (end-uli         . "\n\\end{itemize}")
 197     (begin-uli-item  . "\\item ")
 198     (begin-oli       . "\\begin{enumerate}\n")
 199     (end-oli         . "\n\\end{enumerate}")
 200     (begin-oli-item  . "\\item ")
 201     (begin-dl        . "\\begin{description}\n")
 202     (end-dl          . "\n\\end{description}")
 203     (begin-ddt       . "\\item[")
 204     (end-ddt         . "] "))
 205   "Strings used for marking up text.
 206 These cover the most basic kinds of markup, the handling of which
 207 differs little between the various styles."
 208   :type '(alist :key-type symbol :value-type string)
 209   :group 'muse-latex)
 210
 211 (defcustom muse-latexcjk-encoding-map
 212   '((utf-8              . "{UTF8}{song}")
 213     (japanese-iso-8bit  . "[dnp]{JIS}{min}")
 214     (chinese-big5       . "{Bg5}{bsmi}")
 215     (mule-utf-8         . "{UTF8}{song}")
 216     (chinese-iso-8bit   . "{GB}{song}")
 217     (chinese-gbk        . "{GBK}{song}"))
 218   "An alist mapping emacs coding systems to appropriate CJK codings.
 219 Use the base name of the coding system (ie, without the -unix)."
 220   :type '(alist :key-type coding-system :value-type string)
 221   :group 'muse-latex)
 222
 223 (defcustom muse-latexcjk-encoding-default "{GB}{song}"
 224   "The default Emacs buffer encoding to use in published files.
 225 This will be used if no special characters are found."
 226   :type 'string
 227   :group 'muse-latex)
 228
 229 (defun muse-latexcjk-encoding ()
 230   (when (boundp 'buffer-file-coding-system)
 231     (muse-latexcjk-transform-content-type buffer-file-coding-system)))
 232
 233 (defun muse-latexcjk-transform-content-type (content-type)
 234   "Using `muse-cjklatex-encoding-map', try and resolve an emacs coding
 235 system to an associated CJK coding system."
 236   (let ((match (and (fboundp 'coding-system-base)
 237                     (assoc (coding-system-base content-type)
 238                            muse-latexcjk-encoding-map))))
 239     (if match
 240         (cdr match)
 241       muse-latexcjk-encoding-default)))
 242
 243 (defcustom muse-latex-markup-specials-document
 244   '((?\\ . "\\textbackslash{}")
 245     (?\_ . "\\textunderscore{}")
 246     (?\< . "\\textless{}")
 247     (?\> . "\\textgreater{}")
 248     (?^  . "\\^{}")
 249     (?\~ . "\\~{}")
 250     (?\@ . "\\@")
 251     (?\$ . "\\$")
 252     (?\% . "\\%")
 253     (?\{ . "\\{")
 254     (?\} . "\\}")
 255     (?\& . "\\&")
 256     (?\# . "\\#"))
 257   "A table of characters which must be represented specially.
 258 These are applied to the entire document, sans already-escaped
 259 regions."
 260   :type '(alist :key-type character :value-type string)
 261   :group 'muse-latex)
 262
 263 (defcustom muse-latex-markup-specials-example
 264   '((?\\ . "\\\\"))
 265   "A table of characters which must be represented specially.
 266 These are applied to <example>regions</example>."
 267   :type '(alist :key-type character :value-type string)
 268   :group 'muse-latex)
 269
 270 (defcustom muse-latex-markup-specials-literal
 271   '((?\n . "\\\n")
 272     (?_  . "\\textunderscore{}")
 273     (?\< . "\\textless{}")
 274     (?\> . "\\textgreater{}")
 275     (?^  . "\\^{}")
 276     (?\~ . "\\~{}")
 277     (?\$ . "\\$")
 278     (?\% . "\\%")
 279     (?\{ . "\\{")
 280     (?\} . "\\}")
 281     (?\& . "\\&")
 282     (?\# . "\\#"))
 283   "A table of characters which must be represented specially.
 284 This applies to =monospaced text= and <code>regions</code>."
 285   :type '(alist :key-type character :value-type string)
 286   :group 'muse-latex)
 287
 288 (defcustom muse-latex-markup-specials-url
 289   '((?\\ . "\\\\")
 290     (?\_ . "\\_")
 291     (?\< . "\\<")
 292     (?\> . "\\>")
 293     (?\$ . "\\$")
 294     (?\% . "\\%")
 295     (?\{ . "\\{")
 296     (?\} . "\\}")
 297     (?\& . "\\&")
 298     (?\# . "\\#"))
 299   "A table of characters which must be represented specially.
 300 These are applied to URLs."
 301   :type '(alist :key-type character :value-type string)
 302   :group 'muse-latex)
 303
 304 (defun muse-latex-decide-specials (context)
 305   "Determine the specials to escape, depending on CONTEXT."
 306   (cond ((memq context '(underline emphasis document url-desc verbatim))
 307          muse-latex-markup-specials-document)
 308         ((memq context '(email url))
 309          muse-latex-markup-specials-url)
 310         ((eq context 'literal)
 311          muse-latex-markup-specials-literal)
 312         ((eq context 'example)
 313          muse-latex-markup-specials-example)
 314         (t (error "Invalid context '%s' in muse-latex" context))))
 315
 316 (defun muse-latex-markup-table ()
 317   (let* ((table-info (muse-publish-table-fields (match-beginning 0)
 318                                                 (match-end 0)))
 319          (row-len (car table-info))
 320          (field-list (cdr table-info)))
 321     (muse-insert-markup "\\begin{tabular}{" (make-string row-len ?l) "}\n")
 322     (dolist (fields field-list)
 323       (let ((type (car fields)))
 324         (setq fields (cdr fields))
 325         (when (= type 3)
 326           (muse-insert-markup "\\hline\n"))
 327         (insert (car fields))
 328         (setq fields (cdr fields))
 329         (dolist (field fields)
 330           (muse-insert-markup " & ")
 331           (insert field))
 332         (muse-insert-markup " \\\\\n")
 333         (when (= type 2)
 334           (muse-insert-markup "\\hline\n"))))
 335     (muse-insert-markup "\\end{tabular}")))
 336
 337 (defun muse-latex-fixup-dquotes ()
 338   "Fixup double quotes."
 339   (let ((open t))
 340     (while (search-forward "\"" nil t)
 341       (unless (get-text-property (match-beginning 0) 'read-only)
 342         (when (or (bobp)
 343                   (eq (char-before) ?\n))
 344           (setq open t))
 345         (if open
 346             (progn
 347               (replace-match "``")
 348               (setq open nil))
 349           (replace-match "''")
 350           (setq open t))))))
 351
 352 (defun muse-latex-finalize-buffer ()
 353   (goto-char (point-min))
 354   (muse-latex-fixup-dquotes))
 355
 356 (defun muse-latex-pdf-browse-file (file)
 357   (shell-command (concat "open " file)))
 358
 359 (defun muse-latex-pdf-generate (file output-path final-target)
 360   (muse-publish-transform-output
 361    file output-path final-target "PDF"
 362    (function
 363     (lambda (file output-path)
 364       (let ((command (format "cd \"%s\"; pdflatex \"%s\""
 365                              (file-name-directory output-path) file))
 366             (times 0)
 367             result)
 368         ;; XEmacs can sometimes return a non-number result.  We'll err
 369         ;; on the side of caution by continuing to attempt to generate
 370         ;; the PDF if this happens and treat the final result as
 371         ;; successful.
 372         (while (and (< times 2)
 373                     (or (not (numberp result))
 374                         (not (eq result 0))
 375                         ;; table of contents takes 2 passes
 376                         (file-readable-p
 377                          (muse-replace-regexp-in-string
 378                           "\\.tex\\'" ".toc" file t t))))
 379           (setq result (shell-command command)
 380                 times (1+ times)))
 381         (if (or (not (numberp result))
 382                 (eq result 0))
 383             t
 384           nil))))
 385    ".aux" ".toc" ".out" ".log"))
 386
 387 (unless (assoc "latex" muse-publishing-styles)
 388   (muse-define-style "latex"
 389                      :suffix    'muse-latex-extension
 390                      :regexps   'muse-latex-markup-regexps
 391                      :functions 'muse-latex-markup-functions
 392                      :strings   'muse-latex-markup-strings
 393                      :specials  'muse-latex-decide-specials
 394                      :after     'muse-latex-finalize-buffer
 395                      :header    'muse-latex-header
 396                      :footer    'muse-latex-footer
 397                      :browser   'find-file)
 398
 399   (muse-derive-style "pdf" "latex"
 400                      :final   'muse-latex-pdf-generate
 401                      :browser 'muse-latex-pdf-browse-file
 402                      :link-suffix 'muse-latex-pdf-extension
 403                      :osuffix 'muse-latex-pdf-extension)
 404
 405   (muse-derive-style "latexcjk" "latex"
 406                      :header    'muse-latexcjk-header
 407                      :footer    'muse-latexcjk-footer)
 408
 409   (muse-derive-style "pdfcjk" "latexcjk"
 410                      :final   'muse-latex-pdf-generate
 411                      :browser 'muse-latex-pdf-browse-file
 412                      :link-suffix 'muse-latex-pdf-extension
 413                      :osuffix 'muse-latex-pdf-extension))
 414
 415 (provide 'muse-latex)
 416
 417 ;;; muse-latex.el ends here