| blob | b04dc58113eaa4fe6c7f7f94cb5898794bb99f94 |
1 AC_INIT(README)
2 AC_CANONICAL_SYSTEM
4 # Gross hack to enable 'make dist' on automake 1.9+tar 1.14.
5 # The extra brackets are to foil regex-based scans.
6 m4_ifdef([_A][M_PROG_TAR],[_A][M_SET_OPTION([tar-ustar])])
8 AM_CONFIG_HEADER(config.h)
9 AM_INIT_AUTOMAKE(mono,2.7)
10 AM_MAINTAINER_MODE
12 API_VER=2.0
13 AC_SUBST(API_VER)
15 AC_PROG_LN_S
17 # In case of cygwin, override LN_S, irrespective of what it determines.
18 # The build uses cygwin, but the actual runtime doesn't.
19 case $host_os in
20 *cygwin* ) LN_S='cp -p';;
21 esac
23 dnl
24 dnl libgc checks
25 dnl
27 gc_headers=no
28 gc=included
29 use_included_gc=no
30 libgc_configure_args=
32 if test -d $srcdir/libgc ; then
33 gc_default=included
34 else
35 gc_default=boehm
36 fi
38 # These variables are the CPPFLAGS/CFLAGS passed to libgc's configure
39 # libgc should inherit the original CFLAGS/CPPFLAGS passed to configure, i.e. -O0
40 CPPFLAGS_FOR_LIBGC=$CPPFLAGS
41 CFLAGS_FOR_LIBGC=$CFLAGS
42 CPPFLAGS_FOR_EGLIB=$CPPFLAGS
43 CFLAGS_FOR_EGLIB=$CFLAGS
45 #
46 # These are the flags that need to be stored in the mono.pc file for
47 # compiling code that will embed Mono
48 #
49 libmono_cflags=""
50 libmono_ldflags=""
51 AC_SUBST(libmono_cflags)
52 AC_SUBST(libmono_ldflags)
54 # Variable to have relocatable .pc files (lib, or lib64)
55 reloc_libdir=`basename ${libdir}`
56 AC_SUBST(reloc_libdir)
58 dnl if linker handles the version script
59 no_version_script=no
61 # Set to yes if Unix sockets cannot be created in an anonymous namespace
62 need_link_unlink=no
64 # Thread configuration inspired by sleepycat's db
65 AC_MSG_CHECKING([host platform characteristics])
66 libgc_threads=no
67 has_dtrace=no
68 parallel_mark=yes
70 case "$host" in
71 powerpc*-*-linux*)
72 # https://bugzilla.novell.com/show_bug.cgi?id=504411
73 disable_munmap=yes
74 ;;
75 esac
77 host_win32=no
78 target_win32=no
79 case "$host" in
80 *-*-mingw*|*-*-cygwin*)
81 AC_DEFINE(HOST_WIN32,1,[Host Platform is Win32])
82 AC_DEFINE(DISABLE_PORTABILITY,1,[Disable the io-portability layer])
83 AC_DEFINE(PLATFORM_NO_SYMLINKS,1,[This platform does not support symlinks])
84 host_win32=yes
85 if test "x$cross_compiling" = "xno"; then
86 target_win32=yes
87 if test "x$host" == "x$target"; then
88 AC_DEFINE(TARGET_WIN32,1,[Target OS is Win32])
89 fi
90 CC="gcc -mno-cygwin -g"
91 CXX="g++ -mno-cygwin -g"
92 # So libgc configure gets -mno-cygwin
93 export CC
94 export CXX
95 fi
96 HOST_CC="gcc"
97 # Windows 2000 is required that includes Internet Explorer 5.01
98 CPPFLAGS="$CPPFLAGS -DWINVER=0x0500 -D_WIN32_WINNT=0x0500 -D_WIN32_IE=0x0501 -D_UNICODE -DUNICODE -DWIN32_THREADS -DFD_SETSIZE=1024"
99 LDFLAGS="$LDFLAGS -lmswsock -lws2_32 -lole32 -loleaut32 -lpsapi -lversion -ladvapi32 -lwinmm"
100 libmono_cflags="-mno-cygwin -mms-bitfields -mwindows"
101 libmono_ldflags="-mno-cygwin -mms-bitfields -mwindows"
102 libdl=
103 libgc_threads=win32
104 gc_default=included
105 with_sigaltstack=no
106 LN_S=cp
107 # This forces libgc to use the DllMain based thread registration code on win32
108 libgc_configure_args="$libgc_configure_args --enable-win32-dllmain=yes"
109 ;;
110 *-*-*netbsd*)
111 host_win32=no
112 CPPFLAGS="$CPPFLAGS -D_REENTRANT -DGC_NETBSD_THREADS -D_GNU_SOURCE"
113 libmono_cflags="-D_REENTRANT"
114 LDFLAGS="$LDFLAGS -pthread"
115 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD"
116 libmono_ldflags="-pthread"
117 need_link_unlink=yes
118 libdl="-ldl"
119 libgc_threads=pthreads
120 with_sigaltstack=no
121 use_sigposix=yes
122 ;;
123 *-*-*freebsd*)
124 host_win32=no
125 if test "x$PTHREAD_CFLAGS" = "x"; then
126 CPPFLAGS="$CPPFLAGS -DGC_FREEBSD_THREADS"
127 libmono_cflags=
128 else
129 CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
130 libmono_cflags="$PTHREAD_CFLAGS"
131 fi
132 if test "x$PTHREAD_LIBS" = "x"; then
133 LDFLAGS="$LDFLAGS -pthread"
134 libmono_ldflags="-pthread"
135 else
136 LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
137 libmono_ldflags="$PTHREAD_LIBS"
138 fi
139 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD"
140 need_link_unlink=yes
141 AC_DEFINE(PTHREAD_POINTER_ID, 1, [pthread is a pointer])
142 libdl=
143 libgc_threads=pthreads
144 # This doesn't seem to work as of 7.0 on amd64
145 with_sigaltstack=no
146 # TLS is only partially implemented on -CURRENT (compiler support
147 # but NOT library support)
148 #
149 with_tls=pthread
150 use_sigposix=yes
151 ;;
152 *-*-*openbsd*)
153 host_win32=no
154 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS -DPLATFORM_BSD -D_GNU_SOURCE -D_REENTRANT -DUSE_MMAP"
155 if test "x$disable_munmap" != "xyes"; then
156 CPPFLAGS="$CPPFLAGS -DUSE_MUNMAP"
157 fi
158 libmono_cflags="-D_THREAD_SAFE -D_REENTRANT"
159 LDFLAGS="$LDFLAGS -pthread"
160 libmono_ldflags="-pthread"
161 need_link_unlink=yes
162 AC_DEFINE(PTHREAD_POINTER_ID)
163 libdl=
164 libgc_threads=pthreads
165 use_sigposix=yes
166 ;;
167 *-*-linux*)
168 host_win32=no
169 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -D_GNU_SOURCE -D_REENTRANT -DUSE_MMAP"
170 if test "x$disable_munmap" != "xyes"; then
171 CPPFLAGS="$CPPFLAGS -DUSE_MUNMAP"
172 fi
173 libmono_cflags="-D_REENTRANT"
174 libmono_ldflags="-lpthread"
175 libdl="-ldl"
176 libgc_threads=pthreads
177 AOT_SUPPORTED="yes"
178 use_sigposix=yes
179 ;;
180 *-*-hpux*)
181 host_win32=no
182 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
183 # +ESdbgasm only valid on bundled cc on RISC
184 # silently ignored for ia64
185 if test $GCC != "yes"; then
186 CFLAGS="$CFLAGS +ESdbgasm"
187 # Arrange for run-time dereferencing of null
188 # pointers to produce a SIGSEGV signal.
189 LDFLAGS="$LDFLAGS -z"
190 fi
191 CFLAGS="$CFLAGS +ESdbgasm"
192 LDFLAGS="$LDFLAGS -z"
193 libmono_cflags="-D_REENTRANT"
194 libmono_ldflags="-lpthread"
195 libgc_threads=pthreads
196 need_link_unlink=yes
197 use_sigposix=yes
198 ;;
199 *-*-solaris*)
200 host_win32=no
201 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS -DUSE_MMAP -DUSE_MUNMAP -DPLATFORM_SOLARIS"
202 need_link_unlink=yes
203 libmono_cflags="-D_REENTRANT"
204 libgc_threads=pthreads
205 # This doesn't seem to work on solaris/x86, but the configure test runs
206 with_tls=pthread
207 has_dtrace=yes
208 use_sigposix=yes
209 enable_solaris_tar_check=yes
210 ;;
211 *-*-darwin*)
212 parallel_mark="Disabled_Currently_Hangs_On_MacOSX"
213 host_win32=no
214 platform_darwin=yes
215 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE -DGC_MACOSX_THREADS -DPLATFORM_MACOSX -DUSE_MMAP -DUSE_MUNMAP"
216 CPPFLAGS="$CPPFLAGS -DGetCurrentProcess=MonoGetCurrentProcess -DGetCurrentThread=MonoGetCurrentThread -DCreateEvent=MonoCreateEvent"
217 libmono_cflags="-D_THREAD_SAFE"
218 LDFLAGS="$LDFLAGS -pthread"
219 libmono_ldflags="-pthread"
220 need_link_unlink=yes
221 AC_DEFINE(PTHREAD_POINTER_ID)
222 AC_DEFINE(USE_MACH_SEMA, 1, [...])
223 no_version_script=yes
224 libdl=
225 libgc_threads=pthreads
226 has_dtrace=yes
227 if test "x$cross_compiling" = "xyes"; then
228 has_broken_apple_cpp=yes
229 fi
230 dnl Snow Leopard is horribly broken -- it reports itself as i386-apple-darwin10.0.0, but
231 dnl its gcc defaults to 64-bit mode. They have also deprecated the usage of ucontext
232 dnl we need to set some flags to build our 32-bit binaries on 10.6 properly
233 case "$host" in
234 dnl MacPorts config.guess reports as this
235 x86_64-*-darwin10*)
236 BROKEN_DARWIN_FLAGS="-arch i386 -D_XOPEN_SOURCE -mmacosx-version-min=10.5"
237 CPPFLAGS="$CPPFLAGS $BROKEN_DARWIN_FLAGS"
238 CFLAGS="$CFLAGS $BROKEN_DARWIN_FLAGS"
239 CXXFLAGS="$CXXFLAGS $BROKEN_DARWIN_FLAGS"
240 CCASFLAGS="$CCASFLAGS $BROKEN_DARWIN_FLAGS"
241 CPPFLAGS_FOR_LIBGC="$CPPFLAGS_FOR_LIBGC $BROKEN_DARWIN_FLAGS"
242 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC $BROKEN_DARWIN_FLAGS"
243 CPPFLAGS_FOR_EGLIB="$CPPFLAGS_FOR_EGLIB $BROKEN_DARWIN_FLAGS"
244 CFLAGS_FOR_EGLIB="$CFLAGS_FOR_EGLIB $BROKEN_DARWIN_FLAGS"
245 ;;
246 dnl Snow Leopard config.guess reports as this
247 i*86-*-darwin10*)
248 BROKEN_DARWIN_FLAGS="-arch i386 -D_XOPEN_SOURCE -mmacosx-version-min=10.5"
249 CPPFLAGS="$CPPFLAGS $BROKEN_DARWIN_FLAGS"
250 CFLAGS="$CFLAGS $BROKEN_DARWIN_FLAGS"
251 CXXFLAGS="$CXXFLAGS $BROKEN_DARWIN_FLAGS"
252 CCASFLAGS="$CCASFLAGS $BROKEN_DARWIN_FLAGS"
253 CPPFLAGS_FOR_LIBGC="$CPPFLAGS_FOR_LIBGC $BROKEN_DARWIN_FLAGS"
254 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC $BROKEN_DARWIN_FLAGS"
255 CPPFLAGS_FOR_EGLIB="$CPPFLAGS_FOR_EGLIB $BROKEN_DARWIN_FLAGS"
256 CFLAGS_FOR_EGLIB="$CFLAGS_FOR_EGLIB $BROKEN_DARWIN_FLAGS"
257 ;;
258 esac
259 ;;
260 *)
261 AC_MSG_WARN([*** Please add $host to configure.in checks!])
262 host_win32=no
263 libdl="-ldl"
264 ;;
265 esac
266 AC_MSG_RESULT(ok)
268 if test x$need_link_unlink = xyes; then
269 AC_DEFINE(NEED_LINK_UNLINK, 1, [Define if Unix sockets cannot be created in an anonymous namespace])
270 fi
272 AM_CONDITIONAL(HOST_WIN32, test x$host_win32 = xyes)
273 AM_CONDITIONAL(TARGET_WIN32, test x$target_win32 = xyes)
274 AM_CONDITIONAL(PLATFORM_LINUX, echo x$target_os | grep -q linux)
275 AM_CONDITIONAL(PLATFORM_DARWIN, test x$platform_darwin = xyes)
276 AM_CONDITIONAL(PLATFORM_SIGPOSIX, test x$use_sigposix = xyes)
278 AC_CHECK_TOOL(CC, gcc, gcc)
279 AC_PROG_CC
280 AC_CHECK_TOOL(CXX, g++, g++)
281 AC_PROG_CXX
282 AM_PROG_AS
283 AM_PROG_CC_STDC
284 AC_PROG_INSTALL
285 AC_PROG_AWK
286 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
287 : ${CCAS='$(CC)'}
288 # Set ASFLAGS if not already set.
289 : ${CCASFLAGS='$(CFLAGS)'}
290 AC_SUBST(CCAS)
291 AC_SUBST(CCASFLAGS)
293 # AC_PROG_CXX helpfully sets CXX to g++ even if no c++ compiler is found so check
294 # GXX instead. See http://lists.gnu.org/archive/html/bug-autoconf/2002-04/msg00056.html
295 if test "x$CXX" = "xg++"; then
296 if test "x$GXX" != "xyes"; then
297 # automake/libtool is so broken, it requires g++ even if the c++ sources
298 # are inside automake conditionals
299 AC_MSG_ERROR([You need to install g++])
300 fi
301 fi
303 AC_CHECK_PROG(BISON, bison,yes,no)
304 if test "x$BISON" = "xno";
305 then
306 AC_MSG_ERROR([You need to install bison])
307 fi
309 dnl may require a specific autoconf version
310 dnl AC_PROG_CC_FOR_BUILD
311 dnl CC_FOR_BUILD not automatically detected
312 CC_FOR_BUILD=$CC
313 CFLAGS_FOR_BUILD=$CFLAGS
314 BUILD_EXEEXT=
315 if test "x$cross_compiling" = "xyes"; then
316 CC_FOR_BUILD=cc
317 CFLAGS_FOR_BUILD=
318 BUILD_EXEEXT=""
319 fi
320 AC_SUBST(CC_FOR_BUILD)
321 AC_SUBST(CFLAGS_FOR_BUILD)
322 AC_SUBST(HOST_CC)
323 AC_SUBST(BUILD_EXEEXT)
325 AM_CONDITIONAL(CROSS_COMPILING, [test x$cross_compiling = xyes])
326 AM_CONDITIONAL(USE_BATCH_FILES, [test x$host_win32 = xyes -a x$cross_compiling = xyes])
328 # Set STDC_HEADERS
329 AC_HEADER_STDC
330 AC_LIBTOOL_WIN32_DLL
331 # This causes monodis to not link correctly
332 #AC_DISABLE_FAST_INSTALL
333 AM_PROG_LIBTOOL
334 # Use dolt (http://dolt.freedesktop.org/) instead of libtool for building.
335 DOLT
337 export_ldflags=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
338 AC_SUBST(export_ldflags)
340 # Test whenever ld supports -version-script
341 AC_PROG_LD
342 AC_PROG_LD_GNU
343 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
344 no_version_script=yes
345 fi
347 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
349 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h sys/utime.h semaphore.h sys/un.h linux/rtc.h sys/syscall.h sys/mkdev.h sys/uio.h)
350 AC_CHECK_HEADERS(sys/user.h sys/socket.h sys/ipc.h sys/sem.h sys/utsname.h alloca.h ucontext.h pwd.h sys/select.h netinet/tcp.h netinet/in.h unistd.h sys/types.h link.h)
353 AC_CHECK_HEADER(zlib.h, [have_zlib=yes], [have_zlib=no])
354 if test x$have_zlib = xyes; then
355 AC_TRY_COMPILE([#include <zlib.h>], [
356 void main () {
357 #if defined(ZLIB_VERNUM) && (ZLIB_VERNUM >= 0x1230)
358 }
359 #else
360 #error No good zlib found
361 #endif
362 ],[
363 AC_MSG_RESULT(Using system zlib)
364 zlib_msg="system zlib"
365 ],[
366 AC_MSG_RESULT(Using embedded zlib)
367 have_zlib=no
368 zlib_msg="bundled zlib"
369 ])
370 fi
372 AM_CONDITIONAL(HAVE_ZLIB, test x$have_zlib = xyes)
373 AC_DEFINE(HAVE_ZLIB,1,[Have system zlib])
375 # for mono/metadata/debug-symfile.c
376 AC_CHECK_HEADERS(elf.h)
378 # for support
379 AC_CHECK_HEADERS(poll.h)
380 AC_CHECK_HEADERS(sys/poll.h)
381 AC_CHECK_HEADERS(sys/wait.h)
382 AC_CHECK_HEADERS(grp.h)
383 AC_CHECK_HEADERS(syslog.h)
385 # for mono/dis
386 AC_CHECK_HEADERS(wchar.h)
387 AC_CHECK_HEADERS(ieeefp.h)
388 AC_MSG_CHECKING(for isinf)
389 AC_TRY_LINK([#include <math.h>], [
390 int f = isinf (1);
391 ], [
392 AC_MSG_RESULT(yes)
393 AC_DEFINE(HAVE_ISINF, 1, [isinf available])
394 ], [
395 # We'll have to use signals
396 AC_MSG_RESULT(no)
397 ])
400 # not 64 bit clean in cross-compile
401 AC_CHECK_SIZEOF(void *, 4)
403 WARN=''
404 if test x"$GCC" = xyes; then
405 WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wwrite-strings'
406 # The runtime code does not respect ANSI C strict aliasing rules
407 CFLAGS="$CFLAGS -fno-strict-aliasing"
409 ORIG_CFLAGS=$CFLAGS
410 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
411 AC_MSG_CHECKING(for -Wdeclaration-after-statement option to gcc)
412 AC_TRY_COMPILE([], [
413 void main () { }
414 ], [
415 AC_MSG_RESULT(yes)
416 ], [
417 AC_MSG_RESULT(no)
418 CFLAGS=$ORIG_CFLAGS
419 ])
420 else
421 # The Sun Forte compiler complains about inline functions that access static variables
422 # so disable all inlining.
423 case "$host" in
424 *-*-solaris*)
425 CFLAGS="$CFLAGS -Dinline="
426 ;;
427 esac
428 fi
429 CFLAGS="$CFLAGS -g $WARN"
430 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC -g"
432 # Where's the 'mcs' source tree?
433 if test -d $srcdir/mcs; then
434 mcsdir=mcs
435 else
436 mcsdir=../mcs
437 fi
439 #
440 # A sanity check to catch cases where the package was unpacked
441 # with an ancient tar program (Solaris)
442 #
443 AC_ARG_ENABLE(solaris-tar-check,
444 [ --disable-solaris-tar-check disable solaris tar check],
445 do_solaris_tar_check=no, do_solaris_tar_check=yes)
447 if test x"$do_solaris_tar_check" = xyes -a x"$enable_solaris_tar_check" = xyes; then
448 AC_MSG_CHECKING(integrity of package)
449 if test -f $srcdir/$mcsdir/class/System.Runtime.Serialization.Formatters.Soap/System.Runtime.Serialization.Formatters.Soap/SoapTypeMapper.cs
450 then
451 AC_MSG_RESULT(ok)
452 else
453 errorm="Your mono distribution is incomplete; if unpacking from a tar file, make sure you use GNU tar; see http://www.mono-project.com/IncompletePackage for more details"
454 AC_MSG_ERROR([$errorm])
455 fi
456 fi
458 mcs_topdir='$(top_srcdir)/'$mcsdir
459 mcs_topdir_from_srcdir='$(top_builddir)/'$mcsdir
461 ## Maybe should also disable if mcsdir is invalid. Let's punt the issue for now.
462 AM_CONDITIONAL(BUILD_MCS, [test x$cross_compiling = xno && test x$enable_mcs_build != xno])
464 AC_SUBST([mcs_topdir])
465 AC_SUBST([mcs_topdir_from_srcdir])
467 # Where's the 'olive' source tree?
468 if test -d $srcdir/olive; then
469 olivedir=olive
470 else
471 olivedir=../olive
472 fi
474 if test -d $srcdir/$olivedir; then
475 olive_topdir='$(top_srcdir)/'$olivedir
476 fi
478 # gettext: prepare the translation directories.
479 # we do not configure the full gettext, as we consume it dynamically from C#
480 AM_PO_SUBDIRS
482 if test "x$USE_NLS" = "xyes"; then
483 AC_CHECK_PROG(HAVE_MSGFMT, msgfmt,yes,no)
485 if test "x$HAVE_MSGFMT" = "xno"; then
486 AC_MSG_ERROR([msgfmt not found. You need to install the 'gettext' package, or pass --enable-nls=no to configure.])
487 fi
488 fi
490 AC_ARG_WITH([libgdiplus],
491 [ --with-libgdiplus=installed|sibling|<path> Override the libgdiplus used for System.Drawing tests (defaults to installed)],
492 [], [with_libgdiplus=installed])
494 case $with_libgdiplus in
495 no|installed) libgdiplus_loc= ;;
496 yes|sibling) libgdiplus_loc=`cd ../libgdiplus && pwd`/src/libgdiplus.la ;;
497 /*) libgdiplus_loc=$with_libgdiplus ;;
498 *) libgdiplus_loc=`pwd`/$with_libgdiplus ;;
499 esac
500 AC_SUBST([libgdiplus_loc])
502 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
503 if test "x$PKG_CONFIG" = "xno"; then
504 AC_MSG_ERROR([You need to install pkg-config])
505 fi
507 pkg_config_path=
508 AC_ARG_WITH(crosspkgdir, [ --with-crosspkgdir=/path/to/pkg-config/dir Change pkg-config dir to custom dir],
509 if test x$with_crosspkgdir = "x"; then
510 if test -s $PKG_CONFIG_PATH; then
511 pkg_config_path=$PKG_CONFIG_PATH
512 fi
513 else
514 pkg_config_path=$with_crosspkgdir
515 PKG_CONFIG_PATH=$pkg_config_path
516 export PKG_CONFIG_PATH
517 fi
518 )
520 AC_ARG_WITH([glib],
521 [ --with-glib=embedded|system Choose glib API: system or embedded (default to system)],
522 [], [with_glib=system])
524 eglib_dir=
526 ac_configure_args="$ac_configure_args \"CPPFLAGS_FOR_EGLIB=$EGLIB_CPPFLAGS\" \"CFLAGS_FOR_EGLIB=$CFLAGS_FOR_EGLIB\""
527 AC_CONFIG_SUBDIRS(eglib)
529 case $with_glib in
530 embedded)
531 GLIB_CFLAGS='-I$(top_srcdir)/eglib/src -I$(top_builddir)/eglib/src'
532 GLIB_LIBS='-L$(top_builddir)/eglib/src -leglib -lm'
533 BUILD_GLIB_CFLAGS="$GLIB_CFLAGS"
534 BUILD_GLIB_LIBS="$GLIB_LIBS"
535 GMODULE_CFLAGS="$GLIB_CFLAGS"
536 GMODULE_LIBS="$GLIB_LIBS"
537 eglib_dir=eglib
538 ;;
539 system)
540 if test "x$cross_compiling" = "xyes"; then
541 pkg_config_path="$PKG_CONFIG_PATH"
542 unset PKG_CONFIG_PATH
543 fi
544 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
545 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
546 if test "x$cross_compiling" = "xyes"; then
547 PKG_CONFIG_PATH=$pkg_config_path
548 export PKG_CONFIG_PATH
549 fi
551 ## Versions of dependencies
552 GLIB_REQUIRED_VERSION=2.4.0
554 dnl
555 dnl No, you will not replace this check with a pkg.m4 check
556 dnl
557 if $PKG_CONFIG --atleast-version=$GLIB_REQUIRED_VERSION glib-2.0; then
558 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
559 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
560 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
561 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
562 else
563 AC_MSG_ERROR([You need at least glib-2.0 $GLIB_REQUIRED_VERSION])
564 fi
565 ;;
566 *)
567 AC_MSG_ERROR([Invalid argument to --with-glib.])
568 esac
569 AM_CONDITIONAL(EGLIB_BUILD, test x$with_glib = xembedded)
571 AC_SUBST(GLIB_CFLAGS)
572 AC_SUBST(GLIB_LIBS)
573 AC_SUBST(GMODULE_CFLAGS)
574 AC_SUBST(GMODULE_LIBS)
575 AC_SUBST(BUILD_GLIB_CFLAGS)
576 AC_SUBST(BUILD_GLIB_LIBS)
577 AC_SUBST(eglib_dir)
579 if test x$cross_compiling$host_win32 = xnoyes; then
580 AC_MSG_CHECKING(for cygwin glib2-dev package)
581 if [ cygcheck --f /usr/lib/libglib-2.0.dll.a | grep -q glib2-devel ]; then
582 AC_MSG_RESULT(found)
583 AC_MSG_ERROR([Mono cannot be built with the cygwin glib2-devel package installed, because that package doesn't work with -mno-cygwin. Please uninstall it then re-run configure.])
584 else
585 AC_MSG_RESULT(not found, ok)
586 fi
588 AC_MSG_CHECKING(for broken gwin32.h)
589 glib_include=`$PKG_CONFIG --cflags-only-I glib-2.0 | sed -e 's/ -I.*//g' | sed -e 's/-I//g'`
590 if test -f $glib_include/glib/gwin32.h; then
591 if [ grep ftruncate $glib_include/glib/gwin32.h | grep -q define ]; then
592 AC_MSG_RESULT(failed)
593 hashmark='#'
594 AC_MSG_ERROR([Your version of gwin32.h is broken and will cause compilation errors when building mono. Please fix it by deleting the line: '$hashmark define ftruncate...' from '$glib_include/glib/gwin32.h' then re-run configure.])
595 fi
596 fi
597 AC_MSG_RESULT(ok)
598 fi
600 AC_ARG_WITH(gc, [ --with-gc=boehm,included,none Defaults to included],[gc=$with_gc],[gc=$gc_default])
602 # Enable support for fast thread-local storage
603 # Some systems have broken support, so we allow to disable it.
604 AC_ARG_WITH(tls, [ --with-tls=__thread,pthread select Thread Local Storage implementation (defaults to __thread)],[],[with_tls=__thread])
606 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
607 # This does not work on some platforms (bug #55253)
608 AC_ARG_WITH(sigaltstack, [ --with-sigaltstack=yes,no enable/disable support for sigaltstack (defaults to yes)],[],[with_sigaltstack=yes])
610 AC_ARG_WITH(static_mono, [ --with-static_mono=yes,no link mono statically to libmono (faster) (defaults to yes)],[],[with_static_mono=yes])
612 if test "x$enable_static" = "xno"; then
613 with_static_mono=no
614 fi
616 if test "x$host_win32" = "xyes"; then
617 # Boehm GC requires the runtime to be in its own dll
618 with_static_mono=no
619 fi
621 AM_CONDITIONAL(STATIC_MONO, test x$with_static_mono != xno)
622 AC_ARG_ENABLE(mcs-build, [ --disable-mcs-build disable the build of the mcs directory], try_mcs_build=$enableval, enable_mcs_build=yes)
624 AC_ARG_WITH(xen_opt, [ --with-xen_opt=yes,no Enable Xen-specific behaviour (defaults to yes)],[],[with_xen_opt=yes])
625 if test "x$with_xen_opt" = "xyes"; then
626 AC_DEFINE(MONO_XEN_OPT, 1, [Xen-specific behaviour])
627 ORIG_CFLAGS=$CFLAGS
628 CFLAGS="$CFLAGS -mno-tls-direct-seg-refs"
629 AC_MSG_CHECKING(for -mno-tls-direct-seg-refs option to gcc)
630 AC_TRY_COMPILE([], [
631 void main () { }
632 ], [
633 AC_MSG_RESULT(yes)
634 # Pass it to libgc as well
635 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC -mno-tls-direct-seg-refs"
636 ], [
637 AC_MSG_RESULT(no)
638 CFLAGS=$ORIG_CFLAGS
639 ])
640 fi
642 AC_ARG_ENABLE(quiet-build, [ --enable-quiet-build Enable quiet runtime build (on by default)], enable_quiet_build=$enableval, enable_quiet_build=yes)
643 AC_ARG_ENABLE(small-config, [ --enable-small-config Enable tweaks to reduce requirements (and capabilities)], enable_small_config=$enableval, enable_small_config=no)
645 if test x$enable_small_config = xyes; then
646 AC_DEFINE(MONO_SMALL_CONFIG,1,[Reduce runtime requirements (and capabilities)])
647 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC -DSMALL_CONFIG"
648 fi
650 if test x$AOT_SUPPORTED != xyes; then
651 AOT_SUPPORTED=no
652 fi
654 AC_ARG_ENABLE(system-aot, [ --enable-system-aot Enable the Ahead-Of-Time compilation of system assemblies during the build (on by default on some platforms)], enable_system_aot=$enableval, enable_system_aot=$AOT_SUPPORTED)
656 DISABLED_FEATURES=none
658 AC_ARG_ENABLE(minimal, [ --enable-minimal=LIST drop support for LIST subsystems.
659 LIST is a comma-separated list from: aot, profiler, decimal, pinvoke, debug,
660 reflection_emit, reflection_emit_save, large_code, logging, com, ssa, generics, attach, jit, simd,soft_debug.],
661 [
662 for feature in `echo "$enable_minimal" | sed -e "s/,/ /g"`; do
663 eval "mono_feature_disable_$feature='yes'"
664 done
665 DISABLED_FEATURES=$enable_minimal
666 disabled="Disabled: $enable_minimal"
667 ],[])
669 AC_DEFINE_UNQUOTED(DISABLED_FEATURES, "$DISABLED_FEATURES", [String of disabled features])
671 if test "x$mono_feature_disable_aot" = "xyes"; then
672 AC_DEFINE(DISABLE_AOT_COMPILER, 1, [Disable AOT Compiler])
673 AC_MSG_NOTICE([Disabled AOT compiler])
674 fi
676 if test "x$mono_feature_disable_profiler" = "xyes"; then
677 AC_DEFINE(DISABLE_PROFILER, 1, [Disable default profiler support])
678 AC_MSG_NOTICE([Disabled support for the profiler])
679 fi
680 AM_CONDITIONAL(DISABLE_PROFILER, test x$mono_feature_disable_profiler = xyes)
682 if test "x$mono_feature_disable_decimal" = "xyes"; then
683 AC_DEFINE(DISABLE_DECIMAL, 1, [Disable System.Decimal support])
684 AC_MSG_NOTICE([Disabled support for decimal])
685 fi
687 if test "x$mono_feature_disable_pinvoke" = "xyes"; then
688 AC_DEFINE(DISABLE_PINVOKE, 1, [Disable P/Invoke support])
689 AC_MSG_NOTICE([Disabled support for P/Invoke])
690 fi
692 if test "x$mono_feature_disable_debug" = "xyes"; then
693 AC_DEFINE(DISABLE_DEBUG, 1, [Disable runtime debugging support])
694 AC_MSG_NOTICE([Disabled support for runtime debugging])
695 fi
697 if test "x$mono_feature_disable_reflection_emit" = "xyes"; then
698 AC_DEFINE(DISABLE_REFLECTION_EMIT, 1, [Disable reflection emit support])
699 mono_feature_disable_reflection_emit_save=yes
700 AC_MSG_NOTICE([Disabled support for Reflection.Emit])
701 fi
703 if test "x$mono_feature_disable_reflection_emit_save" = "xyes"; then
704 AC_DEFINE(DISABLE_REFLECTION_EMIT_SAVE, 1, [Disable assembly saving support in reflection emit])
705 AC_MSG_NOTICE([Disabled support for Reflection.Emit.Save])
706 fi
708 if test "x$mono_feature_disable_large_code" = "xyes"; then
709 AC_DEFINE(DISABLE_LARGE_CODE, 1, [Disable support for huge assemblies])
710 AC_MSG_NOTICE([Disabled support for large assemblies])
711 fi
713 if test "x$mono_feature_disable_logging" = "xyes"; then
714 AC_DEFINE(DISABLE_LOGGING, 1, [Disable support debug logging])
715 AC_MSG_NOTICE([Disabled support for logging])
716 fi
718 if test "x$mono_feature_disable_com" = "xyes"; then
719 AC_DEFINE(DISABLE_COM, 1, [Disable COM support])
720 AC_MSG_NOTICE([Disabled COM support])
721 fi
723 if test "x$mono_feature_disable_ssa" = "xyes"; then
724 AC_DEFINE(DISABLE_SSA, 1, [Disable advanced SSA JIT optimizations])
725 AC_MSG_NOTICE([Disabled SSA JIT optimizations])
726 fi
728 if test "x$mono_feature_disable_generics" = "xyes"; then
729 AC_DEFINE(DISABLE_GENERICS, 1, [Disable generics support])
730 AC_MSG_NOTICE([Disabled Generics Support])
731 fi
733 if test "x$mono_feature_disable_shadowcopy" = "xyes"; then
734 AC_DEFINE(DISABLE_SHADOW_COPY, 1, [Disable Shadow Copy for AppDomains])
735 AC_MSG_NOTICE([Disabled Shadow copy for AppDomains])
736 fi
738 if test "x$mono_feature_disable_portability" = "xyes"; then
739 AC_DEFINE(DISABLE_PORTABILITY, 1, [Disables the IO portability layer])
740 AC_MSG_NOTICE([Disabled IO Portability layer])
741 fi
743 if test "x$mono_feature_disable_attach" = "xyes"; then
744 AC_DEFINE(DISABLE_ATTACH, 1, [Disable agent attach support])
745 AC_MSG_NOTICE([Disabled agent attach])
746 fi
748 if test "x$mono_feature_disable_full_messages" = "xyes"; then
749 AC_DEFINE(DISABLE_FULL_MESSAGES, 1, [Disables building in the full table of WAPI messages])
750 AC_MSG_NOTICE([Disabled full messages for Win32 errors, only core message strings shipped])
751 fi
753 if test "x$mono_feature_disable_verifier" = "xyes"; then
754 AC_DEFINE(DISABLE_VERIFIER, 1, [Disables the verifier])
755 AC_MSG_NOTICE([Disabled the metadata and IL verifiers])
756 fi
758 if test "x$mono_feature_disable_jit" = "xyes"; then
759 AC_DEFINE(DISABLE_JIT, 1, [Disable the JIT, only full-aot mode will be supported by the runtime.])
760 AC_MSG_NOTICE([Disabled the JIT engine, only full AOT will be supported])
761 fi
763 AM_CONDITIONAL(DISABLE_JIT, test x$mono_feature_disable_jit = xyes)
765 if test "x$mono_feature_disable_simd" = "xyes"; then
766 AC_DEFINE(DISABLE_SIMD, 1, [Disable SIMD intrinsics related optimizations.])
767 AC_MSG_NOTICE([Disabled SIMD support])
768 fi
770 if test "x$mono_feature_disable_soft_debug" = "xyes"; then
771 AC_DEFINE(DISABLE_SOFT_DEBUG, 1, [Disable Soft Debugger Agent.])
772 AC_MSG_NOTICE([Disabled Soft Debugger.])
773 fi
775 AC_MSG_CHECKING(for visibility __attribute__)
776 AC_TRY_COMPILE([], [
777 void __attribute__ ((visibility ("hidden"))) doit (void) {}
778 void main () { doit (); }
779 ], [
780 have_visibility_hidden=yes
781 AC_MSG_RESULT(yes)
782 ], [
783 have_visibility_hidden=no
784 AC_MSG_RESULT(no)
785 ])
787 AC_MSG_CHECKING(for deprecated __attribute__)
788 AC_TRY_COMPILE([
789 int doit (void) __attribute__ ((deprecated));
790 int doit (void) { return 0; }
791 ], [
792 return 0;
793 ], [
794 have_deprecated=yes
795 AC_MSG_RESULT(yes)
796 ], [
797 have_deprecated=no
798 AC_MSG_RESULT(no)
799 ])
801 AC_ARG_ENABLE(parallel-mark, [ --enable-parallel-mark Enables GC Parallel Marking], enable_parallel_mark=$enableval, enable_parallel_mark=$parallel_mark)
802 if test x$enable_parallel_mark = xyes; then
803 libgc_configure_args="$libgc_configure_args --enable-parallel-mark"
804 fi
806 LIBGC_CFLAGS=
807 LIBGC_LIBS=
808 LIBGC_STATIC_LIBS=
809 libgc_dir=
810 case "x$gc" in
811 xboehm|xbohem|xyes)
812 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
813 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
815 if test "x$found_boehm" != "xyes"; then
816 AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
817 fi
818 if test "x$gc_headers" != "xyes"; then
819 AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
820 fi
822 AC_DEFINE(HAVE_BOEHM_GC, 1, [Have Boehm GC])
823 AC_SUBST(HAVE_BOEHM_GC)
824 LIBGC_LIBS="-lgc $libdl"
825 LIBGC_STATIC_LIBS="$LIBGC_LIBS"
827 # AC_CHECK_FUNCS does not work for some reason...
828 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
829 if test "x$found_gcj_malloc" = "xyes"; then
830 AC_DEFINE(HAVE_GC_GCJ_MALLOC, 1, [Have GC_gcj_malloc])
831 AC_DEFINE_UNQUOTED(USED_GC_NAME, "System Boehm (with typed GC)", [GC description])
832 else
833 AC_DEFINE_UNQUOTED(USED_GC_NAME, "System Boehm (no typed GC)", [GC description])
834 fi
835 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
836 if test "x$found_gc_enable" = "xyes"; then
837 AC_DEFINE(HAVE_GC_ENABLE, 1, [Have 'GC_enable'])
838 fi
839 ;;
841 xincluded)
842 found_boehm=yes
843 gc_headers=yes
844 use_included_gc=yes
845 libgc_dir=libgc
847 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
848 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
849 LIBGC_STATIC_LIBS='$(top_builddir)/libgc/libmonogc-static.la'
851 AC_DEFINE(HAVE_BOEHM_GC, 1, [Have Boehm GC])
852 AC_SUBST(HAVE_BOEHM_GC)
854 AC_DEFINE(HAVE_GC_H, 1, [Have gc.h])
855 AC_DEFINE(USE_INCLUDED_LIBGC, 1, [Use included libgc])
857 # The included libgc contains GCJ support
858 AC_DEFINE(HAVE_GC_GCJ_MALLOC, 1, [Have GC_gcj_malloc])
859 AC_DEFINE(HAVE_GC_ENABLE, 1, [Have GC_enable])
860 if test x$enable_parallel_mark = xyes; then
861 AC_DEFINE_UNQUOTED(USED_GC_NAME, "Included Boehm (with typed GC and Parallel Mark)", [GC description])
862 else
863 AC_DEFINE_UNQUOTED(USED_GC_NAME, "Included Boehm (with typed GC)", [GC description])
864 fi
865 ;;
867 xsgen)
868 found_boehm=no
869 gc_headers=no
870 use_included_gc=no
871 AC_DEFINE(HAVE_SGEN_GC,1,[Using the simple generational GC.])
872 AC_DEFINE(HAVE_MOVING_COLLECTOR,1,[The GC can move objects.])
873 AC_DEFINE(HAVE_WRITE_BARRIERS,1,[The GC needs write barriers.])
874 AC_DEFINE_UNQUOTED(USED_GC_NAME, "Simple generational", [GC description])
875 ;;
877 xnone)
878 AC_MSG_WARN("Compiling mono without GC.")
879 AC_DEFINE_UNQUOTED(USED_GC_NAME, "none", [GC description])
880 AC_DEFINE(HAVE_NULL_GC,1,[No GC support.])
881 ;;
882 *)
883 AC_MSG_ERROR([Invalid argument to --with-gc.])
884 ;;
885 esac
887 AC_ARG_WITH(large-heap, [ --with-large-heap=yes,no Enable support for GC heaps larger than 3GB (defaults to no)], [large_heap=$withval], [large_heap=no])
888 if test "x$large_heap" = "xyes"; then
889 echo "FOO"
890 CPPFLAGS="$CPPFLAGS -DLARGE_CONFIG"
891 fi
893 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
894 AC_SUBST(LIBGC_CFLAGS)
895 AC_SUBST(LIBGC_LIBS)
896 AC_SUBST(LIBGC_STATIC_LIBS)
897 AC_SUBST(libgc_dir)
899 dnl
900 dnl End of libgc checks
901 dnl
903 dnl *************************************
904 dnl *** Checks for zero length arrays ***
905 dnl *************************************
906 AC_MSG_CHECKING(whether $CC supports zero length arrays)
907 AC_TRY_COMPILE([
908 struct s {
909 int length;
910 char data [0];
911 };
912 ], [], [
913 AC_MSG_RESULT(yes)
914 AC_DEFINE_UNQUOTED(MONO_ZERO_LEN_ARRAY, 0, [Length of zero length arrays])
915 ], [
916 AC_MSG_RESULT(no)
917 AC_DEFINE_UNQUOTED(MONO_ZERO_LEN_ARRAY, 1, [Length of zero length arrays])
918 ])
920 if test x$target_win32 = xno; then
922 dnl hires monotonic clock support
923 AC_SEARCH_LIBS(clock_gettime, rt)
925 dnl dynamic loader support
926 AC_CHECK_FUNC(dlopen, DL_LIB="",
927 AC_CHECK_LIB(dl, dlopen, DL_LIB="-ldl", dl_support=no)
928 )
929 if test x$dl_support = xno; then
930 AC_MSG_WARN([No dynamic loading support available])
931 else
932 LIBS="$LIBS $DL_LIB"
933 AC_DEFINE(HAVE_DL_LOADER,1,[dlopen-based dynamic loader available])
934 dnl from glib's configure.in
935 AC_CACHE_CHECK([for preceeding underscore in symbols],
936 mono_cv_uscore,[
937 AC_TRY_RUN([#include <dlfcn.h>
938 int mono_underscore_test (void) { return 42; }
939 int main() {
940 void *f1 = (void*)0, *f2 = (void*)0, *handle;
941 handle = dlopen ((void*)0, 0);
942 if (handle) {
943 f1 = dlsym (handle, "mono_underscore_test");
944 f2 = dlsym (handle, "_mono_underscore_test");
945 } return (!f2 || f1);
946 }],
947 [mono_cv_uscore=yes],
948 [mono_cv_uscore=no],
949 [])
950 ])
951 if test "x$mono_cv_uscore" = "xyes"; then
952 MONO_DL_NEED_USCORE=1
953 else
954 MONO_DL_NEED_USCORE=0
955 fi
956 AC_SUBST(MONO_DL_NEED_USCORE)
957 AC_CHECK_FUNC(dlerror)
958 fi
960 dnl ******************************************************************
961 dnl *** Checks for the IKVM JNI interface library ***
962 dnl ******************************************************************
963 AC_ARG_WITH(ikvm-native, [ --with-ikvm-native=yes,no build the IKVM JNI interface library (defaults to yes)],[with_ikvm_native=$withval],[with_ikvm_native=yes])
965 ikvm_native_dir=
966 if test x$with_ikvm_native = xyes; then
967 ikvm_native_dir=ikvm-native
968 jdk_headers_found="IKVM Native"
969 fi
971 AC_SUBST(ikvm_native_dir)
973 AC_CHECK_HEADERS(execinfo.h)
975 AC_CHECK_FUNCS(getgrgid_r)
976 AC_CHECK_FUNCS(getgrnam_r)
977 AC_CHECK_FUNCS(getpwnam_r)
978 AC_CHECK_FUNCS(getpwuid_r)
979 AC_CHECK_FUNCS(getresuid)
980 AC_CHECK_FUNCS(setresuid)
981 AC_CHECK_FUNCS(kqueue)
982 AC_CHECK_FUNCS(backtrace_symbols)
983 AC_CHECK_FUNCS(mkstemp)
984 AC_CHECK_FUNCS(mmap)
985 AC_CHECK_FUNCS(madvise)
986 AC_CHECK_FUNCS(getrusage)
987 AC_CHECK_FUNCS(getpriority)
988 AC_CHECK_FUNCS(setpriority)
989 AC_CHECK_FUNCS(dl_iterate_phdr)
991 AC_CHECK_FUNCS(sched_setaffinity)
993 dnl ****************************************************************
994 dnl *** Check for sched_setaffinity from glibc versions before ***
995 dnl *** 2.3.4. The older versions of the function only take 2 ***
996 dnl *** parameters, not 3. ***
997 dnl *** ***
998 dnl *** Because the interface change was not made in a minor ***
999 dnl *** version rev, the __GLIBC__ and __GLIBC_MINOR__ macros ***
1000 dnl *** won't always indicate the interface sched_affinity has. ***
1001 dnl ****************************************************************
1002 AC_MSG_CHECKING(for sched_setaffinity from glibc < 2.3.4)
1003 AC_TRY_COMPILE([#include <sched.h>], [
1004 int main() {
1005 int mask = 1;
1006 sched_setaffinity(0, &mask);
1007 }
1008 ], [
1009 # Yes, we have it...
1010 AC_MSG_RESULT(yes)
1011 AC_DEFINE(GLIBC_BEFORE_2_3_4_SCHED_SETAFFINITY, 1, [Have GLIBC_BEFORE_2_3_4_SCHED_SETAFFINITY])
1012 ], [
1013 # We have the new, three-parameter version
1014 AC_MSG_RESULT(no)
1015 ])
1018 dnl ******************************************************************
1019 dnl *** Check for large file support ***
1020 dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
1021 dnl ******************************************************************
1023 # Check that off_t can represent 2**63 - 1 correctly, working around
1024 # potential compiler bugs. Defines LARGE_FILE_SUPPORT, adds $1 to
1025 # CPPFLAGS and sets $large_offt to yes if the test succeeds
1026 large_offt=no
1027 AC_DEFUN([LARGE_FILES], [
1028 large_CPPFLAGS=$CPPFLAGS
1029 CPPFLAGS="$CPPFLAGS $1"
1030 AC_TRY_RUN([
1031 #include <sys/types.h>
1033 #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
1035 int main(void) {
1036 int big_off_t=((BIG_OFF_T%2147483629==721) &&
1037 (BIG_OFF_T%2147483647==1));
1038 if(big_off_t) {
1039 exit(0);
1040 } else {
1041 exit(1);
1042 }
1043 }
1044 ], [
1045 AC_MSG_RESULT(ok)
1046 AC_DEFINE(HAVE_LARGE_FILE_SUPPORT, 1, [Have large file support])
1047 large_CPPFLAGS="$large_CPPFLAGS $1"
1048 large_offt=yes
1049 ], [
1050 AC_MSG_RESULT(no)
1051 ], "")
1052 CPPFLAGS=$large_CPPFLAGS
1053 ])
1055 AC_MSG_CHECKING(if off_t is 64 bits wide)
1056 LARGE_FILES("")
1057 if test $large_offt = no; then
1058 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
1059 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
1060 fi
1061 if test $large_offt = no; then
1062 AC_MSG_WARN([No 64 bit file size support available])
1063 fi
1065 dnl *****************************
1066 dnl *** Checks for libsocket ***
1067 dnl *****************************
1068 AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
1070 dnl *******************************
1071 dnl *** Checks for MSG_NOSIGNAL ***
1072 dnl *******************************
1073 AC_MSG_CHECKING(for MSG_NOSIGNAL)
1074 AC_TRY_COMPILE([#include <sys/socket.h>], [
1075 int f = MSG_NOSIGNAL;
1076 ], [
1077 # Yes, we have it...
1078 AC_MSG_RESULT(yes)
1079 AC_DEFINE(HAVE_MSG_NOSIGNAL, 1, [Have MSG_NOSIGNAL])
1080 ], [
1081 # We'll have to use signals
1082 AC_MSG_RESULT(no)
1083 ])
1085 dnl *****************************
1086 dnl *** Checks for SOL_IP ***
1087 dnl *****************************
1088 AC_MSG_CHECKING(for SOL_IP)
1089 AC_TRY_COMPILE([#include <netdb.h>], [
1090 int level = SOL_IP;
1091 ], [
1092 # Yes, we have it...
1093 AC_MSG_RESULT(yes)
1094 AC_DEFINE(HAVE_SOL_IP, 1, [Have SOL_IP])
1095 ], [
1096 # We'll have to use getprotobyname
1097 AC_MSG_RESULT(no)
1098 ])
1100 dnl *****************************
1101 dnl *** Checks for SOL_IPV6 ***
1102 dnl *****************************
1103 AC_MSG_CHECKING(for SOL_IPV6)
1104 AC_TRY_COMPILE([#include <netdb.h>], [
1105 int level = SOL_IPV6;
1106 ], [
1107 # Yes, we have it...
1108 AC_MSG_RESULT(yes)
1109 AC_DEFINE(HAVE_SOL_IPV6, 1, [Have SOL_IPV6])
1110 ], [
1111 # We'll have to use getprotobyname
1112 AC_MSG_RESULT(no)
1113 ])
1115 dnl *****************************
1116 dnl *** Checks for SOL_TCP ***
1117 dnl *****************************
1118 AC_MSG_CHECKING(for SOL_TCP)
1119 AC_TRY_COMPILE([#include <netdb.h>], [
1120 int level = SOL_TCP;
1121 ], [
1122 # Yes, we have it...
1123 AC_MSG_RESULT(yes)
1124 AC_DEFINE(HAVE_SOL_TCP, 1, [Have SOL_TCP])
1125 ], [
1126 # We'll have to use getprotobyname
1127 AC_MSG_RESULT(no)
1128 ])
1130 dnl *****************************
1131 dnl *** Checks for IP_PKTINFO ***
1132 dnl *****************************
1133 AC_MSG_CHECKING(for IP_PKTINFO)
1134 AC_TRY_COMPILE([#include <netdb.h>], [
1135 int level = IP_PKTINFO;
1136 ], [
1137 # Yes, we have it...
1138 AC_MSG_RESULT(yes)
1139 AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1140 ], [
1141 AC_MSG_RESULT(no)
1142 ])
1144 dnl *****************************
1145 dnl *** Checks for IPV6_PKTINFO ***
1146 dnl *****************************
1147 AC_MSG_CHECKING(for IPV6_PKTINFO)
1148 AC_TRY_COMPILE([#include <netdb.h>], [
1149 int level = IPV6_PKTINFO;
1150 ], [
1151 # Yes, we have it...
1152 AC_MSG_RESULT(yes)
1153 AC_DEFINE(HAVE_IPV6_PKTINFO, 1, [Have IPV6_PKTINFO])
1154 ], [
1155 AC_MSG_RESULT(no)
1156 ])
1158 dnl **********************************
1159 dnl *** Checks for IP_DONTFRAGMENT ***
1160 dnl **********************************
1161 AC_MSG_CHECKING(for IP_DONTFRAGMENT)
1162 AC_TRY_COMPILE([#include <netdb.h>], [
1163 int level = IP_DONTFRAGMENT;
1164 ], [
1165 # Yes, we have it...
1166 AC_MSG_RESULT(yes)
1167 AC_DEFINE(HAVE_IP_DONTFRAGMENT, 1, [Have IP_DONTFRAGMENT])
1168 ], [
1169 AC_MSG_RESULT(no)
1170 ])
1172 dnl **********************************
1173 dnl *** Checks for IP_MTU_DISCOVER ***
1174 dnl **********************************
1175 AC_MSG_CHECKING(for IP_MTU_DISCOVER)
1176 AC_TRY_COMPILE([#include <netdb.h>], [
1177 int level = IP_MTU_DISCOVER;
1178 ], [
1179 # Yes, we have it...
1180 AC_MSG_RESULT(yes)
1181 AC_DEFINE(HAVE_IP_MTU_DISCOVER, 1, [Have IP_MTU_DISCOVER])
1182 ], [
1183 AC_MSG_RESULT(no)
1184 ])
1186 dnl *********************************
1187 dnl *** Check for struct ip_mreqn ***
1188 dnl *********************************
1189 AC_MSG_CHECKING(for struct ip_mreqn)
1190 AC_TRY_COMPILE([#include <netinet/in.h>], [
1191 struct ip_mreqn mreq;
1192 mreq.imr_address.s_addr = 0;
1193 ], [
1194 # Yes, we have it...
1195 AC_MSG_RESULT(yes)
1196 AC_DEFINE(HAVE_STRUCT_IP_MREQN, 1, [Have struct ip_mreqn])
1197 ], [
1198 # We'll just have to try and use struct ip_mreq
1199 AC_MSG_RESULT(no)
1200 AC_MSG_CHECKING(for struct ip_mreq)
1201 AC_TRY_COMPILE([#include <netinet/in.h>], [
1202 struct ip_mreq mreq;
1203 mreq.imr_interface.s_addr = 0;
1204 ], [
1205 # Yes, we have it...
1206 AC_MSG_RESULT(yes)
1207 AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1, [Have struct ip_mreq])
1208 ], [
1209 # No multicast support
1210 AC_MSG_RESULT(no)
1211 ])
1212 ])
1214 dnl **********************************
1215 dnl *** Check for gethostbyname2_r ***
1216 dnl **********************************
1217 AC_MSG_CHECKING(for gethostbyname2_r)
1218 AC_TRY_LINK([#include <netdb.h>], [
1219 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
1220 ], [
1221 # Yes, we have it...
1222 AC_MSG_RESULT(yes)
1223 AC_DEFINE(HAVE_GETHOSTBYNAME2_R, 1, [Have gethostbyname2_r])
1224 ], [
1225 AC_MSG_RESULT(no)
1226 ])
1228 dnl *****************************
1229 dnl *** Checks for libnsl ***
1230 dnl *****************************
1231 AC_CHECK_FUNC(gethostbyaddr, , AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl"))
1233 AC_CHECK_FUNCS(inet_pton inet_aton)
1235 dnl ***********************************************
1236 dnl *** Checks for size of sockaddr_un.sun_path ***
1237 dnl ***********************************************
1238 # AC_CHECK_SIZEOF can't cope with struct members :-(
1239 AC_MSG_CHECKING(size of sockaddr_un.sun_path)
1240 AC_CACHE_VAL(mono_cv_sizeof_sunpath,
1241 [AC_TRY_RUN([
1242 #include <sys/types.h>
1243 #include <stdio.h>
1244 #include <sys/un.h>
1246 int main(void) {
1247 struct sockaddr_un sock_un;
1248 FILE *f=fopen("conftestval", "w");
1249 if(!f) exit(1);
1250 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
1251 exit(0);
1252 }
1253 ], mono_cv_sizeof_sunpath=`cat conftestval`,
1254 mono_cv_sizeof_sunpath=0,
1255 mono_cv_sizeof_sunpath=0)])dnl
1256 AC_MSG_RESULT($mono_cv_sizeof_sunpath)
1257 AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $mono_cv_sizeof_sunpath, [Sizeof sock_un.sun_path])
1259 dnl *****************************
1260 dnl *** Checks for libxnet ***
1261 dnl *****************************
1262 case "${host}" in
1263 *solaris* )
1264 AC_MSG_CHECKING(for Solaris XPG4 support)
1265 if test -f /usr/lib/libxnet.so; then
1266 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
1267 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
1268 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
1269 LIBS="$LIBS -lxnet"
1270 AC_MSG_RESULT(yes)
1271 else
1272 AC_MSG_RESULT(no)
1273 fi
1275 if test "$GCC" = "yes"; then
1276 CFLAGS="$CFLAGS -Wno-char-subscripts"
1277 fi
1278 ;;
1279 esac
1281 dnl *****************************
1282 dnl *** Checks for libpthread ***
1283 dnl *****************************
1284 # on FreeBSD -STABLE, the pthreads functions all reside in libc_r
1285 # and libpthread does not exist
1286 #
1287 case "${host}" in
1288 *-*-*freebsd*)
1289 AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
1290 ;;
1291 *-*-*openbsd*)
1292 AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
1293 ;;
1294 *)
1295 AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
1296 ;;
1297 esac
1298 AC_CHECK_HEADERS(pthread.h)
1299 AC_CHECK_FUNCS(pthread_mutex_timedlock)
1300 AC_CHECK_FUNCS(pthread_getattr_np pthread_attr_get_np)
1301 AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
1302 AC_TRY_COMPILE([ #include <pthread.h>], [
1303 pthread_mutexattr_t attr;
1304 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
1305 ], [
1306 AC_MSG_RESULT(ok)
1307 ], [
1308 AC_MSG_RESULT(no)
1309 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
1310 AC_DEFINE(USE_MONO_MUTEX, 1, [Use mono_mutex_t])
1311 ])
1312 AC_CHECK_FUNCS(pthread_attr_setstacksize)
1313 AC_CHECK_FUNCS(pthread_attr_getstack pthread_attr_getstacksize)
1314 AC_CHECK_FUNCS(pthread_get_stacksize_np pthread_get_stackaddr_np)
1316 dnl ***********************************
1317 dnl *** Checks for signals
1318 dnl ***********************************
1319 AC_CHECK_HEADERS(signal.h)
1320 AC_CHECK_FUNCS(sigaction)
1322 dnl ***********************************
1323 dnl *** Checks for working __thread ***
1324 dnl ***********************************
1325 AC_MSG_CHECKING(for working __thread)
1326 if test "x$with_tls" != "x__thread"; then
1327 AC_MSG_RESULT(disabled)
1328 else
1329 AC_TRY_RUN([
1330 #include <pthread.h>
1331 __thread int i;
1332 static int res1, res2;
1334 void thread_main (void *arg)
1335 {
1336 i = arg;
1337 sleep (1);
1338 if (arg == 1)
1339 res1 = (i == arg);
1340 else
1341 res2 = (i == arg);
1342 }
1344 int main () {
1345 pthread_t t1, t2;
1347 i = 5;
1349 pthread_create (&t1, NULL, thread_main, 1);
1350 pthread_create (&t2, NULL, thread_main, 2);
1352 pthread_join (t1, NULL);
1353 pthread_join (t2, NULL);
1355 return !(res1 + res2 == 2);
1356 }
1357 ], [
1358 AC_MSG_RESULT(yes)
1359 ], [
1360 AC_MSG_RESULT(no)
1361 with_tls=pthread
1362 ])
1363 fi
1365 dnl **************************************
1366 dnl *** Checks for working sigaltstack ***
1367 dnl **************************************
1368 AC_MSG_CHECKING(for working sigaltstack)
1369 if test "x$with_sigaltstack" != "xyes"; then
1370 AC_MSG_RESULT(disabled)
1371 else
1372 AC_TRY_RUN([
1373 #include <stdio.h>
1374 #include <stdlib.h>
1375 #include <unistd.h>
1376 #include <signal.h>
1377 #include <pthread.h>
1378 #include <sys/wait.h>
1379 #if defined(__FreeBSD__) || defined(__NetBSD__)
1380 #define SA_STACK SA_ONSTACK
1381 #endif
1382 static void
1383 sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
1384 {
1385 exit (0);
1386 }
1388 static void *
1389 loop (void *ignored)
1390 {
1391 char *ptr = NULL;
1393 *ptr = 0;
1394 return NULL;
1395 }
1397 static void
1398 child ()
1399 {
1400 struct sigaction sa;
1401 struct sigaltstack sas;
1402 pthread_t id;
1403 pthread_attr_t attr;
1405 sa.sa_sigaction = sigsegv_signal_handler;
1406 sigemptyset (&sa.sa_mask);
1407 sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
1408 if (sigaction (SIGSEGV, &sa, NULL) == -1) {
1409 perror ("sigaction");
1410 return;
1411 }
1413 sas.ss_sp = malloc (SIGSTKSZ);
1414 sas.ss_size = SIGSTKSZ;
1415 sas.ss_flags = 0;
1416 if (sigaltstack (&sas, NULL) == -1) {
1417 perror ("sigaltstack");
1418 return;
1419 }
1421 pthread_attr_init (&attr);
1422 if (pthread_create(&id, &attr, loop, &attr) != 0) {
1423 printf ("pthread_create\n");
1424 return;
1425 }
1427 sleep (100);
1428 }
1430 int
1431 main ()
1432 {
1433 pid_t son;
1434 int status;
1435 int i;
1437 son = fork ();
1438 if (son == -1) {
1439 return 1;
1440 }
1442 if (son == 0) {
1443 child ();
1444 return 0;
1445 }
1447 for (i = 0; i < 3; ++i) {
1448 sleep (1);
1449 waitpid (son, &status, WNOHANG);
1450 if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
1451 return 0;
1452 }
1454 kill (son, SIGKILL);
1455 return 1;
1456 }
1458 ], [
1459 AC_MSG_RESULT(yes)
1460 AC_DEFINE(HAVE_WORKING_SIGALTSTACK, 1, [Have a working sigaltstack])
1461 ], [
1462 with_sigaltstack=no
1463 AC_MSG_RESULT(no)
1464 ])
1465 fi
1467 dnl ********************************
1468 dnl *** Checks for semaphore lib ***
1469 dnl ********************************
1470 # 'Real Time' functions on Solaris
1471 # posix4 on Solaris 2.6
1472 # pthread (first!) on Linux
1473 AC_SEARCH_LIBS(sem_init, pthread rt posix4)
1475 AC_SEARCH_LIBS(shm_open, pthread rt posix4)
1476 AC_CHECK_FUNCS(shm_open)
1478 dnl ********************************
1479 dnl *** Checks for timezone stuff **
1480 dnl ********************************
1481 AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
1482 AC_TRY_COMPILE([
1483 #include <time.h>
1484 ], [
1485 struct tm tm;
1486 tm.tm_gmtoff = 1;
1487 ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
1488 if test $ac_cv_struct_tm_gmtoff = yes; then
1489 AC_DEFINE(HAVE_TM_GMTOFF, 1, [Have tm_gmtoff])
1490 else
1491 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
1492 AC_TRY_COMPILE([
1493 #include <time.h>
1494 ], [
1495 timezone = 1;
1496 ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
1497 if test $ac_cv_var_timezone = yes; then
1498 AC_DEFINE(HAVE_TIMEZONE, 1, [Have timezone variable])
1499 else
1500 AC_ERROR(unable to find a way to determine timezone)
1501 fi
1502 fi
1504 dnl *********************************
1505 dnl *** Checks for math functions ***
1506 dnl *********************************
1507 LIBS="$LIBS -lm";
1508 if test "x$has_broken_apple_cpp" != "xyes"; then
1509 AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
1510 AC_TRY_LINK([#include <math.h>],
1511 [ finite(0.0); ],
1512 AC_DEFINE(HAVE_FINITE, 1, [Have finite]) AC_MSG_RESULT(yes),
1513 AC_MSG_RESULT(no)))
1514 fi
1515 AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
1516 AC_TRY_LINK([#include <math.h>],
1517 [ isfinite(0.0); ],
1518 AC_DEFINE(HAVE_ISFINITE, 1, [Have isfinite]) AC_MSG_RESULT(yes),
1519 AC_MSG_RESULT(no)))
1521 dnl ****************************************************************
1522 dnl *** Checks for working poll() (macosx defines it but doesn't ***
1523 dnl *** have it in the library (duh)) ***
1524 dnl ****************************************************************
1525 AC_CHECK_FUNCS(poll)
1527 dnl *************************
1528 dnl *** Check for signbit ***
1529 dnl *************************
1530 AC_MSG_CHECKING(for signbit)
1531 AC_TRY_LINK([#include <math.h>], [
1532 int s = signbit(1.0);
1533 ], [
1534 AC_MSG_RESULT(yes)
1535 AC_DEFINE(HAVE_SIGNBIT, 1, [Have signbit])
1536 ], [
1537 AC_MSG_RESULT(no)
1538 ])
1540 dnl **********************************
1541 dnl *** epoll ***
1542 dnl **********************************
1543 AC_CHECK_HEADERS(sys/epoll.h)
1544 haveepoll=no
1545 AC_CHECK_FUNCS(epoll_ctl, [haveepoll=yes], )
1546 if test "x$haveepoll" = "xyes" -a "x$ac_cv_header_sys_epoll_h" = "xyes" ; then
1547 AC_DEFINE(HAVE_EPOLL, 1, [epoll supported])
1548 fi
1550 dnl ******************************
1551 dnl *** Checks for SIOCGIFCONF ***
1552 dnl ******************************
1553 AC_CHECK_HEADERS(sys/ioctl.h)
1554 AC_CHECK_HEADERS(net/if.h)
1555 AC_MSG_CHECKING(for ifreq)
1556 AC_TRY_COMPILE([
1557 #include <stdio.h>
1558 #include <sys/ioctl.h>
1559 #include <net/if.h>
1560 ], [
1561 struct ifconf ifc;
1562 struct ifreq *ifr;
1563 void *x;
1564 ifc.ifc_len = 0;
1565 ifc.ifc_buf = NULL;
1566 x = (void *) &ifr->ifr_addr;
1567 ],[
1568 AC_MSG_RESULT(yes)
1569 AC_DEFINE(HAVE_SIOCGIFCONF, 1, [Can get interface list])
1570 ], [
1571 AC_MSG_RESULT(no)
1572 ])
1573 dnl **********************************
1574 dnl *** Checks for sin_len ***
1575 dnl **********************************
1576 AC_MSG_CHECKING(for sockaddr_in.sin_len)
1577 AC_TRY_COMPILE([
1578 #include <netinet/in.h>
1579 ], [
1580 struct sockaddr_in saddr;
1581 saddr.sin_len = sizeof (saddr);
1582 ],[
1583 AC_MSG_RESULT(yes)
1584 AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [sockaddr_in has sin_len])
1585 ], [
1586 AC_MSG_RESULT(no)
1587 ])
1588 dnl **********************************
1589 dnl *** Checks for sin6_len ***
1590 dnl **********************************
1591 AC_MSG_CHECKING(for sockaddr_in6.sin6_len)
1592 AC_TRY_COMPILE([
1593 #include <netinet/in.h>
1594 ], [
1595 struct sockaddr_in6 saddr6;
1596 saddr6.sin6_len = sizeof (saddr6);
1597 ],[
1598 AC_MSG_RESULT(yes)
1599 AC_DEFINE(HAVE_SOCKADDR_IN6_SIN_LEN, 1, [sockaddr_in6 has sin6_len])
1600 ], [
1601 AC_MSG_RESULT(no)
1602 ])
1603 dnl **********************************
1604 dnl *** Checks for MonoPosixHelper ***
1605 dnl **********************************
1606 AC_CHECK_HEADERS(checklist.h)
1607 AC_CHECK_HEADERS(fstab.h)
1608 AC_CHECK_HEADERS(attr/xattr.h)
1609 AC_CHECK_HEADERS(sys/extattr.h)
1610 AC_CHECK_HEADERS(sys/sendfile.h)
1611 AC_CHECK_HEADERS(sys/statvfs.h)
1612 AC_CHECK_HEADERS(sys/statfs.h)
1613 AC_CHECK_HEADERS(sys/vfstab.h)
1614 AC_CHECK_HEADERS(sys/xattr.h)
1615 AC_CHECK_HEADERS(sys/mman.h)
1616 AC_CHECK_HEADERS(sys/param.h)
1617 AC_CHECK_HEADERS(sys/mount.h)
1618 AC_CHECK_FUNCS(getdomainname)
1619 AC_CHECK_FUNCS(setdomainname)
1620 AC_CHECK_FUNCS(fgetgrent)
1621 AC_CHECK_FUNCS(fgetpwent)
1622 AC_CHECK_FUNCS(fgetpwent)
1623 AC_CHECK_FUNCS(getfsstat)
1624 AC_CHECK_FUNCS(lutimes)
1625 AC_CHECK_FUNCS(mremap)
1626 AC_CHECK_FUNCS(remap_file_pages)
1627 AC_CHECK_FUNCS(posix_fadvise)
1628 AC_CHECK_FUNCS(posix_fallocate)
1629 AC_CHECK_FUNCS(posix_madvise)
1630 AC_CHECK_FUNCS(vsnprintf)
1631 AC_CHECK_FUNCS(sendfile)
1632 AC_CHECK_FUNCS(sethostid)
1633 AC_CHECK_FUNCS(statfs)
1634 AC_CHECK_FUNCS(fstatfs)
1635 AC_CHECK_FUNCS(statvfs)
1636 AC_CHECK_FUNCS(fstatvfs)
1637 AC_CHECK_FUNCS(stime)
1638 AC_CHECK_FUNCS(strerror_r)
1639 AC_CHECK_FUNCS(ttyname_r)
1640 AC_CHECK_SIZEOF(size_t)
1641 AC_CHECK_TYPES([blksize_t], [AC_DEFINE(HAVE_BLKSIZE_T)], ,
1642 [#include <sys/types.h>
1643 #include <sys/stat.h>
1644 #include <unistd.h>])
1645 AC_CHECK_TYPES([blkcnt_t], [AC_DEFINE(HAVE_BLKCNT_T)], ,
1646 [#include <sys/types.h>
1647 #include <sys/stat.h>
1648 #include <unistd.h>])
1649 AC_CHECK_TYPES([suseconds_t], [AC_DEFINE(HAVE_SUSECONDS_T)], ,
1650 [#include <sys/time.h>])
1651 AC_CHECK_TYPES([struct flock], [AC_DEFINE(HAVE_STRUCT_FLOCK)], ,
1652 [#include <unistd.h>
1653 #include <fcntl.h>])
1654 AC_CHECK_TYPES([struct pollfd], [AC_DEFINE(HAVE_STRUCT_POLLFD)], ,
1655 [#include <sys/poll.h>])
1656 AC_CHECK_TYPES([struct stat], [AC_DEFINE(HAVE_STRUCT_STAT)], ,
1657 [#include <sys/types.h>
1658 #include <sys/stat.h>
1659 #include <unistd.h>])
1660 AC_CHECK_TYPES([struct timespec], [AC_DEFINE(HAVE_STRUCT_TIMESPEC)], ,
1661 [#include <time.h>])
1662 AC_CHECK_TYPES([struct timeval], [AC_DEFINE(HAVE_STRUCT_TIMEVAL)], ,
1663 [#include <sys/time.h>
1664 #include <sys/types.h>
1665 #include <utime.h>])
1666 AC_CHECK_TYPES([struct timezone], [AC_DEFINE(HAVE_STRUCT_TIMEZONE)], ,
1667 [#include <sys/time.h>])
1668 AC_CHECK_TYPES([struct utimbuf], [AC_DEFINE(HAVE_STRUCT_UTIMBUF)], ,
1669 [#include <sys/types.h>
1670 #include <utime.h>])
1671 AC_CHECK_MEMBERS(
1672 [struct dirent.d_off, struct dirent.d_reclen, struct dirent.d_type],,,
1673 [#include <sys/types.h>
1674 #include <dirent.h>])
1676 dnl Favour xattr through glibc, but use libattr if we have to
1677 AC_CHECK_FUNC(lsetxattr, ,
1678 AC_CHECK_LIB(attr, lsetxattr, XATTR_LIB="-lattr",)
1679 )
1680 AC_SUBST(XATTR_LIB)
1682 dnl kinfo_proc.kp_proc works on darwin but fails on other simil-bsds
1683 AC_CHECK_MEMBERS(
1684 [struct kinfo_proc.kp_proc],,,
1685 [#include <sys/types.h>
1686 #include <sys/param.h>
1687 #include <sys/sysctl.h>
1688 #include <sys/proc.h>
1689 ])
1691 dnl *********************************
1692 dnl *** Checks for Windows compilation ***
1693 dnl *********************************
1694 AC_CHECK_HEADERS(sys/time.h)
1695 AC_CHECK_HEADERS(sys/param.h)
1696 AC_CHECK_HEADERS(dirent.h)
1698 dnl *********************************
1699 dnl *** Check for Console 2.0 I/O ***
1700 dnl *********************************
1701 AC_CHECK_HEADERS([curses.h])
1702 AC_CHECK_HEADERS([term.h], [], [],
1703 [#if HAVE_CURSES_H
1704 #include <curses.h>
1705 #endif
1706 ])
1707 AC_CHECK_HEADERS([termios.h])
1709 dnl * This is provided in io-layer, but on windows it's only available
1710 dnl * on xp+
1711 AC_DEFINE(HAVE_GETPROCESSID, 1, [Define if GetProcessId is available])
1712 else
1713 jdk_headers_found=no
1714 AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
1715 AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
1716 AC_CHECK_LIB(ole32, main, LIBS="$LIBS -lole32", AC_ERROR(bad mingw install?))
1717 AC_CHECK_LIB(winmm, main, LIBS="$LIBS -lwinmm", AC_ERROR(bad mingw install?))
1718 AC_CHECK_LIB(oleaut32, main, LIBS="$LIBS -loleaut32", AC_ERROR(bad mingw install?))
1719 AC_CHECK_LIB(advapi32, main, LIBS="$LIBS -ladvapi32", AC_ERROR(bad mingw install?))
1720 AC_CHECK_LIB(version, main, LIBS="$LIBS -lversion", AC_ERROR(bad mingw install?))
1722 dnl *********************************
1723 dnl *** Check for struct ip_mreqn ***
1724 dnl *********************************
1725 AC_MSG_CHECKING(for struct ip_mreqn)
1726 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1727 struct ip_mreqn mreq;
1728 mreq.imr_address.s_addr = 0;
1729 ], [
1730 # Yes, we have it...
1731 AC_MSG_RESULT(yes)
1732 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
1733 ], [
1734 # We'll just have to try and use struct ip_mreq
1735 AC_MSG_RESULT(no)
1736 AC_MSG_CHECKING(for struct ip_mreq)
1737 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1738 struct ip_mreq mreq;
1739 mreq.imr_interface.s_addr = 0;
1740 ], [
1741 # Yes, we have it...
1742 AC_MSG_RESULT(yes)
1743 AC_DEFINE(HAVE_STRUCT_IP_MREQ)
1744 ], [
1745 # No multicast support
1746 AC_MSG_RESULT(no)
1747 ])
1748 ])
1749 AC_CHECK_FUNCS(GetProcessId)
1750 fi
1752 dnl socklen_t check
1753 AC_MSG_CHECKING(for socklen_t)
1754 AC_TRY_COMPILE([
1755 #include <sys/types.h>
1756 #include <sys/socket.h>
1757 ],[
1758 socklen_t foo;
1759 ],[
1760 ac_cv_c_socklen_t=yes
1761 AC_DEFINE(HAVE_SOCKLEN_T, 1, [Have socklen_t])
1762 AC_MSG_RESULT(yes)
1763 ],[
1764 AC_MSG_RESULT(no)
1765 ])
1767 AC_MSG_CHECKING(for array element initalizer support)
1768 AC_TRY_COMPILE([#include <sys/socket.h>], [
1769 const int array[] = {[1] = 2,};
1770 ], [
1771 # Yes, we have it...
1772 AC_MSG_RESULT(yes)
1773 AC_DEFINE(HAVE_ARRAY_ELEM_INIT,1,[Supports C99 array initialization])
1774 ], [
1775 # We'll have to use signals
1776 AC_MSG_RESULT(no)
1777 ])
1779 AC_CHECK_FUNCS(trunc, , AC_MSG_CHECKING(for trunc in math.h)
1780 # Simply calling trunc (0.0) is no good since gcc will optimize the call away
1781 AC_TRY_LINK([#include <math.h>],
1782 [ static void *p = &trunc; ],
1783 [
1784 AC_DEFINE(HAVE_TRUNC)
1785 AC_MSG_RESULT(yes)
1786 ac_cv_trunc=yes
1787 ],
1788 AC_MSG_RESULT(no)))
1790 if test "x$ac_cv_truncl" != "xyes"; then
1791 AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL, 1, [Has the 'aintl' function]) LIBS="$LIBS -lsunmath"])
1792 fi
1794 AC_CHECK_FUNCS(round)
1795 AC_CHECK_FUNCS(rint)
1797 dnl ****************************
1798 dnl *** Look for /dev/random ***
1799 dnl ****************************
1801 AC_MSG_CHECKING([if usage of random device is requested])
1802 AC_ARG_ENABLE(dev-random,
1803 [ --disable-dev-random disable the use of the random device (enabled by default)],
1804 try_dev_random=$enableval, try_dev_random=yes)
1806 AC_MSG_RESULT($try_dev_random)
1808 case "{$target}" in
1809 *-openbsd*)
1810 NAME_DEV_RANDOM="/dev/srandom"
1811 ;;
1813 dnl Win32 does not have /dev/random, they have their own method...
1815 *-*-mingw*|*-*-cygwin*)
1816 ac_cv_have_dev_random=no
1817 ;;
1819 dnl Everywhere else, it's /dev/random
1821 *)
1822 NAME_DEV_RANDOM="/dev/random"
1823 ;;
1824 esac
1826 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM", [Name of /dev/random])
1828 dnl Now check if the device actually exists
1830 if test "x$try_dev_random" = "xyes"; then
1831 AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
1832 [if test -r "$NAME_DEV_RANDOM" ; then
1833 ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
1834 if test "x$ac_cv_have_dev_random" = "xyes"; then
1835 AC_DEFINE(HAVE_CRYPT_RNG, 1, [Have /dev/random])
1836 fi
1837 else
1838 AC_MSG_CHECKING(for random device)
1839 ac_cv_have_dev_random=no
1840 AC_MSG_RESULT(has been disabled)
1841 fi
1843 if test "x$host_win32" = "xyes"; then
1844 AC_DEFINE(HAVE_CRYPT_RNG)
1845 fi
1847 if test "x$ac_cv_have_dev_random" = "xno" \
1848 && test "x$host_win32" = "xno"; then
1849 AC_MSG_WARN([[
1850 ***
1851 *** A system-provided entropy source was not found on this system.
1852 *** Because of this, the System.Security.Cryptography random number generator
1853 *** will throw a NotImplemented exception.
1854 ***
1855 *** If you are seeing this message, and you know your system DOES have an
1856 *** entropy collection in place, please contact <crichton@gimp.org> and
1857 *** provide information about the system and how to access the random device.
1858 ***
1859 *** Otherwise you can install either egd or prngd and set the environment
1860 *** variable MONO_EGD_SOCKET to point to the daemon's socket to use that.
1861 ***]])
1862 fi
1864 AC_MSG_CHECKING([if inter-process shared handles are requested])
1865 AC_ARG_ENABLE(shared-handles, [ --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
1866 AC_MSG_RESULT($try_shared_handles)
1867 if test "x$try_shared_handles" != "xyes"; then
1868 AC_DEFINE(DISABLE_SHARED_HANDLES, 1, [Disable inter-process shared handles])
1869 AC_SUBST(DISABLE_SHARED_HANDLES)
1870 fi
1872 AC_ARG_ENABLE(nunit-tests, [ --enable-nunit-tests Run the nunit tests of the class library on 'make check'])
1873 AM_CONDITIONAL(ENABLE_NUNIT_TESTS, [test x$enable_nunit_tests = xyes])
1875 AC_MSG_CHECKING([if big-arrays are to be enabled])
1876 AC_ARG_ENABLE(big-arrays, [ --enable-big-arrays Enable the allocation and indexing of arrays greater than Int32.MaxValue], enable_big_arrays=$enableval, enable_big_arrays=no)
1877 if test "x$enable_big_arrays" = "xyes" ; then
1878 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1879 AC_DEFINE(MONO_BIG_ARRAYS,1,[Enable the allocation and indexing of arrays greater than Int32.MaxValue])
1880 else
1881 AC_MSG_ERROR([The allocation and indexing of arrays greater than Int32.MaxValue is not supported on this platform.])
1882 fi
1883 fi
1884 AC_MSG_RESULT($enable_big_arrays)
1886 dnl **************
1887 dnl *** DTRACE ***
1888 dnl **************
1890 AC_ARG_ENABLE(dtrace,[ --enable-dtrace Enable DTrace probes], enable_dtrace=$enableval, enable_dtrace=$has_dtrace)
1892 if test "x$enable_dtrace" = "xyes"; then
1893 if test "x$has_dtrace" = "xno"; then
1894 AC_MSG_ERROR([DTrace probes are not supported on this platform.])
1895 fi
1896 AC_PATH_PROG(DTRACE, [dtrace], [no], [$PATH:/usr/sbin])
1897 if test "x$DTRACE" = "xno"; then
1898 AC_MSG_RESULT([dtrace utility not found, dtrace support disabled.])
1899 enable_dtrace=no
1900 elif ! $DTRACE -h -s $srcdir/data/mono.d > /dev/null 2>&1; then
1901 AC_MSG_RESULT([dtrace doesn't support -h option, dtrace support disabled.])
1902 enable_dtrace=no
1903 fi
1904 fi
1906 dtrace_g=no
1907 if test "x$enable_dtrace" = "xyes"; then
1908 AC_DEFINE(ENABLE_DTRACE, 1, [Enable DTrace probes])
1909 DTRACEFLAGS=
1910 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1911 case "$host" in
1912 powerpc-*-darwin*)
1913 DTRACEFLAGS="-arch ppc64"
1914 ;;
1915 i*86-*-darwin*)
1916 DTRACEFLAGS="-arch x86_64"
1917 ;;
1918 *)
1919 DTRACEFLAGS=-64
1920 ;;
1921 esac
1922 else
1923 case "$host" in
1924 powerpc-*-darwin*)
1925 DTRACEFLAGS="-arch ppc"
1926 ;;
1927 i*86-*-darwin*)
1928 DTRACEFLAGS="-arch i386"
1929 ;;
1930 *)
1931 DTRACEFLAGS=-32
1932 ;;
1933 esac
1934 fi
1935 AC_SUBST(DTRACEFLAGS)
1936 case "$host" in
1937 *-*-solaris*)
1938 dtrace_g=yes
1939 ;;
1940 esac
1941 AC_CHECK_HEADERS([sys/sdt.h])
1942 fi
1943 AM_CONDITIONAL(ENABLE_DTRACE, [test x$enable_dtrace = xyes])
1944 AM_CONDITIONAL(DTRACE_G_REQUIRED, [test x$dtrace_g = xyes])
1946 dnl **************
1947 dnl *** LLVM ***
1948 dnl **************
1950 AC_ARG_ENABLE(llvm,[ --enable-llvm Enable the experimental LLVM back-end], enable_llvm=$enableval, enable_llvm=no)
1952 if test "x$enable_llvm" = "xyes"; then
1953 AC_PATH_PROG(LLVM_CONFIG, llvm-config, no)
1954 if test "x$LLVM_CONFIG" = "xno"; then
1955 AC_MSG_ERROR([llvm-config not found.])
1956 fi
1958 # The output of --cflags seems to include optimizations flags too
1959 LLVM_CFLAGS=`$LLVM_CONFIG --cflags | sed -e 's/-O2//g' | sed -e 's/-O0//g' | sed -e 's/-fomit-frame-pointer//g' | sed -e 's/-fPIC//g'`
1960 # LLVM is compiled with -fno-rtti, so we need this too, since our classes inherit
1961 # from LLVM classes.
1962 LLVM_CXXFLAGS="`$LLVM_CONFIG --cxxflags` -fno-rtti"
1963 LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1964 LLVM_LIBS=`$LLVM_CONFIG --libs core bitwriter jit x86codegen`
1965 LLVM_LIBS="$LLVM_LDFLAGS $LLVM_LIBS -lstdc++"
1967 # Should be something like '2.6' or '2.7svn'
1968 llvm_version=`$LLVM_CONFIG --version`
1969 major_version=`echo $llvm_version | cut -c 1`
1970 minor_version=`echo $llvm_version | cut -c 3`
1972 AC_DEFINE_UNQUOTED(LLVM_MAJOR_VERSION, $major_version, [Major version of LLVM libraries])
1973 AC_DEFINE_UNQUOTED(LLVM_MINOR_VERSION, $minor_version, [Minor version of LLVM libraries])
1975 # Have to pass these on the command line since mini-llvm-cpp.h already includes
1976 # llvm's config.h
1977 LLVM_CXXFLAGS="$LLVM_CXXFLAGS -DLLVM_MAJOR_VERSION=$major_version -DLLVM_MINOR_VERSION=$minor_version"
1979 AC_SUBST(LLVM_CFLAGS)
1980 AC_SUBST(LLVM_CXXFLAGS)
1981 AC_SUBST(LLVM_LIBS)
1982 AC_SUBST(LLVM_LDFLAGS)
1983 AC_DEFINE(ENABLE_LLVM, 1, [Enable the LLVM back end])
1984 fi
1986 AM_CONDITIONAL(ENABLE_LLVM, [test x$enable_llvm = xyes])
1988 TARGET="unknown"
1989 ACCESS_UNALIGNED="yes"
1991 JIT_SUPPORTED=no
1992 INTERP_SUPPORTED=no
1993 LIBC="libc.so.6"
1994 INTL="libc.so.6"
1995 SQLITE="libsqlite.so.0"
1996 SQLITE3="libsqlite3.so.0"
1997 X11="libX11.so"
1999 sizeof_register="SIZEOF_VOID_P"
2001 jit_wanted=false
2002 interp_wanted=false
2003 case "$host" in
2004 # mips-sgi-irix5.* | mips-sgi-irix6.*)
2005 # TARGET=MIPS;
2006 # ACCESS_UNALIGNED="no"
2007 # ;;
2008 mips*)
2009 TARGET=MIPS;
2010 arch_target=mips;
2011 ACCESS_UNALIGNED="no"
2012 JIT_SUPPORTED=yes
2013 jit_wanted=true
2015 AC_MSG_CHECKING(for mips n32)
2016 AC_TRY_COMPILE([], [
2017 void main () {
2018 #if _MIPS_SIM != _ABIN32
2019 #error Not mips n32
2020 #endif
2021 }
2022 ],[
2023 AC_MSG_RESULT(yes)
2024 sizeof_register=8
2025 ],[
2026 AC_MSG_RESULT(no)
2027 ])
2028 ;;
2029 i*86-*-*)
2030 TARGET=X86;
2031 arch_target=x86;
2032 JIT_SUPPORTED=yes
2033 jit_wanted=true
2034 case $host_os in
2035 solaris*)
2036 LIBC="libc.so"
2037 INTL="libintl.so"
2038 if test "x$ac_cv_sizeof_void_p" = "x8"; then
2039 TARGET=AMD64
2040 arch_target=amd64
2041 fi
2043 # On solaris 10 x86, gcc prints a warning saying 'visibility attribute not supported on this configuration; ignored', but linking fails. A test case:
2044 # int astruct __attribute__ ((visibility ("hidden")));
2045 # void foo ()
2046 # {
2047 # void *p = &astruct;
2048 # }
2049 # gcc -fPIC --shared -o libfoo.so foo.c
2050 # yields:
2051 # foo.c:6: warning: visibility attribute not supported in this configuration; ignored
2052 # ld: fatal: relocation error: R_386_GOTOFF: file /var/tmp//ccxYR96k.o: symbol astruct: relocation must bind locally
2053 have_visibility_hidden=no
2054 ;;
2055 cygwin*)
2056 have_visibility_hidden=no
2057 esac
2058 ;;
2059 x86_64-*-* | amd64-*-*)
2060 TARGET=AMD64;
2061 arch_target=amd64;
2062 JIT_SUPPORTED=yes
2063 jit_wanted=true
2064 ;;
2065 ia64-*-*)
2066 TARGET=IA64
2067 arch_target=ia64
2068 ACCESS_UNALIGNED="no"
2069 JIT_SUPPORTED=yes
2070 jit_wanted=true
2071 LIBC="libc.so.6.1"
2072 INTL="libc.so.6.1"
2073 AC_CHECK_LIB(unwind, _U_dyn_register, [], [AC_MSG_ERROR(library libunwind not found)])
2074 libmono_ldflags="-lunwind"
2075 ;;
2076 sparc*-*-*)
2077 if test "x$ac_cv_sizeof_void_p" = "x8"; then
2078 TARGET=SPARC64
2079 else
2080 TARGET=SPARC
2081 fi
2082 arch_target=sparc;
2083 JIT_SUPPORTED=yes
2084 ACCESS_UNALIGNED="no"
2085 case $host_os in
2086 linux*) ;;
2087 *)
2088 LIBC="libc.so"
2089 INTL="libintl.so"
2090 esac
2091 jit_wanted=true
2092 if test x"$GCC" = xyes; then
2093 # We don't support v8 cpus
2094 CFLAGS="$CFLAGS -Wno-cast-align -mcpu=v9"
2095 fi
2096 if test x"$AR" = xfalse; then
2097 AC_MSG_ERROR([The required utility 'ar' is not found in your PATH. Usually it can be found in /usr/ccs/bin.])
2098 fi
2099 ;;
2100 alpha*-*-linux* | alpha*-*-osf*)
2101 TARGET=ALPHA;
2102 ACCESS_UNALIGNED="no"
2103 JIT_SUPPORTED=yes
2104 jit_wanted=true
2105 arch_target=alpha;
2106 CFLAGS="$CFLAGS -mieee -O0"
2107 case $host_os in
2108 linux*)
2109 LIBC="libc.so.6.1"
2110 INTL="libc.so.6.1"
2111 esac
2112 ;;
2113 *-*-mingw*|*-*-cygwin*)
2114 # When this is enabled, it leads to very strange crashes at runtime (gcc-3.4.4)
2115 have_visibility_hidden=no
2116 INTL="intl"
2117 ;;
2118 hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
2119 TARGET=HPPA;
2120 arch_target=hppa;
2121 LIBC="libc.sl"
2122 ACCESS_UNALIGNED="no"
2123 INTERP_SUPPORTED=yes
2124 interp_wanted=true
2125 ;;
2126 hppa*linux*)
2127 TARGET=HPPA;
2128 arch_target=hppa;
2129 ACCESS_UNALIGNED="no"
2130 JIT_SUPPORTED=yes
2131 jit_wanted=true
2132 ;;
2133 macppc-*-openbsd* | powerpc*-*-linux* | powerpc-*-openbsd* | \
2134 powerpc-*-sysv* | powerpc-*-darwin* | powerpc-*-netbsd* | powerpc-*-freebsd* )
2135 if test "x$ac_cv_sizeof_void_p" = "x8"; then
2136 TARGET=POWERPC64;
2137 CPPFLAGS="$CPPFLAGS -D__mono_ppc__ -D__mono_ppc64__"
2138 CFLAGS="$CFLAGS -mminimal-toc"
2139 else
2140 TARGET=POWERPC;
2141 CPPFLAGS="$CPPFLAGS -D__mono_ppc__"
2142 fi
2143 arch_target=ppc;
2144 JIT_SUPPORTED=yes
2145 jit_wanted=true
2146 ;;
2147 arm*-darwin*)
2148 TARGET=ARM;
2149 arch_target=arm;
2150 ACCESS_UNALIGNED="no"
2151 JIT_SUPPORTED=yes
2152 CPPFLAGS="$CPPFLAGS -DARM_FPU_NONE=1"
2153 jit_wanted=true
2154 ;;
2155 arm*-linux*)
2156 TARGET=ARM;
2157 arch_target=arm;
2158 ACCESS_UNALIGNED="no"
2159 JIT_SUPPORTED=yes
2160 jit_wanted=true
2161 ;;
2162 s390-*-linux*)
2163 TARGET=S390;
2164 arch_target=s390;
2165 ACCESS_UNALIGNED="yes"
2166 JIT_SUPPORTED=yes
2167 jit_wanted=true
2168 # Required CFLAGS for s390[x]. USE_STRING_INLINES is automatic with gcc 4.1
2169 CFLAGS="$CFLAGS -mbackchain -D__USE_STRING_INLINES"
2170 ;;
2171 s390x-*-linux*)
2172 TARGET=S390x;
2173 arch_target=s390x;
2174 ACCESS_UNALIGNED="yes"
2175 JIT_SUPPORTED=yes
2176 jit_wanted=true
2177 CFLAGS="$CFLAGS -mbackchain -D__USE_STRING_INLINES"
2178 ;;
2179 esac
2181 if test "x$host" != "x$target"; then
2182 case "$target" in
2183 powerpc64-ps3-linux-gnu)
2184 TARGET=POWERPC64
2185 arch_target=powerpc64
2186 AC_DEFINE(TARGET_PS3, 1, [...])
2187 AC_DEFINE(MONO_CROSS_COMPILE,1,[The runtime is compiled for cross-compiling mode])
2188 # It would be better to just use TARGET_POWERPC64, but lots of code already
2189 # uses this define
2190 AC_DEFINE(__mono_ppc64__, 1, [...])
2191 AC_DEFINE(__mono_ilp32__, 1, [64 bit mode with 4 byte longs and pointers])
2192 sizeof_register=8
2193 target_byte_order=G_BIG_ENDIAN
2194 ;;
2196 powerpc64-xbox360-linux-gnu)
2197 TARGET=POWERPC64
2198 arch_target=powerpc64
2199 AC_DEFINE(TARGET_XBOX360, 1, [...])
2200 AC_DEFINE(MONO_CROSS_COMPILE,1,[The runtime is compiled for cross-compiling mode])
2201 # It would be better to just use TARGET_POWERPC64, but lots of code already
2202 # uses this define
2203 sizeof_register=8
2204 target_byte_order=G_BIG_ENDIAN
2205 ;;
2206 *)
2207 AC_MSG_ERROR([Cross compiling is only supported for targets matching 'powerpc64-{ps3,xbox360}-linux-gnu'])
2208 esac
2209 fi
2211 # FIXME: Define the others as well
2212 case "$TARGET" in
2213 X86)
2214 AC_DEFINE(TARGET_X86, 1, [...])
2215 ;;
2216 AMD64)
2217 AC_DEFINE(TARGET_AMD64, 1, [...])
2218 ;;
2219 ARM)
2220 AC_DEFINE(TARGET_ARM, 1, [...])
2221 ;;
2222 POWERPC)
2223 AC_DEFINE(TARGET_POWERPC, 1, [...])
2224 ;;
2225 POWERPC64)
2226 AC_DEFINE(TARGET_POWERPC, 1, [...])
2227 AC_DEFINE(TARGET_POWERPC64, 1, [...])
2228 ;;
2229 esac
2231 if test "x$sizeof_register" = "x4"; then
2232 AC_DEFINE(SIZEOF_REGISTER,4,[size of machine integer registers])
2233 elif test "x$sizeof_register" = "x8"; then
2234 AC_DEFINE(SIZEOF_REGISTER,8,[size of machine integer registers])
2235 else
2236 AC_DEFINE(SIZEOF_REGISTER,SIZEOF_VOID_P,[size of machine integer registers])
2237 fi
2239 if test "x$target_byte_order" = "xG_BIG_ENDIAN"; then
2240 AC_DEFINE(TARGET_BYTE_ORDER,G_BIG_ENDIAN,[byte order of target])
2241 elif test "x$target_byte_order" = "xG_LITTLE_ENDIAN"; then
2242 AC_DEFINE(TARGET_BYTE_ORDER,G_LITTLE_ENDIAN,[byte order of target])
2243 else
2244 AC_DEFINE(TARGET_BYTE_ORDER,G_BYTE_ORDER,[byte order of target])
2245 fi
2247 if test "x$have_visibility_hidden" = "xyes"; then
2248 AC_DEFINE(HAVE_VISIBILITY_HIDDEN, 1, [Support for the visibility ("hidden") attribute])
2249 fi
2251 if test "x$have_deprecated" = "xyes"; then
2252 AC_DEFINE(HAVE_DEPRECATED, 1, [Support for the deprecated attribute])
2253 fi
2255 AC_ARG_WITH(jit, [ --with-jit=yes,no If you want to build scripts that default to the JIT (defaults to no)],[
2256 if test x$withval = xyes; then
2257 jit_wanted=true
2258 else
2259 jit_wanted=false
2260 fi
2261 ])
2263 AC_ARG_WITH(interp, [ --with-interp=yes,no If you want to build scripts that default to the interpreter (defaults to no)],[
2264 if test x$withval = xyes; then
2265 interp_wanted=true
2266 else
2267 interp_wanted=false
2268 fi
2269 ])
2271 USEJIT=false
2272 if test x$JIT_SUPPORTED = xyes; then
2273 if $jit_wanted; then
2274 USEJIT=true
2275 jit_status="Building and using the JIT"
2276 else
2277 if $interp_wanted; then
2278 jit_status="Building the JIT, defaulting to the interpreter"
2279 else
2280 AC_ERROR(No JIT or interpreter support available or selected.)
2281 fi
2282 fi
2283 else
2284 if test x$interp_wanted = xtrue; then
2285 jit_status="interpreter"
2286 else
2287 AC_ERROR(No JIT or interpreter support available or selected.)
2288 fi
2289 fi
2291 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
2293 libsuffix=".so"
2295 case "$host" in
2296 *-*-darwin*)
2297 libsuffix=".dylib"
2298 LIBC="libc.dylib"
2299 INTL="libintl.dylib"
2300 SQLITE="libsqlite.0.dylib"
2301 SQLITE3="libsqlite3.0.dylib"
2302 X11="libX11.dylib"
2303 ;;
2304 *-*-*netbsd*)
2305 LIBC="libc.so.12"
2306 INTL="libintl.so.0"
2307 ;;
2308 *-*-*freebsd*)
2309 LIBC="libc.so"
2310 INTL="libintl.so"
2311 ;;
2312 *-*-*openbsd*)
2313 LIBC="libc.so"
2314 INTL="libintl.so"
2315 ;;
2316 *-*-*linux*)
2317 AC_PATH_X
2318 AC_MSG_CHECKING(for the soname of libX11.so)
2319 for i in $x_libraries /usr/lib /usr/lib64; do
2320 for r in 4 5 6; do
2321 if test -f $i/libX11.so.$r; then
2322 X11=libX11.so.$r
2323 AC_MSG_RESULT($X11)
2324 fi
2325 done
2326 done
2328 if test "x$X11" = "xlibX11.so"; then
2329 AC_MSG_WARN([Could not find X development libs. Do you have the -devel package installed? WinForms may not work...]);
2330 fi
2331 ;;
2332 esac
2335 AC_SUBST(libsuffix)
2337 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86"; then
2338 if test "x$with_tls" = "x__thread"; then
2339 #
2340 # On some linux distributions, TLS works in executables, but linking
2341 # against a shared library containing TLS fails with:
2342 # undefined reference to `__tls_get_addr'
2343 #
2344 rm -f conftest.c conftest.so conftest
2345 echo "static __thread int foo; void main () { foo = 5; }" > conftest.c
2346 $CC -fPIC --shared -o conftest.so conftest.c > /dev/null 2>&1
2347 $CC -o conftest conftest.so > /dev/null 2>&1
2348 if test ! -f conftest; then
2349 AC_MSG_WARN([Disabling usage of __thread.]);
2350 with_tls=pthread
2351 fi
2352 rm -f conftest.c conftest.so conftest
2353 fi
2354 fi
2356 mono_debugger_supported=no
2357 AC_ARG_ENABLE(mono-debugger, [ --disable-mono-debugger disable support for the mdb debugger], try_mono_debugger=$enableval, try_mono_debugger=yes)
2358 if test "x$try_mono_debugger" = "xyes"; then
2359 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86" -o "x$TARGET" = "xALPHA"; then
2360 if test x$use_included_gc = xyes; then
2361 case "$host" in
2362 *-*-*linux*)
2363 mono_debugger_supported=yes
2364 ;;
2365 *86-apple-darwin*)
2366 mono_debugger_supported=yes
2367 ;;
2368 esac
2369 fi
2370 fi
2371 fi
2373 AC_MSG_CHECKING(if the Mono Debugger is supported on this platform)
2374 if test "x$mono_debugger_supported" = "xyes"; then
2375 AC_DEFINE(MONO_DEBUGGER_SUPPORTED,1,[The Mono Debugger is supported on this platform])
2376 fi
2377 AC_MSG_RESULT($mono_debugger_supported)
2378 AM_CONDITIONAL(MONO_DEBUGGER_SUPPORTED, test x$mono_debugger_supported = xyes)
2380 if test "x$with_tls" = "x__thread"; then
2381 AC_DEFINE(HAVE_KW_THREAD, 1, [Have __thread keyword])
2382 # Pass the information to libgc
2383 CPPFLAGS="$CPPFLAGS -DUSE_COMPILER_TLS"
2384 AC_MSG_CHECKING(if the tls_model attribute is supported)
2385 AC_TRY_COMPILE([static __thread int foo __attribute__((tls_model("initial-exec")));], [
2386 ], [
2387 AC_MSG_RESULT(yes)
2388 AC_DEFINE(HAVE_TLS_MODEL_ATTR, 1, [tld_model available])
2389 ], [
2390 AC_MSG_RESULT(no)
2391 ])
2392 fi
2394 if test ${TARGET} = ARM && test x$cross_compiling = xno && test x$enable_mcs_build != xno; then
2395 dnl ******************************************
2396 dnl *** Check to see what FPU is available ***
2397 dnl ******************************************
2398 AC_MSG_CHECKING(which FPU to use)
2400 AC_TRY_COMPILE([], [
2401 __asm__ ("ldfd f0, [r0]");
2402 ], fpu=FPA, fpu=NONE)
2404 AC_MSG_RESULT($fpu)
2405 CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu=1"
2406 unset fpu
2407 fi
2409 if test ${TARGET} = unknown; then
2410 CPPFLAGS="$CPPFLAGS -DNO_PORT"
2411 AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
2412 fi
2414 if test ${ACCESS_UNALIGNED} = no; then
2415 CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
2416 fi
2418 case "x$gc" in
2419 xincluded)
2420 # Pass CPPFLAGS to libgc configure
2421 # We should use a separate variable for this to avoid passing useless and
2422 # potentially problematic defines to libgc (like -D_FILE_OFFSET_BITS=64)
2423 # This should be executed late so we pick up the final version of CPPFLAGS
2424 # The problem with this approach, is that during a reconfigure, the main
2425 # configure scripts gets invoked with these arguments, so we use separate
2426 # variables understood by libgc's configure to pass CPPFLAGS and CFLAGS.
2427 LIBGC_CPPFLAGS=$CPPFLAGS
2428 if test x$TARGET = xSPARC -o x$TARGET = xSPARC64; then
2429 LIBGC_CPPFLAGS=`echo $LIBGC_CPPFLAGS | sed -e 's/-D_FILE_OFFSET_BITS=64//g'`
2430 fi
2431 ac_configure_args="$ac_configure_args --disable-embed-check --with-libgc-threads=$libgc_threads $libgc_configure_args \"CPPFLAGS_FOR_LIBGC=$LIBGC_CPPFLAGS\" \"CFLAGS_FOR_LIBGC=$CFLAGS_FOR_LIBGC\""
2432 AC_CONFIG_SUBDIRS(libgc)
2433 ;;
2434 esac
2436 #AC_ARG_WITH(profile2, [ --with-profile2=yes,no If you want to install the 2.0 FX (defaults to yes)], [], [with_profile2=yes])
2437 AC_ARG_WITH(profile4, [ --with-profile4=yes,no If you want to install the 4.0 FX (defaults to yes)], [], [with_profile4=yes])
2438 AC_ARG_WITH(monotouch, [ --with-monotouch=yes,no If you want to build the raw MonoTouch 2.1 assemblies (defaults to no)], [], [with_monotouch=no])
2440 OPROFILE=no
2441 AC_ARG_WITH(oprofile,[ --with-oprofile=no,<oprofile install dir> Enable oprofile support (defaults to no)],[
2442 if test x$with_oprofile != xno; then
2443 oprofile_include=$with_oprofile/include
2444 if test ! -f $oprofile_include/opagent.h; then
2445 AC_MSG_ERROR([oprofile include file not found at $oprofile_include/opagent.h])
2446 fi
2447 OPROFILE=yes
2448 OPROFILE_CFLAGS="-I$oprofile_include"
2449 OPROFILE_LIBS="-L$with_oprofile/lib/oprofile -lopagent"
2450 AC_DEFINE(HAVE_OPROFILE,1,[Have oprofile support])
2451 fi
2452 ])
2454 MALLOC_MEMPOOLS=no
2455 AC_ARG_WITH(malloc_mempools,[ --with-malloc-mempools=yes,no Use malloc for each single mempool allocation (only for runtime debugging, defaults to no)],[
2456 if test x$with_malloc_mempools = xyes; then
2457 MALLOC_MEMPOOLS=yes
2458 AC_DEFINE(USE_MALLOC_FOR_MEMPOOLS,1,[Use malloc for each single mempool allocation])
2459 fi
2460 ])
2463 DISABLE_MCS_DOCS=no
2464 AC_ARG_WITH(mcs_docs,[ --with-mcs-docs=yes,no If you want to build the documentation under mcs (defaults to yes)],[
2465 if test x$with_mcs_docs != xyes; then
2466 DISABLE_MCS_DOCS=yes
2467 fi
2468 ])
2470 MOONLIGHT=no
2471 AC_ARG_WITH(moonlight, [ --with-moonlight=yes,no If you want to build Mono for Moonlight (defaults to no - the resulting mono build is useless for anything but moonlight)],[
2472 if test x$with_moonlight = xyes; then
2473 MOONLIGHT=yes
2474 AC_DEFINE(MOONLIGHT,1,[Building for Moonlight])
2475 fi
2476 ])
2480 dnl
2481 dnl Consistency settings
2482 dnl
2483 if test x$cross_compiling = xyes -o x$enable_mcs_build = xno; then
2484 DISABLE_MCS_DOCS=yes
2485 fi
2487 if test x$DISABLE_MCS_DOCS = xyes; then
2488 docs_dir=""
2489 else
2490 docs_dir=docs
2491 fi
2492 AC_SUBST(docs_dir)
2494 AM_CONDITIONAL(HAVE_OPROFILE, test x$OPROFILE = xyes)
2495 AC_SUBST(OPROFILE_CFLAGS)
2496 AC_SUBST(OPROFILE_LIBS)
2498 libmono_ldflags="$libmono_ldflags $LIBS"
2500 AM_CONDITIONAL(MOONLIGHT, [test "x$with_moonlight" = xyes])
2501 AM_CONDITIONAL(INSTALL_4_0, [test "x$with_profile4" = xyes])
2502 AM_CONDITIONAL(INSTALL_MONOTOUCH, [test "x$with_monotouch" = xyes])
2504 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
2505 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
2506 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
2507 AM_CONDITIONAL(SPARC64, test x$TARGET = xSPARC64)
2508 AM_CONDITIONAL(X86, test x$TARGET = xX86)
2509 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
2510 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
2511 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
2512 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
2513 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
2514 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
2515 AM_CONDITIONAL(POWERPC64, test x$TARGET = xPOWERPC64)
2516 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
2517 AM_CONDITIONAL(S390, test x$TARGET = xS390)
2518 AM_CONDITIONAL(S390x, test x$TARGET = xS390x)
2519 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
2521 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
2522 AM_CONDITIONAL(INTERP_SUPPORTED, test x$interp_wanted = xtrue)
2523 AM_CONDITIONAL(INCLUDED_LIBGC, test x$gc = xincluded)
2525 AC_SUBST(LIBC)
2526 AC_SUBST(INTL)
2527 AC_SUBST(SQLITE)
2528 AC_SUBST(SQLITE3)
2529 AC_SUBST(X11)
2530 AC_DEFINE_UNQUOTED(ARCHITECTURE,"$arch_target",[The architecture this is running on])
2531 AC_SUBST(arch_target)
2532 AC_SUBST(CFLAGS)
2533 AC_SUBST(CPPFLAGS)
2534 AC_SUBST(LDFLAGS)
2536 mono_build_root=`pwd`
2537 AC_SUBST(mono_build_root)
2539 if test x$USEJIT = xtrue; then
2540 mono_runtime=mono/mini/mono
2541 else
2542 mono_runtime=mono/interpreter/mint
2543 fi
2544 AC_SUBST(mono_runtime)
2546 mono_cfg_root=$mono_build_root/runtime
2547 if test x$host_win32 = xyes; then
2548 if test "x$cross_compiling" = "xno"; then
2549 mono_cfg_dir=`cygpath -w -a $mono_cfg_root`\\etc
2550 else
2551 mono_cfg_dir=`echo $mono_cfg_root | tr '/' '\\'`\\etc
2552 fi
2553 else
2554 mono_cfg_dir=$mono_cfg_root/etc
2555 fi
2556 AC_SUBST(mono_cfg_dir)
2558 AC_CONFIG_FILES([po/mcs/Makefile.in])
2560 AC_CONFIG_FILES([runtime/mono-wrapper],[chmod +x runtime/mono-wrapper])
2561 AC_CONFIG_FILES([runtime/monodis-wrapper],[chmod +x runtime/monodis-wrapper])
2563 AC_CONFIG_COMMANDS([runtime/etc/mono/1.0/machine.config],
2564 [ depth=../../../..
2565 case $srcdir in
2566 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2567 .) reldir=$depth ;;
2568 *) reldir=$depth/$srcdir ;;
2569 esac
2570 $ac_aux_dir/install-sh -d runtime/etc/mono/1.0
2571 cd runtime/etc/mono/1.0
2572 rm -f machine.config
2573 $LN_S $reldir/data/net_1_1/machine.config machine.config
2574 cd $depth
2575 ],[LN_S='$LN_S'])
2577 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/machine.config],
2578 [ depth=../../../..
2579 case $srcdir in
2580 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2581 .) reldir=$depth ;;
2582 *) reldir=$depth/$srcdir ;;
2583 esac
2584 $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
2585 cd runtime/etc/mono/2.0
2586 rm -f machine.config
2587 $LN_S $reldir/data/net_2_0/machine.config machine.config
2588 cd $depth
2589 ],[LN_S='$LN_S'])
2591 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/web.config],
2592 [ depth=../../../..
2593 case $srcdir in
2594 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2595 .) reldir=$depth ;;
2596 *) reldir=$depth/$srcdir ;;
2597 esac
2598 $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
2599 cd runtime/etc/mono/2.0
2600 rm -f web.config
2601 $LN_S $reldir/data/net_2_0/web.config web.config
2602 cd $depth
2603 ],[LN_S='$LN_S'])
2605 AC_CONFIG_COMMANDS([runtime/etc/mono/browscap.ini],
2606 [ depth=../../..
2607 case $srcdir in
2608 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2609 .) reldir=$depth ;;
2610 *) reldir=$depth/$srcdir ;;
2611 esac
2612 $ac_aux_dir/install-sh -d runtime/etc/mono/
2613 cd runtime/etc/mono/
2614 rm -f browscap.ini
2615 $LN_S $reldir/data/browscap.ini browscap.ini
2616 cd $depth
2617 ],[LN_S='$LN_S'])
2619 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/Browsers/Compat.browser],
2620 [ depth=../../../../..
2621 case $srcdir in
2622 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2623 .) reldir=$depth ;;
2624 *) reldir=$depth/$srcdir ;;
2625 esac
2626 $ac_aux_dir/install-sh -d runtime/etc/mono/2.0/Browsers/
2627 cd runtime/etc/mono/2.0/Browsers
2628 rm -f Compat.browser
2629 $LN_S $reldir/data/net_2_0/Browsers/Compat.browser Compat.browser
2630 cd $depth
2631 ],[LN_S='$LN_S'])
2633 AC_CONFIG_COMMANDS([runtime/etc/mono/4.0/machine.config],
2634 [ depth=../../../..
2635 case $srcdir in
2636 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2637 .) reldir=$depth ;;
2638 *) reldir=$depth/$srcdir ;;
2639 esac
2640 $ac_aux_dir/install-sh -d runtime/etc/mono/4.0
2641 cd runtime/etc/mono/4.0
2642 rm -f machine.config
2643 $LN_S $reldir/data/net_4_0/machine.config machine.config
2644 cd $depth
2645 ],[LN_S='$LN_S'])
2647 AC_CONFIG_COMMANDS([runtime/etc/mono/4.0/web.config],
2648 [ depth=../../../..
2649 case $srcdir in
2650 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2651 .) reldir=$depth ;;
2652 *) reldir=$depth/$srcdir ;;
2653 esac
2654 $ac_aux_dir/install-sh -d runtime/etc/mono/4.0
2655 cd runtime/etc/mono/4.0
2656 rm -f web.config
2657 $LN_S $reldir/data/net_4_0/web.config web.config
2658 cd $depth
2659 ],[LN_S='$LN_S'])
2661 if test x$enable_quiet_build = xyes; then
2662 AC_CONFIG_COMMANDS([quiet], [for i in `find mono libgc support -name Makefile.in | sed -e 's/Makefile.in/Makefile/g'`; do if test -f $i; then $srcdir/scripts/patch-quiet.sh $i; fi; done], [shell=$SHELL])
2663 AC_CONFIG_COMMANDS([quiet-libtool], [sed -e 's/$echo "copying selected/$show "copying selected/g' < libtool > libtool.tmp && mv libtool.tmp libtool && chmod a+x libtool; sed -e 's/$ECHO "copying selected/# "copying selected/g' < libtool > libtool.tmp && mv libtool.tmp libtool && chmod a+x libtool])
2664 fi
2666 AC_OUTPUT([
2667 Makefile
2668 mono-core.spec
2669 mono-uninstalled.pc
2670 scripts/mono-find-provides
2671 scripts/mono-find-requires
2672 mono/Makefile
2673 mono/utils/Makefile
2674 mono/metadata/Makefile
2675 mono/dis/Makefile
2676 mono/cil/Makefile
2677 mono/arch/Makefile
2678 mono/arch/x86/Makefile
2679 mono/arch/amd64/Makefile
2680 mono/arch/hppa/Makefile
2681 mono/arch/ppc/Makefile
2682 mono/arch/sparc/Makefile
2683 mono/arch/s390/Makefile
2684 mono/arch/s390x/Makefile
2685 mono/arch/arm/Makefile
2686 mono/arch/alpha/Makefile
2687 mono/arch/ia64/Makefile
2688 mono/arch/mips/Makefile
2689 mono/interpreter/Makefile
2690 mono/tests/Makefile
2691 mono/tests/tests-config
2692 mono/tests/assemblyresolve/Makefile
2693 mono/tests/cas/Makefile
2694 mono/tests/cas/assembly/Makefile
2695 mono/tests/cas/demand/Makefile
2696 mono/tests/cas/inheritance/Makefile
2697 mono/tests/cas/linkdemand/Makefile
2698 mono/tests/cas/threads/Makefile
2699 mono/benchmark/Makefile
2700 mono/monograph/Makefile
2701 mono/io-layer/Makefile
2702 mono/mini/Makefile
2703 mono/profiler/Makefile
2704 ikvm-native/Makefile
2705 scripts/Makefile
2706 man/Makefile
2707 web/Makefile
2708 docs/Makefile
2709 data/Makefile
2710 data/net_2_0/Makefile
2711 data/net_4_0/Makefile
2712 data/net_2_0/Browsers/Makefile
2713 data/mint.pc
2714 data/mono-2.pc
2715 data/mono-cairo.pc
2716 data/mono-nunit.pc
2717 data/mono-options.pc
2718 data/mono-lineeditor.pc
2719 data/monodoc.pc
2720 data/mono.web.pc
2721 data/dotnet.pc
2722 data/dotnet35.pc
2723 data/wcf.pc
2724 data/cecil.pc
2725 data/system.web.extensions_1.0.pc
2726 data/system.web.extensions.design_1.0.pc
2727 data/system.web.mvc.pc
2728 data/system.web.mvc2.pc
2729 samples/Makefile
2730 support/Makefile
2731 data/config
2732 tools/Makefile
2733 tools/locale-builder/Makefile
2734 tools/sgen/Makefile
2735 runtime/Makefile
2736 msvc/Makefile
2737 po/Makefile
2738 ])
2740 if test x$host_win32 = xyes; then
2741 # Get rid of 'cyg' prefixes in library names
2742 sed -e "s/\/cyg\//\/\//" libtool > libtool.new; mv libtool.new libtool; chmod 755 libtool
2743 # libtool seems to inherit -mno-cygwin from our CFLAGS, and uses it to compile its executable
2744 # wrapper scripts which use exec(). gcc has no problem compiling+linking this, but the resulting
2745 # executable doesn't work...
2746 sed -e "s,-mno-cygwin,,g" libtool > libtool.new; mv libtool.new libtool; chmod 755 libtool
2747 fi
2749 (
2750 case $prefix in
2751 NONE) prefix=$ac_default_prefix ;;
2752 esac
2753 case $exec_prefix in
2754 NONE) exec_prefix='${prefix}' ;;
2755 esac
2757 test -w $srcdir/$mcsdir/build || chmod +w $srcdir/$mcsdir/build
2759 #
2760 # If we are cross compiling, we don't build in the mcs/ tree. Let us not clobber
2761 # any existing config.make. This allows people to share the same source tree
2762 # with different build directories, one native and one cross
2763 #
2764 if test x$cross_compiling = xno && test x$enable_mcs_build != xno; then
2765 echo "prefix=$prefix" > $srcdir/$mcsdir/build/config.make
2766 echo "exec_prefix=$exec_prefix" >> $srcdir/$mcsdir/build/config.make
2767 echo "sysconfdir=$sysconfdir" >> $srcdir/$mcsdir/build/config.make
2768 echo 'mono_libdir=${exec_prefix}/lib' >> $srcdir/$mcsdir/build/config.make
2769 echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $srcdir/$mcsdir/build/config.make
2770 echo 'IL_FLAGS = /debug' >> $srcdir/$mcsdir/build/config.make
2771 echo "RUNTIME = $mono_build_root/runtime/mono-wrapper" >> $srcdir/$mcsdir/build/config.make
2772 echo "ILDISASM = $mono_build_root/runtime/monodis-wrapper" >> $srcdir/$mcsdir/build/config.make
2773 case $INSTALL in
2774 [[\\/$]]* | ?:[[\\/]]* ) mcs_INSTALL=$INSTALL ;;
2775 *) mcs_INSTALL=$mono_build_root/$INSTALL ;;
2776 esac
2778 echo "INSTALL = $mcs_INSTALL" >> $srcdir/$mcsdir/build/config.make
2780 export VERSION
2781 [myver=$($AWK 'BEGIN {
2782 split (ENVIRON["VERSION"] ".0.0.0", vsplit, ".")
2783 if(length(vsplit [1]) > 4) {
2784 split (substr(ENVIRON["VERSION"], 0, 4) "." substr(ENVIRON["VERSION"], 5) ".0.0", vsplit, ".")
2785 }
2786 print vsplit [1] "." vsplit [2] "." vsplit [3] "." vsplit [4]
2787 }')]
2789 echo "MONO_VERSION = $myver" >> $srcdir/$mcsdir/build/config.make
2790 fi
2792 if test x$platform_darwin = xyes; then
2793 echo "PLATFORM = darwin" >> $srcdir/$mcsdir/build/config.make
2794 fi
2796 if test x$TARGET = xAMD64 -a x$host_win32 = xno -a "x$AOT_SUPPORTED" = "xyes" -a x$enable_system_aot = xyes; then
2797 echo "ENABLE_AOT = 1" >> $srcdir/$mcsdir/build/config.make
2798 fi
2800 # if we have an olive folder, override the default settings
2801 if test -d $olivedir; then
2803 test -w $srcdir/$olivedir/build || chmod +w $srcdir/$olivedir/build
2805 if test x$cross_compiling = xno && test x$enable_olive_build != xno; then
2806 echo "prefix=$prefix" > $srcdir/$olivedir/build/config.make
2807 echo "exec_prefix=$exec_prefix" >> $srcdir/$olivedir/build/config.make
2808 echo 'mono_libdir=${exec_prefix}/lib' >> $srcdir/$olivedir/build/config.make
2809 echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $srcdir/$olivedir/build/config.make
2810 echo "RUNTIME = $mono_build_root/runtime/mono-wrapper" >> $srcdir/$olivedir/build/config.make
2811 echo "MONO_VERSION = $myver" >> $srcdir/$olivedir/build/config.make
2812 fi
2813 fi
2815 if test x$DISABLE_MCS_DOCS = xyes; then
2816 echo "DISABLE_MCS_DOCS = yes" >> $srcdir/$mcsdir/build/config.make
2817 fi
2819 if test x$with_moonlight = xyes; then
2820 echo "MOONLIGHT = 1" >> $srcdir/$mcsdir/build/config.make
2821 fi
2822 )
2824 libgdiplus_msg=${libgdiplus_loc:-assumed to be installed}
2826 echo "
2827 mcs source: $mcs_topdir
2828 olive source: $olive_topdir
2830 Engine:
2831 GC: $gc
2832 GLIB: $with_glib
2833 TLS: $with_tls
2834 SIGALTSTACK: $with_sigaltstack
2835 Engine: $jit_status
2836 oprofile: $OPROFILE
2837 BigArrays: $enable_big_arrays
2838 DTrace: $enable_dtrace
2839 Parallel Mark: $enable_parallel_mark
2840 LLVM Back End: $enable_llvm
2842 Libraries:
2843 Moon Profile: $with_moonlight
2844 MonoTouch: $with_monotouch
2845 JNI support: $jdk_headers_found
2846 libgdiplus: $libgdiplus_msg
2847 zlib: $zlib_msg
2848 $disabled
2849 "
2850 if test x$with_static_mono = xno -a "x$host_win32" != "xyes"; then
2851 AC_MSG_WARN(Turning off static Mono is a risk, you might run into unexpected bugs)
2852 fi
2854 if test x$gc = xsgen; then
2855 echo IMPORTANT:
2856 echo IMPORTANT: You have selected an experimental, work-in-progress
2857 echo IMPORTANT: GC engine. This GC engine is currently not supported
2858 echo IMPORTANT: and is not yet ready for use.
2859 echo IMPORTANT:
2860 echo IMPORTANT: There are known problems with it, use at your own risk.
2861 fi
2863 if test x$enable_llvm = xyes; then
2864 echo IMPORTANT:
2865 echo IMPORTANT: The LLVM Back End is experimental and has known problems.
2866 echo IMPORTANT:
2867 fi