MPUI_Setup.nsi

   1 ; ///////////////////////////////////////////////////////////////////////////////
   2 ; // MPlayer for Windows - Install Script
   3 ; // Copyright (C) 2004-2015 LoRd_MuldeR <MuldeR2@GMX.de>
   4 ; //
   5 ; // This program is free software; you can redistribute it and/or modify
   6 ; // it under the terms of the GNU General Public License as published by
   7 ; // the Free Software Foundation; either version 2 of the License, or
   8 ; // (at your option) any later version.
   9 ; //
  10 ; // This program is distributed in the hope that it will be useful,
  11 ; // but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ; // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ; // GNU General Public License for more details.
  14 ; //
  15 ; // You should have received a copy of the GNU General Public License along
  16 ; // with this program; if not, write to the Free Software Foundation, Inc.,
  17 ; // 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18 ; //
  19 ; // http://www.gnu.org/licenses/gpl-2.0.txt
  20 ; ///////////////////////////////////////////////////////////////////////////////
  21
  22
  23 ;--------------------------------------------------------------------------------
  24 ; BASIC DEFINES
  25 ;--------------------------------------------------------------------------------
  26
  27 !ifndef NSIS_UNICODE
  28   !error "NSIS_UNICODE is undefined, please compile with Unicode NSIS !!!"
  29 !endif
  30
  31 !ifndef MPLAYER_BUILDNO
  32   !error "MPLAYER_BUILDNO is not defined !!!"
  33 !endif
  34
  35 !ifndef MPLAYER_REVISION
  36   !error "MPLAYER_REVISION is not defined !!!"
  37 !endif
  38
  39 !ifndef MPLAYER_DATE
  40   !error "MPLAYER_DATE is not defined !!!"
  41 !endif
  42
  43 !ifndef SMPLAYER_VERSION
  44   !error "SMPLAYER_VERSION is not defined !!!"
  45 !endif
  46
  47 !ifndef MPUI_VERSION
  48   !error "MPUI_VERSION is not defined !!!"
  49 !endif
  50
  51 !ifndef CODECS_DATE
  52   !error "CODECS_DATE is not defined !!!"
  53 !endif
  54
  55 !ifndef MPLAYER_OUTFILE
  56   !error "MPLAYER_OUTFILE is not defined !!!"
  57 !endif
  58
  59 !ifndef UPX_PATH
  60   !error "UPX_PATH is not defined !!!"
  61 !endif
  62
  63 ; UUID
  64 !define MPlayerRegPath "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{97D341C8-B0D1-4E4A-A49A-C30B52F168E9}"
  65
  66 ; Web-Site
  67 !define MPlayerWebSite "http://mplayerhq.hu/"
  68
  69
  70 ;--------------------------------------------------------------------------------
  71 ; INSTALLER ATTRIBUTES
  72 ;--------------------------------------------------------------------------------
  73
  74 RequestExecutionLevel admin
  75 ShowInstDetails show
  76 ShowUninstDetails show
  77
  78 Name "$(MPLAYER_LANG_MPLAYER_WIN32) ${MPLAYER_DATE} (Build #${MPLAYER_BUILDNO})"
  79 Caption "$(MPLAYER_LANG_MPLAYER_WIN32) ${MPLAYER_DATE} (Build #${MPLAYER_BUILDNO})"
  80 BrandingText "MPlayer-Win32 (Build #${MPLAYER_BUILDNO})"
  81 InstallDir "$PROGRAMFILES\MPlayer for Windows"
  82 InstallDirRegKey HKLM "${MPlayerRegPath}" "InstallLocation"
  83 OutFile "${MPLAYER_OUTFILE}"
  84
  85
  86 ;--------------------------------------------------------------------------------
  87 ; COMPRESSOR
  88 ;--------------------------------------------------------------------------------
  89
  90 SetCompressor /SOLID /FINAL LZMA
  91 SetCompressorDictSize 112
  92
  93 !tempfile PACKHDRTEMP
  94 !packhdr "${PACKHDRTEMP}" '"Utils\MT.exe" -manifest "Resources\Setup.manifest" -outputresource:"${PACKHDRTEMP};1"'
  95
  96 #!packhdr "$%TEMP%\exehead.tmp" '"${UPX_PATH}\upx.exe" --brute "$%TEMP%\exehead.tmp"'
  97
  98
  99 ;--------------------------------------------------------------------------------
 100 ; RESERVE FILES
 101 ;--------------------------------------------------------------------------------
 102
 103 ReserveFile "${NSISDIR}\Plugins\Aero.dll"
 104 ReserveFile "${NSISDIR}\Plugins\Banner.dll"
 105 ReserveFile "${NSISDIR}\Plugins\CPUFeatures.dll"
 106 ReserveFile "${NSISDIR}\Plugins\InstallOptions.dll"
 107 ReserveFile "${NSISDIR}\Plugins\LangDLL.dll"
 108 ReserveFile "${NSISDIR}\Plugins\LockedList.dll"
 109 ReserveFile "${NSISDIR}\Plugins\LockedList64.dll"
 110 ReserveFile "${NSISDIR}\Plugins\nsDialogs.dll"
 111 ReserveFile "${NSISDIR}\Plugins\nsExec.dll"
 112 ReserveFile "${NSISDIR}\Plugins\StartMenu.dll"
 113 ReserveFile "${NSISDIR}\Plugins\StdUtils.dll"
 114 ReserveFile "${NSISDIR}\Plugins\System.dll"
 115 ReserveFile "${NSISDIR}\Plugins\UserInfo.dll"
 116 ReserveFile "Dialogs\Page_CPU.ini"
 117 ReserveFile "Resources\Splash.gif"
 118
 119
 120 ;--------------------------------------------------------------------------------
 121 ; INCLUDES
 122 ;--------------------------------------------------------------------------------
 123
 124 !include `MUI2.nsh`
 125 !include `InstallOptions.nsh`
 126 !include `WinVer.nsh`
 127 !include `x64.nsh`
 128 !include `StrFunc.nsh`
 129 !include `StdUtils.nsh`
 130 !include `CPUFeatures.nsh`
 131 !include `MPUI_Common.nsh`
 132
 133 ; Enable functions
 134 ${StrRep}
 135
 136
 137 ;--------------------------------------------------------------------------------
 138 ; GLOBAL VARIABLES
 139 ;--------------------------------------------------------------------------------
 140
 141 Var StartMenuFolder
 142 Var DetectedCPUType
 143 Var DetectedCPUCores
 144 Var SelectedCPUType
 145 Var SelectedTweaks
 146 Var NotUpdateInstall
 147
 148
 149 ;--------------------------------------------------------------------------------
 150 ; VERSION INFO
 151 ;--------------------------------------------------------------------------------
 152
 153 !searchreplace PRODUCT_VERSION_DATE "${MPLAYER_DATE}" "-" "."
 154 VIProductVersion "${PRODUCT_VERSION_DATE}.${MPLAYER_BUILDNO}"
 155
 156 VIAddVersionKey "Author" "LoRd_MuldeR <mulder2@gmx.de>"
 157 VIAddVersionKey "Comments" "This program is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation; either version 2 of the License, or (at your option) any later version."
 158 VIAddVersionKey "CompanyName" "Free Software Foundation"
 159 VIAddVersionKey "FileDescription" "MPlayer for Windows (Build #${MPLAYER_BUILDNO})"
 160 VIAddVersionKey "FileVersion" "${PRODUCT_VERSION_DATE}.${MPLAYER_BUILDNO}"
 161 VIAddVersionKey "LegalCopyright" "Copyright 2000-2015 The MPlayer Project"
 162 VIAddVersionKey "LegalTrademarks" "GNU"
 163 VIAddVersionKey "OriginalFilename" "MPUI-Setup.exe"
 164 VIAddVersionKey "ProductName" "MPlayer for Windows"
 165 VIAddVersionKey "ProductVersion" "Build #${MPLAYER_BUILDNO} (${MPLAYER_DATE})"
 166 VIAddVersionKey "Website" "${MPlayerWebSite}"
 167
 168
 169 ;--------------------------------------------------------------------------------
 170 ; MUI2 INTERFACE SETTINGS
 171 ;--------------------------------------------------------------------------------
 172
 173 !define MUI_ABORTWARNING
 174 !define MUI_STARTMENUPAGE_REGISTRY_ROOT HKLM
 175 !define MUI_STARTMENUPAGE_REGISTRY_KEY "${MPlayerRegPath}"
 176 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "StartmenuFolder"
 177 !define MUI_LANGDLL_REGISTRY_ROOT HKLM
 178 !define MUI_LANGDLL_REGISTRY_KEY "${MPlayerRegPath}"
 179 !define MUI_LANGDLL_REGISTRY_VALUENAME "SetupLanguage"
 180 !define MUI_STARTMENUPAGE_DEFAULTFOLDER "MPlayer for Windows"
 181 !define MUI_FINISHPAGE_NOAUTOCLOSE
 182 !define MUI_UNFINISHPAGE_NOAUTOCLOSE
 183 !define MUI_FINISHPAGE_RUN
 184 !define MUI_FINISHPAGE_RUN_FUNCTION RunAppFunction
 185 !define MUI_FINISHPAGE_SHOWREADME
 186 !define MUI_FINISHPAGE_SHOWREADME_FUNCTION ShowReadmeFunction
 187 !define MUI_FINISHPAGE_LINK ${MPlayerWebSite}
 188 !define MUI_FINISHPAGE_LINK_LOCATION ${MPlayerWebSite}
 189 !define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\orange-install.ico"
 190 !define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\orange-uninstall.ico"
 191 !define MUI_WELCOMEFINISHPAGE_BITMAP "Artwork\wizard.bmp"
 192 !define MUI_UNWELCOMEFINISHPAGE_BITMAP "Artwork\wizard-un.bmp"
 193 !define MUI_HEADERIMAGE
 194 !define MUI_HEADERIMAGE_BITMAP "Artwork\header.bmp"
 195 !define MUI_HEADERIMAGE_UNBITMAP "Artwork\header-un.bmp"
 196 !define MUI_LANGDLL_ALLLANGUAGES
 197 !define MUI_CUSTOMFUNCTION_GUIINIT MyGuiInit
 198 !define MUI_CUSTOMFUNCTION_UNGUIINIT un.MyGuiInit
 199 !define MUI_LANGDLL_ALWAYSSHOW
 200 !define MUI_COMPONENTSPAGE_SMALLDESC
 201
 202
 203 ;--------------------------------------------------------------------------------
 204 ; MUI2 PAGE SETUP
 205 ;--------------------------------------------------------------------------------
 206
 207 ; Installer
 208 !define MUI_WELCOMEPAGE_TITLE_3LINES
 209 !define MUI_FINISHPAGE_TITLE_3LINES
 210 !insertmacro MUI_PAGE_WELCOME
 211 !insertmacro MUI_PAGE_LICENSE "Docs\License.txt"
 212 !define MUI_PAGE_CUSTOMFUNCTION_SHOW CheckForUpdate
 213 !insertmacro MUI_PAGE_DIRECTORY
 214 !insertmacro  MUI_PAGE_COMPONENTS
 215 !insertmacro MUI_PAGE_STARTMENU Application $StartMenuFolder
 216 Page Custom SelectCPUPage_Show SelectCPUPage_Validate
 217 Page Custom SetTweaksPage_Show
 218 Page Custom LockedListPage_Show
 219 !insertmacro MUI_PAGE_INSTFILES
 220 !insertmacro MUI_PAGE_FINISH
 221
 222 ; Un-Installer
 223 !define MUI_WELCOMEPAGE_TITLE_3LINES
 224 !define MUI_FINISHPAGE_TITLE_3LINES
 225 !insertmacro MUI_UNPAGE_WELCOME
 226 !insertmacro MUI_UNPAGE_CONFIRM
 227 UninstPage Custom un.LockedListPage_Show
 228 !insertmacro MUI_UNPAGE_INSTFILES
 229 !insertmacro MUI_UNPAGE_FINISH
 230
 231
 232 ;--------------------------------------------------------------------------------
 233 ; LANGUAGE
 234 ;--------------------------------------------------------------------------------
 235
 236 !insertmacro MUI_LANGUAGE "English"
 237 !insertmacro MUI_LANGUAGE "German"
 238
 239 ; Translation files
 240 !include "Language\MPUI_EN.nsh"
 241 !include "Language\MPUI_DE.nsh"
 242
 243
 244 ;--------------------------------------------------------------------------------
 245 ; INSTALL TYPES
 246 ;--------------------------------------------------------------------------------
 247
 248 InstType "$(MPLAYER_LANG_INSTTYPE_COMPLETE)"
 249 InstType "$(MPLAYER_LANG_INSTTYPE_MINIMAL)"
 250
 251
 252 ;--------------------------------------------------------------------------------
 253 ; INITIALIZATION
 254 ;--------------------------------------------------------------------------------
 255
 256 Function .onInit
 257         StrCpy $SelectedCPUType 0
 258         StrCpy $DetectedCPUType 0
 259         StrCpy $DetectedCPUCores 0
 260         StrCpy $SelectedTweaks 1
 261         StrCpy $NotUpdateInstall 1
 262
 263         InitPluginsDir
 264
 265         ; --------
 266
 267         System::Call 'kernel32::CreateMutexA(i 0, i 0, t "{B800490C-C100-4B12-9F09-1A54DF063049}") i .r1 ?e'
 268         Pop $0
 269         ${If} $0 <> 0
 270                 MessageBox MB_ICONSTOP|MB_TOPMOST "Oups, the installer is already running!"
 271                 Quit
 272         ${EndIf}
 273
 274         ; --------
 275
 276         # Running on Windows NT family?
 277         ${IfNot} ${IsNT}
 278                 MessageBox MB_TOPMOST|MB_ICONSTOP "Sorry, this application does *not* support Windows 9x or Windows ME!"
 279                 ExecShell "open" "http://windows.microsoft.com/"
 280                 Quit
 281         ${EndIf}
 282
 283         # Running on Windows XP or later?
 284         ${If} ${AtMostWin2000}
 285                 MessageBox MB_TOPMOST|MB_ICONSTOP "Sorry, but your operating system is *not* supported anymore.$\nInstallation will be aborted!$\n$\nThe minimum required platform is Windows XP."
 286                 ExecShell "open" "http://windows.microsoft.com/"
 287                 Quit
 288         ${EndIf}
 289
 290         ; --------
 291
 292         UserInfo::GetAccountType
 293         Pop $0
 294         ${If} $0 != "Admin"
 295                 MessageBox MB_ICONSTOP|MB_TOPMOST "Your system requires administrative permissions in order to install this software."
 296                 SetErrorLevel 740 ;ERROR_ELEVATION_REQUIRED
 297                 Quit
 298         ${EndIf}
 299
 300         ; --------
 301
 302         !insertmacro MUI_LANGDLL_DISPLAY
 303
 304         !insertmacro INSTALLOPTIONS_EXTRACT_AS "Dialogs\Page_CPU.ini"    "Page_CPU.ini"
 305         !insertmacro INSTALLOPTIONS_EXTRACT_AS "Dialogs\Page_Tweaks.ini" "Page_Tweaks.ini"
 306
 307         !ifdef PRE_RELEASE
 308                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL|MB_DEFBUTTON2 "Note: This is an early pre-release version for test only!" IDCANCEL ${||} Quit ${|}
 309         !endif
 310
 311         ; --------
 312
 313         ${IfNot} ${Silent}
 314                 File "/oname=$PLUGINSDIR\Splash.gif" "Resources\Splash.gif"
 315                 newadvsplash::show 3000 1000 500 -1 /NOCANCEL "$PLUGINSDIR\Splash.gif"
 316                 Delete /REBOOTOK "$PLUGINSDIR\Splash.gif"
 317         ${EndIf}
 318 FunctionEnd
 319
 320 Function un.onInit
 321         InitPluginsDir
 322
 323         System::Call 'kernel32::CreateMutexA(i 0, i 0, t "{B800490C-C100-4B12-9F09-1A54DF063049}") i .r1 ?e'
 324         Pop $0
 325         ${If} $0 <> 0
 326                 MessageBox MB_ICONSTOP|MB_TOPMOST "Sorry, the un-installer is already running!"
 327                 Quit
 328         ${EndIf}
 329
 330         ; --------
 331
 332         UserInfo::GetAccountType
 333         Pop $0
 334         ${If} $0 != "Admin"
 335                 MessageBox MB_ICONSTOP|MB_TOPMOST "Your system requires administrative permissions in order to un-install this software."
 336                 SetErrorLevel 740 ;ERROR_ELEVATION_REQUIRED
 337                 Quit
 338         ${EndIf}
 339
 340         ; --------
 341
 342         !insertmacro MUI_LANGDLL_DISPLAY
 343 FunctionEnd
 344
 345
 346 ;--------------------------------------------------------------------------------
 347 ; GUI INITIALIZATION
 348 ;--------------------------------------------------------------------------------
 349
 350 Function MyGuiInit
 351         StrCpy $0 $HWNDPARENT
 352         System::Call "user32::SetWindowPos(i r0, i -1, i 0, i 0, i 0, i 0, i 3)"
 353         Aero::Apply
 354 FunctionEnd
 355
 356 Function un.MyGuiInit
 357         StrCpy $0 $HWNDPARENT
 358         System::Call "user32::SetWindowPos(i r0, i -1, i 0, i 0, i 0, i 0, i 3)"
 359         Aero::Apply
 360 FunctionEnd
 361
 362
 363 ;--------------------------------------------------------------------------------
 364 ; INSTALL SECTIONS
 365 ;--------------------------------------------------------------------------------
 366
 367 Section "-Clean Up"
 368         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_CLEAN)"
 369
 370         SetShellVarContext all
 371         SetOutPath "$INSTDIR"
 372
 373         ; Uninstall old version (aka "Setup v1")
 374         ClearErrors
 375         ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{DB9E4EAB-2717-499F-8D56-4CC8A644AB60}" "InstallLocation"
 376         ${IfNot} ${Errors}
 377                 MessageBox MB_ICONINFORMATION|MB_OK "$(MPLAYER_LANG_UNINSTALL_OLDVER)"
 378                 File "/oname=$PLUGINSDIR\Uninstall-V1.exe" "Resources\Uninstall-V1.exe"
 379                 HideWindow
 380                 ExecWait '"$PLUGINSDIR\Uninstall-V1.exe" _?=$0'
 381                 Delete /REBOOTOK "$PLUGINSDIR\Uninstall-V1.exe"
 382                 BringToFront
 383         ${EndIf}
 384
 385         ; Clean registry
 386         DeleteRegKey HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{DB9E4EAB-2717-499F-8D56-4CC8A644AB60}"
 387         DeleteRegKey HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{DB9E4EAB-2717-499F-8D56-4CC8A644AB60}"
 388         DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_UpdateReminder"
 389         DeleteRegValue HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_UpdateReminder"
 390
 391         ; Make sure MPlayer isn't running
 392         ${Do}
 393                 ClearErrors
 394                 Delete "$INSTDIR\MPlayer.exe"
 395                 Delete "$INSTDIR\SMPlayer.exe"
 396                 Delete "$INSTDIR\MPUI.exe"
 397                 ${If} ${Errors}
 398                         ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL "$(MPLAYER_LANG_STILL_RUNNING)" IDCANCEL ${||} Abort ${|}
 399                 ${Else}
 400                         ${Break}
 401                 ${EndIf}
 402         ${Loop}
 403
 404         ; Clean the install folder
 405         Delete "$INSTDIR\*.exe"
 406         Delete "$INSTDIR\*.dll"
 407         Delete "$INSTDIR\*.ini"
 408         Delete "$INSTDIR\*.txt"
 409         Delete "$INSTDIR\*.html"
 410         Delete "$INSTDIR\*.htm"
 411         Delete "$INSTDIR\*.ass"
 412         Delete "$INSTDIR\*.m3u8"
 413         Delete "$INSTDIR\*.tag"
 414         RMDir /r "$INSTDIR\codecs"
 415         RMDir /r "$INSTDIR\fonts"
 416         RMDir /r "$INSTDIR\imageformats"
 417         RMDir /r "$INSTDIR\legal_stuff"
 418         RMDir /r "$INSTDIR\locale"
 419         RMDir /r "$INSTDIR\mplayer"
 420         RMDir /r "$INSTDIR\shortcuts"
 421         RMDir /r "$INSTDIR\themes"
 422         RMDir /r "$INSTDIR\translations"
 423
 424         ; Now deal with Virtual Store
 425         ${GetVirtualStorePath} $0 "$INSTDIR"
 426         Delete "$0\*.exe"
 427         Delete "$0\*.dll"
 428         Delete "$0\*.ini"
 429         Delete "$0\*.txt"
 430         Delete "$0\*.html"
 431         Delete "$0\*.htm"
 432         Delete "$0\*.ass"
 433         Delete "$0\*.m3u8"
 434         Delete "$0\*.tag"
 435         Delete "$0\mplayer\config"
 436         Delete "$0\mplayer\*.conf"
 437 SectionEnd
 438
 439 Section "!MPlayer r${MPLAYER_REVISION}" SECID_MPLAYER
 440         SectionIn 1 2 RO
 441         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_MPLAYER)"
 442         SetOutPath "$INSTDIR"
 443
 444         ; Detect
 445         ${If} ${Silent}
 446                 Call DetectCPUType
 447                 StrCpy $SelectedCPUType $DetectedCPUType
 448         ${EndIf}
 449
 450         ; MPlayer.exe
 451         ${Select} $SelectedCPUType
 452                 ${Case} "2"
 453                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): core2"
 454                         File "Builds\MPlayer-core2\MPlayer.exe"
 455                 ${Case} "3"
 456                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): corei7"
 457                         File "Builds\MPlayer-corei7\MPlayer.exe"
 458                 ${Case} "4"
 459                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): k8-sse3"
 460                         File "Builds\MPlayer-k8-sse3\MPlayer.exe"
 461                 ${Case} "5"
 462                         DetailPrint "$(MPLAYER_LANG_SELECTED_TYPE): generic"
 463                         File "Builds\MPlayer-generic\MPlayer.exe"
 464                 ${CaseElse}
 465                         MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OK "Internal error: Invalid CPU type selection detected!"
 466                         Abort
 467         ${EndSelect}
 468
 469         ; Utilities
 470         File ".Compile\Updater.exe"
 471         File "Resources\AppRegGUI.exe"
 472
 473         ; Other MPlayer-related files
 474         File "Builds\MPlayer-generic\dsnative.dll"
 475         SetOutPath "$INSTDIR\mplayer"
 476         File "Builds\MPlayer-generic\mplayer\config"
 477         File "Builds\MPlayer-generic\mplayer\subfont.ttf"
 478         SetOutPath "$INSTDIR\fonts"
 479         File "Builds\MPlayer-generic\fonts\fonts.conf"
 480         SetOutPath "$INSTDIR\fonts\conf.d"
 481         File "Builds\MPlayer-generic\fonts\conf.d\*.conf"
 482
 483         ; Documents
 484         SetOutPath "$INSTDIR"
 485         File "GPL.txt"
 486         File "/oname=Manual.html" "Builds\MPlayer-generic\MPlayer.man.html"
 487         File "Docs\Readme.html"
 488         SetOutPath "$INSTDIR\legal_stuff"
 489         File "Docs\legal_stuff\*.txt"
 490
 491         ; Write version tag
 492         ${Do}
 493                 ClearErrors
 494                 Delete "$INSTDIR\version.tag"
 495                 ${If} ${Errors}
 496                         ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_OKCANCEL "$(MPLAYER_LANG_TAG_WRITE)" IDCANCEL ${||} Abort ${|}
 497                 ${Else}
 498                         ${Break}
 499                 ${EndIf}
 500         ${Loop}
 501         WriteINIStr "$INSTDIR\version.tag" "mplayer_version" "build_no" "${MPLAYER_BUILDNO}"
 502         WriteINIStr "$INSTDIR\version.tag" "mplayer_version" "pkg_date" "${MPLAYER_DATE}"
 503         SetFileAttributes "$INSTDIR\version.tag" FILE_ATTRIBUTE_READONLY
 504
 505         ; Set file access rights
 506         ${MakeFilePublic} "$INSTDIR\mplayer\config"
 507         ${MakeFilePublic} "$INSTDIR\fonts\fonts.conf"
 508 SectionEnd
 509
 510 Section "!MPUI $(MPLAYER_LANG_FRONT_END) v${MPUI_VERSION}" SECID_MPUI
 511         SectionIn 1 2
 512         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_MPUI)"
 513
 514         ; Extract files
 515         SetOutPath "$INSTDIR"
 516         File "MPUI\MPUI.exe"
 517
 518         ; Extract locales
 519         SetOutPath "$INSTDIR\locale"
 520         File "MPUI\locale\*.txt"
 521
 522         ; Set file access rights
 523         ${MakeFilePublic} "$INSTDIR\MPUI.ini"
 524
 525         ; Setup initial config
 526         ClearErrors
 527         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Params" "-vo direct3d -lavdopts threads=$DetectedCPUCores"
 528         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Locale" "$(MPLAYER_LANG_MPUI_DEFAULT_LANGUAGE)"
 529         ${If} ${Errors}
 530                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONSTOP|MB_DEFBUTTON2|MB_OKCANCEL "$(MPLAYER_LANG_CONFIG_MPUI)" IDCANCEL ${||} Abort ${|}
 531         ${EndIf}
 532 SectionEnd
 533
 534 Section "!SMPlayer $(MPLAYER_LANG_FRONT_END) v${SMPLAYER_VERSION}" SECID_SMPLAYER
 535         SectionIn 1
 536         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_SMPLAYER)"
 537
 538         ; SMPlayer files
 539         SetOutPath "$INSTDIR"
 540         File "SMPlayer\SMPlayer.exe"
 541         File "SMPlayer\libgcc_s_dw2-1.dll"
 542         File "SMPlayer\libstdc++-6.dll"
 543         File "SMPlayer\libwinpthread-1.dll"
 544         File "SMPlayer\QtCore4.dll"
 545         File "SMPlayer\QtGui4.dll"
 546         File "SMPlayer\QtNetwork4.dll"
 547         File "SMPlayer\QtScript4.dll"
 548         File "SMPlayer\QtXml4.dll"
 549         File "SMPlayer\QtDBus4.dll"
 550         File "SMPlayer\libeay32.dll"
 551         File "SMPlayer\ssleay32.dll"
 552         File "SMPlayer\zlib1.dll"
 553
 554         ; Additional SMPlayer files
 555         SetOutPath "$INSTDIR\translations"
 556         File "SMPlayer\translations\*.qm"
 557         SetOutPath "$INSTDIR\imageformats"
 558         File "SMPlayer\imageformats\*.dll"
 559         SetOutPath "$INSTDIR\shortcuts"
 560         File "SMPlayer\shortcuts\*.keys"
 561         SetOutPath "$INSTDIR\themes"
 562         File /r "SMPlayer\themes\*.txt"
 563         File /r "SMPlayer\themes\*.rcc"
 564         File /r "SMPlayer\themes\*.css"
 565
 566         ; Set file access rights
 567         ${MakeFilePublic} "$INSTDIR\SMPlayer.ini"
 568         ${MakeFilePublic} "$INSTDIR\SMPlayer_files.ini"
 569         ${MakeFilePublic} "$INSTDIR\favorites.m3u8"
 570         ${MakeFilePublic} "$INSTDIR\radio.m3u8"
 571         ${MakeFilePublic} "$INSTDIR\tv.m3u8"
 572         ${MakeFilePublic} "$INSTDIR\styles.ass"
 573         ${MakeFilePublic} "$INSTDIR\shortcuts\default.keys"
 574
 575         ; Setup initial config
 576         ${StrRep} $0 "$INSTDIR\MPlayer.exe" "\" "/"
 577         ClearErrors
 578         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "config_version"             "4"
 579         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "mplayer_bin"                "$0"
 580         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "driver\vo"                  "direct3d"
 581         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "autosync"                   "true"
 582         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "autosync_factor"            "30"
 583         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "use_audio_equalizer"        "false"
 584         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "use_scaletempo"             "0"
 585         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "osd"                        "1"
 586         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General"       "file_settings_method"       "normal"
 587         WriteINIStr "$INSTDIR\SMPlayer.ini" "performance"    "threads"                    "$DetectedCPUCores"
 588         WriteINIStr "$INSTDIR\SMPlayer.ini" "performance"    "priority"                   "1"
 589         WriteINIStr "$INSTDIR\SMPlayer.ini" "performance"    "frame_drop"                 "true"
 590         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui"            "gui"                        "DefaultGUI"
 591         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui"            "iconset"                    "Numix-remix"
 592         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui"            "style"                      "Plastique"
 593         WriteINIStr "$INSTDIR\SMPlayer.ini" "advanced"       "mplayer_additional_options" ""
 594         WriteINIStr "$INSTDIR\SMPlayer.ini" "smplayer"       "check_for_new_version"      "false"
 595         WriteINIStr "$INSTDIR\SMPlayer.ini" "smplayer"       "check_if_upgraded"          "false"
 596         WriteINIStr "$INSTDIR\SMPlayer.ini" "update_checker" "enabled"                    "false"
 597
 598         ${If} ${Errors}
 599                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONSTOP|MB_DEFBUTTON2|MB_OKCANCEL "$(MPLAYER_LANG_CONFIG_SMPLAYER)" IDCANCEL ${||} Abort ${|}
 600         ${EndIf}
 601 SectionEnd
 602
 603 Section "!$(MPLAYER_LANG_BIN_CODECS) (${CODECS_DATE})"
 604         SectionIn 1
 605         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_CODECS)"
 606
 607         SetOutPath "$INSTDIR\codecs"
 608
 609         File "Codecs\*.0"
 610         File "Codecs\*.acm"
 611         File "Codecs\*.ax"
 612         File "Codecs\*.dll"
 613         File "Codecs\*.qtx"
 614         File "Codecs\*.so"
 615         File "Codecs\*.vwp"
 616         File "Codecs\*.xa"
 617 SectionEnd
 618
 619 Section "-Write Uninstaller"
 620         ${PrintProgress} "$(MPLAYER_LANG_STATUS_MAKEUNINST)"
 621         WriteUninstaller "$INSTDIR\Uninstall.exe"
 622 SectionEnd
 623
 624 Section "-Create Shortcuts"
 625         !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
 626                 ${PrintProgress} "$(MPLAYER_LANG_STATUS_SHORTCUTS)"
 627                 CreateDirectory "$SMPROGRAMS\$StartMenuFolder"
 628
 629                 SetShellVarContext current
 630                 Delete "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 631                 Delete "$SMPROGRAMS\$StartMenuFolder\*.pif"
 632                 Delete "$SMPROGRAMS\$StartMenuFolder\*.url"
 633
 634                 SetShellVarContext all
 635                 Delete "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 636                 Delete "$SMPROGRAMS\$StartMenuFolder\*.pif"
 637                 Delete "$SMPROGRAMS\$StartMenuFolder\*.url"
 638
 639                 ${If} ${FileExists} "$INSTDIR\MPUI.exe"
 640                         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\MPUI.lnk" "$INSTDIR\MPUI.exe"
 641                         CreateShortCut "$DESKTOP\MPUI.lnk" "$INSTDIR\MPUI.exe"
 642                 ${EndIf}
 643                 ${If} ${FileExists} "$INSTDIR\SMPlayer.exe"
 644                         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" "$INSTDIR\SMPlayer.exe"
 645                         CreateShortCut "$DESKTOP\SMPlayer.lnk" "$INSTDIR\SMPlayer.exe"
 646                 ${EndIf}
 647
 648                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_UPDATE).lnk" "$INSTDIR\Updater.exe" "/L=$LANGUAGE"
 649                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_README).lnk" "$INSTDIR\Readme.html"
 650                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_MANUAL).lnk" "$INSTDIR\Manual.html"
 651
 652                 ${If} ${AtLeastWinVista}
 653                         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_APPREG).lnk" "$INSTDIR\AppRegGUI.exe"
 654                 ${EndIf}
 655
 656                 ${CreateWebLink} "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_SITE_MULDERS).url" "http://muldersoft.com/"
 657                 ${CreateWebLink} "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_SITE_MPWIN32).url" "http://oss.netfarm.it/mplayer-win32.php"
 658                 ${CreateWebLink} "$SMPROGRAMS\$StartMenuFolder\$(MPLAYER_LANG_SHORTCUT_SITE_MPLAYER).url" "http://www.mplayerhq.hu/"
 659
 660                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk"
 661                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "SMPlayer.lnk" ${StdUtils.Const.ISV_PinToTaskbar}
 662                         DetailPrint 'Pin: "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" -> $R1'
 663                 ${EndIf}
 664         !insertmacro MUI_STARTMENU_WRITE_END
 665 SectionEnd
 666
 667 Section "-ApplyTweaks"
 668         ${PrintProgress} "$(MPLAYER_LANG_STATUS_TWEAKS)"
 669         DetailPrint "$(MPLAYER_LANG_APPLYING_TWEAKS)"
 670
 671         IntOp $0 $SelectedTweaks & 1
 672         ${If} $0 != 0
 673                 ${If} ${FileExists} "$INSTDIR\SMPlayer.ini"
 674                         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui" "gui"     "SkinGUI"
 675                         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui" "iconset" "Gonzo"
 676                         WriteINIStr "$INSTDIR\SMPlayer.ini" "gui" "style"   "Plastique"
 677                 ${EndIf}
 678         ${EndIf}
 679
 680         IntOp $0 $SelectedTweaks & 2
 681         ${If} $0 != 0
 682                 ${If} ${FileExists} "$INSTDIR\MPUI.ini"
 683                         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Params" "-vo gl:yuv=3 -lavdopts threads=$DetectedCPUCores"
 684                 ${EndIf}
 685                 ${If} ${FileExists} "$INSTDIR\SMPlayer.ini"
 686                         WriteINIStr "$INSTDIR\SMPlayer.ini" "%General" "driver\vo" "gl:yuv=3"
 687                 ${EndIf}
 688         ${EndIf}
 689
 690         IntOp $0 $SelectedTweaks & 4
 691         ${If} $0 != 0
 692                 ${If} ${FileExists} "$INSTDIR\MPUI.ini"
 693                         ReadINIStr $1 "$INSTDIR\MPUI.ini" "MPUI" "Params"
 694                         WriteINIStr "$INSTDIR\MPUI.ini" "MPUI" "Params" "$1 -af volnorm=2"
 695                 ${EndIf}
 696                 ${If} ${FileExists} "$INSTDIR\SMPlayer.ini"
 697                         WriteINIStr "$INSTDIR\SMPlayer.ini" "defaults" "initial_volnorm" "true"
 698                 ${EndIf}
 699         ${EndIf}
 700 SectionEnd
 701
 702 Section "$(MPLAYER_LANG_COMPRESS_FILES)"
 703         SectionIn 1 2
 704         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_COMPRESS)"
 705
 706         File "/oname=$PLUGINSDIR\UPX.exe" "Utils\UPX.exe"
 707
 708         ${PackAll} "$INSTDIR" "*.exe"
 709         ${PackAll} "$INSTDIR" "*.dll"
 710         ${PackAll} "$INSTDIR\codecs" "*.acm"
 711         ${PackAll} "$INSTDIR\codecs" "*.ax"
 712         ${PackAll} "$INSTDIR\codecs" "*.dll"
 713         ${PackAll} "$INSTDIR\codecs" "*.qtx"
 714
 715         Delete "$PLUGINSDIR\UPX.exe"
 716 SectionEnd
 717
 718 Section "-Update Font Cache"
 719         ${PrintProgress} "$(MPLAYER_LANG_STATUS_INST_FONTCACHE)"
 720
 721         SetShellVarContext current
 722         Delete "$APPDATA\fontconfig\cache\*.*"
 723         Delete "$LOCALAPPDATA\fontconfig\cache\*.*"
 724
 725         SetShellVarContext all
 726         Delete "$APPDATA\fontconfig\cache\*.*"
 727         Delete "$LOCALAPPDATA\fontconfig\cache\*.*"
 728
 729         File "/oname=$PLUGINSDIR\Sample.avi" "Resources\Sample.avi"
 730         DetailPrint "$(MPLAYER_LANG_UPDATING_FONTCACHE)"
 731         NsExec::Exec '"$INSTDIR\MPlayer.exe" -fontconfig -ass -vo null -ao null "$PLUGINSDIR\Sample.avi"'
 732         Delete "Resources\Sample.avi"
 733 SectionEnd
 734
 735 Section "-Update Registry"
 736         ${PrintProgress} "$(MPLAYER_LANG_STATUS_REGISTRY)"
 737         DetailPrint "$(MPLAYER_LANG_WRITING_REGISTRY)"
 738
 739         ; Clean up
 740         DeleteRegKey HKLM "${MPlayerRegPath}"
 741         DeleteRegKey HKCU "${MPlayerRegPath}"
 742         DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 743         DeleteRegValue HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 744
 745         ; Uninstaller
 746         WriteRegStr HKLM "${MPlayerRegPath}" "InstallLocation" "$INSTDIR"
 747         WriteRegStr HKLM "${MPlayerRegPath}" "UninstallString" '"$INSTDIR\Uninstall.exe"'
 748         WriteRegStr HKLM "${MPlayerRegPath}" "DisplayName" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 749         WriteRegStr HKLM "${MPlayerRegPath}" "DisplayIcon" "$INSTDIR\MPlayer.exe,0"
 750         WriteRegStr HKLM "${MPlayerRegPath}" "DisplayVersion" "${MPLAYER_DATE}"
 751         WriteRegStr HKLM "${MPlayerRegPath}" "URLInfoAbout" "http://muldersoft.com/"
 752         WriteRegStr HKLM "${MPlayerRegPath}" "URLUpdateInfo" "http://muldersoft.com/"
 753         WriteRegStr HKLM "${MPlayerRegPath}" "Publisher" "The MPlayer Team"
 754         WriteRegDWORD HKLM "${MPlayerRegPath}" "NoModify" 1
 755         WriteRegDWORD HKLM "${MPlayerRegPath}" "NoRepair" 1
 756
 757         ; Shell
 758         DeleteRegKey HKCR "MPlayerForWindowsV2.File"
 759         DeleteRegKey HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 760         DeleteRegKey HKCU "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 761         ${If} ${FileExists} "$INSTDIR\MPUI.exe"
 762                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\shell\open\command" "" '"$INSTDIR\MPUI.exe" "%1"'
 763                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\DefaultIcon" "" "$INSTDIR\MPUI.exe,0"
 764         ${EndIf}
 765         ${If} ${FileExists} "$INSTDIR\SMPlayer.exe"
 766                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\shell\open\command" "" '"$INSTDIR\SMPlayer.exe" "%1"'
 767                 WriteRegStr HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File\DefaultIcon" "" "$INSTDIR\SMPlayer.exe,1"
 768         ${EndIf}
 769
 770         ; Register App
 771         DeleteRegValue HKCU "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2"
 772         WriteRegStr HKLM "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2" "${MPlayerRegPath}\Capabilities"
 773
 774         ; Capabilities
 775         WriteRegStr HKLM "${MPlayerRegPath}\Capabilities" "ApplicationName" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 776         WriteRegStr HKLM "${MPlayerRegPath}\Capabilities" "ApplicationDescription" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 777         WriteRegStr HKLM "${MPlayerRegPath}\Capabilities" "ApplicationDescription" "$(MPLAYER_LANG_MPLAYER_WIN32)"
 778
 779         ; File Associations
 780         ${RegisterFileExtCapability} "256"
 781         ${RegisterFileExtCapability} "3GP"
 782         ${RegisterFileExtCapability} "AAC"
 783         ${RegisterFileExtCapability} "ASF"
 784         ${RegisterFileExtCapability} "AVI"
 785         ${RegisterFileExtCapability} "BIN"
 786         ${RegisterFileExtCapability} "DAT"
 787         ${RegisterFileExtCapability} "DIVX"
 788         ${RegisterFileExtCapability} "EVO"
 789         ${RegisterFileExtCapability} "FLV"
 790         ${RegisterFileExtCapability} "M2V"
 791         ${RegisterFileExtCapability} "M2TS"
 792         ${RegisterFileExtCapability} "M4A"
 793         ${RegisterFileExtCapability} "MKA"
 794         ${RegisterFileExtCapability} "MKV"
 795         ${RegisterFileExtCapability} "MOV"
 796         ${RegisterFileExtCapability} "MP2"
 797         ${RegisterFileExtCapability} "MP3"
 798         ${RegisterFileExtCapability} "MP4"
 799         ${RegisterFileExtCapability} "MPEG"
 800         ${RegisterFileExtCapability} "MPG"
 801         ${RegisterFileExtCapability} "MPV"
 802         ${RegisterFileExtCapability} "NSV"
 803         ${RegisterFileExtCapability} "OGG"
 804         ${RegisterFileExtCapability} "OGM"
 805         ${RegisterFileExtCapability} "RM"
 806         ${RegisterFileExtCapability} "RMVB"
 807         ${RegisterFileExtCapability} "TS"
 808         ${RegisterFileExtCapability} "VOB"
 809         ${RegisterFileExtCapability} "WAV"
 810         ${RegisterFileExtCapability} "WEBM"
 811         ${RegisterFileExtCapability} "WMV"
 812
 813         ; Reset auto update interval
 814         DeleteRegValue HKLM "${MPlayerRegPath}" "LastUpdateCheck"
 815         DeleteRegValue HKCU "${MPlayerRegPath}" "LastUpdateCheck"
 816 SectionEnd
 817
 818 Section "$(MPLAYER_LANG_INST_AUTOUPDATE)" SECID_AUTOUPDATE
 819         SectionIn 1 2
 820         DetailPrint "$(MPLAYER_LANG_SCHEDULE_UPDATE)"
 821         WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2" '"$INSTDIR\Updater.exe" /L=$LANGUAGE /AutoCheck'
 822 SectionEnd
 823
 824 Section "-Protect Files"
 825         SetFileAttributes "$INSTDIR\MPlayer.exe" FILE_ATTRIBUTE_READONLY
 826         SetFileAttributes "$INSTDIR\dsnative.dll" FILE_ATTRIBUTE_READONLY
 827         SetFileAttributes "$INSTDIR\MPUI.exe" FILE_ATTRIBUTE_READONLY
 828         SetFileAttributes "$INSTDIR\SMPlayer.exe" FILE_ATTRIBUTE_READONLY
 829         SetFileAttributes "$INSTDIR\Updater.exe" FILE_ATTRIBUTE_READONLY
 830         SetFileAttributes "$INSTDIR\QtCore4.dll" FILE_ATTRIBUTE_READONLY
 831         SetFileAttributes "$INSTDIR\QtGui4.dll" FILE_ATTRIBUTE_READONLY
 832         SetFileAttributes "$INSTDIR\QtNetwork4.dll" FILE_ATTRIBUTE_READONLY
 833         SetFileAttributes "$INSTDIR\QtXml4.dll" FILE_ATTRIBUTE_READONLY
 834         SetFileAttributes "$INSTDIR\dsnative.dll" FILE_ATTRIBUTE_READONLY
 835         SetFileAttributes "$INSTDIR\libgcc_s_dw2-1.dll" FILE_ATTRIBUTE_READONLY
 836         SetFileAttributes "$INSTDIR\mingwm10.dll" FILE_ATTRIBUTE_READONLY
 837         SetFileAttributes "$INSTDIR\zlib1.dll" FILE_ATTRIBUTE_READONLY
 838 SectionEnd
 839
 840 Section "-Finished"
 841         ${PrintStatus} "$(MUI_TEXT_FINISH_TITLE)"
 842 SectionEnd
 843
 844
 845 ;--------------------------------------------------------------------------------
 846 ; UN-INSTALL SECTIONS
 847 ;--------------------------------------------------------------------------------
 848
 849 Section "Uninstall"
 850         SetOutPath "$TEMP"
 851         ${PrintProgress} "$(MPLAYER_LANG_STATUS_UNINSTALL)"
 852
 853         ; Startmenu
 854         !insertmacro MUI_STARTMENU_GETFOLDER Application $StartMenuFolder
 855         ${IfNot} "$StartMenuFolder" == ""
 856                 SetShellVarContext current
 857                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk"
 858                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "SMPlayer.lnk" ${StdUtils.Const.ISV_UnpinFromTaskbar}
 859                         DetailPrint 'Unpin: "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" -> $R1'
 860                 ${EndIf}
 861                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\*.*"
 862                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 863                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.url"
 864                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.pif"
 865                         RMDir "$SMPROGRAMS\$StartMenuFolder"
 866                 ${EndIf}
 867                 SetShellVarContext all
 868                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk"
 869                         ${StdUtils.InvokeShellVerb} $R1 "$SMPROGRAMS\$StartMenuFolder" "SMPlayer.lnk" ${StdUtils.Const.ISV_UnpinFromTaskbar}
 870                         DetailPrint 'Unpin: "$SMPROGRAMS\$StartMenuFolder\SMPlayer.lnk" -> $R1'
 871                 ${EndIf}
 872                 ${If} ${FileExists} "$SMPROGRAMS\$StartMenuFolder\*.*"
 873                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.lnk"
 874                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.url"
 875                         Delete /REBOOTOK "$SMPROGRAMS\$StartMenuFolder\*.pif"
 876                         RMDir "$SMPROGRAMS\$StartMenuFolder"
 877                 ${EndIf}
 878         ${EndIf}
 879
 880         ; Desktop icons
 881         Delete /REBOOTOK "$DESKTOP\MPUI.lnk"
 882         Delete /REBOOTOK "$DESKTOP\SMPlayer.lnk"
 883
 884         ; Files
 885         Delete /REBOOTOK "$INSTDIR\*.exe"
 886         Delete /REBOOTOK "$INSTDIR\*.dll"
 887         Delete /REBOOTOK "$INSTDIR\*.ini"
 888         Delete /REBOOTOK "$INSTDIR\*.txt"
 889         Delete /REBOOTOK "$INSTDIR\*.html"
 890         Delete /REBOOTOK "$INSTDIR\*.htm"
 891         Delete /REBOOTOK "$INSTDIR\*.ass"
 892         Delete /REBOOTOK "$INSTDIR\*.m3u8"
 893         Delete /REBOOTOK "$INSTDIR\*.tag"
 894         RMDir /r "$INSTDIR\codecs"
 895         RMDir /r "$INSTDIR\fonts"
 896         RMDir /r "$INSTDIR\imageformats"
 897         RMDir /r "$INSTDIR\legal_stuff"
 898         RMDir /r "$INSTDIR\locale"
 899         RMDir /r "$INSTDIR\mplayer"
 900         RMDir /r "$INSTDIR\shortcuts"
 901         RMDir /r "$INSTDIR\themes"
 902         RMDir /r "$INSTDIR\translations"
 903         RMDir "$INSTDIR"
 904
 905         ; Virtual Store
 906         ${GetVirtualStorePath} $0 "$INSTDIR"
 907         ${If} ${FileExists} "$0\*.*"
 908                 RMDir /r "$0"
 909         ${EndIf}
 910
 911         ; Registry Keys
 912         DeleteRegKey HKLM "${MPlayerRegPath}"
 913         DeleteRegKey HKCU "${MPlayerRegPath}"
 914         DeleteRegValue HKLM "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2"
 915         DeleteRegValue HKCU "SOFTWARE\RegisteredApplications" "MPlayerForWindowsV2"
 916
 917         ; Auto Update
 918         DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 919         DeleteRegValue HKCU "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "MPlayerForWindows_AutoUpdateV2"
 920
 921         ; Shell
 922         DeleteRegKey HKCR "MPlayerForWindowsV2.File"
 923         DeleteRegKey HKLM "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 924         DeleteRegKey HKCU "SOFTWARE\Classes\MPlayerForWindowsV2.File"
 925
 926         ${PrintStatus} "$(MUI_UNTEXT_FINISH_TITLE)"
 927 SectionEnd
 928
 929
 930 ;--------------------------------------------------------------------------------
 931 ; SECTION SELECTION CHANGED
 932 ;--------------------------------------------------------------------------------
 933
 934 Function .onSelChange
 935         ${IfNot} ${SectionIsSelected} ${SECID_MPUI}
 936         ${AndIfNot} ${SectionIsSelected} ${SECID_SMPLAYER}
 937                 MessageBox MB_TOPMOST|MB_ICONEXCLAMATION "$(MPLAYER_LANG_SELCHANGE)"
 938                 SectionGetFlags ${SECID_MPUI} $0
 939                 IntOp $0 $0 | ${SF_SELECTED}
 940                 SectionSetFlags ${SECID_MPUI} $0
 941         ${EndIf}
 942
 943         ${IfNot} ${SectionIsSelected} ${SECID_AUTOUPDATE}
 944                 StrCpy $0 "nope"
 945                 ${IfCmd} MessageBox MB_TOPMOST|MB_ICONEXCLAMATION|MB_YESNO|MB_DEFBUTTON2 "$(MPLAYER_LANG_SEL_AUTOUPDATE)" IDNO ${||} StrCpy $0 "ok" ${|}
 946                 ${If} "$0" == "ok"
 947                         SectionGetFlags ${SECID_AUTOUPDATE} $0
 948                         IntOp $0 $0 | ${SF_SELECTED}
 949                         SectionSetFlags ${SECID_AUTOUPDATE} $0
 950                 ${EndIf}
 951         ${EndIf}
 952 FunctionEnd
 953
 954
 955 ;--------------------------------------------------------------------------------
 956 ; LOCKED-LIST PLUGIN
 957 ;--------------------------------------------------------------------------------
 958
 959 !macro LockedListPage_Function
 960         !insertmacro MUI_HEADER_TEXT "$(MPLAYER_LANG_LOCKEDLIST_HEADER)" "$(MPLAYER_LANG_LOCKEDLIST_TEXT)"
 961
 962         InitPluginsDir
 963         File /oname=$PLUGINSDIR\LockedList64.dll `${NSISDIR}\Plugins\LockedList64.dll`
 964
 965         LockedList::AddModule "\MPlayer.exe"
 966         LockedList::AddModule "\SMPlayer.exe"
 967         LockedList::AddModule "\MPUI.exe"
 968         LockedList::AddModule "\QtCore4.dll"
 969
 970         LockedList::Dialog /autonext /ignore "$(MPLAYER_LANG_IGNORE)" /heading "$(MPLAYER_LANG_LOCKEDLIST_HEADING)" /noprograms "$(MPLAYER_LANG_LOCKEDLIST_NOPROG)" /searching  "$(MPLAYER_LANG_LOCKEDLIST_SEARCH)" /colheadings "$(MPLAYER_LANG_LOCKEDLIST_COLHDR1)" "$(MPLAYER_LANG_LOCKEDLIST_COLHDR2)"
 971         Pop $R0
 972 !macroend
 973
 974 Function LockedListPage_Show
 975         !insertmacro LockedListPage_Function
 976 FunctionEnd
 977
 978 Function un.LockedListPage_Show
 979         !insertmacro LockedListPage_Function
 980 FunctionEnd
 981
 982
 983 ;--------------------------------------------------------------------------------
 984 ; CUSTOME PAGE: CPU SELECTOR
 985 ;--------------------------------------------------------------------------------
 986
 987 Function SelectCPUPage_Show
 988         ; Detect CPU type, if not detected yet
 989         ${If} $DetectedCPUType < 2
 990         ${OrIf} $DetectedCPUType > 5
 991                 Call DetectCPUType
 992                 !insertmacro INSTALLOPTIONS_READ $0 "Page_CPU.ini" "Field $DetectedCPUType" "Text"
 993                 !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field $DetectedCPUType" "Text" "$0  <---"
 994         ${EndIf}
 995
 996         ; Make sure the current selection is valid
 997         ${IfThen} $SelectedCPUType < 2 ${|} StrCpy $SelectedCPUType $DetectedCPUType ${|}
 998         ${IfThen} $SelectedCPUType > 5 ${|} StrCpy $SelectedCPUType $DetectedCPUType ${|}
 999
1000         ; Translate
1001         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field 1" "Text" "$(MPLAYER_LANG_SELECT_CPU_TYPE)"
1002         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field 6" "Text" "$(MPLAYER_LANG_SELECT_CPU_HINT)"
1003
1004         ; Apply current selection to dialog
1005         ${For} $0 2 5
1006                 ${If} $0 == $SelectedCPUType
1007                         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field $0" "State" "1"
1008                 ${Else}
1009                         !insertmacro INSTALLOPTIONS_WRITE "Page_CPU.ini" "Field $0" "State" "0"
1010                 ${EndIf}
1011         ${Next}
1012
1013         ; Display dialog
1014         !insertmacro MUI_HEADER_TEXT "$(MPLAYER_LANG_SELECT_CPU_HEAD)" "$(MPLAYER_LANG_SELECT_CPU_TEXT)"
1015         !insertmacro INSTALLOPTIONS_DISPLAY "Page_CPU.ini"
1016
1017         ; Read new selection from dialog
1018         StrCpy $SelectedCPUType 0
1019         ${For} $0 2 5
1020                 !insertmacro INSTALLOPTIONS_READ $1 "Page_CPU.ini" "Field $0" "State"
1021                 ${IfThen} $1 == 1 ${|} StrCpy $SelectedCPUType $0 ${|}
1022         ${Next}
1023 FunctionEnd
1024
1025 Function SelectCPUPage_Validate
1026         ; Read new selection from dialog
1027         StrCpy $2 0
1028         ${For} $0 2 5
1029                 !insertmacro INSTALLOPTIONS_READ $1 "Page_CPU.ini" "Field $0" "State"
1030                 ${IfThen} $1 == 1 ${|} StrCpy $2 $0 ${|}
1031         ${Next}
1032
1033         ; Validate selection
1034         ${If} $2 < 2
1035         ${OrIf} $2 > 5
1036                 MessageBox MB_ICONSTOP "Oups, invalid selection detected!"
1037                 Abort
1038         ${EndIf}
1039 FunctionEnd
1040
1041 Function DetectCPUType
1042         StrCpy $DetectedCPUType 5 ;generic
1043         StrCpy $DetectedCPUCores 2
1044
1045         ${IfNot} ${Silent}
1046                 Banner::show /NOUNLOAD "$(MPLAYER_LANG_DETECTING)"
1047         ${EndIf}
1048
1049         ${CPUFeatures.GetCount} $0
1050         ${IfNot} $0 == "error"
1051                 StrCpy $DetectedCPUCores $0
1052         ${EndIf}
1053
1054         ; Debug Code
1055         !ifdef CPU_DETECT_DEBUG
1056                 ${CPUFeatures.GetVendor} $0
1057                 ${CPUFeatures.CheckFeature} "MMX1"   $1
1058                 ${CPUFeatures.CheckFeature} "3DNOW"  $2
1059                 ${CPUFeatures.CheckFeature} "SSE3"   $3
1060                 ${CPUFeatures.CheckFeature} "SSSE3"  $4
1061                 ${CPUFeatures.CheckFeature} "SSE4.2" $5
1062                 ${CPUFeatures.CheckFeature} "AVX1"   $6
1063                 ${CPUFeatures.CheckFeature} "FMA4"   $7
1064                 StrCpy $9 `Vendor = $0`
1065                 StrCpy $9 `$9$\n"MMX1" = $1`
1066                 StrCpy $9 `$9$\n"3DNOW" = $2`
1067                 StrCpy $9 `$9$\n"SSE3" = $3`
1068                 StrCpy $9 `$9$\n"SSSE3" = $4`
1069                 StrCpy $9 `$9$\n"SSE4.2" = $5`
1070                 StrCpy $9 `$9$\n"AVX1" = $6`
1071                 StrCpy $9 `$9$\n"FMA4" = $7`
1072                 MessageBox MB_TOPMOST `$9`
1073         !endif
1074
1075         ; Make sure we have at least MMX
1076         ${IfNot} ${CPUSupports} "MMX1"
1077                 Banner::destroy
1078                 Return
1079         ${EndIf}
1080
1081         ; Select the "best" model for Intel's
1082         ${If} ${CPUIsIntel}
1083                 ; Core2 (SSE3 + SSSE3)
1084                 ${If} ${CPUSupportsAll} "SSE3,SSSE3"
1085                         StrCpy $DetectedCPUType 2 ;
1086                 ${EndIf}
1087                 ; Nehalem (SSE3 + SSSE3 + SSE4.2)
1088                 ${If} ${CPUSupportsAll} "SSE3,SSSE3,SSE4.2"
1089                         StrCpy $DetectedCPUType 3
1090                 ${EndIf}
1091         ${EndIf}
1092
1093         ; Select the "best" model for AMD's
1094         ${If} ${CPUIsAMD}
1095                 ; K8+SSE3 (3DNow! + SSE3)
1096                 ${If} ${CPUSupportsAll} "3DNOW,SSE3"
1097                         StrCpy $DetectedCPUType 4
1098                 ${EndIf}
1099                 ; Bulldozer (SSE3 + SSSE3 + SSE4.2 + AVX + FMA4)
1100                 ;${If} ${CPUSupportsAll} "SSE3,SSSE3,SSE4.2,AVX1,FMA4"
1101                 ;       StrCpy $DetectedCPUType 5       #5 is now generic, as 'bdver1' build got dropped
1102                 ;${EndIf}
1103         ${EndIf}
1104
1105         Banner::destroy
1106 FunctionEnd
1107
1108
1109 ;--------------------------------------------------------------------------------
1110 ; CUSTOME PAGE: TWEAKS
1111 ;--------------------------------------------------------------------------------
1112
1113 Function SetTweaksPage_Show
1114         ; Apply current selection to dialog
1115         StrCpy $0 1
1116         ${For} $1 2 4
1117                 IntOp $2 $0 & $SelectedTweaks
1118                 ${If} $2 != 0
1119                         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field $1" "State" "1"
1120                 ${Else}
1121                         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field $1" "State" "0"
1122                 ${EndIf}
1123                 IntOp $0 $0 << 1
1124         ${Next}
1125
1126         ; Translate
1127         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 1" "Text" "$(MPLAYER_LANG_TWEAKS_HINT)"
1128         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 2" "Text" "$(MPLAYER_LANG_TWEAKS_SKINNEDUI)"
1129         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 3" "Text" "$(MPLAYER_LANG_TWEAKS_OPENGL)"
1130         !insertmacro INSTALLOPTIONS_WRITE "Page_Tweaks.ini" "Field 4" "Text" "$(MPLAYER_LANG_TWEAKS_VOLNORM)"
1131
1132         ; Display dialog
1133         !insertmacro MUI_HEADER_TEXT "$(MPLAYER_LANG_TWEAKS_HEAD)" "$(MPLAYER_LANG_TWEAKS_TEXT)"
1134         !insertmacro INSTALLOPTIONS_DISPLAY "Page_Tweaks.ini"
1135
1136         ; Read new selection from dialog
1137         StrCpy $0 1
1138         ${For} $1 2 4
1139                 !insertmacro INSTALLOPTIONS_READ $2 "Page_Tweaks.ini" "Field $1" "State"
1140                 ${IfThen} $2 == 1 ${|} IntOp $SelectedTweaks $SelectedTweaks | $0 ${|}
1141                 IntOp $0 $0 << 1
1142         ${Next}
1143 FunctionEnd
1144
1145
1146 ;--------------------------------------------------------------------------------
1147 ; CHECK FOR UPDATE MODE
1148 ;--------------------------------------------------------------------------------
1149
1150 !macro EnablePathEditable flag show_msg
1151         ${IfNot} $NotUpdateInstall == ${flag}
1152                 !if ${show_msg} == 1
1153                         MessageBox MB_OK|MB_ICONINFORMATION "$(MPLAYER_LANG_FORCE_UPDATE)" /SD IDOK
1154                 !endif
1155                 StrCpy $NotUpdateInstall ${flag}
1156         ${EndIf}
1157         FindWindow $1 "#32770" "" $HWNDPARENT
1158         GetDlgItem $2 $1 1019
1159         EnableWindow $2 ${flag}
1160         GetDlgItem $2 $1 1001
1161         EnableWindow $2 ${flag}
1162 !macroend
1163
1164 Function CheckForUpdate
1165         ${StdUtils.GetParameter} $0 "Update" "?"
1166         ${IfNot} "$0" == "?"
1167                 !insertmacro EnablePathEditable 0 0
1168                 Return
1169         ${EndIf}
1170
1171         ${If} ${FileExists} "$INSTDIR\MPlayer.exe"
1172                 !insertmacro EnablePathEditable 0 1
1173                 Return
1174         ${EndIf}
1175
1176         !insertmacro EnablePathEditable 1 0
1177 FunctionEnd
1178
1179
1180 ;--------------------------------------------------------------------------------
1181 ; FINISHED
1182 ;--------------------------------------------------------------------------------
1183
1184 Function RunAppFunction
1185         !insertmacro DisableNextButton $R0
1186         ${If} ${FileExists} "$INSTDIR\SMPlayer.exe"
1187                 ${StdUtils.ExecShellAsUser} $R0 "$INSTDIR\SMPlayer.exe" "open" "http://lounge-office.rautemusik.fm/"
1188         ${Else}
1189                 ${StdUtils.ExecShellAsUser} $R0 "$INSTDIR\MPUI.exe" "open" "http://lounge-office.rautemusik.fm/"
1190         ${EndIf}
1191 FunctionEnd
1192
1193 Function ShowReadmeFunction
1194         !insertmacro DisableNextButton $R0
1195         ${StdUtils.ExecShellAsUser} $R0 "$INSTDIR\Readme.html" "open" ""
1196 FunctionEnd
1197
1198 Function .onInstSuccess
1199         ${StdUtils.ExecShellAsUser} $R0 "$SMPROGRAMS\$StartMenuFolder" "explore" ""
1200 FunctionEnd
1201
1202
1203 ### EOF ###