mingw/lib/tk8.5/demos/ttknote.tcl

   1 # ttknote.tcl --
   2 #
   3 # This demonstration script creates a toplevel window containing a Ttk
   4 # notebook widget.
   5 #
   6 # RCS: @(#) $Id: ttknote.tcl,v 1.5 2007/12/13 15:27:07 dgp Exp $
   7
   8 if {![info exists widgetDemo]} {
   9     error "This script should be run from the \"widget\" demo."
  10 }
  11
  12 package require Tk
  13 package require Ttk
  14
  15 set w .ttknote
  16 catch {destroy $w}
  17 toplevel $w
  18 wm title $w "Ttk Notebook Widget"
  19 wm iconname $w "ttknote"
  20 positionWindow $w
  21
  22 ## See Code / Dismiss
  23 pack [addSeeDismiss $w.seeDismiss $w] -side bottom -fill x
  24
  25 ttk::frame $w.f
  26 pack $w.f -fill both -expand 1
  27 set w $w.f
  28
  29 ## Make the notebook and set up Ctrl+Tab traversal
  30 ttk::notebook $w.note
  31 pack $w.note -fill both -expand 1 -padx 2 -pady 3
  32 ttk::notebook::enableTraversal $w.note
  33
  34 ## Popuplate the first pane
  35 ttk::frame $w.note.msg
  36 ttk::label $w.note.msg.m -font $font -wraplength 4i -justify left -anchor n -text "Ttk is the new Tk themed widget set. One of the widgets it includes is the notebook widget, which provides a set of tabs that allow the selection of a group of panels, each with distinct content. They are a feature of many modern user interfaces. Not only can the tabs be selected with the mouse, but they can also be switched between using Ctrl+Tab when the notebook page heading itself is selected. Note that the second tab is disabled, and cannot be selected."
  37 ttk::button $w.note.msg.b -text "Neat!" -underline 0 -command {
  38     set neat "Yeah, I know..."
  39     after 500 {set neat {}}
  40 }
  41 bind $w <Alt-n> "focus $w.note.msg.b; $w.note.msg.b invoke"
  42 ttk::label $w.note.msg.l -textvariable neat
  43 $w.note add $w.note.msg -text "Description" -underline 0 -padding 2
  44 grid $w.note.msg.m - -sticky new -pady 2
  45 grid $w.note.msg.b $w.note.msg.l -pady {2 4}
  46 grid rowconfigure $w.note.msg 1 -weight 1
  47 grid columnconfigure $w.note.msg {0 1} -weight 1 -uniform 1
  48
  49 ## Populate the second pane. Note that the content doesn't really matter
  50 ttk::frame $w.note.disabled
  51 $w.note add $w.note.disabled -text "Disabled" -state disabled
  52
  53 ## Popuplate the third pane
  54 ttk::frame $w.note.editor
  55 $w.note add $w.note.editor -text "Text Editor" -underline 0
  56 text $w.note.editor.t -width 40 -height 10 -wrap char \
  57         -yscroll "$w.note.editor.s set"
  58 if {[tk windowingsystem] ne "aqua"} {
  59     ttk::scrollbar $w.note.editor.s -orient vertical -command "$w.note.editor.t yview"
  60 } else {
  61     scrollbar $w.note.editor.s -orient vertical -command "$w.note.editor.t yview"
  62 }
  63 pack $w.note.editor.s -side right -fill y -padx {0 2} -pady 2
  64 pack $w.note.editor.t -fill both -expand 1 -pady 2 -padx {2 0}