MPUI_Setup.nsi

   1 ; ///////////////////////////////////////////////////////////////////////////////
   2 ; // MPlayer for Windows - Install Script
   3 ; // Copyright (C) 2004-2013 LoRd_MuldeR <MuldeR2@GMX.de>
   4 ; //
   5 ; // This program is free software; you can redistribute it and/or modify
   6 ; // it under the terms of the GNU General Public License as published by
   7 ; // the Free Software Foundation; either version 2 of the License, or
   8 ; // (at your option) any later version.
   9 ; //
  10 ; // This program is distributed in the hope that it will be useful,
  11 ; // but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ; // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ; // GNU General Public License for more details.
  14 ; //
  15 ; // You should have received a copy of the GNU General Public License along
  16 ; // with this program; if not, write to the Free Software Foundation, Inc.,
  17 ; // 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18 ; //
  19 ; // http://www.gnu.org/licenses/gpl-2.0.txt
  20 ; ///////////////////////////////////////////////////////////////////////////////
  21
  22
  23 ;--------------------------------------------------------------------------------
  24 ; BASIC DEFINES
  25 ;--------------------------------------------------------------------------------
  26
  27 !ifndef NSIS_UNICODE
  28   !error "NSIS_UNICODE is undefined, please compile with Unicode NSIS !!!"
  29 !endif
  30
  31 !ifndef MPLAYER_BUILDNO
  32   !error "MPLAYER_BUILDNO is not defined !!!"
  33 !endif
  34
  35 !ifndef MPLAYER_REVISION
  36   !error "MPLAYER_REVISION is not defined !!!"
  37 !endif
  38
  39 !ifndef MPLAYER_DATE
  40   !error "MPLAYER_DATE is not defined !!!"
  41 !endif
  42
  43 !ifndef SMPLAYER_VERSION
  44   !error "SMPLAYER_VERSION is not defined !!!"
  45 !endif
  46
  47 !ifndef MPUI_VERSION
  48   !error "MPUI_VERSION is not defined !!!"
  49 !endif
  50
  51 !ifndef CODECS_DATE
  52   !error "CODECS_DATE is not defined !!!"
  53 !endif
  54
  55 !ifndef MPLAYER_OUTFILE
  56   !error "MPLAYER_OUTFILE is not defined !!!"
  57 !endif
  58
  59 !ifndef UPX_PATH
  60   !error "UPX_PATH is not defined !!!"
  61 !endif
  62
  63 ; UUID
  64 !define MPlayerRegPath "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{97D341C8-B0D1-4E4A-A49A-C30B52F168E9}"
  65
  66 ; Web-Site
  67 !define MPlayerWebSite "http://mplayerhq.hu/"
  68
  69
  70 ;--------------------------------------------------------------------------------
  71 ; INSTALLER ATTRIBUTES
  72 ;--------------------------------------------------------------------------------
  73
  74 RequestExecutionLevel admin
  75 ShowInstDetails show
  76 ShowUninstDetails show
  77
  78 Name "$(MPLAYER_LANG_MPLAYER_WIN32) ${MPLAYER_DATE} (Build #${MPLAYER_BUILDNO})"
  79 Caption "$(MPLAYER_LANG_MPLAYER_WIN32) ${MPLAYER_DATE} (Build #${MPLAYER_BUILDNO})"
  80 BrandingText "MPlayer-Win32 (Build #${MPLAYER_BUILDNO})"
  81 InstallDir "$PROGRAMFILES\MPlayer for Windows"
  82 InstallDirRegKey HKLM "${MPlayerRegPath}" "InstallLocation"
  83 OutFile "${MPLAYER_OUTFILE}"
  84
  85
  86 ;--------------------------------------------------------------------------------
  87 ; COMPRESSOR
  88 ;--------------------------------------------------------------------------------
  89
  90 SetCompressor /SOLID /FINAL LZMA
  91 SetCompressorDictSize 112
  92
  93 !packhdr "$%TEMP%\exehead.tmp" '"${UPX_PATH}\upx.exe" --brute "$%TEMP%\exehead.tmp"'
  94
  95
  96 ;--------------------------------------------------------------------------------
  97 ; RESERVE FILES
  98 ;--------------------------------------------------------------------------------
  99
 100 ReserveFile "${NSISDIR}\Plugins\Aero.dll"
 101 ReserveFile "${NSISDIR}\Plugins\Banner.dll"
 102 ReserveFile "${NSISDIR}\Plugins\CPUFeatures.dll"
 103 ReserveFile "${NSISDIR}\Plugins\InstallOptions.dll"
 104 ReserveFile "${NSISDIR}\Plugins\LangDLL.dll"
 105 ReserveFile "${NSISDIR}\Plugins\LockedList.dll"
 106 ReserveFile "${NSISDIR}\Plugins\nsDialogs.dll"
 107 ReserveFile "${NSISDIR}\Plugins\nsExec.dll"
 108 ReserveFile "${NSISDIR}\Plugins\StartMenu.dll"
 109 ReserveFile "${NSISDIR}\Plugins\StdUtils.dll"
 110 ReserveFile "${NSISDIR}\Plugins\System.dll"
 111 ReserveFile "${NSISDIR}\Plugins\UserInfo.dll"
 112 ReserveFile "Dialogs\Page_CPU.ini"
 113 ReserveFile "Resources\Splash.gif"
 114
 115
 116 ;--------------------------------------------------------------------------------
 117 ; INCLUDES
 118 ;--------------------------------------------------------------------------------
 119
 120 !include `MUI2.nsh`
 121 !include `InstallOptions.nsh`
 122 !include `WinVer.nsh`
 123 !include `x64.nsh`
 124 !include `StrFunc.nsh`
 125 !include `StdUtils.nsh`
 126 !include `CPUFeatures.nsh`
 127 !include `MPUI_Common.nsh`
 128
 129 ; Enable functions
 130 ${StrRep}
 131
 132
 133 ;--------------------------------------------------------------------------------
 134 ; GLOBAL VARIABLES
 135 ;--------------------------------------------------------------------------------
 136
 137 Var StartMenuFolder
 138 Var DetectedCPUType
 139 Var DetectedCPUCores
 140 Var SelectedCPUType
 141 Var SelectedTweaks
 142 Var NotUpdateInstall
 143
 144
 145 ;--------------------------------------------------------------------------------
 146 ; VERSION INFO
 147 ;--------------------------------------------------------------------------------
 148
 149 !searchreplace PRODUCT_VERSION_DATE "${MPLAYER_DATE}" "-" "."
 150 VIProductVersion "${PRODUCT_VERSION_DATE}.${MPLAYER_BUILDNO}"
 151
 152 VIAddVersionKey "Author" "LoRd_MuldeR <mulder2@gmx.de>"
 153 VIAddVersionKey "Comments" "This program is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation; either version 2 of the License, or (at your option) any later version."
 154 VIAddVersionKey "CompanyName" "Free Software Foundation"
 155 VIAddVersionKey "FileDescription" "MPlayer for Windows (Build #${MPLAYER_BUILDNO})"
 156 VIAddVersionKey "FileVersion" "${PRODUCT_VERSION_DATE}.${MPLAYER_BUILDNO}"
 157 VIAddVersionKey "LegalCopyright" "Copyright 2000-2013 The MPlayer Project"
 158 VIAddVersionKey "LegalTrademarks" "GNU"
 159 VIAddVersionKey "OriginalFilename" "MPUI-Setup.exe"
 160 VIAddVersionKey "ProductName" "MPlayer for Windows"
 161 VIAddVersionKey "ProductVersion" "Build #${MPLAYER_BUILDNO} (${MPLAYER_DATE})"
 162 VIAddVersionKey "Website" "${MPlayerWebSite}"
 163
 164
 165 ;--------------------------------------------------------------------------------
 166 ; MUI2 INTERFACE SETTINGS
 167 ;--------------------------------------------------------------------------------
 168
 169 !define MUI_ABORTWARNING
 170 !define MUI_STARTMENUPAGE_REGISTRY_ROOT HKLM
 171 !define MUI_STARTMENUPAGE_REGISTRY_KEY "${MPlayerRegPath}"
 172 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "StartmenuFolder"
 173 !define MUI_LANGDLL_REGISTRY_ROOT HKLM
 174 !define MUI_LANGDLL_REGISTRY_KEY "${MPlayerRegPath}"
 175 !define MUI_LANGDLL_REGISTRY_VALUENAME "SetupLanguage"
 176 !define MUI_STARTMENUPAGE_DEFAULTFOLDER "MPlayer for Windows"
 177 !define MUI_FINISHPAGE_NOAUTOCLOSE
 178 !define MUI_UNFINISHPAGE_NOAUTOCLOSE
 179 !define MUI_FINISHPAGE_RUN
 180 !define MUI_FINISHPAGE_RUN_FUNCTION RunAppFunction
 181 !define MUI_FINISHPAGE_SHOWREADME
 182 !define MUI_FINISHPAGE_SHOWREADME_FUNCTION ShowReadmeFunction
 183 !define MUI_FINISHPAGE_LINK ${MPlayerWebSite}
 184 !define MUI_FINISHPAGE_LINK_LOCATION ${MPlayerWebSite}
 185 !define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\orange-install.ico"
 186 !define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\orange-uninstall.ico"
 187 !define MUI_WELCOMEFINISHPAGE_BITMAP "Artwork\wizard.bmp"
 188 !define MUI_UNWELCOMEFINISHPAGE_BITMAP "Artwork\wizard-un.bmp"
 189 !define MUI_HEADERIMAGE
 190 !define MUI_HEADERIMAGE_BITMAP "Artwork\header.bmp"
 191 !define MUI_HEADERIMAGE_UNBITMAP "Artwork\header-un.bmp"
 192 !define MUI_LANGDLL_ALLLANGUAGES
 193 !define MUI_CUSTOMFUNCTION_GUIINIT MyGuiInit
 194 !define MUI_CUSTOMFUNCTION_UNGUIINIT un.MyGuiInit
 195 !define MUI_LANGDLL_ALWAYSSHOW
 196 !define MUI_COMPONENTSPAGE_SMALLDESC
 197
 198
 199 ;--------------------------------------------------------------------------------
 200 ; MUI2 PAGE SETUP
 201 ;--------------------------------------------------------------------------------
 202
 203 ; Installer
 204 !define MUI_WELCOMEPAGE_TITLE_3LINES
 205 !define MUI_FINISHPAGE_TITLE_3LINES
 206 !insertmacro MUI_PAGE_WELCOME
 207 !insertmacro MUI_PAGE_LICENSE "Docs\License.txt"
 208 !define MUI_PAGE_CUSTOMFUNCTION_SHOW CheckForUpdate
 209 !insertmacro MUI_PAGE_DIRECTORY
 210 !insertmacro  MUI_PAGE_COMPONENTS
 211 !insertmacro MUI_PAGE_STARTMENU Application $StartMenuFolder
 212 Page Custom SelectCPUPage_Show SelectCPUPage_Validate
 213 Page Custom SetTweaksPage_Show
 214 Page Custom LockedListPage_Show
 215 !insertmacro MUI_PAGE_INSTFILES
 216 !insertmacro MUI_PAGE_FINISH
 217
 218 ; Un-Installer
 219 !define MUI_WELCOMEPAGE_TITLE_3LINES
 220 !define MUI_FINISHPAGE_TITLE_3LINES
 221 !insertmacro MUI_UNPAGE_WELCOME
 222 !insertmacro MUI_UNPAGE_CONFIRM
 223 UninstPage Custom un.LockedListPage_Show
 224 !insertmacro MUI_UNPAGE_INSTFILES
 225 !insertmacro MUI_UNPAGE_FINISH
 226
 227
 228 ;--------------------------------------------------------------------------------
 229 ; LANGUAGE
 230 ;--------------------------------------------------------------------------------
 231
 232 !insertmacro MUI_LANGUAGE "English"
 233 !insertmacro MUI_LANGUAGE "German"
 234
 235 ; Translation files
 236 !include "Language\MPUI_EN.nsh"
 237 !include "Language\MPUI_DE.nsh"
 238
 239
 240 ;--------------------------------------------------------------------------------
 241 ; INSTALL TYPES
 242 ;--------------------------------------------------------------------------------
 243
 244 InstType "$(MPLAYER_LANG_INSTTYPE_COMPLETE)"
 245 InstType "$(MPLAYER_LANG_INSTTYPE_MINIMAL)"
 246
 247
 248 ;--------------------------------------------------------------------------------
 249 ; INITIALIZATION
 250 ;--------------------------------------------------------------------------------
 251
 252 Function .onInit
 253         StrCpy $SelectedCPUType 0
 254         StrCpy $DetectedCPUType 0
 255         StrCpy $DetectedCPUCores 0
 256         StrCpy $SelectedTweaks 0
 257         StrCpy $NotUpdateInstall 1
 258
 259         InitPluginsDir
 260
 261         ; --------
 262
 263         System::Call 'kernel32::CreateMutexA(i 0, i 0, t "{B800490C-C100-4B12-9F09-1A54DF063049}") i .r1 ?e'
 264         Pop $0
 265         ${If} $0 <> 0
 266                 MessageBox MB_ICONSTOP|MB_TOPMOST "Oups, the installer is already running!"
 267                 Quit
 268         ${EndIf}
 269
 270         ; --------
 271
 272         # Running on Windows NT family?
 273         ${IfNot} ${IsNT}
 274                 MessageBox MB_TOPMOST|MB_ICONSTOP "Sorry, this application does *not* support Windows 9x or Windows ME!"
 275                 ExecShell "open" "http://windows.microsoft.com/"
 276                 Quit
 277         ${EndIf}
 278
 279         # Running on Windows XP or later?
 280         ${If} ${AtMostWin2000}
 281                 MessageBox MB_TOPMOST|MB_ICONSTOP "Sorry, but your operating system is *not* supported anymore.$\nInstallation will be aborted!$\n$\nThe minimum required platform is Windows XP."
 282                 ExecShell "open" "http://windows.microsoft.com/"
 283                 Quit
 284         ${EndIf}
 285
 286         ; --------
 287
 288         UserInfo::GetAccountType
 289         Pop $0
 290         ${If} $0 != "Admin"
 291                 MessageBox MB_ICONSTOP|MB_TOPMOST "Your system requires administrative permissions in order to install this software."
 292                 SetErrorLevel 740 ;ERROR_ELEVATION_REQUIRED
 293                 Quit
 294         ${EndIf}
 295
 296         ; --------
 297
 298         !insertmacro MUI_LANGDLL_DISPLAY
 299
 300         !insertmacro INSTALLOPTIONS_EXTRACT_AS "Dialogs\Page_CPU.ini"    "Page_CPU.ini"
 301         !insertmacro INSTALLOPTIONS_EXTRACT_AS "Dialogs\Page_Tweaks.ini" "Page_Tweaks.ini"
 302
 303         !ifdef PRE_RELEASE
 304                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL|MB_DEFBUTTON2 "Note: This is an early pre-release version for test only!" IDCANCEL ${||} Quit ${|}
 305         !endif
 306
 307         ; --------
 308
 309         ${IfNot} ${Silent}
 310                 File "/oname=$PLUGINSDIR\Splash.gif" "Resources\Splash.gif"
 311                 newadvsplash::show 3000 1000 500 -1 /NOCANCEL "$PLUGINSDIR\Splash.gif"
 312                 Delete /REBOOTOK "$PLUGINSDIR\Splash.gif"
 313         ${EndIf}
 314 FunctionEnd
 315
 316 Function un.onInit
 317         InitPluginsDir
 318
 319         System::Call 'kernel32::CreateMutexA(i 0, i 0, t "{B800490C-C100-4B12-9F09-1A54DF063049}") i .r1 ?e'
 320         Pop $0
 321         ${If} $0 <> 0
 322                 MessageBox MB_ICONSTOP|MB_TOPMOST "Sorry, the un-installer is already running!"
 323                 Quit
 324         ${EndIf}
 325
 326         ; --------
 327
 328         UserInfo::GetAccountType
 329         Pop $0
 330         ${If} $0 != "Admin"
 331                 MessageBox MB_ICONSTOP|MB_TOPMOST "Your system requires administrative permissions in order to un-install this software."
 332                 SetErrorLevel 740 ;ERROR_ELEVATION_REQUIRED
 333                 Quit
 334         ${EndIf}
 335
 336         ; --------
 337
 338         !insertmacro MUI_LANGDLL_DISPLAY
 339 FunctionEnd
 340
 341
 342 ;--------------------------------------------------------------------------------
 343 ; GUI INITIALIZATION
 344 ;--------------------------------------------------------------------------------
 345
 346 Function MyGuiInit
 347         StrCpy $0 $HWNDPARENT
 348         System::Call "user32::SetWindowPos(i r0, i -1, i 0, i 0, i 0, i 0, i 3)"
 349         Aero::Apply
 350 FunctionEnd
 351
 352 Function un.MyGuiInit
 353         StrCpy $0 $HWNDPARENT
 354         System::Call "user32::SetWindowPos(i r0, i -1, i 0, i 0, i 0, i 0, i 3)"
 355         Aero::Apply
 356 FunctionEnd
 357
 358
 359 ;--------------------------------------------------------------------------------
 360 ; INSTALL SECTIONS
 361 ;--------------------------------------------------------------------------------
 362
 363 Section "-Clean Up"
 364         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_CLEAN)"
 365
 366         SetShellVarContext all
 367         SetOutPath "$INSTDIR"
 368
 369         ; Uninstall old version (aka "Setup v1")
 370         ClearErrors
 371         ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{DB9E4EAB-2717-499F-8D56-4CC8A644AB60}" "InstallLocation"
 372         ${IfNot} ${Errors}
 373                 MessageBox MB_ICONINFORMATION|MB_OK "$(MPLAYER_LANG_UNINSTALL_OLDVER)"
 374                 File "/oname=$PLUGINSDIR\Uninstall-V1.exe" "Resources\Uninstall-V1.exe"
 375                 HideWindow
 376                 ExecWait '"$PLUGINSDIR\Uninstall-V1.exe" _?=$0'
 377                 Delete /REBOOTOK "$PLUGINSDIR\Uninstall-V1.exe"
 378                 BringToFront
 379         ${EndIf}
 380
 381         ; Clean registry
 382         DeleteRegKey HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{DB9E4EAB-2717-499F-8D56-4CC8A644AB60}"
 383         DeleteRegKey HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{DB9E4EAB-2717-499F-8D56-4CC8A644AB60}"
 384         DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_UpdateReminder"
 385         DeleteRegValue HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_UpdateReminder"
 386
 387         ; Make sure MPlayer isn't running
 388         ${Do}
 389                 ClearErrors
 390                 Delete "$INSTDIR\MPlayer.exe"
 391                 Delete "$INSTDIR\SMPlayer.exe"
 392                 Delete "$INSTDIR\MPUI.exe"
 393                 ${If} ${Errors}
 394                         ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL "$(MPLAYER_LANG_STILL_RUNNING)" IDCANCEL ${||} Abort ${|}
 395                 ${Else}
 396                         ${Break}
 397                 ${EndIf}
 398         ${Loop}
 399
 400         ; Clean the install folder
 401         Delete "$INSTDIR\*.exe"
 402         Delete "$INSTDIR\*.dll"
 403         Delete "$INSTDIR\*.ini"
 404         Delete "$INSTDIR\*.txt"
 405         Delete "$INSTDIR\*.html"
 406         Delete "$INSTDIR\*.htm"
 407         Delete "$INSTDIR\*.ass"
 408         Delete "$INSTDIR\*.m3u8"
 409         Delete "$INSTDIR\*.tag"
 410         Delete "$INSTDIR\mplayer\config"
 411         Delete "$INSTDIR\mplayer\*.conf"
 412
 413         ; Now deal with Virtual Store
 414         ${GetVirtualStorePath} $0 "$INSTDIR"
 415         Delete "$0\*.exe"
 416         Delete "$0\*.dll"
 417         Delete "$0\*.ini"
 418         Delete "$0\*.txt"
 419         Delete "$0\*.html"
 420         Delete "$0\*.htm"
 421         Delete "$0\*.ass"
 422         Delete "$0\*.m3u8"
 423         Delete "$0\*.tag"
 424         Delete "$0\mplayer\config"
 425         Delete "$0\mplayer\*.conf"
 426 SectionEnd
 427
 428 Section "!MPlayer r${MPLAYER_REVISION}" SECID_MPLAYER
 429         SectionIn 1 2 RO
 430         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_MPLAYER)"
 431         SetOutPath "$INSTDIR"
 432
 433         ; Detect
 434         ${If} ${Silent}
 435                 Call DetectCPUType
 436                 StrCpy $SelectedCPUType $DetectedCPUType
 437         ${EndIf}
 438
 439         ; MPlayer.exe
 440         ${Select} $SelectedCPUType
 441                 ${Case} "2"
 442                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): core2"
 443                         File "Builds\MPlayer-core2\MPlayer.exe"
 444                 ${Case} "3"
 445                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): corei7"
 446                         File "Builds\MPlayer-corei7\MPlayer.exe"
 447                 ${Case} "4"
 448                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): k8-sse3"
 449                         File "Builds\MPlayer-k8-sse3\MPlayer.exe"
 450                 ${Case} "5"
 451                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): bdver1"
 452                         File "Builds\MPlayer-bdver1\MPlayer.exe"
 453                 ${Case} "6"
 454                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): generic"
 455                         File "Builds\MPlayer-generic\MPlayer.exe"
 456                 ${CaseElse}
 457                         MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OK "Internal error: Invalid CPU type selection detected!"
 458                         Abort
 459         ${EndSelect}
 460
 461         ; Utilities
 462         File ".Compile\Updater.exe"
 463         File "Resources\AppRegGUI.exe"
 464
 465         ; Other MPlayer-related files
 466         File "Builds\MPlayer-generic\dsnative.dll"
 467         SetOutPath "$INSTDIR\mplayer"
 468         File "Builds\MPlayer-generic\mplayer\config"
 469         File "Builds\MPlayer-generic\mplayer\subfont.ttf"
 470         SetOutPath "$INSTDIR\fonts"
 471         File "Builds\MPlayer-generic\fonts\fonts.conf"
 472         SetOutPath "$INSTDIR\fonts\conf.d"
 473         File "Builds\MPlayer-generic\fonts\conf.d\*.conf"
 474
 475         ; Documents
 476         SetOutPath "$INSTDIR"
 477         File "GPL.txt"
 478         File "/oname=Manual.html" "Builds\MPlayer-generic\MPlayer.man.html"
 479         File "Docs\Readme.html"
 480         SetOutPath "$INSTDIR\legal_stuff"
 481         File "Docs\legal_stuff\*.txt"
 482
 483         ; Write version tag
 484         ${Do}
 485                 ClearErrors
 486                 Delete "$INSTDIR\version.tag"
 487                 ${If} ${Errors}
 488                         ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL "$(MPLAYER_LANG_TAG_WRITE)" IDCANCEL ${||} Abort ${|}
 489                 ${Else}
 490                         ${Break}
 491                 ${EndIf}
 492         ${Loop}
 493         WriteINIStr "$INSTDIR\version.tag" "mplayer_version" "build_no" "${MPLAYER_BUILDNO}"
 494         WriteINIStr "$INSTDIR\version.tag" "mplayer_version" "pkg_date" "${MPLAYER_DATE}"
 495         SetFileAttributes "$INSTDIR\version.tag" FILE_ATTRIBUTE_READONLY
 496
 497         ; Set file access rights
 498         ${MakeFilePublic} "$INSTDIR\mplayer\config"
 499         ${MakeFilePublic} "$INSTDIR\fonts\fonts.conf"
 500 SectionEnd
 501
 502 Section "!MPUI $(MPLAYER_LANG_FRONT_END) v${MPUI_VERSION}" SECID_MPUI
 503         SectionIn 1 2
 504         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_MPUI)"
 505
 506         ; Extract files
 507         SetOutPath "$INSTDIR"
 508         File "MPUI\MPUI.exe"
 509
 510         ; Extract locales
 511         SetOutPath "$INSTDIR\locale"
 512         File "MPUI\locale\*.txt"
 513
 514         ; Set file access rights
 515         ${MakeFilePublic} "$INSTDIR\MPUI.ini"
 516
 517         ; Setup initial config
 518         ClearErrors
 519         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Params" "-vo direct3d -lavdopts threads=$DetectedCPUCores"
 520         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Locale" "$(MPLAYER_LANG_MPUI_DEFAULT_LANGUAGE)"
 521         ${If} ${Errors}
 522                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONSTOP|MB_DEFBUTTON2|MB_OKCANCEL "$(MPLAYER_LANG_CONFIG_MPUI)" IDCANCEL ${||} Abort ${|}
 523         ${EndIf}
 524 SectionEnd
 525
 526 Section "!SMPlayer $(MPLAYER_LANG_FRONT_END) v${SMPLAYER_VERSION}" SECID_SMPLAYER
 527         SectionIn 1
 528         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_CODECS)"
 529
 530         ; SMPlayer files
 531         SetOutPath "$INSTDIR"
 532         File "SMPlayer\SMPlayer.exe"
 533         File "SMPlayer\libgcc_s_dw2-1.dll"
 534         File "SMPlayer\mingwm10.dll"
 535         File "SMPlayer\QtCore4.dll"
 536         File "SMPlayer\QtGui4.dll"
 537         File "SMPlayer\QtNetwork4.dll"
 538         File "SMPlayer\QtXml4.dll"
 539         File "SMPlayer\zlib1.dll"
 540
 541         ; Additional SMPlayer files
 542         SetOutPath "$INSTDIR\translations"
 543         File "SMPlayer\translations\*.qm"
 544         SetOutPath "$INSTDIR\imageformats"
 545         File "SMPlayer\imageformats\*.dll"
 546         SetOutPath "$INSTDIR\shortcuts"
 547         File "SMPlayer\shortcuts\*.keys"
 548         SetOutPath "$INSTDIR\themes"
 549         File /r "SMPlayer\themes\*.css"
 550         File /r "SMPlayer\themes\*.png"
 551
 552         ; Set file access rights
 553         ${MakeFilePublic} "$INSTDIR\SMPlayer.ini"
 554         ${MakeFilePublic} "$INSTDIR\SMPlayer_files.ini"
 555         ${MakeFilePublic} "$INSTDIR\favorites.m3u8"
 556         ${MakeFilePublic} "$INSTDIR\radio.m3u8"
 557         ${MakeFilePublic} "$INSTDIR\tv.m3u8"
 558         ${MakeFilePublic} "$INSTDIR\styles.ass"
 559         ${MakeFilePublic} "$INSTDIR\shortcuts\default.keys"
 560
 561         ; Setup initial config
 562         ${StrRep} $0 "$INSTDIR\MPlayer.exe" "\" "/"
 563         ClearErrors
 564         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"    "config_version"             "3"
 565         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"    "mplayer_bin"                "$0"
 566         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"    "driver\vo"                  "direct3d"
 567         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"    "autosync"                   "true"
 568         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"    "autosync_factor"            "30"
 569         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"    "use_audio_equalizer"        "false"
 570         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"    "use_scaletempo"             "0"
 571         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"    "osd"                        "1"
 572         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"    "file_settings_method"       "normal"
 573         WriteINIStr "$INSTDIR\SMPlayer.ini" "performance" "threads"                    "$DetectedCPUCores"
 574         WriteINIStr "$INSTDIR\SMPlayer.ini" "performance" "priority"                   "1"
 575         WriteINIStr "$INSTDIR\SMPlayer.ini" "performance" "frame_drop"                 "true"
 576         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui"         "gui"                        "DefaultGUI"
 577         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui"         "iconset"                    "Oxygen-Refit"
 578         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui"         "style"                      "Plastique"
 579         WriteINIStr "$INSTDIR\SMPlayer.ini" "advanced"    "mplayer_additional_options" ""
 580
 581         ${If} ${Errors}
 582                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONSTOP|MB_DEFBUTTON2|MB_OKCANCEL "$(MPLAYER_LANG_CONFIG_SMPLAYER)" IDCANCEL ${||} Abort ${|}
 583         ${EndIf}
 584 SectionEnd
 585
 586 Section "!$(MPLAYER_LANG_BIN_CODECS) (${CODECS_DATE})"
 587         SectionIn 1
 588         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_CODECS)"
 589
 590         SetOutPath "$INSTDIR\codecs"
 591
 592         File "Codecs\*.0"
 593         File "Codecs\*.acm"
 594         File "Codecs\*.ax"
 595         File "Codecs\*.dll"
 596         File "Codecs\*.qtx"
 597         File "Codecs\*.so"
 598         File "Codecs\*.vwp"
 599         File "Codecs\*.xa"
 600 SectionEnd
 601
 602 Section "-Write Uninstaller"
 603         ${PrintProgress} "$(MPLAYER_LANG_STATUS_MAKEUNINST)"
 604         WriteUninstaller "$INSTDIR\Uninstall.exe"
 605 SectionEnd
 606
 607 Section "-Create Shortcuts"
 608         !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
 609                 ${PrintProgress} "$(MPLAYER_LANG_STATUS_SHORTCUTS)"
 610                 CreateDirectory "$SMPROGRAMS\$StartMenuFolder"
 611
 612                 SetShellVarContext current
 613                 Delete "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 614                 Delete "$SMPROGRAMS\$StartMenuFolder\*.pif"
 615                 Delete "$SMPROGRAMS\$StartMenuFolder\*.url"
 616
 617                 SetShellVarContext all
 618                 Delete "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 619                 Delete "$SMPROGRAMS\$StartMenuFolder\*.pif"
 620                 Delete "$SMPROGRAMS\$StartMenuFolder\*.url"
 621
 622                 ${If} ${FileExists} "$INSTDIR\MPUI.exe"
 623                         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\MPUI.lnk" "$INSTDIR\MPUI.exe"
 624                         CreateShortCut "$DESKTOP\MPUI.lnk" "$INSTDIR\MPUI.exe"
 625                 ${EndIf}
 626                 ${If} ${FileExists} "$INSTDIR\SMPlayer.exe"
 627                         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" "$INSTDIR\SMPlayer.exe"
 628                         CreateShortCut "$DESKTOP\SMPlayer.lnk" "$INSTDIR\SMPlayer.exe"
 629                 ${EndIf}
 630
 631                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_UPDATE).lnk" "$INSTDIR\Updater.exe" "/L=$LANGUAGE"
 632                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_README).lnk" "$INSTDIR\Readme.html"
 633                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_MANUAL).lnk" "$INSTDIR\Manual.html"
 634
 635                 ${If} ${AtLeastWinVista}
 636                         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_APPREG).lnk" "$INSTDIR\AppRegGUI.exe"
 637                 ${EndIf}
 638
 639                 ${CreateWebLink} "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_SITE_MULDERS).url" "http://www.mulder.at.gg/"
 640                 ${CreateWebLink} "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_SITE_MPWIN32).url" "http://oss.netfarm.it/mplayer-win32.php"
 641                 ${CreateWebLink} "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_SITE_MPLAYER).url" "http://www.mplayerhq.hu/"
 642
 643                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk"
 644                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "SMPlayer.lnk" ${StdUtils.Const.ISV_PinToTaskbar}
 645                         DetailPrint 'Pin: "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" -> $R1'
 646                 ${EndIf}
 647         !insertmacro MUI_STARTMENU_WRITE_END
 648 SectionEnd
 649
 650 Section "-ApplyTweaks"
 651         ${PrintProgress} "$(MPLAYER_LANG_STATUS_TWEAKS)"
 652         DetailPrint "$(MPLAYER_LANG_APPLYING_TWEAKS)"
 653
 654         IntOp $0 $SelectedTweaks & 1
 655         ${If} $0 != 0
 656                 ${If} ${FileExists} "$INSTDIR\SMPlayer.ini"
 657                         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui" "gui" "SkinGUI"
 658                         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui" "iconset" "Gonzo"
 659                 ${EndIf}
 660         ${EndIf}
 661
 662         IntOp $0 $SelectedTweaks & 2
 663         ${If} $0 != 0
 664                 ${If} ${FileExists} "$INSTDIR\MPUI.ini"
 665                         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Params" "-vo gl:yuv=3 -lavdopts threads=$DetectedCPUCores"
 666                 ${EndIf}
 667                 ${If} ${FileExists} "$INSTDIR\SMPlayer.ini"
 668                         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General" "driver\vo" "gl:yuv=3"
 669                 ${EndIf}
 670         ${EndIf}
 671
 672         IntOp $0 $SelectedTweaks & 4
 673         ${If} $0 != 0
 674                 ${If} ${FileExists} "$INSTDIR\MPUI.ini"
 675                         ReadINIStr $1 "$INSTDIR\MPUI.ini" "MPUI" "Params"
 676                         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Params" "$1 -af volnorm=2"
 677                 ${EndIf}
 678                 ${If} ${FileExists} "$INSTDIR\SMPlayer.ini"
 679                         WriteINIStr "$INSTDIR\SMPlayer.ini" "defaults" "initial_volnorm" "true"
 680                 ${EndIf}
 681         ${EndIf}
 682 SectionEnd
 683
 684 Section "$(MPLAYER_LANG_COMPRESS_FILES)"
 685         SectionIn 1 2
 686         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_COMPRESS)"
 687
 688         File "/oname=$PLUGINSDIR\UPX.exe" "Utils\UPX.exe"
 689
 690         ${PackAll} "$INSTDIR" "*.exe"
 691         ${PackAll} "$INSTDIR" "*.dll"
 692         ${PackAll} "$INSTDIR\codecs" "*.acm"
 693         ${PackAll} "$INSTDIR\codecs" "*.ax"
 694         ${PackAll} "$INSTDIR\codecs" "*.dll"
 695         ${PackAll} "$INSTDIR\codecs" "*.qtx"
 696
 697         Delete "$PLUGINSDIR\UPX.exe"
 698 SectionEnd
 699
 700 Section "-Update Font Cache"
 701         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_FONTCACHE)"
 702
 703         SetShellVarContext current
 704         Delete "$APPDATA\fontconfig\cache\*.*"
 705         Delete "$LOCALAPPDATA\fontconfig\cache\*.*"
 706
 707         SetShellVarContext all
 708         Delete "$APPDATA\fontconfig\cache\*.*"
 709         Delete "$LOCALAPPDATA\fontconfig\cache\*.*"
 710
 711         File "/oname=$PLUGINSDIR\Sample.avi" "Resources\Sample.avi"
 712         DetailPrint "$(MPLAYER_LANG_UPDATING_FONTCACHE)"
 713         NsExec::Exec '"$INSTDIR\MPlayer.exe" -fontconfig -ass -vo null -ao null "$PLUGINSDIR\Sample.avi"'
 714         Delete "Resources\Sample.avi"
 715 SectionEnd
 716
 717 Section "-Update Registry"
 718         ${PrintProgress} "$(MPLAYER_LANG_STATUS_REGISTRY)"
 719         DetailPrint "$(MPLAYER_LANG_WRITING_REGISTRY)"
 720
 721         ; Clean up
 722         DeleteRegKey HKLM "${MPlayerRegPath}"
 723         DeleteRegKey HKCU "${MPlayerRegPath}"
 724         DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 725         DeleteRegValue HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 726
 727         ; Uninstaller
 728         WriteRegStr HKLM "${MPlayerRegPath}" "InstallLocation" "$INSTDIR"
 729         WriteRegStr HKLM "${MPlayerRegPath}" "UninstallString" '"$INSTDIR\Uninstall.exe"'
 730         WriteRegStr HKLM "${MPlayerRegPath}" "DisplayName" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 731         WriteRegStr HKLM "${MPlayerRegPath}" "DisplayIcon" "$INSTDIR\MPlayer.exe,0"
 732         WriteRegStr HKLM "${MPlayerRegPath}" "DisplayVersion" "${MPLAYER_DATE}"
 733         WriteRegStr HKLM "${MPlayerRegPath}" "URLInfoAbout" "http://mulder.at.gg/"
 734         WriteRegStr HKLM "${MPlayerRegPath}" "URLUpdateInfo" "http://mulder.at.gg/"
 735         WriteRegStr HKLM "${MPlayerRegPath}" "Publisher" "The MPlayer Team"
 736         WriteRegDWORD HKLM "${MPlayerRegPath}" "NoModify" 1
 737         WriteRegDWORD HKLM "${MPlayerRegPath}" "NoRepair" 1
 738
 739         ; Shell
 740         DeleteRegKey HKCR "MPlayerForWindowsV2.File"
 741         DeleteRegKey HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 742         DeleteRegKey HKCU "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 743         ${If} ${FileExists} "$INSTDIR\MPUI.exe"
 744                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\shell\open\command" "" '"$INSTDIR\MPUI.exe" "%1"'
 745                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\DefaultIcon" "" "$INSTDIR\MPUI.exe,0"
 746         ${EndIf}
 747         ${If} ${FileExists} "$INSTDIR\SMPlayer.exe"
 748                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\shell\open\command" "" '"$INSTDIR\SMPlayer.exe" "%1"'
 749                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\DefaultIcon" "" "$INSTDIR\SMPlayer.exe,1"
 750         ${EndIf}
 751
 752         ; Register App
 753         DeleteRegValue HKCU "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2"
 754         WriteRegStr HKLM "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2" "${MPlayerRegPath}\Capabilities"
 755
 756         ; Capabilities
 757         WriteRegStr HKLM "${MPlayerRegPath}\Capabilities" "ApplicationName" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 758         WriteRegStr HKLM "${MPlayerRegPath}\Capabilities" "ApplicationDescription" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 759         WriteRegStr HKLM "${MPlayerRegPath}\Capabilities" "ApplicationDescription" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 760
 761         ; File Associations
 762         ${RegisterFileExtCapability} "256"
 763         ${RegisterFileExtCapability} "3GP"
 764         ${RegisterFileExtCapability} "AAC"
 765         ${RegisterFileExtCapability} "ASF"
 766         ${RegisterFileExtCapability} "AVI"
 767         ${RegisterFileExtCapability} "BIN"
 768         ${RegisterFileExtCapability} "DAT"
 769         ${RegisterFileExtCapability} "DIVX"
 770         ${RegisterFileExtCapability} "EVO"
 771         ${RegisterFileExtCapability} "FLV"
 772         ${RegisterFileExtCapability} "M2V"
 773         ${RegisterFileExtCapability} "M2TS"
 774         ${RegisterFileExtCapability} "M4A"
 775         ${RegisterFileExtCapability} "MKA"
 776         ${RegisterFileExtCapability} "MKV"
 777         ${RegisterFileExtCapability} "MOV"
 778         ${RegisterFileExtCapability} "MP2"
 779         ${RegisterFileExtCapability} "MP3"
 780         ${RegisterFileExtCapability} "MP4"
 781         ${RegisterFileExtCapability} "MPEG"
 782         ${RegisterFileExtCapability} "MPG"
 783         ${RegisterFileExtCapability} "MPV"
 784         ${RegisterFileExtCapability} "NSV"
 785         ${RegisterFileExtCapability} "OGG"
 786         ${RegisterFileExtCapability} "OGM"
 787         ${RegisterFileExtCapability} "RM"
 788         ${RegisterFileExtCapability} "RMVB"
 789         ${RegisterFileExtCapability} "TS"
 790         ${RegisterFileExtCapability} "VOB"
 791         ${RegisterFileExtCapability} "WAV"
 792         ${RegisterFileExtCapability} "WEBM"
 793         ${RegisterFileExtCapability} "WMV"
 794
 795         ; Reset auto update interval
 796         DeleteRegValue HKLM "${MPlayerRegPath}" "LastUpdateCheck"
 797         DeleteRegValue HKCU "${MPlayerRegPath}" "LastUpdateCheck"
 798 SectionEnd
 799
 800 Section "$(MPLAYER_LANG_INST_AUTOUPDATE)" SECID_AUTOUPDATE
 801         SectionIn 1 2
 802         DetailPrint "$(MPLAYER_LANG_WRITING_REGISTRY)"
 803         WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2" '"$INSTDIR\Updater.exe" /L=$LANGUAGE /AutoCheck'
 804 SectionEnd
 805
 806 Section "-Protect Files"
 807         SetFileAttributes "$INSTDIR\MPlayer.exe" FILE_ATTRIBUTE_READONLY
 808         SetFileAttributes "$INSTDIR\dsnative.dll" FILE_ATTRIBUTE_READONLY
 809         SetFileAttributes "$INSTDIR\MPUI.exe" FILE_ATTRIBUTE_READONLY
 810         SetFileAttributes "$INSTDIR\SMPlayer.exe" FILE_ATTRIBUTE_READONLY
 811         SetFileAttributes "$INSTDIR\Updater.exe" FILE_ATTRIBUTE_READONLY
 812         SetFileAttributes "$INSTDIR\QtCore4.dll" FILE_ATTRIBUTE_READONLY
 813         SetFileAttributes "$INSTDIR\QtGui4.dll" FILE_ATTRIBUTE_READONLY
 814         SetFileAttributes "$INSTDIR\QtNetwork4.dll" FILE_ATTRIBUTE_READONLY
 815         SetFileAttributes "$INSTDIR\QtXml4.dll" FILE_ATTRIBUTE_READONLY
 816         SetFileAttributes "$INSTDIR\dsnative.dll" FILE_ATTRIBUTE_READONLY
 817         SetFileAttributes "$INSTDIR\libgcc_s_dw2-1.dll" FILE_ATTRIBUTE_READONLY
 818         SetFileAttributes "$INSTDIR\mingwm10.dll" FILE_ATTRIBUTE_READONLY
 819         SetFileAttributes "$INSTDIR\zlib1.dll" FILE_ATTRIBUTE_READONLY
 820 SectionEnd
 821
 822 Section "-Finished"
 823         ${PrintStatus} "$(MUI_TEXT_FINISH_TITLE)"
 824 SectionEnd
 825
 826
 827 ;--------------------------------------------------------------------------------
 828 ; UN-INSTALL SECTIONS
 829 ;--------------------------------------------------------------------------------
 830
 831 Section "Uninstall"
 832         SetOutPath "$INSTDIR"
 833         ${PrintProgress} "$(MPLAYER_LANG_STATUS_UNINSTALL)"
 834
 835         ; Startmenu
 836         !insertmacro MUI_STARTMENU_GETFOLDER Application $StartMenuFolder
 837         ${IfNot} "$StartMenuFolder" == ""
 838                 SetShellVarContext current
 839                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk"
 840                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "SMPlayer.lnk" ${StdUtils.Const.ISV_UnpinFromTaskbar}
 841                         DetailPrint 'Unpin: "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" -> $R1'
 842                 ${EndIf}
 843                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\*.*"
 844                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 845                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.url"
 846                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.pif"
 847                         RMDir "$SMPROGRAMS\$StartMenuFolder"
 848                 ${EndIf}
 849                 SetShellVarContext all
 850                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk"
 851                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "SMPlayer.lnk" ${StdUtils.Const.ISV_UnpinFromTaskbar}
 852                         DetailPrint 'Unpin: "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" -> $R1'
 853                 ${EndIf}
 854                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\*.*"
 855                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 856                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.url"
 857                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.pif"
 858                         RMDir "$SMPROGRAMS\$StartMenuFolder"
 859                 ${EndIf}
 860         ${EndIf}
 861
 862         ; Desktop icons
 863         Delete /REBOOTOK "$DESKTOP\MPUI.lnk"
 864         Delete /REBOOTOK "$DESKTOP\SMPlayer.lnk"
 865
 866         ; Files
 867         Delete /REBOOTOK "$INSTDIR\*.exe"
 868         Delete /REBOOTOK "$INSTDIR\*.dll"
 869         Delete /REBOOTOK "$INSTDIR\*.ini"
 870         Delete /REBOOTOK "$INSTDIR\*.txt"
 871         Delete /REBOOTOK "$INSTDIR\*.html"
 872         Delete /REBOOTOK "$INSTDIR\*.htm"
 873         Delete /REBOOTOK "$INSTDIR\*.ass"
 874         Delete /REBOOTOK "$INSTDIR\*.m3u8"
 875         Delete /REBOOTOK "$INSTDIR\*.tag"
 876         RMDir /r "$INSTDIR\codecs"
 877         RMDir /r "$INSTDIR\fonts"
 878         RMDir /r "$INSTDIR\imageformats"
 879         RMDir /r "$INSTDIR\legal_stuff"
 880         RMDir /r "$INSTDIR\locale"
 881         RMDir /r "$INSTDIR\mplayer"
 882         RMDir /r "$INSTDIR\shortcuts"
 883         RMDir /r "$INSTDIR\themes"
 884         RMDir /r "$INSTDIR\translations"
 885         RMDir "$INSTDIR"
 886
 887         ; Virtual Store
 888         ${GetVirtualStorePath} $0 "$INSTDIR"
 889         ${If} ${FileExists} "$0\*.*"
 890                 RMDir /r "$0"
 891         ${EndIf}
 892
 893         ; Registry Keys
 894         DeleteRegKey HKLM "${MPlayerRegPath}"
 895         DeleteRegKey HKCU "${MPlayerRegPath}"
 896         DeleteRegValue HKLM "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2"
 897         DeleteRegValue HKCU "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2"
 898
 899         ; Auto Update
 900         DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 901         DeleteRegValue HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 902
 903         ; Shell
 904         DeleteRegKey HKCR "MPlayerForWindowsV2.File"
 905         DeleteRegKey HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 906         DeleteRegKey HKCU "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 907
 908         ${PrintStatus} "$(MUI_UNTEXT_FINISH_TITLE)"
 909 SectionEnd
 910
 911
 912 ;--------------------------------------------------------------------------------
 913 ; SECTION SELECTION CHANGED
 914 ;--------------------------------------------------------------------------------
 915
 916 Function .onSelChange
 917         ${IfNot} ${SectionIsSelected} ${SECID_MPUI}
 918         ${AndIfNot} ${SectionIsSelected} ${SECID_SMPLAYER}
 919                 MessageBox MB_TOPMOST|MB_ICONEXCLAMATION "$(MPLAYER_LANG_SELCHANGE)"
 920                 SectionGetFlags ${SECID_MPUI} $0
 921                 IntOp $0 $0 | ${SF_SELECTED}
 922                 SectionSetFlags ${SECID_MPUI} $0
 923         ${EndIf}
 924
 925         ${IfNot} ${SectionIsSelected} ${SECID_AUTOUPDATE}
 926                 StrCpy $0 "nope"
 927                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_YESNO|MB_DEFBUTTON2 "$(MPLAYER_LANG_SEL_AUTOUPDATE)" IDNO ${||} StrCpy $0 "ok" ${|}
 928                 ${If} "$0" == "ok"
 929                         SectionGetFlags ${SECID_AUTOUPDATE} $0
 930                         IntOp $0 $0 | ${SF_SELECTED}
 931                         SectionSetFlags ${SECID_AUTOUPDATE} $0
 932                 ${EndIf}
 933         ${EndIf}
 934 FunctionEnd
 935
 936
 937 ;--------------------------------------------------------------------------------
 938 ; LOCKED-LIST PLUGIN
 939 ;--------------------------------------------------------------------------------
 940
 941 !macro LockedListPage_Function
 942         !insertmacro MUI_HEADER_TEXT "$(MPLAYER_LANG_LOCKEDLIST_HEADER)" "$(MPLAYER_LANG_LOCKEDLIST_TEXT)"
 943         LockedList::AddModule "\MPlayer.exe"
 944         LockedList::AddModule "\SMPlayer.exe"
 945         LockedList::AddModule "\MPUI.exe"
 946         LockedList::Dialog /autonext /ignore "$(MPLAYER_LANG_IGNORE)" /heading "$(MPLAYER_LANG_LOCKEDLIST_HEADING)" /noprograms "$(MPLAYER_LANG_LOCKEDLIST_NOPROG)" /searching  "$(MPLAYER_LANG_LOCKEDLIST_SEARCH)" /colheadings "$(MPLAYER_LANG_LOCKEDLIST_COLHDR1)" "$(MPLAYER_LANG_LOCKEDLIST_COLHDR2)"
 947         Pop $R0
 948 !macroend
 949
 950 Function LockedListPage_Show
 951         !insertmacro LockedListPage_Function
 952 FunctionEnd
 953
 954 Function un.LockedListPage_Show
 955         !insertmacro LockedListPage_Function
 956 FunctionEnd
 957
 958
 959 ;--------------------------------------------------------------------------------
 960 ; CUSTOME PAGE: CPU SELECTOR
 961 ;--------------------------------------------------------------------------------
 962
 963 Function SelectCPUPage_Show
 964         ; Detect CPU type, if not detected yet
 965         ${If} $DetectedCPUType < 2
 966         ${OrIf} $DetectedCPUType > 6
 967                 Call DetectCPUType
 968                 !insertmacro INSTALLOPTIONS_READ $0 "Page_CPU.ini" "Field $DetectedCPUType" "Text"
 969                 !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field $DetectedCPUType" "Text" "$0  <---"
 970         ${EndIf}
 971
 972         ; Make sure the current selection is valid
 973         ${IfThen} $SelectedCPUType < 2 ${|} StrCpy $SelectedCPUType $DetectedCPUType ${|}
 974         ${IfThen} $SelectedCPUType > 6 ${|} StrCpy $SelectedCPUType $DetectedCPUType ${|}
 975
 976         ; Translate
 977         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field 1" "Text" "$(MPLAYER_LANG_SELECT_CPU_TYPE)"
 978         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field 7" "Text" "$(MPLAYER_LANG_SELECT_CPU_HINT)"
 979
 980         ; Apply current selection to dialog
 981         ${For} $0 2 6
 982                 ${If} $0 == $SelectedCPUType
 983                         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field $0" "State" "1"
 984                 ${Else}
 985                         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field $0" "State" "0"
 986                 ${EndIf}
 987         ${Next}
 988
 989         ; Display dialog
 990         !insertmacro MUI_HEADER_TEXT "$(MPLAYER_LANG_SELECT_CPU_HEAD)" "$(MPLAYER_LANG_SELECT_CPU_TEXT)"
 991         !insertmacro INSTALLOPTIONS_DISPLAY "Page_CPU.ini"
 992
 993         ; Read new selection from dialog
 994         StrCpy $SelectedCPUType 0
 995         ${For} $0 2 6
 996                 !insertmacro INSTALLOPTIONS_READ $1 "Page_CPU.ini" "Field $0" "State"
 997                 ${IfThen} $1 == 1 ${|} StrCpy $SelectedCPUType $0 ${|}
 998         ${Next}
 999 FunctionEnd
1000
1001 Function SelectCPUPage_Validate
1002         ; Read new selection from dialog
1003         StrCpy $2 0
1004         ${For} $0 2 6
1005                 !insertmacro INSTALLOPTIONS_READ $1 "Page_CPU.ini" "Field $0" "State"
1006                 ${IfThen} $1 == 1 ${|} StrCpy $2 $0 ${|}
1007         ${Next}
1008
1009         ; Validate selection
1010         ${If} $2 < 2
1011         ${OrIf} $2 > 6
1012                 MessageBox MB_ICONSTOP "Oups, invalid selection detected!"
1013                 Abort
1014         ${EndIf}
1015 FunctionEnd
1016
1017 Function DetectCPUType
1018         StrCpy $DetectedCPUType 6 ;generic
1019         StrCpy $DetectedCPUCores 2
1020
1021         ${IfNot} ${Silent}
1022                 Banner::show /NOUNLOAD "$(MPLAYER_LANG_DETECTING)"
1023         ${EndIf}
1024
1025         ${CPUFeatures.GetCount} $0
1026         ${IfNot} $0 == "error"
1027                 StrCpy $DetectedCPUCores $0
1028         ${EndIf}
1029
1030         ; Debug Code
1031         !ifdef CPU_DETECT_DEBUG
1032                 ${CPUFeatures.GetVendor} $0
1033                 ${CPUFeatures.CheckFeature} "MMX1"   $1
1034                 ${CPUFeatures.CheckFeature} "3DNOW"  $2
1035                 ${CPUFeatures.CheckFeature} "SSE3"   $3
1036                 ${CPUFeatures.CheckFeature} "SSSE3"  $4
1037                 ${CPUFeatures.CheckFeature} "SSE4.2" $5
1038                 ${CPUFeatures.CheckFeature} "AVX1"   $6
1039                 ${CPUFeatures.CheckFeature} "FMA4"   $7
1040                 StrCpy $9 `Vendor = $0`
1041                 StrCpy $9 `$9$\n"MMX1" = $1`
1042                 StrCpy $9 `$9$\n"3DNOW" = $2`
1043                 StrCpy $9 `$9$\n"SSE3" = $3`
1044                 StrCpy $9 `$9$\n"SSSE3" = $4`
1045                 StrCpy $9 `$9$\n"SSE4.2" = $5`
1046                 StrCpy $9 `$9$\n"AVX1" = $6`
1047                 StrCpy $9 `$9$\n"FMA4" = $7`
1048                 MessageBox MB_TOPMOST `$9`
1049         !endif
1050
1051         ; Make sure we have at least MMX
1052         ${IfNot} ${CPUSupports} "MMX1"
1053                 Banner::destroy
1054                 Return
1055         ${EndIf}
1056
1057         ; Select the "best" model for Intel's
1058         ${If} ${CPUIsIntel}
1059                 ; Core2 (SSE3 + SSSE3)
1060                 ${If} ${CPUSupportsAll} "SSE3,SSSE3"
1061                         StrCpy $DetectedCPUType 2 ;
1062                 ${EndIf}
1063                 ; Nehalem (SSE3 + SSSE3 + SSE4.2)
1064                 ${If} ${CPUSupportsAll} "SSE3,SSSE3,SSE4.2"
1065                         StrCpy $DetectedCPUType 3
1066                 ${EndIf}
1067         ${EndIf}
1068
1069         ; Select the "best" model for AMD's
1070         ${If} ${CPUIsAMD}
1071                 ; K8+SSE3 (3DNow! + SSE3)
1072                 ${If} ${CPUSupportsAll} "3DNOW,SSE3"
1073                         StrCpy $DetectedCPUType 4
1074                 ${EndIf}
1075                 ; Bulldozer (SSE3 + SSSE3 + SSE4.2 + AVX + FMA4)
1076                 ${If} ${CPUSupportsAll} "SSE3,SSSE3,SSE4.2,AVX1,FMA4"
1077                         StrCpy $DetectedCPUType 5
1078                 ${EndIf}
1079         ${EndIf}
1080
1081         Banner::destroy
1082 FunctionEnd
1083
1084
1085 ;--------------------------------------------------------------------------------
1086 ; CUSTOME PAGE: TWEAKS
1087 ;--------------------------------------------------------------------------------
1088
1089 Function SetTweaksPage_Show
1090         ; Apply current selection to dialog
1091         StrCpy $0 1
1092         ${For} $1 2 4
1093                 IntOp $2 $0 & $SelectedTweaks
1094                 ${If} $2 != 0
1095                         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field $1" "State" "1"
1096                 ${Else}
1097                         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field $1" "State" "0"
1098                 ${EndIf}
1099                 IntOp $0 $0 << 1
1100         ${Next}
1101
1102         ; Translate
1103         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 1" "Text" "$(MPLAYER_LANG_TWEAKS_HINT)"
1104         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 2" "Text" "$(MPLAYER_LANG_TWEAKS_SKINNEDUI)"
1105         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 3" "Text" "$(MPLAYER_LANG_TWEAKS_OPENGL)"
1106         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 4" "Text" "$(MPLAYER_LANG_TWEAKS_VOLNORM)"
1107
1108         ; Display dialog
1109         !insertmacro MUI_HEADER_TEXT "$(MPLAYER_LANG_TWEAKS_HEAD)" "$(MPLAYER_LANG_TWEAKS_TEXT)"
1110         !insertmacro INSTALLOPTIONS_DISPLAY "Page_Tweaks.ini"
1111
1112         ; Read new selection from dialog
1113         StrCpy $0 1
1114         ${For} $1 2 4
1115                 !insertmacro INSTALLOPTIONS_READ $2 "Page_Tweaks.ini" "Field $1" "State"
1116                 ${IfThen} $2 == 1 ${|} IntOp $SelectedTweaks $SelectedTweaks | $0 ${|}
1117                 IntOp $0 $0 << 1
1118         ${Next}
1119 FunctionEnd
1120
1121
1122 ;--------------------------------------------------------------------------------
1123 ; CHECK FOR UPDATE MODE
1124 ;--------------------------------------------------------------------------------
1125
1126 !macro EnablePathEditable flag show_msg
1127         ${IfNot} $NotUpdateInstall == ${flag}
1128                 !if ${show_msg} == 1
1129                         MessageBox MB_OK|MB_ICONINFORMATION "$(MPLAYER_LANG_FORCE_UPDATE)" /SD IDOK
1130                 !endif
1131                 StrCpy $NotUpdateInstall ${flag}
1132         ${EndIf}
1133         FindWindow $1 "#32770" "" $HWNDPARENT
1134         GetDlgItem $2 $1 1019
1135         EnableWindow $2 ${flag}
1136         GetDlgItem $2 $1 1001
1137         EnableWindow $2 ${flag}
1138 !macroend
1139
1140 Function CheckForUpdate
1141         ${StdUtils.GetParameter} $0 "Update" "?"
1142         ${IfNot} "$0" == "?"
1143                 !insertmacro EnablePathEditable 0 0
1144                 Return
1145         ${EndIf}
1146
1147         ${If} ${FileExists} "$INSTDIR\MPlayer.exe"
1148                 !insertmacro EnablePathEditable 0 1
1149                 Return
1150         ${EndIf}
1151
1152         !insertmacro EnablePathEditable 1 0
1153 FunctionEnd
1154
1155
1156 ;--------------------------------------------------------------------------------
1157 ; FINISHED
1158 ;--------------------------------------------------------------------------------
1159
1160 Function RunAppFunction
1161         !insertmacro DisableNextButton $R0
1162         ${If} ${FileExists} "$INSTDIR\SMPlayer.exe"
1163                 ${StdUtils.ExecShellAsUser} $R0 "$INSTDIR\SMPlayer.exe" "open" "http://lounge-office.rautemusik.fm/"
1164         ${Else}
1165                 ${StdUtils.ExecShellAsUser} $R0 "$INSTDIR\MPUI.exe" "open" "http://lounge-office.rautemusik.fm/"
1166         ${EndIf}
1167 FunctionEnd
1168
1169 Function ShowReadmeFunction
1170         !insertmacro DisableNextButton $R0
1171         ${StdUtils.ExecShellAsUser} $R0 "$INSTDIR\Readme.html" "open" ""
1172 FunctionEnd
1173
1174 Function .onInstSuccess
1175         ${StdUtils.ExecShellAsUser} $R0 "$SMPROGRAMS\$StartMenuFolder" "explore" ""
1176 FunctionEnd
1177
1178
1179 ### EOF ###