MPUI_Setup.nsi

   1 ; ///////////////////////////////////////////////////////////////////////////////
   2 ; // MPlayer for Windows - Install Script
   3 ; // Copyright (C) 2004-2013 LoRd_MuldeR <MuldeR2@GMX.de>
   4 ; //
   5 ; // This program is free software; you can redistribute it and/or modify
   6 ; // it under the terms of the GNU General Public License as published by
   7 ; // the Free Software Foundation; either version 2 of the License, or
   8 ; // (at your option) any later version.
   9 ; //
  10 ; // This program is distributed in the hope that it will be useful,
  11 ; // but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ; // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ; // GNU General Public License for more details.
  14 ; //
  15 ; // You should have received a copy of the GNU General Public License along
  16 ; // with this program; if not, write to the Free Software Foundation, Inc.,
  17 ; // 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18 ; //
  19 ; // http://www.gnu.org/licenses/gpl-2.0.txt
  20 ; ///////////////////////////////////////////////////////////////////////////////
  21
  22
  23 ;--------------------------------------------------------------------------------
  24 ; BASIC DEFINES
  25 ;--------------------------------------------------------------------------------
  26
  27 !ifndef NSIS_UNICODE
  28   !error "NSIS_UNICODE is undefined, please compile with Unicode NSIS !!!"
  29 !endif
  30
  31 !ifndef MPLAYER_BUILDNO
  32   !error "MPLAYER_BUILDNO is not defined !!!"
  33 !endif
  34
  35 !ifndef MPLAYER_REVISION
  36   !error "MPLAYER_REVISION is not defined !!!"
  37 !endif
  38
  39 !ifndef MPLAYER_DATE
  40   !error "MPLAYER_DATE is not defined !!!"
  41 !endif
  42
  43 !ifndef SMPLAYER_VERSION
  44   !error "SMPLAYER_VERSION is not defined !!!"
  45 !endif
  46
  47 !ifndef MPUI_VERSION
  48   !error "MPUI_VERSION is not defined !!!"
  49 !endif
  50
  51 !ifndef CODECS_DATE
  52   !error "CODECS_DATE is not defined !!!"
  53 !endif
  54
  55 !ifndef MPLAYER_OUTFILE
  56   !error "MPLAYER_OUTFILE is not defined !!!"
  57 !endif
  58
  59 !ifndef UPX_PATH
  60   !error "UPX_PATH is not defined !!!"
  61 !endif
  62
  63 ; UUID
  64 !define MPlayerRegPath "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{97D341C8-B0D1-4E4A-A49A-C30B52F168E9}"
  65
  66 ; Web-Site
  67 !define MPlayerWebSite "http://mplayerhq.hu/"
  68
  69
  70 ;--------------------------------------------------------------------------------
  71 ; INSTALLER ATTRIBUTES
  72 ;--------------------------------------------------------------------------------
  73
  74 RequestExecutionLevel admin
  75 ShowInstDetails show
  76 ShowUninstDetails show
  77
  78 Name "$(MPLAYER_LANG_MPLAYER_WIN32) ${MPLAYER_DATE} (Build #${MPLAYER_BUILDNO})"
  79 Caption "$(MPLAYER_LANG_MPLAYER_WIN32) ${MPLAYER_DATE} (Build #${MPLAYER_BUILDNO})"
  80 BrandingText "MPlayer-Win32 (Build #${MPLAYER_BUILDNO})"
  81 InstallDir "$PROGRAMFILES\MPlayer for Windows"
  82 InstallDirRegKey HKLM "${MPlayerRegPath}" "InstallLocation"
  83 OutFile "${MPLAYER_OUTFILE}"
  84
  85
  86 ;--------------------------------------------------------------------------------
  87 ; COMPRESSOR
  88 ;--------------------------------------------------------------------------------
  89
  90 SetCompressor /SOLID /FINAL LZMA
  91 SetCompressorDictSize 112
  92
  93 !packhdr "$%TEMP%\exehead.tmp" '"${UPX_PATH}\upx.exe" --brute "$%TEMP%\exehead.tmp"'
  94
  95
  96 ;--------------------------------------------------------------------------------
  97 ; RESERVE FILES
  98 ;--------------------------------------------------------------------------------
  99
 100 ReserveFile "${NSISDIR}\Plugins\Aero.dll"
 101 ReserveFile "${NSISDIR}\Plugins\Banner.dll"
 102 ReserveFile "${NSISDIR}\Plugins\CPUFeatures.dll"
 103 ReserveFile "${NSISDIR}\Plugins\InstallOptions.dll"
 104 ReserveFile "${NSISDIR}\Plugins\LangDLL.dll"
 105 ReserveFile "${NSISDIR}\Plugins\LockedList.dll"
 106 ReserveFile "${NSISDIR}\Plugins\nsDialogs.dll"
 107 ReserveFile "${NSISDIR}\Plugins\nsExec.dll"
 108 ReserveFile "${NSISDIR}\Plugins\StartMenu.dll"
 109 ReserveFile "${NSISDIR}\Plugins\StdUtils.dll"
 110 ReserveFile "${NSISDIR}\Plugins\System.dll"
 111 ReserveFile "${NSISDIR}\Plugins\UserInfo.dll"
 112 ReserveFile "Dialogs\Page_CPU.ini"
 113 ReserveFile "Resources\Splash.gif"
 114
 115
 116 ;--------------------------------------------------------------------------------
 117 ; INCLUDES
 118 ;--------------------------------------------------------------------------------
 119
 120 !include `MUI2.nsh`
 121 !include `InstallOptions.nsh`
 122 !include `WinVer.nsh`
 123 !include `x64.nsh`
 124 !include `StrFunc.nsh`
 125 !include `StdUtils.nsh`
 126 !include `CPUFeatures.nsh`
 127 !include `MPUI_Common.nsh`
 128
 129 ; Enable functions
 130 ${StrRep}
 131
 132
 133 ;--------------------------------------------------------------------------------
 134 ; GLOBAL VARIABLES
 135 ;--------------------------------------------------------------------------------
 136
 137 Var StartMenuFolder
 138 Var DetectedCPUType
 139 Var DetectedCPUCores
 140 Var SelectedCPUType
 141 Var SelectedTweaks
 142 Var NotUpdateInstall
 143
 144
 145 ;--------------------------------------------------------------------------------
 146 ; VERSION INFO
 147 ;--------------------------------------------------------------------------------
 148
 149 !searchreplace PRODUCT_VERSION_DATE "${MPLAYER_DATE}" "-" "."
 150 VIProductVersion "${PRODUCT_VERSION_DATE}.${MPLAYER_BUILDNO}"
 151
 152 VIAddVersionKey "Author" "LoRd_MuldeR <mulder2@gmx.de>"
 153 VIAddVersionKey "Comments" "This program is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation; either version 2 of the License, or (at your option) any later version."
 154 VIAddVersionKey "CompanyName" "Free Software Foundation"
 155 VIAddVersionKey "FileDescription" "MPlayer for Windows (Build #${MPLAYER_BUILDNO})"
 156 VIAddVersionKey "FileVersion" "${PRODUCT_VERSION_DATE}.${MPLAYER_BUILDNO}"
 157 VIAddVersionKey "LegalCopyright" "Copyright 2000-2013 The MPlayer Project"
 158 VIAddVersionKey "LegalTrademarks" "GNU"
 159 VIAddVersionKey "OriginalFilename" "MPUI-Setup.exe"
 160 VIAddVersionKey "ProductName" "MPlayer for Windows"
 161 VIAddVersionKey "ProductVersion" "Build #${MPLAYER_BUILDNO} (${MPLAYER_DATE})"
 162 VIAddVersionKey "Website" "${MPlayerWebSite}"
 163
 164
 165 ;--------------------------------------------------------------------------------
 166 ; MUI2 INTERFACE SETTINGS
 167 ;--------------------------------------------------------------------------------
 168
 169 !define MUI_ABORTWARNING
 170 !define MUI_STARTMENUPAGE_REGISTRY_ROOT HKLM
 171 !define MUI_STARTMENUPAGE_REGISTRY_KEY "${MPlayerRegPath}"
 172 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "StartmenuFolder"
 173 !define MUI_LANGDLL_REGISTRY_ROOT HKLM
 174 !define MUI_LANGDLL_REGISTRY_KEY "${MPlayerRegPath}"
 175 !define MUI_LANGDLL_REGISTRY_VALUENAME "SetupLanguage"
 176 !define MUI_STARTMENUPAGE_DEFAULTFOLDER "MPlayer for Windows"
 177 !define MUI_FINISHPAGE_NOAUTOCLOSE
 178 !define MUI_UNFINISHPAGE_NOAUTOCLOSE
 179 !define MUI_FINISHPAGE_RUN
 180 !define MUI_FINISHPAGE_RUN_FUNCTION RunAppFunction
 181 !define MUI_FINISHPAGE_SHOWREADME
 182 !define MUI_FINISHPAGE_SHOWREADME_FUNCTION ShowReadmeFunction
 183 !define MUI_FINISHPAGE_LINK ${MPlayerWebSite}
 184 !define MUI_FINISHPAGE_LINK_LOCATION ${MPlayerWebSite}
 185 !define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\orange-install.ico"
 186 !define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\orange-uninstall.ico"
 187 !define MUI_WELCOMEFINISHPAGE_BITMAP "Artwork\wizard.bmp"
 188 !define MUI_UNWELCOMEFINISHPAGE_BITMAP "Artwork\wizard-un.bmp"
 189 !define MUI_HEADERIMAGE
 190 !define MUI_HEADERIMAGE_BITMAP "Artwork\header.bmp"
 191 !define MUI_HEADERIMAGE_UNBITMAP "Artwork\header-un.bmp"
 192 !define MUI_LANGDLL_ALLLANGUAGES
 193 !define MUI_CUSTOMFUNCTION_GUIINIT MyGuiInit
 194 !define MUI_CUSTOMFUNCTION_UNGUIINIT un.MyGuiInit
 195 !define MUI_LANGDLL_ALWAYSSHOW
 196 !define MUI_COMPONENTSPAGE_SMALLDESC
 197
 198
 199 ;--------------------------------------------------------------------------------
 200 ; MUI2 PAGE SETUP
 201 ;--------------------------------------------------------------------------------
 202
 203 ; Installer
 204 !define MUI_WELCOMEPAGE_TITLE_3LINES
 205 !define MUI_FINISHPAGE_TITLE_3LINES
 206 !insertmacro MUI_PAGE_WELCOME
 207 !insertmacro MUI_PAGE_LICENSE "Docs\License.txt"
 208 !define MUI_PAGE_CUSTOMFUNCTION_SHOW CheckForUpdate
 209 !insertmacro MUI_PAGE_DIRECTORY
 210 !insertmacro  MUI_PAGE_COMPONENTS
 211 !insertmacro MUI_PAGE_STARTMENU Application $StartMenuFolder
 212 Page Custom SelectCPUPage_Show SelectCPUPage_Validate
 213 Page Custom SetTweaksPage_Show
 214 Page Custom LockedListPage_Show
 215 !insertmacro MUI_PAGE_INSTFILES
 216 !insertmacro MUI_PAGE_FINISH
 217
 218 ; Un-Installer
 219 !define MUI_WELCOMEPAGE_TITLE_3LINES
 220 !define MUI_FINISHPAGE_TITLE_3LINES
 221 !insertmacro MUI_UNPAGE_WELCOME
 222 !insertmacro MUI_UNPAGE_CONFIRM
 223 UninstPage Custom un.LockedListPage_Show
 224 !insertmacro MUI_UNPAGE_INSTFILES
 225 !insertmacro MUI_UNPAGE_FINISH
 226
 227
 228 ;--------------------------------------------------------------------------------
 229 ; LANGUAGE
 230 ;--------------------------------------------------------------------------------
 231
 232 !insertmacro MUI_LANGUAGE "English"
 233 !insertmacro MUI_LANGUAGE "German"
 234
 235 ; Translation files
 236 !include "Language\MPUI_EN.nsh"
 237 !include "Language\MPUI_DE.nsh"
 238
 239
 240 ;--------------------------------------------------------------------------------
 241 ; INSTALL TYPES
 242 ;--------------------------------------------------------------------------------
 243
 244 InstType "$(MPLAYER_LANG_INSTTYPE_COMPLETE)"
 245 InstType "$(MPLAYER_LANG_INSTTYPE_MINIMAL)"
 246
 247
 248 ;--------------------------------------------------------------------------------
 249 ; INITIALIZATION
 250 ;--------------------------------------------------------------------------------
 251
 252 Function .onInit
 253         StrCpy $SelectedCPUType 0
 254         StrCpy $DetectedCPUType 0
 255         StrCpy $DetectedCPUCores 0
 256         StrCpy $SelectedTweaks 0
 257         StrCpy $NotUpdateInstall 1
 258
 259         InitPluginsDir
 260
 261         ; --------
 262
 263         System::Call 'kernel32::CreateMutexA(i 0, i 0, t "{B800490C-C100-4B12-9F09-1A54DF063049}") i .r1 ?e'
 264         Pop $0
 265         ${If} $0 <> 0
 266                 MessageBox MB_ICONSTOP|MB_TOPMOST "Oups, the installer is already running!"
 267                 Quit
 268         ${EndIf}
 269
 270         ; --------
 271
 272         # Running on Windows NT family?
 273         ${IfNot} ${IsNT}
 274                 MessageBox MB_TOPMOST|MB_ICONSTOP "Sorry, this application does *not* support Windows 9x or Windows ME!"
 275                 ExecShell "open" "http://windows.microsoft.com/"
 276                 Quit
 277         ${EndIf}
 278
 279         # Running on Windows XP or later?
 280         ${If} ${AtMostWin2000}
 281                 MessageBox MB_TOPMOST|MB_ICONSTOP "Sorry, but your operating system is *not* supported anymore.$\nInstallation will be aborted!$\n$\nThe minimum required platform is Windows XP."
 282                 ExecShell "open" "http://windows.microsoft.com/"
 283                 Quit
 284         ${EndIf}
 285
 286         ; --------
 287
 288         UserInfo::GetAccountType
 289         Pop $0
 290         ${If} $0 != "Admin"
 291                 MessageBox MB_ICONSTOP|MB_TOPMOST "Your system requires administrative permissions in order to install this software."
 292                 SetErrorLevel 740 ;ERROR_ELEVATION_REQUIRED
 293                 Quit
 294         ${EndIf}
 295
 296         ; --------
 297
 298         !insertmacro MUI_LANGDLL_DISPLAY
 299
 300         !insertmacro INSTALLOPTIONS_EXTRACT_AS "Dialogs\Page_CPU.ini"    "Page_CPU.ini"
 301         !insertmacro INSTALLOPTIONS_EXTRACT_AS "Dialogs\Page_Tweaks.ini" "Page_Tweaks.ini"
 302
 303         !ifdef PRE_RELEASE
 304                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL|MB_DEFBUTTON2 "Note: This is an early pre-release version for test only!" IDCANCEL ${||} Quit ${|}
 305         !endif
 306
 307         ; --------
 308
 309         ${IfNot} ${Silent}
 310                 File "/oname=$PLUGINSDIR\Splash.gif" "Resources\Splash.gif"
 311                 newadvsplash::show 3000 1000 500 -1 /NOCANCEL "$PLUGINSDIR\Splash.gif"
 312                 Delete /REBOOTOK "$PLUGINSDIR\Splash.gif"
 313         ${EndIf}
 314 FunctionEnd
 315
 316 Function un.onInit
 317         InitPluginsDir
 318
 319         System::Call 'kernel32::CreateMutexA(i 0, i 0, t "{B800490C-C100-4B12-9F09-1A54DF063049}") i .r1 ?e'
 320         Pop $0
 321         ${If} $0 <> 0
 322                 MessageBox MB_ICONSTOP|MB_TOPMOST "Sorry, the un-installer is already running!"
 323                 Quit
 324         ${EndIf}
 325
 326         ; --------
 327
 328         UserInfo::GetAccountType
 329         Pop $0
 330         ${If} $0 != "Admin"
 331                 MessageBox MB_ICONSTOP|MB_TOPMOST "Your system requires administrative permissions in order to un-install this software."
 332                 SetErrorLevel 740 ;ERROR_ELEVATION_REQUIRED
 333                 Quit
 334         ${EndIf}
 335
 336         ; --------
 337
 338         !insertmacro MUI_LANGDLL_DISPLAY
 339 FunctionEnd
 340
 341
 342 ;--------------------------------------------------------------------------------
 343 ; GUI INITIALIZATION
 344 ;--------------------------------------------------------------------------------
 345
 346 Function MyGuiInit
 347         StrCpy $0 $HWNDPARENT
 348         System::Call "user32::SetWindowPos(i r0, i -1, i 0, i 0, i 0, i 0, i 3)"
 349         Aero::Apply
 350 FunctionEnd
 351
 352 Function un.MyGuiInit
 353         StrCpy $0 $HWNDPARENT
 354         System::Call "user32::SetWindowPos(i r0, i -1, i 0, i 0, i 0, i 0, i 3)"
 355         Aero::Apply
 356 FunctionEnd
 357
 358
 359 ;--------------------------------------------------------------------------------
 360 ; INSTALL SECTIONS
 361 ;--------------------------------------------------------------------------------
 362
 363 Section "-Clean Up"
 364         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_CLEAN)"
 365
 366         SetShellVarContext all
 367         SetOutPath "$INSTDIR"
 368
 369         ; Uninstall old version (aka "Setup v1")
 370         ClearErrors
 371         ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{DB9E4EAB-2717-499F-8D56-4CC8A644AB60}" "InstallLocation"
 372         ${IfNot} ${Errors}
 373                 MessageBox MB_ICONINFORMATION|MB_OK "$(MPLAYER_LANG_UNINSTALL_OLDVER)"
 374                 File "/oname=$PLUGINSDIR\Uninstall-V1.exe" "Resources\Uninstall-V1.exe"
 375                 HideWindow
 376                 ExecWait '"$PLUGINSDIR\Uninstall-V1.exe" _?=$0'
 377                 Delete /REBOOTOK "$PLUGINSDIR\Uninstall-V1.exe"
 378                 BringToFront
 379         ${EndIf}
 380
 381         ; Clean registry
 382         DeleteRegKey HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{DB9E4EAB-2717-499F-8D56-4CC8A644AB60}"
 383         DeleteRegKey HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{DB9E4EAB-2717-499F-8D56-4CC8A644AB60}"
 384         DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_UpdateReminder"
 385         DeleteRegValue HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_UpdateReminder"
 386
 387         ; Make sure MPlayer isn't running
 388         ${Do}
 389                 ClearErrors
 390                 Delete "$INSTDIR\MPlayer.exe"
 391                 Delete "$INSTDIR\SMPlayer.exe"
 392                 Delete "$INSTDIR\MPUI.exe"
 393                 ${If} ${Errors}
 394                         ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL "$(MPLAYER_LANG_STILL_RUNNING)" IDCANCEL ${||} Abort ${|}
 395                 ${Else}
 396                         ${Break}
 397                 ${EndIf}
 398         ${Loop}
 399
 400         ; Clean the install folder
 401         Delete "$INSTDIR\*.exe"
 402         Delete "$INSTDIR\*.dll"
 403         Delete "$INSTDIR\*.ini"
 404         Delete "$INSTDIR\*.txt"
 405         Delete "$INSTDIR\*.html"
 406         Delete "$INSTDIR\*.htm"
 407         Delete "$INSTDIR\*.ass"
 408         Delete "$INSTDIR\*.m3u8"
 409         Delete "$INSTDIR\*.tag"
 410         Delete "$INSTDIR\mplayer\config"
 411         Delete "$INSTDIR\mplayer\*.conf"
 412
 413         ; Now deal with Virtual Store
 414         ${GetVirtualStorePath} $0 "$INSTDIR"
 415         Delete "$0\*.ini"
 416         Delete "$0\*.ass"
 417         Delete "$0\*.m3u8"
 418         Delete "$0\mplayer\config"
 419         Delete "$0\mplayer\*.conf"
 420 SectionEnd
 421
 422 Section "!MPlayer r${MPLAYER_REVISION}" SECID_MPLAYER
 423         SectionIn 1 2 RO
 424         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_MPLAYER)"
 425         SetOutPath "$INSTDIR"
 426
 427         ; Detect
 428         ${If} ${Silent}
 429                 Call DetectCPUType
 430                 StrCpy $SelectedCPUType $DetectedCPUType
 431         ${EndIf}
 432
 433         ; MPlayer.exe
 434         ${Select} $SelectedCPUType
 435                 ${Case} "2"
 436                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): core2"
 437                         File "Builds\MPlayer-core2\MPlayer.exe"
 438                 ${Case} "3"
 439                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): corei7"
 440                         File "Builds\MPlayer-corei7\MPlayer.exe"
 441                 ${Case} "4"
 442                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): k8-sse3"
 443                         File "Builds\MPlayer-k8-sse3\MPlayer.exe"
 444                 ${Case} "5"
 445                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): bdver1"
 446                         File "Builds\MPlayer-bdver1\MPlayer.exe"
 447                 ${Case} "6"
 448                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): generic"
 449                         File "Builds\MPlayer-generic\MPlayer.exe"
 450                 ${CaseElse}
 451                         MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OK "Internal error: Invalid CPU type selection detected!"
 452                         Abort
 453         ${EndSelect}
 454
 455         ; Utilities
 456         File ".Compile\Updater.exe"
 457         File "Resources\AppRegGUI.exe"
 458
 459         ; Other MPlayer-related files
 460         File "Builds\MPlayer-generic\dsnative.dll"
 461         SetOutPath "$INSTDIR\mplayer"
 462         File "Builds\MPlayer-generic\mplayer\config"
 463         SetOutPath "$INSTDIR\fonts"
 464         File "Builds\MPlayer-generic\fonts\fonts.conf"
 465         SetOutPath "$INSTDIR\fonts\conf.d"
 466         File "Builds\MPlayer-generic\fonts\conf.d\*.conf"
 467
 468         ; Documents
 469         SetOutPath "$INSTDIR"
 470         File "GPL.txt"
 471         File "/oname=Manual.html" "Builds\MPlayer-generic\MPlayer.man.html"
 472         File "Docs\Readme.html"
 473         SetOutPath "$INSTDIR\legal_stuff"
 474         File "Docs\legal_stuff\*.txt"
 475
 476         ; Write version tag
 477         ${Do}
 478                 ClearErrors
 479                 Delete "$INSTDIR\version.tag"
 480                 ${If} ${Errors}
 481                         ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL "$(MPLAYER_LANG_TAG_WRITE)" IDCANCEL ${||} Abort ${|}
 482                 ${Else}
 483                         ${Break}
 484                 ${EndIf}
 485         ${Loop}
 486         WriteINIStr "$INSTDIR\version.tag" "mplayer_version" "build_no" "${MPLAYER_BUILDNO}"
 487         WriteINIStr "$INSTDIR\version.tag" "mplayer_version" "pkg_date" "${MPLAYER_DATE}"
 488         SetFileAttributes "$INSTDIR\version.tag" FILE_ATTRIBUTE_READONLY
 489
 490         ; Set file access rights
 491         ${MakeFilePublic} "$INSTDIR\mplayer\config"
 492         ${MakeFilePublic} "$INSTDIR\fonts\fonts.conf"
 493 SectionEnd
 494
 495 Section "!MPUI $(MPLAYER_LANG_FRONT_END) v${MPUI_VERSION}" SECID_MPUI
 496         SectionIn 1 2
 497         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_MPUI)"
 498
 499         ; Extract files
 500         SetOutPath "$INSTDIR"
 501         File "MPUI\MPUI.exe"
 502
 503         ; Extract locales
 504         SetOutPath "$INSTDIR\locale"
 505         File "MPUI\locale\*.txt"
 506
 507         ; Set file access rights
 508         ${MakeFilePublic} "$INSTDIR\MPUI.ini"
 509
 510         ; Setup initial config
 511         ClearErrors
 512         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Params" "-vo direct3d -lavdopts threads=$DetectedCPUCores"
 513         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Locale" "$(MPLAYER_LANG_MPUI_DEFAULT_LANGUAGE)"
 514         ${If} ${Errors}
 515                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONSTOP|MB_DEFBUTTON2|MB_OKCANCEL "$(MPLAYER_LANG_CONFIG_MPUI)" IDCANCEL ${||} Abort ${|}
 516         ${EndIf}
 517 SectionEnd
 518
 519 Section "!SMPlayer $(MPLAYER_LANG_FRONT_END) v${SMPLAYER_VERSION}" SECID_SMPLAYER
 520         SectionIn 1
 521         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_CODECS)"
 522
 523         ; SMPlayer files
 524         SetOutPath "$INSTDIR"
 525         File "SMPlayer\SMPlayer.exe"
 526         File "SMPlayer\libgcc_s_dw2-1.dll"
 527         File "SMPlayer\mingwm10.dll"
 528         File "SMPlayer\QtCore4.dll"
 529         File "SMPlayer\QtGui4.dll"
 530         File "SMPlayer\QtNetwork4.dll"
 531         File "SMPlayer\QtXml4.dll"
 532         File "SMPlayer\zlib1.dll"
 533
 534         ; Additional SMPlayer files
 535         SetOutPath "$INSTDIR\translations"
 536         File "SMPlayer\translations\*.qm"
 537         SetOutPath "$INSTDIR\imageformats"
 538         File "SMPlayer\imageformats\*.dll"
 539         SetOutPath "$INSTDIR\shortcuts"
 540         File "SMPlayer\shortcuts\*.keys"
 541         SetOutPath "$INSTDIR\themes"
 542         File /r "SMPlayer\themes\*.css"
 543         File /r "SMPlayer\themes\*.png"
 544
 545         ; Set file access rights
 546         ${MakeFilePublic} "$INSTDIR\SMPlayer.ini"
 547         ${MakeFilePublic} "$INSTDIR\favorites.m3u8"
 548         ${MakeFilePublic} "$INSTDIR\radio.m3u8"
 549         ${MakeFilePublic} "$INSTDIR\tv.m3u8"
 550         ${MakeFilePublic} "$INSTDIR\styles.ass"
 551         ${MakeFilePublic} "$INSTDIR\shortcuts\default.keys"
 552
 553         ; Setup initial config
 554         ${StrRep} $0 "$INSTDIR\MPlayer.exe" "\" "/"
 555         ClearErrors
 556         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"    "mplayer_bin"          "$0"
 557         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"    "driver\vo"            "direct3d"
 558         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"    "autosync"             "true"
 559         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"    "autosync_factor"      "30"
 560         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"    "use_audio_equalizer"  "false"
 561         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"    "use_scaletempo"       "0"
 562         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"    "file_settings_method" "normal"
 563         WriteINIStr "$INSTDIR\SMPlayer.ini" "performance" "threads"              "$DetectedCPUCores"
 564         WriteINIStr "$INSTDIR\SMPlayer.ini" "performance" "priority"             "1"
 565         WriteINIStr "$INSTDIR\SMPlayer.ini" "performance" "frame_drop"           "true"
 566         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui"         "gui"                  "DefaultGUI"
 567         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui"         "iconset"              "Oxygen-Refit"
 568         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui"         "style"                "Plastique"
 569
 570         ${If} ${Errors}
 571                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONSTOP|MB_DEFBUTTON2|MB_OKCANCEL "$(MPLAYER_LANG_CONFIG_SMPLAYER)" IDCANCEL ${||} Abort ${|}
 572         ${EndIf}
 573 SectionEnd
 574
 575 Section "!$(MPLAYER_LANG_BIN_CODECS) (${CODECS_DATE})"
 576         SectionIn 1
 577         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_CODECS)"
 578
 579         SetOutPath "$INSTDIR\codecs"
 580
 581         File "Codecs\*.0"
 582         File "Codecs\*.acm"
 583         File "Codecs\*.ax"
 584         File "Codecs\*.dll"
 585         File "Codecs\*.qtx"
 586         File "Codecs\*.so"
 587         File "Codecs\*.vwp"
 588         File "Codecs\*.xa"
 589 SectionEnd
 590
 591 Section "-Write Uninstaller"
 592         ${PrintProgress} "$(MPLAYER_LANG_STATUS_MAKEUNINST)"
 593         WriteUninstaller "$INSTDIR\Uninstall.exe"
 594 SectionEnd
 595
 596 Section "-Create Shortcuts"
 597         !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
 598                 ${PrintProgress} "$(MPLAYER_LANG_STATUS_SHORTCUTS)"
 599                 CreateDirectory "$SMPROGRAMS\$StartMenuFolder"
 600
 601                 SetShellVarContext current
 602                 Delete "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 603                 Delete "$SMPROGRAMS\$StartMenuFolder\*.pif"
 604                 Delete "$SMPROGRAMS\$StartMenuFolder\*.url"
 605
 606                 SetShellVarContext all
 607                 Delete "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 608                 Delete "$SMPROGRAMS\$StartMenuFolder\*.pif"
 609                 Delete "$SMPROGRAMS\$StartMenuFolder\*.url"
 610
 611                 ${If} ${FileExists} "$INSTDIR\MPUI.exe"
 612                         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\MPUI.lnk" "$INSTDIR\MPUI.exe"
 613                         CreateShortCut "$DESKTOP\MPUI.lnk" "$INSTDIR\MPUI.exe"
 614                 ${EndIf}
 615                 ${If} ${FileExists} "$INSTDIR\SMPlayer.exe"
 616                         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" "$INSTDIR\SMPlayer.exe"
 617                         CreateShortCut "$DESKTOP\SMPlayer.lnk" "$INSTDIR\SMPlayer.exe"
 618                 ${EndIf}
 619
 620                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_UPDATE).lnk" "$INSTDIR\Updater.exe" "/L=$LANGUAGE"
 621                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_README).lnk" "$INSTDIR\Readme.html"
 622                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_MANUAL).lnk" "$INSTDIR\Manual.html"
 623
 624                 ${If} ${AtLeastWinVista}
 625                         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_APPREG).lnk" "$INSTDIR\AppRegGUI.exe"
 626                 ${EndIf}
 627
 628                 ${CreateWebLink} "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_SITE_MULDERS).url" "http://www.mulder.at.gg/"
 629                 ${CreateWebLink} "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_SITE_MPWIN32).url" "http://oss.netfarm.it/mplayer-win32.php"
 630                 ${CreateWebLink} "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_SITE_MPLAYER).url" "http://www.mplayerhq.hu/"
 631
 632                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk"
 633                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "SMPlayer.lnk" ${StdUtils.Const.ISV_PinToTaskbar}
 634                         DetailPrint 'Pin: "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" -> $R1'
 635                 ${EndIf}
 636         !insertmacro MUI_STARTMENU_WRITE_END
 637 SectionEnd
 638
 639 Section "-ApplyTweaks"
 640         ${PrintProgress} "$(MPLAYER_LANG_STATUS_TWEAKS)"
 641         DetailPrint "$(MPLAYER_LANG_APPLYING_TWEAKS)"
 642
 643         IntOp $0 $SelectedTweaks & 1
 644         ${If} $0 != 0
 645                 ${If} ${FileExists} "$INSTDIR\SMPlayer.ini"
 646                         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui" "gui" "SkinGUI"
 647                         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui" "iconset" "Gonzo"
 648                 ${EndIf}
 649         ${EndIf}
 650
 651         IntOp $0 $SelectedTweaks & 2
 652         ${If} $0 != 0
 653                 ${If} ${FileExists} "$INSTDIR\MPUI.ini"
 654                         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Params" "-vo gl:yuv=3 -lavdopts threads=$DetectedCPUCores"
 655                 ${EndIf}
 656                 ${If} ${FileExists} "$INSTDIR\SMPlayer.ini"
 657                         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General" "driver\vo" "gl:yuv=3"
 658                 ${EndIf}
 659         ${EndIf}
 660
 661         IntOp $0 $SelectedTweaks & 4
 662         ${If} $0 != 0
 663                 ${If} ${FileExists} "$INSTDIR\MPUI.ini"
 664                         ReadINIStr $1 "$INSTDIR\MPUI.ini" "MPUI" "Params"
 665                         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Params" "$1 -af volnorm=2"
 666                 ${EndIf}
 667                 ${If} ${FileExists} "$INSTDIR\SMPlayer.ini"
 668                         WriteINIStr "$INSTDIR\SMPlayer.ini" "defaults" "initial_volnorm" "true"
 669                 ${EndIf}
 670         ${EndIf}
 671 SectionEnd
 672
 673 Section "$(MPLAYER_LANG_COMPRESS_FILES)"
 674         SectionIn 1 2
 675         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_COMPRESS)"
 676
 677         File "/oname=$PLUGINSDIR\UPX.exe" "Utils\UPX.exe"
 678
 679         ${PackAll} "$INSTDIR" "*.exe"
 680         ${PackAll} "$INSTDIR" "*.dll"
 681         ${PackAll} "$INSTDIR\codecs" "*.acm"
 682         ${PackAll} "$INSTDIR\codecs" "*.ax"
 683         ${PackAll} "$INSTDIR\codecs" "*.dll"
 684         ${PackAll} "$INSTDIR\codecs" "*.qtx"
 685
 686         Delete "$PLUGINSDIR\UPX.exe"
 687 SectionEnd
 688
 689 Section "-Update Font Cache"
 690         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_FONTCACHE)"
 691
 692         SetShellVarContext current
 693         Delete "$APPDATA\fontconfig\cache\*.*"
 694         Delete "$LOCALAPPDATA\fontconfig\cache\*.*"
 695
 696         SetShellVarContext all
 697         Delete "$APPDATA\fontconfig\cache\*.*"
 698         Delete "$LOCALAPPDATA\fontconfig\cache\*.*"
 699
 700         File "/oname=$PLUGINSDIR\Sample.avi" "Resources\Sample.avi"
 701         DetailPrint "$(MPLAYER_LANG_UPDATING_FONTCACHE)"
 702         NsExec::Exec '"$INSTDIR\MPlayer.exe" -fontconfig -ass -vo null -ao null "$PLUGINSDIR\Sample.avi"'
 703         Delete "Resources\Sample.avi"
 704 SectionEnd
 705
 706 Section "-Update Registry"
 707         ${PrintProgress} "$(MPLAYER_LANG_STATUS_REGISTRY)"
 708         DetailPrint "$(MPLAYER_LANG_WRITING_REGISTRY)"
 709
 710         ; Clean up
 711         DeleteRegKey HKLM "${MPlayerRegPath}"
 712         DeleteRegKey HKCU "${MPlayerRegPath}"
 713         DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 714         DeleteRegValue HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 715
 716         ; Uninstaller
 717         WriteRegStr HKLM "${MPlayerRegPath}" "InstallLocation" "$INSTDIR"
 718         WriteRegStr HKLM "${MPlayerRegPath}" "UninstallString" '"$INSTDIR\Uninstall.exe"'
 719         WriteRegStr HKLM "${MPlayerRegPath}" "DisplayName" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 720         WriteRegStr HKLM "${MPlayerRegPath}" "DisplayIcon" "$INSTDIR\MPlayer.exe,0"
 721         WriteRegStr HKLM "${MPlayerRegPath}" "DisplayVersion" "${MPLAYER_DATE}"
 722         WriteRegStr HKLM "${MPlayerRegPath}" "URLInfoAbout" "http://mulder.at.gg/"
 723         WriteRegStr HKLM "${MPlayerRegPath}" "URLUpdateInfo" "http://mulder.at.gg/"
 724         WriteRegStr HKLM "${MPlayerRegPath}" "Publisher" "The MPlayer Team"
 725         WriteRegDWORD HKLM "${MPlayerRegPath}" "NoModify" 1
 726         WriteRegDWORD HKLM "${MPlayerRegPath}" "NoRepair" 1
 727
 728         ; Shell
 729         DeleteRegKey HKCR "MPlayerForWindowsV2.File"
 730         DeleteRegKey HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 731         DeleteRegKey HKCU "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 732         ${If} ${FileExists} "$INSTDIR\MPUI.exe"
 733                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\shell\open\command" "" '"$INSTDIR\MPUI.exe" "%1"'
 734                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\DefaultIcon" "" "$INSTDIR\MPUI.exe,0"
 735         ${EndIf}
 736         ${If} ${FileExists} "$INSTDIR\SMPlayer.exe"
 737                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\shell\open\command" "" '"$INSTDIR\SMPlayer.exe" "%1"'
 738                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\DefaultIcon" "" "$INSTDIR\SMPlayer.exe,1"
 739         ${EndIf}
 740
 741         ; Register App
 742         DeleteRegValue HKCU "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2"
 743         WriteRegStr HKLM "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2" "${MPlayerRegPath}\Capabilities"
 744
 745         ; Capabilities
 746         WriteRegStr HKLM "${MPlayerRegPath}\Capabilities" "ApplicationName" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 747         WriteRegStr HKLM "${MPlayerRegPath}\Capabilities" "ApplicationDescription" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 748         WriteRegStr HKLM "${MPlayerRegPath}\Capabilities" "ApplicationDescription" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 749
 750         ; File Associations
 751         ${RegisterFileExtCapability} "256"
 752         ${RegisterFileExtCapability} "3GP"
 753         ${RegisterFileExtCapability} "ASF"
 754         ${RegisterFileExtCapability} "AVI"
 755         ${RegisterFileExtCapability} "BIN"
 756         ${RegisterFileExtCapability} "DAT"
 757         ${RegisterFileExtCapability} "DIVX"
 758         ${RegisterFileExtCapability} "EVO"
 759         ${RegisterFileExtCapability} "FLV"
 760         ${RegisterFileExtCapability} "M2V"
 761         ${RegisterFileExtCapability} "M2TS"
 762         ${RegisterFileExtCapability} "MKA"
 763         ${RegisterFileExtCapability} "MKV"
 764         ${RegisterFileExtCapability} "MOV"
 765         ${RegisterFileExtCapability} "MP2"
 766         ${RegisterFileExtCapability} "MP3"
 767         ${RegisterFileExtCapability} "MP4"
 768         ${RegisterFileExtCapability} "MPEG"
 769         ${RegisterFileExtCapability} "MPG"
 770         ${RegisterFileExtCapability} "MPV"
 771         ${RegisterFileExtCapability} "NSV"
 772         ${RegisterFileExtCapability} "OGG"
 773         ${RegisterFileExtCapability} "OGM"
 774         ${RegisterFileExtCapability} "RM"
 775         ${RegisterFileExtCapability} "RMVB"
 776         ${RegisterFileExtCapability} "TS"
 777         ${RegisterFileExtCapability} "VOB"
 778         ${RegisterFileExtCapability} "WAV"
 779         ${RegisterFileExtCapability} "WEBM"
 780         ${RegisterFileExtCapability} "WMV"
 781
 782         ; Reset auto update interval
 783         DeleteRegValue HKLM "${MPlayerRegPath}" "LastUpdateCheck"
 784         DeleteRegValue HKCU "${MPlayerRegPath}" "LastUpdateCheck"
 785 SectionEnd
 786
 787 Section "$(MPLAYER_LANG_INST_AUTOUPDATE)" SECID_AUTOUPDATE
 788         SectionIn 1 2
 789         DetailPrint "$(MPLAYER_LANG_WRITING_REGISTRY)"
 790         WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2" '"$INSTDIR\Updater.exe" /L=$LANGUAGE /AutoCheck'
 791 SectionEnd
 792
 793 Section "-Protect Files"
 794         SetFileAttributes "$INSTDIR\MPlayer.exe" FILE_ATTRIBUTE_READONLY
 795         SetFileAttributes "$INSTDIR\dsnative.dll" FILE_ATTRIBUTE_READONLY
 796         SetFileAttributes "$INSTDIR\MPUI.exe" FILE_ATTRIBUTE_READONLY
 797         SetFileAttributes "$INSTDIR\SMPlayer.exe" FILE_ATTRIBUTE_READONLY
 798         SetFileAttributes "$INSTDIR\Updater.exe" FILE_ATTRIBUTE_READONLY
 799         SetFileAttributes "$INSTDIR\QtCore4.dll" FILE_ATTRIBUTE_READONLY
 800         SetFileAttributes "$INSTDIR\QtGui4.dll" FILE_ATTRIBUTE_READONLY
 801         SetFileAttributes "$INSTDIR\QtNetwork4.dll" FILE_ATTRIBUTE_READONLY
 802         SetFileAttributes "$INSTDIR\QtXml4.dll" FILE_ATTRIBUTE_READONLY
 803         SetFileAttributes "$INSTDIR\dsnative.dll" FILE_ATTRIBUTE_READONLY
 804         SetFileAttributes "$INSTDIR\libgcc_s_dw2-1.dll" FILE_ATTRIBUTE_READONLY
 805         SetFileAttributes "$INSTDIR\mingwm10.dll" FILE_ATTRIBUTE_READONLY
 806         SetFileAttributes "$INSTDIR\zlib1.dll" FILE_ATTRIBUTE_READONLY
 807 SectionEnd
 808
 809 Section "-Finished"
 810         ${PrintStatus} "$(MUI_TEXT_FINISH_TITLE)"
 811 SectionEnd
 812
 813
 814 ;--------------------------------------------------------------------------------
 815 ; UN-INSTALL SECTIONS
 816 ;--------------------------------------------------------------------------------
 817
 818 Section "Uninstall"
 819         SetOutPath "$INSTDIR"
 820         ${PrintProgress} "$(MPLAYER_LANG_STATUS_UNINSTALL)"
 821
 822         ; Startmenu
 823         !insertmacro MUI_STARTMENU_GETFOLDER Application $StartMenuFolder
 824         ${IfNot} "$StartMenuFolder" == ""
 825                 SetShellVarContext current
 826                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk"
 827                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "SMPlayer.lnk" ${StdUtils.Const.ISV_UnpinFromTaskbar}
 828                         DetailPrint 'Unpin: "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" -> $R1'
 829                 ${EndIf}
 830                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\*.*"
 831                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 832                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.url"
 833                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.pif"
 834                         RMDir "$SMPROGRAMS\$StartMenuFolder"
 835                 ${EndIf}
 836                 SetShellVarContext all
 837                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk"
 838                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "SMPlayer.lnk" ${StdUtils.Const.ISV_UnpinFromTaskbar}
 839                         DetailPrint 'Unpin: "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" -> $R1'
 840                 ${EndIf}
 841                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\*.*"
 842                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 843                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.url"
 844                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.pif"
 845                         RMDir "$SMPROGRAMS\$StartMenuFolder"
 846                 ${EndIf}
 847         ${EndIf}
 848
 849         ; Desktop icons
 850         Delete /REBOOTOK "$DESKTOP\MPUI.lnk"
 851         Delete /REBOOTOK "$DESKTOP\SMPlayer.lnk"
 852
 853         ; Files
 854         Delete /REBOOTOK "$INSTDIR\*.exe"
 855         Delete /REBOOTOK "$INSTDIR\*.dll"
 856         Delete /REBOOTOK "$INSTDIR\*.ini"
 857         Delete /REBOOTOK "$INSTDIR\*.txt"
 858         Delete /REBOOTOK "$INSTDIR\*.html"
 859         Delete /REBOOTOK "$INSTDIR\*.htm"
 860         Delete /REBOOTOK "$INSTDIR\*.ass"
 861         Delete /REBOOTOK "$INSTDIR\*.m3u8"
 862         Delete /REBOOTOK "$INSTDIR\*.tag"
 863         RMDir /r "$INSTDIR\codecs"
 864         RMDir /r "$INSTDIR\fonts"
 865         RMDir /r "$INSTDIR\imageformats"
 866         RMDir /r "$INSTDIR\legal_stuff"
 867         RMDir /r "$INSTDIR\locale"
 868         RMDir /r "$INSTDIR\mplayer"
 869         RMDir /r "$INSTDIR\shortcuts"
 870         RMDir /r "$INSTDIR\themes"
 871         RMDir /r "$INSTDIR\translations"
 872         RMDir "$INSTDIR"
 873
 874         ; Virtual Store
 875         ${GetVirtualStorePath} $0 "$INSTDIR"
 876         ${If} ${FileExists} "$0\*.*"
 877                 RMDir /r "$0"
 878         ${EndIf}
 879
 880         ; Registry Keys
 881         DeleteRegKey HKLM "${MPlayerRegPath}"
 882         DeleteRegKey HKCU "${MPlayerRegPath}"
 883         DeleteRegValue HKLM "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2"
 884         DeleteRegValue HKCU "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2"
 885
 886         ; Auto Update
 887         DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 888         DeleteRegValue HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 889
 890         ; Shell
 891         DeleteRegKey HKCR "MPlayerForWindowsV2.File"
 892         DeleteRegKey HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 893         DeleteRegKey HKCU "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 894
 895         ${PrintStatus} "$(MUI_UNTEXT_FINISH_TITLE)"
 896 SectionEnd
 897
 898
 899 ;--------------------------------------------------------------------------------
 900 ; SECTION SELECTION CHANGED
 901 ;--------------------------------------------------------------------------------
 902
 903 Function .onSelChange
 904         ${IfNot} ${SectionIsSelected} ${SECID_MPUI}
 905         ${AndIfNot} ${SectionIsSelected} ${SECID_SMPLAYER}
 906                 MessageBox MB_TOPMOST|MB_ICONEXCLAMATION "$(MPLAYER_LANG_SELCHANGE)"
 907                 SectionGetFlags ${SECID_MPUI} $0
 908                 IntOp $0 $0 | ${SF_SELECTED}
 909                 SectionSetFlags ${SECID_MPUI} $0
 910         ${EndIf}
 911
 912         ${IfNot} ${SectionIsSelected} ${SECID_AUTOUPDATE}
 913                 StrCpy $0 "nope"
 914                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_YESNO|MB_DEFBUTTON2 "$(MPLAYER_LANG_SEL_AUTOUPDATE)" IDNO ${||} StrCpy $0 "ok" ${|}
 915                 ${If} "$0" == "ok"
 916                         SectionGetFlags ${SECID_AUTOUPDATE} $0
 917                         IntOp $0 $0 | ${SF_SELECTED}
 918                         SectionSetFlags ${SECID_AUTOUPDATE} $0
 919                 ${EndIf}
 920         ${EndIf}
 921 FunctionEnd
 922
 923
 924 ;--------------------------------------------------------------------------------
 925 ; LOCKED-LIST PLUGIN
 926 ;--------------------------------------------------------------------------------
 927
 928 !macro LockedListPage_Function
 929         !insertmacro MUI_HEADER_TEXT "$(MPLAYER_LANG_LOCKEDLIST_HEADER)" "$(MPLAYER_LANG_LOCKEDLIST_TEXT)"
 930         LockedList::AddModule "\MPlayer.exe"
 931         LockedList::AddModule "\SMPlayer.exe"
 932         LockedList::AddModule "\MPUI.exe"
 933         LockedList::Dialog /autonext /ignore "$(MPLAYER_LANG_IGNORE)" /heading "$(MPLAYER_LANG_LOCKEDLIST_HEADING)" /noprograms "$(MPLAYER_LANG_LOCKEDLIST_NOPROG)" /searching  "$(MPLAYER_LANG_LOCKEDLIST_SEARCH)" /colheadings "$(MPLAYER_LANG_LOCKEDLIST_COLHDR1)" "$(MPLAYER_LANG_LOCKEDLIST_COLHDR2)"
 934         Pop $R0
 935 !macroend
 936
 937 Function LockedListPage_Show
 938         !insertmacro LockedListPage_Function
 939 FunctionEnd
 940
 941 Function un.LockedListPage_Show
 942         !insertmacro LockedListPage_Function
 943 FunctionEnd
 944
 945
 946 ;--------------------------------------------------------------------------------
 947 ; CUSTOME PAGE: CPU SELECTOR
 948 ;--------------------------------------------------------------------------------
 949
 950 Function SelectCPUPage_Show
 951         ; Detect CPU type, if not detected yet
 952         ${If} $DetectedCPUType < 2
 953         ${OrIf} $DetectedCPUType > 6
 954                 Call DetectCPUType
 955                 !insertmacro INSTALLOPTIONS_READ $0 "Page_CPU.ini" "Field $DetectedCPUType" "Text"
 956                 !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field $DetectedCPUType" "Text" "$0  <---"
 957         ${EndIf}
 958
 959         ; Make sure the current selection is valid
 960         ${IfThen} $SelectedCPUType < 2 ${|} StrCpy $SelectedCPUType $DetectedCPUType ${|}
 961         ${IfThen} $SelectedCPUType > 6 ${|} StrCpy $SelectedCPUType $DetectedCPUType ${|}
 962
 963         ; Translate
 964         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field 1" "Text" "$(MPLAYER_LANG_SELECT_CPU_TYPE)"
 965         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field 7" "Text" "$(MPLAYER_LANG_SELECT_CPU_HINT)"
 966
 967         ; Apply current selection to dialog
 968         ${For} $0 2 6
 969                 ${If} $0 == $SelectedCPUType
 970                         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field $0" "State" "1"
 971                 ${Else}
 972                         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field $0" "State" "0"
 973                 ${EndIf}
 974         ${Next}
 975
 976         ; Display dialog
 977         !insertmacro MUI_HEADER_TEXT "$(MPLAYER_LANG_SELECT_CPU_HEAD)" "$(MPLAYER_LANG_SELECT_CPU_TEXT)"
 978         !insertmacro INSTALLOPTIONS_DISPLAY "Page_CPU.ini"
 979
 980         ; Read new selection from dialog
 981         StrCpy $SelectedCPUType 0
 982         ${For} $0 2 6
 983                 !insertmacro INSTALLOPTIONS_READ $1 "Page_CPU.ini" "Field $0" "State"
 984                 ${IfThen} $1 == 1 ${|} StrCpy $SelectedCPUType $0 ${|}
 985         ${Next}
 986 FunctionEnd
 987
 988 Function SelectCPUPage_Validate
 989         ; Read new selection from dialog
 990         StrCpy $2 0
 991         ${For} $0 2 6
 992                 !insertmacro INSTALLOPTIONS_READ $1 "Page_CPU.ini" "Field $0" "State"
 993                 ${IfThen} $1 == 1 ${|} StrCpy $2 $0 ${|}
 994         ${Next}
 995
 996         ; Validate selection
 997         ${If} $2 < 2
 998         ${OrIf} $2 > 6
 999                 MessageBox MB_ICONSTOP "Oups, invalid selection detected!"
1000                 Abort
1001         ${EndIf}
1002 FunctionEnd
1003
1004 Function DetectCPUType
1005         StrCpy $DetectedCPUType 6 ;generic
1006         StrCpy $DetectedCPUCores 2
1007
1008         ${IfNot} ${Silent}
1009                 Banner::show /NOUNLOAD "$(MPLAYER_LANG_DETECTING)"
1010         ${EndIf}
1011
1012         ${CPUFeatures.GetCount} $0
1013         ${IfNot} $0 == "error"
1014                 StrCpy $DetectedCPUCores $0
1015         ${EndIf}
1016
1017         ; Debug Code
1018         !ifdef CPU_DETECT_DEBUG
1019                 ${CPUFeatures.GetVendor} $0
1020                 ${CPUFeatures.CheckFeature} "MMX1"   $1
1021                 ${CPUFeatures.CheckFeature} "3DNOW"  $2
1022                 ${CPUFeatures.CheckFeature} "SSE3"   $3
1023                 ${CPUFeatures.CheckFeature} "SSSE3"  $4
1024                 ${CPUFeatures.CheckFeature} "SSE4.2" $5
1025                 ${CPUFeatures.CheckFeature} "AVX1"   $6
1026                 ${CPUFeatures.CheckFeature} "FMA4"   $7
1027                 StrCpy $9 `Vendor = $0`
1028                 StrCpy $9 `$9$\n"MMX1" = $1`
1029                 StrCpy $9 `$9$\n"3DNOW" = $2`
1030                 StrCpy $9 `$9$\n"SSE3" = $3`
1031                 StrCpy $9 `$9$\n"SSSE3" = $4`
1032                 StrCpy $9 `$9$\n"SSE4.2" = $5`
1033                 StrCpy $9 `$9$\n"AVX1" = $6`
1034                 StrCpy $9 `$9$\n"FMA4" = $7`
1035                 MessageBox MB_TOPMOST `$9`
1036         !endif
1037
1038         ; Make sure we have at least MMX
1039         ${IfNot} ${CPUSupports} "MMX1"
1040                 Banner::destroy
1041                 Return
1042         ${EndIf}
1043
1044         ; Select the "best" model for Intel's
1045         ${If} ${CPUIsIntel}
1046                 ; Core2 (SSE3 + SSSE3)
1047                 ${If} ${CPUSupportsAll} "SSE3,SSSE3"
1048                         StrCpy $DetectedCPUType 2 ;
1049                 ${EndIf}
1050                 ; Nehalem (SSE3 + SSSE3 + SSE4.2)
1051                 ${If} ${CPUSupportsAll} "SSE3,SSSE3,SSE4.2"
1052                         StrCpy $DetectedCPUType 3
1053                 ${EndIf}
1054         ${EndIf}
1055
1056         ; Select the "best" model for AMD's
1057         ${If} ${CPUIsAMD}
1058                 ; K8+SSE3 (3DNow! + SSE3)
1059                 ${If} ${CPUSupportsAll} "3DNOW,SSE3"
1060                         StrCpy $DetectedCPUType 4
1061                 ${EndIf}
1062                 ; Bulldozer (SSE3 + SSSE3 + SSE4.2 + AVX + FMA4)
1063                 ${If} ${CPUSupportsAll} "SSE3,SSSE3,SSE4.2,AVX1,FMA4"
1064                         StrCpy $DetectedCPUType 5
1065                 ${EndIf}
1066         ${EndIf}
1067
1068         Banner::destroy
1069 FunctionEnd
1070
1071
1072 ;--------------------------------------------------------------------------------
1073 ; CUSTOME PAGE: TWEAKS
1074 ;--------------------------------------------------------------------------------
1075
1076 Function SetTweaksPage_Show
1077         ; Apply current selection to dialog
1078         StrCpy $0 1
1079         ${For} $1 2 4
1080                 IntOp $2 $0 & $SelectedTweaks
1081                 ${If} $2 != 0
1082                         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field $1" "State" "1"
1083                 ${Else}
1084                         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field $1" "State" "0"
1085                 ${EndIf}
1086                 IntOp $0 $0 << 1
1087         ${Next}
1088
1089         ; Translate
1090         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 1" "Text" "$(MPLAYER_LANG_TWEAKS_HINT)"
1091         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 2" "Text" "$(MPLAYER_LANG_TWEAKS_SKINNEDUI)"
1092         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 3" "Text" "$(MPLAYER_LANG_TWEAKS_OPENGL)"
1093         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 4" "Text" "$(MPLAYER_LANG_TWEAKS_VOLNORM)"
1094
1095         ; Display dialog
1096         !insertmacro MUI_HEADER_TEXT "$(MPLAYER_LANG_TWEAKS_HEAD)" "$(MPLAYER_LANG_TWEAKS_TEXT)"
1097         !insertmacro INSTALLOPTIONS_DISPLAY "Page_Tweaks.ini"
1098
1099         ; Read new selection from dialog
1100         StrCpy $0 1
1101         ${For} $1 2 4
1102                 !insertmacro INSTALLOPTIONS_READ $2 "Page_Tweaks.ini" "Field $1" "State"
1103                 ${IfThen} $2 == 1 ${|} IntOp $SelectedTweaks $SelectedTweaks | $0 ${|}
1104                 IntOp $0 $0 << 1
1105         ${Next}
1106 FunctionEnd
1107
1108
1109 ;--------------------------------------------------------------------------------
1110 ; CHECK FOR UPDATE MODE
1111 ;--------------------------------------------------------------------------------
1112
1113 !macro EnablePathEditable flag show_msg
1114         ${IfNot} $NotUpdateInstall == ${flag}
1115                 !if ${show_msg} == 1
1116                         MessageBox MB_OK|MB_ICONINFORMATION "$(MPLAYER_LANG_FORCE_UPDATE)" /SD IDOK
1117                 !endif
1118                 StrCpy $NotUpdateInstall ${flag}
1119         ${EndIf}
1120         FindWindow $1 "#32770" "" $HWNDPARENT
1121         GetDlgItem $2 $1 1019
1122         EnableWindow $2 ${flag}
1123         GetDlgItem $2 $1 1001
1124         EnableWindow $2 ${flag}
1125 !macroend
1126
1127 Function CheckForUpdate
1128         ${StdUtils.GetParameter} $0 "Update" "?"
1129         ${IfNot} "$0" == "?"
1130                 !insertmacro EnablePathEditable 0 0
1131                 Return
1132         ${EndIf}
1133
1134         ${If} ${FileExists} "$INSTDIR\MPlayer.exe"
1135                 !insertmacro EnablePathEditable 0 1
1136                 Return
1137         ${EndIf}
1138
1139         !insertmacro EnablePathEditable 1 0
1140 FunctionEnd
1141
1142
1143 ;--------------------------------------------------------------------------------
1144 ; FINISHED
1145 ;--------------------------------------------------------------------------------
1146
1147 Function RunAppFunction
1148         !insertmacro DisableNextButton $R0
1149         ${If} ${FileExists} "$INSTDIR\SMPlayer.exe"
1150                 ${StdUtils.ExecShellAsUser} $R0 "$INSTDIR\SMPlayer.exe" "open" "http://lounge-office.rautemusik.fm/"
1151         ${Else}
1152                 ${StdUtils.ExecShellAsUser} $R0 "$INSTDIR\MPUI.exe" "open" "http://lounge-office.rautemusik.fm/"
1153         ${EndIf}
1154 FunctionEnd
1155
1156 Function ShowReadmeFunction
1157         !insertmacro DisableNextButton $R0
1158         ${StdUtils.ExecShellAsUser} $R0 "$INSTDIR\Readme.html" "open" ""
1159 FunctionEnd
1160
1161 Function .onInstSuccess
1162         ${StdUtils.ExecShellAsUser} $R0 "$SMPROGRAMS\$StartMenuFolder" "explore" ""
1163 FunctionEnd
1164
1165
1166 ### EOF ###