share/vim/vim73/syntax/2html.vim

   1 " Vim syntax support file
   2 " Maintainer: Ben Fritz <fritzophrenic@gmail.com>
   3 " Last Change: 2010 Aug 12
   4 "
   5 " Additional contributors:
   6 "
   7 "             Original by Bram Moolenaar <Bram@vim.org>
   8 "             Modified by David Ne\v{c}as (Yeti) <yeti@physics.muni.cz>
   9 "             XHTML support by Panagiotis Issaris <takis@lumumba.luc.ac.be>
  10 "             Made w3 compliant by Edd Barrett <vext01@gmail.com>
  11 "             Added html_font. Edd Barrett <vext01@gmail.com>
  12 "             Progress bar based off code from "progressbar widget" plugin by
  13 "               Andreas Politz, heavily modified:
  14 "               http://www.vim.org/scripts/script.php?script_id=2006
  15 "
  16 "             See Mercurial change logs for more!
  17
  18 " Transform a file into HTML, using the current syntax highlighting.
  19
  20 " this file uses line continuations
  21 let s:cpo_sav = &cpo
  22 let s:ls  = &ls
  23 set cpo-=C
  24
  25 let s:end=line('$')
  26
  27 " Font
  28 if exists("g:html_font")
  29   let s:htmlfont = "'". g:html_font . "', monospace"
  30 else
  31   let s:htmlfont = "monospace"
  32 endif
  33
  34 let s:settings = tohtml#GetUserSettings()
  35
  36 " When not in gui we can only guess the colors.
  37 if has("gui_running")
  38   let s:whatterm = "gui"
  39 else
  40   let s:whatterm = "cterm"
  41   if &t_Co == 8
  42     let s:cterm_color = {0: "#808080", 1: "#ff6060", 2: "#00ff00", 3: "#ffff00", 4: "#8080ff", 5: "#ff40ff", 6: "#00ffff", 7: "#ffffff"}
  43   else
  44     let s:cterm_color = {0: "#000000", 1: "#c00000", 2: "#008000", 3: "#804000", 4: "#0000c0", 5: "#c000c0", 6: "#008080", 7: "#c0c0c0", 8: "#808080", 9: "#ff6060", 10: "#00ff00", 11: "#ffff00", 12: "#8080ff", 13: "#ff40ff", 14: "#00ffff", 15: "#ffffff"}
  45
  46     " Colors for 88 and 256 come from xterm.
  47     if &t_Co == 88
  48       call extend(s:cterm_color, {16: "#000000", 17: "#00008b", 18: "#0000cd", 19: "#0000ff", 20: "#008b00", 21: "#008b8b", 22: "#008bcd", 23: "#008bff", 24: "#00cd00", 25: "#00cd8b", 26: "#00cdcd", 27: "#00cdff", 28: "#00ff00", 29: "#00ff8b", 30: "#00ffcd", 31: "#00ffff", 32: "#8b0000", 33: "#8b008b", 34: "#8b00cd", 35: "#8b00ff", 36: "#8b8b00", 37: "#8b8b8b", 38: "#8b8bcd", 39: "#8b8bff", 40: "#8bcd00", 41: "#8bcd8b", 42: "#8bcdcd", 43: "#8bcdff", 44: "#8bff00", 45: "#8bff8b", 46: "#8bffcd", 47: "#8bffff", 48: "#cd0000", 49: "#cd008b", 50: "#cd00cd", 51: "#cd00ff", 52: "#cd8b00", 53: "#cd8b8b", 54: "#cd8bcd", 55: "#cd8bff", 56: "#cdcd00", 57: "#cdcd8b", 58: "#cdcdcd", 59: "#cdcdff", 60: "#cdff00", 61: "#cdff8b", 62: "#cdffcd", 63: "#cdffff", 64: "#ff0000"})
  49       call extend(s:cterm_color, {65: "#ff008b", 66: "#ff00cd", 67: "#ff00ff", 68: "#ff8b00", 69: "#ff8b8b", 70: "#ff8bcd", 71: "#ff8bff", 72: "#ffcd00", 73: "#ffcd8b", 74: "#ffcdcd", 75: "#ffcdff", 76: "#ffff00", 77: "#ffff8b", 78: "#ffffcd", 79: "#ffffff", 80: "#2e2e2e", 81: "#5c5c5c", 82: "#737373", 83: "#8b8b8b", 84: "#a2a2a2", 85: "#b9b9b9", 86: "#d0d0d0", 87: "#e7e7e7"})
  50     elseif &t_Co == 256
  51       call extend(s:cterm_color, {16: "#000000", 17: "#00005f", 18: "#000087", 19: "#0000af", 20: "#0000d7", 21: "#0000ff", 22: "#005f00", 23: "#005f5f", 24: "#005f87", 25: "#005faf", 26: "#005fd7", 27: "#005fff", 28: "#008700", 29: "#00875f", 30: "#008787", 31: "#0087af", 32: "#0087d7", 33: "#0087ff", 34: "#00af00", 35: "#00af5f", 36: "#00af87", 37: "#00afaf", 38: "#00afd7", 39: "#00afff", 40: "#00d700", 41: "#00d75f", 42: "#00d787", 43: "#00d7af", 44: "#00d7d7", 45: "#00d7ff", 46: "#00ff00", 47: "#00ff5f", 48: "#00ff87", 49: "#00ffaf", 50: "#00ffd7", 51: "#00ffff", 52: "#5f0000", 53: "#5f005f", 54: "#5f0087", 55: "#5f00af", 56: "#5f00d7", 57: "#5f00ff", 58: "#5f5f00", 59: "#5f5f5f", 60: "#5f5f87", 61: "#5f5faf", 62: "#5f5fd7", 63: "#5f5fff", 64: "#5f8700"})
  52       call extend(s:cterm_color, {65: "#5f875f", 66: "#5f8787", 67: "#5f87af", 68: "#5f87d7", 69: "#5f87ff", 70: "#5faf00", 71: "#5faf5f", 72: "#5faf87", 73: "#5fafaf", 74: "#5fafd7", 75: "#5fafff", 76: "#5fd700", 77: "#5fd75f", 78: "#5fd787", 79: "#5fd7af", 80: "#5fd7d7", 81: "#5fd7ff", 82: "#5fff00", 83: "#5fff5f", 84: "#5fff87", 85: "#5fffaf", 86: "#5fffd7", 87: "#5fffff", 88: "#870000", 89: "#87005f", 90: "#870087", 91: "#8700af", 92: "#8700d7", 93: "#8700ff", 94: "#875f00", 95: "#875f5f", 96: "#875f87", 97: "#875faf", 98: "#875fd7", 99: "#875fff", 100: "#878700", 101: "#87875f", 102: "#878787", 103: "#8787af", 104: "#8787d7", 105: "#8787ff", 106: "#87af00", 107: "#87af5f", 108: "#87af87", 109: "#87afaf", 110: "#87afd7", 111: "#87afff", 112: "#87d700"})
  53       call extend(s:cterm_color, {113: "#87d75f", 114: "#87d787", 115: "#87d7af", 116: "#87d7d7", 117: "#87d7ff", 118: "#87ff00", 119: "#87ff5f", 120: "#87ff87", 121: "#87ffaf", 122: "#87ffd7", 123: "#87ffff", 124: "#af0000", 125: "#af005f", 126: "#af0087", 127: "#af00af", 128: "#af00d7", 129: "#af00ff", 130: "#af5f00", 131: "#af5f5f", 132: "#af5f87", 133: "#af5faf", 134: "#af5fd7", 135: "#af5fff", 136: "#af8700", 137: "#af875f", 138: "#af8787", 139: "#af87af", 140: "#af87d7", 141: "#af87ff", 142: "#afaf00", 143: "#afaf5f", 144: "#afaf87", 145: "#afafaf", 146: "#afafd7", 147: "#afafff", 148: "#afd700", 149: "#afd75f", 150: "#afd787", 151: "#afd7af", 152: "#afd7d7", 153: "#afd7ff", 154: "#afff00", 155: "#afff5f", 156: "#afff87", 157: "#afffaf", 158: "#afffd7"})
  54       call extend(s:cterm_color, {159: "#afffff", 160: "#d70000", 161: "#d7005f", 162: "#d70087", 163: "#d700af", 164: "#d700d7", 165: "#d700ff", 166: "#d75f00", 167: "#d75f5f", 168: "#d75f87", 169: "#d75faf", 170: "#d75fd7", 171: "#d75fff", 172: "#d78700", 173: "#d7875f", 174: "#d78787", 175: "#d787af", 176: "#d787d7", 177: "#d787ff", 178: "#d7af00", 179: "#d7af5f", 180: "#d7af87", 181: "#d7afaf", 182: "#d7afd7", 183: "#d7afff", 184: "#d7d700", 185: "#d7d75f", 186: "#d7d787", 187: "#d7d7af", 188: "#d7d7d7", 189: "#d7d7ff", 190: "#d7ff00", 191: "#d7ff5f", 192: "#d7ff87", 193: "#d7ffaf", 194: "#d7ffd7", 195: "#d7ffff", 196: "#ff0000", 197: "#ff005f", 198: "#ff0087", 199: "#ff00af", 200: "#ff00d7", 201: "#ff00ff", 202: "#ff5f00", 203: "#ff5f5f", 204: "#ff5f87"})
  55       call extend(s:cterm_color, {205: "#ff5faf", 206: "#ff5fd7", 207: "#ff5fff", 208: "#ff8700", 209: "#ff875f", 210: "#ff8787", 211: "#ff87af", 212: "#ff87d7", 213: "#ff87ff", 214: "#ffaf00", 215: "#ffaf5f", 216: "#ffaf87", 217: "#ffafaf", 218: "#ffafd7", 219: "#ffafff", 220: "#ffd700", 221: "#ffd75f", 222: "#ffd787", 223: "#ffd7af", 224: "#ffd7d7", 225: "#ffd7ff", 226: "#ffff00", 227: "#ffff5f", 228: "#ffff87", 229: "#ffffaf", 230: "#ffffd7", 231: "#ffffff", 232: "#080808", 233: "#121212", 234: "#1c1c1c", 235: "#262626", 236: "#303030", 237: "#3a3a3a", 238: "#444444", 239: "#4e4e4e", 240: "#585858", 241: "#626262", 242: "#6c6c6c", 243: "#767676", 244: "#808080", 245: "#8a8a8a", 246: "#949494", 247: "#9e9e9e", 248: "#a8a8a8", 249: "#b2b2b2", 250: "#bcbcbc", 251: "#c6c6c6", 252: "#d0d0d0", 253: "#dadada", 254: "#e4e4e4", 255: "#eeeeee"})
  56     endif
  57   endif
  58 endif
  59
  60 " Return good color specification: in GUI no transformation is done, in
  61 " terminal return RGB values of known colors and empty string for unknown
  62 if s:whatterm == "gui"
  63   function! s:HtmlColor(color)
  64     return a:color
  65   endfun
  66 else
  67   function! s:HtmlColor(color)
  68     if has_key(s:cterm_color, a:color)
  69       return s:cterm_color[a:color]
  70     else
  71       return ""
  72     endif
  73   endfun
  74 endif
  75
  76 if !s:settings.use_css
  77   " Return opening HTML tag for given highlight id
  78   function! s:HtmlOpening(id)
  79     let a = ""
  80     if synIDattr(a:id, "inverse")
  81       " For inverse, we always must set both colors (and exchange them)
  82       let x = s:HtmlColor(synIDattr(a:id, "fg#", s:whatterm))
  83       let a = a . '<span style="background-color: ' . ( x != "" ? x : s:fgc ) . '">'
  84       let x = s:HtmlColor(synIDattr(a:id, "bg#", s:whatterm))
  85       let a = a . '<font color="' . ( x != "" ? x : s:bgc ) . '">'
  86     else
  87       let x = s:HtmlColor(synIDattr(a:id, "bg#", s:whatterm))
  88       if x != "" | let a = a . '<span style="background-color: ' . x . '">' | endif
  89       let x = s:HtmlColor(synIDattr(a:id, "fg#", s:whatterm))
  90       if x != "" | let a = a . '<font color="' . x . '">' | endif
  91     endif
  92     if synIDattr(a:id, "bold") | let a = a . "<b>" | endif
  93     if synIDattr(a:id, "italic") | let a = a . "<i>" | endif
  94     if synIDattr(a:id, "underline") | let a = a . "<u>" | endif
  95     return a
  96   endfun
  97
  98   " Return closing HTML tag for given highlight id
  99   function! s:HtmlClosing(id)
 100     let a = ""
 101     if synIDattr(a:id, "underline") | let a = a . "</u>" | endif
 102     if synIDattr(a:id, "italic") | let a = a . "</i>" | endif
 103     if synIDattr(a:id, "bold") | let a = a . "</b>" | endif
 104     if synIDattr(a:id, "inverse")
 105       let a = a . '</font></span>'
 106     else
 107       let x = s:HtmlColor(synIDattr(a:id, "fg#", s:whatterm))
 108       if x != "" | let a = a . '</font>' | endif
 109       let x = s:HtmlColor(synIDattr(a:id, "bg#", s:whatterm))
 110       if x != "" | let a = a . '</span>' | endif
 111     endif
 112     return a
 113   endfun
 114 endif
 115
 116 " Return HTML valid characters enclosed in a span of class style_name with
 117 " unprintable characters expanded and double spaces replaced as necessary.
 118 function! s:HtmlFormat(text, style_name, diff_style_name)
 119   " Replace unprintable characters
 120   let formatted = strtrans(a:text)
 121
 122   " separate the two classes by a space to apply them both if there is a diff
 123   " style name
 124   let l:style_name = a:style_name . (a:diff_style_name == '' ? '' : ' ') . a:diff_style_name
 125
 126   " Replace the reserved html characters
 127   let formatted = substitute(substitute(substitute(substitute(substitute(formatted, '&', '\&amp;', 'g'), '<', '\&lt;', 'g'), '>', '\&gt;', 'g'), '"', '\&quot;', 'g'), "\x0c", '<hr class="PAGE-BREAK">', 'g')
 128
 129   " Replace double spaces, leading spaces, and trailing spaces if needed
 130   if ' ' != s:HtmlSpace
 131     let formatted = substitute(formatted, '  ', s:HtmlSpace . s:HtmlSpace, 'g')
 132     let formatted = substitute(formatted, '^ ', s:HtmlSpace, 'g')
 133     let formatted = substitute(formatted, ' \+$', s:HtmlSpace, 'g')
 134   endif
 135
 136   " Enclose in a span of class style_name
 137   let formatted = '<span class="' . l:style_name . '">' . formatted . '</span>'
 138
 139   " Add the class to class list if it's not there yet.
 140   " Add normal groups to the beginning so diff groups can override them.
 141   let s:id = hlID(a:style_name)
 142   if index(s:idlist, s:id ) == -1
 143     if a:style_name =~ 'Diff\%(Add\|Change\|Delete\|Text\)'
 144       call add(s:idlist, s:id)
 145     else
 146       call insert(s:idlist, s:id)
 147     endif
 148   endif
 149
 150   " Add the diff highlight class to class list if used and it's not there yet.
 151   " Add diff groups to the end so they override the other highlighting.
 152   if a:diff_style_name != ""
 153     let s:diff_id = hlID(a:diff_style_name)
 154     if index(s:idlist, s:diff_id) == -1
 155       call add(s:idlist, s:diff_id)
 156     endif
 157   endif
 158
 159   return formatted
 160 endfun
 161
 162 " Return CSS style describing given highlight id (can be empty)
 163 function! s:CSS1(id)
 164   let a = ""
 165   if synIDattr(a:id, "inverse")
 166     " For inverse, we always must set both colors (and exchange them)
 167     let x = s:HtmlColor(synIDattr(a:id, "bg#", s:whatterm))
 168     let a = a . "color: " . ( x != "" ? x : s:bgc ) . "; "
 169     let x = s:HtmlColor(synIDattr(a:id, "fg#", s:whatterm))
 170     let a = a . "background-color: " . ( x != "" ? x : s:fgc ) . "; "
 171   else
 172     let x = s:HtmlColor(synIDattr(a:id, "fg#", s:whatterm))
 173     if x != "" | let a = a . "color: " . x . "; " | endif
 174     let x = s:HtmlColor(synIDattr(a:id, "bg#", s:whatterm))
 175     if x != "" | let a = a . "background-color: " . x . "; " | endif
 176   endif
 177   if synIDattr(a:id, "bold") | let a = a . "font-weight: bold; " | endif
 178   if synIDattr(a:id, "italic") | let a = a . "font-style: italic; " | endif
 179   if synIDattr(a:id, "underline") | let a = a . "text-decoration: underline; " | endif
 180   return a
 181 endfun
 182
 183 if s:settings.dynamic_folds
 184   " compares two folds as stored in our list of folds
 185   " A fold is "less" than another if it starts at an earlier line number,
 186   " or ends at a later line number, ties broken by fold level
 187   function! s:FoldCompare(f1, f2)
 188     if a:f1.firstline != a:f2.firstline
 189       " put it before if it starts earlier
 190       return a:f1.firstline - a:f2.firstline
 191     elseif a:f1.lastline != a:f2.lastline
 192       " put it before if it ends later
 193       return a:f2.lastline - a:f1.lastline
 194     else
 195       " if folds begin and end on the same lines, put lowest fold level first
 196       return a:f1.level - a:f2.level
 197     endif
 198   endfunction
 199
 200 endif
 201
 202
 203 " Set some options to make it work faster.
 204 " Don't report changes for :substitute, there will be many of them.
 205 " Don't change other windows; turn off scroll bind temporarily
 206 let s:old_title = &title
 207 let s:old_icon = &icon
 208 let s:old_et = &l:et
 209 let s:old_bind = &l:scrollbind
 210 let s:old_report = &report
 211 let s:old_search = @/
 212 let s:old_more = &more
 213 set notitle noicon
 214 setlocal et
 215 set nomore
 216 set report=1000000
 217 setlocal noscrollbind
 218
 219 if exists(':ownsyntax') && exists('w:current_syntax')
 220   let s:current_syntax = w:current_syntax
 221 elseif exists('b:current_syntax')
 222   let s:current_syntax = b:current_syntax
 223 else
 224   let s:current_syntax = 'none'
 225 endif
 226
 227 if s:current_syntax == ''
 228   let s:current_syntax = 'none'
 229 endif
 230
 231 " Split window to create a buffer with the HTML file.
 232 let s:orgbufnr = winbufnr(0)
 233 let s:origwin_stl = &l:stl
 234 if expand("%") == ""
 235   exec 'new Untitled.'.(s:settings.use_xhtml ? 'x' : '').'html'
 236 else
 237   exec 'new %.'.(s:settings.use_xhtml ? 'x' : '').'html'
 238 endif
 239
 240 " Resize the new window to very small in order to make it draw faster
 241 let s:old_winheight = winheight(0)
 242 let s:old_winfixheight = &l:winfixheight
 243 if s:old_winheight > 2
 244   resize 1 " leave enough room to view one line at a time
 245   norm! G
 246   norm! zt
 247 endif
 248 setlocal winfixheight
 249
 250 let s:newwin_stl = &l:stl
 251
 252 " on the new window, set the least time-consuming fold method
 253 let s:old_fdm = &foldmethod
 254 let s:old_fen = &foldenable
 255 setlocal foldmethod=manual
 256 setlocal nofoldenable
 257
 258 let s:newwin = winnr()
 259 let s:orgwin = bufwinnr(s:orgbufnr)
 260
 261 setlocal modifiable
 262 %d
 263 let s:old_paste = &paste
 264 set paste
 265 let s:old_magic = &magic
 266 set magic
 267
 268 let s:lines = []
 269
 270 if s:settings.use_xhtml
 271   if s:settings.encoding != ""
 272     call add(s:lines, "<?xml version=\"1.0\" encoding=\"" . s:settings.encoding . "\"?>")
 273   else
 274     call add(s:lines, "<?xml version=\"1.0\"?>")
 275   endif
 276   let s:tag_close = ' />'
 277 else
 278   let s:tag_close = '>'
 279 endif
 280
 281 let s:HtmlSpace = ' '
 282 let s:LeadingSpace = ' '
 283 let s:HtmlEndline = ''
 284 if s:settings.no_pre
 285   let s:HtmlEndline = '<br' . s:tag_close
 286   let s:LeadingSpace = '&nbsp;'
 287   let s:HtmlSpace = '\' . s:LeadingSpace
 288 endif
 289
 290 " HTML header, with the title and generator ;-). Left free space for the CSS,
 291 " to be filled at the end.
 292 call extend(s:lines, [
 293       \ "<html>",
 294       \ "<head>"])
 295 " include encoding as close to the top as possible, but only if not already
 296 " contained in XML information (to avoid haggling over content type)
 297 if s:settings.encoding != "" && !s:settings.use_xhtml
 298   call add(s:lines, "<meta http-equiv=\"content-type\" content=\"text/html; charset=" . s:settings.encoding . '"' . s:tag_close)
 299 endif
 300 call extend(s:lines, [
 301       \ ("<title>".expand("%:p:~")."</title>"),
 302       \ ("<meta name=\"Generator\" content=\"Vim/".v:version/100.".".v:version%100.'"'.s:tag_close),
 303       \ ("<meta name=\"plugin-version\" content=\"".g:loaded_2html_plugin.'"'.s:tag_close)
 304       \ ])
 305 call add(s:lines, '<meta name="syntax" content="'.s:current_syntax.'"'.s:tag_close)
 306 call add(s:lines, '<meta name="settings" content="'.
 307       \ join(filter(keys(s:settings),'s:settings[v:val]'),',').
 308       \ '"'.s:tag_close)
 309
 310 if s:settings.use_css
 311   if s:settings.dynamic_folds
 312     if s:settings.hover_unfold
 313       " if we are doing hover_unfold, use css 2 with css 1 fallback for IE6
 314       call extend(s:lines, [
 315             \ "<style type=\"text/css\">",
 316             \ s:settings.use_xhtml ? "" : "<!--",
 317             \ ".FoldColumn { text-decoration: none; white-space: pre; }",
 318             \ "",
 319             \ "body * { margin: 0; padding: 0; }", "",
 320             \ ".open-fold   > .Folded { display: none;  }",
 321             \ ".open-fold   > .fulltext { display: inline; }",
 322             \ ".closed-fold > .fulltext { display: none;  }",
 323             \ ".closed-fold > .Folded { display: inline; }",
 324             \ "",
 325             \ ".open-fold   > .toggle-open   { display: none;   }",
 326             \ ".open-fold   > .toggle-closed { display: inline; }",
 327             \ ".closed-fold > .toggle-open   { display: inline; }",
 328             \ ".closed-fold > .toggle-closed { display: none;   }",
 329             \ "", "",
 330             \ '/* opening a fold while hovering won''t be supported by IE6 and other',
 331             \ "similar browsers, but it should fail gracefully. */",
 332             \ ".closed-fold:hover > .fulltext { display: inline; }",
 333             \ ".closed-fold:hover > .toggle-filler { display: none; }",
 334             \ ".closed-fold:hover > .Folded { display: none; }",
 335             \ s:settings.use_xhtml ? "" : '-->',
 336             \ '</style>'])
 337       " TODO: IE7 doesn't *actually* support XHTML, maybe we should remove this.
 338       " But if it's served up as tag soup, maybe the following will work, so
 339       " leave it in for now.
 340       call extend(s:lines, [
 341             \ "<!--[if lt IE 7]><style type=\"text/css\">",
 342             \ ".open-fold   .Folded      { display: none; }",
 343             \ ".open-fold   .fulltext      { display: inline; }",
 344             \ ".open-fold   .toggle-open   { display: none; }",
 345             \ ".closed-fold .toggle-closed { display: inline; }",
 346             \ "",
 347             \ ".closed-fold .fulltext      { display: none; }",
 348             \ ".closed-fold .Folded      { display: inline; }",
 349             \ ".closed-fold .toggle-open   { display: inline; }",
 350             \ ".closed-fold .toggle-closed { display: none; }",
 351             \ "</style>",
 352             \ "<![endif]-->",
 353             \])
 354     else
 355       " if we aren't doing hover_unfold, use CSS 1 only
 356       call extend(s:lines, [
 357             \ "<style type=\"text/css\">",
 358             \ s:settings.use_xhtml ? "" :"<!--",
 359             \ ".FoldColumn { text-decoration: none; white-space: pre; }",
 360             \ ".open-fold   .Folded      { display: none; }",
 361             \ ".open-fold   .fulltext      { display: inline; }",
 362             \ ".open-fold   .toggle-open   { display: none; }",
 363             \ ".closed-fold .toggle-closed { display: inline; }",
 364             \ "",
 365             \ ".closed-fold .fulltext      { display: none; }",
 366             \ ".closed-fold .Folded      { display: inline; }",
 367             \ ".closed-fold .toggle-open   { display: inline; }",
 368             \ ".closed-fold .toggle-closed { display: none; }",
 369             \ s:settings.use_xhtml ? "" : '-->',
 370             \ '</style>'
 371             \])
 372     endif
 373   else
 374     " if we aren't doing any dynamic folding, no need for any special rules
 375     call extend(s:lines, [
 376           \ "<style type=\"text/css\">",
 377           \ s:settings.use_xhtml ? "" : "<!--",
 378           \ s:settings.use_xhtml ? "" : '-->',
 379           \ "</style>",
 380           \])
 381   endif
 382 endif
 383
 384 " insert javascript to toggle folds open and closed
 385 if s:settings.dynamic_folds
 386   call extend(s:lines, [
 387         \ "",
 388         \ "<script type='text/javascript'>",
 389         \ s:settings.use_xhtml ? '//<![CDATA[' : "<!--",
 390         \ "function toggleFold(objID)",
 391         \ "{",
 392         \ "  var fold;",
 393         \ "  fold = document.getElementById(objID);",
 394         \ "  if(fold.className == 'closed-fold')",
 395         \ "  {",
 396         \ "    fold.className = 'open-fold';",
 397         \ "  }",
 398         \ "  else if (fold.className == 'open-fold')",
 399         \ "  {",
 400         \ "    fold.className = 'closed-fold';",
 401         \ "  }",
 402         \ "}",
 403         \ s:settings.use_xhtml ? '//]]>' : '-->',
 404         \ "</script>"
 405         \])
 406 endif
 407
 408 if s:settings.no_pre
 409   call extend(s:lines, ["</head>", "<body>"])
 410 else
 411   call extend(s:lines, ["</head>", "<body>", "<pre>"])
 412 endif
 413
 414 exe s:orgwin . "wincmd w"
 415
 416 " List of all id's
 417 let s:idlist = []
 418
 419 " set up progress bar in the status line
 420 if !s:settings.no_progress
 421   " ProgressBar Indicator
 422   let s:progressbar={}
 423
 424   " Progessbar specific functions
 425   func! s:ProgressBar(title, max_value, winnr)
 426     let pgb=copy(s:progressbar)
 427     let pgb.title = a:title.' '
 428     let pgb.max_value = a:max_value
 429     let pgb.winnr = a:winnr
 430     let pgb.cur_value = 0
 431     let pgb.items = { 'title'   : { 'color' : 'Statusline' },
 432           \'bar'     : { 'color' : 'Statusline' , 'fillcolor' : 'DiffDelete' , 'bg' : 'Statusline' } ,
 433           \'counter' : { 'color' : 'Statusline' } }
 434     let pgb.last_value = 0
 435     let pgb.needs_redraw = 0
 436     " Note that you must use len(split) instead of len() if you want to use
 437     " unicode in title.
 438     "
 439     " Subtract 3 for spacing around the title.
 440     " Subtract 4 for the percentage display.
 441     " Subtract 2 for spacing before this.
 442     " Subtract 2 more for the '|' on either side of the progress bar
 443     let pgb.subtractedlen=len(split(pgb.title, '\zs'))+3+4+2+2
 444     let pgb.max_len = 0
 445     set laststatus=2
 446     return pgb
 447   endfun
 448
 449   " Function: progressbar.calculate_ticks() {{{1
 450   func! s:progressbar.calculate_ticks(pb_len)
 451     if a:pb_len<=0
 452       let pb_len = 100
 453     else
 454       let pb_len = a:pb_len
 455     endif
 456     let self.progress_ticks = map(range(pb_len+1), "v:val * self.max_value / pb_len")
 457   endfun
 458
 459   "Function: progressbar.paint()
 460   func! s:progressbar.paint()
 461     " Recalculate widths.
 462     let max_len = winwidth(self.winnr)
 463     let pb_len = 0
 464     " always true on first call because of initial value of self.max_len
 465     if max_len != self.max_len
 466       let self.max_len = max_len
 467
 468       " Progressbar length
 469       let pb_len = max_len - self.subtractedlen
 470
 471       call self.calculate_ticks(pb_len)
 472
 473       let self.needs_redraw = 1
 474       let cur_value = 0
 475       let self.pb_len = pb_len
 476     else
 477       " start searching at the last found index to make the search for the
 478       " appropriate tick value normally take 0 or 1 comparisons
 479       let cur_value = self.last_value
 480       let pb_len = self.pb_len
 481     endif
 482
 483     let cur_val_max = pb_len > 0 ? pb_len : 100
 484
 485     " find the current progress bar position based on precalculated thresholds
 486     while cur_value < cur_val_max && self.cur_value > self.progress_ticks[cur_value]
 487       let cur_value += 1
 488     endwhile
 489
 490     " update progress bar
 491     if self.last_value != cur_value || self.needs_redraw || self.cur_value == self.max_value
 492       let self.needs_redraw = 1
 493       let self.last_value = cur_value
 494
 495       let t_color  = self.items.title.color
 496       let b_fcolor = self.items.bar.fillcolor
 497       let b_color  = self.items.bar.color
 498       let c_color  = self.items.counter.color
 499
 500       let stl =  "%#".t_color."#%-( ".self.title." %)".
 501             \"%#".b_color."#".
 502             \(pb_len>0 ?
 503             \   ('|%#'.b_fcolor."#%-(".repeat(" ",cur_value)."%)".
 504             \    '%#'.b_color."#".repeat(" ",pb_len-cur_value)."|"):
 505             \   ('')).
 506             \"%=%#".c_color."#%( ".printf("%3.d ",100*self.cur_value/self.max_value)."%% %)"
 507       call setwinvar(self.winnr, '&stl', stl)
 508     endif
 509   endfun
 510
 511   func! s:progressbar.incr( ... )
 512     let self.cur_value += (a:0 ? a:1 : 1)
 513     " if we were making a general-purpose progress bar, we'd need to limit to a
 514     " lower limit as well, but since we always increment with a positive value
 515     " in this script, we only need limit the upper value
 516     let self.cur_value = (self.cur_value > self.max_value ? self.max_value : self.cur_value)
 517     call self.paint()
 518   endfun
 519   " }}}
 520   if s:settings.dynamic_folds
 521     " to process folds we make two passes through each line
 522     let s:pgb = s:ProgressBar("Processing folds:", line('$')*2, s:orgwin)
 523   endif
 524 endif
 525
 526 " First do some preprocessing for dynamic folding. Do this for the entire file
 527 " so we don't accidentally start within a closed fold or something.
 528 let s:allfolds = []
 529
 530 if s:settings.dynamic_folds
 531   let s:lnum = 1
 532   let s:end = line('$')
 533   " save the fold text and set it to the default so we can find fold levels
 534   let s:foldtext_save = &foldtext
 535   setlocal foldtext&
 536
 537   " we will set the foldcolumn in the html to the greater of the maximum fold
 538   " level and the current foldcolumn setting
 539   let s:foldcolumn = &foldcolumn
 540
 541   " get all info needed to describe currently closed folds
 542   while s:lnum <= s:end
 543     if foldclosed(s:lnum) == s:lnum
 544       " default fold text has '+-' and then a number of dashes equal to fold
 545       " level, so subtract 2 from index of first non-dash after the dashes
 546       " in order to get the fold level of the current fold
 547       let s:level = match(foldtextresult(s:lnum), '+-*\zs[^-]') - 2
 548       if s:level+1 > s:foldcolumn
 549         let s:foldcolumn = s:level+1
 550       endif
 551       " store fold info for later use
 552       let s:newfold = {'firstline': s:lnum, 'lastline': foldclosedend(s:lnum), 'level': s:level,'type': "closed-fold"}
 553       call add(s:allfolds, s:newfold)
 554       " open the fold so we can find any contained folds
 555       execute s:lnum."foldopen"
 556     else
 557       if !s:settings.no_progress
 558         call s:pgb.incr()
 559         if s:pgb.needs_redraw
 560           redrawstatus
 561           let s:pgb.needs_redraw = 0
 562         endif
 563       endif
 564       let s:lnum = s:lnum + 1
 565     endif
 566   endwhile
 567
 568   " close all folds to get info for originally open folds
 569   silent! %foldclose!
 570   let s:lnum = 1
 571
 572   " the originally open folds will be all folds we encounter that aren't
 573   " already in the list of closed folds
 574   while s:lnum <= s:end
 575     if foldclosed(s:lnum) == s:lnum
 576       " default fold text has '+-' and then a number of dashes equal to fold
 577       " level, so subtract 2 from index of first non-dash after the dashes
 578       " in order to get the fold level of the current fold
 579       let s:level = match(foldtextresult(s:lnum), '+-*\zs[^-]') - 2
 580       if s:level+1 > s:foldcolumn
 581         let s:foldcolumn = s:level+1
 582       endif
 583       let s:newfold = {'firstline': s:lnum, 'lastline': foldclosedend(s:lnum), 'level': s:level,'type': "closed-fold"}
 584       " only add the fold if we don't already have it
 585       if empty(s:allfolds) || index(s:allfolds, s:newfold) == -1
 586         let s:newfold.type = "open-fold"
 587         call add(s:allfolds, s:newfold)
 588       endif
 589       " open the fold so we can find any contained folds
 590       execute s:lnum."foldopen"
 591     else
 592       if !s:settings.no_progress
 593         call s:pgb.incr()
 594         if s:pgb.needs_redraw
 595           redrawstatus
 596           let s:pgb.needs_redraw = 0
 597         endif
 598       endif
 599       let s:lnum = s:lnum + 1
 600     endif
 601   endwhile
 602
 603   " sort the folds so that we only ever need to look at the first item in the
 604   " list of folds
 605   call sort(s:allfolds, "s:FoldCompare")
 606
 607   let &l:foldtext = s:foldtext_save
 608   unlet s:foldtext_save
 609
 610   " close all folds again so we can get the fold text as we go
 611   silent! %foldclose!
 612 endif
 613
 614 " Now loop over all lines in the original text to convert to html.
 615 " Use html_start_line and html_end_line if they are set.
 616 if exists("g:html_start_line")
 617   let s:lnum = html_start_line
 618   if s:lnum < 1 || s:lnum > line("$")
 619     let s:lnum = 1
 620   endif
 621 else
 622   let s:lnum = 1
 623 endif
 624 if exists("g:html_end_line")
 625   let s:end = html_end_line
 626   if s:end < s:lnum || s:end > line("$")
 627     let s:end = line("$")
 628   endif
 629 else
 630   let s:end = line("$")
 631 endif
 632
 633 " stack to keep track of all the folds containing the current line
 634 let s:foldstack = []
 635
 636 if !s:settings.no_progress
 637   let s:pgb = s:ProgressBar("Processing lines:", s:end - s:lnum + 1, s:orgwin)
 638 endif
 639
 640 if s:settings.number_lines
 641   let s:margin = strlen(s:end) + 1
 642 else
 643   let s:margin = 0
 644 endif
 645
 646 if has('folding') && !s:settings.ignore_folding
 647   let s:foldfillchar = &fillchars[matchend(&fillchars, 'fold:')]
 648   if s:foldfillchar == ''
 649     let s:foldfillchar = '-'
 650   endif
 651 endif
 652 let s:difffillchar = &fillchars[matchend(&fillchars, 'diff:')]
 653 if s:difffillchar == ''
 654   let s:difffillchar = '-'
 655 endif
 656
 657 let s:foldId = 0
 658
 659 while s:lnum <= s:end
 660
 661   " If there are filler lines for diff mode, show these above the line.
 662   let s:filler = diff_filler(s:lnum)
 663   if s:filler > 0
 664     let s:n = s:filler
 665     while s:n > 0
 666       let s:new = repeat(s:difffillchar, 3)
 667
 668       if s:n > 2 && s:n < s:filler && !s:settings.whole_filler
 669         let s:new = s:new . " " . s:filler . " inserted lines "
 670         let s:n = 2
 671       endif
 672
 673       if !s:settings.no_pre
 674         " HTML line wrapping is off--go ahead and fill to the margin
 675         let s:new = s:new . repeat(s:difffillchar, &columns - strlen(s:new) - s:margin)
 676       else
 677         let s:new = s:new . repeat(s:difffillchar, 3)
 678       endif
 679
 680       let s:new = s:HtmlFormat(s:new, "DiffDelete", "")
 681       if s:settings.number_lines
 682         " Indent if line numbering is on; must be after escaping.
 683         let s:new = repeat(s:LeadingSpace, s:margin) . s:new
 684       endif
 685       call add(s:lines, s:new.s:HtmlEndline)
 686
 687       let s:n = s:n - 1
 688     endwhile
 689     unlet s:n
 690   endif
 691   unlet s:filler
 692
 693   " Start the line with the line number.
 694   if s:settings.number_lines
 695     let s:numcol = repeat(' ', s:margin - 1 - strlen(s:lnum)) . s:lnum . ' '
 696   else
 697     let s:numcol = ""
 698   endif
 699
 700   let s:new = ""
 701
 702   if has('folding') && !s:settings.ignore_folding && foldclosed(s:lnum) > -1 && !s:settings.dynamic_folds
 703     "
 704     " This is the beginning of a folded block (with no dynamic folding)
 705     "
 706     let s:new = s:numcol . foldtextresult(s:lnum)
 707     if !s:settings.no_pre
 708       " HTML line wrapping is off--go ahead and fill to the margin
 709       let s:new = s:new . repeat(s:foldfillchar, &columns - strlen(s:new))
 710     endif
 711
 712     let s:new = s:HtmlFormat(s:new, "Folded", "")
 713
 714     " Skip to the end of the fold
 715     let s:new_lnum = foldclosedend(s:lnum)
 716
 717     if !s:settings.no_progress
 718       call s:pgb.incr(s:new_lnum - s:lnum)
 719     endif
 720
 721     let s:lnum = s:new_lnum
 722
 723   else
 724     "
 725     " A line that is not folded, or doing dynamic folding.
 726     "
 727     let s:line = getline(s:lnum)
 728     let s:len = strlen(s:line)
 729
 730     if s:settings.dynamic_folds
 731       " First insert a closing for any open folds that end on this line
 732       while !empty(s:foldstack) && get(s:foldstack,0).lastline == s:lnum-1
 733         let s:new = s:new."</span></span>"
 734         call remove(s:foldstack, 0)
 735       endwhile
 736
 737       " Now insert an opening any new folds that start on this line
 738       let s:firstfold = 1
 739       while !empty(s:allfolds) && get(s:allfolds,0).firstline == s:lnum
 740         let s:foldId = s:foldId + 1
 741         let s:new .= "<span id='"
 742         let s:new .= (exists('g:html_diff_win_num') ? "win".g:html_diff_win_num : "")
 743         let s:new .= "fold".s:foldId."' class='".s:allfolds[0].type."'>"
 744
 745
 746         " Unless disabled, add a fold column for the opening line of a fold.
 747         "
 748         " Note that dynamic folds require using css so we just use css to take
 749         " care of the leading spaces rather than using &nbsp; in the case of
 750         " html_no_pre to make it easier
 751         if !s:settings.no_foldcolumn
 752           " add fold column that can open the new fold
 753           if s:allfolds[0].level > 1 && s:firstfold
 754             let s:new = s:new . "<a class='toggle-open FoldColumn' href='javascript:toggleFold(\"fold".s:foldstack[0].id."\")'>"
 755             let s:new = s:new . repeat('|', s:allfolds[0].level - 1) . "</a>"
 756           endif
 757           let s:new = s:new . "<a class='toggle-open FoldColumn' href='javascript:toggleFold(\"fold".s:foldId."\")'>+</a>"
 758           let s:new = s:new . "<a class='toggle-open "
 759           " If this is not the last fold we're opening on this line, we need
 760           " to keep the filler spaces hidden if the fold is opened by mouse
 761           " hover. If it is the last fold to open in the line, we shouldn't hide
 762           " them, so don't apply the toggle-filler class.
 763           if get(s:allfolds, 1, {'firstline': 0}).firstline == s:lnum
 764             let s:new = s:new . "toggle-filler "
 765           endif
 766           let s:new = s:new . "FoldColumn' href='javascript:toggleFold(\"fold".s:foldId."\")'>"
 767           let s:new = s:new . repeat(" ", s:foldcolumn - s:allfolds[0].level) . "</a>"
 768
 769           " add fold column that can close the new fold
 770           let s:new = s:new . "<a class='toggle-closed FoldColumn' href='javascript:toggleFold(\"fold".s:foldId."\")'>"
 771           if s:firstfold
 772             let s:new = s:new . repeat('|', s:allfolds[0].level - 1)
 773           endif
 774           let s:new = s:new . "-"
 775           " only add spaces if we aren't opening another fold on the same line
 776           if get(s:allfolds, 1, {'firstline': 0}).firstline != s:lnum
 777             let s:new = s:new . repeat(" ", s:foldcolumn - s:allfolds[0].level)
 778           endif
 779           let s:new = s:new . "</a>"
 780           let s:firstfold = 0
 781         endif
 782
 783         " add fold text, moving the span ending to the next line so collapsing
 784         " of folds works correctly
 785         let s:new = s:new . substitute(s:HtmlFormat(s:numcol . foldtextresult(s:lnum), "Folded", ""), '</span>', s:HtmlEndline.'\n\0', '')
 786         let s:new = s:new . "<span class='fulltext'>"
 787
 788         " open the fold now that we have the fold text to allow retrieval of
 789         " fold text for subsequent folds
 790         execute s:lnum."foldopen"
 791         call insert(s:foldstack, remove(s:allfolds,0))
 792         let s:foldstack[0].id = s:foldId
 793       endwhile
 794
 795       " Unless disabled, add a fold column for other lines.
 796       "
 797       " Note that dynamic folds require using css so we just use css to take
 798       " care of the leading spaces rather than using &nbsp; in the case of
 799       " html_no_pre to make it easier
 800       if !s:settings.no_foldcolumn
 801         if empty(s:foldstack)
 802           " add the empty foldcolumn for unfolded lines if there is a fold
 803           " column at all
 804           if s:foldcolumn > 0
 805             let s:new = s:new . s:HtmlFormat(repeat(' ', s:foldcolumn), "FoldColumn", "")
 806           endif
 807         else
 808           " add the fold column for folds not on the opening line
 809           if get(s:foldstack, 0).firstline < s:lnum
 810             let s:new = s:new . "<a class='FoldColumn' href='javascript:toggleFold(\"fold".s:foldstack[0].id."\")'>"
 811             let s:new = s:new . repeat('|', s:foldstack[0].level)
 812             let s:new = s:new . repeat(' ', s:foldcolumn - s:foldstack[0].level) . "</a>"
 813           endif
 814         endif
 815       endif
 816     endif
 817
 818     " Now continue with the unfolded line text
 819     if s:settings.number_lines
 820       " TODO: why not use the real highlight name here?
 821       let s:new = s:new . s:HtmlFormat(s:numcol, "lnr", "")
 822     endif
 823
 824     " Get the diff attribute, if any.
 825     let s:diffattr = diff_hlID(s:lnum, 1)
 826
 827     " initialize conceal info to act like not concealed, just in case
 828     let s:concealinfo = [0, '']
 829
 830     " Loop over each character in the line
 831     let s:col = 1
 832
 833     " most of the time we won't use the diff_id, initialize to zero
 834     let s:diff_id = 0
 835     let s:diff_id_name = ""
 836
 837     while s:col <= s:len || (s:col == 1 && s:diffattr)
 838       let s:startcol = s:col " The start column for processing text
 839       if !s:settings.ignore_conceal && has('conceal')
 840         let s:concealinfo = synconcealed(s:lnum, s:col)
 841       endif
 842       if !s:settings.ignore_conceal && s:concealinfo[0]
 843         let s:col = s:col + 1
 844         " Speed loop (it's small - that's the trick)
 845         " Go along till we find a change in the match sequence number (ending
 846         " the specific concealed region) or until there are no more concealed
 847         " characters.
 848         while s:col <= s:len && s:concealinfo == synconcealed(s:lnum, s:col) | let s:col = s:col + 1 | endwhile
 849       elseif s:diffattr
 850         let s:diff_id = diff_hlID(s:lnum, s:col)
 851         let s:id = synID(s:lnum, s:col, 1)
 852         let s:col = s:col + 1
 853         " Speed loop (it's small - that's the trick)
 854         " Go along till we find a change in hlID
 855         while s:col <= s:len && s:id == synID(s:lnum, s:col, 1)
 856               \   && s:diff_id == diff_hlID(s:lnum, s:col) |
 857               \     let s:col = s:col + 1 |
 858               \ endwhile
 859         if s:len < &columns && !s:settings.no_pre
 860           " Add spaces at the end of the raw text line to extend the changed
 861           " line to the full width.
 862           let s:line = s:line . repeat(' ', &columns - virtcol([s:lnum, s:len]) - s:margin)
 863           let s:len = &columns
 864         endif
 865       else
 866         let s:id = synID(s:lnum, s:col, 1)
 867         let s:col = s:col + 1
 868         " Speed loop (it's small - that's the trick)
 869         " Go along till we find a change in synID
 870         while s:col <= s:len && s:id == synID(s:lnum, s:col, 1) | let s:col = s:col + 1 | endwhile
 871       endif
 872
 873       if s:settings.ignore_conceal || !s:concealinfo[0]
 874         " Expand tabs
 875         let s:expandedtab = strpart(s:line, s:startcol - 1, s:col - s:startcol)
 876         let s:offset = 0
 877         let s:idx = stridx(s:expandedtab, "\t")
 878         while s:idx >= 0
 879           if has("multi_byte_encoding")
 880             if s:startcol + s:idx == 1
 881               let s:i = &ts
 882             else
 883               if s:idx == 0
 884                 let s:prevc = matchstr(s:line, '.\%' . (s:startcol + s:idx + s:offset) . 'c')
 885               else
 886                 let s:prevc = matchstr(s:expandedtab, '.\%' . (s:idx + 1) . 'c')
 887               endif
 888               let s:vcol = virtcol([s:lnum, s:startcol + s:idx + s:offset - len(s:prevc)])
 889               let s:i = &ts - (s:vcol % &ts)
 890             endif
 891             let s:offset -= s:i - 1
 892           else
 893             let s:i = &ts - ((s:idx + s:startcol - 1) % &ts)
 894           endif
 895           let s:expandedtab = substitute(s:expandedtab, '\t', repeat(' ', s:i), '')
 896           let s:idx = stridx(s:expandedtab, "\t")
 897         endwhile
 898
 899         " get the highlight group name to use
 900         let s:id = synIDtrans(s:id)
 901         let s:id_name = synIDattr(s:id, "name", s:whatterm)
 902         if s:diff_id
 903           let s:diff_id_name = synIDattr(s:diff_id, "name", s:whatterm)
 904         endif
 905       else
 906         " use Conceal highlighting for concealed text
 907         let s:id_name = 'Conceal'
 908         let s:expandedtab = s:concealinfo[1]
 909       endif
 910
 911       " Output the text with the same synID, with class set to {s:id_name},
 912       " unless it has been concealed completely.
 913       if strlen(s:expandedtab) > 0
 914         let s:new = s:new . s:HtmlFormat(s:expandedtab,  s:id_name, s:diff_id_name)
 915       endif
 916     endwhile
 917   endif
 918
 919   call extend(s:lines, split(s:new.s:HtmlEndline, '\n', 1))
 920   if !s:settings.no_progress && s:pgb.needs_redraw
 921     redrawstatus
 922     let s:pgb.needs_redraw = 0
 923   endif
 924   let s:lnum = s:lnum + 1
 925
 926   if !s:settings.no_progress
 927     call s:pgb.incr()
 928   endif
 929 endwhile
 930
 931 if s:settings.dynamic_folds
 932   " finish off any open folds
 933   while !empty(s:foldstack)
 934     let s:lines[-1].="</span></span>"
 935     call remove(s:foldstack, 0)
 936   endwhile
 937
 938   " add fold column to the style list if not already there
 939   let s:id = hlID('FoldColumn')
 940   if index(s:idlist, s:id) == -1
 941     call insert(s:idlist, s:id)
 942   endif
 943 endif
 944
 945 if s:settings.no_pre
 946   if !s:settings.use_css
 947     " Close off the font tag that encapsulates the whole <body>
 948     call extend(s:lines, ["</font>", "</body>", "</html>"])
 949   else
 950     call extend(s:lines, ["</body>", "</html>"])
 951   endif
 952 else
 953   call extend(s:lines, ["</pre>", "</body>", "</html>"])
 954 endif
 955
 956 exe s:newwin . "wincmd w"
 957 call setline(1, s:lines)
 958 unlet s:lines
 959
 960 " Now, when we finally know which, we define the colors and styles
 961 if s:settings.use_css
 962   1;/<style type="text/+1
 963 endif
 964
 965 " Find out the background and foreground color.
 966 let s:fgc = s:HtmlColor(synIDattr(hlID("Normal"), "fg#", s:whatterm))
 967 let s:bgc = s:HtmlColor(synIDattr(hlID("Normal"), "bg#", s:whatterm))
 968 if s:fgc == ""
 969   let s:fgc = ( &background == "dark" ? "#ffffff" : "#000000" )
 970 endif
 971 if s:bgc == ""
 972   let s:bgc = ( &background == "dark" ? "#000000" : "#ffffff" )
 973 endif
 974
 975 " Normal/global attributes
 976 " For Netscape 4, set <body> attributes too, though, strictly speaking, it's
 977 " incorrect.
 978 if s:settings.use_css
 979   if s:settings.no_pre
 980     execute "normal! A\nbody { color: " . s:fgc . "; background-color: " . s:bgc . "; font-family: ". s:htmlfont ."; }\e"
 981   else
 982     execute "normal! A\npre { font-family: ". s:htmlfont ."; color: " . s:fgc . "; background-color: " . s:bgc . "; }\e"
 983     yank
 984     put
 985     execute "normal! ^cwbody\e"
 986   endif
 987 else
 988   execute '%s:<body>:<body bgcolor="' . s:bgc . '" text="' . s:fgc . '">\r<font face="'. s:htmlfont .'">'
 989 endif
 990
 991 " Line numbering attributes
 992 if s:settings.number_lines
 993   if s:settings.use_css
 994     execute "normal! A\n.lnr { " . s:CSS1(hlID("LineNr")) . "}\e"
 995   else
 996     execute '%s+^<span class="lnr">\([^<]*\)</span>+' . s:HtmlOpening(hlID("LineNr")) . '\1' . s:HtmlClosing(hlID("LineNr")) . '+g'
 997   endif
 998 endif
 999
1000 " Gather attributes for all other classes
1001 if !s:settings.no_progress && !empty(s:idlist)
1002   let s:pgb = s:ProgressBar("Processing classes:", len(s:idlist),s:newwin)
1003 endif
1004 while !empty(s:idlist)
1005   let s:attr = ""
1006   let s:id = remove(s:idlist, 0)
1007   let s:attr = s:CSS1(s:id)
1008   let s:id_name = synIDattr(s:id, "name", s:whatterm)
1009
1010   " If the class has some attributes, export the style, otherwise DELETE all
1011   " its occurences to make the HTML shorter
1012   if s:attr != ""
1013     if s:settings.use_css
1014       execute "normal! A\n." . s:id_name . " { " . s:attr . "}"
1015     else
1016       " replace spans of just this class name with non-CSS style markup
1017       execute '%s+<span class="' . s:id_name . '">\([^<]*\)</span>+' . s:HtmlOpening(s:id) . '\1' . s:HtmlClosing(s:id) . '+ge'
1018       " Replace spans of this class name AND a diff class with non-CSS style
1019       " markup surrounding a span of just the diff class. The diff class will
1020       " be handled later because we know that information is at the end.
1021       execute '%s+<span class="' . s:id_name . ' \(Diff\%(Add\|Change\|Delete\|Text\)\)">\([^<]*\)</span>+' . s:HtmlOpening(s:id) . '<span class="\1">\2</span>' . s:HtmlClosing(s:id) . '+ge'
1022     endif
1023   else
1024     execute '%s+<span class="' . s:id_name . '">\([^<]*\)</span>+\1+ge'
1025     execute '%s+<span class="' . s:id_name . ' \(Diff\%(Add\|Change\|Delete\|Text\)\)">\([^<]*\)</span>+<span class="\1">\2</span>+ge'
1026     if s:settings.use_css
1027       1;/<\/style>/-2
1028     endif
1029   endif
1030
1031   if !s:settings.no_progress
1032     call s:pgb.incr()
1033     if s:pgb.needs_redraw
1034       redrawstatus
1035       let s:pgb.needs_redraw = 0
1036       " TODO: sleep here to show the progress bar, but only if total time spent
1037       " so far on this step is < 1 second? Too slow for batch runs like the test
1038       " suite to sleep all the time. Maybe there's no good reason to sleep at
1039       " all.
1040     endif
1041   endif
1042 endwhile
1043
1044 " Add hyperlinks
1045 %s+\(https\=://\S\{-}\)\(\([.,;:}]\=\(\s\|$\)\)\|[\\"'<>]\|&gt;\|&lt;\|&quot;\)+<a href="\1">\1</a>\2+ge
1046
1047 " The DTD
1048 if s:settings.use_xhtml
1049   exe "normal! gg$a\n<!DOCTYPE html PUBLIC \"-//W3C//DTD XHTML 1.0 Transitional//EN\" \"http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd\">"
1050 elseif s:settings.use_css && !s:settings.no_pre
1051   exe "normal! gg0i<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 4.01//EN\" \"http://www.w3.org/TR/html4/strict.dtd\">\n"
1052 else
1053   exe "normal! gg0i<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 4.01 Transitional//EN\" \"http://www.w3.org/TR/html4/loose.dtd\">\n"
1054 endif
1055
1056 if s:settings.use_xhtml
1057   exe "normal! gg/<html/e\na xmlns=\"http://www.w3.org/1999/xhtml\"\e"
1058 endif
1059
1060 " Cleanup
1061 %s:\s\+$::e
1062
1063 " Restore old settings
1064 let &l:foldenable = s:old_fen
1065 let &l:foldmethod = s:old_fdm
1066 let &report = s:old_report
1067 let &title = s:old_title
1068 let &icon = s:old_icon
1069 let &paste = s:old_paste
1070 let &magic = s:old_magic
1071 let @/ = s:old_search
1072 let &more = s:old_more
1073 exe s:orgwin . "wincmd w"
1074 let &l:et = s:old_et
1075 let &l:scrollbind = s:old_bind
1076 exe s:newwin . "wincmd w"
1077 exec 'resize' s:old_winheight
1078 let &l:winfixheight = s:old_winfixheight
1079
1080 call setwinvar(s:orgwin,'&stl', s:origwin_stl)
1081 call setwinvar(s:newwin,'&stl', s:newwin_stl)
1082 let &ls=s:ls
1083
1084 " Save a little bit of memory (worth doing?)
1085 unlet s:htmlfont
1086 unlet s:old_et s:old_paste s:old_icon s:old_report s:old_title s:old_search
1087 unlet s:old_magic s:old_more s:old_fdm s:old_fen s:old_winheight
1088 unlet s:whatterm s:idlist s:lnum s:end s:margin s:fgc s:bgc s:old_winfixheight
1089 unlet! s:col s:id s:attr s:len s:line s:new s:expandedtab s:concealinfo
1090 unlet! s:orgwin s:newwin s:orgbufnr s:idx s:i s:offset s:ls s:origwin_stl
1091 unlet! s:newwin_stl s:current_syntax
1092 if !v:profiling
1093   delfunc s:HtmlColor
1094   delfunc s:HtmlFormat
1095   delfunc s:CSS1
1096   if !s:settings.use_css
1097     delfunc s:HtmlOpening
1098     delfunc s:HtmlClosing
1099   endif
1100   if s:settings.dynamic_folds
1101     delfunc s:FoldCompare
1102   endif
1103
1104   if !s:settings.no_progress
1105     delfunc s:ProgressBar
1106     delfunc s:progressbar.paint
1107     delfunc s:progressbar.incr
1108     unlet s:pgb s:progressbar
1109   endif
1110 endif
1111
1112 unlet! s:new_lnum s:diffattr s:difffillchar s:foldfillchar s:HtmlSpace
1113 unlet! s:LeadingSpace s:HtmlEndline s:firstfold s:foldcolumn
1114 unlet s:foldstack s:allfolds s:foldId s:numcol s:settings
1115
1116 let &cpo = s:cpo_sav
1117 unlet! s:cpo_sav
1118
1119 " Make sure any patches will probably use consistent indent
1120 "   vim: ts=8 sw=2 sts=2 noet