zrun

   1 #!/usr/bin/perl
   2
   3 =head1 NAME
   4
   5 zrun - automatically uncompress arguments to command
   6
   7 =head1 SYNOPSIS
   8
   9 zrun command file.gz [...]
  10
  11 =head1 DESCRIPTION
  12
  13 Prefixing a shell command with "zrun" causes any compressed files that are
  14 arguments of the command to be transparently uncompressed to temp files
  15 (not pipes) and the uncompressed files fed to the command.
  16
  17 This is a quick way to run a command that does not itself support
  18 compressed files, without manually uncompressing the files.
  19
  20 =head1 BUGS
  21
  22 Modifications to the uncompressed temporary file are not fed back into the
  23 input file, so using this as a quick way to make an editor support
  24 compressed files won't work.
  25
  26 =head1 AUTHOR
  27
  28 Copyright 2006 by Chung-chieh Shan <ccshan@post.harvard.edu>
  29
  30 =cut
  31
  32 use warnings;
  33 use strict;
  34 use IO::Handle;
  35 use File::Spec;
  36 use File::Temp qw{tempfile};
  37
  38 my $program = shift;
  39
  40 if (! @ARGV) {
  41         die "Usage: zrun <command> <args>\n";
  42 }
  43
  44 my @argument;
  45 my %child;
  46 foreach my $argument (@ARGV) {
  47         if ($argument =~ m{^(.*/)?([^/]*)\.(gz|Z|bz2)$}s) {
  48                 my $suffix = "-$2";
  49                 my @preprocess = $3 eq "bz2" ? qw(bzip2 -d -c) : qw(gzip -d -c);
  50
  51                 my ($fh, $tmpname) = tempfile(SUFFIX => $suffix,
  52                         DIR => File::Spec->tmpdir, UNLINK => 1)
  53                         or die "zrun: cannot create temporary file: $!\n";
  54
  55                 if (my $child = fork) {
  56                         $child{$child} = $argument;
  57                         $argument = $tmpname;
  58                 }
  59                 elsif (defined $child) {
  60                         STDOUT->fdopen($fh, "w");
  61                         exec @preprocess, $argument;
  62                 }
  63                 else {
  64                         die "zrun: cannot fork to handle $argument: $!\n";
  65                 }
  66         }
  67         push @argument, $argument;
  68 }
  69
  70 while (%child and (my $pid = wait) != -1) {
  71         if (defined(my $argument = delete $child{$pid})) {
  72                 if ($? & 255) {
  73                         die "zrun: preprocessing for $argument terminated abnormally: $?\n";
  74                 }
  75                 elsif (my $code = $? >> 8) {
  76                         die "zrun: preprocessing for $argument terminated with code $code\n";
  77                 }
  78         }
  79 }
  80
  81 my $status = system $program ($program, @argument);
  82 if ($status & 255) {
  83         die "zrun: $program terminated abnormally: $?\n";
  84 }
  85 else {
  86         my $code = $? >> 8;
  87         exit $code;
  88 }