vidix/pci_db2c.awk

   1 # This file converts given pci.db to "C" source and header files
   2 # For latest version of pci ids see: http://pciids.sf.net
   3 # Copyright 2002 Nick Kurshev
   4 #
   5 # Usage: awk -f pci_db2c.awk pci.db
   6 #
   7 # Tested with Gawk v 3.0.x and Mawk 1.3.3
   8 # But it should work with standard Awk implementations (hopefully).
   9 # (Nobody tested it with Nawk, but it should work, too).
  10 #
  11 # This file is part of MPlayer.
  12 #
  13 # MPlayer is free software; you can redistribute it and/or modify
  14 # it under the terms of the GNU General Public License as published by
  15 # the Free Software Foundation; either version 2 of the License, or
  16 # (at your option) any later version.
  17 #
  18 # MPlayer is distributed in the hope that it will be useful,
  19 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 # GNU General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with MPlayer; if not, write to the Free Software
  25 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  26
  27 BEGIN {
  28
  29     if(ARGC != 2) {
  30 # check for arguments:
  31         print "Usage awk -f pci_db2c.awk pci.db (and make sure pci.db file exists first)";
  32         exit(1);
  33     }
  34     in_file = ARGV[1];
  35     vendor_file = "pci_vendors.h";
  36     ids_file = "pci_ids.h"
  37     name_file = "pci_names.c"
  38     name_h_file = "pci_names.h"
  39     dev_ids_file = "pci_dev_ids.c"
  40     line=0;
  41 # print out head lines
  42     print_head(vendor_file);
  43     print_head(ids_file);
  44     print_head(name_file);
  45     print_head(name_h_file);
  46     print_head(dev_ids_file);
  47     print_includes(dev_ids_file);
  48     print "#ifndef PCI_VENDORS_INCLUDED" >vendor_file
  49     print "#define PCI_VENDORS_INCLUDED 1">vendor_file
  50     print "" >vendor_file
  51     print "#ifndef PCI_IDS_INCLUDED" >ids_file
  52     print "#define PCI_IDS_INCLUDED 1">ids_file
  53     print "" >ids_file
  54     print "#include \"pci_vendors.h\"">ids_file
  55     print "" >ids_file
  56
  57     print "#ifndef PCI_NAMES_INCLUDED" >name_h_file
  58     print "#define PCI_NAMES_INCLUDED 1">name_h_file
  59     print "" >name_h_file
  60     print_name_struct(name_h_file);
  61     print "#include <stddef.h>">name_file
  62     print "#include \"pci_names.h\"">name_file
  63     print "#include \"pci_dev_ids.c\"">name_file
  64     print "">name_file
  65     print "static struct vendor_id_s vendor_ids[] = {">name_file
  66     first_pass=1;
  67     init_name_db();
  68     while(getline <in_file)
  69     {
  70 # count up lines
  71         line++;
  72         n=split($0, field, "[\t]");
  73         name_field = kill_double_quoting(field[3])
  74         if(field[1] == "v" && length(field[3])>0 && field[4] == "0")
  75         {
  76                 init_device_db()
  77                 svend_name = get_short_vendor_name(field[3])
  78                 printf("#define VENDOR_%s\t", svend_name) >vendor_file;
  79                 if(length(svend_name) < 9) printf("\t") >vendor_file;
  80                 printf("0x%s /*%s*/\n",field[2], name_field) >vendor_file;
  81                 printf("{ 0x%s, \"%s\", dev_lst_%s },\n",field[2], name_field, field[2]) >name_file;
  82                 printf("/* Vendor: %s: %s */\n", field[2], name_field) > ids_file
  83                 if(first_pass == 1) { first_pass=0; }
  84                 else    { print "{ 0xFFFF,  NULL }\n};" >dev_ids_file; }
  85                 printf("static const struct device_id_s dev_lst_%s[]={\n", field[2])>dev_ids_file
  86         }
  87         if(field[1] == "d" && length(field[3])>0 && field[4] == "0")
  88         {
  89                 sdev_name = get_short_device_name(field[3])
  90                 full_name = sprintf("#define DEVICE_%s_%s", svend_name, sdev_name);
  91                 printf("%s\t", full_name) >ids_file
  92                 if(length(full_name) < 9) printf("\t") >ids_file;
  93                 if(length(full_name) < 17) printf("\t") >ids_file;
  94                 if(length(full_name) < 25) printf("\t") >ids_file;
  95                 if(length(full_name) < 32) printf("\t") >ids_file;
  96                 if(length(full_name) < 40) printf("\t") >ids_file;
  97                 if(length(full_name) < 48) printf("\t") >ids_file;
  98                 printf("0x%s /*%s*/\n", substr(field[2], 5), name_field) >ids_file
  99                 printf("{ 0x%s, \"%s\" },\n", substr(field[2], 5), name_field) >dev_ids_file
 100         }
 101         if(field[1] == "s" && length(field[3])>0 && field[4] == "0")
 102         {
 103                 subdev_name = get_short_subdevice_name(field[3])
 104                 full_name = sprintf("#define SUBDEVICE_%s_%s", svend_name, subdev_name)
 105                 printf("\t%s\t", full_name) >ids_file
 106                 if(length(full_name) < 9) printf("\t") >ids_file;
 107                 if(length(full_name) < 17) printf("\t") >ids_file;
 108                 if(length(full_name) < 25) printf("\t") >ids_file;
 109                 if(length(full_name) < 32) printf("\t") >ids_file;
 110                 if(length(full_name) < 40) printf("\t") >ids_file;
 111                 printf("0x%s /*%s*/\n", substr(field[2], 9), name_field) >ids_file
 112         }
 113     }
 114     print "Total lines parsed:", line;
 115     print "">vendor_file
 116     print "#endif/*PCI_VENDORS_INCLUDED*/">vendor_file
 117     print "">ids_file
 118     print "#endif/*PCI_IDS_INCLUDED*/">ids_file
 119     print "">name_h_file
 120     print "#endif/*PCI_NAMES_INCLUDED*/">name_h_file
 121     print "};">name_file
 122     print "{ 0xFFFF,  NULL }" >dev_ids_file;
 123     print "};">dev_ids_file
 124     print_func_bodies(name_file);
 125 }
 126
 127 function print_includes(out_file)
 128 {
 129     print "#include <stdlib.h>" >out_file;
 130     print "#include \"pci_names.h\"" >out_file;
 131     return;
 132 }
 133
 134 function print_head( out_file)
 135 {
 136     print "/*" >out_file;
 137     printf(" * File: %s\n", out_file) >out_file;
 138     printf(" * This file was generated automatically. Don't modify it.\n") >out_file;
 139     print "*/" >out_file;
 140     return;
 141 }
 142
 143 function print_name_struct(out_file)
 144 {
 145    print "#ifdef __cplusplus" >out_file
 146    print "extern \"C\" {" >out_file
 147    print "#endif" >out_file
 148    print "">out_file
 149    print "struct device_id_s" >out_file
 150    print "{" >out_file
 151    print "\tunsigned short\tid;" >out_file
 152    print "\tconst char *\tname;" >out_file
 153    print "};" >out_file
 154    print "">out_file
 155    print "struct vendor_id_s" >out_file
 156    print "{" >out_file
 157    print "\tunsigned short\tid;" >out_file
 158    print "\tconst char *\tname;" >out_file
 159    print "\tconst struct device_id_s *\tdev_list;" >out_file
 160    print "};" >out_file
 161    print "extern const char *pci_vendor_name(unsigned short id);">out_file
 162    print "extern const char *pci_device_name(unsigned short vendor_id, unsigned short device_id);">out_file
 163    print "">out_file
 164    print "#ifdef __cplusplus" >out_file
 165    print "}" >out_file
 166    print "#endif" >out_file
 167    return
 168 }
 169
 170 function print_func_bodies(out_file)
 171 {
 172    print "">out_file
 173    print "const char *pci_vendor_name(unsigned short id)" >out_file
 174    print "{" >out_file
 175    print "  unsigned i;" >out_file
 176    print "  for(i=0;i<sizeof(vendor_ids)/sizeof(struct vendor_id_s);i++)">out_file
 177    print "  {" >out_file
 178    print "\tif(vendor_ids[i].id == id) return vendor_ids[i].name;" >out_file
 179    print "  }" >out_file
 180    print "  return NULL;" >out_file
 181    print "}">out_file
 182    print "" >out_file
 183    print "const char *pci_device_name(unsigned short vendor_id, unsigned short device_id)" >out_file
 184    print "{" >out_file
 185    print "  unsigned i, j;" >out_file
 186    print "  for(i=0;i<sizeof(vendor_ids)/sizeof(struct vendor_id_s);i++)">out_file
 187    print "  {" >out_file
 188    print "\tif(vendor_ids[i].id == vendor_id)" >out_file
 189    print "\t{" >out_file
 190    print "\t  j=0;" >out_file
 191    print "\t  while(vendor_ids[i].dev_list[j].id != 0xFFFF)" >out_file
 192    print "\t  {">out_file
 193    print "\t\tif(vendor_ids[i].dev_list[j].id == device_id) return vendor_ids[i].dev_list[j].name;">out_file
 194    print "\t\tj++;">out_file
 195    print "\t  };">out_file
 196    print "\t  break;" >out_file
 197    print "\t}" >out_file
 198    print "  }" >out_file
 199    print "  return NULL;">out_file
 200    print "}">out_file
 201    return
 202 }
 203
 204 function kill_double_quoting(fld)
 205 {
 206   n=split(fld,phrases, "[\"]");
 207   new_fld = phrases[1]
 208   for(i=2;i<=n;i++) new_fld = sprintf("%s\\\"%s", new_fld, phrases[i])
 209   return new_fld
 210 }
 211
 212 function init_name_db()
 213 {
 214   vendor_names[1]=""
 215 }
 216
 217 function init_device_db()
 218 {
 219 #  delete device_names
 220   for( i in device_names ) delete device_names[i];
 221   device_names[1]=""
 222 #  delete subdevice_names
 223   for( i in subdevice_names ) delete subdevice_names[i];
 224   subdevice_names[1] = ""
 225 }
 226
 227 function get_short_vendor_name(from)
 228 {
 229   n=split(from, name, "[ ]");
 230   new_name = toupper(name[1]);
 231   if(length(new_name)<3) new_name = sprintf("%s_%s", new_name, toupper(name[2]));
 232   n=split(new_name, name, "[^0-9A-Za-z]");
 233   svendor = name[1];
 234   for(i=2;i<=n;i++) svendor=sprintf("%s%s%s", svendor, length(name[i])?"_":"", name[i]);
 235   new_name = svendor;
 236   vend_suffix = 2;
 237 # check for unique
 238   while(new_name in vendor_names)
 239   {
 240     new_name = sprintf("%s%u", svendor, vend_suffix)
 241     vend_suffix = vend_suffix + 1;
 242   }
 243 # Add new name in array of vendor's names
 244   vendor_names[new_name] = new_name
 245   return new_name;
 246 }
 247
 248 function get_short_device_name(from_name)
 249 {
 250   n=split(from_name, name, "[ ]");
 251   new_name = toupper(name[1]);
 252   if(length(name[2])) new_name = sprintf("%s_%s", new_name, toupper(name[2]));
 253   if(length(name[3])) new_name = sprintf("%s_%s", new_name, toupper(name[3]));
 254   n=split(new_name, name, "[^0-9A-Za-z]");
 255   sdevice = name[1];
 256   for(i=2;i<=n;i++) sdevice=sprintf("%s%s%s", sdevice, length(name[i])?"_":"", name[i]);
 257   new_name = sdevice;
 258   dev_suffix = 2;
 259 # check for unique
 260   while(new_name in device_names)
 261   {
 262     new_name = sprintf("%s%u", sdevice, dev_suffix)
 263     dev_suffix = dev_suffix + 1;
 264   }
 265 # Add new name in array of device names
 266   device_names[new_name] = new_name
 267   return new_name;
 268 }
 269
 270 function get_short_subdevice_name(from_name)
 271 {
 272   n=split(from_name, name, "[ ]");
 273   new_name = toupper(name[1]);
 274   if(length(name[2])) new_name = sprintf("%s_%s", new_name, toupper(name[2]));
 275   if(length(name[3])) new_name = sprintf("%s_%s", new_name, toupper(name[3]));
 276   n=split(new_name, name, "[^0-9A-Za-z]");
 277   ssdevice = name[1];
 278   for(i=2;i<=n;i++) ssdevice=sprintf("%s%s%s", ssdevice, length(name[i])?"_":"", name[i]);
 279   new_name = ssdevice;
 280   sdev_suffix = 2;
 281 # check for unique
 282   while(new_name in subdevice_names)
 283   {
 284     new_name = sprintf("%s%u", ssdevice, sdev_suffix)
 285     sdev_suffix = sdev_suffix + 1;
 286   }
 287 # Add new name in array of subdevice names
 288   subdevice_names[new_name] = new_name
 289   return new_name;
 290 }