ts

   1 #!/usr/bin/perl
   2
   3 =head1 NAME
   4
   5 ts - timestamp input
   6
   7 =head1 SYNOPSIS
   8
   9 ts [-r] [-i | -s] [format]
  10
  11 =head1 DESCRIPTION
  12
  13 ts adds a timestamp to the beginning of each line of input.
  14
  15 The optional format parameter controls how the timestamp is formatted,
  16 as used by L<strftime(3)>. The default format is "%b %d %H:%M:%S". In
  17 addition to the regular strftime conversion specifications, "%.S" and "%.s"
  18 are like "%S" and "%s", but provide subsecond resolution
  19 (ie, "30.00001" and "1301682593.00001").
  20
  21 If the -r switch is passed, it instead converts existing timestamps in
  22 the input to relative times, such as "15m5s ago". Many common timestamp
  23 formats are supported. Note that the Time::Duration and Date::Parse perl
  24 modules are required for this mode to work. Currently, converting localized
  25 dates is not supported.
  26
  27 If both -r and a format is passed, the existing timestamps are
  28 converted to the specified format.
  29
  30 If the -i or -s switch is passed, ts timestamps incrementally instead. In case
  31 of -i, every timestamp will be the time elapsed since the last timestamp. In
  32 case of -s, the time elapsed since start of the program is used.
  33 The default format changes to "%H:%M:%S", and "%.S" and "%.s" can be used
  34 as well.
  35
  36 =head1 ENVIRONMENT
  37
  38 The standard TZ environment variable controls what time zone dates
  39 are assumed to be in, if a timezone is not specified as part of the date.
  40
  41 =head1 AUTHOR
  42
  43 Copyright 2006 by Joey Hess <id@joeyh.name>
  44
  45 Licensed under the GNU GPL.
  46
  47 =cut
  48
  49 use warnings;
  50 use strict;
  51 use POSIX q{strftime};
  52
  53 $|=1;
  54
  55 my $rel=0;
  56 my $inc=0;
  57 my $sincestart=0;
  58 use Getopt::Long;
  59 GetOptions("r" => \$rel, "i" => \$inc, "s" => \$sincestart) || die "usage: ts [-r] [-i | -s] [format]\n";
  60
  61 if ($rel) {
  62         eval q{
  63                 use Date::Parse;
  64                 use Time::Duration;
  65         };
  66         die $@ if $@;
  67 }
  68
  69 my $use_format=@ARGV;
  70 my $format="%b %d %H:%M:%S";
  71 if ($inc || $sincestart) {
  72         $format="%H:%M:%S";
  73         $ENV{TZ}='GMT';
  74 }
  75 $format=shift if @ARGV;
  76
  77 # For subsecond resolution, Time::HiRes is needed.
  78 my $hires=0;
  79 if ($format=~/\%\.[Ss]/) {
  80         require Time::HiRes;
  81         $hires=1;
  82 }
  83
  84 my $lastseconds = 0;
  85 my $lastmicroseconds = 0;
  86
  87 if ($hires) {
  88         ($lastseconds, $lastmicroseconds) = Time::HiRes::gettimeofday();
  89 } else {
  90         $lastseconds = time;
  91 }
  92
  93
  94 while (<>) {
  95         if (! $rel) {
  96                 if ($hires) {
  97                         my $f=$format;
  98                         my ($seconds, $microseconds) = Time::HiRes::gettimeofday();
  99                         if ($inc || $sincestart) {
 100                                 my $deltaseconds = $seconds - $lastseconds;
 101                                 my $deltamicroseconds = $microseconds - $lastmicroseconds;
 102                                 if ($deltamicroseconds < 0) {
 103                                         $deltaseconds -= 1;
 104                                         $deltamicroseconds += 1000000;
 105                                 }
 106                                 if ($inc) {
 107                                         $lastseconds = $seconds;
 108                                         $lastmicroseconds = $microseconds;
 109                                 }
 110                                 $seconds = $deltaseconds;
 111                                 $microseconds = $deltamicroseconds;
 112                         }
 113                         my $s=sprintf("%06i", $microseconds);
 114                         $f=~s/\%\.([Ss])/%$1.$s/g;
 115                         print strftime($f, localtime($seconds));
 116                 }
 117                 else {
 118                         if ($inc || $sincestart) {
 119                                 my $seconds = time;
 120                                 my $deltaseconds = $seconds - $lastseconds;
 121                                 if ($inc) {
 122                                         $lastseconds = $seconds;
 123                                 }
 124                                 print strftime($format, localtime($deltaseconds));
 125                         } else {
 126                                 print strftime($format, localtime);
 127                         }
 128                 }
 129                 print " ".$_;
 130         }
 131         else {
 132                 s{\b(
 133                         \d\d[-\s\/]\w\w\w       # 21 dec 17:05
 134                                 (?:\/\d\d+)?    # 21 dec/93 17:05
 135                                 [\s:]\d\d:\d\d  #       (time part of above)
 136                                 (?::\d\d)?      #       (optional seconds)
 137                                 (?:\s+[+-]\d\d\d\d)? #  (optional timezone)
 138                         |
 139                         \w{3}\s+\d{1,2}\s+\d\d:\d\d:\d\d # syslog form
 140                         |
 141                         \d\d\d[-:]\d\d[-:]\d\dT\d\d:\d\d:\d\d.\d+ # ISO-8601
 142                         |
 143                         (?:\w\w\w,?\s+)?        #       (optional Day)
 144                         \d+\s+\w\w\w\s+\d\d+\s+\d\d:\d\d:\d\d
 145                                                 # 16 Jun 94 07:29:35
 146                                 (?:\s+\w\w\w|\s[+-]\d\d\d\d)?
 147                                                 #       (optional timezone)
 148                         |
 149                         \w\w\w\s+\w\w\w\s+\d\d\s+\d\d:\d\d
 150                                                 # lastlog format
 151                   )\b
 152                 }{
 153                         $use_format
 154                                 ? strftime($format, localtime(str2time($1)))
 155                                 : concise(ago(time - str2time($1), 2))
 156                 }exg;
 157
 158                 print $_;
 159         }
 160 }