lisp/muse-wiki.el

   1 ;;; muse-wiki.el --- wiki features for Muse
   2
   3 ;; Copyright (C) 2005, 2006 Free Software Foundation, Inc.
   4
   5 ;; Author: Yann Hodique <Yann.Hodique@lifl.fr>
   6 ;; Keywords:
   7
   8 ;; This file is part of Emacs Muse.  It is not part of GNU Emacs.
   9
  10 ;; Emacs Muse is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published
  12 ;; by the Free Software Foundation; either version 2, or (at your
  13 ;; option) any later version.
  14
  15 ;; Emacs Muse is distributed in the hope that it will be useful, but
  16 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 ;; General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with Emacs Muse; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Contributors:
  28
  29 ;; Per B. Sederberg (per AT med DOT upenn DOT edu) made it so that all
  30 ;; files in a Muse project can become implicit links.
  31
  32 ;;; Code:
  33
  34 (require 'muse-regexps)
  35 (require 'muse-mode)
  36
  37 (eval-when-compile
  38   (require 'muse-colors))
  39
  40 (defgroup muse-wiki nil
  41   "Options controlling the behavior of Emacs Muse Wiki features."
  42   :group 'muse-mode)
  43
  44 (defcustom muse-wiki-use-wikiword t
  45   "Whether to use color and publish bare WikiNames."
  46   :type 'boolean
  47   :group 'muse-wiki)
  48
  49 (defcustom muse-wiki-allow-nonexistent-wikiword nil
  50   "Whether to color bare WikiNames that don't have an existing file."
  51   :type 'boolean
  52   :group 'muse-wiki)
  53
  54 (defcustom muse-wiki-match-all-project-files nil
  55   "If non-nil, Muse will color and publish implicit links to any
  56 file in your project, regardless of whether its name is a WikiWord."
  57   :type 'boolean
  58   :group 'muse-wiki)
  59
  60 (defcustom muse-wiki-ignore-implicit-links-to-current-page nil
  61   "If non-nil, Muse will not recognize implicit links to the current
  62 page, both when formatting and publishing."
  63   :type 'boolean
  64   :group 'muse-wiki)
  65
  66 (defvar muse-wiki-project-file-regexp nil
  67   "Regexp used to match the files in the current project.
  68
  69 This is set by `muse-wiki-update-project-file-regexp' automatically
  70 when `muse-wiki-martch-all-project-files' is non-nil.")
  71 (make-variable-buffer-local 'muse-wiki-project-file-regexp)
  72
  73 (defun muse-wiki-update-project-file-regexp ()
  74   "Update a local copy of `muse-wiki-project-file-regexp' to include
  75 all the files in the project."
  76   ;; see if the user wants to match project files
  77   (when muse-wiki-match-all-project-files
  78     (let ((files (mapcar #'car (muse-project-file-alist (muse-project)))))
  79       (setq muse-wiki-project-file-regexp
  80             (when files
  81               (concat "\\("
  82                       ;; include all files from the project
  83                       (regexp-opt files 'words)
  84                       "\\)"))))
  85     ;; update coloring setup
  86     (when (featurep 'muse-colors)
  87       (muse-configure-highlighting
  88        'muse-colors-markup muse-colors-markup))))
  89
  90 (add-hook 'muse-update-values-hook
  91           'muse-wiki-update-project-file-regexp)
  92 (add-hook 'muse-project-file-alist-hook
  93           'muse-wiki-update-project-file-regexp)
  94
  95 (defcustom muse-wiki-wikiword-regexp
  96   (concat "\\<\\(\\(?:[" muse-regexp-upper
  97           "]+[" muse-regexp-lower "]+\\)\\(?:["
  98           muse-regexp-upper "]+[" muse-regexp-lower "]+\\)+\\)")
  99   "Regexp used to match WikiWords."
 100   :set (function
 101         (lambda (sym value)
 102           (set sym value)
 103           (when (featurep 'muse-colors)
 104             (muse-configure-highlighting
 105              'muse-colors-markup muse-colors-markup))))
 106   :type 'regexp
 107   :group 'muse-wiki)
 108
 109 (defcustom muse-wiki-ignore-bare-project-names nil
 110   "Determine whether project names without a page specifer are links.
 111
 112 If non-nil, project names without a page specifier will not be
 113 considered links.
 114
 115 When nil, project names without a specifier are highlighted and
 116 they link to the default page of the project that they name."
 117   :type 'boolean
 118   :group 'muse-wiki)
 119
 120 (defvar muse-wiki-interwiki-regexp ""
 121   "Regexp that matches all interwiki links.
 122
 123 This is automatically generated by setting `muse-wiki-interwiki-alist'.
 124 It can also be set by calling `muse-wiki-update-interwiki-regexp'.")
 125
 126 (defcustom muse-wiki-interwiki-delimiter "#\\|::"
 127   "Delimiter regexp used for InterWiki links.
 128
 129 If you use groups, use only shy groups."
 130   :type 'regexp
 131   :group 'muse-wiki)
 132
 133 (defcustom muse-wiki-interwiki-replacement ": "
 134   "Regexp used for replacing `muse-wiki-interwiki-delimiter' in
 135 InterWiki link descriptions.
 136
 137 If you want this replacement to happen, you must add
 138 `muse-wiki-publish-pretty-interwiki' to
 139 `muse-publish-desc-transforms'."
 140   :type 'regexp
 141   :group 'muse-wiki)
 142
 143 (eval-when-compile
 144   (defvar muse-wiki-interwiki-alist))
 145
 146 (defun muse-wiki-project-files-with-spaces (&optional project)
 147   "Return a list of files in PROJECT that have spaces."
 148   (setq project (muse-project project))
 149   (let ((flist nil))
 150     (save-match-data
 151       (mapcar (function (lambda (file)
 152                           (when (string-match " " (car file))
 153                             (setq flist (cons (car file) flist)))))
 154               (muse-project-file-alist project)))
 155     flist))
 156
 157 (defun muse-wiki-update-interwiki-regexp ()
 158   "Update the value of `muse-wiki-interwiki-regexp' based on
 159 `muse-wiki-interwiki-alist' and `muse-project-alist'."
 160   (when muse-project-alist
 161     (setq muse-wiki-interwiki-regexp
 162           (concat "\\<\\(" (regexp-opt (mapcar #'car muse-project-alist))
 163                   (when muse-wiki-interwiki-alist
 164                     (let ((interwiki-rules (mapcar #'car
 165                                                    muse-wiki-interwiki-alist)))
 166                       (when interwiki-rules
 167                         (concat "\\|" (regexp-opt interwiki-rules)))))
 168                   "\\)\\(?:\\(?:" muse-wiki-interwiki-delimiter
 169                   "\\)\\("
 170                   (when muse-wiki-match-all-project-files
 171                   ;; append the files from the project
 172                     (let ((files nil))
 173                       (dolist (proj muse-project-alist)
 174                         (setq files
 175                               (nconc (muse-wiki-project-files-with-spaces
 176                                       (car proj))
 177                                      files)))
 178                       (when files
 179                         (concat (regexp-opt files) "\\|"))))
 180                   "\\sw+\\)\\)?\\>"))
 181     (when (featurep 'muse-colors)
 182       (muse-configure-highlighting 'muse-colors-markup muse-colors-markup))))
 183
 184 (defcustom muse-wiki-interwiki-alist
 185   '(("EmacsWiki" . "http://www.emacswiki.org/cgi-bin/wiki/"))
 186   "A table of WikiNames that refer to external entities.
 187
 188 The format of this table is an alist, or series of cons cells.
 189 Each cons cell must be of the form:
 190
 191   (WIKINAME . STRING-OR-FUNCTION)
 192
 193 The second part of the cons cell may either be a STRING, which in most
 194 cases should be a URL, or a FUNCTION.  If a function, it will be
 195 called with one argument: the tag applied to the Interwiki name, or
 196 nil if no tag was used.  If the cdr was a STRING and a tag is used,
 197 the tag is simply appended.
 198
 199 Here are some examples:
 200
 201   (\"JohnWiki\" . \"http://alice.dynodns.net/wiki?\")
 202
 203 Referring to [[JohnWiki::EmacsModules]] then really means:
 204
 205   http://alice.dynodns.net/wiki?EmacsModules
 206
 207 If a function is used for the replacement text, you can get creative
 208 depending on what the tag is.  Tags may contain any alphabetic
 209 character, any number, % or _.  If you need other special characters,
 210 use % to specify the hex code, as in %2E.  All browsers should support
 211 this."
 212   :type '(repeat (cons (string :tag "WikiName")
 213                        (choice (string :tag "URL") function)))
 214   :set (function
 215         (lambda (sym value)
 216           (set sym value)
 217           (muse-wiki-update-interwiki-regexp)))
 218   :group 'muse-wiki)
 219
 220 (add-hook 'muse-update-values-hook
 221           'muse-wiki-update-interwiki-regexp)
 222
 223 (defun muse-wiki-resolve-project-page (&optional project page)
 224   "Return the published path from the current page to PAGE of PROJECT.
 225
 226 If PAGE is not specified, use the value of :default in PROJECT.
 227
 228 If PROJECT is not specified, default to first project of
 229 `muse-projects-alist'.
 230
 231 Note that PAGE can have several output directories.  If this is
 232 the case, we will use the first one that matches our current
 233 style and has the same link suffix, ignoring the others.  If no
 234 style has the same link suffix as the current publishing style,
 235 use the first style we find."
 236   (setq project (or (and project
 237                          (muse-project project))
 238                     (car muse-project-alist))
 239         page (or page (muse-get-keyword :default
 240                                         (cadr project))))
 241   (let* ((page-path (muse-project-page-file page project))
 242          (remote-styles (when page-path (muse-project-applicable-styles
 243                                          page-path (cddr project))))
 244          (local-style (muse-project-current-output-style)))
 245     (cond ((and remote-styles local-style muse-publishing-p)
 246            (muse-project-resolve-link page local-style remote-styles))
 247           ((not muse-publishing-p)
 248            (if page-path
 249                page-path
 250              (when muse-wiki-allow-nonexistent-wikiword
 251                ;; make a path to a nonexistent file in project
 252                (setq page-path (expand-file-name
 253                                 page (car (cadr project))))
 254                (if (and muse-file-extension
 255                         (not (string= muse-file-extension "")))
 256                    (concat page-path "." muse-file-extension)
 257                  page-path)))))))
 258
 259 (defun muse-wiki-handle-interwiki (&optional string)
 260   "If STRING or point has an interwiki link, resolve it and
 261 return the first match.
 262
 263 Match 1 is set to the link.
 264 Match 2 is set to the description."
 265   (when (if string (string-match muse-wiki-interwiki-regexp string)
 266           (looking-at muse-wiki-interwiki-regexp))
 267     (let* ((project (match-string 1 string))
 268            (subst (cdr (assoc project muse-wiki-interwiki-alist)))
 269            (word (if string
 270                      (and (match-beginning 2)
 271                           (substring string (match-beginning 2)))
 272                    (match-string 2 string))))
 273       (if subst
 274           (if (functionp subst)
 275               (funcall subst word)
 276             (concat subst word))
 277         (and (assoc project muse-project-alist)
 278              (or word (not muse-wiki-ignore-bare-project-names))
 279              (muse-wiki-resolve-project-page project word))))))
 280
 281 (defun muse-wiki-handle-wikiword (&optional string)
 282   "If STRING or point has a WikiWord, return it.
 283
 284 Match 1 is set to the WikiWord."
 285   (when (and (or (and muse-wiki-match-all-project-files
 286                       muse-wiki-project-file-regexp
 287                       (if string
 288                           (string-match muse-wiki-project-file-regexp string)
 289                         (looking-at muse-wiki-project-file-regexp)))
 290                  (and muse-wiki-use-wikiword
 291                       (if string
 292                           (string-match muse-wiki-wikiword-regexp string)
 293                         (looking-at muse-wiki-wikiword-regexp))))
 294              (cond
 295               (muse-wiki-allow-nonexistent-wikiword
 296                t)
 297               ((and muse-wiki-ignore-implicit-links-to-current-page
 298                     (string= (match-string 1 string) (muse-page-name)))
 299                nil)
 300               ((and (muse-project-of-file)
 301                     (muse-project-page-file
 302                      (match-string 1 string) muse-current-project t))
 303                t)
 304               ((file-exists-p (match-string 1 string))
 305                t)
 306               (t nil)))
 307     (match-string 1 string)))
 308
 309 ;; Prettifications
 310
 311 (defcustom muse-wiki-publish-small-title-words
 312   '("the" "and" "at" "on" "of" "for" "in" "an" "a")
 313   "Strings that should be downcased in a page title.
 314
 315 This is used by `muse-wiki-publish-pretty-title', which must be
 316 called manually."
 317   :type '(repeat string)
 318   :group 'muse-wiki)
 319
 320 (defcustom muse-wiki-hide-nop-tag t
 321   "If non-nil, hide <nop> tags when coloring a Muse buffer."
 322   :type 'boolean
 323   :group 'muse-wiki)
 324
 325 (defun muse-wiki-publish-pretty-title (&optional title explicit)
 326   "Return a pretty version of the given TITLE.
 327
 328 If EXPLICIT is non-nil, TITLE will be returned unmodified."
 329   (unless title (setq title (or (muse-publishing-directive "title") "")))
 330   (if (or explicit
 331           (save-match-data (string-match muse-url-regexp title)))
 332       title
 333     (save-match-data
 334       (let ((case-fold-search nil))
 335         (while (string-match (concat "\\([" muse-regexp-lower
 336                                      "]\\)\\([" muse-regexp-upper
 337                                      "0-9]\\)")
 338                              title)
 339           (setq title (replace-match "\\1 \\2" t nil title)))
 340         (let* ((words (split-string title))
 341                (w (cdr words)))
 342           (while w
 343             (if (member (downcase (car w))
 344                         muse-wiki-publish-small-title-words)
 345                 (setcar w (downcase (car w))))
 346             (setq w (cdr w)))
 347           (mapconcat 'identity words " "))))))
 348
 349 (defun muse-wiki-publish-pretty-interwiki (desc &optional explicit)
 350   "Replace instances of `muse-wiki-interwiki-delimiter' with
 351 `muse-wiki-interwiki-replacement'."
 352   (if (or explicit
 353           (save-match-data (string-match muse-url-regexp desc)))
 354       desc
 355     (muse-replace-regexp-in-string muse-wiki-interwiki-delimiter
 356                                    muse-wiki-interwiki-replacement
 357                                    desc)))
 358
 359 ;; Coloring setup
 360
 361 (eval-after-load "muse-colors"
 362   '(progn
 363      (defun muse-wiki-colors-nop-tag (beg end)
 364        (when muse-wiki-hide-nop-tag
 365          (add-text-properties beg (+ beg 5)
 366                               '(invisible muse intangible t))))
 367      (defun muse-colors-wikiword-separate ()
 368        (add-text-properties (match-beginning 0) (match-end 0)
 369                             '(invisible muse intangible t)))
 370
 371      (add-to-list 'muse-colors-tags
 372                   '("nop" nil nil nil muse-wiki-colors-nop-tag)
 373                   t)
 374
 375      (add-to-list 'muse-colors-markup
 376                   '(muse-wiki-interwiki-regexp t muse-colors-implicit-link)
 377                   t)
 378      (add-to-list 'muse-colors-markup
 379                   '(muse-wiki-wikiword-regexp t muse-colors-implicit-link)
 380                   t)
 381      (add-to-list 'muse-colors-markup
 382                   '(muse-wiki-project-file-regexp t muse-colors-implicit-link)
 383                   t)
 384      (add-to-list 'muse-colors-markup
 385                   '("''''" ?\' muse-colors-wikiword-separate)
 386                   nil)
 387
 388      (muse-configure-highlighting 'muse-colors-markup muse-colors-markup)))
 389
 390 ;; Publishing setup
 391
 392 (eval-after-load "muse-publish"
 393   '(progn
 394      (add-to-list 'muse-publish-markup-regexps
 395                   '(3100 muse-wiki-interwiki-regexp 0 link)
 396                   t)
 397      (add-to-list 'muse-publish-markup-regexps
 398                   '(3200 muse-wiki-wikiword-regexp 0 link)
 399                   t)
 400      (add-to-list 'muse-publish-markup-regexps
 401                   '(3250 muse-wiki-project-file-regexp 0 link)
 402                   t)
 403      (add-to-list 'muse-publish-markup-regexps
 404                   '(3300 "''''" 0 "")
 405                   t)
 406
 407      (custom-add-option 'muse-publish-desc-transforms
 408                         'muse-wiki-publish-pretty-interwiki)
 409      (custom-add-option 'muse-publish-desc-transforms
 410                         'muse-wiki-publish-pretty-title)))
 411
 412 ;; Insinuate link handling
 413
 414 (custom-add-option 'muse-implicit-link-functions
 415                    'muse-wiki-handle-interwiki)
 416 (custom-add-option 'muse-implicit-link-functions
 417                    'muse-wiki-handle-wikiword)
 418
 419 (custom-add-option 'muse-explicit-link-functions
 420                    'muse-wiki-handle-interwiki)
 421
 422 (add-to-list 'muse-implicit-link-functions
 423              'muse-wiki-handle-interwiki t)
 424 (add-to-list 'muse-implicit-link-functions
 425              'muse-wiki-handle-wikiword t)
 426
 427 (add-to-list 'muse-explicit-link-functions
 428              'muse-wiki-handle-interwiki t)
 429
 430 ;; Obsolete functions
 431
 432 (defun muse-wiki-update-custom-values ()
 433   (muse-display-warning
 434    (concat "Please remove `muse-wiki-update-custom-values' from"
 435            " `muse-mode-hook'.  Its use is now deprecated.")))
 436
 437 (provide 'muse-wiki)
 438 ;;; muse-wiki.el ends here