| blob | 45b970bacd920eaee68391fae11d29e2b6a0e70d |
1 AC_INIT(README)
2 AC_CANONICAL_SYSTEM
4 # Gross hack to enable 'make dist' on automake 1.9+tar 1.14.
5 # The extra brackets are to foil regex-based scans.
6 m4_ifdef([_A][M_PROG_TAR],[_A][M_SET_OPTION([tar-ustar])])
8 AM_CONFIG_HEADER(config.h)
9 AM_INIT_AUTOMAKE(mono,2.7)
10 AM_MAINTAINER_MODE
12 API_VER=2.0
13 AC_SUBST(API_VER)
15 AC_PROG_LN_S
17 # In case of cygwin, override LN_S, irrespective of what it determines.
18 # The build uses cygwin, but the actual runtime doesn't.
19 case $host_os in
20 *cygwin* ) LN_S='cp -p';;
21 esac
23 dnl
24 dnl libgc checks
25 dnl
27 gc_headers=no
28 gc=included
29 use_included_gc=no
30 libgc_configure_args=
32 if test -d $srcdir/libgc ; then
33 gc_default=included
34 else
35 gc_default=boehm
36 fi
38 # These variables are the CPPFLAGS/CFLAGS passed to libgc's configure
39 # libgc should inherit the original CFLAGS/CPPFLAGS passed to configure, i.e. -O0
40 CPPFLAGS_FOR_LIBGC=$CPPFLAGS
41 CFLAGS_FOR_LIBGC=$CFLAGS
42 CPPFLAGS_FOR_EGLIB=$CPPFLAGS
43 CFLAGS_FOR_EGLIB=$CFLAGS
45 #
46 # These are the flags that need to be stored in the mono.pc file for
47 # compiling code that will embed Mono
48 #
49 libmono_cflags=""
50 libmono_ldflags=""
51 AC_SUBST(libmono_cflags)
52 AC_SUBST(libmono_ldflags)
54 # Variable to have relocatable .pc files (lib, or lib64)
55 reloc_libdir=`basename ${libdir}`
56 AC_SUBST(reloc_libdir)
58 dnl if linker handles the version script
59 no_version_script=no
61 # Set to yes if Unix sockets cannot be created in an anonymous namespace
62 need_link_unlink=no
64 # Thread configuration inspired by sleepycat's db
65 AC_MSG_CHECKING([host platform characteristics])
66 libgc_threads=no
67 has_dtrace=no
68 parallel_mark=yes
70 case "$host" in
71 powerpc*-*-linux*)
72 # https://bugzilla.novell.com/show_bug.cgi?id=504411
73 disable_munmap=yes
74 ;;
75 esac
77 host_win32=no
78 target_win32=no
79 case "$host" in
80 *-mingw*|*-*-cygwin*)
81 AC_DEFINE(HOST_WIN32,1,[Host Platform is Win32])
82 AC_DEFINE(DISABLE_PORTABILITY,1,[Disable the io-portability layer])
83 AC_DEFINE(PLATFORM_NO_SYMLINKS,1,[This platform does not support symlinks])
84 host_win32=yes
85 if test "x$cross_compiling" = "xno"; then
86 target_win32=yes
87 if test "x$host" == "x$target"; then
88 AC_DEFINE(TARGET_WIN32,1,[Target OS is Win32])
89 fi
90 CC="gcc -mno-cygwin -g"
91 CXX="g++ -mno-cygwin -g"
92 # So libgc configure gets -mno-cygwin
93 export CC
94 export CXX
95 else
96 target_win32=yes
97 AC_DEFINE(TARGET_WIN32,1,[Target OS is Win32/MinGW])
98 AC_DEFINE(MINGW_CROSS_COMPILE,1,[Cross-compiling using MinGW])
99 fi
100 HOST_CC="gcc"
101 # Windows 2000 is required that includes Internet Explorer 5.01
102 CPPFLAGS="$CPPFLAGS -DWINVER=0x0500 -D_WIN32_WINNT=0x0500 -D_WIN32_IE=0x0501 -D_UNICODE -DUNICODE -DWIN32_THREADS -DFD_SETSIZE=1024"
103 LDFLAGS="$LDFLAGS -lmswsock -lws2_32 -lole32 -loleaut32 -lpsapi -lversion -ladvapi32 -lwinmm -lkernel32"
104 libmono_cflags="-mno-cygwin -mms-bitfields -mwindows"
105 libmono_ldflags="-mno-cygwin -mms-bitfields -mwindows"
106 libdl=
107 libgc_threads=win32
108 gc_default=included
109 with_sigaltstack=no
110 LN_S=cp
111 # This forces libgc to use the DllMain based thread registration code on win32
112 libgc_configure_args="$libgc_configure_args --enable-win32-dllmain=yes"
113 ;;
114 *-*-*netbsd*)
115 host_win32=no
116 CPPFLAGS="$CPPFLAGS -D_REENTRANT -DGC_NETBSD_THREADS -D_GNU_SOURCE"
117 libmono_cflags="-D_REENTRANT"
118 LDFLAGS="$LDFLAGS -pthread"
119 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD"
120 libmono_ldflags="-pthread"
121 need_link_unlink=yes
122 libdl="-ldl"
123 libgc_threads=pthreads
124 with_sigaltstack=no
125 use_sigposix=yes
126 ;;
127 *-*-*freebsd*)
128 host_win32=no
129 if test "x$PTHREAD_CFLAGS" = "x"; then
130 CPPFLAGS="$CPPFLAGS -DGC_FREEBSD_THREADS"
131 libmono_cflags=
132 else
133 CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
134 libmono_cflags="$PTHREAD_CFLAGS"
135 fi
136 if test "x$PTHREAD_LIBS" = "x"; then
137 LDFLAGS="$LDFLAGS -pthread"
138 libmono_ldflags="-pthread"
139 else
140 LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
141 libmono_ldflags="$PTHREAD_LIBS"
142 fi
143 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD"
144 need_link_unlink=yes
145 AC_DEFINE(PTHREAD_POINTER_ID, 1, [pthread is a pointer])
146 libdl=
147 libgc_threads=pthreads
148 # This doesn't seem to work as of 7.0 on amd64
149 with_sigaltstack=no
150 # TLS is only partially implemented on -CURRENT (compiler support
151 # but NOT library support)
152 #
153 with_tls=pthread
154 use_sigposix=yes
155 ;;
156 *-*-*openbsd*)
157 host_win32=no
158 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_OPENBSD_THREADS -DPLATFORM_BSD -D_GNU_SOURCE -D_REENTRANT -DUSE_MMAP"
159 if test "x$disable_munmap" != "xyes"; then
160 CPPFLAGS="$CPPFLAGS -DUSE_MUNMAP"
161 fi
162 libmono_cflags="-D_THREAD_SAFE -D_REENTRANT"
163 LDFLAGS="$LDFLAGS -pthread"
164 libmono_ldflags="-pthread"
165 need_link_unlink=yes
166 AC_DEFINE(PTHREAD_POINTER_ID)
167 libdl=
168 gc_default=boehm
169 libgc_threads=pthreads
170 with_sigaltstack=no
171 use_sigposix=yes
172 ;;
173 *-*-linux*)
174 host_win32=no
175 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -D_GNU_SOURCE -D_REENTRANT -DUSE_MMAP"
176 if test "x$disable_munmap" != "xyes"; then
177 CPPFLAGS="$CPPFLAGS -DUSE_MUNMAP"
178 fi
179 libmono_cflags="-D_REENTRANT"
180 libmono_ldflags="-lpthread"
181 libdl="-ldl"
182 libgc_threads=pthreads
183 AOT_SUPPORTED="yes"
184 use_sigposix=yes
185 ;;
186 *-*-hpux*)
187 host_win32=no
188 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
189 # +ESdbgasm only valid on bundled cc on RISC
190 # silently ignored for ia64
191 if test $GCC != "yes"; then
192 CFLAGS="$CFLAGS +ESdbgasm"
193 # Arrange for run-time dereferencing of null
194 # pointers to produce a SIGSEGV signal.
195 LDFLAGS="$LDFLAGS -z"
196 fi
197 CFLAGS="$CFLAGS +ESdbgasm"
198 LDFLAGS="$LDFLAGS -z"
199 libmono_cflags="-D_REENTRANT"
200 libmono_ldflags="-lpthread"
201 libgc_threads=pthreads
202 need_link_unlink=yes
203 use_sigposix=yes
204 ;;
205 *-*-solaris*)
206 host_win32=no
207 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS -DUSE_MMAP -DUSE_MUNMAP -DPLATFORM_SOLARIS"
208 need_link_unlink=yes
209 libmono_cflags="-D_REENTRANT"
210 libgc_threads=pthreads
211 # This doesn't seem to work on solaris/x86, but the configure test runs
212 with_tls=pthread
213 has_dtrace=yes
214 use_sigposix=yes
215 enable_solaris_tar_check=yes
216 ;;
217 *-*-darwin*)
218 parallel_mark="Disabled_Currently_Hangs_On_MacOSX"
219 host_win32=no
220 platform_darwin=yes
221 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE -DGC_MACOSX_THREADS -DPLATFORM_MACOSX -DUSE_MMAP -DUSE_MUNMAP"
222 CPPFLAGS="$CPPFLAGS -DGetCurrentProcess=MonoGetCurrentProcess -DGetCurrentThread=MonoGetCurrentThread -DCreateEvent=MonoCreateEvent"
223 libmono_cflags="-D_THREAD_SAFE"
224 LDFLAGS="$LDFLAGS -pthread"
225 libmono_ldflags="-pthread"
226 need_link_unlink=yes
227 AC_DEFINE(PTHREAD_POINTER_ID)
228 AC_DEFINE(USE_MACH_SEMA, 1, [...])
229 no_version_script=yes
230 libdl=
231 libgc_threads=pthreads
232 has_dtrace=yes
233 if test "x$cross_compiling" = "xyes"; then
234 has_broken_apple_cpp=yes
235 fi
236 dnl Snow Leopard is horribly broken -- it reports itself as i386-apple-darwin10.0.0, but
237 dnl its gcc defaults to 64-bit mode. They have also deprecated the usage of ucontext
238 dnl we need to set some flags to build our 32-bit binaries on 10.6 properly
239 case "$host" in
240 dnl MacPorts config.guess reports as this
241 x86_64-*-darwin10*)
242 BROKEN_DARWIN_FLAGS="-arch i386 -D_XOPEN_SOURCE -mmacosx-version-min=10.5"
243 CPPFLAGS="$CPPFLAGS $BROKEN_DARWIN_FLAGS"
244 CFLAGS="$CFLAGS $BROKEN_DARWIN_FLAGS"
245 CXXFLAGS="$CXXFLAGS $BROKEN_DARWIN_FLAGS"
246 CCASFLAGS="$CCASFLAGS $BROKEN_DARWIN_FLAGS"
247 CPPFLAGS_FOR_LIBGC="$CPPFLAGS_FOR_LIBGC $BROKEN_DARWIN_FLAGS"
248 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC $BROKEN_DARWIN_FLAGS"
249 CPPFLAGS_FOR_EGLIB="$CPPFLAGS_FOR_EGLIB $BROKEN_DARWIN_FLAGS"
250 CFLAGS_FOR_EGLIB="$CFLAGS_FOR_EGLIB $BROKEN_DARWIN_FLAGS"
251 ;;
252 dnl Snow Leopard config.guess reports as this
253 i*86-*-darwin10*)
254 BROKEN_DARWIN_FLAGS="-arch i386 -D_XOPEN_SOURCE -mmacosx-version-min=10.5"
255 CPPFLAGS="$CPPFLAGS $BROKEN_DARWIN_FLAGS"
256 CFLAGS="$CFLAGS $BROKEN_DARWIN_FLAGS"
257 CXXFLAGS="$CXXFLAGS $BROKEN_DARWIN_FLAGS"
258 CCASFLAGS="$CCASFLAGS $BROKEN_DARWIN_FLAGS"
259 CPPFLAGS_FOR_LIBGC="$CPPFLAGS_FOR_LIBGC $BROKEN_DARWIN_FLAGS"
260 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC $BROKEN_DARWIN_FLAGS"
261 CPPFLAGS_FOR_EGLIB="$CPPFLAGS_FOR_EGLIB $BROKEN_DARWIN_FLAGS"
262 CFLAGS_FOR_EGLIB="$CFLAGS_FOR_EGLIB $BROKEN_DARWIN_FLAGS"
263 ;;
264 esac
265 ;;
266 *-*-haiku*)
267 host_win32=no
268 CPPFLAGS="$CPPFLAGS -D_REENTRANT -D_THREAD_SAFE"
269 libmono_cflags="-D_REENTRANT -D_THREAD_SAFE"
270 libdl=
271 LIBS="$LIBS -lnetwork"
272 need_link_unlink=yes
273 AC_DEFINE(PTHREAD_POINTER_ID)
274 libgc_threads=pthreads
275 use_sigposix=yes
276 ;;
277 *)
278 AC_MSG_WARN([*** Please add $host to configure.in checks!])
279 host_win32=no
280 libdl="-ldl"
281 ;;
282 esac
283 AC_MSG_RESULT(ok)
285 if test x$need_link_unlink = xyes; then
286 AC_DEFINE(NEED_LINK_UNLINK, 1, [Define if Unix sockets cannot be created in an anonymous namespace])
287 fi
289 AM_CONDITIONAL(HOST_WIN32, test x$host_win32 = xyes)
290 AM_CONDITIONAL(TARGET_WIN32, test x$target_win32 = xyes)
291 AM_CONDITIONAL(PLATFORM_LINUX, echo x$target_os | grep -q linux)
292 AM_CONDITIONAL(PLATFORM_DARWIN, test x$platform_darwin = xyes)
293 AM_CONDITIONAL(PLATFORM_SIGPOSIX, test x$use_sigposix = xyes)
295 AC_CHECK_TOOL(CC, gcc, gcc)
296 AC_PROG_CC
297 AC_CHECK_TOOL(CXX, g++, g++)
298 AC_PROG_CXX
299 AM_PROG_AS
300 AM_PROG_CC_STDC
301 AC_PROG_INSTALL
302 AC_PROG_AWK
303 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
304 : ${CCAS='$(CC)'}
305 # Set ASFLAGS if not already set.
306 : ${CCASFLAGS='$(CFLAGS)'}
307 AC_SUBST(CCAS)
308 AC_SUBST(CCASFLAGS)
310 # AC_PROG_CXX helpfully sets CXX to g++ even if no c++ compiler is found so check
311 # GXX instead. See http://lists.gnu.org/archive/html/bug-autoconf/2002-04/msg00056.html
312 if test "x$CXX" = "xg++"; then
313 if test "x$GXX" != "xyes"; then
314 # automake/libtool is so broken, it requires g++ even if the c++ sources
315 # are inside automake conditionals
316 AC_MSG_ERROR([You need to install g++])
317 fi
318 fi
320 AC_CHECK_PROG(BISON, bison,yes,no)
321 if test "x$BISON" = "xno";
322 then
323 AC_MSG_ERROR([You need to install bison])
324 fi
326 dnl may require a specific autoconf version
327 dnl AC_PROG_CC_FOR_BUILD
328 dnl CC_FOR_BUILD not automatically detected
329 CC_FOR_BUILD=$CC
330 CFLAGS_FOR_BUILD=$CFLAGS
331 BUILD_EXEEXT=
332 if test "x$cross_compiling" = "xyes"; then
333 CC_FOR_BUILD=cc
334 CFLAGS_FOR_BUILD=
335 BUILD_EXEEXT=""
336 fi
337 AC_SUBST(CC_FOR_BUILD)
338 AC_SUBST(CFLAGS_FOR_BUILD)
339 AC_SUBST(HOST_CC)
340 AC_SUBST(BUILD_EXEEXT)
342 AM_CONDITIONAL(CROSS_COMPILING, [test x$cross_compiling = xyes])
343 AM_CONDITIONAL(USE_BATCH_FILES, [test x$host_win32 = xyes -a x$cross_compiling = xyes])
345 # Set STDC_HEADERS
346 AC_HEADER_STDC
347 AC_LIBTOOL_WIN32_DLL
348 # This causes monodis to not link correctly
349 #AC_DISABLE_FAST_INSTALL
350 AM_PROG_LIBTOOL
351 # Use dolt (http://dolt.freedesktop.org/) instead of libtool for building.
352 DOLT
354 export_ldflags=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
355 AC_SUBST(export_ldflags)
357 # Test whenever ld supports -version-script
358 AC_PROG_LD
359 AC_PROG_LD_GNU
360 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
361 no_version_script=yes
362 fi
364 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
366 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h sys/utime.h semaphore.h sys/un.h linux/rtc.h sys/syscall.h sys/mkdev.h sys/uio.h)
367 AC_CHECK_HEADERS(sys/user.h sys/socket.h sys/ipc.h sys/sem.h sys/utsname.h alloca.h ucontext.h pwd.h sys/select.h netinet/tcp.h netinet/in.h unistd.h sys/types.h link.h)
370 AC_CHECK_HEADER(zlib.h, [have_zlib=yes], [have_zlib=no])
371 if test x$have_zlib = xyes; then
372 AC_TRY_COMPILE([#include <zlib.h>], [
373 void main () {
374 #if defined(ZLIB_VERNUM) && (ZLIB_VERNUM >= 0x1230)
375 }
376 #else
377 #error No good zlib found
378 #endif
379 ],[
380 AC_MSG_RESULT(Using system zlib)
381 zlib_msg="system zlib"
382 ],[
383 AC_MSG_RESULT(Using embedded zlib)
384 have_zlib=no
385 zlib_msg="bundled zlib"
386 ])
387 fi
389 AM_CONDITIONAL(HAVE_ZLIB, test x$have_zlib = xyes)
390 AC_DEFINE(HAVE_ZLIB,1,[Have system zlib])
392 # for mono/metadata/debug-symfile.c
393 AC_CHECK_HEADERS(elf.h)
395 # for support
396 AC_CHECK_HEADERS(poll.h)
397 AC_CHECK_HEADERS(sys/poll.h)
398 AC_CHECK_HEADERS(sys/wait.h)
399 AC_CHECK_HEADERS(grp.h)
400 AC_CHECK_HEADERS(syslog.h)
402 # for mono/dis
403 AC_CHECK_HEADERS(wchar.h)
404 AC_CHECK_HEADERS(ieeefp.h)
405 AC_MSG_CHECKING(for isinf)
406 AC_TRY_LINK([#include <math.h>], [
407 int f = isinf (1);
408 ], [
409 AC_MSG_RESULT(yes)
410 AC_DEFINE(HAVE_ISINF, 1, [isinf available])
411 ], [
412 # We'll have to use signals
413 AC_MSG_RESULT(no)
414 ])
417 # not 64 bit clean in cross-compile
418 AC_CHECK_SIZEOF(void *, 4)
420 WARN=''
421 if test x"$GCC" = xyes; then
422 WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wwrite-strings'
423 # The runtime code does not respect ANSI C strict aliasing rules
424 CFLAGS="$CFLAGS -fno-strict-aliasing"
426 ORIG_CFLAGS=$CFLAGS
427 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
428 AC_MSG_CHECKING(for -Wdeclaration-after-statement option to gcc)
429 AC_TRY_COMPILE([], [
430 void main () { }
431 ], [
432 AC_MSG_RESULT(yes)
433 ], [
434 AC_MSG_RESULT(no)
435 CFLAGS=$ORIG_CFLAGS
436 ])
437 else
438 # The Sun Forte compiler complains about inline functions that access static variables
439 # so disable all inlining.
440 case "$host" in
441 *-*-solaris*)
442 CFLAGS="$CFLAGS -Dinline="
443 ;;
444 esac
445 fi
446 CFLAGS="$CFLAGS -g $WARN"
447 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC -g"
449 # Where's the 'mcs' source tree?
450 if test -d $srcdir/mcs; then
451 mcsdir=mcs
452 else
453 mcsdir=../mcs
454 fi
456 #
457 # A sanity check to catch cases where the package was unpacked
458 # with an ancient tar program (Solaris)
459 #
460 AC_ARG_ENABLE(solaris-tar-check,
461 [ --disable-solaris-tar-check disable solaris tar check],
462 do_solaris_tar_check=no, do_solaris_tar_check=yes)
464 if test x"$do_solaris_tar_check" = xyes -a x"$enable_solaris_tar_check" = xyes; then
465 AC_MSG_CHECKING(integrity of package)
466 if test -f $srcdir/$mcsdir/class/System.Runtime.Serialization.Formatters.Soap/System.Runtime.Serialization.Formatters.Soap/SoapTypeMapper.cs
467 then
468 AC_MSG_RESULT(ok)
469 else
470 errorm="Your mono distribution is incomplete; if unpacking from a tar file, make sure you use GNU tar; see http://www.mono-project.com/IncompletePackage for more details"
471 AC_MSG_ERROR([$errorm])
472 fi
473 fi
475 mcs_topdir='$(top_srcdir)/'$mcsdir
476 mcs_topdir_from_srcdir='$(top_builddir)/'$mcsdir
478 ## Maybe should also disable if mcsdir is invalid. Let's punt the issue for now.
479 AM_CONDITIONAL(BUILD_MCS, [test x$cross_compiling = xno && test x$enable_mcs_build != xno])
481 AC_SUBST([mcs_topdir])
482 AC_SUBST([mcs_topdir_from_srcdir])
484 # Where's the 'olive' source tree?
485 if test -d $srcdir/olive; then
486 olivedir=olive
487 else
488 olivedir=../olive
489 fi
491 if test -d $srcdir/$olivedir; then
492 olive_topdir='$(top_srcdir)/'$olivedir
493 fi
495 # gettext: prepare the translation directories.
496 # we do not configure the full gettext, as we consume it dynamically from C#
497 AM_PO_SUBDIRS
499 if test "x$USE_NLS" = "xyes"; then
500 AC_CHECK_PROG(HAVE_MSGFMT, msgfmt,yes,no)
502 if test "x$HAVE_MSGFMT" = "xno"; then
503 AC_MSG_ERROR([msgfmt not found. You need to install the 'gettext' package, or pass --enable-nls=no to configure.])
504 fi
505 fi
507 AC_ARG_WITH([libgdiplus],
508 [ --with-libgdiplus=installed|sibling|<path> Override the libgdiplus used for System.Drawing tests (defaults to installed)],
509 [], [with_libgdiplus=installed])
511 case $with_libgdiplus in
512 no|installed) libgdiplus_loc= ;;
513 yes|sibling) libgdiplus_loc=`cd ../libgdiplus && pwd`/src/libgdiplus.la ;;
514 /*) libgdiplus_loc=$with_libgdiplus ;;
515 *) libgdiplus_loc=`pwd`/$with_libgdiplus ;;
516 esac
517 AC_SUBST([libgdiplus_loc])
519 PKG_PROG_PKG_CONFIG()
520 if test "x$PKG_CONFIG" = "x"; then
521 AC_MSG_ERROR([You need to install pkg-config])
522 fi
524 pkg_config_path=
525 AC_ARG_WITH(crosspkgdir, [ --with-crosspkgdir=/path/to/pkg-config/dir Change pkg-config dir to custom dir],
526 if test x$with_crosspkgdir = "x"; then
527 if test -s $PKG_CONFIG_PATH; then
528 pkg_config_path=$PKG_CONFIG_PATH
529 fi
530 else
531 pkg_config_path=$with_crosspkgdir
532 PKG_CONFIG_PATH=$pkg_config_path
533 export PKG_CONFIG_PATH
534 fi
535 )
537 AC_ARG_WITH([glib],
538 [ --with-glib=embedded|system Choose glib API: system or embedded (default to system)],
539 [], [with_glib=system])
541 eglib_dir=
543 ac_configure_args="$ac_configure_args \"CPPFLAGS_FOR_EGLIB=$EGLIB_CPPFLAGS\" \"CFLAGS_FOR_EGLIB=$CFLAGS_FOR_EGLIB\""
544 AC_CONFIG_SUBDIRS(eglib)
546 case $with_glib in
547 embedded)
548 GLIB_CFLAGS='-I$(top_srcdir)/eglib/src -I$(top_builddir)/eglib/src'
549 GLIB_LIBS='-L$(top_builddir)/eglib/src -leglib -lm'
550 BUILD_GLIB_CFLAGS="$GLIB_CFLAGS"
551 BUILD_GLIB_LIBS="$GLIB_LIBS"
552 GMODULE_CFLAGS="$GLIB_CFLAGS"
553 GMODULE_LIBS="$GLIB_LIBS"
554 eglib_dir=eglib
555 ;;
556 system)
557 echo "PKG_CONFIG_PATH=$PKG_CONFIG_PATH"
558 echo "cross_compiling=$cross_compiling"
559 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
560 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
562 ## Versions of dependencies
563 GLIB_REQUIRED_VERSION=2.4.0
565 dnl
566 dnl No, you will not replace this check with a pkg.m4 check
567 dnl
568 if $PKG_CONFIG --atleast-version=$GLIB_REQUIRED_VERSION glib-2.0; then
569 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
570 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
571 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
572 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
573 else
574 AC_MSG_ERROR([You need at least glib-2.0 $GLIB_REQUIRED_VERSION])
575 fi
576 ;;
577 *)
578 AC_MSG_ERROR([Invalid argument to --with-glib.])
579 esac
580 AM_CONDITIONAL(EGLIB_BUILD, test x$with_glib = xembedded)
582 AC_SUBST(GLIB_CFLAGS)
583 AC_SUBST(GLIB_LIBS)
584 AC_SUBST(GMODULE_CFLAGS)
585 AC_SUBST(GMODULE_LIBS)
586 AC_SUBST(BUILD_GLIB_CFLAGS)
587 AC_SUBST(BUILD_GLIB_LIBS)
588 AC_SUBST(eglib_dir)
590 if test x$cross_compiling$host_win32 = xnoyes; then
591 AC_MSG_CHECKING(for cygwin glib2-dev package)
592 if [ cygcheck --f /usr/lib/libglib-2.0.dll.a | grep -q glib2-devel ]; then
593 AC_MSG_RESULT(found)
594 AC_MSG_ERROR([Mono cannot be built with the cygwin glib2-devel package installed, because that package doesn't work with -mno-cygwin. Please uninstall it then re-run configure.])
595 else
596 AC_MSG_RESULT(not found, ok)
597 fi
599 AC_MSG_CHECKING(for broken gwin32.h)
600 glib_include=`$PKG_CONFIG --cflags-only-I glib-2.0 | sed -e 's/ -I.*//g' | sed -e 's/-I//g'`
601 if test -f $glib_include/glib/gwin32.h; then
602 if [ grep ftruncate $glib_include/glib/gwin32.h | grep -q define ]; then
603 AC_MSG_RESULT(failed)
604 hashmark='#'
605 AC_MSG_ERROR([Your version of gwin32.h is broken and will cause compilation errors when building mono. Please fix it by deleting the line: '$hashmark define ftruncate...' from '$glib_include/glib/gwin32.h' then re-run configure.])
606 fi
607 fi
608 AC_MSG_RESULT(ok)
609 fi
611 AC_ARG_WITH(gc, [ --with-gc=boehm,included,none Defaults to included],[gc=$with_gc],[gc=$gc_default])
613 # Enable support for fast thread-local storage
614 # Some systems have broken support, so we allow to disable it.
615 AC_ARG_WITH(tls, [ --with-tls=__thread,pthread select Thread Local Storage implementation (defaults to __thread)],[],[with_tls=__thread])
617 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
618 # This does not work on some platforms (bug #55253)
619 AC_ARG_WITH(sigaltstack, [ --with-sigaltstack=yes,no enable/disable support for sigaltstack (defaults to yes)],[],[with_sigaltstack=yes])
621 AC_ARG_WITH(static_mono, [ --with-static_mono=yes,no link mono statically to libmono (faster) (defaults to yes)],[],[with_static_mono=yes])
623 if test "x$enable_static" = "xno"; then
624 with_static_mono=no
625 fi
627 if test "x$host_win32" = "xyes"; then
628 # Boehm GC requires the runtime to be in its own dll
629 with_static_mono=no
630 fi
632 AM_CONDITIONAL(STATIC_MONO, test x$with_static_mono != xno)
633 AC_ARG_ENABLE(mcs-build, [ --disable-mcs-build disable the build of the mcs directory], try_mcs_build=$enableval, enable_mcs_build=yes)
635 AC_ARG_WITH(xen_opt, [ --with-xen_opt=yes,no Enable Xen-specific behaviour (defaults to yes)],[],[with_xen_opt=yes])
636 if test "x$with_xen_opt" = "xyes"; then
637 AC_DEFINE(MONO_XEN_OPT, 1, [Xen-specific behaviour])
638 ORIG_CFLAGS=$CFLAGS
639 CFLAGS="$CFLAGS -mno-tls-direct-seg-refs"
640 AC_MSG_CHECKING(for -mno-tls-direct-seg-refs option to gcc)
641 AC_TRY_COMPILE([], [
642 void main () { }
643 ], [
644 AC_MSG_RESULT(yes)
645 # Pass it to libgc as well
646 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC -mno-tls-direct-seg-refs"
647 ], [
648 AC_MSG_RESULT(no)
649 CFLAGS=$ORIG_CFLAGS
650 ])
651 fi
653 AC_ARG_ENABLE(quiet-build, [ --enable-quiet-build Enable quiet runtime build (on by default)], enable_quiet_build=$enableval, enable_quiet_build=yes)
654 AC_ARG_ENABLE(small-config, [ --enable-small-config Enable tweaks to reduce requirements (and capabilities)], enable_small_config=$enableval, enable_small_config=no)
656 if test x$enable_small_config = xyes; then
657 AC_DEFINE(MONO_SMALL_CONFIG,1,[Reduce runtime requirements (and capabilities)])
658 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC -DSMALL_CONFIG"
659 fi
661 if test x$AOT_SUPPORTED != xyes; then
662 AOT_SUPPORTED=no
663 fi
665 AC_ARG_ENABLE(system-aot, [ --enable-system-aot Enable the Ahead-Of-Time compilation of system assemblies during the build (on by default on some platforms)], enable_system_aot=$enableval, enable_system_aot=$AOT_SUPPORTED)
667 DISABLED_FEATURES=none
669 AC_ARG_ENABLE(minimal, [ --enable-minimal=LIST drop support for LIST subsystems.
670 LIST is a comma-separated list from: aot, profiler, decimal, pinvoke, debug,
671 reflection_emit, reflection_emit_save, large_code, logging, com, ssa, generics, attach, jit, simd,soft_debug.],
672 [
673 for feature in `echo "$enable_minimal" | sed -e "s/,/ /g"`; do
674 eval "mono_feature_disable_$feature='yes'"
675 done
676 DISABLED_FEATURES=$enable_minimal
677 disabled="Disabled: $enable_minimal"
678 ],[])
680 AC_DEFINE_UNQUOTED(DISABLED_FEATURES, "$DISABLED_FEATURES", [String of disabled features])
682 if test "x$mono_feature_disable_aot" = "xyes"; then
683 AC_DEFINE(DISABLE_AOT_COMPILER, 1, [Disable AOT Compiler])
684 AC_MSG_NOTICE([Disabled AOT compiler])
685 fi
687 if test "x$mono_feature_disable_profiler" = "xyes"; then
688 AC_DEFINE(DISABLE_PROFILER, 1, [Disable default profiler support])
689 AC_MSG_NOTICE([Disabled support for the profiler])
690 fi
691 AM_CONDITIONAL(DISABLE_PROFILER, test x$mono_feature_disable_profiler = xyes)
693 if test "x$mono_feature_disable_decimal" = "xyes"; then
694 AC_DEFINE(DISABLE_DECIMAL, 1, [Disable System.Decimal support])
695 AC_MSG_NOTICE([Disabled support for decimal])
696 fi
698 if test "x$mono_feature_disable_pinvoke" = "xyes"; then
699 AC_DEFINE(DISABLE_PINVOKE, 1, [Disable P/Invoke support])
700 AC_MSG_NOTICE([Disabled support for P/Invoke])
701 fi
703 if test "x$mono_feature_disable_debug" = "xyes"; then
704 AC_DEFINE(DISABLE_DEBUG, 1, [Disable runtime debugging support])
705 AC_MSG_NOTICE([Disabled support for runtime debugging])
706 fi
708 if test "x$mono_feature_disable_reflection_emit" = "xyes"; then
709 AC_DEFINE(DISABLE_REFLECTION_EMIT, 1, [Disable reflection emit support])
710 mono_feature_disable_reflection_emit_save=yes
711 AC_MSG_NOTICE([Disabled support for Reflection.Emit])
712 fi
714 if test "x$mono_feature_disable_reflection_emit_save" = "xyes"; then
715 AC_DEFINE(DISABLE_REFLECTION_EMIT_SAVE, 1, [Disable assembly saving support in reflection emit])
716 AC_MSG_NOTICE([Disabled support for Reflection.Emit.Save])
717 fi
719 if test "x$mono_feature_disable_large_code" = "xyes"; then
720 AC_DEFINE(DISABLE_LARGE_CODE, 1, [Disable support for huge assemblies])
721 AC_MSG_NOTICE([Disabled support for large assemblies])
722 fi
724 if test "x$mono_feature_disable_logging" = "xyes"; then
725 AC_DEFINE(DISABLE_LOGGING, 1, [Disable support debug logging])
726 AC_MSG_NOTICE([Disabled support for logging])
727 fi
729 if test "x$mono_feature_disable_com" = "xyes"; then
730 AC_DEFINE(DISABLE_COM, 1, [Disable COM support])
731 AC_MSG_NOTICE([Disabled COM support])
732 fi
734 if test "x$mono_feature_disable_ssa" = "xyes"; then
735 AC_DEFINE(DISABLE_SSA, 1, [Disable advanced SSA JIT optimizations])
736 AC_MSG_NOTICE([Disabled SSA JIT optimizations])
737 fi
739 if test "x$mono_feature_disable_generics" = "xyes"; then
740 AC_DEFINE(DISABLE_GENERICS, 1, [Disable generics support])
741 AC_MSG_NOTICE([Disabled Generics Support])
742 fi
744 if test "x$mono_feature_disable_shadowcopy" = "xyes"; then
745 AC_DEFINE(DISABLE_SHADOW_COPY, 1, [Disable Shadow Copy for AppDomains])
746 AC_MSG_NOTICE([Disabled Shadow copy for AppDomains])
747 fi
749 if test "x$mono_feature_disable_portability" = "xyes"; then
750 AC_DEFINE(DISABLE_PORTABILITY, 1, [Disables the IO portability layer])
751 AC_MSG_NOTICE([Disabled IO Portability layer])
752 fi
754 if test "x$mono_feature_disable_attach" = "xyes"; then
755 AC_DEFINE(DISABLE_ATTACH, 1, [Disable agent attach support])
756 AC_MSG_NOTICE([Disabled agent attach])
757 fi
759 if test "x$mono_feature_disable_full_messages" = "xyes"; then
760 AC_DEFINE(DISABLE_FULL_MESSAGES, 1, [Disables building in the full table of WAPI messages])
761 AC_MSG_NOTICE([Disabled full messages for Win32 errors, only core message strings shipped])
762 fi
764 if test "x$mono_feature_disable_verifier" = "xyes"; then
765 AC_DEFINE(DISABLE_VERIFIER, 1, [Disables the verifier])
766 AC_MSG_NOTICE([Disabled the metadata and IL verifiers])
767 fi
769 if test "x$mono_feature_disable_jit" = "xyes"; then
770 AC_DEFINE(DISABLE_JIT, 1, [Disable the JIT, only full-aot mode will be supported by the runtime.])
771 AC_MSG_NOTICE([Disabled the JIT engine, only full AOT will be supported])
772 fi
774 AM_CONDITIONAL(DISABLE_JIT, test x$mono_feature_disable_jit = xyes)
776 if test "x$mono_feature_disable_simd" = "xyes"; then
777 AC_DEFINE(DISABLE_SIMD, 1, [Disable SIMD intrinsics related optimizations.])
778 AC_MSG_NOTICE([Disabled SIMD support])
779 fi
781 if test "x$mono_feature_disable_soft_debug" = "xyes"; then
782 AC_DEFINE(DISABLE_SOFT_DEBUG, 1, [Disable Soft Debugger Agent.])
783 AC_MSG_NOTICE([Disabled Soft Debugger.])
784 fi
786 AC_MSG_CHECKING(for visibility __attribute__)
787 AC_TRY_COMPILE([], [
788 void __attribute__ ((visibility ("hidden"))) doit (void) {}
789 void main () { doit (); }
790 ], [
791 have_visibility_hidden=yes
792 AC_MSG_RESULT(yes)
793 ], [
794 have_visibility_hidden=no
795 AC_MSG_RESULT(no)
796 ])
798 AC_MSG_CHECKING(for deprecated __attribute__)
799 AC_TRY_COMPILE([
800 int doit (void) __attribute__ ((deprecated));
801 int doit (void) { return 0; }
802 ], [
803 return 0;
804 ], [
805 have_deprecated=yes
806 AC_MSG_RESULT(yes)
807 ], [
808 have_deprecated=no
809 AC_MSG_RESULT(no)
810 ])
812 AC_ARG_ENABLE(parallel-mark, [ --enable-parallel-mark Enables GC Parallel Marking], enable_parallel_mark=$enableval, enable_parallel_mark=$parallel_mark)
813 if test x$enable_parallel_mark = xyes; then
814 libgc_configure_args="$libgc_configure_args --enable-parallel-mark"
815 fi
817 LIBGC_CFLAGS=
818 LIBGC_LIBS=
819 LIBGC_STATIC_LIBS=
820 libgc_dir=
821 case "x$gc" in
822 xboehm|xbohem|xyes)
823 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
824 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
826 if test "x$found_boehm" != "xyes"; then
827 AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
828 fi
829 if test "x$gc_headers" != "xyes"; then
830 AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
831 fi
833 AC_DEFINE(HAVE_BOEHM_GC, 1, [Have Boehm GC])
834 AC_SUBST(HAVE_BOEHM_GC)
835 LIBGC_LIBS="-lgc $libdl"
836 LIBGC_STATIC_LIBS="$LIBGC_LIBS"
838 # AC_CHECK_FUNCS does not work for some reason...
839 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
840 if test "x$found_gcj_malloc" = "xyes"; then
841 AC_DEFINE(HAVE_GC_GCJ_MALLOC, 1, [Have GC_gcj_malloc])
842 AC_DEFINE_UNQUOTED(USED_GC_NAME, "System Boehm (with typed GC)", [GC description])
843 else
844 AC_DEFINE_UNQUOTED(USED_GC_NAME, "System Boehm (no typed GC)", [GC description])
845 fi
846 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
847 if test "x$found_gc_enable" = "xyes"; then
848 AC_DEFINE(HAVE_GC_ENABLE, 1, [Have 'GC_enable'])
849 fi
850 ;;
852 xincluded)
853 found_boehm=yes
854 gc_headers=yes
855 use_included_gc=yes
856 libgc_dir=libgc
858 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
859 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
860 LIBGC_STATIC_LIBS='$(top_builddir)/libgc/libmonogc-static.la'
862 AC_DEFINE(HAVE_BOEHM_GC, 1, [Have Boehm GC])
863 AC_SUBST(HAVE_BOEHM_GC)
865 AC_DEFINE(HAVE_GC_H, 1, [Have gc.h])
866 AC_DEFINE(USE_INCLUDED_LIBGC, 1, [Use included libgc])
868 # The included libgc contains GCJ support
869 AC_DEFINE(HAVE_GC_GCJ_MALLOC, 1, [Have GC_gcj_malloc])
870 AC_DEFINE(HAVE_GC_ENABLE, 1, [Have GC_enable])
871 if test x$enable_parallel_mark = xyes; then
872 AC_DEFINE_UNQUOTED(USED_GC_NAME, "Included Boehm (with typed GC and Parallel Mark)", [GC description])
873 else
874 AC_DEFINE_UNQUOTED(USED_GC_NAME, "Included Boehm (with typed GC)", [GC description])
875 fi
876 ;;
878 xsgen)
879 found_boehm=no
880 gc_headers=no
881 use_included_gc=no
882 AC_DEFINE(HAVE_SGEN_GC,1,[Using the simple generational GC.])
883 AC_DEFINE(HAVE_MOVING_COLLECTOR,1,[The GC can move objects.])
884 AC_DEFINE(HAVE_WRITE_BARRIERS,1,[The GC needs write barriers.])
885 AC_DEFINE_UNQUOTED(USED_GC_NAME, "Simple generational", [GC description])
886 ;;
888 xnone)
889 AC_MSG_WARN("Compiling mono without GC.")
890 AC_DEFINE_UNQUOTED(USED_GC_NAME, "none", [GC description])
891 AC_DEFINE(HAVE_NULL_GC,1,[No GC support.])
892 ;;
893 *)
894 AC_MSG_ERROR([Invalid argument to --with-gc.])
895 ;;
896 esac
898 AC_ARG_WITH(large-heap, [ --with-large-heap=yes,no Enable support for GC heaps larger than 3GB (defaults to no)], [large_heap=$withval], [large_heap=no])
899 if test "x$large_heap" = "xyes"; then
900 echo "FOO"
901 CPPFLAGS="$CPPFLAGS -DLARGE_CONFIG"
902 fi
904 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
905 AC_SUBST(LIBGC_CFLAGS)
906 AC_SUBST(LIBGC_LIBS)
907 AC_SUBST(LIBGC_STATIC_LIBS)
908 AC_SUBST(libgc_dir)
910 dnl
911 dnl End of libgc checks
912 dnl
914 dnl *************************************
915 dnl *** Checks for zero length arrays ***
916 dnl *************************************
917 AC_MSG_CHECKING(whether $CC supports zero length arrays)
918 AC_TRY_COMPILE([
919 struct s {
920 int length;
921 char data [0];
922 };
923 ], [], [
924 AC_MSG_RESULT(yes)
925 AC_DEFINE_UNQUOTED(MONO_ZERO_LEN_ARRAY, 0, [Length of zero length arrays])
926 ], [
927 AC_MSG_RESULT(no)
928 AC_DEFINE_UNQUOTED(MONO_ZERO_LEN_ARRAY, 1, [Length of zero length arrays])
929 ])
931 if test x$target_win32 = xno; then
933 dnl hires monotonic clock support
934 AC_SEARCH_LIBS(clock_gettime, rt)
936 dnl dynamic loader support
937 AC_CHECK_FUNC(dlopen, DL_LIB="",
938 AC_CHECK_LIB(dl, dlopen, DL_LIB="-ldl", dl_support=no)
939 )
940 if test x$dl_support = xno; then
941 AC_MSG_WARN([No dynamic loading support available])
942 else
943 LIBS="$LIBS $DL_LIB"
944 AC_DEFINE(HAVE_DL_LOADER,1,[dlopen-based dynamic loader available])
945 dnl from glib's configure.in
946 AC_CACHE_CHECK([for preceeding underscore in symbols],
947 mono_cv_uscore,[
948 AC_TRY_RUN([#include <dlfcn.h>
949 int mono_underscore_test (void) { return 42; }
950 int main() {
951 void *f1 = (void*)0, *f2 = (void*)0, *handle;
952 handle = dlopen ((void*)0, 0);
953 if (handle) {
954 f1 = dlsym (handle, "mono_underscore_test");
955 f2 = dlsym (handle, "_mono_underscore_test");
956 } return (!f2 || f1);
957 }],
958 [mono_cv_uscore=yes],
959 [mono_cv_uscore=no],
960 [])
961 ])
962 if test "x$mono_cv_uscore" = "xyes"; then
963 MONO_DL_NEED_USCORE=1
964 else
965 MONO_DL_NEED_USCORE=0
966 fi
967 AC_SUBST(MONO_DL_NEED_USCORE)
968 AC_CHECK_FUNC(dlerror)
969 fi
971 dnl ******************************************************************
972 dnl *** Checks for the IKVM JNI interface library ***
973 dnl ******************************************************************
974 AC_ARG_WITH(ikvm-native, [ --with-ikvm-native=yes,no build the IKVM JNI interface library (defaults to yes)],[with_ikvm_native=$withval],[with_ikvm_native=yes])
976 ikvm_native_dir=
977 if test x$with_ikvm_native = xyes; then
978 ikvm_native_dir=ikvm-native
979 jdk_headers_found="IKVM Native"
980 fi
982 AC_SUBST(ikvm_native_dir)
984 AC_CHECK_HEADERS(execinfo.h)
986 AC_CHECK_FUNCS(getgrgid_r)
987 AC_CHECK_FUNCS(getgrnam_r)
988 AC_CHECK_FUNCS(getpwnam_r)
989 AC_CHECK_FUNCS(getpwuid_r)
990 AC_CHECK_FUNCS(getresuid)
991 AC_CHECK_FUNCS(setresuid)
992 AC_CHECK_FUNCS(kqueue)
993 AC_CHECK_FUNCS(backtrace_symbols)
994 AC_CHECK_FUNCS(mkstemp)
995 AC_CHECK_FUNCS(mmap)
996 AC_CHECK_FUNCS(madvise)
997 AC_CHECK_FUNCS(getrusage)
998 AC_CHECK_FUNCS(getpriority)
999 AC_CHECK_FUNCS(setpriority)
1000 AC_CHECK_FUNCS(dl_iterate_phdr)
1002 AC_CHECK_FUNCS(sched_setaffinity)
1004 dnl ****************************************************************
1005 dnl *** Check for sched_setaffinity from glibc versions before ***
1006 dnl *** 2.3.4. The older versions of the function only take 2 ***
1007 dnl *** parameters, not 3. ***
1008 dnl *** ***
1009 dnl *** Because the interface change was not made in a minor ***
1010 dnl *** version rev, the __GLIBC__ and __GLIBC_MINOR__ macros ***
1011 dnl *** won't always indicate the interface sched_affinity has. ***
1012 dnl ****************************************************************
1013 AC_MSG_CHECKING(for sched_setaffinity from glibc < 2.3.4)
1014 AC_TRY_COMPILE([#include <sched.h>], [
1015 int main() {
1016 int mask = 1;
1017 sched_setaffinity(0, &mask);
1018 }
1019 ], [
1020 # Yes, we have it...
1021 AC_MSG_RESULT(yes)
1022 AC_DEFINE(GLIBC_BEFORE_2_3_4_SCHED_SETAFFINITY, 1, [Have GLIBC_BEFORE_2_3_4_SCHED_SETAFFINITY])
1023 ], [
1024 # We have the new, three-parameter version
1025 AC_MSG_RESULT(no)
1026 ])
1029 dnl ******************************************************************
1030 dnl *** Check for large file support ***
1031 dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
1032 dnl ******************************************************************
1034 # Check that off_t can represent 2**63 - 1 correctly, working around
1035 # potential compiler bugs. Defines LARGE_FILE_SUPPORT, adds $1 to
1036 # CPPFLAGS and sets $large_offt to yes if the test succeeds
1037 large_offt=no
1038 AC_DEFUN([LARGE_FILES], [
1039 large_CPPFLAGS=$CPPFLAGS
1040 CPPFLAGS="$CPPFLAGS $1"
1041 AC_TRY_RUN([
1042 #include <sys/types.h>
1044 #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
1046 int main(void) {
1047 int big_off_t=((BIG_OFF_T%2147483629==721) &&
1048 (BIG_OFF_T%2147483647==1));
1049 if(big_off_t) {
1050 exit(0);
1051 } else {
1052 exit(1);
1053 }
1054 }
1055 ], [
1056 AC_MSG_RESULT(ok)
1057 AC_DEFINE(HAVE_LARGE_FILE_SUPPORT, 1, [Have large file support])
1058 large_CPPFLAGS="$large_CPPFLAGS $1"
1059 large_offt=yes
1060 ], [
1061 AC_MSG_RESULT(no)
1062 ], "")
1063 CPPFLAGS=$large_CPPFLAGS
1064 ])
1066 AC_MSG_CHECKING(if off_t is 64 bits wide)
1067 LARGE_FILES("")
1068 if test $large_offt = no; then
1069 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
1070 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
1071 fi
1072 if test $large_offt = no; then
1073 AC_MSG_WARN([No 64 bit file size support available])
1074 fi
1076 dnl *****************************
1077 dnl *** Checks for libsocket ***
1078 dnl *****************************
1079 AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
1081 dnl *******************************
1082 dnl *** Checks for MSG_NOSIGNAL ***
1083 dnl *******************************
1084 AC_MSG_CHECKING(for MSG_NOSIGNAL)
1085 AC_TRY_COMPILE([#include <sys/socket.h>], [
1086 int f = MSG_NOSIGNAL;
1087 ], [
1088 # Yes, we have it...
1089 AC_MSG_RESULT(yes)
1090 AC_DEFINE(HAVE_MSG_NOSIGNAL, 1, [Have MSG_NOSIGNAL])
1091 ], [
1092 # We'll have to use signals
1093 AC_MSG_RESULT(no)
1094 ])
1096 dnl *****************************
1097 dnl *** Checks for SOL_IP ***
1098 dnl *****************************
1099 AC_MSG_CHECKING(for SOL_IP)
1100 AC_TRY_COMPILE([#include <netdb.h>], [
1101 int level = SOL_IP;
1102 ], [
1103 # Yes, we have it...
1104 AC_MSG_RESULT(yes)
1105 AC_DEFINE(HAVE_SOL_IP, 1, [Have SOL_IP])
1106 ], [
1107 # We'll have to use getprotobyname
1108 AC_MSG_RESULT(no)
1109 ])
1111 dnl *****************************
1112 dnl *** Checks for SOL_IPV6 ***
1113 dnl *****************************
1114 AC_MSG_CHECKING(for SOL_IPV6)
1115 AC_TRY_COMPILE([#include <netdb.h>], [
1116 int level = SOL_IPV6;
1117 ], [
1118 # Yes, we have it...
1119 AC_MSG_RESULT(yes)
1120 AC_DEFINE(HAVE_SOL_IPV6, 1, [Have SOL_IPV6])
1121 ], [
1122 # We'll have to use getprotobyname
1123 AC_MSG_RESULT(no)
1124 ])
1126 dnl *****************************
1127 dnl *** Checks for SOL_TCP ***
1128 dnl *****************************
1129 AC_MSG_CHECKING(for SOL_TCP)
1130 AC_TRY_COMPILE([#include <netdb.h>], [
1131 int level = SOL_TCP;
1132 ], [
1133 # Yes, we have it...
1134 AC_MSG_RESULT(yes)
1135 AC_DEFINE(HAVE_SOL_TCP, 1, [Have SOL_TCP])
1136 ], [
1137 # We'll have to use getprotobyname
1138 AC_MSG_RESULT(no)
1139 ])
1141 dnl *****************************
1142 dnl *** Checks for IP_PKTINFO ***
1143 dnl *****************************
1144 AC_MSG_CHECKING(for IP_PKTINFO)
1145 AC_TRY_COMPILE([#include <netdb.h>], [
1146 int level = IP_PKTINFO;
1147 ], [
1148 # Yes, we have it...
1149 AC_MSG_RESULT(yes)
1150 AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1151 ], [
1152 AC_MSG_RESULT(no)
1153 ])
1155 dnl *****************************
1156 dnl *** Checks for IPV6_PKTINFO ***
1157 dnl *****************************
1158 AC_MSG_CHECKING(for IPV6_PKTINFO)
1159 AC_TRY_COMPILE([#include <netdb.h>], [
1160 int level = IPV6_PKTINFO;
1161 ], [
1162 # Yes, we have it...
1163 AC_MSG_RESULT(yes)
1164 AC_DEFINE(HAVE_IPV6_PKTINFO, 1, [Have IPV6_PKTINFO])
1165 ], [
1166 AC_MSG_RESULT(no)
1167 ])
1169 dnl **********************************
1170 dnl *** Checks for IP_DONTFRAGMENT ***
1171 dnl **********************************
1172 AC_MSG_CHECKING(for IP_DONTFRAGMENT)
1173 AC_TRY_COMPILE([#include <netdb.h>], [
1174 int level = IP_DONTFRAGMENT;
1175 ], [
1176 # Yes, we have it...
1177 AC_MSG_RESULT(yes)
1178 AC_DEFINE(HAVE_IP_DONTFRAGMENT, 1, [Have IP_DONTFRAGMENT])
1179 ], [
1180 AC_MSG_RESULT(no)
1181 ])
1183 dnl **********************************
1184 dnl *** Checks for IP_MTU_DISCOVER ***
1185 dnl **********************************
1186 AC_MSG_CHECKING(for IP_MTU_DISCOVER)
1187 AC_TRY_COMPILE([#include <netdb.h>], [
1188 int level = IP_MTU_DISCOVER;
1189 ], [
1190 # Yes, we have it...
1191 AC_MSG_RESULT(yes)
1192 AC_DEFINE(HAVE_IP_MTU_DISCOVER, 1, [Have IP_MTU_DISCOVER])
1193 ], [
1194 AC_MSG_RESULT(no)
1195 ])
1197 dnl *********************************
1198 dnl *** Check for struct ip_mreqn ***
1199 dnl *********************************
1200 AC_MSG_CHECKING(for struct ip_mreqn)
1201 AC_TRY_COMPILE([#include <netinet/in.h>], [
1202 struct ip_mreqn mreq;
1203 mreq.imr_address.s_addr = 0;
1204 ], [
1205 # Yes, we have it...
1206 AC_MSG_RESULT(yes)
1207 AC_DEFINE(HAVE_STRUCT_IP_MREQN, 1, [Have struct ip_mreqn])
1208 ], [
1209 # We'll just have to try and use struct ip_mreq
1210 AC_MSG_RESULT(no)
1211 AC_MSG_CHECKING(for struct ip_mreq)
1212 AC_TRY_COMPILE([#include <netinet/in.h>], [
1213 struct ip_mreq mreq;
1214 mreq.imr_interface.s_addr = 0;
1215 ], [
1216 # Yes, we have it...
1217 AC_MSG_RESULT(yes)
1218 AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1, [Have struct ip_mreq])
1219 ], [
1220 # No multicast support
1221 AC_MSG_RESULT(no)
1222 ])
1223 ])
1225 dnl **********************************
1226 dnl *** Check for gethostbyname2_r ***
1227 dnl **********************************
1228 AC_MSG_CHECKING(for gethostbyname2_r)
1229 AC_TRY_LINK([#include <netdb.h>], [
1230 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
1231 ], [
1232 # Yes, we have it...
1233 AC_MSG_RESULT(yes)
1234 AC_DEFINE(HAVE_GETHOSTBYNAME2_R, 1, [Have gethostbyname2_r])
1235 ], [
1236 AC_MSG_RESULT(no)
1237 ])
1239 dnl *****************************
1240 dnl *** Checks for libnsl ***
1241 dnl *****************************
1242 AC_CHECK_FUNC(gethostbyaddr, , AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl"))
1244 AC_CHECK_FUNCS(inet_pton inet_aton)
1246 dnl ***********************************************
1247 dnl *** Checks for size of sockaddr_un.sun_path ***
1248 dnl ***********************************************
1249 # AC_CHECK_SIZEOF can't cope with struct members :-(
1250 AC_MSG_CHECKING(size of sockaddr_un.sun_path)
1251 AC_CACHE_VAL(mono_cv_sizeof_sunpath,
1252 [AC_TRY_RUN([
1253 #include <sys/types.h>
1254 #include <stdio.h>
1255 #include <sys/un.h>
1257 int main(void) {
1258 struct sockaddr_un sock_un;
1259 FILE *f=fopen("conftestval", "w");
1260 if(!f) exit(1);
1261 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
1262 exit(0);
1263 }
1264 ], mono_cv_sizeof_sunpath=`cat conftestval`,
1265 mono_cv_sizeof_sunpath=0,
1266 mono_cv_sizeof_sunpath=0)])dnl
1267 AC_MSG_RESULT($mono_cv_sizeof_sunpath)
1268 AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $mono_cv_sizeof_sunpath, [Sizeof sock_un.sun_path])
1270 dnl *****************************
1271 dnl *** Checks for libxnet ***
1272 dnl *****************************
1273 case "${host}" in
1274 *solaris* )
1275 AC_MSG_CHECKING(for Solaris XPG4 support)
1276 if test -f /usr/lib/libxnet.so; then
1277 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
1278 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
1279 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
1280 LIBS="$LIBS -lxnet"
1281 AC_MSG_RESULT(yes)
1282 else
1283 AC_MSG_RESULT(no)
1284 fi
1286 if test "$GCC" = "yes"; then
1287 CFLAGS="$CFLAGS -Wno-char-subscripts"
1288 fi
1289 ;;
1290 esac
1292 dnl *****************************
1293 dnl *** Checks for libpthread ***
1294 dnl *****************************
1295 # on FreeBSD -STABLE, the pthreads functions all reside in libc_r
1296 # and libpthread does not exist
1297 #
1298 case "${host}" in
1299 *-*-*freebsd*)
1300 AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
1301 ;;
1302 *-*-*openbsd*)
1303 AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
1304 ;;
1305 *)
1306 AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
1307 ;;
1308 esac
1309 AC_CHECK_HEADERS(pthread.h)
1310 AC_CHECK_FUNCS(pthread_mutex_timedlock)
1311 AC_CHECK_FUNCS(pthread_getattr_np pthread_attr_get_np)
1312 AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
1313 AC_TRY_COMPILE([ #include <pthread.h>], [
1314 pthread_mutexattr_t attr;
1315 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
1316 ], [
1317 AC_MSG_RESULT(ok)
1318 ], [
1319 AC_MSG_RESULT(no)
1320 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
1321 AC_DEFINE(USE_MONO_MUTEX, 1, [Use mono_mutex_t])
1322 ])
1323 AC_CHECK_FUNCS(pthread_attr_setstacksize)
1324 AC_CHECK_FUNCS(pthread_attr_getstack pthread_attr_getstacksize)
1325 AC_CHECK_FUNCS(pthread_get_stacksize_np pthread_get_stackaddr_np)
1327 dnl ***********************************
1328 dnl *** Checks for signals
1329 dnl ***********************************
1330 AC_CHECK_HEADERS(signal.h)
1331 AC_CHECK_FUNCS(sigaction)
1333 dnl ***********************************
1334 dnl *** Checks for working __thread ***
1335 dnl ***********************************
1336 AC_MSG_CHECKING(for working __thread)
1337 if test "x$with_tls" != "x__thread"; then
1338 AC_MSG_RESULT(disabled)
1339 else
1340 AC_TRY_RUN([
1341 #include <pthread.h>
1342 __thread int i;
1343 static int res1, res2;
1345 void thread_main (void *arg)
1346 {
1347 i = arg;
1348 sleep (1);
1349 if (arg == 1)
1350 res1 = (i == arg);
1351 else
1352 res2 = (i == arg);
1353 }
1355 int main () {
1356 pthread_t t1, t2;
1358 i = 5;
1360 pthread_create (&t1, NULL, thread_main, 1);
1361 pthread_create (&t2, NULL, thread_main, 2);
1363 pthread_join (t1, NULL);
1364 pthread_join (t2, NULL);
1366 return !(res1 + res2 == 2);
1367 }
1368 ], [
1369 AC_MSG_RESULT(yes)
1370 ], [
1371 AC_MSG_RESULT(no)
1372 with_tls=pthread
1373 ])
1374 fi
1376 dnl **************************************
1377 dnl *** Checks for working sigaltstack ***
1378 dnl **************************************
1379 AC_MSG_CHECKING(for working sigaltstack)
1380 if test "x$with_sigaltstack" != "xyes"; then
1381 AC_MSG_RESULT(disabled)
1382 else
1383 AC_TRY_RUN([
1384 #include <stdio.h>
1385 #include <stdlib.h>
1386 #include <unistd.h>
1387 #include <signal.h>
1388 #include <pthread.h>
1389 #include <sys/wait.h>
1390 #if defined(__FreeBSD__) || defined(__NetBSD__)
1391 #define SA_STACK SA_ONSTACK
1392 #endif
1393 static void
1394 sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
1395 {
1396 exit (0);
1397 }
1399 static void *
1400 loop (void *ignored)
1401 {
1402 char *ptr = NULL;
1404 *ptr = 0;
1405 return NULL;
1406 }
1408 static void
1409 child ()
1410 {
1411 struct sigaction sa;
1412 struct sigaltstack sas;
1413 pthread_t id;
1414 pthread_attr_t attr;
1416 sa.sa_sigaction = sigsegv_signal_handler;
1417 sigemptyset (&sa.sa_mask);
1418 sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
1419 if (sigaction (SIGSEGV, &sa, NULL) == -1) {
1420 perror ("sigaction");
1421 return;
1422 }
1424 sas.ss_sp = malloc (SIGSTKSZ);
1425 sas.ss_size = SIGSTKSZ;
1426 sas.ss_flags = 0;
1427 if (sigaltstack (&sas, NULL) == -1) {
1428 perror ("sigaltstack");
1429 return;
1430 }
1432 pthread_attr_init (&attr);
1433 if (pthread_create(&id, &attr, loop, &attr) != 0) {
1434 printf ("pthread_create\n");
1435 return;
1436 }
1438 sleep (100);
1439 }
1441 int
1442 main ()
1443 {
1444 pid_t son;
1445 int status;
1446 int i;
1448 son = fork ();
1449 if (son == -1) {
1450 return 1;
1451 }
1453 if (son == 0) {
1454 child ();
1455 return 0;
1456 }
1458 for (i = 0; i < 3; ++i) {
1459 sleep (1);
1460 waitpid (son, &status, WNOHANG);
1461 if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
1462 return 0;
1463 }
1465 kill (son, SIGKILL);
1466 return 1;
1467 }
1469 ], [
1470 AC_MSG_RESULT(yes)
1471 AC_DEFINE(HAVE_WORKING_SIGALTSTACK, 1, [Have a working sigaltstack])
1472 ], [
1473 with_sigaltstack=no
1474 AC_MSG_RESULT(no)
1475 ])
1476 fi
1478 dnl ********************************
1479 dnl *** Checks for semaphore lib ***
1480 dnl ********************************
1481 # 'Real Time' functions on Solaris
1482 # posix4 on Solaris 2.6
1483 # pthread (first!) on Linux
1484 AC_SEARCH_LIBS(sem_init, pthread rt posix4)
1486 AC_SEARCH_LIBS(shm_open, pthread rt posix4)
1487 AC_CHECK_FUNCS(shm_open)
1489 dnl ********************************
1490 dnl *** Checks for timezone stuff **
1491 dnl ********************************
1492 AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
1493 AC_TRY_COMPILE([
1494 #include <time.h>
1495 ], [
1496 struct tm tm;
1497 tm.tm_gmtoff = 1;
1498 ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
1499 if test $ac_cv_struct_tm_gmtoff = yes; then
1500 AC_DEFINE(HAVE_TM_GMTOFF, 1, [Have tm_gmtoff])
1501 else
1502 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
1503 AC_TRY_COMPILE([
1504 #include <time.h>
1505 ], [
1506 timezone = 1;
1507 ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
1508 if test $ac_cv_var_timezone = yes; then
1509 AC_DEFINE(HAVE_TIMEZONE, 1, [Have timezone variable])
1510 else
1511 AC_ERROR(unable to find a way to determine timezone)
1512 fi
1513 fi
1515 dnl *********************************
1516 dnl *** Checks for math functions ***
1517 dnl *********************************
1518 LIBS="$LIBS -lm";
1519 if test "x$has_broken_apple_cpp" != "xyes"; then
1520 AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
1521 AC_TRY_LINK([#include <math.h>],
1522 [ finite(0.0); ],
1523 AC_DEFINE(HAVE_FINITE, 1, [Have finite]) AC_MSG_RESULT(yes),
1524 AC_MSG_RESULT(no)))
1525 fi
1526 AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
1527 AC_TRY_LINK([#include <math.h>],
1528 [ isfinite(0.0); ],
1529 AC_DEFINE(HAVE_ISFINITE, 1, [Have isfinite]) AC_MSG_RESULT(yes),
1530 AC_MSG_RESULT(no)))
1532 dnl ****************************************************************
1533 dnl *** Checks for working poll() (macosx defines it but doesn't ***
1534 dnl *** have it in the library (duh)) ***
1535 dnl ****************************************************************
1536 AC_CHECK_FUNCS(poll)
1538 dnl *************************
1539 dnl *** Check for signbit ***
1540 dnl *************************
1541 AC_MSG_CHECKING(for signbit)
1542 AC_TRY_LINK([#include <math.h>], [
1543 int s = signbit(1.0);
1544 ], [
1545 AC_MSG_RESULT(yes)
1546 AC_DEFINE(HAVE_SIGNBIT, 1, [Have signbit])
1547 ], [
1548 AC_MSG_RESULT(no)
1549 ])
1551 dnl **********************************
1552 dnl *** epoll ***
1553 dnl **********************************
1554 AC_CHECK_HEADERS(sys/epoll.h)
1555 haveepoll=no
1556 AC_CHECK_FUNCS(epoll_ctl, [haveepoll=yes], )
1557 if test "x$haveepoll" = "xyes" -a "x$ac_cv_header_sys_epoll_h" = "xyes" ; then
1558 AC_DEFINE(HAVE_EPOLL, 1, [epoll supported])
1559 fi
1561 dnl ******************************
1562 dnl *** Checks for SIOCGIFCONF ***
1563 dnl ******************************
1564 AC_CHECK_HEADERS(sys/ioctl.h)
1565 AC_CHECK_HEADERS(net/if.h)
1566 AC_MSG_CHECKING(for ifreq)
1567 AC_TRY_COMPILE([
1568 #include <stdio.h>
1569 #include <sys/ioctl.h>
1570 #include <net/if.h>
1571 ], [
1572 struct ifconf ifc;
1573 struct ifreq *ifr;
1574 void *x;
1575 ifc.ifc_len = 0;
1576 ifc.ifc_buf = NULL;
1577 x = (void *) &ifr->ifr_addr;
1578 ],[
1579 AC_MSG_RESULT(yes)
1580 AC_DEFINE(HAVE_SIOCGIFCONF, 1, [Can get interface list])
1581 ], [
1582 AC_MSG_RESULT(no)
1583 ])
1584 dnl **********************************
1585 dnl *** Checks for sin_len ***
1586 dnl **********************************
1587 AC_MSG_CHECKING(for sockaddr_in.sin_len)
1588 AC_TRY_COMPILE([
1589 #include <netinet/in.h>
1590 ], [
1591 struct sockaddr_in saddr;
1592 saddr.sin_len = sizeof (saddr);
1593 ],[
1594 AC_MSG_RESULT(yes)
1595 AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [sockaddr_in has sin_len])
1596 ], [
1597 AC_MSG_RESULT(no)
1598 ])
1599 dnl **********************************
1600 dnl *** Checks for sin6_len ***
1601 dnl **********************************
1602 AC_MSG_CHECKING(for sockaddr_in6.sin6_len)
1603 AC_TRY_COMPILE([
1604 #include <netinet/in.h>
1605 ], [
1606 struct sockaddr_in6 saddr6;
1607 saddr6.sin6_len = sizeof (saddr6);
1608 ],[
1609 AC_MSG_RESULT(yes)
1610 AC_DEFINE(HAVE_SOCKADDR_IN6_SIN_LEN, 1, [sockaddr_in6 has sin6_len])
1611 ], [
1612 AC_MSG_RESULT(no)
1613 ])
1614 dnl **********************************
1615 dnl *** Checks for MonoPosixHelper ***
1616 dnl **********************************
1617 AC_CHECK_HEADERS(checklist.h)
1618 AC_CHECK_HEADERS(fstab.h)
1619 AC_CHECK_HEADERS(attr/xattr.h)
1620 AC_CHECK_HEADERS(sys/extattr.h)
1621 AC_CHECK_HEADERS(sys/sendfile.h)
1622 AC_CHECK_HEADERS(sys/statvfs.h)
1623 AC_CHECK_HEADERS(sys/statfs.h)
1624 AC_CHECK_HEADERS(sys/vfstab.h)
1625 AC_CHECK_HEADERS(sys/xattr.h)
1626 AC_CHECK_HEADERS(sys/mman.h)
1627 AC_CHECK_HEADERS(sys/param.h)
1628 AC_CHECK_HEADERS(sys/mount.h)
1629 AC_CHECK_FUNCS(getdomainname)
1630 AC_CHECK_FUNCS(setdomainname)
1631 AC_CHECK_FUNCS(fgetgrent)
1632 AC_CHECK_FUNCS(fgetpwent)
1633 AC_CHECK_FUNCS(fgetpwent)
1634 AC_CHECK_FUNCS(getfsstat)
1635 AC_CHECK_FUNCS(lutimes)
1636 AC_CHECK_FUNCS(mremap)
1637 AC_CHECK_FUNCS(remap_file_pages)
1638 AC_CHECK_FUNCS(posix_fadvise)
1639 AC_CHECK_FUNCS(posix_fallocate)
1640 AC_CHECK_FUNCS(posix_madvise)
1641 AC_CHECK_FUNCS(vsnprintf)
1642 AC_CHECK_FUNCS(sendfile)
1643 AC_CHECK_FUNCS(sethostid)
1644 AC_CHECK_FUNCS(statfs)
1645 AC_CHECK_FUNCS(fstatfs)
1646 AC_CHECK_FUNCS(statvfs)
1647 AC_CHECK_FUNCS(fstatvfs)
1648 AC_CHECK_FUNCS(stime)
1649 AC_CHECK_FUNCS(strerror_r)
1650 AC_CHECK_FUNCS(ttyname_r)
1651 AC_CHECK_SIZEOF(size_t)
1652 AC_CHECK_TYPES([blksize_t], [AC_DEFINE(HAVE_BLKSIZE_T)], ,
1653 [#include <sys/types.h>
1654 #include <sys/stat.h>
1655 #include <unistd.h>])
1656 AC_CHECK_TYPES([blkcnt_t], [AC_DEFINE(HAVE_BLKCNT_T)], ,
1657 [#include <sys/types.h>
1658 #include <sys/stat.h>
1659 #include <unistd.h>])
1660 AC_CHECK_TYPES([suseconds_t], [AC_DEFINE(HAVE_SUSECONDS_T)], ,
1661 [#include <sys/time.h>])
1662 AC_CHECK_TYPES([struct flock], [AC_DEFINE(HAVE_STRUCT_FLOCK)], ,
1663 [#include <unistd.h>
1664 #include <fcntl.h>])
1665 AC_CHECK_TYPES([struct pollfd], [AC_DEFINE(HAVE_STRUCT_POLLFD)], ,
1666 [#include <sys/poll.h>])
1667 AC_CHECK_TYPES([struct stat], [AC_DEFINE(HAVE_STRUCT_STAT)], ,
1668 [#include <sys/types.h>
1669 #include <sys/stat.h>
1670 #include <unistd.h>])
1671 AC_CHECK_TYPES([struct timespec], [AC_DEFINE(HAVE_STRUCT_TIMESPEC)], ,
1672 [#include <time.h>])
1673 AC_CHECK_TYPES([struct timeval], [AC_DEFINE(HAVE_STRUCT_TIMEVAL)], ,
1674 [#include <sys/time.h>
1675 #include <sys/types.h>
1676 #include <utime.h>])
1677 AC_CHECK_TYPES([struct timezone], [AC_DEFINE(HAVE_STRUCT_TIMEZONE)], ,
1678 [#include <sys/time.h>])
1679 AC_CHECK_TYPES([struct utimbuf], [AC_DEFINE(HAVE_STRUCT_UTIMBUF)], ,
1680 [#include <sys/types.h>
1681 #include <utime.h>])
1682 AC_CHECK_MEMBERS(
1683 [struct dirent.d_off, struct dirent.d_reclen, struct dirent.d_type],,,
1684 [#include <sys/types.h>
1685 #include <dirent.h>])
1687 dnl Favour xattr through glibc, but use libattr if we have to
1688 AC_CHECK_FUNC(lsetxattr, ,
1689 AC_CHECK_LIB(attr, lsetxattr, XATTR_LIB="-lattr",)
1690 )
1691 AC_SUBST(XATTR_LIB)
1693 dnl kinfo_proc.kp_proc works on darwin but fails on other simil-bsds
1694 AC_CHECK_MEMBERS(
1695 [struct kinfo_proc.kp_proc],,,
1696 [#include <sys/types.h>
1697 #include <sys/param.h>
1698 #include <sys/sysctl.h>
1699 #include <sys/proc.h>
1700 ])
1702 dnl *********************************
1703 dnl *** Checks for Windows compilation ***
1704 dnl *********************************
1705 AC_CHECK_HEADERS(sys/time.h)
1706 AC_CHECK_HEADERS(sys/param.h)
1707 AC_CHECK_HEADERS(dirent.h)
1709 dnl *********************************
1710 dnl *** Check for Console 2.0 I/O ***
1711 dnl *********************************
1712 AC_CHECK_HEADERS([curses.h])
1713 AC_CHECK_HEADERS([term.h], [], [],
1714 [#if HAVE_CURSES_H
1715 #include <curses.h>
1716 #endif
1717 ])
1718 AC_CHECK_HEADERS([termios.h])
1720 dnl * This is provided in io-layer, but on windows it's only available
1721 dnl * on xp+
1722 AC_DEFINE(HAVE_GETPROCESSID, 1, [Define if GetProcessId is available])
1723 else
1724 jdk_headers_found=no
1725 AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
1726 AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
1727 AC_CHECK_LIB(ole32, main, LIBS="$LIBS -lole32", AC_ERROR(bad mingw install?))
1728 AC_CHECK_LIB(winmm, main, LIBS="$LIBS -lwinmm", AC_ERROR(bad mingw install?))
1729 AC_CHECK_LIB(oleaut32, main, LIBS="$LIBS -loleaut32", AC_ERROR(bad mingw install?))
1730 AC_CHECK_LIB(advapi32, main, LIBS="$LIBS -ladvapi32", AC_ERROR(bad mingw install?))
1731 AC_CHECK_LIB(version, main, LIBS="$LIBS -lversion", AC_ERROR(bad mingw install?))
1733 dnl *********************************
1734 dnl *** Check for struct ip_mreqn ***
1735 dnl *********************************
1736 AC_MSG_CHECKING(for struct ip_mreqn)
1737 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1738 struct ip_mreqn mreq;
1739 mreq.imr_address.s_addr = 0;
1740 ], [
1741 # Yes, we have it...
1742 AC_MSG_RESULT(yes)
1743 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
1744 ], [
1745 # We'll just have to try and use struct ip_mreq
1746 AC_MSG_RESULT(no)
1747 AC_MSG_CHECKING(for struct ip_mreq)
1748 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1749 struct ip_mreq mreq;
1750 mreq.imr_interface.s_addr = 0;
1751 ], [
1752 # Yes, we have it...
1753 AC_MSG_RESULT(yes)
1754 AC_DEFINE(HAVE_STRUCT_IP_MREQ)
1755 ], [
1756 # No multicast support
1757 AC_MSG_RESULT(no)
1758 ])
1759 ])
1760 AC_CHECK_FUNCS(GetProcessId)
1761 fi
1763 dnl socklen_t check
1764 AC_MSG_CHECKING(for socklen_t)
1765 AC_TRY_COMPILE([
1766 #include <sys/types.h>
1767 #include <sys/socket.h>
1768 ],[
1769 socklen_t foo;
1770 ],[
1771 ac_cv_c_socklen_t=yes
1772 AC_DEFINE(HAVE_SOCKLEN_T, 1, [Have socklen_t])
1773 AC_MSG_RESULT(yes)
1774 ],[
1775 AC_MSG_RESULT(no)
1776 ])
1778 AC_MSG_CHECKING(for array element initializer support)
1779 AC_TRY_COMPILE([#include <sys/socket.h>], [
1780 const int array[] = {[1] = 2,};
1781 ], [
1782 # Yes, we have it...
1783 AC_MSG_RESULT(yes)
1784 AC_DEFINE(HAVE_ARRAY_ELEM_INIT,1,[Supports C99 array initialization])
1785 ], [
1786 # We'll have to use signals
1787 AC_MSG_RESULT(no)
1788 ])
1790 AC_CHECK_FUNCS(trunc, , AC_MSG_CHECKING(for trunc in math.h)
1791 # Simply calling trunc (0.0) is no good since gcc will optimize the call away
1792 AC_TRY_LINK([#include <math.h>],
1793 [ static void *p = &trunc; ],
1794 [
1795 AC_DEFINE(HAVE_TRUNC)
1796 AC_MSG_RESULT(yes)
1797 ac_cv_trunc=yes
1798 ],
1799 AC_MSG_RESULT(no)))
1801 if test "x$ac_cv_truncl" != "xyes"; then
1802 AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL, 1, [Has the 'aintl' function]) LIBS="$LIBS -lsunmath"])
1803 fi
1805 AC_CHECK_FUNCS(round)
1806 AC_CHECK_FUNCS(rint)
1808 dnl ****************************
1809 dnl *** Look for /dev/random ***
1810 dnl ****************************
1812 AC_MSG_CHECKING([if usage of random device is requested])
1813 AC_ARG_ENABLE(dev-random,
1814 [ --disable-dev-random disable the use of the random device (enabled by default)],
1815 try_dev_random=$enableval, try_dev_random=yes)
1817 AC_MSG_RESULT($try_dev_random)
1819 case "{$target}" in
1820 *-openbsd*)
1821 NAME_DEV_RANDOM="/dev/srandom"
1822 ;;
1824 dnl Win32 does not have /dev/random, they have their own method...
1826 *-mingw*|*-*-cygwin*)
1827 ac_cv_have_dev_random=no
1828 ;;
1830 dnl Everywhere else, it's /dev/random
1832 *)
1833 NAME_DEV_RANDOM="/dev/random"
1834 ;;
1835 esac
1837 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM", [Name of /dev/random])
1839 dnl Now check if the device actually exists
1841 if test "x$try_dev_random" = "xyes"; then
1842 AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
1843 [if test -r "$NAME_DEV_RANDOM" ; then
1844 ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
1845 if test "x$ac_cv_have_dev_random" = "xyes"; then
1846 AC_DEFINE(HAVE_CRYPT_RNG, 1, [Have /dev/random])
1847 fi
1848 else
1849 AC_MSG_CHECKING(for random device)
1850 ac_cv_have_dev_random=no
1851 AC_MSG_RESULT(has been disabled)
1852 fi
1854 if test "x$host_win32" = "xyes"; then
1855 AC_DEFINE(HAVE_CRYPT_RNG)
1856 fi
1858 if test "x$ac_cv_have_dev_random" = "xno" \
1859 && test "x$host_win32" = "xno"; then
1860 AC_MSG_WARN([[
1861 ***
1862 *** A system-provided entropy source was not found on this system.
1863 *** Because of this, the System.Security.Cryptography random number generator
1864 *** will throw a NotImplemented exception.
1865 ***
1866 *** If you are seeing this message, and you know your system DOES have an
1867 *** entropy collection in place, please contact <crichton@gimp.org> and
1868 *** provide information about the system and how to access the random device.
1869 ***
1870 *** Otherwise you can install either egd or prngd and set the environment
1871 *** variable MONO_EGD_SOCKET to point to the daemon's socket to use that.
1872 ***]])
1873 fi
1875 AC_MSG_CHECKING([if inter-process shared handles are requested])
1876 AC_ARG_ENABLE(shared-handles, [ --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
1877 AC_MSG_RESULT($try_shared_handles)
1878 if test "x$try_shared_handles" != "xyes"; then
1879 AC_DEFINE(DISABLE_SHARED_HANDLES, 1, [Disable inter-process shared handles])
1880 AC_SUBST(DISABLE_SHARED_HANDLES)
1881 fi
1883 AC_ARG_ENABLE(nunit-tests, [ --enable-nunit-tests Run the nunit tests of the class library on 'make check'])
1884 AM_CONDITIONAL(ENABLE_NUNIT_TESTS, [test x$enable_nunit_tests = xyes])
1886 AC_MSG_CHECKING([if big-arrays are to be enabled])
1887 AC_ARG_ENABLE(big-arrays, [ --enable-big-arrays Enable the allocation and indexing of arrays greater than Int32.MaxValue], enable_big_arrays=$enableval, enable_big_arrays=no)
1888 if test "x$enable_big_arrays" = "xyes" ; then
1889 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1890 AC_DEFINE(MONO_BIG_ARRAYS,1,[Enable the allocation and indexing of arrays greater than Int32.MaxValue])
1891 else
1892 AC_MSG_ERROR([The allocation and indexing of arrays greater than Int32.MaxValue is not supported on this platform.])
1893 fi
1894 fi
1895 AC_MSG_RESULT($enable_big_arrays)
1897 dnl **************
1898 dnl *** DTRACE ***
1899 dnl **************
1901 AC_ARG_ENABLE(dtrace,[ --enable-dtrace Enable DTrace probes], enable_dtrace=$enableval, enable_dtrace=$has_dtrace)
1903 if test "x$enable_dtrace" = "xyes"; then
1904 if test "x$has_dtrace" = "xno"; then
1905 AC_MSG_ERROR([DTrace probes are not supported on this platform.])
1906 fi
1907 AC_PATH_PROG(DTRACE, [dtrace], [no], [$PATH:/usr/sbin])
1908 if test "x$DTRACE" = "xno"; then
1909 AC_MSG_RESULT([dtrace utility not found, dtrace support disabled.])
1910 enable_dtrace=no
1911 elif ! $DTRACE -h -s $srcdir/data/mono.d > /dev/null 2>&1; then
1912 AC_MSG_RESULT([dtrace doesn't support -h option, dtrace support disabled.])
1913 enable_dtrace=no
1914 fi
1915 fi
1917 dtrace_g=no
1918 if test "x$enable_dtrace" = "xyes"; then
1919 AC_DEFINE(ENABLE_DTRACE, 1, [Enable DTrace probes])
1920 DTRACEFLAGS=
1921 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1922 case "$host" in
1923 powerpc-*-darwin*)
1924 DTRACEFLAGS="-arch ppc64"
1925 ;;
1926 i*86-*-darwin*)
1927 DTRACEFLAGS="-arch x86_64"
1928 ;;
1929 *)
1930 DTRACEFLAGS=-64
1931 ;;
1932 esac
1933 else
1934 case "$host" in
1935 powerpc-*-darwin*)
1936 DTRACEFLAGS="-arch ppc"
1937 ;;
1938 i*86-*-darwin*)
1939 DTRACEFLAGS="-arch i386"
1940 ;;
1941 *)
1942 DTRACEFLAGS=-32
1943 ;;
1944 esac
1945 fi
1946 AC_SUBST(DTRACEFLAGS)
1947 case "$host" in
1948 *-*-solaris*)
1949 dtrace_g=yes
1950 ;;
1951 esac
1952 AC_CHECK_HEADERS([sys/sdt.h])
1953 fi
1954 AM_CONDITIONAL(ENABLE_DTRACE, [test x$enable_dtrace = xyes])
1955 AM_CONDITIONAL(DTRACE_G_REQUIRED, [test x$dtrace_g = xyes])
1957 dnl **************
1958 dnl *** LLVM ***
1959 dnl **************
1961 AC_ARG_ENABLE(llvm,[ --enable-llvm Enable the experimental LLVM back-end], enable_llvm=$enableval, enable_llvm=no)
1963 if test "x$enable_llvm" = "xyes"; then
1964 AC_PATH_PROG(LLVM_CONFIG, llvm-config, no)
1965 if test "x$LLVM_CONFIG" = "xno"; then
1966 AC_MSG_ERROR([llvm-config not found.])
1967 fi
1969 # The output of --cflags seems to include optimizations flags too
1970 LLVM_CFLAGS=`$LLVM_CONFIG --cflags | sed -e 's/-O2//g' | sed -e 's/-O0//g' | sed -e 's/-fomit-frame-pointer//g' | sed -e 's/-fPIC//g'`
1971 # LLVM is compiled with -fno-rtti, so we need this too, since our classes inherit
1972 # from LLVM classes.
1973 LLVM_CXXFLAGS="`$LLVM_CONFIG --cxxflags` -fno-rtti"
1974 LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1975 LLVM_LIBS=`$LLVM_CONFIG --libs core bitwriter jit x86codegen`
1976 LLVM_LIBS="$LLVM_LDFLAGS $LLVM_LIBS -lstdc++"
1978 # Should be something like '2.6' or '2.7svn'
1979 llvm_version=`$LLVM_CONFIG --version`
1980 major_version=`echo $llvm_version | cut -c 1`
1981 minor_version=`echo $llvm_version | cut -c 3`
1983 AC_DEFINE_UNQUOTED(LLVM_MAJOR_VERSION, $major_version, [Major version of LLVM libraries])
1984 AC_DEFINE_UNQUOTED(LLVM_MINOR_VERSION, $minor_version, [Minor version of LLVM libraries])
1986 # Have to pass these on the command line since mini-llvm-cpp.h already includes
1987 # llvm's config.h
1988 LLVM_CXXFLAGS="$LLVM_CXXFLAGS -DLLVM_MAJOR_VERSION=$major_version -DLLVM_MINOR_VERSION=$minor_version"
1990 AC_SUBST(LLVM_CFLAGS)
1991 AC_SUBST(LLVM_CXXFLAGS)
1992 AC_SUBST(LLVM_LIBS)
1993 AC_SUBST(LLVM_LDFLAGS)
1994 AC_DEFINE(ENABLE_LLVM, 1, [Enable the LLVM back end])
1995 fi
1997 AM_CONDITIONAL(ENABLE_LLVM, [test x$enable_llvm = xyes])
1999 TARGET="unknown"
2000 ACCESS_UNALIGNED="yes"
2002 JIT_SUPPORTED=no
2003 INTERP_SUPPORTED=no
2004 LIBC="libc.so.6"
2005 INTL="libc.so.6"
2006 SQLITE="libsqlite.so.0"
2007 SQLITE3="libsqlite3.so.0"
2008 X11="libX11.so"
2010 sizeof_register="SIZEOF_VOID_P"
2012 jit_wanted=false
2013 interp_wanted=false
2014 case "$host" in
2015 # mips-sgi-irix5.* | mips-sgi-irix6.*)
2016 # TARGET=MIPS;
2017 # ACCESS_UNALIGNED="no"
2018 # ;;
2019 mips*)
2020 TARGET=MIPS;
2021 arch_target=mips;
2022 ACCESS_UNALIGNED="no"
2023 JIT_SUPPORTED=yes
2024 jit_wanted=true
2026 AC_MSG_CHECKING(for mips n32)
2027 AC_TRY_COMPILE([], [
2028 void main () {
2029 #if _MIPS_SIM != _ABIN32
2030 #error Not mips n32
2031 #endif
2032 }
2033 ],[
2034 AC_MSG_RESULT(yes)
2035 sizeof_register=8
2036 ],[
2037 AC_MSG_RESULT(no)
2038 ])
2039 ;;
2040 i*86-*-*)
2041 TARGET=X86;
2042 arch_target=x86;
2043 JIT_SUPPORTED=yes
2044 jit_wanted=true
2045 case $host_os in
2046 solaris*)
2047 LIBC="libc.so"
2048 INTL="libintl.so"
2049 if test "x$ac_cv_sizeof_void_p" = "x8"; then
2050 TARGET=AMD64
2051 arch_target=amd64
2052 fi
2054 # On solaris 10 x86, gcc prints a warning saying 'visibility attribute not supported on this configuration; ignored', but linking fails. A test case:
2055 # int astruct __attribute__ ((visibility ("hidden")));
2056 # void foo ()
2057 # {
2058 # void *p = &astruct;
2059 # }
2060 # gcc -fPIC --shared -o libfoo.so foo.c
2061 # yields:
2062 # foo.c:6: warning: visibility attribute not supported in this configuration; ignored
2063 # ld: fatal: relocation error: R_386_GOTOFF: file /var/tmp//ccxYR96k.o: symbol astruct: relocation must bind locally
2064 have_visibility_hidden=no
2065 ;;
2066 cygwin*)
2067 have_visibility_hidden=no
2068 ;;
2069 haiku*)
2070 LIBC=libroot.so
2071 ;;
2072 esac
2073 ;;
2074 x86_64-*-* | amd64-*-*)
2075 TARGET=AMD64;
2076 arch_target=amd64;
2077 JIT_SUPPORTED=yes
2078 jit_wanted=true
2079 ;;
2080 ia64-*-*)
2081 TARGET=IA64
2082 arch_target=ia64
2083 ACCESS_UNALIGNED="no"
2084 JIT_SUPPORTED=yes
2085 jit_wanted=true
2086 LIBC="libc.so.6.1"
2087 INTL="libc.so.6.1"
2088 AC_CHECK_LIB(unwind, _U_dyn_register, [], [AC_MSG_ERROR(library libunwind not found)])
2089 libmono_ldflags="-lunwind"
2090 ;;
2091 sparc*-*-*)
2092 if test "x$ac_cv_sizeof_void_p" = "x8"; then
2093 TARGET=SPARC64
2094 else
2095 TARGET=SPARC
2096 fi
2097 arch_target=sparc;
2098 JIT_SUPPORTED=yes
2099 ACCESS_UNALIGNED="no"
2100 case $host_os in
2101 linux*) ;;
2102 *)
2103 LIBC="libc.so"
2104 INTL="libintl.so"
2105 esac
2106 jit_wanted=true
2107 if test x"$GCC" = xyes; then
2108 # We don't support v8 cpus
2109 CFLAGS="$CFLAGS -Wno-cast-align -mcpu=v9"
2110 fi
2111 if test x"$AR" = xfalse; then
2112 AC_MSG_ERROR([The required utility 'ar' is not found in your PATH. Usually it can be found in /usr/ccs/bin.])
2113 fi
2114 ;;
2115 alpha*-*-linux* | alpha*-*-osf*)
2116 TARGET=ALPHA;
2117 ACCESS_UNALIGNED="no"
2118 JIT_SUPPORTED=yes
2119 jit_wanted=true
2120 arch_target=alpha;
2121 CFLAGS="$CFLAGS -mieee -O0"
2122 case $host_os in
2123 linux*)
2124 LIBC="libc.so.6.1"
2125 INTL="libc.so.6.1"
2126 esac
2127 ;;
2128 *-mingw*|*-*-cygwin*)
2129 # When this is enabled, it leads to very strange crashes at runtime (gcc-3.4.4)
2130 have_visibility_hidden=no
2131 INTL="intl"
2132 ;;
2133 hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
2134 TARGET=HPPA;
2135 arch_target=hppa;
2136 LIBC="libc.sl"
2137 ACCESS_UNALIGNED="no"
2138 INTERP_SUPPORTED=yes
2139 interp_wanted=true
2140 ;;
2141 hppa*linux*)
2142 TARGET=HPPA;
2143 arch_target=hppa;
2144 ACCESS_UNALIGNED="no"
2145 JIT_SUPPORTED=yes
2146 jit_wanted=true
2147 ;;
2148 macppc-*-openbsd* | powerpc*-*-linux* | powerpc-*-openbsd* | \
2149 powerpc-*-sysv* | powerpc-*-darwin* | powerpc-*-netbsd* | powerpc-*-freebsd* )
2150 if test "x$ac_cv_sizeof_void_p" = "x8"; then
2151 TARGET=POWERPC64;
2152 CPPFLAGS="$CPPFLAGS -D__mono_ppc__ -D__mono_ppc64__"
2153 CFLAGS="$CFLAGS -mminimal-toc"
2154 else
2155 TARGET=POWERPC;
2156 CPPFLAGS="$CPPFLAGS -D__mono_ppc__"
2157 fi
2158 arch_target=ppc;
2159 JIT_SUPPORTED=yes
2160 jit_wanted=true
2161 ;;
2162 arm*-darwin*)
2163 TARGET=ARM;
2164 arch_target=arm;
2165 ACCESS_UNALIGNED="no"
2166 JIT_SUPPORTED=yes
2167 CPPFLAGS="$CPPFLAGS -DARM_FPU_NONE=1"
2168 jit_wanted=true
2169 ;;
2170 arm*-linux*)
2171 TARGET=ARM;
2172 arch_target=arm;
2173 ACCESS_UNALIGNED="no"
2174 JIT_SUPPORTED=yes
2175 jit_wanted=true
2176 ;;
2177 s390-*-linux*)
2178 TARGET=S390;
2179 arch_target=s390;
2180 ACCESS_UNALIGNED="yes"
2181 JIT_SUPPORTED=yes
2182 jit_wanted=true
2183 # Required CFLAGS for s390[x]. USE_STRING_INLINES is automatic with gcc 4.1
2184 CFLAGS="$CFLAGS -mbackchain -D__USE_STRING_INLINES"
2185 ;;
2186 s390x-*-linux*)
2187 TARGET=S390x;
2188 arch_target=s390x;
2189 ACCESS_UNALIGNED="yes"
2190 JIT_SUPPORTED=yes
2191 jit_wanted=true
2192 CFLAGS="$CFLAGS -mbackchain -D__USE_STRING_INLINES"
2193 ;;
2194 esac
2196 if test "x$host" != "x$target"; then
2197 case "$target" in
2198 powerpc64-ps3-linux-gnu)
2199 TARGET=POWERPC64
2200 arch_target=powerpc64
2201 AC_DEFINE(TARGET_PS3, 1, [...])
2202 AC_DEFINE(MONO_CROSS_COMPILE,1,[The runtime is compiled for cross-compiling mode])
2203 # It would be better to just use TARGET_POWERPC64, but lots of code already
2204 # uses this define
2205 AC_DEFINE(__mono_ppc64__, 1, [...])
2206 AC_DEFINE(__mono_ilp32__, 1, [64 bit mode with 4 byte longs and pointers])
2207 sizeof_register=8
2208 target_byte_order=G_BIG_ENDIAN
2209 ;;
2211 powerpc64-xbox360-linux-gnu)
2212 TARGET=POWERPC64
2213 arch_target=powerpc64
2214 AC_DEFINE(TARGET_XBOX360, 1, [...])
2215 AC_DEFINE(MONO_CROSS_COMPILE,1,[The runtime is compiled for cross-compiling mode])
2216 # It would be better to just use TARGET_POWERPC64, but lots of code already
2217 # uses this define
2218 sizeof_register=8
2219 target_byte_order=G_BIG_ENDIAN
2220 ;;
2221 *)
2222 AC_MSG_ERROR([Cross compiling is only supported for targets matching 'powerpc64-{ps3,xbox360}-linux-gnu'])
2223 esac
2224 fi
2226 # FIXME: Define the others as well
2227 case "$TARGET" in
2228 X86)
2229 AC_DEFINE(TARGET_X86, 1, [...])
2230 ;;
2231 AMD64)
2232 AC_DEFINE(TARGET_AMD64, 1, [...])
2233 ;;
2234 ARM)
2235 AC_DEFINE(TARGET_ARM, 1, [...])
2236 ;;
2237 POWERPC)
2238 AC_DEFINE(TARGET_POWERPC, 1, [...])
2239 ;;
2240 POWERPC64)
2241 AC_DEFINE(TARGET_POWERPC, 1, [...])
2242 AC_DEFINE(TARGET_POWERPC64, 1, [...])
2243 ;;
2244 esac
2246 if test "x$sizeof_register" = "x4"; then
2247 AC_DEFINE(SIZEOF_REGISTER,4,[size of machine integer registers])
2248 elif test "x$sizeof_register" = "x8"; then
2249 AC_DEFINE(SIZEOF_REGISTER,8,[size of machine integer registers])
2250 else
2251 AC_DEFINE(SIZEOF_REGISTER,SIZEOF_VOID_P,[size of machine integer registers])
2252 fi
2254 if test "x$target_byte_order" = "xG_BIG_ENDIAN"; then
2255 AC_DEFINE(TARGET_BYTE_ORDER,G_BIG_ENDIAN,[byte order of target])
2256 elif test "x$target_byte_order" = "xG_LITTLE_ENDIAN"; then
2257 AC_DEFINE(TARGET_BYTE_ORDER,G_LITTLE_ENDIAN,[byte order of target])
2258 else
2259 AC_DEFINE(TARGET_BYTE_ORDER,G_BYTE_ORDER,[byte order of target])
2260 fi
2262 if test "x$have_visibility_hidden" = "xyes"; then
2263 AC_DEFINE(HAVE_VISIBILITY_HIDDEN, 1, [Support for the visibility ("hidden") attribute])
2264 fi
2266 if test "x$have_deprecated" = "xyes"; then
2267 AC_DEFINE(HAVE_DEPRECATED, 1, [Support for the deprecated attribute])
2268 fi
2270 AC_ARG_WITH(jit, [ --with-jit=yes,no If you want to build scripts that default to the JIT (defaults to no)],[
2271 if test x$withval = xyes; then
2272 jit_wanted=true
2273 else
2274 jit_wanted=false
2275 fi
2276 ])
2278 AC_ARG_WITH(interp, [ --with-interp=yes,no If you want to build scripts that default to the interpreter (defaults to no)],[
2279 if test x$withval = xyes; then
2280 interp_wanted=true
2281 else
2282 interp_wanted=false
2283 fi
2284 ])
2286 USEJIT=false
2287 if test x$JIT_SUPPORTED = xyes; then
2288 if $jit_wanted; then
2289 USEJIT=true
2290 jit_status="Building and using the JIT"
2291 else
2292 if $interp_wanted; then
2293 jit_status="Building the JIT, defaulting to the interpreter"
2294 else
2295 AC_ERROR(No JIT or interpreter support available or selected.)
2296 fi
2297 fi
2298 else
2299 if test x$interp_wanted = xtrue; then
2300 jit_status="interpreter"
2301 else
2302 AC_ERROR(No JIT or interpreter support available or selected.)
2303 fi
2304 fi
2306 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
2308 libsuffix=".so"
2310 case "$host" in
2311 *-*-darwin*)
2312 libsuffix=".dylib"
2313 LIBC="libc.dylib"
2314 INTL="libintl.dylib"
2315 SQLITE="libsqlite.0.dylib"
2316 SQLITE3="libsqlite3.0.dylib"
2317 X11="libX11.dylib"
2318 ;;
2319 *-*-*netbsd*)
2320 LIBC="libc.so.12"
2321 INTL="libintl.so.0"
2322 ;;
2323 *-*-*freebsd*)
2324 LIBC="libc.so"
2325 INTL="libintl.so"
2326 ;;
2327 *-*-*openbsd*)
2328 LIBC="libc.so"
2329 INTL="libintl.so"
2330 ;;
2331 *-*-*linux*)
2332 AC_PATH_X
2333 AC_MSG_CHECKING(for the soname of libX11.so)
2334 for i in $x_libraries /usr/lib /usr/lib64; do
2335 for r in 4 5 6; do
2336 if test -f $i/libX11.so.$r; then
2337 X11=libX11.so.$r
2338 AC_MSG_RESULT($X11)
2339 fi
2340 done
2341 done
2343 if test "x$X11" = "xlibX11.so"; then
2344 AC_MSG_WARN([Could not find X development libs. Do you have the -devel package installed? WinForms may not work...]);
2345 fi
2346 ;;
2347 esac
2350 AC_SUBST(libsuffix)
2352 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86"; then
2353 if test "x$with_tls" = "x__thread"; then
2354 #
2355 # On some linux distributions, TLS works in executables, but linking
2356 # against a shared library containing TLS fails with:
2357 # undefined reference to `__tls_get_addr'
2358 #
2359 rm -f conftest.c conftest.so conftest
2360 echo "static __thread int foo; void main () { foo = 5; }" > conftest.c
2361 $CC -fPIC --shared -o conftest.so conftest.c > /dev/null 2>&1
2362 $CC -o conftest conftest.so > /dev/null 2>&1
2363 if test ! -f conftest; then
2364 AC_MSG_WARN([Disabling usage of __thread.]);
2365 with_tls=pthread
2366 fi
2367 rm -f conftest.c conftest.so conftest
2368 fi
2369 fi
2371 mono_debugger_supported=no
2372 AC_ARG_ENABLE(mono-debugger, [ --disable-mono-debugger disable support for the mdb debugger], try_mono_debugger=$enableval, try_mono_debugger=yes)
2373 if test "x$try_mono_debugger" = "xyes"; then
2374 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86" -o "x$TARGET" = "xALPHA"; then
2375 if test x$use_included_gc = xyes; then
2376 case "$host" in
2377 *-*-*linux*)
2378 mono_debugger_supported=yes
2379 ;;
2380 *86-apple-darwin*)
2381 mono_debugger_supported=yes
2382 ;;
2383 esac
2384 fi
2385 fi
2386 fi
2388 AC_MSG_CHECKING(if the Mono Debugger is supported on this platform)
2389 if test "x$mono_debugger_supported" = "xyes"; then
2390 AC_DEFINE(MONO_DEBUGGER_SUPPORTED,1,[The Mono Debugger is supported on this platform])
2391 fi
2392 AC_MSG_RESULT($mono_debugger_supported)
2393 AM_CONDITIONAL(MONO_DEBUGGER_SUPPORTED, test x$mono_debugger_supported = xyes)
2395 if test "x$with_tls" = "x__thread"; then
2396 AC_DEFINE(HAVE_KW_THREAD, 1, [Have __thread keyword])
2397 # Pass the information to libgc
2398 CPPFLAGS="$CPPFLAGS -DUSE_COMPILER_TLS"
2399 AC_MSG_CHECKING(if the tls_model attribute is supported)
2400 AC_TRY_COMPILE([static __thread int foo __attribute__((tls_model("initial-exec")));], [
2401 ], [
2402 AC_MSG_RESULT(yes)
2403 AC_DEFINE(HAVE_TLS_MODEL_ATTR, 1, [tld_model available])
2404 ], [
2405 AC_MSG_RESULT(no)
2406 ])
2407 fi
2409 if test ${TARGET} = ARM && test x$cross_compiling = xno && test x$enable_mcs_build != xno; then
2410 dnl ******************************************
2411 dnl *** Check to see what FPU is available ***
2412 dnl ******************************************
2413 AC_MSG_CHECKING(which FPU to use)
2415 AC_TRY_COMPILE([], [
2416 __asm__ ("ldfd f0, [r0]");
2417 ], fpu=FPA, fpu=NONE)
2419 AC_MSG_RESULT($fpu)
2420 CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu=1"
2421 unset fpu
2422 fi
2424 if test ${TARGET} = unknown; then
2425 CPPFLAGS="$CPPFLAGS -DNO_PORT"
2426 AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
2427 fi
2429 if test ${ACCESS_UNALIGNED} = no; then
2430 CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
2431 fi
2433 case "x$gc" in
2434 xincluded)
2435 # Pass CPPFLAGS to libgc configure
2436 # We should use a separate variable for this to avoid passing useless and
2437 # potentially problematic defines to libgc (like -D_FILE_OFFSET_BITS=64)
2438 # This should be executed late so we pick up the final version of CPPFLAGS
2439 # The problem with this approach, is that during a reconfigure, the main
2440 # configure scripts gets invoked with these arguments, so we use separate
2441 # variables understood by libgc's configure to pass CPPFLAGS and CFLAGS.
2442 LIBGC_CPPFLAGS=$CPPFLAGS
2443 if test x$TARGET = xSPARC -o x$TARGET = xSPARC64; then
2444 LIBGC_CPPFLAGS=`echo $LIBGC_CPPFLAGS | sed -e 's/-D_FILE_OFFSET_BITS=64//g'`
2445 fi
2446 ac_configure_args="$ac_configure_args --disable-embed-check --with-libgc-threads=$libgc_threads $libgc_configure_args \"CPPFLAGS_FOR_LIBGC=$LIBGC_CPPFLAGS\" \"CFLAGS_FOR_LIBGC=$CFLAGS_FOR_LIBGC\""
2447 AC_CONFIG_SUBDIRS(libgc)
2448 ;;
2449 esac
2451 #AC_ARG_WITH(profile2, [ --with-profile2=yes,no If you want to install the 2.0 FX (defaults to yes)], [], [with_profile2=yes])
2452 AC_ARG_WITH(profile4, [ --with-profile4=yes,no If you want to install the 4.0 FX (defaults to yes)], [], [with_profile4=yes])
2453 AC_ARG_WITH(monotouch, [ --with-monotouch=yes,no If you want to build the raw MonoTouch 2.1 assemblies (defaults to no)], [], [with_monotouch=no])
2455 OPROFILE=no
2456 AC_ARG_WITH(oprofile,[ --with-oprofile=no,<oprofile install dir> Enable oprofile support (defaults to no)],[
2457 if test x$with_oprofile != xno; then
2458 oprofile_include=$with_oprofile/include
2459 if test ! -f $oprofile_include/opagent.h; then
2460 AC_MSG_ERROR([oprofile include file not found at $oprofile_include/opagent.h])
2461 fi
2462 OPROFILE=yes
2463 OPROFILE_CFLAGS="-I$oprofile_include"
2464 OPROFILE_LIBS="-L$with_oprofile/lib/oprofile -lopagent"
2465 AC_DEFINE(HAVE_OPROFILE,1,[Have oprofile support])
2466 fi
2467 ])
2469 MALLOC_MEMPOOLS=no
2470 AC_ARG_WITH(malloc_mempools,[ --with-malloc-mempools=yes,no Use malloc for each single mempool allocation (only for runtime debugging, defaults to no)],[
2471 if test x$with_malloc_mempools = xyes; then
2472 MALLOC_MEMPOOLS=yes
2473 AC_DEFINE(USE_MALLOC_FOR_MEMPOOLS,1,[Use malloc for each single mempool allocation])
2474 fi
2475 ])
2478 DISABLE_MCS_DOCS=no
2479 AC_ARG_WITH(mcs_docs,[ --with-mcs-docs=yes,no If you want to build the documentation under mcs (defaults to yes)],[
2480 if test x$with_mcs_docs != xyes; then
2481 DISABLE_MCS_DOCS=yes
2482 fi
2483 ])
2485 MOONLIGHT=no
2486 AC_ARG_WITH(moonlight, [ --with-moonlight=yes,no If you want to build Mono for Moonlight (defaults to no - the resulting mono build is useless for anything but moonlight)],[
2487 if test x$with_moonlight = xyes; then
2488 MOONLIGHT=yes
2489 AC_DEFINE(MOONLIGHT,1,[Building for Moonlight])
2490 fi
2491 ], [with_moonlight=no])
2495 dnl
2496 dnl Consistency settings
2497 dnl
2498 if test x$cross_compiling = xyes -o x$enable_mcs_build = xno; then
2499 DISABLE_MCS_DOCS=yes
2500 fi
2502 if test x$DISABLE_MCS_DOCS = xyes; then
2503 docs_dir=""
2504 else
2505 docs_dir=docs
2506 fi
2507 AC_SUBST(docs_dir)
2509 AM_CONDITIONAL(HAVE_OPROFILE, test x$OPROFILE = xyes)
2510 AC_SUBST(OPROFILE_CFLAGS)
2511 AC_SUBST(OPROFILE_LIBS)
2513 libmono_ldflags="$libmono_ldflags $LIBS"
2515 AM_CONDITIONAL(MOONLIGHT, [test "x$with_moonlight" = xyes])
2516 AM_CONDITIONAL(INSTALL_4_0, [test "x$with_profile4" = xyes])
2517 AM_CONDITIONAL(INSTALL_MONOTOUCH, [test "x$with_monotouch" = xyes])
2519 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
2520 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
2521 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
2522 AM_CONDITIONAL(SPARC64, test x$TARGET = xSPARC64)
2523 AM_CONDITIONAL(X86, test x$TARGET = xX86)
2524 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
2525 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
2526 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
2527 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
2528 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
2529 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
2530 AM_CONDITIONAL(POWERPC64, test x$TARGET = xPOWERPC64)
2531 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
2532 AM_CONDITIONAL(S390, test x$TARGET = xS390)
2533 AM_CONDITIONAL(S390x, test x$TARGET = xS390x)
2534 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
2536 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
2537 AM_CONDITIONAL(INTERP_SUPPORTED, test x$interp_wanted = xtrue)
2538 AM_CONDITIONAL(INCLUDED_LIBGC, test x$gc = xincluded)
2540 AC_SUBST(LIBC)
2541 AC_SUBST(INTL)
2542 AC_SUBST(SQLITE)
2543 AC_SUBST(SQLITE3)
2544 AC_SUBST(X11)
2545 AC_DEFINE_UNQUOTED(ARCHITECTURE,"$arch_target",[The architecture this is running on])
2546 AC_SUBST(arch_target)
2547 AC_SUBST(CFLAGS)
2548 AC_SUBST(CPPFLAGS)
2549 AC_SUBST(LDFLAGS)
2551 mono_build_root=`pwd`
2552 AC_SUBST(mono_build_root)
2554 if test x$USEJIT = xtrue; then
2555 mono_runtime=mono/mini/mono
2556 else
2557 mono_runtime=mono/interpreter/mint
2558 fi
2559 AC_SUBST(mono_runtime)
2561 mono_cfg_root=$mono_build_root/runtime
2562 if test x$host_win32 = xyes; then
2563 if test "x$cross_compiling" = "xno"; then
2564 mono_cfg_dir=`cygpath -w -a $mono_cfg_root`\\etc
2565 else
2566 mono_cfg_dir=`echo $mono_cfg_root | tr '/' '\\'`\\etc
2567 fi
2568 else
2569 mono_cfg_dir=$mono_cfg_root/etc
2570 fi
2571 AC_SUBST(mono_cfg_dir)
2573 AC_CONFIG_FILES([po/mcs/Makefile.in])
2575 AC_CONFIG_FILES([runtime/mono-wrapper],[chmod +x runtime/mono-wrapper])
2576 AC_CONFIG_FILES([runtime/monodis-wrapper],[chmod +x runtime/monodis-wrapper])
2578 AC_CONFIG_COMMANDS([runtime/etc/mono/1.0/machine.config],
2579 [ depth=../../../..
2580 case $srcdir in
2581 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2582 .) reldir=$depth ;;
2583 *) reldir=$depth/$srcdir ;;
2584 esac
2585 $ac_aux_dir/install-sh -d runtime/etc/mono/1.0
2586 cd runtime/etc/mono/1.0
2587 rm -f machine.config
2588 $LN_S $reldir/data/net_1_1/machine.config machine.config
2589 cd $depth
2590 ],[LN_S='$LN_S'])
2592 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/machine.config],
2593 [ depth=../../../..
2594 case $srcdir in
2595 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2596 .) reldir=$depth ;;
2597 *) reldir=$depth/$srcdir ;;
2598 esac
2599 $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
2600 cd runtime/etc/mono/2.0
2601 rm -f machine.config
2602 $LN_S $reldir/data/net_2_0/machine.config machine.config
2603 cd $depth
2604 ],[LN_S='$LN_S'])
2606 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/web.config],
2607 [ depth=../../../..
2608 case $srcdir in
2609 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2610 .) reldir=$depth ;;
2611 *) reldir=$depth/$srcdir ;;
2612 esac
2613 $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
2614 cd runtime/etc/mono/2.0
2615 rm -f web.config
2616 $LN_S $reldir/data/net_2_0/web.config web.config
2617 cd $depth
2618 ],[LN_S='$LN_S'])
2620 AC_CONFIG_COMMANDS([runtime/etc/mono/browscap.ini],
2621 [ depth=../../..
2622 case $srcdir in
2623 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2624 .) reldir=$depth ;;
2625 *) reldir=$depth/$srcdir ;;
2626 esac
2627 $ac_aux_dir/install-sh -d runtime/etc/mono/
2628 cd runtime/etc/mono/
2629 rm -f browscap.ini
2630 $LN_S $reldir/data/browscap.ini browscap.ini
2631 cd $depth
2632 ],[LN_S='$LN_S'])
2634 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/Browsers/Compat.browser],
2635 [ depth=../../../../..
2636 case $srcdir in
2637 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2638 .) reldir=$depth ;;
2639 *) reldir=$depth/$srcdir ;;
2640 esac
2641 $ac_aux_dir/install-sh -d runtime/etc/mono/2.0/Browsers/
2642 cd runtime/etc/mono/2.0/Browsers
2643 rm -f Compat.browser
2644 $LN_S $reldir/data/net_2_0/Browsers/Compat.browser Compat.browser
2645 cd $depth
2646 ],[LN_S='$LN_S'])
2648 AC_CONFIG_COMMANDS([runtime/etc/mono/4.0/machine.config],
2649 [ depth=../../../..
2650 case $srcdir in
2651 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2652 .) reldir=$depth ;;
2653 *) reldir=$depth/$srcdir ;;
2654 esac
2655 $ac_aux_dir/install-sh -d runtime/etc/mono/4.0
2656 cd runtime/etc/mono/4.0
2657 rm -f machine.config
2658 $LN_S $reldir/data/net_4_0/machine.config machine.config
2659 cd $depth
2660 ],[LN_S='$LN_S'])
2662 AC_CONFIG_COMMANDS([runtime/etc/mono/4.0/web.config],
2663 [ depth=../../../..
2664 case $srcdir in
2665 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2666 .) reldir=$depth ;;
2667 *) reldir=$depth/$srcdir ;;
2668 esac
2669 $ac_aux_dir/install-sh -d runtime/etc/mono/4.0
2670 cd runtime/etc/mono/4.0
2671 rm -f web.config
2672 $LN_S $reldir/data/net_4_0/web.config web.config
2673 cd $depth
2674 ],[LN_S='$LN_S'])
2676 if test x$enable_quiet_build = xyes; then
2677 AC_CONFIG_COMMANDS([quiet], [for i in `find mono libgc support -name Makefile.in | sed -e 's/Makefile.in/Makefile/g'`; do if test -f $i; then $srcdir/scripts/patch-quiet.sh $i; fi; done], [shell=$SHELL])
2678 AC_CONFIG_COMMANDS([quiet-libtool], [sed -e 's/$echo "copying selected/$show "copying selected/g' < libtool > libtool.tmp && mv libtool.tmp libtool && chmod a+x libtool; sed -e 's/$ECHO "copying selected/# "copying selected/g' < libtool > libtool.tmp && mv libtool.tmp libtool && chmod a+x libtool])
2679 fi
2681 AC_OUTPUT([
2682 Makefile
2683 mono-core.spec
2684 mono-uninstalled.pc
2685 scripts/mono-find-provides
2686 scripts/mono-find-requires
2687 mono/Makefile
2688 mono/utils/Makefile
2689 mono/metadata/Makefile
2690 mono/dis/Makefile
2691 mono/cil/Makefile
2692 mono/arch/Makefile
2693 mono/arch/x86/Makefile
2694 mono/arch/amd64/Makefile
2695 mono/arch/hppa/Makefile
2696 mono/arch/ppc/Makefile
2697 mono/arch/sparc/Makefile
2698 mono/arch/s390/Makefile
2699 mono/arch/s390x/Makefile
2700 mono/arch/arm/Makefile
2701 mono/arch/alpha/Makefile
2702 mono/arch/ia64/Makefile
2703 mono/arch/mips/Makefile
2704 mono/interpreter/Makefile
2705 mono/tests/Makefile
2706 mono/tests/tests-config
2707 mono/tests/assemblyresolve/Makefile
2708 mono/tests/cas/Makefile
2709 mono/tests/cas/assembly/Makefile
2710 mono/tests/cas/demand/Makefile
2711 mono/tests/cas/inheritance/Makefile
2712 mono/tests/cas/linkdemand/Makefile
2713 mono/tests/cas/threads/Makefile
2714 mono/benchmark/Makefile
2715 mono/monograph/Makefile
2716 mono/io-layer/Makefile
2717 mono/mini/Makefile
2718 mono/profiler/Makefile
2719 ikvm-native/Makefile
2720 scripts/Makefile
2721 man/Makefile
2722 web/Makefile
2723 docs/Makefile
2724 data/Makefile
2725 data/net_2_0/Makefile
2726 data/net_4_0/Makefile
2727 data/net_2_0/Browsers/Makefile
2728 data/mint.pc
2729 data/mono-2.pc
2730 data/mono-cairo.pc
2731 data/mono-nunit.pc
2732 data/mono-options.pc
2733 data/mono-lineeditor.pc
2734 data/monodoc.pc
2735 data/mono.web.pc
2736 data/dotnet.pc
2737 data/dotnet35.pc
2738 data/wcf.pc
2739 data/cecil.pc
2740 data/system.web.extensions_1.0.pc
2741 data/system.web.extensions.design_1.0.pc
2742 data/system.web.mvc.pc
2743 data/system.web.mvc2.pc
2744 samples/Makefile
2745 support/Makefile
2746 data/config
2747 tools/Makefile
2748 tools/locale-builder/Makefile
2749 tools/sgen/Makefile
2750 runtime/Makefile
2751 msvc/Makefile
2752 po/Makefile
2753 ])
2755 if test x$host_win32 = xyes; then
2756 # Get rid of 'cyg' prefixes in library names
2757 sed -e "s/\/cyg\//\/\//" libtool > libtool.new; mv libtool.new libtool; chmod 755 libtool
2758 # libtool seems to inherit -mno-cygwin from our CFLAGS, and uses it to compile its executable
2759 # wrapper scripts which use exec(). gcc has no problem compiling+linking this, but the resulting
2760 # executable doesn't work...
2761 sed -e "s,-mno-cygwin,,g" libtool > libtool.new; mv libtool.new libtool; chmod 755 libtool
2762 fi
2764 (
2765 case $prefix in
2766 NONE) prefix=$ac_default_prefix ;;
2767 esac
2768 case $exec_prefix in
2769 NONE) exec_prefix='${prefix}' ;;
2770 esac
2772 test -w $srcdir/$mcsdir/build || chmod +w $srcdir/$mcsdir/build
2774 #
2775 # If we are cross compiling, we don't build in the mcs/ tree. Let us not clobber
2776 # any existing config.make. This allows people to share the same source tree
2777 # with different build directories, one native and one cross
2778 #
2779 if test x$cross_compiling = xno && test x$enable_mcs_build != xno; then
2780 echo "prefix=$prefix" > $srcdir/$mcsdir/build/config.make
2781 echo "exec_prefix=$exec_prefix" >> $srcdir/$mcsdir/build/config.make
2782 echo "sysconfdir=$sysconfdir" >> $srcdir/$mcsdir/build/config.make
2783 echo 'mono_libdir=${exec_prefix}/lib' >> $srcdir/$mcsdir/build/config.make
2784 echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $srcdir/$mcsdir/build/config.make
2785 echo 'IL_FLAGS = /debug' >> $srcdir/$mcsdir/build/config.make
2786 echo "RUNTIME = $mono_build_root/runtime/mono-wrapper" >> $srcdir/$mcsdir/build/config.make
2787 echo "ILDISASM = $mono_build_root/runtime/monodis-wrapper" >> $srcdir/$mcsdir/build/config.make
2788 case $INSTALL in
2789 [[\\/$]]* | ?:[[\\/]]* ) mcs_INSTALL=$INSTALL ;;
2790 *) mcs_INSTALL=$mono_build_root/$INSTALL ;;
2791 esac
2793 echo "INSTALL = $mcs_INSTALL" >> $srcdir/$mcsdir/build/config.make
2795 export VERSION
2796 [myver=$($AWK 'BEGIN {
2797 split (ENVIRON["VERSION"] ".0.0.0", vsplit, ".")
2798 if(length(vsplit [1]) > 4) {
2799 split (substr(ENVIRON["VERSION"], 0, 4) "." substr(ENVIRON["VERSION"], 5) ".0.0", vsplit, ".")
2800 }
2801 print vsplit [1] "." vsplit [2] "." vsplit [3] "." vsplit [4]
2802 }')]
2804 echo "MONO_VERSION = $myver" >> $srcdir/$mcsdir/build/config.make
2805 fi
2807 if test x$platform_darwin = xyes; then
2808 echo "PLATFORM = darwin" >> $srcdir/$mcsdir/build/config.make
2809 fi
2811 if test x$TARGET = xAMD64 -a x$host_win32 = xno -a "x$AOT_SUPPORTED" = "xyes" -a x$enable_system_aot = xyes; then
2812 echo "ENABLE_AOT = 1" >> $srcdir/$mcsdir/build/config.make
2813 fi
2815 # if we have an olive folder, override the default settings
2816 if test -d $olivedir; then
2818 test -w $srcdir/$olivedir/build || chmod +w $srcdir/$olivedir/build
2820 if test x$cross_compiling = xno && test x$enable_olive_build != xno; then
2821 echo "prefix=$prefix" > $srcdir/$olivedir/build/config.make
2822 echo "exec_prefix=$exec_prefix" >> $srcdir/$olivedir/build/config.make
2823 echo 'mono_libdir=${exec_prefix}/lib' >> $srcdir/$olivedir/build/config.make
2824 echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $srcdir/$olivedir/build/config.make
2825 echo "RUNTIME = $mono_build_root/runtime/mono-wrapper" >> $srcdir/$olivedir/build/config.make
2826 echo "MONO_VERSION = $myver" >> $srcdir/$olivedir/build/config.make
2827 fi
2828 fi
2830 if test x$DISABLE_MCS_DOCS = xyes; then
2831 echo "DISABLE_MCS_DOCS = yes" >> $srcdir/$mcsdir/build/config.make
2832 fi
2834 if test x$with_moonlight = xyes; then
2835 echo "MOONLIGHT = 1" >> $srcdir/$mcsdir/build/config.make
2836 fi
2837 )
2839 libgdiplus_msg=${libgdiplus_loc:-assumed to be installed}
2841 echo "
2842 mcs source: $mcs_topdir
2843 olive source: $olive_topdir
2845 Engine:
2846 GC: $gc
2847 GLIB: $with_glib
2848 TLS: $with_tls
2849 SIGALTSTACK: $with_sigaltstack
2850 Engine: $jit_status
2851 oprofile: $OPROFILE
2852 BigArrays: $enable_big_arrays
2853 DTrace: $enable_dtrace
2854 Parallel Mark: $enable_parallel_mark
2855 LLVM Back End: $enable_llvm
2857 Libraries:
2858 Moon Profile: $with_moonlight
2859 MonoTouch: $with_monotouch
2860 JNI support: $jdk_headers_found
2861 libgdiplus: $libgdiplus_msg
2862 zlib: $zlib_msg
2863 $disabled
2864 "
2865 if test x$with_static_mono = xno -a "x$host_win32" != "xyes"; then
2866 AC_MSG_WARN(Turning off static Mono is a risk, you might run into unexpected bugs)
2867 fi
2869 if test x$gc = xsgen; then
2870 echo IMPORTANT:
2871 echo IMPORTANT: You have selected an experimental, work-in-progress
2872 echo IMPORTANT: GC engine. This GC engine is currently not supported
2873 echo IMPORTANT: and is not yet ready for use.
2874 echo IMPORTANT:
2875 echo IMPORTANT: There are known problems with it, use at your own risk.
2876 fi
2878 if test x$enable_llvm = xyes; then
2879 echo IMPORTANT:
2880 echo IMPORTANT: The LLVM Back End is experimental and has known problems.
2881 echo IMPORTANT:
2882 fi