| blob | f6f7a047e6198fe21070d5a63069ee8f95d6bff3 |
1 AC_INIT(README)
2 AC_CANONICAL_SYSTEM
3 AM_CONFIG_HEADER(config.h)
4 AM_INIT_AUTOMAKE(mono,1.1.1)
5 AM_MAINTAINER_MODE
7 AC_PROG_LN_S
9 dnl
10 dnl libgc checks
11 dnl
13 gc_headers=no
14 gc=included
15 use_included_gc=no
17 if test -d $srcdir/libgc ; then
18 gc_default=included
19 else
20 gc_default=boehm
21 fi
23 #
24 # These are the flags that need to be stored in the mono.pc file for
25 # compiling code that will embed Mono
26 #
27 libmono_cflags=""
28 libmono_ldflags=""
29 AC_SUBST(libmono_cflags)
30 AC_SUBST(libmono_ldflags)
32 dnl if linker handles the version script
33 no_version_script=no
35 # Set to yes if Unix sockets cannot be created in an anonymous namespace
36 need_link_unlink=no
38 # Thread configuration inspired by sleepycat's db
39 AC_MSG_CHECKING([host platform characteristics])
40 libgc_threads=no
41 case "$host" in
42 *-*-mingw*|*-*-cygwin*)
43 platform_win32=yes
44 AC_DEFINE(PLATFORM_WIN32,1,[Platform is Win32])
45 CC="gcc -mno-cygwin -g"
46 HOST_CC="gcc"
47 # So libgc configure gets -mno-cygwin
48 export CC
49 # latest libgc already defines GC_WIN32_THREADS
50 # CPPFLAGS="$CPPFLAGS -DGC_WIN32_THREADS -DWIN32_THREADS"
51 CPPFLAGS="$CPPFLAGS -DWIN32_THREADS"
52 libdl=
53 libgc_threads=win32
54 gc_default=included
55 with_nptl=default
56 with_sigaltstack=no
57 LN_S=cp
59 ;;
60 *-*-*netbsd*)
61 platform_win32=no
62 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
63 libmono_cflags="-D_REENTRANT"
64 LDFLAGS="$LDFLAGS -pthread"
65 libmono_ldflags="-pthread"
66 need_link_unlink=yes
67 libdl=
68 libgc_threads=no
69 ;;
70 # these flags will work for all versions of -STABLE
71 #
72 *-*-*freebsd4*)
73 platform_win32=no
74 if test "x$PTHREAD_CFLAGS" = "x"; then
75 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
76 libmono_cflags="-D_THREAD_SAFE"
77 else
78 CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
79 libmono_cflags="$PTHREAD_CFLAGS"
80 fi
81 if test "x$PTHREAD_LIBS" = "x"; then
82 LDFLAGS="$LDFLAGS -pthread"
83 libmono_ldflags="-pthread"
84 else
85 LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
86 libmono_ldflags="$PTHREAD_LIBS"
87 fi
88 need_link_unlink=yes
89 AC_DEFINE(PTHREAD_POINTER_ID)
90 libdl=
91 libgc_threads=pthreads
92 # TLS isn't implemented at all on -STABLE
93 with_nptl=no
94 with_tls=pthread
95 ;;
96 # older versions of -CURRENT will break with these flags but testing
97 # indicates these older versions won't run Mono anyway
98 #
99 *-*-*freebsd5*)
100 platform_win32=no
101 if test "x$PTHREAD_CFLAGS" = "x"; then
102 CPPFLAGS="$CPPFLAGS -DGC_FREEBSD_THREADS"
103 libmono_cflags=
104 else
105 CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
106 libmono_cflags="$PTHREAD_CFLAGS"
107 fi
108 if test "x$PTHREAD_LIBS" = "x"; then
109 LDFLAGS="$LDFLAGS -lpthread"
110 libmono_ldflags="-lpthread"
111 else
112 LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
113 libmono_ldflags="$PTHREAD_LIBS"
114 fi
115 need_link_unlink=yes
116 AC_DEFINE(PTHREAD_POINTER_ID)
117 libdl=
118 libgc_threads=pthreads
119 # TLS is only partially implemented on -CURRENT (compiler support
120 # but NOT library support)
121 #
122 with_nptl=no
123 with_tls=pthread
124 ;;
125 *-*-*openbsd*)
126 platform_win32=no
127 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
128 libmono_cflags="-D_THREAD_SAFE"
129 LDFLAGS="$LDFLAGS -pthread"
130 libmono_ldflags="-pthread"
131 need_link_unlink=yes
132 AC_DEFINE(PTHREAD_POINTER_ID)
133 libdl=
134 libgc_threads=pthreads
135 ;;
136 *-*-linux*)
137 platform_win32=no
138 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -D_GNU_SOURCE -D_REENTRANT"
139 libmono_cflags="-D_REENTRANT"
140 libmono_ldflags="-lpthread"
141 libdl="-ldl"
142 libgc_threads=pthreads
143 ;;
144 *-*-hpux*)
145 platform_win32=no
146 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
147 CFLAGS="$CFLAGS +ESdbgasm"
148 LDFLAGS="$LDFLAGS -z"
149 libmono_cflags="-D_REENTRANT"
150 libmono_ldflags="-lpthread"
151 libgc_threads=pthreads
152 need_link_unlink=yes
153 ;;
154 *-*-solaris*)
155 platform_win32=no
156 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT"
157 need_link_unlink=yes
158 libmono_cflags="-D_REENTRANT"
159 libgc_threads=pthreads
160 ;;
161 *-*-darwin*)
162 platform_win32=no
163 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE -DGC_MACOSX_THREADS"
164 libmono_cflags="-D_THREAD_SAFE"
165 LDFLAGS="$LDFLAGS -pthread"
166 libmono_ldflags="-pthread"
167 need_link_unlink=yes
168 AC_DEFINE(PTHREAD_POINTER_ID)
169 AC_DEFINE(USE_MACH_SEMA)
170 no_version_script=yes
171 libdl=
172 libgc_threads=pthreads
173 ;;
174 *)
175 AC_MSG_WARN([*** Please add $host to configure.in checks!])
176 platform_win32=no
177 libdl="-ldl"
178 ;;
179 esac
180 AC_MSG_RESULT(ok)
182 if test x$need_link_unlink = xyes; then
183 AC_DEFINE(NEED_LINK_UNLINK, 1, [Define if Unix sockets cannot be created in an anonymous namespace])
184 fi
186 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
188 AC_CHECK_TOOL(CC, gcc, gcc)
189 AC_PROG_CC
190 AM_PROG_CC_STDC
191 AC_PROG_INSTALL
192 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
193 : ${CCAS='$(CC)'}
194 # Set ASFLAGS if not already set.
195 : ${CCASFLAGS='$(CFLAGS)'}
196 AC_SUBST(CCAS)
197 AC_SUBST(CCASFLAGS)
199 AC_CHECK_PROG(BISON, bison,yes,no)
200 if test "x$BISON" = "xno";
201 then
202 AC_MSG_ERROR([You need to install bison])
203 fi
205 dnl may require a specific autoconf version
206 dnl AC_PROG_CC_FOR_BUILD
207 dnl CC_FOR_BUILD not automatically detected
208 CC_FOR_BUILD=$CC
209 BUILD_EXEEXT=
210 if test "x$cross_compiling" = "xyes"; then
211 CC_FOR_BUILD=cc
212 BUILD_EXEEXT=""
213 fi
214 AC_SUBST(CC_FOR_BUILD)
215 AC_SUBST(HOST_CC)
216 AC_SUBST(BUILD_EXEEXT)
218 # Set STDC_HEADERS
219 AC_HEADER_STDC
220 AC_LIBTOOL_WIN32_DLL
221 AM_PROG_LIBTOOL
223 # Test whenever ld supports -version-script
224 AC_PROG_LD
225 AC_PROG_LD_GNU
226 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
227 no_version_script=yes
228 fi
230 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
232 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h semaphore.h sys/un.h)
234 # for mono/metadata/debug-symfile.c
235 AC_CHECK_HEADERS(elf.h)
237 # for mono/dis
238 AC_CHECK_HEADERS(wchar.h)
240 # not 64 bit clean in cross-compile
241 AC_CHECK_SIZEOF(void *, 4)
243 WARN=''
244 if test x"$GCC" = xyes; then
245 WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wcast-align -Wwrite-strings'
246 # The runtime code does not respect ANSI C strict aliasing rules
247 CFLAGS="$CFLAGS -fno-strict-aliasing"
248 else
249 # The Sun Forte compiler complains about inline functions that access static variables
250 # so disable all inlining.
251 case "$host" in
252 *-*-solaris*)
253 CFLAGS="$CFLAGS -Dinline="
254 ;;
255 esac
256 fi
257 CFLAGS="$CFLAGS -g $WARN"
259 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
260 if test "x$PKG_CONFIG" = "xno"; then
261 AC_MSG_ERROR([You need to install pkg-config])
262 fi
264 dnl for use on the build system
265 dnl pkg-config is stupid
266 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
267 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
268 AC_SUBST(BUILD_GLIB_CFLAGS)
269 AC_SUBST(BUILD_GLIB_LIBS)
271 PKG_PATH=
272 AC_ARG_WITH(crosspkgdir, [ --with-crosspkgdir=/path/to/pkg-config/dir],
273 if test x$with_crosspkgdir = "x"; then
274 if test -s $PKG_CONFIG_PATH; then
275 PKG_PATH=$PKG_CONFIG_PATH
276 fi
277 else
278 PKG_PATH=$with_crosspkgdir
279 PKG_CONFIG_PATH=$PKG_PATH
280 export PKG_CONFIG_PATH
281 fi
282 )
284 ## Versions of dependencies
285 GLIB_REQUIRED_VERSION=1.3.11
287 PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION)
289 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
290 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
291 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
292 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
294 AC_SUBST(GLIB_CFLAGS)
295 AC_SUBST(GLIB_LIBS)
296 AC_SUBST(GMODULE_CFLAGS)
297 AC_SUBST(GMODULE_LIBS)
299 AC_ARG_WITH(gc, [ --with-gc=boehm,included,none],[gc=$with_gc],[gc=$gc_default])
301 # Enable support for fast thread-local storage
302 # Some systems have broken support, so we allow to disable it.
303 AC_ARG_WITH(tls, [ --with-tls=__thread,pthread select Thread Local Storage implementation],[],[with_tls=__thread])
305 # Kept for compatibility
306 AC_ARG_WITH(nptl, [ --with-nptl=yes,no deprecated, use --with-tls instead],[],[with_nptl=default])
308 if test "x$with_nptl" != "xdefault"; then
309 if test "x$with_nptl" = "xyes"; then
310 AC_MSG_WARN([--with-nptl=yes is deprecated, use --with-tls=__thread option instead.])
311 with_tls=__thread
312 fi
313 if test "x$with_nptl" = "xno"; then
314 AC_MSG_WARN([--with-nptl=no is deprecated, use --with-tls=pthread option instead.])
315 with_tls=pthread
316 fi
317 fi
319 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
320 # This does not work on some platforms (bug #55253)
321 AC_ARG_WITH(sigaltstack, [ --with-sigaltstack=yes,no enable/disable support for sigaltstack],[],[with_sigaltstack=no])
323 # assembly bundle support, see metadata/make-bundle.pl for more info
324 AC_ARG_WITH(bundle, [ --with-bundle=bundle_template],[
325 BUNDLE_FILE=$with_bundle
326 AC_SUBST(BUNDLE_FILE)
327 AC_DEFINE(WITH_BUNDLE)
328 ],[with_bundle=no])
329 AM_CONDITIONAL(WITH_BUNDLE, test x$with_bundle != xno)
331 LIBGC_CFLAGS=
332 LIBGC_LIBS=
333 LIBGC_STATIC_LIBS=
334 libgc_dir=
335 case "x$gc" in
336 xboehm|xbohem|xyes)
337 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
338 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
340 if test "x$found_boehm" != "xyes"; then
341 AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
342 fi
343 if test "x$gc_headers" != "xyes"; then
344 AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
345 fi
347 AC_DEFINE(HAVE_BOEHM_GC)
348 AC_SUBST(HAVE_BOEHM_GC)
349 LIBGC_LIBS="-lgc $libdl"
350 LIBGC_STATIC_LIBS="$LIBGC_LIBS"
352 # AC_CHECK_FUNCS does not work for some reason...
353 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
354 if test "x$found_gcj_malloc" = "xyes"; then
355 AC_DEFINE(HAVE_GC_GCJ_MALLOC)
356 fi
357 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
358 if test "x$found_gc_enable" = "xyes"; then
359 AC_DEFINE(HAVE_GC_ENABLE)
360 fi
361 ;;
363 xincluded)
364 AC_CONFIG_SUBDIRS(libgc)
366 found_boehm=yes
367 gc_headers=yes
368 use_included_gc=yes
369 libgc_dir=libgc
371 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
372 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
373 LIBGC_STATIC_LIBS='$(top_builddir)/libgc/libmonogc-static.la'
375 AC_DEFINE(HAVE_BOEHM_GC)
376 AC_SUBST(HAVE_BOEHM_GC)
378 AC_DEFINE(HAVE_GC_H)
379 AC_DEFINE(USE_INCLUDED_LIBGC)
381 # The included libgc contains GCJ support
382 AC_DEFINE(HAVE_GC_GCJ_MALLOC)
383 AC_DEFINE(HAVE_GC_ENABLE)
384 ;;
386 xnone)
387 AC_MSG_WARN("Compiling mono without GC.")
388 ;;
389 *)
390 AC_MSG_ERROR([Invalid argument to --with-gc.])
391 ;;
392 esac
395 # tell libgc/configure about what we want
396 ac_configure_args="$ac_configure_args --disable-embed-check --with-libgc-threads=$libgc_threads"
398 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
399 AC_SUBST(LIBGC_CFLAGS)
400 AC_SUBST(LIBGC_LIBS)
401 AC_SUBST(LIBGC_STATIC_LIBS)
402 AC_SUBST(libgc_dir)
404 dnl
405 dnl End of libgc checks
406 dnl
408 if test x$platform_win32 = xno; then
410 dnl ******************************************************************
411 dnl *** Checks for the IKVM JNI interface library ***
412 dnl ******************************************************************
413 AC_ARG_WITH(ikvm-jni, [ --with-ikvm-jni=yes,no build the IKVM JNI interface library],[with_ikvm_jni=$withval],[with_ikvm_jni=yes])
414 AC_ARG_WITH(jdk, [ --with-jdk=DIRECTORY Use JDK from DIRECTORY],[with_jdk_dir=$withval],[with_jdk_dir=])
416 ikvm_jni_dir=
417 if test x$with_ikvm_jni = xyes; then
418 AC_MSG_CHECKING([JDK headers])
420 if test x$with_jdk_dir = x; then
421 # Try JAVA_HOME variable
422 if test x$JAVA_HOME != x; then
423 with_jdk_dir=$JAVA_HOME
424 fi
425 fi
427 jdk_platform=
428 if test -d $with_jdk_dir/include; then
429 jdk_headers_found=yes
431 if test -d $with_jdk_dir/include/linux; then
432 jdk_platform=linux
433 else
434 if test -d $with_jdk_dir/include/solaris; then
435 jdk_platform=solaris
436 else
437 if test -f $with_jdk_dir/include/jni_md.h; then
438 # GNU Classpath sources
439 jdk_platform=
440 else
441 jdk_headers_found=no
442 fi
443 fi
444 fi
445 else
446 jdk_headers_found=no
447 fi
449 if test x$jdk_headers_found = xyes; then
450 AC_MSG_RESULT($with_jdk_dir/include $with_jdk_dir/include/$jdk_platform)
451 else
452 AC_MSG_RESULT(not found)
453 fi
455 if test x$jdk_headers_found = xyes; then
456 ikvm_jni_dir=ikvm-jni
457 IKVM_JNI_CFLAGS="-I$with_jdk_dir/include -I$with_jdk_dir/include/$jdk_platform"
458 fi
459 fi
461 AC_SUBST(ikvm_jni_dir)
462 AC_SUBST(IKVM_JNI_CFLAGS)
464 AC_CHECK_FUNCS(getgrgid_r)
465 AC_CHECK_FUNCS(getgrnam_r)
466 AC_CHECK_FUNCS(getpwnam_r)
467 AC_CHECK_FUNCS(getpwuid_r)
468 AC_CHECK_FUNCS(getresuid)
469 AC_CHECK_FUNCS(setresuid)
470 AC_CHECK_FUNCS(kqueue)
472 dnl ******************************************************************
473 dnl *** Check for large file support ***
474 dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
475 dnl ******************************************************************
477 # Check that off_t can represent 2**63 - 1 correctly, working around
478 # potential compiler bugs. Defines LARGE_FILE_SUPPORT, adds $1 to
479 # CPPFLAGS and sets $large_offt to yes if the test succeeds
480 large_offt=no
481 AC_DEFUN(LARGE_FILES, [
482 large_CPPFLAGS=$CPPFLAGS
483 CPPFLAGS="$CPPFLAGS $1"
484 AC_TRY_RUN([
485 #include <sys/types.h>
487 #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
489 int main(void) {
490 int big_off_t=((BIG_OFF_T%2147483629==721) &&
491 (BIG_OFF_T%2147483647==1));
492 if(big_off_t) {
493 exit(0);
494 } else {
495 exit(1);
496 }
497 }
498 ], [
499 AC_MSG_RESULT(ok)
500 AC_DEFINE(HAVE_LARGE_FILE_SUPPORT)
501 large_CPPFLAGS="$large_CPPFLAGS $1"
502 large_offt=yes
503 ], [
504 AC_MSG_RESULT(no)
505 ], "")
506 CPPFLAGS=$large_CPPFLAGS
507 ])
509 AC_MSG_CHECKING(if off_t is 64 bits wide)
510 LARGE_FILES("")
511 if test $large_offt = no; then
512 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
513 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
514 fi
515 if test $large_offt = no; then
516 AC_MSG_WARN([No 64 bit file size support available])
517 fi
519 dnl *****************************
520 dnl *** Checks for libsocket ***
521 dnl *****************************
522 AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
524 dnl *******************************
525 dnl *** Checks for MSG_NOSIGNAL ***
526 dnl *******************************
527 AC_MSG_CHECKING(for MSG_NOSIGNAL)
528 AC_TRY_COMPILE([#include <sys/socket.h>], [
529 int f = MSG_NOSIGNAL;
530 ], [
531 # Yes, we have it...
532 AC_MSG_RESULT(yes)
533 AC_DEFINE(HAVE_MSG_NOSIGNAL)
534 ], [
535 # We'll have to use signals
536 AC_MSG_RESULT(no)
537 ])
539 dnl *****************************
540 dnl *** Checks for SOL_IP ***
541 dnl *****************************
542 AC_MSG_CHECKING(for SOL_IP)
543 AC_TRY_COMPILE([#include <netdb.h>], [
544 int level = SOL_IP;
545 ], [
546 # Yes, we have it...
547 AC_MSG_RESULT(yes)
548 AC_DEFINE(HAVE_SOL_IP)
549 ], [
550 # We'll have to use getprotobyname
551 AC_MSG_RESULT(no)
552 ])
554 dnl *****************************
555 dnl *** Checks for SOL_IPV6 ***
556 dnl *****************************
557 AC_MSG_CHECKING(for SOL_IPV6)
558 AC_TRY_COMPILE([#include <netdb.h>], [
559 int level = SOL_IPV6;
560 ], [
561 # Yes, we have it...
562 AC_MSG_RESULT(yes)
563 AC_DEFINE(HAVE_SOL_IPV6)
564 ], [
565 # We'll have to use getprotobyname
566 AC_MSG_RESULT(no)
567 ])
569 dnl *****************************
570 dnl *** Checks for SOL_TCP ***
571 dnl *****************************
572 AC_MSG_CHECKING(for SOL_TCP)
573 AC_TRY_COMPILE([#include <netdb.h>], [
574 int level = SOL_TCP;
575 ], [
576 # Yes, we have it...
577 AC_MSG_RESULT(yes)
578 AC_DEFINE(HAVE_SOL_TCP)
579 ], [
580 # We'll have to use getprotobyname
581 AC_MSG_RESULT(no)
582 ])
584 dnl *****************************
585 dnl *** Checks for IP_PKTINFO ***
586 dnl *****************************
587 AC_MSG_CHECKING(for IP_PKTINFO)
588 AC_TRY_COMPILE([#include <netdb.h>], [
589 int level = IP_PKTINFO;
590 ], [
591 # Yes, we have it...
592 AC_MSG_RESULT(yes)
593 AC_DEFINE(HAVE_IP_PKTINFO)
594 ], [
595 AC_MSG_RESULT(no)
596 ])
598 dnl *********************************
599 dnl *** Check for struct ip_mreqn ***
600 dnl *********************************
601 AC_MSG_CHECKING(for struct ip_mreqn)
602 AC_TRY_COMPILE([#include <netinet/in.h>], [
603 struct ip_mreqn mreq;
604 mreq.imr_address.s_addr = 0;
605 ], [
606 # Yes, we have it...
607 AC_MSG_RESULT(yes)
608 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
609 ], [
610 # We'll just have to try and use struct ip_mreq
611 AC_MSG_RESULT(no)
612 AC_MSG_CHECKING(for struct ip_mreq)
613 AC_TRY_COMPILE([#include <netinet/in.h>], [
614 struct ip_mreq mreq;
615 mreq.imr_interface.s_addr = 0;
616 ], [
617 # Yes, we have it...
618 AC_MSG_RESULT(yes)
619 AC_DEFINE(HAVE_STRUCT_IP_MREQ)
620 ], [
621 # No multicast support
622 AC_MSG_RESULT(no)
623 ])
624 ])
626 dnl **********************************
627 dnl *** Check for gethostbyname2_r ***
628 dnl **********************************
629 AC_MSG_CHECKING(for gethostbyname2_r)
630 AC_TRY_LINK([#include <netdb.h>], [
631 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
632 ], [
633 # Yes, we have it...
634 AC_MSG_RESULT(yes)
635 AC_DEFINE(HAVE_GETHOSTBYNAME2_R)
636 ], [
637 AC_MSG_RESULT(no)
638 ])
640 dnl *****************************
641 dnl *** Checks for libnsl ***
642 dnl *****************************
643 AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl")
645 AC_CHECK_FUNCS(inet_pton inet_aton)
647 dnl ***********************************************
648 dnl *** Checks for size of sockaddr_un.sun_path ***
649 dnl ***********************************************
650 # AC_CHECK_SIZEOF can't cope with struct members :-(
651 AC_MSG_CHECKING(size of sockaddr_un.sun_path)
652 AC_CACHE_VAL(cv_mono_sizeof_sunpath,
653 [AC_TRY_RUN([
654 #include <sys/types.h>
655 #include <stdio.h>
656 #include <sys/un.h>
658 int main(void) {
659 struct sockaddr_un sock_un;
660 FILE *f=fopen("conftestval", "w");
661 if(!f) exit(1);
662 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
663 exit(0);
664 }
665 ], cv_mono_sizeof_sunpath=`cat conftestval`,
666 cv_mono_sizeof_sunpath=0,
667 cv_mono_sizeof_sunpath=0)])dnl
668 AC_MSG_RESULT($cv_mono_sizeof_sunpath)
669 AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $cv_mono_sizeof_sunpath)
671 dnl *************************************
672 dnl *** Checks for zero length arrays ***
673 dnl *************************************
674 AC_MSG_CHECKING(whether $CC supports zero length arrays)
675 AC_TRY_COMPILE([
676 struct s {
677 int length;
678 char data [0];
679 };
680 ], [], [
681 AC_MSG_RESULT(yes)
682 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 0)
683 ], [
684 AC_MSG_RESULT(no)
685 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 1)
686 ])
688 dnl *****************************
689 dnl *** Checks for libxnet ***
690 dnl *****************************
691 case "${host}" in
692 *solaris* )
693 AC_MSG_CHECKING(for Solaris XPG4 support)
694 if test -f /usr/lib/libxnet.so; then
695 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
696 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
697 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
698 LIBS="$LIBS -lxnet"
699 AC_MSG_RESULT(yes)
700 else
701 AC_MSG_RESULT(no)
702 fi
704 if test "$GCC" = "yes"; then
705 CFLAGS="$CFLAGS -Wno-char-subscripts"
706 fi
707 ;;
708 esac
710 dnl *****************************
711 dnl *** Checks for libpthread ***
712 dnl *****************************
713 # on FreeBSD -STABLE, the pthreads functions all reside in libc_r
714 # and libpthread does not exist
715 #
716 case "${host}" in
717 *-*-*freebsd4*)
718 AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
719 ;;
720 *)
721 AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
722 ;;
723 esac
724 AC_CHECK_HEADERS(pthread.h)
725 AC_CHECK_FUNCS(pthread_mutex_timedlock)
726 AC_CHECK_FUNCS(pthread_getattr_np pthread_attr_get_np)
727 AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
728 AC_TRY_COMPILE([ #include <pthread.h>], [
729 pthread_mutexattr_t attr;
730 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
731 ], [
732 AC_MSG_RESULT(ok)
733 ], [
734 AC_MSG_RESULT(no)
735 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
736 AC_DEFINE(USE_MONO_MUTEX)
737 ])
738 AC_CHECK_FUNCS(pthread_attr_setstacksize)
740 dnl ***********************************
741 dnl *** Checks for working __thread ***
742 dnl ***********************************
743 AC_MSG_CHECKING(for working __thread)
744 if test "x$with_tls" != "x__thread"; then
745 AC_MSG_RESULT(disabled)
746 else
747 AC_TRY_RUN([
748 #include <pthread.h>
750 __thread int i;
751 static int res1, res2;
753 void thread_main (void *arg)
754 {
755 i = arg;
756 sleep (1);
757 if (arg == 1)
758 res1 = (i == arg);
759 else
760 res2 = (i == arg);
761 }
763 int main () {
764 pthread_t t1, t2;
766 i = 5;
768 pthread_create (&t1, NULL, thread_main, 1);
769 pthread_create (&t2, NULL, thread_main, 2);
771 pthread_join (t1, NULL);
772 pthread_join (t2, NULL);
774 return !(res1 + res2 == 2);
775 }
776 ], [
777 AC_MSG_RESULT(yes)
778 ], [
779 AC_MSG_RESULT(no)
780 with_tls=pthread
781 ])
782 fi
784 dnl **************************************
785 dnl *** Checks for working sigaltstack ***
786 dnl **************************************
787 AC_MSG_CHECKING(for working sigaltstack)
788 if test "x$with_sigaltstack" != "xyes"; then
789 AC_MSG_RESULT(disabled)
790 else
791 AC_TRY_RUN([
792 #include <stdio.h>
793 #include <stdlib.h>
794 #include <unistd.h>
795 #include <signal.h>
796 #include <pthread.h>
797 #include <sys/wait.h>
799 static void
800 sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
801 {
802 exit (0);
803 }
805 static void *
806 loop (void *ignored)
807 {
808 char *ptr = NULL;
810 *ptr = 0;
811 return NULL;
812 }
814 static void
815 child ()
816 {
817 struct sigaction sa;
818 struct sigaltstack sas;
819 pthread_t id;
820 pthread_attr_t attr;
822 sa.sa_sigaction = sigsegv_signal_handler;
823 sigemptyset (&sa.sa_mask);
824 sa.sa_flags = SA_SIGINFO | SA_STACK;
825 if (sigaction (SIGSEGV, &sa, NULL) == -1) {
826 perror ("lala");
827 return;
828 }
830 sas.ss_sp = malloc (SIGSTKSZ);
831 sas.ss_size = SIGSTKSZ;
832 sas.ss_flags = SS_ONSTACK;
833 if (sigaltstack (&sas, NULL) == -1) {
834 perror ("lala");
835 return;
836 }
838 pthread_attr_init (&attr);
839 if (pthread_create(&id, &attr, loop, &attr) != 0) {
840 printf ("failed\n");
841 return;
842 }
844 sleep (100);
845 }
847 int
848 main ()
849 {
850 pid_t son;
851 int status;
852 int i;
854 son = fork ();
855 if (son == -1) {
856 return 1;
857 }
859 if (son == 0) {
860 child ();
861 return 0;
862 }
864 for (i = 0; i < 3; ++i) {
865 sleep (1);
866 waitpid (son, &status, WNOHANG);
867 if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
868 return 0;
869 }
871 kill (son, SIGKILL);
872 return 1;
873 }
875 ], [
876 AC_MSG_RESULT(yes)
877 AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
878 ], [
879 with_sigaltstack=no
880 AC_MSG_RESULT(no)
881 ])
882 fi
884 dnl ********************************
885 dnl *** Checks for semaphore lib ***
886 dnl ********************************
887 # 'Real Time' functions on Solaris
888 # posix4 on Solaris 2.6
889 # pthread (first!) on Linux
890 AC_SEARCH_LIBS(sem_init, pthread rt posix4)
892 dnl ********************************
893 dnl *** Checks for timezone stuff **
894 dnl ********************************
895 AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
896 AC_TRY_COMPILE([
897 #include <time.h>
898 ], [
899 struct tm tm;
900 tm.tm_gmtoff = 1;
901 ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
902 if test $ac_cv_struct_tm_gmtoff = yes; then
903 AC_DEFINE(HAVE_TM_GMTOFF)
904 else
905 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
906 AC_TRY_COMPILE([
907 #include <time.h>
908 ], [
909 timezone = 1;
910 ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
911 if test $ac_cv_var_timezone = yes; then
912 AC_DEFINE(HAVE_TIMEZONE)
913 else
914 AC_ERROR(unable to find a way to determine timezone)
915 fi
916 fi
918 dnl *********************************
919 dnl *** Checks for math functions ***
920 dnl *********************************
921 LIBS="$LIBS -lm";
922 AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
923 AC_TRY_LINK([#include <math.h>],
924 [ finite(0.0); ],
925 AC_DEFINE(HAVE_FINITE) AC_MSG_RESULT(yes),
926 AC_MSG_RESULT(no)))
927 AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
928 AC_TRY_LINK([#include <math.h>],
929 [ isfinite(0.0); ],
930 AC_DEFINE(HAVE_ISFINITE) AC_MSG_RESULT(yes),
931 AC_MSG_RESULT(no)))
933 dnl ****************************************************************
934 dnl *** Checks for working poll() (macosx defines it but doesn't ***
935 dnl *** have it in the library (duh)) ***
936 dnl ****************************************************************
937 AC_CHECK_FUNCS(poll)
939 dnl *************************
940 dnl *** Check for signbit ***
941 dnl *************************
942 AC_MSG_CHECKING(for signbit)
943 AC_TRY_LINK([#include <math.h>], [
944 int s = signbit(1.0);
945 ], [
946 AC_MSG_RESULT(yes)
947 AC_DEFINE(HAVE_SIGNBIT)
948 ], [
949 AC_MSG_RESULT(no)
950 ])
952 dnl *********************
953 dnl *** Check for AIO ***
954 dnl *********************
955 AC_MSG_CHECKING([for SIGEV_THREAD definition])
956 dnl Some systems (FreeBSD at least) may have aio_read
957 dnl but don't support/define SIGEV_THREAD.
958 AC_TRY_COMPILE([
959 #include <sys/signal.h>
960 ],[
961 int x = SIGEV_THREAD;
962 ],[
963 ac_cv_c_sigev_thread=yes
964 AC_MSG_RESULT(yes)
965 ],[
966 AC_MSG_RESULT(no)
967 ])
969 if test "$ac_cv_c_sigev_thread" = "yes" ; then
970 AC_CHECK_HEADERS(aio.h sys/aio.h)
971 AC_CHECK_LIB(rt, aio_read, [ LIBS="$LIBS -lrt" ],)
972 SIGVAL_PTR="undefined"
973 if test "$ac_cv_header_aio_h" = "yes" -o "$ac_cv_header_sys_aio_h" = "yes" ; then
974 AC_CHECK_MEMBER(union sigval.sigval_ptr,SIGVAL_PTR="sigval_ptr",, [
975 #include <sys/signal.h>
976 ])
977 AC_CHECK_MEMBER(union sigval.sival_ptr,SIGVAL_PTR="sival_ptr",, [
978 #include <sys/signal.h>
979 ])
980 if test "$SIGVAL_PTR" = "undefined" ; then
981 AC_MSG_ERROR([Unable to detect field name in 'union sigval'])
982 fi
983 fi
984 AC_DEFINE_UNQUOTED(SIGVAL_PTR,$SIGVAL_PTR,[Pointer field name in 'union sigval'])
985 fi
986 else
987 jdk_headers_found=no
988 AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
989 AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
990 AC_CHECK_LIB(ole32, main, LIBS="$LIBS -lole32", AC_ERROR(bad mingw install?))
992 dnl *********************************
993 dnl *** Check for struct ip_mreqn ***
994 dnl *********************************
995 AC_MSG_CHECKING(for struct ip_mreqn)
996 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
997 struct ip_mreqn mreq;
998 mreq.imr_address.s_addr = 0;
999 ], [
1000 # Yes, we have it...
1001 AC_MSG_RESULT(yes)
1002 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
1003 ], [
1004 # We'll just have to try and use struct ip_mreq
1005 AC_MSG_RESULT(no)
1006 AC_MSG_CHECKING(for struct ip_mreq)
1007 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1008 struct ip_mreq mreq;
1009 mreq.imr_interface.s_addr = 0;
1010 ], [
1011 # Yes, we have it...
1012 AC_MSG_RESULT(yes)
1013 AC_DEFINE(HAVE_STRUCT_IP_MREQ)
1014 ], [
1015 # No multicast support
1016 AC_MSG_RESULT(no)
1017 ])
1018 ])
1019 fi
1021 dnl socklen_t check
1022 AC_MSG_CHECKING(for socklen_t)
1023 AC_TRY_COMPILE([
1024 #include <sys/types.h>
1025 #include <sys/socket.h>
1026 ],[
1027 socklen_t foo;
1028 ],[
1029 ac_cv_c_socklen_t=yes
1030 AC_DEFINE(HAVE_SOCKLEN_T)
1031 AC_MSG_RESULT(yes)
1032 ],[
1033 AC_MSG_RESULT(no)
1034 ])
1036 AC_MSG_CHECKING(for array element initalizer support)
1037 AC_TRY_COMPILE([#include <sys/socket.h>], [
1038 const int array[] = {[1] = 2,};
1039 ], [
1040 # Yes, we have it...
1041 AC_MSG_RESULT(yes)
1042 AC_DEFINE(HAVE_ARRAY_ELEM_INIT,1,[Supports C99 array initialization])
1043 ], [
1044 # We'll have to use signals
1045 AC_MSG_RESULT(no)
1046 ])
1048 AC_CHECK_FUNCS(trunc, , AC_MSG_CHECKING(for trunc in math.h)
1049 # Simply calling trunc (0.0) is no good since gcc will optimize the call away
1050 AC_TRY_LINK([#include <math.h>],
1051 [ static void *p = &trunc; ],
1052 [
1053 AC_DEFINE(HAVE_TRUNC)
1054 AC_MSG_RESULT(yes)
1055 ac_cv_trunc=yes
1056 ],
1057 AC_MSG_RESULT(no)))
1059 if test "x$ac_cv_truncl" != "xyes"; then
1060 AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL) LIBS="$LIBS -lsunmath"])
1061 fi
1063 dnl ****************************
1064 dnl *** Look for /dev/random ***
1065 dnl ****************************
1067 AC_MSG_CHECKING([if usage of random device is requested])
1068 AC_ARG_ENABLE(dev-random,
1069 [ --disable-dev-random disable the use of the random device],
1070 try_dev_random=$enableval, try_dev_random=yes)
1071 AC_MSG_RESULT($try_dev_random)
1073 case "{$target}" in
1074 *-openbsd*)
1075 NAME_DEV_RANDOM="/dev/srandom"
1076 ;;
1078 dnl Win32 does not have /dev/random, they have their own method...
1080 *-*-mingw*|*-*-cygwin*)
1081 ac_cv_have_dev_random=no
1082 ;;
1084 dnl Everywhere else, it's /dev/random
1086 *)
1087 NAME_DEV_RANDOM="/dev/random"
1088 ;;
1089 esac
1091 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM")
1093 dnl Now check if the device actually exists
1095 if test "x$try_dev_random" = "xyes"; then
1096 AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
1097 [if test -r "$NAME_DEV_RANDOM" ; then
1098 ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
1099 if test "x$ac_cv_have_dev_random" = "xyes"; then
1100 AC_DEFINE(HAVE_CRYPT_RNG)
1101 fi
1102 else
1103 AC_MSG_CHECKING(for random device)
1104 ac_cv_have_dev_random=no
1105 AC_MSG_RESULT(has been disabled)
1106 fi
1108 if test "x$platform_win32" = "xyes"; then
1109 AC_DEFINE(HAVE_CRYPT_RNG)
1110 fi
1112 if test "x$ac_cv_have_dev_random" = "xno" \
1113 && test "x$platform_win32" = "xno"; then
1114 AC_MSG_WARN([[
1115 ***
1116 *** A system-provided entropy source was not found on this system.
1117 *** Because of this, the System.Security.Cryptography random number generator
1118 *** will throw a NotImplemented exception.
1119 ***
1120 *** If you are seeing this message, and you know your system DOES have an
1121 *** entropy collection in place, please contact <crichton@gimp.org> and
1122 *** provide information about the system and how to access the random device.
1123 ***
1124 *** Otherwise you can install either egd or prngd and set the environment
1125 *** variable MONO_EGD_SOCKET to point to the daemon's socket to use that.
1126 ***]])
1127 fi
1129 AC_MSG_CHECKING([if inter-process shared handles are requested])
1130 AC_ARG_ENABLE(shared-handles, [ --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
1131 AC_MSG_RESULT($try_shared_handles)
1132 if test "x$try_shared_handles" != "xyes"; then
1133 AC_DEFINE(DISABLE_SHARED_HANDLES)
1134 AC_SUBST(DISABLE_SHARED_HANDLES)
1135 fi
1137 #
1138 # ICU
1139 #
1140 ICU_CFLAGS=""
1141 ICU_LIBS=""
1142 enable_icu=no
1144 probe_icu=true
1145 AC_ARG_WITH(icu, [ --with-icu=yes/no],
1146 if test x$with_icu = xno; then
1147 probe_icu=false;
1148 AC_MSG_RESULT(Will not probe for ICU)
1149 fi
1150 )
1152 if $probe_icu; then
1153 AC_PATH_PROG(ICU_CONFIG, icu-config, no)
1154 if test "x$ICU_CONFIG" = "xno" -o ! -x "$ICU_CONFIG"; then
1155 AC_MSG_WARN([Only invariant locale available; install ICU for I18N support])
1156 enable_icu="no, if you want full i18n support download it from: http://oss.software.ibm.com/icu/index.html"
1157 else
1158 enable_icu="yes. Version: `$ICU_CONFIG --version`"
1159 AC_DEFINE(HAVE_ICU)
1160 ICU_CFLAGS=`$ICU_CONFIG --cppflags`
1161 ICU_LIBS=`$ICU_CONFIG --ldflags`
1162 fi
1163 fi
1164 AC_SUBST(ICU_CFLAGS)
1165 AC_SUBST(ICU_LIBS)
1167 TARGET="unknown"
1168 ACCESS_UNALIGNED="yes"
1170 JIT_SUPPORTED=no
1171 LIBC="libc.so.6"
1172 INTL="libc.so.6"
1174 jit_wanted=false
1175 case "$host" in
1176 # mips-sgi-irix5.* | mips-sgi-irix6.*)
1177 # TARGET=MIPS;
1178 # ACCESS_UNALIGNED="no"
1179 # ;;
1180 i*86-*-*)
1181 TARGET=X86;
1182 arch_target=x86;
1183 JIT_SUPPORTED=yes
1184 jit_wanted=true
1185 ;;
1186 x86_64-*-* | amd64-*-*)
1187 TARGET=AMD64;
1188 arch_target=amd64;
1189 JIT_SUPPORTED=yes
1190 jit_wanted=true
1191 ;;
1192 sparc*-*-*)
1193 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1194 TARGET=SPARC64
1195 else
1196 TARGET=SPARC
1197 fi
1198 arch_target=sparc;
1199 JIT_SUPPORTED=yes
1200 ACCESS_UNALIGNED="no"
1201 LIBC="libc.so"
1202 INTL="libintl.so"
1203 jit_wanted=true
1204 ;;
1205 alpha*-*-linux* | alpha*-*-osf*)
1206 TARGET=ALPHA;
1207 ACCESS_UNALIGNED="no"
1208 JIT_SUPPORTED=no
1209 arch_target=alpha;
1210 ;;
1211 # ia64-*-linux* | ia64-*-hpux*)
1212 # TARGET=IA64;
1213 # arch_target=ia64;
1214 # JIT_SUPPORTED=no;
1215 # ACCESS_UNALIGNED="no";
1216 # case "$host_os" in
1217 # linux*) LIBC="libc.so.6.1";;
1218 # hpux*) LIBC="libc.so.1";;
1219 # esac
1220 # ;;
1221 # m68k-*-linux*)
1222 # TARGET=M68K
1223 # ;;
1224 hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
1225 TARGET=HPPA;
1226 arch_target=hppa;
1227 LIBC="libc.sl"
1228 ACCESS_UNALIGNED="no"
1229 ;;
1230 hppa*linux*)
1231 TARGET=HPPA;
1232 arch_target=hppa;
1233 ACCESS_UNALIGNED="no"
1234 ;;
1235 macppc-*-openbsd* | powerpc-*-linux* | powerpc-*-openbsd* | \
1236 powerpc-*-sysv* | powerpc-*-darwin*)
1237 TARGET=POWERPC;
1238 arch_target=ppc;
1239 JIT_SUPPORTED=yes
1240 jit_wanted=true
1241 ;;
1242 arm-*-linux-* | armv4l-*-linux-*)
1243 TARGET=ARM;
1244 arch_target=arm;
1245 ACCESS_UNALIGNED="no"
1246 ;;
1247 s390-*-linux*)
1248 TARGET=S390;
1249 arch_target=s390;
1250 ACCESS_UNALIGNED="no"
1251 JIT_SUPPORTED=yes
1252 ;;
1253 s390x-*-linux*)
1254 TARGET=S390x;
1255 arch_target=s390x;
1256 ACCESS_UNALIGNED="no"
1257 JIT_SUPPORTED=yes
1258 ;;
1259 esac
1261 AC_ARG_WITH(jit, [ --with-jit=yes,no If you want to build scripts that default to the JIT],[
1262 jit_wanted=true
1263 ])
1265 USEJIT=false
1266 if test x$JIT_SUPPORTED = xyes; then
1267 if $jit_wanted; then
1268 USEJIT=true
1269 jit_status="Building and using the JIT"
1270 else
1271 jit_status="Building the JIT, defaulting to the interpreter"
1272 fi
1273 else
1274 jit_status="interpreter"
1275 fi
1277 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
1279 libsuffix=".so"
1281 case "$host" in
1282 powerpc-*-darwin*)
1283 libsuffix=".dylib"
1284 LIBC="libc.dylib"
1285 INTL="libintl.dylib"
1286 ;;
1287 *-*-*netbsd*)
1288 LIBC="libc.so.12"
1289 INTL="libintl.so.0"
1290 ;;
1291 *-*-*freebsd*)
1292 LIBC="libc.so"
1293 INTL="libintl.so"
1294 ;;
1295 *-*-*openbsd*)
1296 LIBC="libc.so"
1297 INTL="libintl.so"
1298 ;;
1299 esac
1300 AC_SUBST(libsuffix)
1302 if test "x$TARGET" != "xAMD64"; then
1303 # valgrind headers don't compile under x86-64
1304 AC_CHECK_HEADERS(valgrind/memcheck.h)
1305 fi
1307 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86"; then
1308 if test "x$with_tls" = "x__thread"; then
1309 #
1310 # On some linux distributions, TLS works in executables, but linking
1311 # against a shared library containing TLS fails with:
1312 # undefined reference to `__tls_get_addr'
1313 #
1314 rm -f conftest.c conftest.so conftest
1315 echo "static __thread int foo; void main () { foo = 5; }" > conftest.c
1316 gcc -fPIC --shared -o conftest.so conftest.c > /dev/null 2>&1
1317 gcc -o conftest conftest.so > /dev/null 2>&1
1318 if test ! -f conftest; then
1319 AC_MSG_WARN([Disabling usage of __thread.]);
1320 with_tls=pthread
1321 fi
1322 rm -f conftest.c conftest.so conftest
1323 fi
1324 fi
1326 if test "x$with_tls" = "x__thread"; then
1327 AC_DEFINE(HAVE_KW_THREAD)
1328 # Pass the information to libgc
1329 CPPFLAGS="$CPPFLAGS -DUSE_COMPILER_TLS"
1330 export CPPFLAGS
1331 fi
1333 if test ${TARGET} = ARM; then
1334 dnl ******************************************
1335 dnl *** Check to see what FPU is available ***
1336 dnl ******************************************
1337 AC_MSG_CHECKING(which FPU to use)
1339 AC_TRY_COMPILE([], [
1340 __asm__ ("ldfd f0, [r0]");
1341 ], fpu=FPA, [
1342 AC_TRY_COMPILE([], [
1343 __asm__ ("fldd d0, [r0]");
1344 ], fpu=VFP, fpu=NONE)
1345 ])
1347 AC_MSG_RESULT($fpu)
1348 CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu"
1349 unset fpu
1350 fi
1352 if test ${TARGET} = unknown; then
1353 CPPFLAGS="$CPPFLAGS -DNO_PORT"
1354 AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
1355 fi
1357 if test ${ACCESS_UNALIGNED} = no; then
1358 CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
1359 fi
1361 PREVIEW=no
1362 AC_ARG_WITH(preview, [ --with-preview=yes,no If you want to install the 2.0 FX preview],[
1363 if test x$with_preview = xyes; then
1364 PREVIEW=yes
1365 fi
1366 ])
1368 AM_CONDITIONAL(INSTALL_2_0, test x$PREVIEW = xyes)
1370 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
1371 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
1372 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
1373 AM_CONDITIONAL(SPARC64, test x$TARGET = xSPARC64)
1374 AM_CONDITIONAL(X86, test x$TARGET = xX86)
1375 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
1376 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
1377 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
1378 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
1379 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
1380 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
1381 AM_CONDITIONAL(S390, test x$TARGET = xS390)
1382 AM_CONDITIONAL(S390x, test x$TARGET = xS390x)
1383 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
1385 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
1387 AC_SUBST(LIBC)
1388 AC_SUBST(INTL)
1390 AC_SUBST(arch_target)
1391 AC_SUBST(CFLAGS)
1392 AC_SUBST(CPPFLAGS)
1393 AC_SUBST(LDFLAGS)
1395 AC_OUTPUT([
1396 Makefile
1397 mint.pc
1398 mono.pc
1399 mono/Makefile
1400 mono/utils/Makefile
1401 mono/metadata/Makefile
1402 mono/dis/Makefile
1403 mono/cil/Makefile
1404 mono/arch/Makefile
1405 mono/os/Makefile
1406 mono/os/win32/Makefile
1407 mono/os/unix/Makefile
1408 mono/arch/x86/Makefile
1409 mono/arch/amd64/Makefile
1410 mono/arch/hppa/Makefile
1411 mono/arch/ppc/Makefile
1412 mono/arch/sparc/Makefile
1413 mono/arch/s390/Makefile
1414 mono/arch/s390x/Makefile
1415 mono/arch/arm/Makefile
1416 mono/arch/alpha/Makefile
1417 mono/interpreter/Makefile
1418 mono/tests/Makefile
1419 mono/tests/tests-config
1420 mono/benchmark/Makefile
1421 mono/monoburg/Makefile
1422 mono/monograph/Makefile
1423 mono/io-layer/Makefile
1424 mono/handles/Makefile
1425 mono/mini/Makefile
1426 mono/profiler/Makefile
1427 ikvm-jni/Makefile
1428 runtime/Makefile
1429 runtime/net_1_1/Makefile
1430 runtime/net_2_0/Makefile
1431 scripts/Makefile
1432 man/Makefile
1433 web/Makefile
1434 docs/Makefile
1435 data/Makefile
1436 data/net_1_1/Makefile
1437 data/net_2_0/Makefile
1438 samples/Makefile
1439 support/Makefile
1440 data/config
1441 mono.spec
1442 tools/Makefile
1443 tools/locale-builder/Makefile
1444 ])
1446 echo "
1448 GC: $gc
1449 ICU: $enable_icu
1450 TLS: $with_tls
1451 SIGALTSTACK: $with_sigaltstack
1452 Engine: $jit_status
1453 2.0 Alpha: $PREVIEW
1454 JNI support: $jdk_headers_found
1456 "