| blob | 4b6567d7dc5a943810e81fd73cb4511e2d1e585d |
1 AC_INIT(README)
2 AC_CANONICAL_SYSTEM
4 # Gross hack to enable 'make dist' on automake 1.9+tar 1.14.
5 # The extra brackets are to foil regex-based scans.
6 m4_ifdef([_A][M_PROG_TAR],[_A][M_SET_OPTION([tar-ustar])])
8 AM_CONFIG_HEADER(config.h)
9 AM_INIT_AUTOMAKE(mono,2.7)
10 AM_MAINTAINER_MODE
12 API_VER=2.0
13 AC_SUBST(API_VER)
15 AC_PROG_LN_S
17 # In case of cygwin, override LN_S, irrespective of what it determines.
18 # The build uses cygwin, but the actual runtime doesn't.
19 case $host_os in
20 *cygwin* ) LN_S='cp -p';;
21 esac
23 dnl
24 dnl libgc checks
25 dnl
27 gc_headers=no
28 gc=included
29 use_included_gc=no
30 libgc_configure_args=
32 if test -d $srcdir/libgc ; then
33 gc_default=included
34 else
35 gc_default=boehm
36 fi
38 # These variables are the CPPFLAGS/CFLAGS passed to libgc's configure
39 # libgc should inherit the original CFLAGS/CPPFLAGS passed to configure, i.e. -O0
40 CPPFLAGS_FOR_LIBGC=$CPPFLAGS
41 CFLAGS_FOR_LIBGC=$CFLAGS
42 CPPFLAGS_FOR_EGLIB=$CPPFLAGS
43 CFLAGS_FOR_EGLIB=$CFLAGS
45 #
46 # These are the flags that need to be stored in the mono.pc file for
47 # compiling code that will embed Mono
48 #
49 libmono_cflags=""
50 libmono_ldflags=""
51 AC_SUBST(libmono_cflags)
52 AC_SUBST(libmono_ldflags)
54 # Variable to have relocatable .pc files (lib, or lib64)
55 reloc_libdir=`basename ${libdir}`
56 AC_SUBST(reloc_libdir)
58 dnl if linker handles the version script
59 no_version_script=no
61 # Set to yes if Unix sockets cannot be created in an anonymous namespace
62 need_link_unlink=no
64 # Thread configuration inspired by sleepycat's db
65 AC_MSG_CHECKING([host platform characteristics])
66 libgc_threads=no
67 has_dtrace=no
68 parallel_mark=yes
70 case "$host" in
71 powerpc*-*-linux*)
72 # https://bugzilla.novell.com/show_bug.cgi?id=504411
73 disable_munmap=yes
74 ;;
75 esac
77 host_win32=no
78 target_win32=no
79 case "$host" in
80 *-mingw*|*-*-cygwin*)
81 AC_DEFINE(HOST_WIN32,1,[Host Platform is Win32])
82 AC_DEFINE(DISABLE_PORTABILITY,1,[Disable the io-portability layer])
83 AC_DEFINE(PLATFORM_NO_SYMLINKS,1,[This platform does not support symlinks])
84 host_win32=yes
85 if test "x$cross_compiling" = "xno"; then
86 target_win32=yes
87 if test "x$host" == "x$target"; then
88 AC_DEFINE(TARGET_WIN32,1,[Target OS is Win32])
89 fi
90 CC="gcc -mno-cygwin -g"
91 CXX="g++ -mno-cygwin -g"
92 # So libgc configure gets -mno-cygwin
93 export CC
94 export CXX
95 else
96 target_win32=yes
97 AC_DEFINE(TARGET_WIN32,1,[Target OS is Win32/MinGW])
98 AC_DEFINE(MINGW_CROSS_COMPILE,1,[Cross-compiling using MinGW])
99 fi
100 HOST_CC="gcc"
101 # Windows 2000 is required that includes Internet Explorer 5.01
102 CPPFLAGS="$CPPFLAGS -DWINVER=0x0500 -D_WIN32_WINNT=0x0500 -D_WIN32_IE=0x0501 -D_UNICODE -DUNICODE -DWIN32_THREADS -DFD_SETSIZE=1024"
103 LDFLAGS="$LDFLAGS -lmswsock -lws2_32 -lole32 -loleaut32 -lpsapi -lversion -ladvapi32 -lwinmm -lkernel32"
104 libmono_cflags="-mno-cygwin -mms-bitfields -mwindows"
105 libmono_ldflags="-mno-cygwin -mms-bitfields -mwindows"
106 libdl=
107 libgc_threads=win32
108 gc_default=included
109 with_sigaltstack=no
110 LN_S=cp
111 # This forces libgc to use the DllMain based thread registration code on win32
112 libgc_configure_args="$libgc_configure_args --enable-win32-dllmain=yes"
113 ;;
114 *-*-*netbsd*)
115 host_win32=no
116 CPPFLAGS="$CPPFLAGS -D_REENTRANT -DGC_NETBSD_THREADS -D_GNU_SOURCE"
117 libmono_cflags="-D_REENTRANT"
118 LDFLAGS="$LDFLAGS -pthread"
119 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD"
120 libmono_ldflags="-pthread"
121 need_link_unlink=yes
122 libdl="-ldl"
123 libgc_threads=pthreads
124 with_sigaltstack=no
125 use_sigposix=yes
126 ;;
127 *-*-*freebsd*)
128 host_win32=no
129 if test "x$PTHREAD_CFLAGS" = "x"; then
130 CPPFLAGS="$CPPFLAGS -DGC_FREEBSD_THREADS"
131 libmono_cflags=
132 else
133 CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
134 libmono_cflags="$PTHREAD_CFLAGS"
135 fi
136 if test "x$PTHREAD_LIBS" = "x"; then
137 LDFLAGS="$LDFLAGS -pthread"
138 libmono_ldflags="-pthread"
139 else
140 LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
141 libmono_ldflags="$PTHREAD_LIBS"
142 fi
143 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD"
144 need_link_unlink=yes
145 AC_DEFINE(PTHREAD_POINTER_ID, 1, [pthread is a pointer])
146 libdl=
147 libgc_threads=pthreads
148 # This doesn't seem to work as of 7.0 on amd64
149 with_sigaltstack=no
150 # TLS is only partially implemented on -CURRENT (compiler support
151 # but NOT library support)
152 #
153 with_tls=pthread
154 use_sigposix=yes
155 ;;
156 *-*-*openbsd*)
157 host_win32=no
158 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_OPENBSD_THREADS -DPLATFORM_BSD -D_GNU_SOURCE -D_REENTRANT -DUSE_MMAP"
159 if test "x$disable_munmap" != "xyes"; then
160 CPPFLAGS="$CPPFLAGS -DUSE_MUNMAP"
161 fi
162 libmono_cflags="-D_THREAD_SAFE -D_REENTRANT"
163 LDFLAGS="$LDFLAGS -pthread"
164 need_link_unlink=yes
165 AC_DEFINE(PTHREAD_POINTER_ID)
166 libdl=
167 gc_default=boehm
168 libgc_threads=pthreads
169 with_sigaltstack=no
170 use_sigposix=yes
171 ;;
172 *-*-linux*)
173 host_win32=no
174 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -D_GNU_SOURCE -D_REENTRANT -DUSE_MMAP"
175 if test "x$disable_munmap" != "xyes"; then
176 CPPFLAGS="$CPPFLAGS -DUSE_MUNMAP"
177 fi
178 libmono_cflags="-D_REENTRANT"
179 libdl="-ldl"
180 libgc_threads=pthreads
181 AOT_SUPPORTED="yes"
182 use_sigposix=yes
183 ;;
184 *-*-hpux*)
185 host_win32=no
186 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
187 # +ESdbgasm only valid on bundled cc on RISC
188 # silently ignored for ia64
189 if test $GCC != "yes"; then
190 CFLAGS="$CFLAGS +ESdbgasm"
191 # Arrange for run-time dereferencing of null
192 # pointers to produce a SIGSEGV signal.
193 LDFLAGS="$LDFLAGS -z"
194 fi
195 CFLAGS="$CFLAGS +ESdbgasm"
196 LDFLAGS="$LDFLAGS -z"
197 libmono_cflags="-D_REENTRANT"
198 libmono_ldflags="-lpthread"
199 libgc_threads=pthreads
200 need_link_unlink=yes
201 use_sigposix=yes
202 ;;
203 *-*-solaris*)
204 host_win32=no
205 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS -DUSE_MMAP -DUSE_MUNMAP -DPLATFORM_SOLARIS"
206 need_link_unlink=yes
207 libmono_cflags="-D_REENTRANT"
208 libgc_threads=pthreads
209 # This doesn't seem to work on solaris/x86, but the configure test runs
210 with_tls=pthread
211 has_dtrace=yes
212 use_sigposix=yes
213 enable_solaris_tar_check=yes
214 ;;
215 *-*-darwin*)
216 parallel_mark="Disabled_Currently_Hangs_On_MacOSX"
217 host_win32=no
218 platform_darwin=yes
219 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE -DGC_MACOSX_THREADS -DPLATFORM_MACOSX -DUSE_MMAP -DUSE_MUNMAP"
220 CPPFLAGS="$CPPFLAGS -DGetCurrentProcess=MonoGetCurrentProcess -DGetCurrentThread=MonoGetCurrentThread -DCreateEvent=MonoCreateEvent"
221 libmono_cflags="-D_THREAD_SAFE"
222 LDFLAGS="$LDFLAGS -pthread"
223 libmono_ldflags="-pthread"
224 need_link_unlink=yes
225 AC_DEFINE(PTHREAD_POINTER_ID)
226 AC_DEFINE(USE_MACH_SEMA, 1, [...])
227 no_version_script=yes
228 libdl=
229 libgc_threads=pthreads
230 has_dtrace=yes
231 if test "x$cross_compiling" = "xyes"; then
232 has_broken_apple_cpp=yes
233 fi
234 dnl Snow Leopard is horribly broken -- it reports itself as i386-apple-darwin10.0.0, but
235 dnl its gcc defaults to 64-bit mode. They have also deprecated the usage of ucontext
236 dnl we need to set some flags to build our 32-bit binaries on 10.6 properly
237 case "$host" in
238 dnl Snow Leopard config.guess reports as this
239 i*86-*-darwin10*)
240 BROKEN_DARWIN_FLAGS="-arch i386 -D_XOPEN_SOURCE -mmacosx-version-min=10.5"
241 CPPFLAGS="$CPPFLAGS $BROKEN_DARWIN_FLAGS"
242 CFLAGS="$CFLAGS $BROKEN_DARWIN_FLAGS"
243 CXXFLAGS="$CXXFLAGS $BROKEN_DARWIN_FLAGS"
244 CCASFLAGS="$CCASFLAGS $BROKEN_DARWIN_FLAGS"
245 CPPFLAGS_FOR_LIBGC="$CPPFLAGS_FOR_LIBGC $BROKEN_DARWIN_FLAGS"
246 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC $BROKEN_DARWIN_FLAGS"
247 CPPFLAGS_FOR_EGLIB="$CPPFLAGS_FOR_EGLIB $BROKEN_DARWIN_FLAGS"
248 CFLAGS_FOR_EGLIB="$CFLAGS_FOR_EGLIB $BROKEN_DARWIN_FLAGS"
249 ;;
250 esac
251 ;;
252 *-*-haiku*)
253 host_win32=no
254 CPPFLAGS="$CPPFLAGS -D_REENTRANT -D_THREAD_SAFE"
255 libmono_cflags="-D_REENTRANT -D_THREAD_SAFE"
256 libdl=
257 LIBS="$LIBS -lnetwork"
258 need_link_unlink=yes
259 AC_DEFINE(PTHREAD_POINTER_ID)
260 libgc_threads=pthreads
261 use_sigposix=yes
262 ;;
263 *)
264 AC_MSG_WARN([*** Please add $host to configure.in checks!])
265 host_win32=no
266 libdl="-ldl"
267 ;;
268 esac
269 AC_MSG_RESULT(ok)
271 if test x$need_link_unlink = xyes; then
272 AC_DEFINE(NEED_LINK_UNLINK, 1, [Define if Unix sockets cannot be created in an anonymous namespace])
273 fi
275 AM_CONDITIONAL(HOST_WIN32, test x$host_win32 = xyes)
276 AM_CONDITIONAL(TARGET_WIN32, test x$target_win32 = xyes)
277 AM_CONDITIONAL(PLATFORM_LINUX, echo x$target_os | grep -q linux)
278 AM_CONDITIONAL(PLATFORM_DARWIN, test x$platform_darwin = xyes)
279 AM_CONDITIONAL(PLATFORM_SIGPOSIX, test x$use_sigposix = xyes)
281 AC_CHECK_TOOL(CC, gcc, gcc)
282 AC_PROG_CC
283 AC_CHECK_TOOL(CXX, g++, g++)
284 AC_PROG_CXX
285 AM_PROG_AS
286 AM_PROG_CC_STDC
287 AC_PROG_INSTALL
288 AC_PROG_AWK
289 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
290 : ${CCAS='$(CC)'}
291 # Set ASFLAGS if not already set.
292 : ${CCASFLAGS='$(CFLAGS)'}
293 AC_SUBST(CCAS)
294 AC_SUBST(CCASFLAGS)
296 # AC_PROG_CXX helpfully sets CXX to g++ even if no c++ compiler is found so check
297 # GXX instead. See http://lists.gnu.org/archive/html/bug-autoconf/2002-04/msg00056.html
298 if test "x$CXX" = "xg++"; then
299 if test "x$GXX" != "xyes"; then
300 # automake/libtool is so broken, it requires g++ even if the c++ sources
301 # are inside automake conditionals
302 AC_MSG_ERROR([You need to install g++])
303 fi
304 fi
306 AC_CHECK_PROG(BISON, bison,yes,no)
307 if test "x$BISON" = "xno";
308 then
309 AC_MSG_ERROR([You need to install bison])
310 fi
312 dnl may require a specific autoconf version
313 dnl AC_PROG_CC_FOR_BUILD
314 dnl CC_FOR_BUILD not automatically detected
315 CC_FOR_BUILD=$CC
316 CFLAGS_FOR_BUILD=$CFLAGS
317 BUILD_EXEEXT=
318 if test "x$cross_compiling" = "xyes"; then
319 CC_FOR_BUILD=cc
320 CFLAGS_FOR_BUILD=
321 BUILD_EXEEXT=""
322 fi
323 AC_SUBST(CC_FOR_BUILD)
324 AC_SUBST(CFLAGS_FOR_BUILD)
325 AC_SUBST(HOST_CC)
326 AC_SUBST(BUILD_EXEEXT)
328 AM_CONDITIONAL(CROSS_COMPILING, [test x$cross_compiling = xyes])
329 AM_CONDITIONAL(USE_BATCH_FILES, [test x$host_win32 = xyes -a x$cross_compiling = xyes])
331 # Set STDC_HEADERS
332 AC_HEADER_STDC
333 AC_LIBTOOL_WIN32_DLL
334 # This causes monodis to not link correctly
335 #AC_DISABLE_FAST_INSTALL
336 AM_PROG_LIBTOOL
337 # Use dolt (http://dolt.freedesktop.org/) instead of libtool for building.
338 DOLT
340 export_ldflags=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
341 AC_SUBST(export_ldflags)
343 # Test whenever ld supports -version-script
344 AC_PROG_LD
345 AC_PROG_LD_GNU
346 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
347 no_version_script=yes
348 fi
350 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
352 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h sys/utime.h semaphore.h sys/un.h linux/rtc.h sys/syscall.h sys/mkdev.h sys/uio.h)
353 AC_CHECK_HEADERS(sys/param.h sys/socket.h sys/ipc.h sys/sem.h sys/utsname.h alloca.h ucontext.h pwd.h sys/select.h netinet/tcp.h netinet/in.h unistd.h sys/types.h link.h asm/sigcontext.h)
355 AC_CHECK_HEADERS(sys/user.h, [], [],
356 [
357 #ifdef HAVE_SYS_PARAM_H
358 # include <sys/param.h>
359 #endif
360 ])
362 AC_CHECK_HEADER(zlib.h, [have_zlib=yes], [have_zlib=no])
363 if test x$have_zlib = xyes; then
364 AC_TRY_COMPILE([#include <zlib.h>], [
365 void main () {
366 #if defined(ZLIB_VERNUM) && (ZLIB_VERNUM >= 0x1230)
367 }
368 #else
369 #error No good zlib found
370 #endif
371 ],[
372 AC_MSG_RESULT(Using system zlib)
373 zlib_msg="system zlib"
374 ],[
375 AC_MSG_RESULT(Using embedded zlib)
376 have_zlib=no
377 zlib_msg="bundled zlib"
378 ])
379 fi
381 AM_CONDITIONAL(HAVE_ZLIB, test x$have_zlib = xyes)
382 AC_DEFINE(HAVE_ZLIB,1,[Have system zlib])
384 # for mono/metadata/debug-symfile.c
385 AC_CHECK_HEADERS(elf.h)
387 # for support
388 AC_CHECK_HEADERS(poll.h)
389 AC_CHECK_HEADERS(sys/poll.h)
390 AC_CHECK_HEADERS(sys/wait.h)
391 AC_CHECK_HEADERS(grp.h)
392 AC_CHECK_HEADERS(syslog.h)
394 # for mono/dis
395 AC_CHECK_HEADERS(wchar.h)
396 AC_CHECK_HEADERS(ieeefp.h)
397 AC_MSG_CHECKING(for isinf)
398 AC_TRY_LINK([#include <math.h>], [
399 int f = isinf (1);
400 ], [
401 AC_MSG_RESULT(yes)
402 AC_DEFINE(HAVE_ISINF, 1, [isinf available])
403 ], [
404 # We'll have to use signals
405 AC_MSG_RESULT(no)
406 ])
409 # not 64 bit clean in cross-compile
410 AC_CHECK_SIZEOF(void *, 4)
412 WARN=''
413 if test x"$GCC" = xyes; then
414 WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wwrite-strings'
415 # The runtime code does not respect ANSI C strict aliasing rules
416 CFLAGS="$CFLAGS -fno-strict-aliasing"
418 ORIG_CFLAGS=$CFLAGS
419 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
420 AC_MSG_CHECKING(for -Wdeclaration-after-statement option to gcc)
421 AC_TRY_COMPILE([], [
422 void main () { }
423 ], [
424 AC_MSG_RESULT(yes)
425 ], [
426 AC_MSG_RESULT(no)
427 CFLAGS=$ORIG_CFLAGS
428 ])
429 else
430 # The Sun Forte compiler complains about inline functions that access static variables
431 # so disable all inlining.
432 case "$host" in
433 *-*-solaris*)
434 CFLAGS="$CFLAGS -Dinline="
435 ;;
436 esac
437 fi
438 CFLAGS="$CFLAGS -g $WARN"
439 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC -g"
441 # Where's the 'mcs' source tree?
442 if test -d $srcdir/mcs; then
443 mcsdir=mcs
444 else
445 mcsdir=../mcs
446 fi
448 AC_ARG_WITH(mcs-path, [ --with-mcs-path=/path/to/mcs Specify an alternate mcs source tree],
449 if test x$with_mcs_path != "x" -a -d $with_mcs_path ; then
450 mcsdir=$with_mcs_path
451 fi
452 )
454 #
455 # A sanity check to catch cases where the package was unpacked
456 # with an ancient tar program (Solaris)
457 #
458 AC_ARG_ENABLE(solaris-tar-check,
459 [ --disable-solaris-tar-check disable solaris tar check],
460 do_solaris_tar_check=no, do_solaris_tar_check=yes)
462 if test x"$do_solaris_tar_check" = xyes -a x"$enable_solaris_tar_check" = xyes; then
463 AC_MSG_CHECKING(integrity of package)
464 if test -f $mcsdir/class/System.Runtime.Serialization.Formatters.Soap/System.Runtime.Serialization.Formatters.Soap/SoapTypeMapper.cs
465 then
466 AC_MSG_RESULT(ok)
467 else
468 errorm="Your mono distribution is incomplete; if unpacking from a tar file, make sure you use GNU tar; see http://www.mono-project.com/IncompletePackage for more details"
469 AC_MSG_ERROR([$errorm])
470 fi
471 fi
473 if test "x$with_mcs_path" != "x"; then
474 mcs_topdir=$(cd "$mcsdir" && pwd)
475 mcs_topdir_from_srcdir=$mcs_topdir
476 else
477 mcs_topdir=$(cd "$srcdir/$mcsdir" && pwd)
478 mcs_topdir_from_srcdir='$(top_builddir)'/$mcsdir
479 fi
481 # Convert mcs_topdir* paths to Windows syntax.
482 if test x$cross_compiling$host_win32 = xnoyes; then
483 mcs_topdir=$(cygpath -m $mcs_topdir)
484 case $mcs_topdir_from_srcdir in
485 /cygdrive/*)
486 mcs_topdir_from_srcdir=$(cygpath -m $mcs_topdir_from_srcdir)
487 ;;
488 esac
489 fi
491 ## Maybe should also disable if mcsdir is invalid. Let's punt the issue for now.
492 AM_CONDITIONAL(BUILD_MCS, [test x$cross_compiling = xno && test x$enable_mcs_build != xno])
494 AC_SUBST([mcs_topdir])
495 AC_SUBST([mcs_topdir_from_srcdir])
497 # Where's the 'olive' source tree?
498 if test -d $srcdir/olive; then
499 olivedir=olive
500 else
501 olivedir=../olive
502 fi
504 if test -d $srcdir/$olivedir; then
505 olive_topdir='$(top_srcdir)/'$olivedir
506 fi
508 # gettext: prepare the translation directories.
509 # we do not configure the full gettext, as we consume it dynamically from C#
510 AM_PO_SUBDIRS
512 if test "x$USE_NLS" = "xyes"; then
513 AC_CHECK_PROG(HAVE_MSGFMT, msgfmt,yes,no)
515 if test "x$HAVE_MSGFMT" = "xno"; then
516 AC_MSG_ERROR([msgfmt not found. You need to install the 'gettext' package, or pass --enable-nls=no to configure.])
517 fi
518 fi
520 AC_ARG_WITH([libgdiplus],
521 [ --with-libgdiplus=installed|sibling|<path> Override the libgdiplus used for System.Drawing tests (defaults to installed)],
522 [], [with_libgdiplus=installed])
524 case $with_libgdiplus in
525 no|installed) libgdiplus_loc= ;;
526 yes|sibling) libgdiplus_loc=`cd ../libgdiplus && pwd`/src/libgdiplus.la ;;
527 /*) libgdiplus_loc=$with_libgdiplus ;;
528 *) libgdiplus_loc=`pwd`/$with_libgdiplus ;;
529 esac
530 AC_SUBST([libgdiplus_loc])
532 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
534 pkg_config_path=
535 AC_ARG_WITH(crosspkgdir, [ --with-crosspkgdir=/path/to/pkg-config/dir Change pkg-config dir to custom dir],
536 if test x$with_crosspkgdir = "x"; then
537 if test -s $PKG_CONFIG_PATH; then
538 pkg_config_path=$PKG_CONFIG_PATH
539 fi
540 else
541 pkg_config_path=$with_crosspkgdir
542 PKG_CONFIG_PATH=$pkg_config_path
543 export PKG_CONFIG_PATH
544 fi
545 )
547 AC_ARG_WITH([glib],
548 [ --with-glib=embedded|system Choose glib API: system or embedded (default to embedded)],
549 [], [with_glib=embedded])
551 eglib_dir=
553 ac_configure_args="$ac_configure_args \"CPPFLAGS_FOR_EGLIB=$EGLIB_CPPFLAGS\" \"CFLAGS_FOR_EGLIB=$CFLAGS_FOR_EGLIB\""
554 AC_CONFIG_SUBDIRS(eglib)
556 case $with_glib in
557 embedded)
558 GLIB_CFLAGS='-I$(top_srcdir)/eglib/src -I$(top_builddir)/eglib/src'
559 GLIB_LIBS='-L$(top_builddir)/eglib/src -leglib -lm'
560 BUILD_GLIB_CFLAGS="$GLIB_CFLAGS"
561 BUILD_GLIB_LIBS="$GLIB_LIBS"
562 GMODULE_CFLAGS="$GLIB_CFLAGS"
563 GMODULE_LIBS="$GLIB_LIBS"
564 eglib_dir=eglib
565 ;;
566 system)
567 if test "x$PKG_CONFIG" = "xno"; then
568 AC_MSG_ERROR([You need to install pkg-config])
569 fi
570 echo "PKG_CONFIG_PATH=$PKG_CONFIG_PATH"
571 echo "cross_compiling=$cross_compiling"
572 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
573 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
575 ## Versions of dependencies
576 GLIB_REQUIRED_VERSION=2.4.0
578 dnl
579 dnl No, you will not replace this check with a pkg.m4 check
580 dnl
581 if test "x$PKG_CONFIG" = "xno"; then
582 AC_MSG_ERROR([You need to install pkg-config])
583 fi
584 if $PKG_CONFIG --atleast-version=$GLIB_REQUIRED_VERSION glib-2.0; then
585 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
586 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
587 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
588 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
589 else
590 AC_MSG_ERROR([You need at least glib-2.0 $GLIB_REQUIRED_VERSION])
591 fi
592 ;;
593 *)
594 AC_MSG_ERROR([Invalid argument to --with-glib.])
595 esac
596 AM_CONDITIONAL(EGLIB_BUILD, test x$with_glib = xembedded)
598 AC_SUBST(GLIB_CFLAGS)
599 AC_SUBST(GLIB_LIBS)
600 AC_SUBST(GMODULE_CFLAGS)
601 AC_SUBST(GMODULE_LIBS)
602 AC_SUBST(BUILD_GLIB_CFLAGS)
603 AC_SUBST(BUILD_GLIB_LIBS)
604 AC_SUBST(eglib_dir)
606 if test x$cross_compiling$host_win32 = xnoyes; then
607 AC_MSG_CHECKING(for cygwin glib2-dev package)
608 if [ cygcheck --f /usr/lib/libglib-2.0.dll.a | grep -q glib2-devel ]; then
609 AC_MSG_RESULT(found)
610 AC_MSG_ERROR([Mono cannot be built with the cygwin glib2-devel package installed, because that package doesn't work with -mno-cygwin. Please uninstall it then re-run configure.])
611 else
612 AC_MSG_RESULT(not found, ok)
613 fi
615 AC_MSG_CHECKING(for broken gwin32.h)
616 glib_include=`$PKG_CONFIG --cflags-only-I glib-2.0 | sed -e 's/ -I.*//g' | sed -e 's/-I//g'`
617 if test -f $glib_include/glib/gwin32.h; then
618 if [ grep ftruncate $glib_include/glib/gwin32.h | grep -q define ]; then
619 AC_MSG_RESULT(failed)
620 hashmark='#'
621 AC_MSG_ERROR([Your version of gwin32.h is broken and will cause compilation errors when building mono. Please fix it by deleting the line: '$hashmark define ftruncate...' from '$glib_include/glib/gwin32.h' then re-run configure.])
622 fi
623 fi
624 AC_MSG_RESULT(ok)
625 fi
627 AC_ARG_WITH(gc, [ --with-gc=boehm,included,none Defaults to included],[gc=$with_gc],[gc=$gc_default])
629 # Enable support for fast thread-local storage
630 # Some systems have broken support, so we allow to disable it.
631 AC_ARG_WITH(tls, [ --with-tls=__thread,pthread select Thread Local Storage implementation (defaults to __thread)],[],[with_tls=__thread])
633 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
634 # This does not work on some platforms (bug #55253)
635 AC_ARG_WITH(sigaltstack, [ --with-sigaltstack=yes,no enable/disable support for sigaltstack (defaults to yes)],[],[with_sigaltstack=yes])
637 AC_ARG_WITH(static_mono, [ --with-static_mono=yes,no link mono statically to libmono (faster) (defaults to yes)],[],[with_static_mono=yes])
639 if test "x$enable_static" = "xno"; then
640 with_static_mono=no
641 fi
643 if test "x$host_win32" = "xyes"; then
644 # Boehm GC requires the runtime to be in its own dll
645 with_static_mono=no
646 fi
648 AM_CONDITIONAL(STATIC_MONO, test x$with_static_mono != xno)
649 AC_ARG_ENABLE(mcs-build, [ --disable-mcs-build disable the build of the mcs directory], try_mcs_build=$enableval, enable_mcs_build=yes)
651 AC_ARG_WITH(xen_opt, [ --with-xen_opt=yes,no Enable Xen-specific behaviour (defaults to yes)],[],[with_xen_opt=yes])
652 if test "x$with_xen_opt" = "xyes"; then
653 AC_DEFINE(MONO_XEN_OPT, 1, [Xen-specific behaviour])
654 ORIG_CFLAGS=$CFLAGS
655 CFLAGS="$CFLAGS -mno-tls-direct-seg-refs"
656 AC_MSG_CHECKING(for -mno-tls-direct-seg-refs option to gcc)
657 AC_TRY_COMPILE([], [
658 void main () { }
659 ], [
660 AC_MSG_RESULT(yes)
661 # Pass it to libgc as well
662 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC -mno-tls-direct-seg-refs"
663 ], [
664 AC_MSG_RESULT(no)
665 CFLAGS=$ORIG_CFLAGS
666 ])
667 fi
669 AC_ARG_ENABLE(quiet-build, [ --enable-quiet-build Enable quiet runtime build (on by default)], enable_quiet_build=$enableval, enable_quiet_build=yes)
670 AC_ARG_ENABLE(small-config, [ --enable-small-config Enable tweaks to reduce requirements (and capabilities)], enable_small_config=$enableval, enable_small_config=no)
672 if test x$enable_small_config = xyes; then
673 AC_DEFINE(MONO_SMALL_CONFIG,1,[Reduce runtime requirements (and capabilities)])
674 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC -DSMALL_CONFIG"
675 fi
677 if test x$AOT_SUPPORTED != xyes; then
678 AOT_SUPPORTED=no
679 fi
681 AC_ARG_ENABLE(system-aot, [ --enable-system-aot Enable the Ahead-Of-Time compilation of system assemblies during the build (on by default on some platforms)], enable_system_aot=$enableval, enable_system_aot=$AOT_SUPPORTED)
683 DISABLED_FEATURES=none
685 AC_ARG_ENABLE(minimal, [ --enable-minimal=LIST drop support for LIST subsystems.
686 LIST is a comma-separated list from: aot, profiler, decimal, pinvoke, debug,
687 reflection_emit, reflection_emit_save, large_code, logging, com, ssa, generics, attach, jit, simd, soft_debug, normalization.],
688 [
689 for feature in `echo "$enable_minimal" | sed -e "s/,/ /g"`; do
690 eval "mono_feature_disable_$feature='yes'"
691 done
692 DISABLED_FEATURES=$enable_minimal
693 disabled="Disabled: $enable_minimal"
694 ],[])
696 AC_DEFINE_UNQUOTED(DISABLED_FEATURES, "$DISABLED_FEATURES", [String of disabled features])
698 if test "x$mono_feature_disable_aot" = "xyes"; then
699 AC_DEFINE(DISABLE_AOT_COMPILER, 1, [Disable AOT Compiler])
700 AC_MSG_NOTICE([Disabled AOT compiler])
701 fi
703 if test "x$mono_feature_disable_profiler" = "xyes"; then
704 AC_DEFINE(DISABLE_PROFILER, 1, [Disable default profiler support])
705 AC_MSG_NOTICE([Disabled support for the profiler])
706 fi
707 AM_CONDITIONAL(DISABLE_PROFILER, test x$mono_feature_disable_profiler = xyes)
709 if test "x$mono_feature_disable_decimal" = "xyes"; then
710 AC_DEFINE(DISABLE_DECIMAL, 1, [Disable System.Decimal support])
711 AC_MSG_NOTICE([Disabled support for decimal])
712 fi
714 if test "x$mono_feature_disable_pinvoke" = "xyes"; then
715 AC_DEFINE(DISABLE_PINVOKE, 1, [Disable P/Invoke support])
716 AC_MSG_NOTICE([Disabled support for P/Invoke])
717 fi
719 if test "x$mono_feature_disable_debug" = "xyes"; then
720 AC_DEFINE(DISABLE_DEBUG, 1, [Disable runtime debugging support])
721 AC_MSG_NOTICE([Disabled support for runtime debugging])
722 fi
724 if test "x$mono_feature_disable_reflection_emit" = "xyes"; then
725 AC_DEFINE(DISABLE_REFLECTION_EMIT, 1, [Disable reflection emit support])
726 mono_feature_disable_reflection_emit_save=yes
727 AC_MSG_NOTICE([Disabled support for Reflection.Emit])
728 fi
730 if test "x$mono_feature_disable_reflection_emit_save" = "xyes"; then
731 AC_DEFINE(DISABLE_REFLECTION_EMIT_SAVE, 1, [Disable assembly saving support in reflection emit])
732 AC_MSG_NOTICE([Disabled support for Reflection.Emit.Save])
733 fi
735 if test "x$mono_feature_disable_large_code" = "xyes"; then
736 AC_DEFINE(DISABLE_LARGE_CODE, 1, [Disable support for huge assemblies])
737 AC_MSG_NOTICE([Disabled support for large assemblies])
738 fi
740 if test "x$mono_feature_disable_logging" = "xyes"; then
741 AC_DEFINE(DISABLE_LOGGING, 1, [Disable support debug logging])
742 AC_MSG_NOTICE([Disabled support for logging])
743 fi
745 if test "x$mono_feature_disable_com" = "xyes"; then
746 AC_DEFINE(DISABLE_COM, 1, [Disable COM support])
747 AC_MSG_NOTICE([Disabled COM support])
748 fi
750 if test "x$mono_feature_disable_ssa" = "xyes"; then
751 AC_DEFINE(DISABLE_SSA, 1, [Disable advanced SSA JIT optimizations])
752 AC_MSG_NOTICE([Disabled SSA JIT optimizations])
753 fi
755 if test "x$mono_feature_disable_generics" = "xyes"; then
756 AC_DEFINE(DISABLE_GENERICS, 1, [Disable generics support])
757 AC_MSG_NOTICE([Disabled Generics Support])
758 fi
760 if test "x$mono_feature_disable_shadowcopy" = "xyes"; then
761 AC_DEFINE(DISABLE_SHADOW_COPY, 1, [Disable Shadow Copy for AppDomains])
762 AC_MSG_NOTICE([Disabled Shadow copy for AppDomains])
763 fi
765 if test "x$mono_feature_disable_portability" = "xyes"; then
766 AC_DEFINE(DISABLE_PORTABILITY, 1, [Disables the IO portability layer])
767 AC_MSG_NOTICE([Disabled IO Portability layer])
768 fi
770 if test "x$mono_feature_disable_attach" = "xyes"; then
771 AC_DEFINE(DISABLE_ATTACH, 1, [Disable agent attach support])
772 AC_MSG_NOTICE([Disabled agent attach])
773 fi
775 if test "x$mono_feature_disable_full_messages" = "xyes"; then
776 AC_DEFINE(DISABLE_FULL_MESSAGES, 1, [Disables building in the full table of WAPI messages])
777 AC_MSG_NOTICE([Disabled full messages for Win32 errors, only core message strings shipped])
778 fi
780 if test "x$mono_feature_disable_verifier" = "xyes"; then
781 AC_DEFINE(DISABLE_VERIFIER, 1, [Disables the verifier])
782 AC_MSG_NOTICE([Disabled the metadata and IL verifiers])
783 fi
785 if test "x$mono_feature_disable_jit" = "xyes"; then
786 AC_DEFINE(DISABLE_JIT, 1, [Disable the JIT, only full-aot mode will be supported by the runtime.])
787 AC_MSG_NOTICE([Disabled the JIT engine, only full AOT will be supported])
788 fi
790 AM_CONDITIONAL(DISABLE_JIT, test x$mono_feature_disable_jit = xyes)
792 if test "x$mono_feature_disable_simd" = "xyes"; then
793 AC_DEFINE(DISABLE_SIMD, 1, [Disable SIMD intrinsics related optimizations.])
794 AC_MSG_NOTICE([Disabled SIMD support])
795 fi
797 if test "x$mono_feature_disable_soft_debug" = "xyes"; then
798 AC_DEFINE(DISABLE_SOFT_DEBUG, 1, [Disable Soft Debugger Agent.])
799 AC_MSG_NOTICE([Disabled Soft Debugger.])
800 fi
802 if test "x$mono_feature_disable_normalization" = "xyes"; then
803 AC_DEFINE(DISABLE_NORMALIZATION, 1, [Disable String normalization support.])
804 AC_MSG_NOTICE([Disabled String normalization support.])
805 fi
807 AC_MSG_CHECKING(for visibility __attribute__)
808 AC_TRY_COMPILE([], [
809 void __attribute__ ((visibility ("hidden"))) doit (void) {}
810 void main () { doit (); }
811 ], [
812 have_visibility_hidden=yes
813 AC_MSG_RESULT(yes)
814 ], [
815 have_visibility_hidden=no
816 AC_MSG_RESULT(no)
817 ])
819 AC_MSG_CHECKING(for deprecated __attribute__)
820 AC_TRY_COMPILE([
821 int doit (void) __attribute__ ((deprecated));
822 int doit (void) { return 0; }
823 ], [
824 return 0;
825 ], [
826 have_deprecated=yes
827 AC_MSG_RESULT(yes)
828 ], [
829 have_deprecated=no
830 AC_MSG_RESULT(no)
831 ])
833 AC_ARG_ENABLE(parallel-mark, [ --enable-parallel-mark Enables GC Parallel Marking], enable_parallel_mark=$enableval, enable_parallel_mark=$parallel_mark)
834 if test x$enable_parallel_mark = xyes; then
835 libgc_configure_args="$libgc_configure_args --enable-parallel-mark"
836 fi
838 LIBGC_CFLAGS=
839 LIBGC_LIBS=
840 LIBGC_STATIC_LIBS=
841 libgc_dir=
842 case "x$gc" in
843 xboehm|xbohem|xyes)
844 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
845 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
847 if test "x$found_boehm" != "xyes"; then
848 AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
849 fi
850 if test "x$gc_headers" != "xyes"; then
851 AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
852 fi
854 AC_DEFINE(HAVE_BOEHM_GC, 1, [Have Boehm GC])
855 AC_SUBST(HAVE_BOEHM_GC)
856 LIBGC_LIBS="-lgc $libdl"
857 LIBGC_STATIC_LIBS="$LIBGC_LIBS"
858 libmono_ldflags="$libmono_ldflags -lgc"
860 # AC_CHECK_FUNCS does not work for some reason...
861 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
862 if test "x$found_gcj_malloc" = "xyes"; then
863 AC_DEFINE(HAVE_GC_GCJ_MALLOC, 1, [Have GC_gcj_malloc])
864 AC_DEFINE_UNQUOTED(USED_GC_NAME, "System Boehm (with typed GC)", [GC description])
865 else
866 AC_DEFINE_UNQUOTED(USED_GC_NAME, "System Boehm (no typed GC)", [GC description])
867 fi
868 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
869 if test "x$found_gc_enable" = "xyes"; then
870 AC_DEFINE(HAVE_GC_ENABLE, 1, [Have 'GC_enable'])
871 fi
872 ;;
874 xincluded)
875 found_boehm=yes
876 gc_headers=yes
877 use_included_gc=yes
878 libgc_dir=libgc
880 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
881 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
882 LIBGC_STATIC_LIBS='$(top_builddir)/libgc/libmonogc-static.la'
884 AC_DEFINE(HAVE_BOEHM_GC, 1, [Have Boehm GC])
885 AC_SUBST(HAVE_BOEHM_GC)
887 AC_DEFINE(HAVE_GC_H, 1, [Have gc.h])
888 AC_DEFINE(USE_INCLUDED_LIBGC, 1, [Use included libgc])
890 # The included libgc contains GCJ support
891 AC_DEFINE(HAVE_GC_GCJ_MALLOC, 1, [Have GC_gcj_malloc])
892 AC_DEFINE(HAVE_GC_ENABLE, 1, [Have GC_enable])
893 if test x$enable_parallel_mark = xyes; then
894 AC_DEFINE_UNQUOTED(USED_GC_NAME, "Included Boehm (with typed GC and Parallel Mark)", [GC description])
895 else
896 AC_DEFINE_UNQUOTED(USED_GC_NAME, "Included Boehm (with typed GC)", [GC description])
897 fi
898 ;;
900 xsgen)
901 found_boehm=no
902 gc_headers=no
903 use_included_gc=no
904 AC_DEFINE(HAVE_SGEN_GC,1,[Using the simple generational GC.])
905 AC_DEFINE(HAVE_MOVING_COLLECTOR,1,[The GC can move objects.])
906 AC_DEFINE(HAVE_WRITE_BARRIERS,1,[The GC needs write barriers.])
907 AC_DEFINE_UNQUOTED(USED_GC_NAME, "Simple generational", [GC description])
908 ;;
910 xnone)
911 AC_MSG_WARN("Compiling mono without GC.")
912 AC_DEFINE_UNQUOTED(USED_GC_NAME, "none", [GC description])
913 AC_DEFINE(HAVE_NULL_GC,1,[No GC support.])
914 ;;
915 *)
916 AC_MSG_ERROR([Invalid argument to --with-gc.])
917 ;;
918 esac
920 AC_ARG_WITH(large-heap, [ --with-large-heap=yes,no Enable support for GC heaps larger than 3GB (defaults to no)], [large_heap=$withval], [large_heap=no])
921 if test "x$large_heap" = "xyes"; then
922 echo "FOO"
923 CPPFLAGS="$CPPFLAGS -DLARGE_CONFIG"
924 fi
926 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
927 AC_SUBST(LIBGC_CFLAGS)
928 AC_SUBST(LIBGC_LIBS)
929 AC_SUBST(LIBGC_STATIC_LIBS)
930 AC_SUBST(libgc_dir)
932 dnl
933 dnl End of libgc checks
934 dnl
936 dnl *************************************
937 dnl *** Checks for zero length arrays ***
938 dnl *************************************
939 AC_MSG_CHECKING(whether $CC supports zero length arrays)
940 AC_TRY_COMPILE([
941 struct s {
942 int length;
943 char data [0];
944 };
945 ], [], [
946 AC_MSG_RESULT(yes)
947 AC_DEFINE_UNQUOTED(MONO_ZERO_LEN_ARRAY, 0, [Length of zero length arrays])
948 ], [
949 AC_MSG_RESULT(no)
950 AC_DEFINE_UNQUOTED(MONO_ZERO_LEN_ARRAY, 1, [Length of zero length arrays])
951 ])
953 if test x$target_win32 = xno; then
955 dnl hires monotonic clock support
956 AC_SEARCH_LIBS(clock_gettime, rt)
958 dnl dynamic loader support
959 AC_CHECK_FUNC(dlopen, DL_LIB="",
960 AC_CHECK_LIB(dl, dlopen, DL_LIB="-ldl", dl_support=no)
961 )
962 if test x$dl_support = xno; then
963 AC_MSG_WARN([No dynamic loading support available])
964 else
965 LIBS="$LIBS $DL_LIB"
966 AC_DEFINE(HAVE_DL_LOADER,1,[dlopen-based dynamic loader available])
967 dnl from glib's configure.in
968 AC_CACHE_CHECK([for preceeding underscore in symbols],
969 mono_cv_uscore,[
970 AC_TRY_RUN([#include <dlfcn.h>
971 int mono_underscore_test (void) { return 42; }
972 int main() {
973 void *f1 = (void*)0, *f2 = (void*)0, *handle;
974 handle = dlopen ((void*)0, 0);
975 if (handle) {
976 f1 = dlsym (handle, "mono_underscore_test");
977 f2 = dlsym (handle, "_mono_underscore_test");
978 } return (!f2 || f1);
979 }],
980 [mono_cv_uscore=yes],
981 [mono_cv_uscore=no],
982 [])
983 ])
984 if test "x$mono_cv_uscore" = "xyes"; then
985 MONO_DL_NEED_USCORE=1
986 else
987 MONO_DL_NEED_USCORE=0
988 fi
989 AC_SUBST(MONO_DL_NEED_USCORE)
990 AC_CHECK_FUNC(dlerror)
991 fi
993 dnl ******************************************************************
994 dnl *** Checks for the IKVM JNI interface library ***
995 dnl ******************************************************************
996 AC_ARG_WITH(ikvm-native, [ --with-ikvm-native=yes,no build the IKVM JNI interface library (defaults to yes)],[with_ikvm_native=$withval],[with_ikvm_native=yes])
998 ikvm_native_dir=
999 if test x$with_ikvm_native = xyes; then
1000 ikvm_native_dir=ikvm-native
1001 jdk_headers_found="IKVM Native"
1002 fi
1004 AC_SUBST(ikvm_native_dir)
1006 AC_CHECK_HEADERS(execinfo.h)
1008 AC_CHECK_FUNCS(getgrgid_r)
1009 AC_CHECK_FUNCS(getgrnam_r)
1010 AC_CHECK_FUNCS(getpwnam_r)
1011 AC_CHECK_FUNCS(getpwuid_r)
1012 AC_CHECK_FUNCS(getresuid)
1013 AC_CHECK_FUNCS(setresuid)
1014 AC_CHECK_FUNCS(kqueue)
1015 AC_CHECK_FUNCS(backtrace_symbols)
1016 AC_CHECK_FUNCS(mkstemp)
1017 AC_CHECK_FUNCS(mmap)
1018 AC_CHECK_FUNCS(madvise)
1019 AC_CHECK_FUNCS(getrusage)
1020 AC_CHECK_FUNCS(getpriority)
1021 AC_CHECK_FUNCS(setpriority)
1022 AC_CHECK_FUNCS(dl_iterate_phdr)
1023 AC_CHECK_FUNCS(sysconf)
1025 AC_CHECK_FUNCS(sched_setaffinity)
1027 dnl ****************************************************************
1028 dnl *** Check for sched_setaffinity from glibc versions before ***
1029 dnl *** 2.3.4. The older versions of the function only take 2 ***
1030 dnl *** parameters, not 3. ***
1031 dnl *** ***
1032 dnl *** Because the interface change was not made in a minor ***
1033 dnl *** version rev, the __GLIBC__ and __GLIBC_MINOR__ macros ***
1034 dnl *** won't always indicate the interface sched_affinity has. ***
1035 dnl ****************************************************************
1036 AC_MSG_CHECKING(for sched_setaffinity from glibc < 2.3.4)
1037 AC_TRY_COMPILE([#include <sched.h>], [
1038 int main() {
1039 int mask = 1;
1040 sched_setaffinity(0, &mask);
1041 }
1042 ], [
1043 # Yes, we have it...
1044 AC_MSG_RESULT(yes)
1045 AC_DEFINE(GLIBC_BEFORE_2_3_4_SCHED_SETAFFINITY, 1, [Have GLIBC_BEFORE_2_3_4_SCHED_SETAFFINITY])
1046 ], [
1047 # We have the new, three-parameter version
1048 AC_MSG_RESULT(no)
1049 ])
1052 dnl ******************************************************************
1053 dnl *** Check for large file support ***
1054 dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
1055 dnl ******************************************************************
1057 # Check that off_t can represent 2**63 - 1 correctly, working around
1058 # potential compiler bugs. Defines LARGE_FILE_SUPPORT, adds $1 to
1059 # CPPFLAGS and sets $large_offt to yes if the test succeeds
1060 large_offt=no
1061 AC_DEFUN([LARGE_FILES], [
1062 large_CPPFLAGS=$CPPFLAGS
1063 CPPFLAGS="$CPPFLAGS $1"
1064 AC_TRY_RUN([
1065 #include <sys/types.h>
1067 #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
1069 int main(void) {
1070 int big_off_t=((BIG_OFF_T%2147483629==721) &&
1071 (BIG_OFF_T%2147483647==1));
1072 if(big_off_t) {
1073 exit(0);
1074 } else {
1075 exit(1);
1076 }
1077 }
1078 ], [
1079 AC_MSG_RESULT(ok)
1080 AC_DEFINE(HAVE_LARGE_FILE_SUPPORT, 1, [Have large file support])
1081 large_CPPFLAGS="$large_CPPFLAGS $1"
1082 large_offt=yes
1083 ], [
1084 AC_MSG_RESULT(no)
1085 ], "")
1086 CPPFLAGS=$large_CPPFLAGS
1087 ])
1089 AC_MSG_CHECKING(if off_t is 64 bits wide)
1090 LARGE_FILES("")
1091 if test $large_offt = no; then
1092 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
1093 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
1094 fi
1095 if test $large_offt = no; then
1096 AC_MSG_WARN([No 64 bit file size support available])
1097 fi
1099 dnl *****************************
1100 dnl *** Checks for libsocket ***
1101 dnl *****************************
1102 AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
1104 dnl *******************************
1105 dnl *** Checks for MSG_NOSIGNAL ***
1106 dnl *******************************
1107 AC_MSG_CHECKING(for MSG_NOSIGNAL)
1108 AC_TRY_COMPILE([#include <sys/socket.h>], [
1109 int f = MSG_NOSIGNAL;
1110 ], [
1111 # Yes, we have it...
1112 AC_MSG_RESULT(yes)
1113 AC_DEFINE(HAVE_MSG_NOSIGNAL, 1, [Have MSG_NOSIGNAL])
1114 ], [
1115 # We'll have to use signals
1116 AC_MSG_RESULT(no)
1117 ])
1119 dnl *****************************
1120 dnl *** Checks for SOL_IP ***
1121 dnl *****************************
1122 AC_MSG_CHECKING(for SOL_IP)
1123 AC_TRY_COMPILE([#include <netdb.h>], [
1124 int level = SOL_IP;
1125 ], [
1126 # Yes, we have it...
1127 AC_MSG_RESULT(yes)
1128 AC_DEFINE(HAVE_SOL_IP, 1, [Have SOL_IP])
1129 ], [
1130 # We'll have to use getprotobyname
1131 AC_MSG_RESULT(no)
1132 ])
1134 dnl *****************************
1135 dnl *** Checks for SOL_IPV6 ***
1136 dnl *****************************
1137 AC_MSG_CHECKING(for SOL_IPV6)
1138 AC_TRY_COMPILE([#include <netdb.h>], [
1139 int level = SOL_IPV6;
1140 ], [
1141 # Yes, we have it...
1142 AC_MSG_RESULT(yes)
1143 AC_DEFINE(HAVE_SOL_IPV6, 1, [Have SOL_IPV6])
1144 ], [
1145 # We'll have to use getprotobyname
1146 AC_MSG_RESULT(no)
1147 ])
1149 dnl *****************************
1150 dnl *** Checks for SOL_TCP ***
1151 dnl *****************************
1152 AC_MSG_CHECKING(for SOL_TCP)
1153 AC_TRY_COMPILE([#include <netdb.h>], [
1154 int level = SOL_TCP;
1155 ], [
1156 # Yes, we have it...
1157 AC_MSG_RESULT(yes)
1158 AC_DEFINE(HAVE_SOL_TCP, 1, [Have SOL_TCP])
1159 ], [
1160 # We'll have to use getprotobyname
1161 AC_MSG_RESULT(no)
1162 ])
1164 dnl *****************************
1165 dnl *** Checks for IP_PKTINFO ***
1166 dnl *****************************
1167 AC_MSG_CHECKING(for IP_PKTINFO)
1168 AC_TRY_COMPILE([#include <netdb.h>], [
1169 int level = IP_PKTINFO;
1170 ], [
1171 # Yes, we have it...
1172 AC_MSG_RESULT(yes)
1173 AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1174 ], [
1175 AC_MSG_RESULT(no)
1176 ])
1178 dnl *****************************
1179 dnl *** Checks for IPV6_PKTINFO ***
1180 dnl *****************************
1181 AC_MSG_CHECKING(for IPV6_PKTINFO)
1182 AC_TRY_COMPILE([#include <netdb.h>], [
1183 int level = IPV6_PKTINFO;
1184 ], [
1185 # Yes, we have it...
1186 AC_MSG_RESULT(yes)
1187 AC_DEFINE(HAVE_IPV6_PKTINFO, 1, [Have IPV6_PKTINFO])
1188 ], [
1189 AC_MSG_RESULT(no)
1190 ])
1192 dnl **********************************
1193 dnl *** Checks for IP_DONTFRAGMENT ***
1194 dnl **********************************
1195 AC_MSG_CHECKING(for IP_DONTFRAGMENT)
1196 AC_TRY_COMPILE([#include <netdb.h>], [
1197 int level = IP_DONTFRAGMENT;
1198 ], [
1199 # Yes, we have it...
1200 AC_MSG_RESULT(yes)
1201 AC_DEFINE(HAVE_IP_DONTFRAGMENT, 1, [Have IP_DONTFRAGMENT])
1202 ], [
1203 AC_MSG_RESULT(no)
1204 ])
1206 dnl **********************************
1207 dnl *** Checks for IP_MTU_DISCOVER ***
1208 dnl **********************************
1209 AC_MSG_CHECKING(for IP_MTU_DISCOVER)
1210 AC_TRY_COMPILE([#include <netdb.h>], [
1211 int level = IP_MTU_DISCOVER;
1212 ], [
1213 # Yes, we have it...
1214 AC_MSG_RESULT(yes)
1215 AC_DEFINE(HAVE_IP_MTU_DISCOVER, 1, [Have IP_MTU_DISCOVER])
1216 ], [
1217 AC_MSG_RESULT(no)
1218 ])
1220 dnl *********************************
1221 dnl *** Check for struct ip_mreqn ***
1222 dnl *********************************
1223 AC_MSG_CHECKING(for struct ip_mreqn)
1224 AC_TRY_COMPILE([#include <netinet/in.h>], [
1225 struct ip_mreqn mreq;
1226 mreq.imr_address.s_addr = 0;
1227 ], [
1228 # Yes, we have it...
1229 AC_MSG_RESULT(yes)
1230 AC_DEFINE(HAVE_STRUCT_IP_MREQN, 1, [Have struct ip_mreqn])
1231 ], [
1232 # We'll just have to try and use struct ip_mreq
1233 AC_MSG_RESULT(no)
1234 AC_MSG_CHECKING(for struct ip_mreq)
1235 AC_TRY_COMPILE([#include <netinet/in.h>], [
1236 struct ip_mreq mreq;
1237 mreq.imr_interface.s_addr = 0;
1238 ], [
1239 # Yes, we have it...
1240 AC_MSG_RESULT(yes)
1241 AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1, [Have struct ip_mreq])
1242 ], [
1243 # No multicast support
1244 AC_MSG_RESULT(no)
1245 ])
1246 ])
1248 dnl **********************************
1249 dnl *** Check for gethostbyname2_r ***
1250 dnl **********************************
1251 AC_MSG_CHECKING(for gethostbyname2_r)
1252 AC_TRY_LINK([#include <netdb.h>], [
1253 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
1254 ], [
1255 # Yes, we have it...
1256 AC_MSG_RESULT(yes)
1257 AC_DEFINE(HAVE_GETHOSTBYNAME2_R, 1, [Have gethostbyname2_r])
1258 ], [
1259 AC_MSG_RESULT(no)
1260 ])
1262 dnl *****************************
1263 dnl *** Checks for libnsl ***
1264 dnl *****************************
1265 AC_CHECK_FUNC(gethostbyaddr, , AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl"))
1267 AC_CHECK_FUNCS(inet_pton inet_aton)
1269 dnl ***********************************************
1270 dnl *** Checks for size of sockaddr_un.sun_path ***
1271 dnl ***********************************************
1272 # AC_CHECK_SIZEOF can't cope with struct members :-(
1273 AC_MSG_CHECKING(size of sockaddr_un.sun_path)
1274 AC_CACHE_VAL(mono_cv_sizeof_sunpath,
1275 [AC_TRY_RUN([
1276 #include <sys/types.h>
1277 #include <stdio.h>
1278 #include <sys/un.h>
1280 int main(void) {
1281 struct sockaddr_un sock_un;
1282 FILE *f=fopen("conftestval", "w");
1283 if(!f) exit(1);
1284 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
1285 exit(0);
1286 }
1287 ], mono_cv_sizeof_sunpath=`cat conftestval`,
1288 mono_cv_sizeof_sunpath=0,
1289 mono_cv_sizeof_sunpath=0)])dnl
1290 AC_MSG_RESULT($mono_cv_sizeof_sunpath)
1291 AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $mono_cv_sizeof_sunpath, [Sizeof sock_un.sun_path])
1293 dnl *****************************
1294 dnl *** Checks for libxnet ***
1295 dnl *****************************
1296 case "${host}" in
1297 *solaris* )
1298 AC_MSG_CHECKING(for Solaris XPG4 support)
1299 if test -f /usr/lib/libxnet.so; then
1300 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
1301 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
1302 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
1303 LIBS="$LIBS -lxnet"
1304 AC_MSG_RESULT(yes)
1305 else
1306 AC_MSG_RESULT(no)
1307 fi
1309 if test "$GCC" = "yes"; then
1310 CFLAGS="$CFLAGS -Wno-char-subscripts"
1311 fi
1312 ;;
1313 esac
1315 dnl *****************************
1316 dnl *** Checks for libpthread ***
1317 dnl *****************************
1318 # on FreeBSD -STABLE, the pthreads functions all reside in libc_r
1319 # and libpthread does not exist
1320 #
1321 case "${host}" in
1322 *-*-*freebsd*)
1323 AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
1324 ;;
1325 *-*-*openbsd*)
1326 AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
1327 ;;
1328 *)
1329 AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
1330 ;;
1331 esac
1332 AC_CHECK_HEADERS(pthread.h)
1333 AC_CHECK_FUNCS(pthread_mutex_timedlock)
1334 AC_CHECK_FUNCS(pthread_getattr_np pthread_attr_get_np)
1335 AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
1336 AC_TRY_COMPILE([ #include <pthread.h>], [
1337 pthread_mutexattr_t attr;
1338 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
1339 ], [
1340 AC_MSG_RESULT(ok)
1341 ], [
1342 AC_MSG_RESULT(no)
1343 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
1344 AC_DEFINE(USE_MONO_MUTEX, 1, [Use mono_mutex_t])
1345 ])
1346 AC_CHECK_FUNCS(pthread_attr_setstacksize)
1347 AC_CHECK_FUNCS(pthread_attr_getstack pthread_attr_getstacksize)
1348 AC_CHECK_FUNCS(pthread_get_stacksize_np pthread_get_stackaddr_np)
1350 dnl ***********************************
1351 dnl *** Checks for signals
1352 dnl ***********************************
1353 AC_CHECK_HEADERS(signal.h)
1354 AC_CHECK_FUNCS(sigaction)
1356 dnl ***********************************
1357 dnl *** Checks for working __thread ***
1358 dnl ***********************************
1359 AC_MSG_CHECKING(for working __thread)
1360 if test "x$with_tls" != "x__thread"; then
1361 AC_MSG_RESULT(disabled)
1362 else
1363 AC_TRY_RUN([
1364 #include <pthread.h>
1365 __thread int i;
1366 static int res1, res2;
1368 void thread_main (void *arg)
1369 {
1370 i = arg;
1371 sleep (1);
1372 if (arg == 1)
1373 res1 = (i == arg);
1374 else
1375 res2 = (i == arg);
1376 }
1378 int main () {
1379 pthread_t t1, t2;
1381 i = 5;
1383 pthread_create (&t1, NULL, thread_main, 1);
1384 pthread_create (&t2, NULL, thread_main, 2);
1386 pthread_join (t1, NULL);
1387 pthread_join (t2, NULL);
1389 return !(res1 + res2 == 2);
1390 }
1391 ], [
1392 AC_MSG_RESULT(yes)
1393 ], [
1394 AC_MSG_RESULT(no)
1395 with_tls=pthread
1396 ])
1397 fi
1399 dnl **************************************
1400 dnl *** Checks for working sigaltstack ***
1401 dnl **************************************
1402 AC_MSG_CHECKING(for working sigaltstack)
1403 if test "x$with_sigaltstack" != "xyes"; then
1404 AC_MSG_RESULT(disabled)
1405 else
1406 AC_TRY_RUN([
1407 #include <stdio.h>
1408 #include <stdlib.h>
1409 #include <unistd.h>
1410 #include <signal.h>
1411 #include <pthread.h>
1412 #include <sys/wait.h>
1413 #if defined(__FreeBSD__) || defined(__NetBSD__)
1414 #define SA_STACK SA_ONSTACK
1415 #endif
1416 static void
1417 sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
1418 {
1419 exit (0);
1420 }
1422 static void *
1423 loop (void *ignored)
1424 {
1425 char *ptr = NULL;
1427 *ptr = 0;
1428 return NULL;
1429 }
1431 static void
1432 child ()
1433 {
1434 struct sigaction sa;
1435 struct sigaltstack sas;
1436 pthread_t id;
1437 pthread_attr_t attr;
1439 sa.sa_sigaction = sigsegv_signal_handler;
1440 sigemptyset (&sa.sa_mask);
1441 sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
1442 if (sigaction (SIGSEGV, &sa, NULL) == -1) {
1443 perror ("sigaction");
1444 return;
1445 }
1447 sas.ss_sp = malloc (SIGSTKSZ);
1448 sas.ss_size = SIGSTKSZ;
1449 sas.ss_flags = 0;
1450 if (sigaltstack (&sas, NULL) == -1) {
1451 perror ("sigaltstack");
1452 return;
1453 }
1455 pthread_attr_init (&attr);
1456 if (pthread_create(&id, &attr, loop, &attr) != 0) {
1457 printf ("pthread_create\n");
1458 return;
1459 }
1461 sleep (100);
1462 }
1464 int
1465 main ()
1466 {
1467 pid_t son;
1468 int status;
1469 int i;
1471 son = fork ();
1472 if (son == -1) {
1473 return 1;
1474 }
1476 if (son == 0) {
1477 child ();
1478 return 0;
1479 }
1481 for (i = 0; i < 3; ++i) {
1482 sleep (1);
1483 waitpid (son, &status, WNOHANG);
1484 if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
1485 return 0;
1486 }
1488 kill (son, SIGKILL);
1489 return 1;
1490 }
1492 ], [
1493 AC_MSG_RESULT(yes)
1494 AC_DEFINE(HAVE_WORKING_SIGALTSTACK, 1, [Have a working sigaltstack])
1495 ], [
1496 with_sigaltstack=no
1497 AC_MSG_RESULT(no)
1498 ])
1499 fi
1501 dnl ********************************
1502 dnl *** Checks for semaphore lib ***
1503 dnl ********************************
1504 # 'Real Time' functions on Solaris
1505 # posix4 on Solaris 2.6
1506 # pthread (first!) on Linux
1507 AC_SEARCH_LIBS(sem_init, pthread rt posix4)
1509 AC_SEARCH_LIBS(shm_open, pthread rt posix4)
1510 AC_CHECK_FUNCS(shm_open)
1512 dnl ********************************
1513 dnl *** Checks for timezone stuff **
1514 dnl ********************************
1515 AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
1516 AC_TRY_COMPILE([
1517 #include <time.h>
1518 ], [
1519 struct tm tm;
1520 tm.tm_gmtoff = 1;
1521 ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
1522 if test $ac_cv_struct_tm_gmtoff = yes; then
1523 AC_DEFINE(HAVE_TM_GMTOFF, 1, [Have tm_gmtoff])
1524 else
1525 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
1526 AC_TRY_COMPILE([
1527 #include <time.h>
1528 ], [
1529 timezone = 1;
1530 ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
1531 if test $ac_cv_var_timezone = yes; then
1532 AC_DEFINE(HAVE_TIMEZONE, 1, [Have timezone variable])
1533 else
1534 AC_ERROR(unable to find a way to determine timezone)
1535 fi
1536 fi
1538 dnl *********************************
1539 dnl *** Checks for math functions ***
1540 dnl *********************************
1541 AC_SEARCH_LIBS(sqrtf, m)
1542 if test "x$has_broken_apple_cpp" != "xyes"; then
1543 AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
1544 AC_TRY_LINK([#include <math.h>],
1545 [ finite(0.0); ],
1546 AC_DEFINE(HAVE_FINITE, 1, [Have finite]) AC_MSG_RESULT(yes),
1547 AC_MSG_RESULT(no)))
1548 fi
1549 AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
1550 AC_TRY_LINK([#include <math.h>],
1551 [ isfinite(0.0); ],
1552 AC_DEFINE(HAVE_ISFINITE, 1, [Have isfinite]) AC_MSG_RESULT(yes),
1553 AC_MSG_RESULT(no)))
1555 dnl ****************************************************************
1556 dnl *** Checks for working poll() (macosx defines it but doesn't ***
1557 dnl *** have it in the library (duh)) ***
1558 dnl ****************************************************************
1559 AC_CHECK_FUNCS(poll)
1561 dnl *************************
1562 dnl *** Check for signbit ***
1563 dnl *************************
1564 AC_MSG_CHECKING(for signbit)
1565 AC_TRY_LINK([#include <math.h>], [
1566 int s = signbit(1.0);
1567 ], [
1568 AC_MSG_RESULT(yes)
1569 AC_DEFINE(HAVE_SIGNBIT, 1, [Have signbit])
1570 ], [
1571 AC_MSG_RESULT(no)
1572 ])
1574 dnl **********************************
1575 dnl *** epoll ***
1576 dnl **********************************
1577 AC_CHECK_HEADERS(sys/epoll.h)
1578 haveepoll=no
1579 AC_CHECK_FUNCS(epoll_ctl, [haveepoll=yes], )
1580 if test "x$haveepoll" = "xyes" -a "x$ac_cv_header_sys_epoll_h" = "xyes" ; then
1581 AC_DEFINE(HAVE_EPOLL, 1, [epoll supported])
1582 fi
1584 dnl ******************************
1585 dnl *** Checks for SIOCGIFCONF ***
1586 dnl ******************************
1587 AC_CHECK_HEADERS(sys/ioctl.h)
1588 AC_CHECK_HEADERS(net/if.h, [], [],
1589 [
1590 #ifdef HAVE_SYS_TYPES_H
1591 # include <sys/types.h>
1592 #endif
1593 #ifdef HAVE_SYS_SOCKET_H
1594 # include <sys/socket.h>
1595 #endif
1596 ])
1597 AC_MSG_CHECKING(for ifreq)
1598 AC_TRY_COMPILE([
1599 #include <stdio.h>
1600 #include <sys/ioctl.h>
1601 #include <net/if.h>
1602 ], [
1603 struct ifconf ifc;
1604 struct ifreq *ifr;
1605 void *x;
1606 ifc.ifc_len = 0;
1607 ifc.ifc_buf = NULL;
1608 x = (void *) &ifr->ifr_addr;
1609 ],[
1610 AC_MSG_RESULT(yes)
1611 AC_DEFINE(HAVE_SIOCGIFCONF, 1, [Can get interface list])
1612 ], [
1613 AC_MSG_RESULT(no)
1614 ])
1615 dnl **********************************
1616 dnl *** Checks for sin_len ***
1617 dnl **********************************
1618 AC_MSG_CHECKING(for sockaddr_in.sin_len)
1619 AC_TRY_COMPILE([
1620 #include <netinet/in.h>
1621 ], [
1622 struct sockaddr_in saddr;
1623 saddr.sin_len = sizeof (saddr);
1624 ],[
1625 AC_MSG_RESULT(yes)
1626 AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [sockaddr_in has sin_len])
1627 ], [
1628 AC_MSG_RESULT(no)
1629 ])
1630 dnl **********************************
1631 dnl *** Checks for sin6_len ***
1632 dnl **********************************
1633 AC_MSG_CHECKING(for sockaddr_in6.sin6_len)
1634 AC_TRY_COMPILE([
1635 #include <netinet/in.h>
1636 ], [
1637 struct sockaddr_in6 saddr6;
1638 saddr6.sin6_len = sizeof (saddr6);
1639 ],[
1640 AC_MSG_RESULT(yes)
1641 AC_DEFINE(HAVE_SOCKADDR_IN6_SIN_LEN, 1, [sockaddr_in6 has sin6_len])
1642 ], [
1643 AC_MSG_RESULT(no)
1644 ])
1645 dnl **********************************
1646 dnl *** Checks for MonoPosixHelper ***
1647 dnl **********************************
1648 AC_CHECK_HEADERS(checklist.h)
1649 AC_CHECK_HEADERS(pathconf.h)
1650 AC_CHECK_HEADERS(fstab.h)
1651 AC_CHECK_HEADERS(attr/xattr.h)
1652 AC_CHECK_HEADERS(sys/extattr.h)
1653 AC_CHECK_HEADERS(sys/sendfile.h)
1654 AC_CHECK_HEADERS(sys/statvfs.h)
1655 AC_CHECK_HEADERS(sys/statfs.h)
1656 AC_CHECK_HEADERS(sys/vfstab.h)
1657 AC_CHECK_HEADERS(sys/xattr.h)
1658 AC_CHECK_HEADERS(sys/mman.h)
1659 AC_CHECK_HEADERS(sys/param.h)
1660 AC_CHECK_HEADERS(sys/mount.h, [], [],
1661 [
1662 #ifdef HAVE_SYS_PARAM_H
1663 # include <sys/param.h>
1664 #endif
1665 ])
1666 AC_CHECK_HEADERS(sys/mount.h)
1667 AC_CHECK_FUNCS(confstr)
1668 AC_CHECK_FUNCS(seekdir telldir)
1669 AC_CHECK_FUNCS(getdomainname)
1670 AC_CHECK_FUNCS(setdomainname)
1671 AC_CHECK_FUNCS(endgrent getgrent fgetgrent setgrent)
1672 AC_CHECK_FUNCS(setgroups)
1673 AC_CHECK_FUNCS(endpwent getpwent fgetpwent setpwent)
1674 AC_CHECK_FUNCS(getfsstat)
1675 AC_CHECK_FUNCS(lutimes futimes)
1676 AC_CHECK_FUNCS(mremap)
1677 AC_CHECK_FUNCS(remap_file_pages)
1678 AC_CHECK_FUNCS(posix_fadvise)
1679 AC_CHECK_FUNCS(posix_fallocate)
1680 AC_CHECK_FUNCS(posix_madvise)
1681 AC_CHECK_FUNCS(vsnprintf)
1682 AC_CHECK_FUNCS(sendfile)
1683 AC_CHECK_FUNCS(gethostid sethostid)
1684 AC_CHECK_FUNCS(sethostname)
1685 AC_CHECK_FUNCS(statfs)
1686 AC_CHECK_FUNCS(fstatfs)
1687 AC_CHECK_FUNCS(statvfs)
1688 AC_CHECK_FUNCS(fstatvfs)
1689 AC_CHECK_FUNCS(stime)
1690 AC_CHECK_FUNCS(strerror_r)
1691 AC_CHECK_FUNCS(ttyname_r)
1692 AC_CHECK_FUNCS(psignal)
1693 AC_CHECK_FUNCS(getlogin_r)
1694 AC_CHECK_FUNCS(lockf)
1695 AC_CHECK_FUNCS(swab)
1696 AC_CHECK_FUNCS(setusershell endusershell)
1697 AC_CHECK_SIZEOF(size_t)
1698 AC_CHECK_TYPES([blksize_t], [AC_DEFINE(HAVE_BLKSIZE_T)], ,
1699 [#include <sys/types.h>
1700 #include <sys/stat.h>
1701 #include <unistd.h>])
1702 AC_CHECK_TYPES([blkcnt_t], [AC_DEFINE(HAVE_BLKCNT_T)], ,
1703 [#include <sys/types.h>
1704 #include <sys/stat.h>
1705 #include <unistd.h>])
1706 AC_CHECK_TYPES([suseconds_t], [AC_DEFINE(HAVE_SUSECONDS_T)], ,
1707 [#include <sys/time.h>])
1708 AC_CHECK_TYPES([struct flock], [AC_DEFINE(HAVE_STRUCT_FLOCK)], ,
1709 [#include <unistd.h>
1710 #include <fcntl.h>])
1711 AC_CHECK_TYPES([struct pollfd], [AC_DEFINE(HAVE_STRUCT_POLLFD)], ,
1712 [#include <sys/poll.h>])
1713 AC_CHECK_TYPES([struct stat], [AC_DEFINE(HAVE_STRUCT_STAT)], ,
1714 [#include <sys/types.h>
1715 #include <sys/stat.h>
1716 #include <unistd.h>])
1717 AC_CHECK_TYPES([struct timespec], [AC_DEFINE(HAVE_STRUCT_TIMESPEC)], ,
1718 [#include <time.h>])
1719 AC_CHECK_TYPES([struct timeval], [AC_DEFINE(HAVE_STRUCT_TIMEVAL)], ,
1720 [#include <sys/time.h>
1721 #include <sys/types.h>
1722 #include <utime.h>])
1723 AC_CHECK_TYPES([struct timezone], [AC_DEFINE(HAVE_STRUCT_TIMEZONE)], ,
1724 [#include <sys/time.h>])
1725 AC_CHECK_TYPES([struct utimbuf], [AC_DEFINE(HAVE_STRUCT_UTIMBUF)], ,
1726 [#include <sys/types.h>
1727 #include <utime.h>])
1728 AC_CHECK_MEMBERS(
1729 [struct dirent.d_off, struct dirent.d_reclen, struct dirent.d_type],,,
1730 [#include <sys/types.h>
1731 #include <dirent.h>])
1732 AC_CHECK_MEMBERS(
1733 [struct passwd.pw_gecos],,,
1734 [#include <sys/types.h>
1735 #include <pwd.h>])
1736 AC_CHECK_MEMBERS(
1737 [struct statfs.f_flags],,,
1738 [#include <sys/types.h>
1739 #include <sys/vfs.h>])
1741 dnl Favour xattr through glibc, but use libattr if we have to
1742 AC_CHECK_FUNC(lsetxattr, ,
1743 AC_CHECK_LIB(attr, lsetxattr, XATTR_LIB="-lattr",)
1744 )
1745 AC_SUBST(XATTR_LIB)
1747 dnl kinfo_proc.kp_proc works on darwin but fails on other simil-bsds
1748 AC_CHECK_MEMBERS(
1749 [struct kinfo_proc.kp_proc],,,
1750 [#include <sys/types.h>
1751 #include <sys/param.h>
1752 #include <sys/sysctl.h>
1753 #include <sys/proc.h>
1754 ])
1756 dnl *********************************
1757 dnl *** Checks for Windows compilation ***
1758 dnl *********************************
1759 AC_CHECK_HEADERS(sys/time.h)
1760 AC_CHECK_HEADERS(sys/param.h)
1761 AC_CHECK_HEADERS(dirent.h)
1763 dnl *********************************
1764 dnl *** Check for Console 2.0 I/O ***
1765 dnl *********************************
1766 AC_CHECK_HEADERS([curses.h])
1767 AC_CHECK_HEADERS([term.h], [], [],
1768 [#if HAVE_CURSES_H
1769 #include <curses.h>
1770 #endif
1771 ])
1772 AC_CHECK_HEADERS([termios.h])
1774 dnl * This is provided in io-layer, but on windows it's only available
1775 dnl * on xp+
1776 AC_DEFINE(HAVE_GETPROCESSID, 1, [Define if GetProcessId is available])
1777 else
1778 jdk_headers_found=no
1779 AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
1780 AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
1781 AC_CHECK_LIB(ole32, main, LIBS="$LIBS -lole32", AC_ERROR(bad mingw install?))
1782 AC_CHECK_LIB(winmm, main, LIBS="$LIBS -lwinmm", AC_ERROR(bad mingw install?))
1783 AC_CHECK_LIB(oleaut32, main, LIBS="$LIBS -loleaut32", AC_ERROR(bad mingw install?))
1784 AC_CHECK_LIB(advapi32, main, LIBS="$LIBS -ladvapi32", AC_ERROR(bad mingw install?))
1785 AC_CHECK_LIB(version, main, LIBS="$LIBS -lversion", AC_ERROR(bad mingw install?))
1787 dnl *********************************
1788 dnl *** Check for struct ip_mreqn ***
1789 dnl *********************************
1790 AC_MSG_CHECKING(for struct ip_mreqn)
1791 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1792 struct ip_mreqn mreq;
1793 mreq.imr_address.s_addr = 0;
1794 ], [
1795 # Yes, we have it...
1796 AC_MSG_RESULT(yes)
1797 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
1798 ], [
1799 # We'll just have to try and use struct ip_mreq
1800 AC_MSG_RESULT(no)
1801 AC_MSG_CHECKING(for struct ip_mreq)
1802 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1803 struct ip_mreq mreq;
1804 mreq.imr_interface.s_addr = 0;
1805 ], [
1806 # Yes, we have it...
1807 AC_MSG_RESULT(yes)
1808 AC_DEFINE(HAVE_STRUCT_IP_MREQ)
1809 ], [
1810 # No multicast support
1811 AC_MSG_RESULT(no)
1812 ])
1813 ])
1814 AC_CHECK_FUNCS(GetProcessId)
1815 fi
1817 dnl socklen_t check
1818 AC_MSG_CHECKING(for socklen_t)
1819 AC_TRY_COMPILE([
1820 #include <sys/types.h>
1821 #include <sys/socket.h>
1822 ],[
1823 socklen_t foo;
1824 ],[
1825 ac_cv_c_socklen_t=yes
1826 AC_DEFINE(HAVE_SOCKLEN_T, 1, [Have socklen_t])
1827 AC_MSG_RESULT(yes)
1828 ],[
1829 AC_MSG_RESULT(no)
1830 ])
1832 AC_MSG_CHECKING(for array element initializer support)
1833 AC_TRY_COMPILE([#include <sys/socket.h>], [
1834 const int array[] = {[1] = 2,};
1835 ], [
1836 # Yes, we have it...
1837 AC_MSG_RESULT(yes)
1838 AC_DEFINE(HAVE_ARRAY_ELEM_INIT,1,[Supports C99 array initialization])
1839 ], [
1840 # We'll have to use signals
1841 AC_MSG_RESULT(no)
1842 ])
1844 AC_CHECK_FUNCS(trunc, , AC_MSG_CHECKING(for trunc in math.h)
1845 # Simply calling trunc (0.0) is no good since gcc will optimize the call away
1846 AC_TRY_LINK([#include <math.h>],
1847 [ static void *p = &trunc; ],
1848 [
1849 AC_DEFINE(HAVE_TRUNC)
1850 AC_MSG_RESULT(yes)
1851 ac_cv_trunc=yes
1852 ],
1853 AC_MSG_RESULT(no)))
1855 if test "x$ac_cv_truncl" != "xyes"; then
1856 AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL, 1, [Has the 'aintl' function]) LIBS="$LIBS -lsunmath"])
1857 fi
1859 AC_CHECK_FUNCS(round)
1860 AC_CHECK_FUNCS(rint)
1862 dnl ****************************
1863 dnl *** Look for /dev/random ***
1864 dnl ****************************
1866 AC_MSG_CHECKING([if usage of random device is requested])
1867 AC_ARG_ENABLE(dev-random,
1868 [ --disable-dev-random disable the use of the random device (enabled by default)],
1869 try_dev_random=$enableval, try_dev_random=yes)
1871 AC_MSG_RESULT($try_dev_random)
1873 case "{$target}" in
1874 *-openbsd*)
1875 NAME_DEV_RANDOM="/dev/srandom"
1876 ;;
1878 dnl Win32 does not have /dev/random, they have their own method...
1880 *-mingw*|*-*-cygwin*)
1881 ac_cv_have_dev_random=no
1882 ;;
1884 dnl Everywhere else, it's /dev/random
1886 *)
1887 NAME_DEV_RANDOM="/dev/random"
1888 ;;
1889 esac
1891 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM", [Name of /dev/random])
1893 dnl Now check if the device actually exists
1895 if test "x$try_dev_random" = "xyes"; then
1896 AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
1897 [if test -r "$NAME_DEV_RANDOM" ; then
1898 ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
1899 if test "x$ac_cv_have_dev_random" = "xyes"; then
1900 AC_DEFINE(HAVE_CRYPT_RNG, 1, [Have /dev/random])
1901 fi
1902 else
1903 AC_MSG_CHECKING(for random device)
1904 ac_cv_have_dev_random=no
1905 AC_MSG_RESULT(has been disabled)
1906 fi
1908 if test "x$host_win32" = "xyes"; then
1909 AC_DEFINE(HAVE_CRYPT_RNG)
1910 fi
1912 if test "x$ac_cv_have_dev_random" = "xno" \
1913 && test "x$host_win32" = "xno"; then
1914 AC_MSG_WARN([[
1915 ***
1916 *** A system-provided entropy source was not found on this system.
1917 *** Because of this, the System.Security.Cryptography random number generator
1918 *** will throw a NotImplemented exception.
1919 ***
1920 *** If you are seeing this message, and you know your system DOES have an
1921 *** entropy collection in place, please contact <crichton@gimp.org> and
1922 *** provide information about the system and how to access the random device.
1923 ***
1924 *** Otherwise you can install either egd or prngd and set the environment
1925 *** variable MONO_EGD_SOCKET to point to the daemon's socket to use that.
1926 ***]])
1927 fi
1929 AC_MSG_CHECKING([if inter-process shared handles are requested])
1930 AC_ARG_ENABLE(shared-handles, [ --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
1931 AC_MSG_RESULT($try_shared_handles)
1932 if test "x$try_shared_handles" != "xyes"; then
1933 AC_DEFINE(DISABLE_SHARED_HANDLES, 1, [Disable inter-process shared handles])
1934 AC_SUBST(DISABLE_SHARED_HANDLES)
1935 fi
1937 AC_ARG_ENABLE(nunit-tests, [ --enable-nunit-tests Run the nunit tests of the class library on 'make check'])
1938 AM_CONDITIONAL(ENABLE_NUNIT_TESTS, [test x$enable_nunit_tests = xyes])
1940 AC_MSG_CHECKING([if big-arrays are to be enabled])
1941 AC_ARG_ENABLE(big-arrays, [ --enable-big-arrays Enable the allocation and indexing of arrays greater than Int32.MaxValue], enable_big_arrays=$enableval, enable_big_arrays=no)
1942 if test "x$enable_big_arrays" = "xyes" ; then
1943 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1944 AC_DEFINE(MONO_BIG_ARRAYS,1,[Enable the allocation and indexing of arrays greater than Int32.MaxValue])
1945 else
1946 AC_MSG_ERROR([The allocation and indexing of arrays greater than Int32.MaxValue is not supported on this platform.])
1947 fi
1948 fi
1949 AC_MSG_RESULT($enable_big_arrays)
1951 dnl **************
1952 dnl *** DTRACE ***
1953 dnl **************
1955 AC_ARG_ENABLE(dtrace,[ --enable-dtrace Enable DTrace probes], enable_dtrace=$enableval, enable_dtrace=$has_dtrace)
1957 if test "x$enable_dtrace" = "xyes"; then
1958 if test "x$has_dtrace" = "xno"; then
1959 AC_MSG_ERROR([DTrace probes are not supported on this platform.])
1960 fi
1961 AC_PATH_PROG(DTRACE, [dtrace], [no], [$PATH:/usr/sbin])
1962 if test "x$DTRACE" = "xno"; then
1963 AC_MSG_RESULT([dtrace utility not found, dtrace support disabled.])
1964 enable_dtrace=no
1965 elif ! $DTRACE -h -s $srcdir/data/mono.d > /dev/null 2>&1; then
1966 AC_MSG_RESULT([dtrace doesn't support -h option, dtrace support disabled.])
1967 enable_dtrace=no
1968 fi
1969 fi
1971 dtrace_g=no
1972 if test "x$enable_dtrace" = "xyes"; then
1973 AC_DEFINE(ENABLE_DTRACE, 1, [Enable DTrace probes])
1974 DTRACEFLAGS=
1975 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1976 case "$host" in
1977 powerpc-*-darwin*)
1978 DTRACEFLAGS="-arch ppc64"
1979 ;;
1980 i*86-*-darwin*)
1981 DTRACEFLAGS="-arch x86_64"
1982 ;;
1983 *)
1984 DTRACEFLAGS=-64
1985 ;;
1986 esac
1987 else
1988 case "$host" in
1989 powerpc-*-darwin*)
1990 DTRACEFLAGS="-arch ppc"
1991 ;;
1992 i*86-*-darwin*)
1993 DTRACEFLAGS="-arch i386"
1994 ;;
1995 *)
1996 DTRACEFLAGS=-32
1997 ;;
1998 esac
1999 fi
2000 AC_SUBST(DTRACEFLAGS)
2001 case "$host" in
2002 *-*-solaris*)
2003 dtrace_g=yes
2004 ;;
2005 esac
2006 AC_CHECK_HEADERS([sys/sdt.h])
2007 fi
2008 AM_CONDITIONAL(ENABLE_DTRACE, [test x$enable_dtrace = xyes])
2009 AM_CONDITIONAL(DTRACE_G_REQUIRED, [test x$dtrace_g = xyes])
2011 dnl **************
2012 dnl *** LLVM ***
2013 dnl **************
2015 AC_ARG_ENABLE(llvm,[ --enable-llvm Enable the experimental LLVM back-end], enable_llvm=$enableval, enable_llvm=no)
2017 if test "x$enable_llvm" = "xyes"; then
2018 AC_PATH_PROG(LLVM_CONFIG, llvm-config, no)
2019 if test "x$LLVM_CONFIG" = "xno"; then
2020 AC_MSG_ERROR([llvm-config not found.])
2021 fi
2023 # The output of --cflags seems to include optimizations flags too
2024 LLVM_CFLAGS=`$LLVM_CONFIG --cflags | sed -e 's/-O2//g' | sed -e 's/-O0//g' | sed -e 's/-fomit-frame-pointer//g' | sed -e 's/-fPIC//g'`
2025 # LLVM is compiled with -fno-rtti, so we need this too, since our classes inherit
2026 # from LLVM classes.
2027 LLVM_CXXFLAGS="`$LLVM_CONFIG --cxxflags` -fno-rtti"
2028 LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2029 LLVM_LIBS=`$LLVM_CONFIG --libs core bitwriter jit x86codegen`
2030 LLVM_LIBS="$LLVM_LDFLAGS $LLVM_LIBS -lstdc++"
2032 # Should be something like '2.6' or '2.7svn'
2033 llvm_version=`$LLVM_CONFIG --version`
2034 major_version=`echo $llvm_version | cut -c 1`
2035 minor_version=`echo $llvm_version | cut -c 3`
2036 if echo $llvm_version | grep -q 'mono'; then
2037 AC_DEFINE(LLVM_MONO_BRANCH, 1, [Whenever we are using the mono branch of LLVM])
2038 LLVM_CXXFLAGS="$LLVM_CXXFLAGS -DLLVM_MONO_BRANCH"
2039 fi
2041 AC_DEFINE_UNQUOTED(LLVM_MAJOR_VERSION, $major_version, [Major version of LLVM libraries])
2042 AC_DEFINE_UNQUOTED(LLVM_MINOR_VERSION, $minor_version, [Minor version of LLVM libraries])
2044 # Have to pass these on the command line since mini-llvm-cpp.h already includes
2045 # llvm's config.h
2046 LLVM_CXXFLAGS="$LLVM_CXXFLAGS -DLLVM_MAJOR_VERSION=$major_version -DLLVM_MINOR_VERSION=$minor_version"
2048 AC_SUBST(LLVM_CFLAGS)
2049 AC_SUBST(LLVM_CXXFLAGS)
2050 AC_SUBST(LLVM_LIBS)
2051 AC_SUBST(LLVM_LDFLAGS)
2052 AC_DEFINE(ENABLE_LLVM, 1, [Enable the LLVM back end])
2053 fi
2055 AM_CONDITIONAL(ENABLE_LLVM, [test x$enable_llvm = xyes])
2057 TARGET="unknown"
2058 ACCESS_UNALIGNED="yes"
2060 JIT_SUPPORTED=no
2061 INTERP_SUPPORTED=no
2062 LIBC="libc.so.6"
2063 INTL="libc.so.6"
2064 SQLITE="libsqlite.so.0"
2065 SQLITE3="libsqlite3.so.0"
2066 X11="libX11.so"
2068 sizeof_register="SIZEOF_VOID_P"
2070 jit_wanted=false
2071 interp_wanted=false
2072 case "$host" in
2073 # mips-sgi-irix5.* | mips-sgi-irix6.*)
2074 # TARGET=MIPS;
2075 # ACCESS_UNALIGNED="no"
2076 # ;;
2077 mips*)
2078 TARGET=MIPS;
2079 arch_target=mips;
2080 ACCESS_UNALIGNED="no"
2081 JIT_SUPPORTED=yes
2082 jit_wanted=true
2084 AC_MSG_CHECKING(for mips n32)
2085 AC_TRY_COMPILE([], [
2086 void main () {
2087 #if _MIPS_SIM != _ABIN32
2088 #error Not mips n32
2089 #endif
2090 }
2091 ],[
2092 AC_MSG_RESULT(yes)
2093 sizeof_register=8
2094 ],[
2095 AC_MSG_RESULT(no)
2096 ])
2097 ;;
2098 i*86-*-*)
2099 TARGET=X86;
2100 arch_target=x86;
2101 JIT_SUPPORTED=yes
2102 jit_wanted=true
2103 case $host_os in
2104 solaris*)
2105 LIBC="libc.so"
2106 INTL="libintl.so"
2107 if test "x$ac_cv_sizeof_void_p" = "x8"; then
2108 TARGET=AMD64
2109 arch_target=amd64
2110 fi
2112 # On solaris 10 x86, gcc prints a warning saying 'visibility attribute not supported on this configuration; ignored', but linking fails. A test case:
2113 # int astruct __attribute__ ((visibility ("hidden")));
2114 # void foo ()
2115 # {
2116 # void *p = &astruct;
2117 # }
2118 # gcc -fPIC --shared -o libfoo.so foo.c
2119 # yields:
2120 # foo.c:6: warning: visibility attribute not supported in this configuration; ignored
2121 # ld: fatal: relocation error: R_386_GOTOFF: file /var/tmp//ccxYR96k.o: symbol astruct: relocation must bind locally
2122 have_visibility_hidden=no
2123 ;;
2124 cygwin*)
2125 have_visibility_hidden=no
2126 ;;
2127 haiku*)
2128 LIBC=libroot.so
2129 ;;
2130 esac
2131 ;;
2132 x86_64-*-* | amd64-*-*)
2133 TARGET=AMD64;
2134 arch_target=amd64;
2135 JIT_SUPPORTED=yes
2136 jit_wanted=true
2137 ;;
2138 ia64-*-*)
2139 TARGET=IA64
2140 arch_target=ia64
2141 ACCESS_UNALIGNED="no"
2142 JIT_SUPPORTED=yes
2143 jit_wanted=true
2144 LIBC="libc.so.6.1"
2145 INTL="libc.so.6.1"
2146 AC_CHECK_LIB(unwind, _U_dyn_register, [], [AC_MSG_ERROR(library libunwind not found)])
2147 libmono_ldflags="-lunwind"
2148 ;;
2149 sparc*-*-*)
2150 if test "x$ac_cv_sizeof_void_p" = "x8"; then
2151 TARGET=SPARC64
2152 else
2153 TARGET=SPARC
2154 fi
2155 arch_target=sparc;
2156 JIT_SUPPORTED=yes
2157 ACCESS_UNALIGNED="no"
2158 case $host_os in
2159 linux*) ;;
2160 *)
2161 LIBC="libc.so"
2162 INTL="libintl.so"
2163 esac
2164 jit_wanted=true
2165 if test x"$GCC" = xyes; then
2166 # We don't support v8 cpus
2167 CFLAGS="$CFLAGS -Wno-cast-align -mcpu=v9"
2168 fi
2169 if test x"$AR" = xfalse; then
2170 AC_MSG_ERROR([The required utility 'ar' is not found in your PATH. Usually it can be found in /usr/ccs/bin.])
2171 fi
2172 ;;
2173 alpha*-*-linux* | alpha*-*-osf*)
2174 TARGET=ALPHA;
2175 ACCESS_UNALIGNED="no"
2176 JIT_SUPPORTED=yes
2177 jit_wanted=true
2178 arch_target=alpha;
2179 CFLAGS="$CFLAGS -mieee -O0"
2180 case $host_os in
2181 linux*)
2182 LIBC="libc.so.6.1"
2183 INTL="libc.so.6.1"
2184 esac
2185 ;;
2186 *-mingw*|*-*-cygwin*)
2187 # When this is enabled, it leads to very strange crashes at runtime (gcc-3.4.4)
2188 have_visibility_hidden=no
2189 INTL="intl"
2190 ;;
2191 hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
2192 TARGET=HPPA;
2193 arch_target=hppa;
2194 LIBC="libc.sl"
2195 ACCESS_UNALIGNED="no"
2196 INTERP_SUPPORTED=yes
2197 interp_wanted=true
2198 ;;
2199 hppa*linux*)
2200 TARGET=HPPA;
2201 arch_target=hppa;
2202 ACCESS_UNALIGNED="no"
2203 JIT_SUPPORTED=yes
2204 jit_wanted=true
2205 ;;
2206 macppc-*-openbsd* | powerpc*-*-linux* | powerpc-*-openbsd* | \
2207 powerpc-*-sysv* | powerpc-*-darwin* | powerpc-*-netbsd* | powerpc-*-freebsd* )
2208 if test "x$ac_cv_sizeof_void_p" = "x8"; then
2209 TARGET=POWERPC64;
2210 CPPFLAGS="$CPPFLAGS -D__mono_ppc__ -D__mono_ppc64__"
2211 CFLAGS="$CFLAGS -mminimal-toc"
2212 else
2213 TARGET=POWERPC;
2214 CPPFLAGS="$CPPFLAGS -D__mono_ppc__"
2215 fi
2216 arch_target=ppc;
2217 JIT_SUPPORTED=yes
2218 jit_wanted=true
2219 ;;
2220 arm*-darwin*)
2221 TARGET=ARM;
2222 arch_target=arm;
2223 ACCESS_UNALIGNED="no"
2224 JIT_SUPPORTED=yes
2225 CPPFLAGS="$CPPFLAGS -DARM_FPU_NONE=1"
2226 jit_wanted=true
2227 ;;
2228 arm*-linux*)
2229 TARGET=ARM;
2230 arch_target=arm;
2231 ACCESS_UNALIGNED="no"
2232 JIT_SUPPORTED=yes
2233 jit_wanted=true
2234 ;;
2235 s390-*-linux*)
2236 TARGET=S390;
2237 arch_target=s390;
2238 ACCESS_UNALIGNED="yes"
2239 JIT_SUPPORTED=yes
2240 jit_wanted=true
2241 # Required CFLAGS for s390[x]. USE_STRING_INLINES is automatic with gcc 4.1
2242 CFLAGS="$CFLAGS -mbackchain -D__USE_STRING_INLINES"
2243 ;;
2244 s390x-*-linux*)
2245 TARGET=S390x;
2246 arch_target=s390x;
2247 ACCESS_UNALIGNED="yes"
2248 JIT_SUPPORTED=yes
2249 jit_wanted=true
2250 CFLAGS="$CFLAGS -mbackchain -D__USE_STRING_INLINES"
2251 ;;
2252 esac
2254 if test "x$host" != "x$target"; then
2255 case "$target" in
2256 powerpc64-ps3-linux-gnu)
2257 TARGET=POWERPC64
2258 arch_target=powerpc64
2259 AC_DEFINE(TARGET_PS3, 1, [...])
2260 AC_DEFINE(MONO_CROSS_COMPILE,1,[The runtime is compiled for cross-compiling mode])
2261 # It would be better to just use TARGET_POWERPC64, but lots of code already
2262 # uses this define
2263 AC_DEFINE(__mono_ppc64__, 1, [...])
2264 AC_DEFINE(__mono_ilp32__, 1, [64 bit mode with 4 byte longs and pointers])
2265 sizeof_register=8
2266 target_byte_order=G_BIG_ENDIAN
2267 ;;
2269 powerpc64-xbox360-linux-gnu)
2270 TARGET=POWERPC64
2271 arch_target=powerpc64
2272 AC_DEFINE(TARGET_XBOX360, 1, [...])
2273 AC_DEFINE(MONO_CROSS_COMPILE,1,[The runtime is compiled for cross-compiling mode])
2274 # It would be better to just use TARGET_POWERPC64, but lots of code already
2275 # uses this define
2276 sizeof_register=8
2277 target_byte_order=G_BIG_ENDIAN
2278 ;;
2279 *)
2280 AC_MSG_WARN([Cross compiling is only supported for targets matching 'powerpc64-{ps3,xbox360}-linux-gnu'])
2281 esac
2282 fi
2284 # FIXME: Define the others as well
2285 case "$TARGET" in
2286 X86)
2287 AC_DEFINE(TARGET_X86, 1, [...])
2288 ;;
2289 AMD64)
2290 AC_DEFINE(TARGET_AMD64, 1, [...])
2291 ;;
2292 ARM)
2293 AC_DEFINE(TARGET_ARM, 1, [...])
2294 ;;
2295 POWERPC)
2296 AC_DEFINE(TARGET_POWERPC, 1, [...])
2297 ;;
2298 POWERPC64)
2299 AC_DEFINE(TARGET_POWERPC, 1, [...])
2300 AC_DEFINE(TARGET_POWERPC64, 1, [...])
2301 ;;
2302 esac
2304 if test "x$sizeof_register" = "x4"; then
2305 AC_DEFINE(SIZEOF_REGISTER,4,[size of machine integer registers])
2306 elif test "x$sizeof_register" = "x8"; then
2307 AC_DEFINE(SIZEOF_REGISTER,8,[size of machine integer registers])
2308 else
2309 AC_DEFINE(SIZEOF_REGISTER,SIZEOF_VOID_P,[size of machine integer registers])
2310 fi
2312 if test "x$target_byte_order" = "xG_BIG_ENDIAN"; then
2313 AC_DEFINE(TARGET_BYTE_ORDER,G_BIG_ENDIAN,[byte order of target])
2314 elif test "x$target_byte_order" = "xG_LITTLE_ENDIAN"; then
2315 AC_DEFINE(TARGET_BYTE_ORDER,G_LITTLE_ENDIAN,[byte order of target])
2316 else
2317 AC_DEFINE(TARGET_BYTE_ORDER,G_BYTE_ORDER,[byte order of target])
2318 fi
2320 if test "x$have_visibility_hidden" = "xyes"; then
2321 AC_DEFINE(HAVE_VISIBILITY_HIDDEN, 1, [Support for the visibility ("hidden") attribute])
2322 fi
2324 if test "x$have_deprecated" = "xyes"; then
2325 AC_DEFINE(HAVE_DEPRECATED, 1, [Support for the deprecated attribute])
2326 fi
2328 AC_ARG_WITH(jit, [ --with-jit=yes,no If you want to build scripts that default to the JIT (defaults to no)],[
2329 if test x$withval = xyes; then
2330 jit_wanted=true
2331 else
2332 jit_wanted=false
2333 fi
2334 ])
2336 AC_ARG_WITH(interp, [ --with-interp=yes,no If you want to build scripts that default to the interpreter (defaults to no)],[
2337 if test x$withval = xyes; then
2338 interp_wanted=true
2339 else
2340 interp_wanted=false
2341 fi
2342 ])
2344 USEJIT=false
2345 if test x$JIT_SUPPORTED = xyes; then
2346 if $jit_wanted; then
2347 USEJIT=true
2348 jit_status="Building and using the JIT"
2349 else
2350 if $interp_wanted; then
2351 jit_status="Building the JIT, defaulting to the interpreter"
2352 else
2353 AC_ERROR(No JIT or interpreter support available or selected.)
2354 fi
2355 fi
2356 else
2357 if test x$interp_wanted = xtrue; then
2358 jit_status="interpreter"
2359 else
2360 AC_ERROR(No JIT or interpreter support available or selected.)
2361 fi
2362 fi
2364 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
2366 libsuffix=".so"
2368 case "$host" in
2369 *-*-darwin*)
2370 libsuffix=".dylib"
2371 LIBC="libc.dylib"
2372 INTL="libintl.dylib"
2373 SQLITE="libsqlite.0.dylib"
2374 SQLITE3="libsqlite3.0.dylib"
2375 X11="libX11.dylib"
2376 ;;
2377 *-*-*netbsd*)
2378 LIBC="libc.so.12"
2379 INTL="libintl.so.0"
2380 ;;
2381 *-*-*freebsd*)
2382 LIBC="libc.so"
2383 INTL="libintl.so"
2384 SQLITE="libsqlite.so"
2385 SQLITE3="libsqlite3.so"
2386 ;;
2387 *-*-*openbsd*)
2388 LIBC="libc.so"
2389 INTL="libintl.so"
2390 SQLITE="libsqlite.so"
2391 SQLITE3="libsqlite3.so"
2392 ;;
2393 *-*-*linux*)
2394 AC_PATH_X
2395 AC_MSG_CHECKING(for the soname of libX11.so)
2396 for i in $x_libraries /usr/lib /usr/lib64; do
2397 for r in 4 5 6; do
2398 if test -f $i/libX11.so.$r; then
2399 X11=libX11.so.$r
2400 AC_MSG_RESULT($X11)
2401 fi
2402 done
2403 done
2405 if test "x$X11" = "xlibX11.so"; then
2406 AC_MSG_WARN([Could not find X development libs. Do you have the -devel package installed? WinForms may not work...]);
2407 fi
2408 ;;
2409 esac
2412 AC_SUBST(libsuffix)
2414 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86"; then
2415 if test "x$with_tls" = "x__thread"; then
2416 #
2417 # On some linux distributions, TLS works in executables, but linking
2418 # against a shared library containing TLS fails with:
2419 # undefined reference to `__tls_get_addr'
2420 #
2421 rm -f conftest.c conftest.so conftest
2422 echo "static __thread int foo; void main () { foo = 5; }" > conftest.c
2423 $CC -fPIC --shared -o conftest.so conftest.c > /dev/null 2>&1
2424 $CC -o conftest conftest.so > /dev/null 2>&1
2425 if test ! -f conftest; then
2426 AC_MSG_WARN([Disabling usage of __thread.]);
2427 with_tls=pthread
2428 fi
2429 rm -f conftest.c conftest.so conftest
2430 fi
2431 fi
2433 mono_debugger_supported=no
2434 AC_ARG_ENABLE(mono-debugger, [ --disable-mono-debugger disable support for the mdb debugger], try_mono_debugger=$enableval, try_mono_debugger=yes)
2435 if test "x$try_mono_debugger" = "xyes"; then
2436 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86" -o "x$TARGET" = "xALPHA"; then
2437 if test x$use_included_gc = xyes; then
2438 case "$host" in
2439 *-*-*linux*)
2440 mono_debugger_supported=yes
2441 ;;
2442 *86-apple-darwin*)
2443 mono_debugger_supported=yes
2444 ;;
2445 esac
2446 fi
2447 fi
2448 fi
2450 AC_MSG_CHECKING(if the Mono Debugger is supported on this platform)
2451 if test "x$mono_debugger_supported" = "xyes"; then
2452 AC_DEFINE(MONO_DEBUGGER_SUPPORTED,1,[The Mono Debugger is supported on this platform])
2453 fi
2454 AC_MSG_RESULT($mono_debugger_supported)
2455 AM_CONDITIONAL(MONO_DEBUGGER_SUPPORTED, test x$mono_debugger_supported = xyes)
2457 if test "x$with_tls" = "x__thread"; then
2458 AC_DEFINE(HAVE_KW_THREAD, 1, [Have __thread keyword])
2459 # Pass the information to libgc
2460 CPPFLAGS="$CPPFLAGS -DUSE_COMPILER_TLS"
2461 AC_MSG_CHECKING(if the tls_model attribute is supported)
2462 AC_TRY_COMPILE([static __thread int foo __attribute__((tls_model("initial-exec")));], [
2463 ], [
2464 AC_MSG_RESULT(yes)
2465 AC_DEFINE(HAVE_TLS_MODEL_ATTR, 1, [tld_model available])
2466 ], [
2467 AC_MSG_RESULT(no)
2468 ])
2469 fi
2471 if test ${TARGET} = ARM && test x$cross_compiling = xno && test x$enable_mcs_build != xno; then
2472 dnl ******************************************
2473 dnl *** Check to see what FPU is available ***
2474 dnl ******************************************
2475 AC_MSG_CHECKING(which FPU to use)
2477 AC_TRY_COMPILE([], [
2478 __asm__ ("ldfd f0, [r0]");
2479 ], fpu=FPA, fpu=NONE)
2481 AC_MSG_RESULT($fpu)
2482 CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu=1"
2483 unset fpu
2484 fi
2486 if test ${TARGET} = unknown; then
2487 CPPFLAGS="$CPPFLAGS -DNO_PORT"
2488 AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
2489 fi
2491 if test ${ACCESS_UNALIGNED} = no; then
2492 CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
2493 fi
2495 case "x$gc" in
2496 xincluded)
2497 # Pass CPPFLAGS to libgc configure
2498 # We should use a separate variable for this to avoid passing useless and
2499 # potentially problematic defines to libgc (like -D_FILE_OFFSET_BITS=64)
2500 # This should be executed late so we pick up the final version of CPPFLAGS
2501 # The problem with this approach, is that during a reconfigure, the main
2502 # configure scripts gets invoked with these arguments, so we use separate
2503 # variables understood by libgc's configure to pass CPPFLAGS and CFLAGS.
2504 LIBGC_CPPFLAGS=$CPPFLAGS
2505 if test x$TARGET = xSPARC -o x$TARGET = xSPARC64; then
2506 LIBGC_CPPFLAGS=`echo $LIBGC_CPPFLAGS | sed -e 's/-D_FILE_OFFSET_BITS=64//g'`
2507 fi
2508 ac_configure_args="$ac_configure_args --disable-embed-check --with-libgc-threads=$libgc_threads $libgc_configure_args \"CPPFLAGS_FOR_LIBGC=$LIBGC_CPPFLAGS\" \"CFLAGS_FOR_LIBGC=$CFLAGS_FOR_LIBGC\""
2509 AC_CONFIG_SUBDIRS(libgc)
2510 ;;
2511 esac
2513 #AC_ARG_WITH(profile2, [ --with-profile2=yes,no If you want to install the 2.0 FX (defaults to yes)], [], [with_profile2=yes])
2514 AC_ARG_WITH(profile4, [ --with-profile4=yes,no If you want to install the 4.0 FX (defaults to yes)], [], [with_profile4=yes])
2515 AC_ARG_WITH(monotouch, [ --with-monotouch=yes,no If you want to build the raw MonoTouch 2.1 assemblies (defaults to no)], [], [with_monotouch=no])
2517 OPROFILE=no
2518 AC_ARG_WITH(oprofile,[ --with-oprofile=no,<oprofile install dir> Enable oprofile support (defaults to no)],[
2519 if test x$with_oprofile != xno; then
2520 oprofile_include=$with_oprofile/include
2521 if test ! -f $oprofile_include/opagent.h; then
2522 AC_MSG_ERROR([oprofile include file not found at $oprofile_include/opagent.h])
2523 fi
2524 OPROFILE=yes
2525 OPROFILE_CFLAGS="-I$oprofile_include"
2526 OPROFILE_LIBS="-L$with_oprofile/lib/oprofile -lopagent"
2527 AC_DEFINE(HAVE_OPROFILE,1,[Have oprofile support])
2528 fi
2529 ])
2531 MALLOC_MEMPOOLS=no
2532 AC_ARG_WITH(malloc_mempools,[ --with-malloc-mempools=yes,no Use malloc for each single mempool allocation (only for runtime debugging, defaults to no)],[
2533 if test x$with_malloc_mempools = xyes; then
2534 MALLOC_MEMPOOLS=yes
2535 AC_DEFINE(USE_MALLOC_FOR_MEMPOOLS,1,[Use malloc for each single mempool allocation])
2536 fi
2537 ])
2540 DISABLE_MCS_DOCS=no
2541 AC_ARG_WITH(mcs_docs,[ --with-mcs-docs=yes,no If you want to build the documentation under mcs (defaults to yes)],[
2542 if test x$with_mcs_docs != xyes; then
2543 DISABLE_MCS_DOCS=yes
2544 fi
2545 ])
2547 AC_ARG_WITH(moonlight, [ --with-moonlight=yes|no|only If you want to build Mono for Moonlight (defaults to no)],[
2548 if test "x$with_moonlight" = "xyes"; then
2549 AC_DEFINE(MOONLIGHT,1,[Building for Moonlight])
2550 elif test "x$with_moonlight" = "xonly"; then
2551 AC_DEFINE(MOONLIGHT,1,[Building for Moonlight])
2552 fi
2553 ], [with_moonlight=no])
2557 AC_CHECK_HEADER([malloc.h],
2558 [AC_DEFINE([HAVE_USR_INCLUDE_MALLOC_H], [1],
2559 [Define to 1 if you have /usr/include/malloc.h.])],,)
2561 dnl
2562 dnl Consistency settings
2563 dnl
2564 if test x$cross_compiling = xyes -o x$enable_mcs_build = xno; then
2565 DISABLE_MCS_DOCS=yes
2566 fi
2568 if test x$DISABLE_MCS_DOCS = xyes; then
2569 docs_dir=""
2570 else
2571 docs_dir=docs
2572 fi
2573 AC_SUBST(docs_dir)
2575 AM_CONDITIONAL(HAVE_OPROFILE, test x$OPROFILE = xyes)
2576 AC_SUBST(OPROFILE_CFLAGS)
2577 AC_SUBST(OPROFILE_LIBS)
2579 libmono_ldflags="$libmono_ldflags $LIBS"
2581 AM_CONDITIONAL(MOONLIGHT, [test "x$with_moonlight" != "xno"])
2582 AM_CONDITIONAL(ONLY_MOONLIGHT, [test "x$with_moonlight" = "xonly"])
2583 AM_CONDITIONAL(INSTALL_4_0, [test "x$with_profile4" = xyes])
2584 AM_CONDITIONAL(INSTALL_MONOTOUCH, [test "x$with_monotouch" = xyes])
2586 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
2587 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
2588 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
2589 AM_CONDITIONAL(SPARC64, test x$TARGET = xSPARC64)
2590 AM_CONDITIONAL(X86, test x$TARGET = xX86)
2591 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
2592 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
2593 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
2594 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
2595 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
2596 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
2597 AM_CONDITIONAL(POWERPC64, test x$TARGET = xPOWERPC64)
2598 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
2599 AM_CONDITIONAL(S390, test x$TARGET = xS390)
2600 AM_CONDITIONAL(S390x, test x$TARGET = xS390x)
2601 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
2603 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
2604 AM_CONDITIONAL(INTERP_SUPPORTED, test x$interp_wanted = xtrue)
2605 AM_CONDITIONAL(INCLUDED_LIBGC, test x$gc = xincluded)
2607 AC_SUBST(LIBC)
2608 AC_SUBST(INTL)
2609 AC_SUBST(SQLITE)
2610 AC_SUBST(SQLITE3)
2611 AC_SUBST(X11)
2612 AC_DEFINE_UNQUOTED(ARCHITECTURE,"$arch_target",[The architecture this is running on])
2613 AC_SUBST(arch_target)
2614 AC_SUBST(CFLAGS)
2615 AC_SUBST(CPPFLAGS)
2616 AC_SUBST(LDFLAGS)
2618 mono_build_root=`pwd`
2619 AC_SUBST(mono_build_root)
2621 if test x$USEJIT = xtrue; then
2622 mono_runtime=mono/mini/mono
2623 else
2624 mono_runtime=mono/interpreter/mint
2625 fi
2626 AC_SUBST(mono_runtime)
2628 mono_cfg_root=$mono_build_root/runtime
2629 if test x$host_win32 = xyes; then
2630 if test "x$cross_compiling" = "xno"; then
2631 mono_cfg_dir=`cygpath -w -a $mono_cfg_root`\\etc
2632 else
2633 mono_cfg_dir=`echo $mono_cfg_root | tr '/' '\\'`\\etc
2634 fi
2635 else
2636 mono_cfg_dir=$mono_cfg_root/etc
2637 fi
2638 AC_SUBST(mono_cfg_dir)
2640 AC_CONFIG_FILES([po/mcs/Makefile.in])
2642 AC_CONFIG_FILES([runtime/mono-wrapper],[chmod +x runtime/mono-wrapper])
2643 AC_CONFIG_FILES([runtime/monodis-wrapper],[chmod +x runtime/monodis-wrapper])
2645 AC_CONFIG_COMMANDS([runtime/etc/mono/1.0/machine.config],
2646 [ depth=../../../..
2647 case $srcdir in
2648 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2649 .) reldir=$depth ;;
2650 *) reldir=$depth/$srcdir ;;
2651 esac
2652 $ac_aux_dir/install-sh -d runtime/etc/mono/1.0
2653 cd runtime/etc/mono/1.0
2654 rm -f machine.config
2655 $LN_S $reldir/data/net_1_1/machine.config machine.config
2656 cd $depth
2657 ],[LN_S='$LN_S'])
2659 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/machine.config],
2660 [ depth=../../../..
2661 case $srcdir in
2662 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2663 .) reldir=$depth ;;
2664 *) reldir=$depth/$srcdir ;;
2665 esac
2666 $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
2667 cd runtime/etc/mono/2.0
2668 rm -f machine.config
2669 $LN_S $reldir/data/net_2_0/machine.config machine.config
2670 cd $depth
2671 ],[LN_S='$LN_S'])
2673 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/web.config],
2674 [ depth=../../../..
2675 case $srcdir in
2676 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2677 .) reldir=$depth ;;
2678 *) reldir=$depth/$srcdir ;;
2679 esac
2680 $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
2681 cd runtime/etc/mono/2.0
2682 rm -f web.config
2683 $LN_S $reldir/data/net_2_0/web.config web.config
2684 cd $depth
2685 ],[LN_S='$LN_S'])
2687 AC_CONFIG_COMMANDS([runtime/etc/mono/browscap.ini],
2688 [ depth=../../..
2689 case $srcdir in
2690 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2691 .) reldir=$depth ;;
2692 *) reldir=$depth/$srcdir ;;
2693 esac
2694 $ac_aux_dir/install-sh -d runtime/etc/mono/
2695 cd runtime/etc/mono/
2696 rm -f browscap.ini
2697 $LN_S $reldir/data/browscap.ini browscap.ini
2698 cd $depth
2699 ],[LN_S='$LN_S'])
2701 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/Browsers/Compat.browser],
2702 [ depth=../../../../..
2703 case $srcdir in
2704 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2705 .) reldir=$depth ;;
2706 *) reldir=$depth/$srcdir ;;
2707 esac
2708 $ac_aux_dir/install-sh -d runtime/etc/mono/2.0/Browsers/
2709 cd runtime/etc/mono/2.0/Browsers
2710 rm -f Compat.browser
2711 $LN_S $reldir/data/net_2_0/Browsers/Compat.browser Compat.browser
2712 cd $depth
2713 ],[LN_S='$LN_S'])
2715 AC_CONFIG_COMMANDS([runtime/etc/mono/4.0/machine.config],
2716 [ depth=../../../..
2717 case $srcdir in
2718 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2719 .) reldir=$depth ;;
2720 *) reldir=$depth/$srcdir ;;
2721 esac
2722 $ac_aux_dir/install-sh -d runtime/etc/mono/4.0
2723 cd runtime/etc/mono/4.0
2724 rm -f machine.config
2725 $LN_S $reldir/data/net_4_0/machine.config machine.config
2726 cd $depth
2727 ],[LN_S='$LN_S'])
2729 AC_CONFIG_COMMANDS([runtime/etc/mono/4.0/web.config],
2730 [ depth=../../../..
2731 case $srcdir in
2732 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2733 .) reldir=$depth ;;
2734 *) reldir=$depth/$srcdir ;;
2735 esac
2736 $ac_aux_dir/install-sh -d runtime/etc/mono/4.0
2737 cd runtime/etc/mono/4.0
2738 rm -f web.config
2739 $LN_S $reldir/data/net_4_0/web.config web.config
2740 cd $depth
2741 ],[LN_S='$LN_S'])
2743 if test x$enable_quiet_build = xyes; then
2744 AC_CONFIG_COMMANDS([quiet], [for i in `find mono libgc support -name Makefile.in | sed -e 's/Makefile.in/Makefile/g'`; do if test -f $i; then $srcdir/scripts/patch-quiet.sh $i; fi; done], [shell=$SHELL])
2745 AC_CONFIG_COMMANDS([quiet-libtool], [sed -e 's/$echo "copying selected/$show "copying selected/g' < libtool > libtool.tmp && mv libtool.tmp libtool && chmod a+x libtool; sed -e 's/$ECHO "copying selected/# "copying selected/g' < libtool > libtool.tmp && mv libtool.tmp libtool && chmod a+x libtool])
2746 fi
2748 AC_OUTPUT([
2749 Makefile
2750 mono-core.spec
2751 mono-uninstalled.pc
2752 scripts/mono-find-provides
2753 scripts/mono-find-requires
2754 mono/Makefile
2755 mono/utils/Makefile
2756 mono/metadata/Makefile
2757 mono/dis/Makefile
2758 mono/cil/Makefile
2759 mono/arch/Makefile
2760 mono/arch/x86/Makefile
2761 mono/arch/amd64/Makefile
2762 mono/arch/hppa/Makefile
2763 mono/arch/ppc/Makefile
2764 mono/arch/sparc/Makefile
2765 mono/arch/s390/Makefile
2766 mono/arch/s390x/Makefile
2767 mono/arch/arm/Makefile
2768 mono/arch/alpha/Makefile
2769 mono/arch/ia64/Makefile
2770 mono/arch/mips/Makefile
2771 mono/interpreter/Makefile
2772 mono/tests/Makefile
2773 mono/tests/tests-config
2774 mono/tests/assemblyresolve/Makefile
2775 mono/tests/cas/Makefile
2776 mono/tests/cas/assembly/Makefile
2777 mono/tests/cas/demand/Makefile
2778 mono/tests/cas/inheritance/Makefile
2779 mono/tests/cas/linkdemand/Makefile
2780 mono/tests/cas/threads/Makefile
2781 mono/benchmark/Makefile
2782 mono/monograph/Makefile
2783 mono/io-layer/Makefile
2784 mono/mini/Makefile
2785 mono/profiler/Makefile
2786 ikvm-native/Makefile
2787 scripts/Makefile
2788 man/Makefile
2789 web/Makefile
2790 docs/Makefile
2791 data/Makefile
2792 data/net_2_0/Makefile
2793 data/net_4_0/Makefile
2794 data/net_2_0/Browsers/Makefile
2795 data/mint.pc
2796 data/mono-2.pc
2797 data/mono.pc
2798 data/mono-cairo.pc
2799 data/mono-nunit.pc
2800 data/mono-options.pc
2801 data/mono-lineeditor.pc
2802 data/monodoc.pc
2803 data/mono.web.pc
2804 data/dotnet.pc
2805 data/dotnet35.pc
2806 data/wcf.pc
2807 data/cecil.pc
2808 data/system.web.extensions_1.0.pc
2809 data/system.web.extensions.design_1.0.pc
2810 data/system.web.mvc.pc
2811 data/system.web.mvc2.pc
2812 samples/Makefile
2813 support/Makefile
2814 data/config
2815 tools/Makefile
2816 tools/locale-builder/Makefile
2817 tools/sgen/Makefile
2818 runtime/Makefile
2819 msvc/Makefile
2820 po/Makefile
2821 ])
2823 if test x$host_win32 = xyes; then
2824 # Get rid of 'cyg' prefixes in library names
2825 sed -e "s/\/cyg\//\/\//" libtool > libtool.new; mv libtool.new libtool; chmod 755 libtool
2826 # libtool seems to inherit -mno-cygwin from our CFLAGS, and uses it to compile its executable
2827 # wrapper scripts which use exec(). gcc has no problem compiling+linking this, but the resulting
2828 # executable doesn't work...
2829 sed -e "s,-mno-cygwin,,g" libtool > libtool.new; mv libtool.new libtool; chmod 755 libtool
2830 fi
2832 (
2833 case $prefix in
2834 NONE) prefix=$ac_default_prefix ;;
2835 esac
2836 case $exec_prefix in
2837 NONE) exec_prefix='${prefix}' ;;
2838 esac
2840 #
2841 # If we are cross compiling, we don't build in the mcs/ tree. Let us not clobber
2842 # any existing config.make. This allows people to share the same source tree
2843 # with different build directories, one native and one cross
2844 #
2845 if test x$cross_compiling = xno && test x$enable_mcs_build != xno; then
2847 test -w $mcs_topdir/build || chmod +w $mcs_topdir/build
2849 echo "prefix=$prefix" > $mcs_topdir/build/config.make
2850 echo "exec_prefix=$exec_prefix" >> $mcs_topdir/build/config.make
2851 echo "sysconfdir=$sysconfdir" >> $mcs_topdir/build/config.make
2852 echo 'mono_libdir=${exec_prefix}/lib' >> $mcs_topdir/build/config.make
2853 echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $mcs_topdir/build/config.make
2854 echo 'IL_FLAGS = /debug' >> $mcs_topdir/build/config.make
2855 echo "RUNTIME = $mono_build_root/runtime/mono-wrapper" >> $mcs_topdir/build/config.make
2856 echo "ILDISASM = $mono_build_root/runtime/monodis-wrapper" >> $mcs_topdir/build/config.make
2858 case $INSTALL in
2859 [[\\/$]]* | ?:[[\\/]]* ) mcs_INSTALL=$INSTALL ;;
2860 *) mcs_INSTALL=$mono_build_root/$INSTALL ;;
2861 esac
2863 echo "INSTALL = $mcs_INSTALL" >> $mcs_topdir/build/config.make
2865 export VERSION
2866 [myver=$($AWK 'BEGIN {
2867 split (ENVIRON["VERSION"] ".0.0.0", vsplit, ".")
2868 if(length(vsplit [1]) > 4) {
2869 split (substr(ENVIRON["VERSION"], 0, 4) "." substr(ENVIRON["VERSION"], 5) ".0.0", vsplit, ".")
2870 }
2871 print vsplit [1] "." vsplit [2] "." vsplit [3] "." vsplit [4]
2872 }')]
2874 echo "MONO_VERSION = $myver" >> $mcs_topdir/build/config.make
2876 if test x$platform_darwin = xyes; then
2877 echo "PLATFORM = darwin" >> $mcs_topdir/build/config.make
2878 fi
2880 if test x$TARGET = xAMD64 -a x$host_win32 = xno -a "x$AOT_SUPPORTED" = "xyes" -a x$enable_system_aot = xyes; then
2881 echo "ENABLE_AOT = 1" >> $mcs_topdir/build/config.make
2882 fi
2884 if test x$DISABLE_MCS_DOCS = xyes; then
2885 echo "DISABLE_MCS_DOCS = yes" >> $mcs_topdir/build/config.make
2886 fi
2888 if test x$with_moonlight != xno; then
2889 echo "MOONLIGHT = 1" >> $srcdir/$mcsdir/build/config.make
2890 fi
2892 fi
2894 # if we have an olive folder, override the default settings
2895 if test -d $olivedir; then
2897 if test x$cross_compiling = xno && test x$enable_olive_build != xno; then
2899 test -w $srcdir/$olivedir/build || chmod +w $srcdir/$olivedir/build
2901 echo "prefix=$prefix" > $srcdir/$olivedir/build/config.make
2902 echo "exec_prefix=$exec_prefix" >> $srcdir/$olivedir/build/config.make
2903 echo 'mono_libdir=${exec_prefix}/lib' >> $srcdir/$olivedir/build/config.make
2904 echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $srcdir/$olivedir/build/config.make
2905 echo "RUNTIME = $mono_build_root/runtime/mono-wrapper" >> $srcdir/$olivedir/build/config.make
2906 echo "MONO_VERSION = $myver" >> $srcdir/$olivedir/build/config.make
2907 fi
2908 fi
2910 )
2912 libgdiplus_msg=${libgdiplus_loc:-assumed to be installed}
2914 echo "
2915 mcs source: $mcsdir
2916 olive source: $olive_topdir
2918 Engine:
2919 GC: $gc
2920 GLIB: $with_glib
2921 TLS: $with_tls
2922 SIGALTSTACK: $with_sigaltstack
2923 Engine: $jit_status
2924 oprofile: $OPROFILE
2925 BigArrays: $enable_big_arrays
2926 DTrace: $enable_dtrace
2927 Parallel Mark: $enable_parallel_mark
2928 LLVM Back End: $enable_llvm
2930 Libraries:
2931 Moon Profile: $with_moonlight
2932 MonoTouch: $with_monotouch
2933 JNI support: $jdk_headers_found
2934 libgdiplus: $libgdiplus_msg
2935 zlib: $zlib_msg
2936 $disabled
2937 "
2938 if test x$with_static_mono = xno -a "x$host_win32" != "xyes"; then
2939 AC_MSG_WARN(Turning off static Mono is a risk, you might run into unexpected bugs)
2940 fi
2942 if test x$gc = xsgen; then
2943 echo IMPORTANT:
2944 echo IMPORTANT: You have selected an experimental, work-in-progress
2945 echo IMPORTANT: GC engine. This GC engine is currently not supported
2946 echo IMPORTANT: and is not yet ready for use.
2947 echo IMPORTANT:
2948 echo IMPORTANT: There are known problems with it, use at your own risk.
2949 fi
2951 if test x$enable_llvm = xyes; then
2952 echo IMPORTANT:
2953 echo IMPORTANT: The LLVM Back End is experimental and has known problems.
2954 echo IMPORTANT:
2955 fi