lisp/muse-journal.el

   1 ;;; muse-journal.el --- keep and publish a journal
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   4
   5 ;; This file is part of Emacs Muse.  It is not part of GNU Emacs.
   6
   7 ;; Emacs Muse is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published
   9 ;; by the Free Software Foundation; either version 2, or (at your
  10 ;; option) any later version.
  11
  12 ;; Emacs Muse is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Emacs Muse; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  20 ;; Boston, MA 02110-1301, USA.
  21
  22 ;;; Commentary:
  23
  24 ;; The module facilitates the keeping and publication of a journal.
  25 ;; When publishing to HTML, it assumes the form of a web log, or blog.
  26 ;;
  27 ;; The input format for each entry is as follows:
  28 ;;
  29 ;;   * 20040317: Title of entry
  30 ;;
  31 ;;   Text for the entry.
  32 ;;
  33 ;;   <qotd>
  34 ;;   "You know who you are. It comes down to a simple gut check: You
  35 ;;   either love what you do or you don't. Period." -- P. Bronson
  36 ;;   </qotd>
  37 ;;
  38 ;; The "qotd", or Quote of the Day, is entirely optional.  When
  39 ;; generated to HTML, this entry is rendered as:
  40 ;;
  41 ;;   <div class="entry">
  42 ;;     <div class="entry-qotd">
  43 ;;       <h3>Quote of the Day:</h3>
  44 ;;       <p>"You know who you are. It comes down to a simple gut
  45 ;;         check: You either love what you do or you don't. Period."
  46 ;;         -- P. Bronson</p>
  47 ;;     </div>
  48 ;;     <div class="entry-body">
  49 ;;       <div class="entry-head">
  50 ;;         <div class="entry-date">
  51 ;;           <span class="date">March 17, 2004</span>
  52 ;;         </div>
  53 ;;         <div class="entry-title">
  54 ;;           <h2>Title of entry</h2>
  55 ;;         </div>
  56 ;;       </div>
  57 ;;       <div class="entry-text">
  58 ;;         <p>Text for the entry.</p>
  59 ;;       </div>
  60 ;;     </div>
  61 ;;   </div>
  62 ;;
  63 ;; The plurality of "div" tags makes it possible to display the
  64 ;; entries in any form you wish, using a CSS style.
  65 ;;
  66 ;; Also, an .RDF file can be generated from your journal by publishing
  67 ;; it with the "rdf" style.  It uses the first two sentences of the
  68 ;; first paragraph of each entry as its "description", and
  69 ;; autogenerates tags for linking to the various entries.
  70
  71 ;;; Contributors:
  72
  73 ;; René Stadler (mail AT renestadler DOT de) provided a patch that
  74 ;; causes dates in RSS feeds to be generated in a format that RSS
  75 ;; readers can parse.
  76
  77 ;;; Code:
  78
  79 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  80 ;;
  81 ;; Muse Journal Publishing
  82 ;;
  83 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  84
  85 (require 'muse-publish)
  86 (require 'muse-html)
  87 (require 'muse-latex)
  88 (require 'muse-book)
  89
  90 (defgroup muse-journal nil
  91   "Rules for transforming a journal into its final form."
  92   :group 'muse-publish)
  93
  94 (defcustom muse-journal-heading-regexp
  95   "\\(?:\\([0-9]+\\)\\(?:: \\)?\\)?\\(.+?\\)?"
  96   "A regexp that matches a journal heading.
  97 Paren group 1 is the ISO date, group 2 is the optional category,
  98 and group 3 is the optional heading for the entry."
  99   :type 'regexp
 100   :group 'muse-journal)
 101
 102 (defcustom muse-journal-date-format "%a, %e %b %Y"
 103   "Date format to use for journal entries."
 104   :type 'string
 105   :group 'muse-journal)
 106
 107 (defcustom muse-journal-html-heading-regexp
 108   (concat "^<h2[^>\n]*>" muse-journal-heading-regexp "</h2>$")
 109   "A regexp that matches a journal heading from an HTML document.
 110 Paren group 1 is the ISO date, group 2 is the optional category,
 111 and group 3 is the optional heading for the entry."
 112   :type 'regexp
 113   :group 'muse-journal)
 114
 115 (defcustom muse-journal-rss-heading-regexp
 116   (concat "^\\* " muse-journal-heading-regexp "$")
 117   "A regexp that matches a journal heading from an HTML document.
 118 Paren group 1 is the ISO date, group 2 is the optional category,
 119 and group 3 is the optional heading for the entry."
 120   :type 'regexp
 121   :group 'muse-journal)
 122
 123 (defcustom muse-journal-html-entry-template
 124   "<div class=\"entry\">
 125   <a name=\"%anchor%\" style=\"text-decoration: none\">&nbsp;</a>
 126   <div class=\"entry-body\">
 127     <div class=\"entry-head\">
 128       <div class=\"entry-date\">
 129         <span class=\"date\">%date%</span>
 130       </div>
 131       <div class=\"entry-title\">
 132         <h2>%title%</h2>
 133       </div>
 134     </div>
 135     <div class=\"entry-text\">
 136       <div class=\"entry-qotd\">
 137         <p>%qotd%</p>
 138       </div>
 139 %text%
 140     </div>
 141   </div>
 142 </div>\n\n"
 143   "Template used to publish individual journal entries as HTML.
 144 This may be text or a filename."
 145   :type 'string
 146   :group 'muse-journal)
 147
 148 (defcustom muse-journal-latex-section
 149   "\\section*{%title% \\hfill {\\normalsize %date%}}
 150 \\addcontentsline{toc}{chapter}{%title%}"
 151   "Template used to publish a LaTeX section."
 152   :type 'string
 153   :group 'muse-journal)
 154
 155 (defcustom muse-journal-latex-subsection
 156   "\\subsection*{%title%}
 157 \\addcontentsline{toc}{section}{%title%}"
 158   "Template used to publish a LaTeX subsection."
 159   :type 'string
 160   :group 'muse-journal)
 161
 162 (defcustom muse-journal-markup-tags
 163   '(("qotd" t nil nil muse-journal-qotd-tag))
 164   "A list of tag specifications, for specially marking up Journal entries.
 165 See `muse-publish-markup-tags' for more info.
 166
 167 This is used by journal-latex and its related styles, as well as
 168 the journal-rss-entry style, which both journal-rdf and
 169 journal-rss use."
 170   :type '(repeat (list (string :tag "Markup tag")
 171                        (boolean :tag "Expect closing tag" :value t)
 172                        (boolean :tag "Parse attributes" :value nil)
 173                        (boolean :tag "Nestable" :value nil)
 174                        function))
 175   :group 'muse-journal)
 176
 177 ;; FIXME: This doesn't appear to be used.
 178 (defun muse-journal-generate-pages ()
 179   (let ((output-dir (muse-style-element :path)))
 180     (goto-char (point-min))
 181     (while (re-search-forward muse-journal-heading-regexp nil t)
 182       (let* ((date (match-string 1))
 183              (category (match-string 1))
 184              (category-file (concat output-dir category "/index.html"))
 185              (heading (match-string 1)))
 186         t))))
 187
 188 (defcustom muse-journal-rdf-extension ".rdf"
 189   "Default file extension for publishing RDF (RSS 1.0) files."
 190   :type 'string
 191   :group 'muse-journal)
 192
 193 (defcustom muse-journal-rdf-base-url ""
 194   "The base URL of the website referenced by the RDF file."
 195   :type 'string
 196   :group 'muse-journal)
 197
 198 (defcustom muse-journal-rdf-header
 199   "<rdf:RDF xmlns:rdf=\"http://www.w3.org/1999/02/22-rdf-syntax-ns#\"
 200          xmlns=\"http://purl.org/rss/1.0/\"
 201          xmlns:dc=\"http://purl.org/dc/elements/1.1/\">
 202   <channel rdf:about=\"<lisp>(concat (muse-style-element :base-url)
 203                                      (muse-publish-link-name))</lisp>\">
 204     <title><lisp>(muse-publishing-directive \"title\")</lisp></title>
 205     <link><lisp>(concat (muse-style-element :base-url)
 206                        (concat (muse-page-name)
 207                                muse-html-extension))</lisp></link>
 208     <description><lisp>(muse-publishing-directive \"desc\")</lisp></description>
 209     <items>
 210       <rdf:Seq>
 211         <rdf:li resource=\"<lisp>
 212           (concat (muse-style-element :base-url)
 213                   (concat (muse-page-name)
 214                           muse-html-extension))</lisp>\"/>
 215       </rdf:Seq>
 216     </items>
 217   </channel>\n"
 218   "Header used for publishing RDF (RSS 1.0) files.
 219 This may be text or a filename."
 220   :type 'string
 221   :group 'muse-journal)
 222
 223 (defcustom muse-journal-rdf-footer
 224   "</rdf:RDF>\n"
 225   "Footer used for publishing RDF (RSS 1.0) files.
 226 This may be text or a filename."
 227   :type 'string
 228   :group 'muse-journal)
 229
 230 (defcustom muse-journal-rdf-date-format
 231   "%Y-%m-%dT%H:%M:%S"
 232   "Date format to use for RDF entries."
 233   :type 'string
 234   :group 'muse-journal)
 235
 236 (defcustom muse-journal-rdf-entry-template
 237   "\n  <item rdf:about=\"%link%#%anchor%\">
 238     <title>%title%</title>
 239     <description>
 240       %desc%
 241     </description>
 242     <link>%link%#%anchor%</link>
 243     <dc:date>%date%</dc:date>
 244     <dc:creator>%maintainer%</dc:creator>
 245   </item>\n"
 246   "Template used to publish individual journal entries as RDF.
 247 This may be text or a filename."
 248   :type 'string
 249   :group 'muse-journal)
 250
 251 (defcustom muse-journal-rdf-summarize-entries nil
 252   "If non-nil, include only summaries in the RDF file, not the full data.
 253
 254 The default is nil, because this annoys some subscribers."
 255   :type 'boolean
 256   :group 'muse-journal)
 257
 258 (defcustom muse-journal-rss-extension ".xml"
 259   "Default file extension for publishing RSS 2.0 files."
 260   :type 'string
 261   :group 'muse-journal)
 262
 263 (defcustom muse-journal-rss-base-url ""
 264   "The base URL of the website referenced by the RSS file."
 265   :type 'string
 266   :group 'muse-journal)
 267
 268 (defcustom muse-journal-rss-header
 269   "<\?xml version=\"1.0\" encoding=\"<lisp>
 270   (muse-html-encoding)</lisp>\"?>
 271 <rss version=\"2.0\">
 272   <channel>
 273     <title><lisp>(muse-publishing-directive \"title\")</lisp></title>
 274     <link><lisp>(concat (muse-style-element :base-url)
 275                         (concat (muse-page-name)
 276                                 muse-html-extension))</lisp></link>
 277     <description><lisp>(muse-publishing-directive \"desc\")</lisp></description>
 278     <language>en-us</language>
 279     <generator>Emacs Muse</generator>\n\n"
 280   "Header used for publishing RSS 2.0 files.  This may be text or a filename."
 281   :type 'string
 282   :group 'muse-journal)
 283
 284 (defcustom muse-journal-rss-footer
 285   "\n\n  </channel>
 286 </rss>\n"
 287   "Footer used for publishing RSS 2.0 files.  This may be text or a filename."
 288   :type 'string
 289   :group 'muse-journal)
 290
 291 (defcustom muse-journal-rss-date-format
 292   "%a, %d %b %Y %H:%M:%S %Z"
 293   "Date format to use for RSS 2.0 entries."
 294   :type 'string
 295   :group 'muse-journal)
 296
 297 (defcustom muse-journal-rss-entry-template
 298   "\n    <item>
 299       <title>%title%</title>
 300       <link>%link%#%anchor%</link>
 301       <description>%desc%</description>
 302       <author><lisp>(muse-publishing-directive \"author\")</lisp></author>
 303       <pubDate>%date%</pubDate>
 304       <guid>%link%#%anchor%</guid>
 305       %enclosure%
 306     </item>\n"
 307   "Template used to publish individual journal entries as RSS 2.0.
 308 This may be text or a filename."
 309   :type 'string
 310   :group 'muse-journal)
 311
 312 (defcustom muse-journal-rss-enclosure-types-alist
 313   '(("mp3" . "audio/mpeg"))
 314   "File types that are accepted as RSS enclosures.
 315 This is an alist that maps file extension to content type.
 316 Useful for podcasting."
 317   :type '(alist :key-type string :value-type string)
 318   :group 'muse-journal)
 319
 320 (defcustom muse-journal-rss-summarize-entries nil
 321   "If non-nil, include only summaries in the RSS file, not the full data.
 322
 323 The default is nil, because this annoys some subscribers."
 324   :type 'boolean
 325   :group 'muse-journal)
 326
 327 (defcustom muse-journal-rss-markup-regexps
 328   '((10000 muse-explicit-link-regexp 0 "\\2"))
 329   "List of markup rules for publishing a Muse journal page to RSS 2.0.
 330 For more information on the structure of this list, see
 331 `muse-publish-markup-regexps'."
 332   :type '(repeat (choice
 333                   (list :tag "Markup rule"
 334                         integer
 335                         (choice regexp symbol)
 336                         integer
 337                         (choice string function symbol))
 338                   function))
 339   :group 'muse-journal)
 340
 341 (defcustom muse-journal-rss-markup-functions
 342   '((email . ignore)
 343     (link  . ignore)
 344     (url   . ignore))
 345   "An alist of style types to custom functions for that kind of text.
 346 For more on the structure of this list, see
 347 `muse-publish-markup-functions'."
 348   :type '(alist :key-type symbol :value-type function)
 349   :group 'muse-journal)
 350
 351 (defun muse-journal-anchorize-title (title)
 352   (save-match-data
 353     (if (string-match "(" title)
 354         (setq title (substring title 0 (match-beginning 0))))
 355     (if (string-match "<[^>]+>" title)
 356         (setq title (replace-match "" nil nil title)))
 357     (downcase (muse-replace-regexp-in-string "[^a-zA-Z0-9_]" "" title))))
 358
 359 (defun muse-journal-sort-entries (&optional direction)
 360   (interactive "P")
 361   (sort-subr
 362    direction
 363    (function
 364     (lambda ()
 365       (if (re-search-forward "^\\* [0-9]+" nil t)
 366           (goto-char (match-beginning 0))
 367         (goto-char (point-max)))))
 368    (function
 369     (lambda ()
 370       (if (re-search-forward "^\\* [0-9]+" nil t)
 371           (goto-char (1- (match-beginning 0)))
 372         (goto-char (point-max)))))
 373    (function
 374     (lambda ()
 375       (forward-char 2)))
 376    (function
 377     (lambda ()
 378       (end-of-line)))))
 379
 380 (defun muse-journal-qotd-tag (beg end)
 381   (muse-publish-ensure-block beg end)
 382   (muse-insert-markup (muse-markup-text 'begin-quote))
 383   (muse-insert-markup (muse-markup-text 'begin-quote-item))
 384   (goto-char end)
 385   (muse-insert-markup (muse-markup-text 'end-quote-item))
 386   (muse-insert-markup (muse-markup-text 'end-quote)))
 387
 388 (defun muse-journal-html-munge-buffer ()
 389   (goto-char (point-min))
 390   (let ((heading-regexp muse-journal-html-heading-regexp)
 391         (inhibit-read-only t))
 392     (while (re-search-forward heading-regexp nil t)
 393       (let* ((date (match-string 1))
 394              (orig-date date)
 395              (title (match-string 2))
 396              (clean-title title)
 397              datestamp qotd text)
 398         (delete-region (match-beginning 0) (match-end 0))
 399         (if clean-title
 400             (save-match-data
 401               (while (string-match "\\(^<[^>]+>\\|<[^>]+>$\\)" clean-title)
 402                 (setq clean-title (replace-match "" nil nil clean-title)))))
 403         (save-match-data
 404           (when (and date
 405                      (string-match
 406                       (concat "\\`\\([1-9][0-9][0-9][0-9]\\)[./]?"
 407                               "\\([0-1][0-9]\\)[./]?\\([0-3][0-9]\\)") date))
 408             (setq datestamp
 409                   (encode-time
 410                    0 0 0
 411                    (string-to-number (match-string 3 date))
 412                    (string-to-number (match-string 2 date))
 413                    (string-to-number (match-string 1 date))
 414                    (current-time-zone))
 415                   date (concat (format-time-string
 416                                 muse-journal-date-format datestamp)
 417                                (substring date (match-end 0))))))
 418         (save-restriction
 419           (narrow-to-region
 420            (point) (if (re-search-forward
 421                         (concat "\\(^<hr>$\\|"
 422                                 heading-regexp "\\)") nil t)
 423                        (match-beginning 0)
 424                      (point-max)))
 425           (goto-char (point-max))
 426           (while (and (not (bobp))
 427                       (eq ?\  (char-syntax (char-before))))
 428             (delete-char -1))
 429           (goto-char (point-min))
 430           (while (and (not (eobp))
 431                       (eq ?\  (char-syntax (char-after))))
 432             (delete-char 1))
 433           (save-excursion
 434             (when (search-forward "<qotd>" nil t)
 435               (let ((tag-beg (match-beginning 0))
 436                     (beg (match-end 0))
 437                     end)
 438                 (re-search-forward "</qotd>\n*")
 439                 (setq end (point-marker))
 440                 (save-restriction
 441                   (narrow-to-region beg (match-beginning 0))
 442                   (muse-publish-escape-specials (point-min) (point-max)
 443                                                 nil 'document)
 444                   (setq qotd (buffer-substring-no-properties
 445                               (point-min) (point-max))))
 446                 (delete-region tag-beg end))))
 447           (setq text (buffer-string))
 448           (delete-region (point-min) (point-max))
 449           (let ((entry muse-journal-html-entry-template))
 450             (muse-insert-file-or-string entry)
 451             (muse-publish-mark-read-only (point-min) (point-max))
 452             (goto-char (point-min))
 453             (while (search-forward "%date%" nil t)
 454               (remove-text-properties (match-beginning 0) (match-end 0)
 455                                       '(read-only nil rear-nonsticky nil))
 456               (replace-match (or date "") nil t))
 457             (goto-char (point-min))
 458             (while (search-forward "%title%" nil t)
 459               (remove-text-properties (match-beginning 0) (match-end 0)
 460                                       '(read-only nil rear-nonsticky nil))
 461               (replace-match (or title "&nbsp;") nil t))
 462             (goto-char (point-min))
 463             (while (search-forward "%anchor%" nil t)
 464               (replace-match (muse-journal-anchorize-title
 465                               (or clean-title orig-date))
 466                              nil t))
 467             (goto-char (point-min))
 468             (while (search-forward "%qotd%" nil t)
 469               (save-restriction
 470                 (narrow-to-region (match-beginning 0) (match-end 0))
 471                 (delete-region (point-min) (point-max))
 472                 (when qotd (muse-insert-markup qotd))))
 473             (goto-char (point-min))
 474             (while (search-forward "%text%" nil t)
 475               (remove-text-properties (match-beginning 0) (match-end 0)
 476                                       '(read-only nil rear-nonsticky nil))
 477               (replace-match text nil t))
 478             (when (null qotd)
 479               (goto-char (point-min))
 480               (when (search-forward "<div class=\"entry-qotd\">" nil t)
 481                 (let ((beg (match-beginning 0)))
 482                   (re-search-forward "</div>\n*" nil t)
 483                   (delete-region beg (point))))))))))
 484   ;; indicate that we are to continue the :before-end processing
 485   nil)
 486
 487 (defun muse-journal-latex-munge-buffer ()
 488   (goto-char (point-min))
 489   (let ((heading-regexp
 490          (concat "^" (regexp-quote (muse-markup-text 'section))
 491                  muse-journal-heading-regexp
 492                  (regexp-quote (muse-markup-text 'section-end)) "$"))
 493         (inhibit-read-only t))
 494     (when (re-search-forward heading-regexp nil t)
 495       (goto-char (match-beginning 0))
 496       (sort-subr nil
 497                  (function
 498                   (lambda ()
 499                     (if (re-search-forward heading-regexp nil t)
 500                         (goto-char (match-beginning 0))
 501                       (goto-char (point-max)))))
 502                  (function
 503                   (lambda ()
 504                     (if (re-search-forward heading-regexp nil t)
 505                         (goto-char (1- (match-beginning 0)))
 506                       (goto-char (point-max)))))
 507                  (function
 508                   (lambda ()
 509                     (forward-char 2)))
 510                  (function
 511                   (lambda ()
 512                     (end-of-line)))))
 513     (while (re-search-forward heading-regexp nil t)
 514       (let ((date (match-string 1))
 515             (title (match-string 2))
 516             ;; FIXME: Nothing is done with qotd
 517             qotd section)
 518         (save-match-data
 519           (when (and date
 520                      (string-match
 521                       (concat "\\([1-9][0-9][0-9][0-9]\\)[./]?"
 522                               "\\([0-1][0-9]\\)[./]?\\([0-3][0-9]\\)") date))
 523             (setq date (encode-time
 524                         0 0 0
 525                         (string-to-number (match-string 3 date))
 526                         (string-to-number (match-string 2 date))
 527                         (string-to-number (match-string 1 date))
 528                         (current-time-zone))
 529                   date (format-time-string
 530                         muse-journal-date-format date))))
 531         (save-restriction
 532           (narrow-to-region (match-beginning 0) (match-end 0))
 533           (delete-region (point-min) (point-max))
 534           (muse-insert-markup muse-journal-latex-section)
 535           (goto-char (point-min))
 536           (while (search-forward "%title%" nil t)
 537             (replace-match (or title "Untitled") nil t))
 538           (goto-char (point-min))
 539           (while (search-forward "%date%" nil t)
 540             (replace-match (or date "") nil t))))))
 541   (goto-char (point-min))
 542   (let ((subheading-regexp
 543          (concat "^" (regexp-quote (muse-markup-text 'subsection))
 544                  "\\([^\n}]+\\)"
 545                  (regexp-quote (muse-markup-text 'subsection-end)) "$"))
 546         (inhibit-read-only t))
 547     (while (re-search-forward subheading-regexp nil t)
 548       (let ((title (match-string 1)))
 549         (save-restriction
 550           (narrow-to-region (match-beginning 0) (match-end 0))
 551           (delete-region (point-min) (point-max))
 552           (muse-insert-markup muse-journal-latex-subsection)
 553           (goto-char (point-min))
 554           (while (search-forward "%title%" nil t)
 555             (replace-match title nil t))))))
 556   ;; indicate that we are to continue the :before-end processing
 557   nil)
 558
 559 (defun muse-journal-rss-munge-buffer ()
 560   (goto-char (point-min))
 561   (let ((heading-regexp muse-journal-rss-heading-regexp)
 562         (inhibit-read-only t))
 563     (while (re-search-forward heading-regexp nil t)
 564       (let* ((date (match-string 1))
 565              (orig-date date)
 566              (title (match-string 2))
 567              ;; FIXME: Nothing is done with qotd
 568              enclosure qotd desc)
 569         (if title
 570             (save-match-data
 571               (if (string-match muse-explicit-link-regexp title)
 572                   (setq enclosure (muse-get-link title)
 573                         title (muse-get-link-desc title)))))
 574         (save-match-data
 575           (when (and date
 576                      (string-match
 577                       (concat "\\([1-9][0-9][0-9][0-9]\\)[./]?"
 578                               "\\([0-1][0-9]\\)[./]?\\([0-3][0-9]\\)") date))
 579             (setq date (encode-time 0 0 0
 580                                     (string-to-number (match-string 3 date))
 581                                     (string-to-number (match-string 2 date))
 582                                     (string-to-number (match-string 1 date))
 583                                     (current-time-zone))
 584                   ;; make sure that date is in a format that RSS
 585                   ;; readers can handle
 586                   date (let ((system-time-locale "C"))
 587                          (format-time-string
 588                           (muse-style-element :date-format) date)))))
 589         (save-restriction
 590           (narrow-to-region
 591            (match-beginning 0)
 592            (if (re-search-forward heading-regexp nil t)
 593                (match-beginning 0)
 594              (if (re-search-forward "^Footnotes:" nil t)
 595                  (match-beginning 0)
 596                (point-max))))
 597           (goto-char (point-min))
 598           (delete-region (point) (muse-line-end-position))
 599           (re-search-forward "</qotd>\n+" nil t)
 600           (while (and (char-after)
 601                       (eq ?\  (char-syntax (char-after))))
 602             (delete-char 1))
 603           (let ((beg (point)))
 604             (if (muse-style-element :summarize)
 605                 (progn
 606                   (forward-sentence 2)
 607                   (setq desc (concat (buffer-substring beg (point)) "...")))
 608               (save-restriction
 609                 (muse-publish-markup-buffer "rss-entry" "journal-rss-entry")
 610                 (goto-char (point-min))
 611                 (if (re-search-forward "Page published by Emacs Muse" nil t)
 612                     (goto-char (muse-line-end-position))
 613                   (muse-display-warning
 614                    (concat
 615                     "Cannot find 'Page published by Emacs Muse begins here'.\n"
 616                     "You will probably need this text in your header."))
 617                   (goto-char (point-min)))
 618                 (setq beg (point))
 619                 (if (re-search-forward "Page published by Emacs Muse" nil t)
 620                     (goto-char (muse-line-beginning-position))
 621                   (muse-display-warning
 622                    (concat
 623                     "Cannot find 'Page published by Emacs Muse ends here'.\n"
 624                     "You will probably need this text in your footer."))
 625                   (goto-char (point-max)))
 626                 (setq desc (concat "<![CDATA[" (buffer-substring beg (point))
 627                                    "]]>")))))
 628           (delete-region (point-min) (point-max))
 629           (let ((entry (muse-style-element :entry-template)))
 630             (muse-insert-file-or-string entry)
 631             (goto-char (point-min))
 632             (while (search-forward "%date%" nil t)
 633               (replace-match (or date "") nil t))
 634             (goto-char (point-min))
 635             (while (search-forward "%title%" nil t)
 636               (replace-match "")
 637               (save-restriction
 638                 (narrow-to-region (point) (point))
 639                 (insert (or title "Untitled"))
 640                 (remove-text-properties (match-beginning 0) (match-end 0)
 641                                         '(read-only nil rear-nonsticky nil))
 642                 (let ((muse-publishing-current-style (muse-style "html")))
 643                   (muse-publish-escape-specials (point-min) (point-max)
 644                                                 nil 'document))))
 645             (goto-char (point-min))
 646             (while (search-forward "%desc%" nil t)
 647               (replace-match desc nil t))
 648             (goto-char (point-min))
 649             (while (search-forward "%enclosure%" nil t)
 650               (replace-match
 651                (if (null enclosure)
 652                    ""
 653                  (save-match-data
 654                    (format
 655                     "<enclosure url=\"%s\" %stype=\"%s\"/>"
 656                     (if (string-match "//" enclosure)
 657                         enclosure
 658                       (concat (muse-style-element :base-url)
 659                               enclosure))
 660                     (let ((file
 661                            (expand-file-name enclosure
 662                                              (muse-style-element :path))))
 663                       (if (file-readable-p file)
 664                           (format "length=\"%d\" "
 665                                   (nth 7 (file-attributes file)))
 666                         ""))
 667                     (if (string-match "\\.\\([^.]+\\)$" enclosure)
 668                         (let* ((ext (match-string 1 enclosure))
 669                                (type
 670                                 (assoc
 671                                  ext muse-journal-rss-enclosure-types-alist)))
 672                           (if type
 673                               (cdr type)
 674                             "application/octet-stream"))))))
 675                nil t))
 676             (goto-char (point-min))
 677             (while (search-forward "%link%" nil t)
 678               (replace-match
 679                (concat (muse-style-element :base-url)
 680                        (concat (muse-page-name)
 681                                muse-html-extension))
 682                nil t))
 683             (goto-char (point-min))
 684             (while (search-forward "%anchor%" nil t)
 685               (replace-match
 686                (muse-journal-anchorize-title (or title orig-date))
 687                nil t))
 688             (goto-char (point-min))
 689             (while (search-forward "%maintainer%" nil t)
 690               (replace-match
 691                (or (muse-style-element :maintainer)
 692                    (concat "webmaster@" (system-name)))
 693                nil t)))))))
 694   ;; indicate that we are to continue the :before-end processing
 695   nil)
 696
 697
 698 ;;; Register the Muse Journal Publishers
 699
 700 (muse-derive-style "journal-html" "html"
 701                    :before-end 'muse-journal-html-munge-buffer)
 702
 703 (muse-derive-style "journal-xhtml" "xhtml"
 704                    :before-end 'muse-journal-html-munge-buffer)
 705
 706 (muse-derive-style "journal-latex" "latex"
 707                    :tags 'muse-journal-markup-tags
 708                    :before-end 'muse-journal-latex-munge-buffer)
 709
 710 (muse-derive-style "journal-pdf" "pdf"
 711                    :tags 'muse-journal-markup-tags
 712                    :before-end 'muse-journal-latex-munge-buffer)
 713
 714 (muse-derive-style "journal-book-latex" "book-latex"
 715                    ;;:nochapters
 716                    :tags 'muse-journal-markup-tags
 717                    :before-end 'muse-journal-latex-munge-buffer)
 718
 719 (muse-derive-style "journal-book-pdf" "book-pdf"
 720                    ;;:nochapters
 721                    :tags 'muse-journal-markup-tags
 722                    :before-end 'muse-journal-latex-munge-buffer)
 723
 724 (muse-define-style "journal-rdf"
 725                    :suffix         'muse-journal-rdf-extension
 726                    :regexps        'muse-journal-rss-markup-regexps
 727                    :functions      'muse-journal-rss-markup-functions
 728                    :before         'muse-journal-rss-munge-buffer
 729                    :header         'muse-journal-rdf-header
 730                    :footer         'muse-journal-rdf-footer
 731                    :date-format    'muse-journal-rdf-date-format
 732                    :entry-template 'muse-journal-rdf-entry-template
 733                    :base-url       'muse-journal-rdf-base-url
 734                    :summarize      'muse-journal-rdf-summarize-entries)
 735
 736 (muse-define-style "journal-rss"
 737                    :suffix         'muse-journal-rss-extension
 738                    :regexps        'muse-journal-rss-markup-regexps
 739                    :functions      'muse-journal-rss-markup-functions
 740                    :before         'muse-journal-rss-munge-buffer
 741                    :header         'muse-journal-rss-header
 742                    :footer         'muse-journal-rss-footer
 743                    :date-format    'muse-journal-rss-date-format
 744                    :entry-template 'muse-journal-rss-entry-template
 745                    :base-url       'muse-journal-rss-base-url
 746                    :summarize      'muse-journal-rss-summarize-entries)
 747
 748 ;; Used by `muse-journal-rss-munge-buffer' to mark up individual entries
 749 (muse-derive-style "journal-rss-entry" "html"
 750                    :tags 'muse-journal-markup-tags)
 751
 752 (provide 'muse-journal)
 753
 754 ;;; muse-journal.el ends here