msvc/install-llvm-mono-build.bat

   1 :: --------------------------------------------------
   2 :: Install needed LLVM binaries from LLVM install directory
   3 :: into Mono build output directory.
   4 ::
   5 :: %1 LLVM install root directory (internal or external LLVM build).
   6 :: %2 Mono distribution root directory.
   7 :: --------------------------------------------------
   8
   9 @echo off
  10 setlocal
  11
  12 set BUILD_RESULT=1
  13
  14 set LLVM_INSTALL_DIR=%~1
  15 shift
  16 set MONO_DIST_DIR=%~1
  17 shift
  18
  19 if "%LLVM_INSTALL_DIR%" == "" (
  20     echo Missing LLVM install directory argument.
  21     goto ECHO_USAGE
  22 )
  23
  24 if "%MONO_DIST_DIR%" == "" (
  25     echo Missing Mono dist directory argument.
  26     goto ECHO_USAGE
  27 )
  28
  29 if not exist "%LLVM_INSTALL_DIR%\bin\opt.exe" (
  30     echo Missing LLVM build output, "%LLVM_INSTALL_DIR%\bin\opt.exe"
  31     goto ON_ERROR
  32 )
  33
  34 if not exist "%LLVM_INSTALL_DIR%\bin\llc.exe" (
  35     echo Missing LLVM build output, "%LLVM_INSTALL_DIR%\bin\llc.exe"
  36     goto ON_ERROR
  37 )
  38
  39 if not exist "%LLVM_INSTALL_DIR%\bin\llvm-dis.exe" (
  40     echo Missing LLVM build output, "%LLVM_INSTALL_DIR%\bin\llvm-dis.exe"
  41     goto ON_ERROR
  42 )
  43
  44 if not exist "%LLVM_INSTALL_DIR%\bin\llvm-mc.exe" (
  45     echo Missing LLVM build output, "%LLVM_INSTALL_DIR%\bin\llvm-mc.exe"
  46     goto ON_ERROR
  47 )
  48
  49 if not exist "%LLVM_INSTALL_DIR%\bin\llvm-as.exe" (
  50     echo Missing LLVM build output, "%LLVM_INSTALL_DIR%\bin\llvm-as.exe"
  51     goto ON_ERROR
  52 )
  53
  54 copy /Y "%LLVM_INSTALL_DIR%\bin\opt.exe" "%MONO_DIST_DIR%" >nul 2>&1
  55 copy /Y "%LLVM_INSTALL_DIR%\bin\llc.exe" "%MONO_DIST_DIR%" >nul 2>&1
  56 copy /Y "%LLVM_INSTALL_DIR%\bin\llvm-dis.exe" "%MONO_DIST_DIR%" >nul 2>&1
  57 copy /Y "%LLVM_INSTALL_DIR%\bin\llvm-mc.exe" "%MONO_DIST_DIR%" >nul 2>&1
  58 copy /Y "%LLVM_INSTALL_DIR%\bin\llvm-as.exe" "%MONO_DIST_DIR%" >nul 2>&1
  59
  60 goto ON_SUCCESS
  61
  62 :ON_SUCCESS
  63
  64 set BUILD_RESULT=0
  65 goto ON_EXIT
  66
  67 :ECHO_USAGE:
  68     ECHO Usage: install-llvm-mono-build.bat [llvm_install_dir] [mono_dist_dir].
  69
  70 :ON_ERROR
  71     echo Failed to install LLVM binaries into Mono build output directory.
  72     goto ON_EXIT
  73
  74 :ON_EXIT
  75     exit /b %BUILD_RESULT%
  76
  77 @echo on