| blob | 2d5a9fec22e8caacec16851b12b94db2db9fbfc2 |
1 AC_INIT(README)
2 AC_CANONICAL_SYSTEM
4 # Gross hack to enable 'make dist' on automake 1.9+tar 1.14.
5 # The extra brackets are to foil regex-based scans.
6 m4_ifdef([_A][M_PROG_TAR],[_A][M_SET_OPTION([tar-ustar])])
8 AM_CONFIG_HEADER(config.h)
9 AM_INIT_AUTOMAKE(mono,2.8.1)
10 AM_MAINTAINER_MODE
12 API_VER=2.0
13 AC_SUBST(API_VER)
15 AC_PROG_LN_S
17 # In case of cygwin, override LN_S, irrespective of what it determines.
18 # The build uses cygwin, but the actual runtime doesn't.
19 case $host_os in
20 *cygwin* ) LN_S='cp -p';;
21 esac
23 dnl
24 dnl libgc checks
25 dnl
27 gc_headers=no
28 gc=included
29 gc_msg="included Boehm"
30 use_included_gc=no
31 libgc_configure_args=
33 if test -d $srcdir/libgc ; then
34 gc_default=included
35 else
36 gc_default=boehm
37 fi
39 # These variables are the CPPFLAGS/CFLAGS passed to libgc's configure
40 # libgc should inherit the original CFLAGS/CPPFLAGS passed to configure, i.e. -O0
41 CPPFLAGS_FOR_LIBGC=$CPPFLAGS
42 CFLAGS_FOR_LIBGC=$CFLAGS
43 CPPFLAGS_FOR_EGLIB=$CPPFLAGS
44 CFLAGS_FOR_EGLIB=$CFLAGS
46 #
47 # These are the flags that need to be stored in the mono.pc file for
48 # compiling code that will embed Mono
49 #
50 libmono_cflags=""
51 libmono_ldflags=""
52 AC_SUBST(libmono_cflags)
53 AC_SUBST(libmono_ldflags)
55 # Variable to have relocatable .pc files (lib, or lib64)
56 reloc_libdir=`basename ${libdir}`
57 AC_SUBST(reloc_libdir)
59 dnl if linker handles the version script
60 no_version_script=no
62 # Set to yes if Unix sockets cannot be created in an anonymous namespace
63 need_link_unlink=no
65 # Thread configuration inspired by sleepycat's db
66 AC_MSG_CHECKING([host platform characteristics])
67 libgc_threads=no
68 has_dtrace=no
69 parallel_mark=yes
70 ikvm_native=yes
72 case "$host" in
73 powerpc*-*-linux*)
74 # https://bugzilla.novell.com/show_bug.cgi?id=504411
75 disable_munmap=yes
76 ;;
77 esac
79 host_win32=no
80 target_win32=no
81 case "$host" in
82 *-mingw*|*-*-cygwin*)
83 AC_DEFINE(HOST_WIN32,1,[Host Platform is Win32])
84 AC_DEFINE(DISABLE_PORTABILITY,1,[Disable the io-portability layer])
85 AC_DEFINE(PLATFORM_NO_SYMLINKS,1,[This platform does not support symlinks])
86 host_win32=yes
87 if test "x$cross_compiling" = "xno"; then
88 target_win32=yes
89 if test "x$host" == "x$target"; then
90 AC_DEFINE(TARGET_WIN32,1,[Target OS is Win32])
91 fi
92 CC="gcc -mno-cygwin -g"
93 CXX="g++ -mno-cygwin -g"
94 # So libgc configure gets -mno-cygwin
95 export CC
96 export CXX
97 else
98 target_win32=yes
99 AC_DEFINE(TARGET_WIN32,1,[Target OS is Win32/MinGW])
100 AC_DEFINE(MINGW_CROSS_COMPILE,1,[Cross-compiling using MinGW])
101 fi
102 HOST_CC="gcc"
103 # Windows 2000 is required that includes Internet Explorer 5.01
104 CPPFLAGS="$CPPFLAGS -DWINVER=0x0500 -D_WIN32_WINNT=0x0500 -D_WIN32_IE=0x0501 -D_UNICODE -DUNICODE -DWIN32_THREADS -DFD_SETSIZE=1024"
105 LDFLAGS="$LDFLAGS -lmswsock -lws2_32 -lole32 -loleaut32 -lpsapi -lversion -ladvapi32 -lwinmm -lkernel32"
106 libmono_cflags="-mno-cygwin -mms-bitfields -mwindows"
107 libmono_ldflags="-mno-cygwin -mms-bitfields -mwindows"
108 libdl=
109 libgc_threads=win32
110 gc_default=included
111 with_sigaltstack=no
112 LN_S=cp
113 # This forces libgc to use the DllMain based thread registration code on win32
114 libgc_configure_args="$libgc_configure_args --enable-win32-dllmain=yes"
115 ;;
116 *-*-*netbsd*)
117 host_win32=no
118 CPPFLAGS="$CPPFLAGS -D_REENTRANT -DGC_NETBSD_THREADS -D_GNU_SOURCE"
119 libmono_cflags="-D_REENTRANT"
120 LDFLAGS="$LDFLAGS -pthread"
121 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD"
122 libmono_ldflags="-pthread"
123 need_link_unlink=yes
124 libdl="-ldl"
125 libgc_threads=pthreads
126 with_sigaltstack=no
127 use_sigposix=yes
128 ;;
129 *-*-*freebsd*)
130 host_win32=no
131 if test "x$PTHREAD_CFLAGS" = "x"; then
132 CPPFLAGS="$CPPFLAGS -DGC_FREEBSD_THREADS"
133 libmono_cflags=
134 else
135 CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
136 libmono_cflags="$PTHREAD_CFLAGS"
137 fi
138 if test "x$PTHREAD_LIBS" = "x"; then
139 LDFLAGS="$LDFLAGS -pthread"
140 libmono_ldflags="-pthread"
141 else
142 LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
143 libmono_ldflags="$PTHREAD_LIBS"
144 fi
145 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD"
146 need_link_unlink=yes
147 AC_DEFINE(PTHREAD_POINTER_ID, 1, [pthread is a pointer])
148 libdl=
149 libgc_threads=pthreads
150 # This doesn't seem to work as of 7.0 on amd64
151 with_sigaltstack=no
152 # TLS is only partially implemented on -CURRENT (compiler support
153 # but NOT library support)
154 #
155 with_tls=pthread
156 use_sigposix=yes
157 ;;
158 *-*-*openbsd*)
159 host_win32=no
160 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_OPENBSD_THREADS -DPLATFORM_BSD -D_REENTRANT -DUSE_MMAP"
161 if test "x$disable_munmap" != "xyes"; then
162 CPPFLAGS="$CPPFLAGS -DUSE_MUNMAP"
163 fi
164 libmono_cflags="-D_THREAD_SAFE -D_REENTRANT"
165 LDFLAGS="$LDFLAGS -pthread"
166 need_link_unlink=yes
167 AC_DEFINE(PTHREAD_POINTER_ID)
168 libdl=
169 gc_default=boehm
170 libgc_threads=pthreads
171 with_sigaltstack=no
172 use_sigposix=yes
173 ;;
174 *-*-linux*)
175 host_win32=no
176 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -D_GNU_SOURCE -D_REENTRANT -DUSE_MMAP"
177 if test "x$disable_munmap" != "xyes"; then
178 CPPFLAGS="$CPPFLAGS -DUSE_MUNMAP"
179 fi
180 libmono_cflags="-D_REENTRANT"
181 libdl="-ldl"
182 libgc_threads=pthreads
183 use_sigposix=yes
184 ;;
185 *-*-nacl*)
186 host_win32=no
187 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -D_GNU_SOURCE -D_REENTRANT -DUSE_MMAP"
188 if test "x$disable_munmap" != "xyes"; then
189 CPPFLAGS="$CPPFLAGS -DUSE_MUNMAP"
190 fi
191 libmono_cflags="-D_REENTRANT"
192 libdl=
193 libgc_threads=pthreads
194 gc_default=boehm
195 use_sigposix=yes
196 ikvm_native=no
197 AC_DEFINE(DISABLE_SOCKETS,1,[Disable sockets support])
198 ;;
199 *-*-hpux*)
200 host_win32=no
201 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
202 # +ESdbgasm only valid on bundled cc on RISC
203 # silently ignored for ia64
204 if test $GCC != "yes"; then
205 CFLAGS="$CFLAGS +ESdbgasm"
206 # Arrange for run-time dereferencing of null
207 # pointers to produce a SIGSEGV signal.
208 LDFLAGS="$LDFLAGS -z"
209 fi
210 CFLAGS="$CFLAGS +ESdbgasm"
211 LDFLAGS="$LDFLAGS -z"
212 libmono_cflags="-D_REENTRANT"
213 libmono_ldflags="-lpthread"
214 libgc_threads=pthreads
215 need_link_unlink=yes
216 use_sigposix=yes
217 ;;
218 *-*-solaris*)
219 host_win32=no
220 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS -DUSE_MMAP -DUSE_MUNMAP -DPLATFORM_SOLARIS"
221 need_link_unlink=yes
222 libmono_cflags="-D_REENTRANT"
223 libgc_threads=pthreads
224 # This doesn't seem to work on solaris/x86, but the configure test runs
225 with_tls=pthread
226 has_dtrace=yes
227 use_sigposix=yes
228 enable_solaris_tar_check=yes
229 ;;
230 *-*-darwin*)
231 parallel_mark="Disabled_Currently_Hangs_On_MacOSX"
232 host_win32=no
233 platform_darwin=yes
234 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE -DGC_MACOSX_THREADS -DPLATFORM_MACOSX -DUSE_MMAP -DUSE_MUNMAP"
235 CPPFLAGS="$CPPFLAGS -DGetCurrentProcess=MonoGetCurrentProcess -DGetCurrentThread=MonoGetCurrentThread -DCreateEvent=MonoCreateEvent"
236 libmono_cflags="-D_THREAD_SAFE"
237 LDFLAGS="$LDFLAGS -pthread"
238 libmono_ldflags="-pthread"
239 need_link_unlink=yes
240 AC_DEFINE(PTHREAD_POINTER_ID)
241 AC_DEFINE(USE_MACH_SEMA, 1, [...])
242 no_version_script=yes
243 libdl=
244 libgc_threads=pthreads
245 has_dtrace=yes
246 if test "x$cross_compiling" = "xyes"; then
247 has_broken_apple_cpp=yes
248 fi
249 dnl Snow Leopard is horribly broken -- it reports itself as i386-apple-darwin10.0.0, but
250 dnl its gcc defaults to 64-bit mode. They have also deprecated the usage of ucontext
251 dnl we need to set some flags to build our 32-bit binaries on 10.6 properly
252 case "$host" in
253 dnl Snow Leopard config.guess reports as this
254 i*86-*-darwin10*)
255 BROKEN_DARWIN_FLAGS="-arch i386 -D_XOPEN_SOURCE -mmacosx-version-min=10.5"
256 CPPFLAGS="$CPPFLAGS $BROKEN_DARWIN_FLAGS"
257 CFLAGS="$CFLAGS $BROKEN_DARWIN_FLAGS"
258 CXXFLAGS="$CXXFLAGS $BROKEN_DARWIN_FLAGS"
259 CCASFLAGS="$CCASFLAGS $BROKEN_DARWIN_FLAGS"
260 CPPFLAGS_FOR_LIBGC="$CPPFLAGS_FOR_LIBGC $BROKEN_DARWIN_FLAGS"
261 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC $BROKEN_DARWIN_FLAGS"
262 CPPFLAGS_FOR_EGLIB="$CPPFLAGS_FOR_EGLIB $BROKEN_DARWIN_FLAGS"
263 CFLAGS_FOR_EGLIB="$CFLAGS_FOR_EGLIB $BROKEN_DARWIN_FLAGS"
264 ;;
265 esac
266 ;;
267 *-*-haiku*)
268 host_win32=no
269 CPPFLAGS="$CPPFLAGS -D_REENTRANT -D_THREAD_SAFE"
270 libmono_cflags="-D_REENTRANT -D_THREAD_SAFE"
271 libdl=
272 LIBS="$LIBS -lnetwork"
273 need_link_unlink=yes
274 AC_DEFINE(PTHREAD_POINTER_ID)
275 libgc_threads=pthreads
276 use_sigposix=yes
277 ;;
278 *)
279 AC_MSG_WARN([*** Please add $host to configure.in checks!])
280 host_win32=no
281 libdl="-ldl"
282 ;;
283 esac
284 AC_MSG_RESULT(ok)
286 if test x$need_link_unlink = xyes; then
287 AC_DEFINE(NEED_LINK_UNLINK, 1, [Define if Unix sockets cannot be created in an anonymous namespace])
288 fi
290 AM_CONDITIONAL(HOST_WIN32, test x$host_win32 = xyes)
291 AM_CONDITIONAL(TARGET_WIN32, test x$target_win32 = xyes)
292 AM_CONDITIONAL(PLATFORM_LINUX, echo x$target_os | grep -q linux)
293 AM_CONDITIONAL(PLATFORM_DARWIN, test x$platform_darwin = xyes)
294 AM_CONDITIONAL(PLATFORM_SIGPOSIX, test x$use_sigposix = xyes)
296 AC_CHECK_TOOL(CC, gcc, gcc)
297 AC_PROG_CC
298 AC_CHECK_TOOL(CXX, g++, g++)
299 AC_PROG_CXX
300 AM_PROG_AS
301 AM_PROG_CC_STDC
302 AC_PROG_INSTALL
303 AC_PROG_AWK
304 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
305 : ${CCAS='$(CC)'}
306 # Set ASFLAGS if not already set.
307 : ${CCASFLAGS='$(CFLAGS)'}
308 AC_SUBST(CCAS)
309 AC_SUBST(CCASFLAGS)
311 # AC_PROG_CXX helpfully sets CXX to g++ even if no c++ compiler is found so check
312 # GXX instead. See http://lists.gnu.org/archive/html/bug-autoconf/2002-04/msg00056.html
313 if test "x$CXX" = "xg++"; then
314 if test "x$GXX" != "xyes"; then
315 # automake/libtool is so broken, it requires g++ even if the c++ sources
316 # are inside automake conditionals
317 AC_MSG_ERROR([You need to install g++])
318 fi
319 fi
321 AC_CHECK_PROG(BISON, bison,yes,no)
322 if test "x$BISON" = "xno";
323 then
324 AC_MSG_ERROR([You need to install bison])
325 fi
327 dnl may require a specific autoconf version
328 dnl AC_PROG_CC_FOR_BUILD
329 dnl CC_FOR_BUILD not automatically detected
330 CC_FOR_BUILD=$CC
331 CFLAGS_FOR_BUILD=$CFLAGS
332 BUILD_EXEEXT=
333 if test "x$cross_compiling" = "xyes"; then
334 CC_FOR_BUILD=cc
335 CFLAGS_FOR_BUILD=
336 BUILD_EXEEXT=""
337 fi
338 AC_SUBST(CC_FOR_BUILD)
339 AC_SUBST(CFLAGS_FOR_BUILD)
340 AC_SUBST(HOST_CC)
341 AC_SUBST(BUILD_EXEEXT)
343 AM_CONDITIONAL(CROSS_COMPILING, [test x$cross_compiling = xyes])
344 AM_CONDITIONAL(USE_BATCH_FILES, [test x$host_win32 = xyes -a x$cross_compiling = xyes])
346 # Set STDC_HEADERS
347 AC_HEADER_STDC
348 AC_LIBTOOL_WIN32_DLL
349 # This causes monodis to not link correctly
350 #AC_DISABLE_FAST_INSTALL
351 AM_PROG_LIBTOOL
352 # Use dolt (http://dolt.freedesktop.org/) instead of libtool for building.
353 DOLT
355 export_ldflags=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
356 AC_SUBST(export_ldflags)
358 # Test whenever ld supports -version-script
359 AC_PROG_LD
360 AC_PROG_LD_GNU
361 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
362 no_version_script=yes
363 fi
365 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
367 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h sys/utime.h semaphore.h sys/un.h linux/rtc.h sys/syscall.h sys/mkdev.h sys/uio.h sys/param.h)
368 AC_CHECK_HEADERS(sys/param.h sys/socket.h sys/ipc.h sys/sem.h sys/utsname.h alloca.h ucontext.h pwd.h sys/select.h netinet/tcp.h netinet/in.h unistd.h sys/types.h link.h asm/sigcontext.h)
370 AC_CHECK_HEADERS(sys/user.h, [], [],
371 [
372 #ifdef HAVE_SYS_PARAM_H
373 # include <sys/param.h>
374 #endif
375 ])
377 AC_CHECK_HEADER(zlib.h, [have_zlib=yes], [have_zlib=no])
378 if test x$have_zlib = xyes; then
379 AC_TRY_COMPILE([#include <zlib.h>], [
380 void main () {
381 #if defined(ZLIB_VERNUM) && (ZLIB_VERNUM >= 0x1230)
382 }
383 #else
384 #error No good zlib found
385 #endif
386 ],[
387 AC_MSG_RESULT(Using system zlib)
388 zlib_msg="system zlib"
389 ],[
390 AC_MSG_RESULT(Using embedded zlib)
391 have_zlib=no
392 zlib_msg="bundled zlib"
393 ])
394 fi
396 AM_CONDITIONAL(HAVE_ZLIB, test x$have_zlib = xyes)
397 AC_DEFINE(HAVE_ZLIB,1,[Have system zlib])
399 # for mono/metadata/debug-symfile.c
400 AC_CHECK_HEADERS(elf.h)
402 # for support
403 AC_CHECK_HEADERS(poll.h)
404 AC_CHECK_HEADERS(sys/poll.h)
405 AC_CHECK_HEADERS(sys/wait.h)
406 AC_CHECK_HEADERS(grp.h)
407 AC_CHECK_HEADERS(syslog.h)
409 # for mono/dis
410 AC_CHECK_HEADERS(wchar.h)
411 AC_CHECK_HEADERS(ieeefp.h)
412 AC_MSG_CHECKING(for isinf)
413 AC_TRY_LINK([#include <math.h>], [
414 int f = isinf (1);
415 ], [
416 AC_MSG_RESULT(yes)
417 AC_DEFINE(HAVE_ISINF, 1, [isinf available])
418 ], [
419 # We'll have to use signals
420 AC_MSG_RESULT(no)
421 ])
424 # not 64 bit clean in cross-compile
425 AC_CHECK_SIZEOF(void *, 4)
427 WARN=''
428 if test x"$GCC" = xyes; then
429 WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wwrite-strings'
430 # The runtime code does not respect ANSI C strict aliasing rules
431 CFLAGS="$CFLAGS -fno-strict-aliasing"
433 ORIG_CFLAGS=$CFLAGS
434 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
435 AC_MSG_CHECKING(for -Wdeclaration-after-statement option to gcc)
436 AC_TRY_COMPILE([], [
437 void main () { }
438 ], [
439 AC_MSG_RESULT(yes)
440 ], [
441 AC_MSG_RESULT(no)
442 CFLAGS=$ORIG_CFLAGS
443 ])
444 else
445 # The Sun Forte compiler complains about inline functions that access static variables
446 # so disable all inlining.
447 case "$host" in
448 *-*-solaris*)
449 CFLAGS="$CFLAGS -Dinline="
450 ;;
451 esac
452 fi
453 CFLAGS="$CFLAGS -g $WARN"
454 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC -g"
456 # Where's the 'mcs' source tree?
457 if test -d $srcdir/mcs; then
458 mcsdir=mcs
459 else
460 mcsdir=../mcs
461 fi
463 AC_ARG_WITH(mcs-path, [ --with-mcs-path=/path/to/mcs Specify an alternate mcs source tree],
464 if test x$with_mcs_path != "x" -a -d $with_mcs_path ; then
465 mcsdir=$with_mcs_path
466 fi
467 )
469 #
470 # A sanity check to catch cases where the package was unpacked
471 # with an ancient tar program (Solaris)
472 #
473 AC_ARG_ENABLE(solaris-tar-check,
474 [ --disable-solaris-tar-check disable solaris tar check],
475 do_solaris_tar_check=no, do_solaris_tar_check=yes)
477 if test x"$do_solaris_tar_check" = xyes -a x"$enable_solaris_tar_check" = xyes; then
478 AC_MSG_CHECKING(integrity of package)
479 if test -f $mcsdir/class/System.Runtime.Serialization.Formatters.Soap/System.Runtime.Serialization.Formatters.Soap/SoapTypeMapper.cs
480 then
481 AC_MSG_RESULT(ok)
482 else
483 errorm="Your mono distribution is incomplete; if unpacking from a tar file, make sure you use GNU tar; see http://www.mono-project.com/IncompletePackage for more details"
484 AC_MSG_ERROR([$errorm])
485 fi
486 fi
488 if test "x$with_mcs_path" != "x"; then
489 mcs_topdir=$(cd "$mcsdir" && pwd)
490 mcs_topdir_from_srcdir=$mcs_topdir
491 else
492 mcs_topdir=$(cd "$srcdir/$mcsdir" && pwd)
493 mcs_topdir_from_srcdir='$(top_builddir)'/$mcsdir
494 fi
496 # Convert mcs_topdir* paths to Windows syntax.
497 if test x$cross_compiling$host_win32 = xnoyes; then
498 mcs_topdir=$(cygpath -m $mcs_topdir)
499 case $mcs_topdir_from_srcdir in
500 /cygdrive/*)
501 mcs_topdir_from_srcdir=$(cygpath -m $mcs_topdir_from_srcdir)
502 ;;
503 esac
504 fi
506 ## Maybe should also disable if mcsdir is invalid. Let's punt the issue for now.
507 AM_CONDITIONAL(BUILD_MCS, [test x$cross_compiling = xno && test x$enable_mcs_build != xno])
509 AC_SUBST([mcs_topdir])
510 AC_SUBST([mcs_topdir_from_srcdir])
512 # Where's the 'olive' source tree?
513 if test -d $srcdir/olive; then
514 olivedir=olive
515 else
516 olivedir=../olive
517 fi
519 if test -d $srcdir/$olivedir; then
520 olive_topdir='$(top_srcdir)/'$olivedir
521 fi
523 # gettext: prepare the translation directories.
524 # we do not configure the full gettext, as we consume it dynamically from C#
525 AM_PO_SUBDIRS
527 if test "x$USE_NLS" = "xyes"; then
528 AC_CHECK_PROG(HAVE_MSGFMT, msgfmt,yes,no)
530 if test "x$HAVE_MSGFMT" = "xno"; then
531 AC_MSG_ERROR([msgfmt not found. You need to install the 'gettext' package, or pass --enable-nls=no to configure.])
532 fi
533 fi
535 AC_ARG_WITH([libgdiplus],
536 [ --with-libgdiplus=installed|sibling|<path> Override the libgdiplus used for System.Drawing tests (defaults to installed)],
537 [], [with_libgdiplus=installed])
539 case $with_libgdiplus in
540 no|installed) libgdiplus_loc= ;;
541 yes|sibling) libgdiplus_loc=`cd ../libgdiplus && pwd`/src/libgdiplus.la ;;
542 /*) libgdiplus_loc=$with_libgdiplus ;;
543 *) libgdiplus_loc=`pwd`/$with_libgdiplus ;;
544 esac
545 AC_SUBST([libgdiplus_loc])
547 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
549 pkg_config_path=
550 AC_ARG_WITH(crosspkgdir, [ --with-crosspkgdir=/path/to/pkg-config/dir Change pkg-config dir to custom dir],
551 if test x$with_crosspkgdir = "x"; then
552 if test -s $PKG_CONFIG_PATH; then
553 pkg_config_path=$PKG_CONFIG_PATH
554 fi
555 else
556 pkg_config_path=$with_crosspkgdir
557 PKG_CONFIG_PATH=$pkg_config_path
558 export PKG_CONFIG_PATH
559 fi
560 )
562 AC_ARG_WITH([glib],
563 [ --with-glib=embedded|system Choose glib API: system or embedded (default to embedded)],
564 [], [with_glib=embedded])
566 ac_configure_args="$ac_configure_args \"CPPFLAGS_FOR_EGLIB=$EGLIB_CPPFLAGS\" \"CFLAGS_FOR_EGLIB=$CFLAGS_FOR_EGLIB\""
567 AC_CONFIG_SUBDIRS(eglib)
569 case $with_glib in
570 embedded)
571 GLIB_CFLAGS='-I$(top_srcdir)/eglib/src -I$(top_builddir)/eglib/src'
572 GLIB_LIBS='-L$(top_builddir)/eglib/src -leglib -lm'
573 BUILD_GLIB_CFLAGS="$GLIB_CFLAGS"
574 BUILD_GLIB_LIBS="$GLIB_LIBS"
575 GMODULE_CFLAGS="$GLIB_CFLAGS"
576 GMODULE_LIBS="$GLIB_LIBS"
577 ;;
578 system)
579 AC_MSG_ERROR([--with-glib=system is no longer supported as of Mono 2.8])
580 ;;
581 *)
582 AC_MSG_ERROR([Invalid argument to --with-glib.])
583 esac
585 AC_SUBST(GLIB_CFLAGS)
586 AC_SUBST(GLIB_LIBS)
587 AC_SUBST(GMODULE_CFLAGS)
588 AC_SUBST(GMODULE_LIBS)
589 AC_SUBST(BUILD_GLIB_CFLAGS)
590 AC_SUBST(BUILD_GLIB_LIBS)
592 if test x$cross_compiling$host_win32 = xnoyes; then
593 AC_MSG_CHECKING(for cygwin glib2-dev package)
594 if [ cygcheck --f /usr/lib/libglib-2.0.dll.a | grep -q glib2-devel ]; then
595 AC_MSG_RESULT(found)
596 AC_MSG_ERROR([Mono cannot be built with the cygwin glib2-devel package installed, because that package doesn't work with -mno-cygwin. Please uninstall it then re-run configure.])
597 else
598 AC_MSG_RESULT(not found, ok)
599 fi
601 AC_MSG_CHECKING(for broken gwin32.h)
602 glib_include=`$PKG_CONFIG --cflags-only-I glib-2.0 | sed -e 's/ -I.*//g' | sed -e 's/-I//g'`
603 if test -f $glib_include/glib/gwin32.h; then
604 if [ grep ftruncate $glib_include/glib/gwin32.h | grep -q define ]; then
605 AC_MSG_RESULT(failed)
606 hashmark='#'
607 AC_MSG_ERROR([Your version of gwin32.h is broken and will cause compilation errors when building mono. Please fix it by deleting the line: '$hashmark define ftruncate...' from '$glib_include/glib/gwin32.h' then re-run configure.])
608 fi
609 fi
610 AC_MSG_RESULT(ok)
611 fi
613 AC_ARG_WITH(gc, [ --with-gc=boehm,included,none Controls the Boehm GC config, default=included],[gc=$with_gc],[gc=$gc_default])
615 # Enable support for fast thread-local storage
616 # Some systems have broken support, so we allow to disable it.
617 AC_ARG_WITH(tls, [ --with-tls=__thread,pthread select Thread Local Storage implementation (defaults to __thread)],[],[with_tls=__thread])
619 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
620 # This does not work on some platforms (bug #55253)
621 AC_ARG_WITH(sigaltstack, [ --with-sigaltstack=yes,no enable/disable support for sigaltstack (defaults to yes)],[],[with_sigaltstack=yes])
623 AC_ARG_WITH(static_mono, [ --with-static_mono=yes,no link mono statically to libmono (faster) (defaults to yes)],[],[with_static_mono=yes])
624 AC_ARG_WITH(shared_mono, [ --with-shared_mono=yes,no build a shared libmono library (defaults to yes)],[],[with_shared_mono=yes])
626 if test "x$enable_static" = "xno"; then
627 with_static_mono=no
628 fi
630 if test "x$enable_shared" = "xno"; then
631 with_shared_mono=no
632 fi
634 if test "x$host_win32" = "xyes"; then
635 # Boehm GC requires the runtime to be in its own dll
636 with_static_mono=no
637 fi
639 AM_CONDITIONAL(STATIC_MONO, test x$with_static_mono != xno)
640 AM_CONDITIONAL(SHARED_MONO, test x$with_shared_mono != xno)
641 AC_ARG_ENABLE(mcs-build, [ --disable-mcs-build disable the build of the mcs directory], try_mcs_build=$enableval, enable_mcs_build=yes)
643 AC_ARG_WITH(xen_opt, [ --with-xen_opt=yes,no Enable Xen-specific behaviour (defaults to yes)],[],[with_xen_opt=yes])
644 if test "x$with_xen_opt" = "xyes"; then
645 AC_DEFINE(MONO_XEN_OPT, 1, [Xen-specific behaviour])
646 ORIG_CFLAGS=$CFLAGS
647 CFLAGS="$CFLAGS -mno-tls-direct-seg-refs"
648 AC_MSG_CHECKING(for -mno-tls-direct-seg-refs option to gcc)
649 AC_TRY_COMPILE([], [
650 void main () { }
651 ], [
652 AC_MSG_RESULT(yes)
653 # Pass it to libgc as well
654 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC -mno-tls-direct-seg-refs"
655 ], [
656 AC_MSG_RESULT(no)
657 CFLAGS=$ORIG_CFLAGS
658 ])
659 fi
661 AC_ARG_ENABLE(quiet-build, [ --enable-quiet-build Enable quiet runtime build (on by default)], enable_quiet_build=$enableval, enable_quiet_build=yes)
662 AC_ARG_ENABLE(small-config, [ --enable-small-config Enable tweaks to reduce requirements (and capabilities)], enable_small_config=$enableval, enable_small_config=no)
664 if test x$enable_small_config = xyes; then
665 AC_DEFINE(MONO_SMALL_CONFIG,1,[Reduce runtime requirements (and capabilities)])
666 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC -DSMALL_CONFIG"
667 fi
669 AC_ARG_ENABLE(system-aot, [ --enable-system-aot Enable the Ahead-Of-Time compilation of system assemblies during the build (on by default on some platforms)], enable_system_aot=$enableval, enable_system_aot=default)
671 DISABLED_FEATURES=none
673 AC_ARG_ENABLE(minimal, [ --enable-minimal=LIST drop support for LIST subsystems.
674 LIST is a comma-separated list from: aot, profiler, decimal, pinvoke, debug,
675 reflection_emit, reflection_emit_save, large_code, logging, com, ssa, generics, attach, jit, simd, soft_debug, normalization, assembly_remapping.],
676 [
677 for feature in `echo "$enable_minimal" | sed -e "s/,/ /g"`; do
678 eval "mono_feature_disable_$feature='yes'"
679 done
680 DISABLED_FEATURES=$enable_minimal
681 disabled="Disabled: $enable_minimal"
682 ],[])
684 AC_DEFINE_UNQUOTED(DISABLED_FEATURES, "$DISABLED_FEATURES", [String of disabled features])
686 if test "x$mono_feature_disable_aot" = "xyes"; then
687 AC_DEFINE(DISABLE_AOT_COMPILER, 1, [Disable AOT Compiler])
688 AC_MSG_NOTICE([Disabled AOT compiler])
689 fi
691 if test "x$mono_feature_disable_profiler" = "xyes"; then
692 AC_DEFINE(DISABLE_PROFILER, 1, [Disable default profiler support])
693 AC_MSG_NOTICE([Disabled support for the profiler])
694 fi
695 AM_CONDITIONAL(DISABLE_PROFILER, test x$mono_feature_disable_profiler = xyes)
697 if test "x$mono_feature_disable_decimal" = "xyes"; then
698 AC_DEFINE(DISABLE_DECIMAL, 1, [Disable System.Decimal support])
699 AC_MSG_NOTICE([Disabled support for decimal])
700 fi
702 if test "x$mono_feature_disable_pinvoke" = "xyes"; then
703 AC_DEFINE(DISABLE_PINVOKE, 1, [Disable P/Invoke support])
704 AC_MSG_NOTICE([Disabled support for P/Invoke])
705 fi
707 if test "x$mono_feature_disable_debug" = "xyes"; then
708 AC_DEFINE(DISABLE_DEBUG, 1, [Disable runtime debugging support])
709 AC_MSG_NOTICE([Disabled support for runtime debugging])
710 fi
712 if test "x$mono_feature_disable_reflection_emit" = "xyes"; then
713 AC_DEFINE(DISABLE_REFLECTION_EMIT, 1, [Disable reflection emit support])
714 mono_feature_disable_reflection_emit_save=yes
715 AC_MSG_NOTICE([Disabled support for Reflection.Emit])
716 fi
718 if test "x$mono_feature_disable_reflection_emit_save" = "xyes"; then
719 AC_DEFINE(DISABLE_REFLECTION_EMIT_SAVE, 1, [Disable assembly saving support in reflection emit])
720 AC_MSG_NOTICE([Disabled support for Reflection.Emit.Save])
721 fi
723 if test "x$mono_feature_disable_large_code" = "xyes"; then
724 AC_DEFINE(DISABLE_LARGE_CODE, 1, [Disable support for huge assemblies])
725 AC_MSG_NOTICE([Disabled support for large assemblies])
726 fi
728 if test "x$mono_feature_disable_logging" = "xyes"; then
729 AC_DEFINE(DISABLE_LOGGING, 1, [Disable support debug logging])
730 AC_MSG_NOTICE([Disabled support for logging])
731 fi
733 if test "x$mono_feature_disable_com" = "xyes"; then
734 AC_DEFINE(DISABLE_COM, 1, [Disable COM support])
735 AC_MSG_NOTICE([Disabled COM support])
736 fi
738 if test "x$mono_feature_disable_ssa" = "xyes"; then
739 AC_DEFINE(DISABLE_SSA, 1, [Disable advanced SSA JIT optimizations])
740 AC_MSG_NOTICE([Disabled SSA JIT optimizations])
741 fi
743 if test "x$mono_feature_disable_generics" = "xyes"; then
744 AC_DEFINE(DISABLE_GENERICS, 1, [Disable generics support])
745 AC_MSG_NOTICE([Disabled Generics Support])
746 fi
748 if test "x$mono_feature_disable_shadowcopy" = "xyes"; then
749 AC_DEFINE(DISABLE_SHADOW_COPY, 1, [Disable Shadow Copy for AppDomains])
750 AC_MSG_NOTICE([Disabled Shadow copy for AppDomains])
751 fi
753 if test "x$mono_feature_disable_portability" = "xyes"; then
754 AC_DEFINE(DISABLE_PORTABILITY, 1, [Disables the IO portability layer])
755 AC_MSG_NOTICE([Disabled IO Portability layer])
756 fi
758 if test "x$mono_feature_disable_attach" = "xyes"; then
759 AC_DEFINE(DISABLE_ATTACH, 1, [Disable agent attach support])
760 AC_MSG_NOTICE([Disabled agent attach])
761 fi
763 if test "x$mono_feature_disable_full_messages" = "xyes"; then
764 AC_DEFINE(DISABLE_FULL_MESSAGES, 1, [Disables building in the full table of WAPI messages])
765 AC_MSG_NOTICE([Disabled full messages for Win32 errors, only core message strings shipped])
766 fi
768 if test "x$mono_feature_disable_verifier" = "xyes"; then
769 AC_DEFINE(DISABLE_VERIFIER, 1, [Disables the verifier])
770 AC_MSG_NOTICE([Disabled the metadata and IL verifiers])
771 fi
773 if test "x$mono_feature_disable_jit" = "xyes"; then
774 AC_DEFINE(DISABLE_JIT, 1, [Disable the JIT, only full-aot mode will be supported by the runtime.])
775 AC_MSG_NOTICE([Disabled the JIT engine, only full AOT will be supported])
776 fi
778 AM_CONDITIONAL(DISABLE_JIT, test x$mono_feature_disable_jit = xyes)
780 if test "x$mono_feature_disable_simd" = "xyes"; then
781 AC_DEFINE(DISABLE_SIMD, 1, [Disable SIMD intrinsics related optimizations.])
782 AC_MSG_NOTICE([Disabled SIMD support])
783 fi
785 if test "x$mono_feature_disable_soft_debug" = "xyes"; then
786 AC_DEFINE(DISABLE_SOFT_DEBUG, 1, [Disable Soft Debugger Agent.])
787 AC_MSG_NOTICE([Disabled Soft Debugger.])
788 fi
790 if test "x$mono_feature_disable_normalization" = "xyes"; then
791 AC_DEFINE(DISABLE_NORMALIZATION, 1, [Disable String normalization support.])
792 AC_MSG_NOTICE([Disabled String normalization support.])
793 fi
795 if test "x$mono_feature_disable_assembly_remapping" = "xyes"; then
796 AC_DEFINE(DISABLE_ASSEMBLY_REMAPPING, 1, [Disable assembly remapping.])
797 AC_MSG_NOTICE([Disabled Assembly remapping.])
798 fi
800 AC_MSG_CHECKING(for visibility __attribute__)
801 AC_TRY_COMPILE([], [
802 void __attribute__ ((visibility ("hidden"))) doit (void) {}
803 void main () { doit (); }
804 ], [
805 have_visibility_hidden=yes
806 AC_MSG_RESULT(yes)
807 ], [
808 have_visibility_hidden=no
809 AC_MSG_RESULT(no)
810 ])
812 AC_MSG_CHECKING(for deprecated __attribute__)
813 AC_TRY_COMPILE([
814 int doit (void) __attribute__ ((deprecated));
815 int doit (void) { return 0; }
816 ], [
817 return 0;
818 ], [
819 have_deprecated=yes
820 AC_MSG_RESULT(yes)
821 ], [
822 have_deprecated=no
823 AC_MSG_RESULT(no)
824 ])
826 AC_ARG_ENABLE(parallel-mark, [ --enable-parallel-mark Enables GC Parallel Marking], enable_parallel_mark=$enableval, enable_parallel_mark=$parallel_mark)
827 if test x$enable_parallel_mark = xyes; then
828 libgc_configure_args="$libgc_configure_args --enable-parallel-mark"
829 fi
831 dnl
832 dnl Boehm GC configuration
833 dnl
834 LIBGC_CFLAGS=
835 LIBGC_LIBS=
836 LIBGC_STATIC_LIBS=
837 libgc_dir=
838 case "x$gc" in
839 xboehm|xbohem|xyes)
840 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
841 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
843 if test "x$found_boehm" != "xyes"; then
844 AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
845 fi
846 if test "x$gc_headers" != "xyes"; then
847 AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
848 fi
850 LIBGC_LIBS="-lgc $libdl"
851 LIBGC_STATIC_LIBS="$LIBGC_LIBS"
852 libmono_ldflags="$libmono_ldflags -lgc"
853 BOEHM_DEFINES="-DHAVE_BOEHM_GC"
855 # AC_CHECK_FUNCS does not work for some reason...
856 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
857 if test "x$found_gcj_malloc" = "xyes"; then
858 BOEHM_DEFINES="-DHAVE_GC_GCJ_MALLOC $BOEHM_DEFINES"
859 AC_DEFINE_UNQUOTED(DEFAULT_GC_NAME, "System Boehm (with typed GC)", [GC description])
860 gc_msg="System Boehm with typed GC"
861 else
862 AC_DEFINE_UNQUOTED(DEFAULT_GC_NAME, "System Boehm (no typed GC)", [GC description])
863 gc_msg="System Boehm (without typed GC)"
864 fi
865 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
866 if test "x$found_gc_enable" = "xyes"; then
867 BOEHM_DEFINES="-DHAVE_GC_ENABLE $BOEHM_DEFINES"
868 fi
869 ;;
871 xincluded)
872 use_included_gc=yes
873 libgc_dir=libgc
875 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
876 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
877 LIBGC_STATIC_LIBS='$(top_builddir)/libgc/libmonogc-static.la'
879 BOEHM_DEFINES="-DHAVE_BOEHM_GC -DHAVE_GC_H -DUSE_INCLUDED_LIBGC -DHAVE_GC_GCJ_MALLOC -DHAVE_GC_ENABLE"
881 gc_msg="bundled Boehm GC with typed GC"
882 if test x$enable_parallel_mark = xyes; then
883 AC_DEFINE_UNQUOTED(DEFAULT_GC_NAME, "Included Boehm (with typed GC and Parallel Mark)", [GC description])
884 gc_msg="$gc_msg and parallel mark"
885 else
886 AC_DEFINE_UNQUOTED(DEFAULT_GC_NAME, "Included Boehm (with typed GC)", [GC description])
887 fi
888 ;;
890 xsgen)
891 AC_MSG_WARN("Use --with-sgen instead, --with-gc= controls Boehm configuration")
892 ;;
894 xnone)
895 AC_MSG_WARN("Compiling mono without GC.")
896 AC_DEFINE_UNQUOTED(DEFAULT_GC_NAME, "none", [GC description])
897 AC_DEFINE(HAVE_NULL_GC,1,[No GC support.])
898 ;;
899 *)
900 AC_MSG_ERROR([Invalid argument to --with-gc.])
901 ;;
902 esac
904 AC_ARG_WITH(large-heap, [ --with-large-heap=yes,no Enable support for GC heaps larger than 3GB (defaults to no)], [large_heap=$withval], [large_heap=no])
905 if test "x$large_heap" = "xyes"; then
906 CPPFLAGS="$CPPFLAGS -DLARGE_CONFIG"
907 fi
909 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
910 AC_SUBST(LIBGC_CFLAGS)
911 AC_SUBST(LIBGC_LIBS)
912 AC_SUBST(LIBGC_STATIC_LIBS)
913 AC_SUBST(libgc_dir)
914 AC_SUBST(BOEHM_DEFINES)
916 dnl
917 dnl End of libgc checks
918 dnl
920 dnl *************************************
921 dnl *** Checks for zero length arrays ***
922 dnl *************************************
923 AC_MSG_CHECKING(whether $CC supports zero length arrays)
924 AC_TRY_COMPILE([
925 struct s {
926 int length;
927 char data [0];
928 };
929 ], [], [
930 AC_MSG_RESULT(yes)
931 AC_DEFINE_UNQUOTED(MONO_ZERO_LEN_ARRAY, 0, [Length of zero length arrays])
932 ], [
933 AC_MSG_RESULT(no)
934 AC_DEFINE_UNQUOTED(MONO_ZERO_LEN_ARRAY, 1, [Length of zero length arrays])
935 ])
937 if test x$target_win32 = xno; then
939 dnl hires monotonic clock support
940 AC_SEARCH_LIBS(clock_gettime, rt)
942 dnl dynamic loader support
943 AC_CHECK_FUNC(dlopen, DL_LIB="",
944 AC_CHECK_LIB(dl, dlopen, DL_LIB="-ldl", dl_support=no)
945 )
946 if test x$dl_support = xno; then
947 AC_MSG_WARN([No dynamic loading support available])
948 else
949 LIBS="$LIBS $DL_LIB"
950 AC_DEFINE(HAVE_DL_LOADER,1,[dlopen-based dynamic loader available])
951 dnl from glib's configure.in
952 AC_CACHE_CHECK([for preceeding underscore in symbols],
953 mono_cv_uscore,[
954 AC_TRY_RUN([#include <dlfcn.h>
955 int mono_underscore_test (void) { return 42; }
956 int main() {
957 void *f1 = (void*)0, *f2 = (void*)0, *handle;
958 handle = dlopen ((void*)0, 0);
959 if (handle) {
960 f1 = dlsym (handle, "mono_underscore_test");
961 f2 = dlsym (handle, "_mono_underscore_test");
962 } return (!f2 || f1);
963 }],
964 [mono_cv_uscore=yes],
965 [mono_cv_uscore=no],
966 [])
967 ])
968 if test "x$mono_cv_uscore" = "xyes"; then
969 MONO_DL_NEED_USCORE=1
970 else
971 MONO_DL_NEED_USCORE=0
972 fi
973 AC_SUBST(MONO_DL_NEED_USCORE)
974 AC_CHECK_FUNC(dlerror)
975 fi
977 dnl ******************************************************************
978 dnl *** Checks for the IKVM JNI interface library ***
979 dnl ******************************************************************
980 AC_ARG_WITH(ikvm-native, [ --with-ikvm-native=yes,no build the IKVM JNI interface library (defaults to yes)],[with_ikvm_native=$withval],[with_ikvm_native=$ikvm_native])
982 ikvm_native_dir=
983 if test x$with_ikvm_native = xyes; then
984 ikvm_native_dir=ikvm-native
985 jdk_headers_found="IKVM Native"
986 fi
988 AC_SUBST(ikvm_native_dir)
990 AC_CHECK_HEADERS(execinfo.h)
992 AC_CHECK_FUNCS(getgrgid_r)
993 AC_CHECK_FUNCS(getgrnam_r)
994 AC_CHECK_FUNCS(getpwnam_r)
995 AC_CHECK_FUNCS(getpwuid_r)
996 AC_CHECK_FUNCS(getresuid)
997 AC_CHECK_FUNCS(setresuid)
998 AC_CHECK_FUNCS(kqueue)
999 AC_CHECK_FUNCS(backtrace_symbols)
1000 AC_CHECK_FUNCS(mkstemp)
1001 AC_CHECK_FUNCS(mmap)
1002 AC_CHECK_FUNCS(madvise)
1003 AC_CHECK_FUNCS(getrusage)
1004 AC_CHECK_FUNCS(getpriority)
1005 AC_CHECK_FUNCS(setpriority)
1006 AC_CHECK_FUNCS(dl_iterate_phdr)
1007 AC_CHECK_FUNCS(sysconf)
1009 AC_CHECK_FUNCS(sched_setaffinity)
1011 dnl ****************************************************************
1012 dnl *** Check for sched_setaffinity from glibc versions before ***
1013 dnl *** 2.3.4. The older versions of the function only take 2 ***
1014 dnl *** parameters, not 3. ***
1015 dnl *** ***
1016 dnl *** Because the interface change was not made in a minor ***
1017 dnl *** version rev, the __GLIBC__ and __GLIBC_MINOR__ macros ***
1018 dnl *** won't always indicate the interface sched_affinity has. ***
1019 dnl ****************************************************************
1020 AC_MSG_CHECKING(for sched_setaffinity from glibc < 2.3.4)
1021 AC_TRY_COMPILE([#include <sched.h>], [
1022 int main() {
1023 int mask = 1;
1024 sched_setaffinity(0, &mask);
1025 }
1026 ], [
1027 # Yes, we have it...
1028 AC_MSG_RESULT(yes)
1029 AC_DEFINE(GLIBC_BEFORE_2_3_4_SCHED_SETAFFINITY, 1, [Have GLIBC_BEFORE_2_3_4_SCHED_SETAFFINITY])
1030 ], [
1031 # We have the new, three-parameter version
1032 AC_MSG_RESULT(no)
1033 ])
1036 dnl ******************************************************************
1037 dnl *** Check for large file support ***
1038 dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
1039 dnl ******************************************************************
1041 # Check that off_t can represent 2**63 - 1 correctly, working around
1042 # potential compiler bugs. Defines LARGE_FILE_SUPPORT, adds $1 to
1043 # CPPFLAGS and sets $large_offt to yes if the test succeeds
1044 large_offt=no
1045 AC_DEFUN([LARGE_FILES], [
1046 large_CPPFLAGS=$CPPFLAGS
1047 CPPFLAGS="$CPPFLAGS $1"
1048 AC_TRY_RUN([
1049 #include <sys/types.h>
1051 #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
1053 int main(void) {
1054 int big_off_t=((BIG_OFF_T%2147483629==721) &&
1055 (BIG_OFF_T%2147483647==1));
1056 if(big_off_t) {
1057 exit(0);
1058 } else {
1059 exit(1);
1060 }
1061 }
1062 ], [
1063 AC_MSG_RESULT(ok)
1064 AC_DEFINE(HAVE_LARGE_FILE_SUPPORT, 1, [Have large file support])
1065 large_CPPFLAGS="$large_CPPFLAGS $1"
1066 large_offt=yes
1067 ], [
1068 AC_MSG_RESULT(no)
1069 ], "")
1070 CPPFLAGS=$large_CPPFLAGS
1071 ])
1073 AC_MSG_CHECKING(if off_t is 64 bits wide)
1074 LARGE_FILES("")
1075 if test $large_offt = no; then
1076 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
1077 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
1078 fi
1079 if test $large_offt = no; then
1080 AC_MSG_WARN([No 64 bit file size support available])
1081 fi
1083 dnl *****************************
1084 dnl *** Checks for libsocket ***
1085 dnl *****************************
1086 AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
1088 dnl *******************************
1089 dnl *** Checks for MSG_NOSIGNAL ***
1090 dnl *******************************
1091 AC_MSG_CHECKING(for MSG_NOSIGNAL)
1092 AC_TRY_COMPILE([#include <sys/socket.h>], [
1093 int f = MSG_NOSIGNAL;
1094 ], [
1095 # Yes, we have it...
1096 AC_MSG_RESULT(yes)
1097 AC_DEFINE(HAVE_MSG_NOSIGNAL, 1, [Have MSG_NOSIGNAL])
1098 ], [
1099 # We'll have to use signals
1100 AC_MSG_RESULT(no)
1101 ])
1103 dnl *****************************
1104 dnl *** Checks for SOL_IP ***
1105 dnl *****************************
1106 AC_MSG_CHECKING(for SOL_IP)
1107 AC_TRY_COMPILE([#include <netdb.h>], [
1108 int level = SOL_IP;
1109 ], [
1110 # Yes, we have it...
1111 AC_MSG_RESULT(yes)
1112 AC_DEFINE(HAVE_SOL_IP, 1, [Have SOL_IP])
1113 ], [
1114 # We'll have to use getprotobyname
1115 AC_MSG_RESULT(no)
1116 ])
1118 dnl *****************************
1119 dnl *** Checks for SOL_IPV6 ***
1120 dnl *****************************
1121 AC_MSG_CHECKING(for SOL_IPV6)
1122 AC_TRY_COMPILE([#include <netdb.h>], [
1123 int level = SOL_IPV6;
1124 ], [
1125 # Yes, we have it...
1126 AC_MSG_RESULT(yes)
1127 AC_DEFINE(HAVE_SOL_IPV6, 1, [Have SOL_IPV6])
1128 ], [
1129 # We'll have to use getprotobyname
1130 AC_MSG_RESULT(no)
1131 ])
1133 dnl *****************************
1134 dnl *** Checks for SOL_TCP ***
1135 dnl *****************************
1136 AC_MSG_CHECKING(for SOL_TCP)
1137 AC_TRY_COMPILE([#include <netdb.h>], [
1138 int level = SOL_TCP;
1139 ], [
1140 # Yes, we have it...
1141 AC_MSG_RESULT(yes)
1142 AC_DEFINE(HAVE_SOL_TCP, 1, [Have SOL_TCP])
1143 ], [
1144 # We'll have to use getprotobyname
1145 AC_MSG_RESULT(no)
1146 ])
1148 dnl *****************************
1149 dnl *** Checks for IP_PKTINFO ***
1150 dnl *****************************
1151 AC_MSG_CHECKING(for IP_PKTINFO)
1152 AC_TRY_COMPILE([#include <netdb.h>], [
1153 int level = IP_PKTINFO;
1154 ], [
1155 # Yes, we have it...
1156 AC_MSG_RESULT(yes)
1157 AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1158 ], [
1159 AC_MSG_RESULT(no)
1160 ])
1162 dnl *****************************
1163 dnl *** Checks for IPV6_PKTINFO ***
1164 dnl *****************************
1165 AC_MSG_CHECKING(for IPV6_PKTINFO)
1166 AC_TRY_COMPILE([#include <netdb.h>], [
1167 int level = IPV6_PKTINFO;
1168 ], [
1169 # Yes, we have it...
1170 AC_MSG_RESULT(yes)
1171 AC_DEFINE(HAVE_IPV6_PKTINFO, 1, [Have IPV6_PKTINFO])
1172 ], [
1173 AC_MSG_RESULT(no)
1174 ])
1176 dnl **********************************
1177 dnl *** Checks for IP_DONTFRAGMENT ***
1178 dnl **********************************
1179 AC_MSG_CHECKING(for IP_DONTFRAGMENT)
1180 AC_TRY_COMPILE([#include <netdb.h>], [
1181 int level = IP_DONTFRAGMENT;
1182 ], [
1183 # Yes, we have it...
1184 AC_MSG_RESULT(yes)
1185 AC_DEFINE(HAVE_IP_DONTFRAGMENT, 1, [Have IP_DONTFRAGMENT])
1186 ], [
1187 AC_MSG_RESULT(no)
1188 ])
1190 dnl **********************************
1191 dnl *** Checks for IP_MTU_DISCOVER ***
1192 dnl **********************************
1193 AC_MSG_CHECKING(for IP_MTU_DISCOVER)
1194 AC_TRY_COMPILE([#include <netdb.h>], [
1195 int level = IP_MTU_DISCOVER;
1196 ], [
1197 # Yes, we have it...
1198 AC_MSG_RESULT(yes)
1199 AC_DEFINE(HAVE_IP_MTU_DISCOVER, 1, [Have IP_MTU_DISCOVER])
1200 ], [
1201 AC_MSG_RESULT(no)
1202 ])
1204 dnl *********************************
1205 dnl *** Check for struct ip_mreqn ***
1206 dnl *********************************
1207 AC_MSG_CHECKING(for struct ip_mreqn)
1208 AC_TRY_COMPILE([#include <netinet/in.h>], [
1209 struct ip_mreqn mreq;
1210 mreq.imr_address.s_addr = 0;
1211 ], [
1212 # Yes, we have it...
1213 AC_MSG_RESULT(yes)
1214 AC_DEFINE(HAVE_STRUCT_IP_MREQN, 1, [Have struct ip_mreqn])
1215 ], [
1216 # We'll just have to try and use struct ip_mreq
1217 AC_MSG_RESULT(no)
1218 AC_MSG_CHECKING(for struct ip_mreq)
1219 AC_TRY_COMPILE([#include <netinet/in.h>], [
1220 struct ip_mreq mreq;
1221 mreq.imr_interface.s_addr = 0;
1222 ], [
1223 # Yes, we have it...
1224 AC_MSG_RESULT(yes)
1225 AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1, [Have struct ip_mreq])
1226 ], [
1227 # No multicast support
1228 AC_MSG_RESULT(no)
1229 ])
1230 ])
1232 dnl **********************************
1233 dnl *** Check for gethostbyname2_r ***
1234 dnl **********************************
1235 AC_MSG_CHECKING(for gethostbyname2_r)
1236 AC_TRY_LINK([#include <netdb.h>], [
1237 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
1238 ], [
1239 # Yes, we have it...
1240 AC_MSG_RESULT(yes)
1241 AC_DEFINE(HAVE_GETHOSTBYNAME2_R, 1, [Have gethostbyname2_r])
1242 ], [
1243 AC_MSG_RESULT(no)
1244 ])
1246 dnl *****************************
1247 dnl *** Checks for libnsl ***
1248 dnl *****************************
1249 AC_CHECK_FUNC(gethostbyaddr, , AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl"))
1251 AC_CHECK_FUNCS(inet_pton inet_aton)
1253 dnl ***********************************************
1254 dnl *** Checks for size of sockaddr_un.sun_path ***
1255 dnl ***********************************************
1256 # AC_CHECK_SIZEOF can't cope with struct members :-(
1257 AC_MSG_CHECKING(size of sockaddr_un.sun_path)
1258 AC_CACHE_VAL(mono_cv_sizeof_sunpath,
1259 [AC_TRY_RUN([
1260 #include <sys/types.h>
1261 #include <stdio.h>
1262 #include <sys/un.h>
1264 int main(void) {
1265 struct sockaddr_un sock_un;
1266 FILE *f=fopen("conftestval", "w");
1267 if(!f) exit(1);
1268 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
1269 exit(0);
1270 }
1271 ], mono_cv_sizeof_sunpath=`cat conftestval`,
1272 mono_cv_sizeof_sunpath=0,
1273 mono_cv_sizeof_sunpath=0)])dnl
1274 AC_MSG_RESULT($mono_cv_sizeof_sunpath)
1275 AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $mono_cv_sizeof_sunpath, [Sizeof sock_un.sun_path])
1277 dnl *****************************
1278 dnl *** Checks for libxnet ***
1279 dnl *****************************
1280 case "${host}" in
1281 *solaris* )
1282 AC_MSG_CHECKING(for Solaris XPG4 support)
1283 if test -f /usr/lib/libxnet.so; then
1284 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
1285 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
1286 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
1287 LIBS="$LIBS -lxnet"
1288 AC_MSG_RESULT(yes)
1289 else
1290 AC_MSG_RESULT(no)
1291 fi
1293 if test "$GCC" = "yes"; then
1294 CFLAGS="$CFLAGS -Wno-char-subscripts"
1295 fi
1296 ;;
1297 esac
1299 dnl *****************************
1300 dnl *** Checks for libpthread ***
1301 dnl *****************************
1302 # on FreeBSD -STABLE, the pthreads functions all reside in libc_r
1303 # and libpthread does not exist
1304 #
1305 case "${host}" in
1306 *-*-*freebsd*)
1307 AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
1308 ;;
1309 *-*-*openbsd*)
1310 AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
1311 ;;
1312 *)
1313 AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
1314 ;;
1315 esac
1316 AC_CHECK_HEADERS(pthread.h)
1317 AC_CHECK_FUNCS(pthread_mutex_timedlock)
1318 AC_CHECK_FUNCS(pthread_getattr_np pthread_attr_get_np)
1319 AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
1320 AC_TRY_COMPILE([ #include <pthread.h>], [
1321 pthread_mutexattr_t attr;
1322 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
1323 ], [
1324 AC_MSG_RESULT(ok)
1325 ], [
1326 AC_MSG_RESULT(no)
1327 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
1328 AC_DEFINE(USE_MONO_MUTEX, 1, [Use mono_mutex_t])
1329 ])
1330 AC_CHECK_FUNCS(pthread_attr_setstacksize)
1331 AC_CHECK_FUNCS(pthread_attr_getstack pthread_attr_getstacksize)
1332 AC_CHECK_FUNCS(pthread_get_stacksize_np pthread_get_stackaddr_np)
1334 dnl ***********************************
1335 dnl *** Checks for signals
1336 dnl ***********************************
1337 AC_CHECK_HEADERS(signal.h)
1338 AC_CHECK_FUNCS(sigaction)
1340 dnl ***********************************
1341 dnl *** Checks for working __thread ***
1342 dnl ***********************************
1343 AC_MSG_CHECKING(for working __thread)
1344 if test "x$with_tls" != "x__thread"; then
1345 AC_MSG_RESULT(disabled)
1346 else
1347 AC_TRY_RUN([
1348 #include <pthread.h>
1349 __thread int i;
1350 static int res1, res2;
1352 void thread_main (void *arg)
1353 {
1354 i = arg;
1355 sleep (1);
1356 if (arg == 1)
1357 res1 = (i == arg);
1358 else
1359 res2 = (i == arg);
1360 }
1362 int main () {
1363 pthread_t t1, t2;
1365 i = 5;
1367 pthread_create (&t1, NULL, thread_main, 1);
1368 pthread_create (&t2, NULL, thread_main, 2);
1370 pthread_join (t1, NULL);
1371 pthread_join (t2, NULL);
1373 return !(res1 + res2 == 2);
1374 }
1375 ], [
1376 AC_MSG_RESULT(yes)
1377 ], [
1378 AC_MSG_RESULT(no)
1379 with_tls=pthread
1380 ])
1381 fi
1383 dnl **************************************
1384 dnl *** Checks for working sigaltstack ***
1385 dnl **************************************
1386 AC_MSG_CHECKING(for working sigaltstack)
1387 if test "x$with_sigaltstack" != "xyes"; then
1388 AC_MSG_RESULT(disabled)
1389 else
1390 AC_TRY_RUN([
1391 #include <stdio.h>
1392 #include <stdlib.h>
1393 #include <unistd.h>
1394 #include <signal.h>
1395 #include <pthread.h>
1396 #include <sys/wait.h>
1397 #if defined(__FreeBSD__) || defined(__NetBSD__)
1398 #define SA_STACK SA_ONSTACK
1399 #endif
1400 static void
1401 sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
1402 {
1403 exit (0);
1404 }
1406 static void *
1407 loop (void *ignored)
1408 {
1409 char *ptr = NULL;
1411 *ptr = 0;
1412 return NULL;
1413 }
1415 static void
1416 child ()
1417 {
1418 struct sigaction sa;
1419 struct sigaltstack sas;
1420 pthread_t id;
1421 pthread_attr_t attr;
1423 sa.sa_sigaction = sigsegv_signal_handler;
1424 sigemptyset (&sa.sa_mask);
1425 sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
1426 if (sigaction (SIGSEGV, &sa, NULL) == -1) {
1427 perror ("sigaction");
1428 return;
1429 }
1431 sas.ss_sp = malloc (SIGSTKSZ);
1432 sas.ss_size = SIGSTKSZ;
1433 sas.ss_flags = 0;
1434 if (sigaltstack (&sas, NULL) == -1) {
1435 perror ("sigaltstack");
1436 return;
1437 }
1439 pthread_attr_init (&attr);
1440 if (pthread_create(&id, &attr, loop, &attr) != 0) {
1441 printf ("pthread_create\n");
1442 return;
1443 }
1445 sleep (100);
1446 }
1448 int
1449 main ()
1450 {
1451 pid_t son;
1452 int status;
1453 int i;
1455 son = fork ();
1456 if (son == -1) {
1457 return 1;
1458 }
1460 if (son == 0) {
1461 child ();
1462 return 0;
1463 }
1465 for (i = 0; i < 3; ++i) {
1466 sleep (1);
1467 waitpid (son, &status, WNOHANG);
1468 if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
1469 return 0;
1470 }
1472 kill (son, SIGKILL);
1473 return 1;
1474 }
1476 ], [
1477 AC_MSG_RESULT(yes)
1478 AC_DEFINE(HAVE_WORKING_SIGALTSTACK, 1, [Have a working sigaltstack])
1479 ], [
1480 with_sigaltstack=no
1481 AC_MSG_RESULT(no)
1482 ])
1483 fi
1485 dnl ********************************
1486 dnl *** Checks for semaphore lib ***
1487 dnl ********************************
1488 # 'Real Time' functions on Solaris
1489 # posix4 on Solaris 2.6
1490 # pthread (first!) on Linux
1491 AC_SEARCH_LIBS(sem_init, pthread rt posix4)
1493 AC_SEARCH_LIBS(shm_open, pthread rt posix4)
1494 AC_CHECK_FUNCS(shm_open)
1496 dnl ********************************
1497 dnl *** Checks for timezone stuff **
1498 dnl ********************************
1499 AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
1500 AC_TRY_COMPILE([
1501 #include <time.h>
1502 ], [
1503 struct tm tm;
1504 tm.tm_gmtoff = 1;
1505 ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
1506 if test $ac_cv_struct_tm_gmtoff = yes; then
1507 AC_DEFINE(HAVE_TM_GMTOFF, 1, [Have tm_gmtoff])
1508 else
1509 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
1510 AC_TRY_COMPILE([
1511 #include <time.h>
1512 ], [
1513 timezone = 1;
1514 ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
1515 if test $ac_cv_var_timezone = yes; then
1516 AC_DEFINE(HAVE_TIMEZONE, 1, [Have timezone variable])
1517 else
1518 AC_ERROR(unable to find a way to determine timezone)
1519 fi
1520 fi
1522 dnl *********************************
1523 dnl *** Checks for math functions ***
1524 dnl *********************************
1525 AC_SEARCH_LIBS(sqrtf, m)
1526 if test "x$has_broken_apple_cpp" != "xyes"; then
1527 AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
1528 AC_TRY_LINK([#include <math.h>],
1529 [ finite(0.0); ],
1530 AC_DEFINE(HAVE_FINITE, 1, [Have finite in -lm]) AC_MSG_RESULT(yes),
1531 AC_MSG_RESULT(no)))
1532 fi
1533 AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
1534 AC_TRY_LINK([#include <math.h>],
1535 [ isfinite(0.0); ],
1536 AC_DEFINE(HAVE_ISFINITE, 1, [Have isfinite]) AC_MSG_RESULT(yes),
1537 AC_MSG_RESULT(no)))
1539 dnl ****************************************************************
1540 dnl *** Checks for working poll() (macosx defines it but doesn't ***
1541 dnl *** have it in the library (duh)) ***
1542 dnl ****************************************************************
1543 AC_CHECK_FUNCS(poll)
1545 dnl *************************
1546 dnl *** Check for signbit ***
1547 dnl *************************
1548 AC_MSG_CHECKING(for signbit)
1549 AC_TRY_LINK([#include <math.h>], [
1550 int s = signbit(1.0);
1551 ], [
1552 AC_MSG_RESULT(yes)
1553 AC_DEFINE(HAVE_SIGNBIT, 1, [Have signbit])
1554 ], [
1555 AC_MSG_RESULT(no)
1556 ])
1558 dnl **********************************
1559 dnl *** epoll ***
1560 dnl **********************************
1561 AC_CHECK_HEADERS(sys/epoll.h)
1562 haveepoll=no
1563 AC_CHECK_FUNCS(epoll_ctl, [haveepoll=yes], )
1564 if test "x$haveepoll" = "xyes" -a "x$ac_cv_header_sys_epoll_h" = "xyes" ; then
1565 AC_DEFINE(HAVE_EPOLL, 1, [epoll supported])
1566 fi
1568 dnl ******************************
1569 dnl *** Checks for SIOCGIFCONF ***
1570 dnl ******************************
1571 AC_CHECK_HEADERS(sys/ioctl.h)
1572 AC_CHECK_HEADERS(net/if.h, [], [],
1573 [
1574 #ifdef HAVE_SYS_TYPES_H
1575 # include <sys/types.h>
1576 #endif
1577 #ifdef HAVE_SYS_SOCKET_H
1578 # include <sys/socket.h>
1579 #endif
1580 ])
1581 AC_MSG_CHECKING(for ifreq)
1582 AC_TRY_COMPILE([
1583 #include <stdio.h>
1584 #include <sys/ioctl.h>
1585 #include <net/if.h>
1586 ], [
1587 struct ifconf ifc;
1588 struct ifreq *ifr;
1589 void *x;
1590 ifc.ifc_len = 0;
1591 ifc.ifc_buf = NULL;
1592 x = (void *) &ifr->ifr_addr;
1593 ],[
1594 AC_MSG_RESULT(yes)
1595 AC_DEFINE(HAVE_SIOCGIFCONF, 1, [Can get interface list])
1596 ], [
1597 AC_MSG_RESULT(no)
1598 ])
1599 dnl **********************************
1600 dnl *** Checks for sin_len ***
1601 dnl **********************************
1602 AC_MSG_CHECKING(for sockaddr_in.sin_len)
1603 AC_TRY_COMPILE([
1604 #include <netinet/in.h>
1605 ], [
1606 struct sockaddr_in saddr;
1607 saddr.sin_len = sizeof (saddr);
1608 ],[
1609 AC_MSG_RESULT(yes)
1610 AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [sockaddr_in has sin_len])
1611 ], [
1612 AC_MSG_RESULT(no)
1613 ])
1614 dnl **********************************
1615 dnl *** Checks for sin6_len ***
1616 dnl **********************************
1617 AC_MSG_CHECKING(for sockaddr_in6.sin6_len)
1618 AC_TRY_COMPILE([
1619 #include <netinet/in.h>
1620 ], [
1621 struct sockaddr_in6 saddr6;
1622 saddr6.sin6_len = sizeof (saddr6);
1623 ],[
1624 AC_MSG_RESULT(yes)
1625 AC_DEFINE(HAVE_SOCKADDR_IN6_SIN_LEN, 1, [sockaddr_in6 has sin6_len])
1626 ], [
1627 AC_MSG_RESULT(no)
1628 ])
1629 dnl **********************************
1630 dnl *** Checks for MonoPosixHelper ***
1631 dnl **********************************
1632 AC_CHECK_HEADERS(checklist.h)
1633 AC_CHECK_HEADERS(pathconf.h)
1634 AC_CHECK_HEADERS(fstab.h)
1635 AC_CHECK_HEADERS(attr/xattr.h)
1636 AC_CHECK_HEADERS(sys/extattr.h)
1637 AC_CHECK_HEADERS(sys/sendfile.h)
1638 AC_CHECK_HEADERS(sys/statvfs.h)
1639 AC_CHECK_HEADERS(sys/statfs.h)
1640 AC_CHECK_HEADERS(sys/vfstab.h)
1641 AC_CHECK_HEADERS(sys/xattr.h)
1642 AC_CHECK_HEADERS(sys/mman.h)
1643 AC_CHECK_HEADERS(sys/param.h)
1644 AC_CHECK_HEADERS(sys/mount.h, [], [],
1645 [
1646 #ifdef HAVE_SYS_PARAM_H
1647 # include <sys/param.h>
1648 #endif
1649 ])
1650 AC_CHECK_HEADERS(sys/mount.h)
1651 AC_CHECK_FUNCS(confstr)
1652 AC_CHECK_FUNCS(seekdir telldir)
1653 AC_CHECK_FUNCS(getdomainname)
1654 AC_CHECK_FUNCS(setdomainname)
1655 AC_CHECK_FUNCS(endgrent getgrent fgetgrent setgrent)
1656 AC_CHECK_FUNCS(setgroups)
1657 AC_CHECK_FUNCS(endpwent getpwent fgetpwent setpwent)
1658 AC_CHECK_FUNCS(getfsstat)
1659 AC_CHECK_FUNCS(lutimes futimes)
1660 AC_CHECK_FUNCS(mremap)
1661 AC_CHECK_FUNCS(remap_file_pages)
1662 AC_CHECK_FUNCS(posix_fadvise)
1663 AC_CHECK_FUNCS(posix_fallocate)
1664 AC_CHECK_FUNCS(posix_madvise)
1665 AC_CHECK_FUNCS(vsnprintf)
1666 AC_CHECK_FUNCS(sendfile)
1667 AC_CHECK_FUNCS(gethostid sethostid)
1668 AC_CHECK_FUNCS(sethostname)
1669 AC_CHECK_FUNCS(statfs)
1670 AC_CHECK_FUNCS(fstatfs)
1671 AC_CHECK_FUNCS(statvfs)
1672 AC_CHECK_FUNCS(fstatvfs)
1673 AC_CHECK_FUNCS(stime)
1674 AC_CHECK_FUNCS(strerror_r)
1675 AC_CHECK_FUNCS(ttyname_r)
1676 AC_CHECK_FUNCS(psignal)
1677 AC_CHECK_FUNCS(getlogin_r)
1678 AC_CHECK_FUNCS(lockf)
1679 AC_CHECK_FUNCS(swab)
1680 AC_CHECK_FUNCS(setusershell endusershell)
1681 AC_CHECK_SIZEOF(size_t)
1682 AC_CHECK_TYPES([blksize_t], [AC_DEFINE(HAVE_BLKSIZE_T)], ,
1683 [#include <sys/types.h>
1684 #include <sys/stat.h>
1685 #include <unistd.h>])
1686 AC_CHECK_TYPES([blkcnt_t], [AC_DEFINE(HAVE_BLKCNT_T)], ,
1687 [#include <sys/types.h>
1688 #include <sys/stat.h>
1689 #include <unistd.h>])
1690 AC_CHECK_TYPES([suseconds_t], [AC_DEFINE(HAVE_SUSECONDS_T)], ,
1691 [#include <sys/time.h>])
1692 AC_CHECK_TYPES([struct flock], [AC_DEFINE(HAVE_STRUCT_FLOCK)], ,
1693 [#include <unistd.h>
1694 #include <fcntl.h>])
1695 AC_CHECK_TYPES([struct pollfd], [AC_DEFINE(HAVE_STRUCT_POLLFD)], ,
1696 [#include <sys/poll.h>])
1697 AC_CHECK_TYPES([struct stat], [AC_DEFINE(HAVE_STRUCT_STAT)], ,
1698 [#include <sys/types.h>
1699 #include <sys/stat.h>
1700 #include <unistd.h>])
1701 AC_CHECK_TYPES([struct timespec], [AC_DEFINE(HAVE_STRUCT_TIMESPEC)], ,
1702 [#include <time.h>])
1703 AC_CHECK_TYPES([struct timeval], [AC_DEFINE(HAVE_STRUCT_TIMEVAL)], ,
1704 [#include <sys/time.h>
1705 #include <sys/types.h>
1706 #include <utime.h>])
1707 AC_CHECK_TYPES([struct timezone], [AC_DEFINE(HAVE_STRUCT_TIMEZONE)], ,
1708 [#include <sys/time.h>])
1709 AC_CHECK_TYPES([struct utimbuf], [AC_DEFINE(HAVE_STRUCT_UTIMBUF)], ,
1710 [#include <sys/types.h>
1711 #include <utime.h>])
1712 AC_CHECK_MEMBERS(
1713 [struct dirent.d_off, struct dirent.d_reclen, struct dirent.d_type],,,
1714 [#include <sys/types.h>
1715 #include <dirent.h>])
1716 AC_CHECK_MEMBERS(
1717 [struct passwd.pw_gecos],,,
1718 [#include <sys/types.h>
1719 #include <pwd.h>])
1720 AC_CHECK_MEMBERS(
1721 [struct statfs.f_flags],,,
1722 [#include <sys/types.h>
1723 #include <sys/vfs.h>])
1725 dnl Favour xattr through glibc, but use libattr if we have to
1726 AC_CHECK_FUNC(lsetxattr, ,
1727 AC_CHECK_LIB(attr, lsetxattr, XATTR_LIB="-lattr",)
1728 )
1729 AC_SUBST(XATTR_LIB)
1731 dnl kinfo_proc.kp_proc works on darwin but fails on other simil-bsds
1732 AC_CHECK_MEMBERS(
1733 [struct kinfo_proc.kp_proc],,,
1734 [#include <sys/types.h>
1735 #include <sys/param.h>
1736 #include <sys/sysctl.h>
1737 #include <sys/proc.h>
1738 ])
1740 dnl *********************************
1741 dnl *** Checks for Windows compilation ***
1742 dnl *********************************
1743 AC_CHECK_HEADERS(sys/time.h)
1744 AC_CHECK_HEADERS(sys/param.h)
1745 AC_CHECK_HEADERS(dirent.h)
1747 dnl *********************************
1748 dnl *** Check for Console 2.0 I/O ***
1749 dnl *********************************
1750 AC_CHECK_HEADERS([curses.h])
1751 AC_CHECK_HEADERS([term.h], [], [],
1752 [#if HAVE_CURSES_H
1753 #include <curses.h>
1754 #endif
1755 ])
1756 AC_CHECK_HEADERS([termios.h])
1758 dnl * This is provided in io-layer, but on windows it's only available
1759 dnl * on xp+
1760 AC_DEFINE(HAVE_GETPROCESSID, 1, [Define if GetProcessId is available])
1761 else
1762 jdk_headers_found=no
1763 AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
1764 AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
1765 AC_CHECK_LIB(ole32, main, LIBS="$LIBS -lole32", AC_ERROR(bad mingw install?))
1766 AC_CHECK_LIB(winmm, main, LIBS="$LIBS -lwinmm", AC_ERROR(bad mingw install?))
1767 AC_CHECK_LIB(oleaut32, main, LIBS="$LIBS -loleaut32", AC_ERROR(bad mingw install?))
1768 AC_CHECK_LIB(advapi32, main, LIBS="$LIBS -ladvapi32", AC_ERROR(bad mingw install?))
1769 AC_CHECK_LIB(version, main, LIBS="$LIBS -lversion", AC_ERROR(bad mingw install?))
1771 dnl *********************************
1772 dnl *** Check for struct ip_mreqn ***
1773 dnl *********************************
1774 AC_MSG_CHECKING(for struct ip_mreqn)
1775 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1776 struct ip_mreqn mreq;
1777 mreq.imr_address.s_addr = 0;
1778 ], [
1779 # Yes, we have it...
1780 AC_MSG_RESULT(yes)
1781 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
1782 ], [
1783 # We'll just have to try and use struct ip_mreq
1784 AC_MSG_RESULT(no)
1785 AC_MSG_CHECKING(for struct ip_mreq)
1786 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1787 struct ip_mreq mreq;
1788 mreq.imr_interface.s_addr = 0;
1789 ], [
1790 # Yes, we have it...
1791 AC_MSG_RESULT(yes)
1792 AC_DEFINE(HAVE_STRUCT_IP_MREQ)
1793 ], [
1794 # No multicast support
1795 AC_MSG_RESULT(no)
1796 ])
1797 ])
1798 AC_CHECK_FUNCS(GetProcessId)
1799 fi
1801 dnl socklen_t check
1802 AC_MSG_CHECKING(for socklen_t)
1803 AC_TRY_COMPILE([
1804 #include <sys/types.h>
1805 #include <sys/socket.h>
1806 ],[
1807 socklen_t foo;
1808 ],[
1809 ac_cv_c_socklen_t=yes
1810 AC_DEFINE(HAVE_SOCKLEN_T, 1, [Have socklen_t])
1811 AC_MSG_RESULT(yes)
1812 ],[
1813 AC_MSG_RESULT(no)
1814 ])
1816 AC_MSG_CHECKING(for array element initializer support)
1817 AC_TRY_COMPILE([#include <sys/socket.h>], [
1818 const int array[] = {[1] = 2,};
1819 ], [
1820 # Yes, we have it...
1821 AC_MSG_RESULT(yes)
1822 AC_DEFINE(HAVE_ARRAY_ELEM_INIT,1,[Supports C99 array initialization])
1823 ], [
1824 # We'll have to use signals
1825 AC_MSG_RESULT(no)
1826 ])
1828 AC_CHECK_FUNCS(trunc, , AC_MSG_CHECKING(for trunc in math.h)
1829 # Simply calling trunc (0.0) is no good since gcc will optimize the call away
1830 AC_TRY_LINK([#include <math.h>],
1831 [ static void *p = &trunc; ],
1832 [
1833 AC_DEFINE(HAVE_TRUNC)
1834 AC_MSG_RESULT(yes)
1835 ac_cv_trunc=yes
1836 ],
1837 AC_MSG_RESULT(no)))
1839 if test "x$ac_cv_truncl" != "xyes"; then
1840 AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL, 1, [Has the 'aintl' function]) LIBS="$LIBS -lsunmath"])
1841 fi
1843 AC_CHECK_FUNCS(round)
1844 AC_CHECK_FUNCS(rint)
1846 dnl ****************************
1847 dnl *** Look for /dev/random ***
1848 dnl ****************************
1850 AC_MSG_CHECKING([if usage of random device is requested])
1851 AC_ARG_ENABLE(dev-random,
1852 [ --disable-dev-random disable the use of the random device (enabled by default)],
1853 try_dev_random=$enableval, try_dev_random=yes)
1855 AC_MSG_RESULT($try_dev_random)
1857 case "{$target}" in
1858 *-openbsd*)
1859 NAME_DEV_RANDOM="/dev/srandom"
1860 ;;
1862 dnl Win32 does not have /dev/random, they have their own method...
1864 *-mingw*|*-*-cygwin*)
1865 ac_cv_have_dev_random=no
1866 ;;
1868 dnl Everywhere else, it's /dev/random
1870 *)
1871 NAME_DEV_RANDOM="/dev/random"
1872 ;;
1873 esac
1875 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM", [Name of /dev/random])
1877 dnl Now check if the device actually exists
1879 if test "x$try_dev_random" = "xyes"; then
1880 AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
1881 [if test -r "$NAME_DEV_RANDOM" ; then
1882 ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
1883 if test "x$ac_cv_have_dev_random" = "xyes"; then
1884 AC_DEFINE(HAVE_CRYPT_RNG, 1, [Have /dev/random])
1885 fi
1886 else
1887 AC_MSG_CHECKING(for random device)
1888 ac_cv_have_dev_random=no
1889 AC_MSG_RESULT(has been disabled)
1890 fi
1892 if test "x$host_win32" = "xyes"; then
1893 AC_DEFINE(HAVE_CRYPT_RNG)
1894 fi
1896 if test "x$ac_cv_have_dev_random" = "xno" \
1897 && test "x$host_win32" = "xno"; then
1898 AC_MSG_WARN([[
1899 ***
1900 *** A system-provided entropy source was not found on this system.
1901 *** Because of this, the System.Security.Cryptography random number generator
1902 *** will throw a NotImplemented exception.
1903 ***
1904 *** If you are seeing this message, and you know your system DOES have an
1905 *** entropy collection in place, please contact <crichton@gimp.org> and
1906 *** provide information about the system and how to access the random device.
1907 ***
1908 *** Otherwise you can install either egd or prngd and set the environment
1909 *** variable MONO_EGD_SOCKET to point to the daemon's socket to use that.
1910 ***]])
1911 fi
1913 AC_MSG_CHECKING([if inter-process shared handles are requested])
1914 AC_ARG_ENABLE(shared-handles, [ --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
1915 AC_MSG_RESULT($try_shared_handles)
1916 if test "x$try_shared_handles" != "xyes"; then
1917 AC_DEFINE(DISABLE_SHARED_HANDLES, 1, [Disable inter-process shared handles])
1918 AC_SUBST(DISABLE_SHARED_HANDLES)
1919 fi
1921 AC_ARG_ENABLE(nunit-tests, [ --enable-nunit-tests Run the nunit tests of the class library on 'make check'])
1922 AM_CONDITIONAL(ENABLE_NUNIT_TESTS, [test x$enable_nunit_tests = xyes])
1924 AC_MSG_CHECKING([if big-arrays are to be enabled])
1925 AC_ARG_ENABLE(big-arrays, [ --enable-big-arrays Enable the allocation and indexing of arrays greater than Int32.MaxValue], enable_big_arrays=$enableval, enable_big_arrays=no)
1926 if test "x$enable_big_arrays" = "xyes" ; then
1927 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1928 AC_DEFINE(MONO_BIG_ARRAYS,1,[Enable the allocation and indexing of arrays greater than Int32.MaxValue])
1929 else
1930 AC_MSG_ERROR([The allocation and indexing of arrays greater than Int32.MaxValue is not supported on this platform.])
1931 fi
1932 fi
1933 AC_MSG_RESULT($enable_big_arrays)
1935 dnl **************
1936 dnl *** DTRACE ***
1937 dnl **************
1939 AC_ARG_ENABLE(dtrace,[ --enable-dtrace Enable DTrace probes], enable_dtrace=$enableval, enable_dtrace=$has_dtrace)
1941 if test "x$enable_dtrace" = "xyes"; then
1942 if test "x$has_dtrace" = "xno"; then
1943 AC_MSG_ERROR([DTrace probes are not supported on this platform.])
1944 fi
1945 AC_PATH_PROG(DTRACE, [dtrace], [no], [$PATH:/usr/sbin])
1946 if test "x$DTRACE" = "xno"; then
1947 AC_MSG_RESULT([dtrace utility not found, dtrace support disabled.])
1948 enable_dtrace=no
1949 elif ! $DTRACE -h -s $srcdir/data/mono.d > /dev/null 2>&1; then
1950 AC_MSG_RESULT([dtrace doesn't support -h option, dtrace support disabled.])
1951 enable_dtrace=no
1952 fi
1953 fi
1955 dtrace_g=no
1956 if test "x$enable_dtrace" = "xyes"; then
1957 AC_DEFINE(ENABLE_DTRACE, 1, [Enable DTrace probes])
1958 DTRACEFLAGS=
1959 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1960 case "$host" in
1961 powerpc-*-darwin*)
1962 DTRACEFLAGS="-arch ppc64"
1963 ;;
1964 i*86-*-darwin*)
1965 DTRACEFLAGS="-arch x86_64"
1966 ;;
1967 *)
1968 DTRACEFLAGS=-64
1969 ;;
1970 esac
1971 else
1972 case "$host" in
1973 powerpc-*-darwin*)
1974 DTRACEFLAGS="-arch ppc"
1975 ;;
1976 i*86-*-darwin*)
1977 DTRACEFLAGS="-arch i386"
1978 ;;
1979 *)
1980 DTRACEFLAGS=-32
1981 ;;
1982 esac
1983 fi
1984 AC_SUBST(DTRACEFLAGS)
1985 case "$host" in
1986 *-*-solaris*)
1987 dtrace_g=yes
1988 ;;
1989 esac
1990 AC_CHECK_HEADERS([sys/sdt.h])
1991 fi
1992 AM_CONDITIONAL(ENABLE_DTRACE, [test x$enable_dtrace = xyes])
1993 AM_CONDITIONAL(DTRACE_G_REQUIRED, [test x$dtrace_g = xyes])
1995 dnl **************
1996 dnl *** NaCl ***
1997 dnl **************
1999 AC_ARG_ENABLE(nacl_codegen, [ --enable-nacl-codegen Enable Native Client code generation], enable_nacl_codegen=$enableval, enable_nacl_codegen=no)
2001 AM_CONDITIONAL(NACL_CODEGEN, test x$enable_nacl_codegen != xno)
2002 if test "x$enable_nacl_codegen" = "xyes"; then
2003 MONO_NACL_ALIGN_MASK_OFF=1
2004 CPPFLAGS="$CPPFLAGS -D__native_client_codegen__"
2005 AC_DEFINE(TARGET_NACL, 1, [...])
2006 else
2007 MONO_NACL_ALIGN_MASK_OFF=0
2008 fi
2009 AC_SUBST(MONO_NACL_ALIGN_MASK_OFF)
2011 dnl **************
2012 dnl *** LLVM ***
2013 dnl **************
2015 AC_ARG_ENABLE(llvm,[ --enable-llvm Enable the experimental LLVM back-end], enable_llvm=$enableval, enable_llvm=no)
2016 AC_ARG_ENABLE(loadedllvm,[ --enable-loadedllvm Load the LLVM back-end dynamically], enable_llvm=$enableval && enable_loadedllvm=$enableval, enable_loadedllvm=no)
2018 if test "x$enable_llvm" = "xyes"; then
2019 AC_PATH_PROG(LLVM_CONFIG, llvm-config, no)
2020 if test "x$LLVM_CONFIG" = "xno"; then
2021 AC_MSG_ERROR([llvm-config not found.])
2022 fi
2024 # The output of --cflags seems to include optimizations flags too
2025 LLVM_CFLAGS=`$LLVM_CONFIG --cflags | sed -e 's/-O2//g' | sed -e 's/-O0//g' | sed -e 's/-fomit-frame-pointer//g' | sed -e 's/-fPIC//g'`
2026 # LLVM is compiled with -fno-rtti, so we need this too, since our classes inherit
2027 # from LLVM classes.
2028 LLVM_CXXFLAGS="`$LLVM_CONFIG --cxxflags` -fno-rtti"
2029 LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2030 LLVM_LIBS=`$LLVM_CONFIG --libs core bitwriter jit x86codegen`
2031 LLVM_LIBS="$LLVM_LDFLAGS $LLVM_LIBS -lstdc++"
2033 # Should be something like '2.6' or '2.7svn'
2034 llvm_version=`$LLVM_CONFIG --version`
2035 major_version=`echo $llvm_version | cut -c 1`
2036 minor_version=`echo $llvm_version | cut -c 3`
2037 if echo $llvm_version | grep -q 'mono'; then
2038 AC_DEFINE(LLVM_MONO_BRANCH, 1, [Whenever we are using the mono branch of LLVM])
2039 LLVM_CXXFLAGS="$LLVM_CXXFLAGS -DLLVM_MONO_BRANCH"
2040 fi
2042 AC_DEFINE_UNQUOTED(LLVM_MAJOR_VERSION, $major_version, [Major version of LLVM libraries])
2043 AC_DEFINE_UNQUOTED(LLVM_MINOR_VERSION, $minor_version, [Minor version of LLVM libraries])
2044 AC_DEFINE_UNQUOTED(LLVM_VERSION, "$llvm_version", [Full version of LLVM libraties])
2046 # Have to pass these on the command line since mini-llvm-cpp.h already includes
2047 # llvm's config.h
2048 LLVM_CXXFLAGS="$LLVM_CXXFLAGS -DLLVM_MAJOR_VERSION=$major_version -DLLVM_MINOR_VERSION=$minor_version"
2050 AC_SUBST(LLVM_CFLAGS)
2051 AC_SUBST(LLVM_CXXFLAGS)
2052 AC_SUBST(LLVM_LIBS)
2053 AC_SUBST(LLVM_LDFLAGS)
2054 AC_DEFINE(ENABLE_LLVM, 1, [Enable the LLVM back end])
2055 fi
2057 AM_CONDITIONAL(ENABLE_LLVM, [test x$enable_llvm = xyes])
2058 if test "x$enable_loadedllvm" = "xyes"; then
2059 AC_DEFINE(MONO_LLVM_LOADED, 1, [The LLVM back end is dynamically loaded])
2060 fi
2061 AM_CONDITIONAL(LOADED_LLVM, [test x$enable_loadedllvm = xyes])
2063 TARGET="unknown"
2064 ACCESS_UNALIGNED="yes"
2066 JIT_SUPPORTED=no
2067 INTERP_SUPPORTED=no
2068 LIBC="libc.so.6"
2069 INTL="libc.so.6"
2070 SQLITE="libsqlite.so.0"
2071 SQLITE3="libsqlite3.so.0"
2072 X11="libX11.so"
2074 sizeof_register="SIZEOF_VOID_P"
2076 jit_wanted=false
2077 interp_wanted=false
2078 sgen_supported=false
2079 case "$host" in
2080 # mips-sgi-irix5.* | mips-sgi-irix6.*)
2081 # TARGET=MIPS;
2082 # ACCESS_UNALIGNED="no"
2083 # ;;
2084 mips*)
2085 TARGET=MIPS;
2086 arch_target=mips;
2087 ACCESS_UNALIGNED="no"
2088 JIT_SUPPORTED=yes
2089 jit_wanted=true
2091 AC_MSG_CHECKING(for mips n32)
2092 AC_TRY_COMPILE([], [
2093 void main () {
2094 #if _MIPS_SIM != _ABIN32
2095 #error Not mips n32
2096 #endif
2097 }
2098 ],[
2099 AC_MSG_RESULT(yes)
2100 sizeof_register=8
2101 ],[
2102 AC_MSG_RESULT(no)
2103 ])
2104 ;;
2105 i*86-*-*)
2106 TARGET=X86;
2107 arch_target=x86;
2108 JIT_SUPPORTED=yes
2109 jit_wanted=true
2110 case $host_os in
2111 solaris*)
2112 LIBC="libc.so"
2113 INTL="libintl.so"
2114 if test "x$ac_cv_sizeof_void_p" = "x8"; then
2115 TARGET=AMD64
2116 arch_target=amd64
2117 fi
2119 # On solaris 10 x86, gcc prints a warning saying 'visibility attribute not supported on this configuration; ignored', but linking fails. A test case:
2120 # int astruct __attribute__ ((visibility ("hidden")));
2121 # void foo ()
2122 # {
2123 # void *p = &astruct;
2124 # }
2125 # gcc -fPIC --shared -o libfoo.so foo.c
2126 # yields:
2127 # foo.c:6: warning: visibility attribute not supported in this configuration; ignored
2128 # ld: fatal: relocation error: R_386_GOTOFF: file /var/tmp//ccxYR96k.o: symbol astruct: relocation must bind locally
2129 have_visibility_hidden=no
2130 ;;
2131 cygwin*)
2132 have_visibility_hidden=no
2133 ;;
2134 haiku*)
2135 LIBC=libroot.so
2136 ;;
2137 linux*)
2138 sgen_supported=true
2139 AOT_SUPPORTED="yes"
2140 ;;
2141 darwin*|openbsd*)
2142 sgen_supported=true
2143 ;;
2144 esac
2145 ;;
2146 x86_64-*-* | amd64-*-*)
2147 TARGET=AMD64;
2148 arch_target=amd64;
2149 JIT_SUPPORTED=yes
2150 jit_wanted=true
2151 case $host_os in
2152 linux*)
2153 sgen_supported=true
2154 AOT_SUPPORTED="yes"
2155 ;;
2156 darwin*|openbsd*)
2157 sgen_supported=true
2158 ;;
2159 esac
2160 ;;
2161 ia64-*-*)
2162 TARGET=IA64
2163 arch_target=ia64
2164 ACCESS_UNALIGNED="no"
2165 JIT_SUPPORTED=yes
2166 jit_wanted=true
2167 LIBC="libc.so.6.1"
2168 INTL="libc.so.6.1"
2169 AC_CHECK_LIB(unwind, _U_dyn_register, [], [AC_MSG_ERROR(library libunwind not found)])
2170 libmono_ldflags="-lunwind"
2171 ;;
2172 sparc*-*-*)
2173 if test "x$ac_cv_sizeof_void_p" = "x8"; then
2174 TARGET=SPARC64
2175 else
2176 TARGET=SPARC
2177 fi
2178 arch_target=sparc;
2179 JIT_SUPPORTED=yes
2180 ACCESS_UNALIGNED="no"
2181 case $host_os in
2182 linux*) ;;
2183 *)
2184 LIBC="libc.so"
2185 INTL="libintl.so"
2186 esac
2187 jit_wanted=true
2188 if test x"$GCC" = xyes; then
2189 # We don't support v8 cpus
2190 CFLAGS="$CFLAGS -Wno-cast-align -mcpu=v9"
2191 fi
2192 if test x"$AR" = xfalse; then
2193 AC_MSG_ERROR([The required utility 'ar' is not found in your PATH. Usually it can be found in /usr/ccs/bin.])
2194 fi
2195 ;;
2196 alpha*-*-linux* | alpha*-*-osf*)
2197 TARGET=ALPHA;
2198 ACCESS_UNALIGNED="no"
2199 JIT_SUPPORTED=yes
2200 jit_wanted=true
2201 arch_target=alpha;
2202 CFLAGS="$CFLAGS -mieee -O0"
2203 case $host_os in
2204 linux*)
2205 LIBC="libc.so.6.1"
2206 INTL="libc.so.6.1"
2207 esac
2208 ;;
2209 *-mingw*|*-*-cygwin*)
2210 # When this is enabled, it leads to very strange crashes at runtime (gcc-3.4.4)
2211 have_visibility_hidden=no
2212 INTL="intl"
2213 ;;
2214 hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
2215 TARGET=HPPA;
2216 arch_target=hppa;
2217 LIBC="libc.sl"
2218 ACCESS_UNALIGNED="no"
2219 INTERP_SUPPORTED=yes
2220 interp_wanted=true
2221 ;;
2222 hppa*linux*)
2223 TARGET=HPPA;
2224 arch_target=hppa;
2225 ACCESS_UNALIGNED="no"
2226 JIT_SUPPORTED=yes
2227 jit_wanted=true
2228 ;;
2229 macppc-*-openbsd* | powerpc*-*-linux* | powerpc-*-openbsd* | \
2230 powerpc-*-sysv* | powerpc-*-darwin* | powerpc-*-netbsd* | powerpc-*-freebsd* )
2231 if test "x$ac_cv_sizeof_void_p" = "x8"; then
2232 TARGET=POWERPC64;
2233 CPPFLAGS="$CPPFLAGS -D__mono_ppc__ -D__mono_ppc64__"
2234 CFLAGS="$CFLAGS -mminimal-toc"
2235 else
2236 TARGET=POWERPC;
2237 CPPFLAGS="$CPPFLAGS -D__mono_ppc__"
2238 fi
2239 arch_target=ppc;
2240 JIT_SUPPORTED=yes
2241 jit_wanted=true
2242 case $host_os in
2243 linux*|darwin*)
2244 sgen_supported=true
2245 ;;
2246 esac
2247 ;;
2248 arm*-darwin*)
2249 TARGET=ARM;
2250 arch_target=arm;
2251 ACCESS_UNALIGNED="no"
2252 JIT_SUPPORTED=yes
2253 CPPFLAGS="$CPPFLAGS -DARM_FPU_NONE=1"
2254 jit_wanted=true
2255 sgen_supported=true
2256 ;;
2257 arm*-linux*)
2258 TARGET=ARM;
2259 arch_target=arm;
2260 ACCESS_UNALIGNED="no"
2261 JIT_SUPPORTED=yes
2262 jit_wanted=true
2263 sgen_supported=true
2264 ;;
2265 s390-*-linux*)
2266 TARGET=S390;
2267 arch_target=s390;
2268 ACCESS_UNALIGNED="yes"
2269 JIT_SUPPORTED=yes
2270 jit_wanted=true
2271 sgen_supported=true
2272 # Required CFLAGS for s390[x]. USE_STRING_INLINES is automatic with gcc 4.1
2273 CFLAGS="$CFLAGS -mbackchain -D__USE_STRING_INLINES"
2274 ;;
2275 s390x-*-linux*)
2276 TARGET=S390x;
2277 arch_target=s390x;
2278 ACCESS_UNALIGNED="yes"
2279 JIT_SUPPORTED=yes
2280 jit_wanted=true
2281 sgen_supported=true
2282 CFLAGS="$CFLAGS -mbackchain -D__USE_STRING_INLINES"
2283 ;;
2284 esac
2286 if test "x$host" != "x$target"; then
2287 case "$target" in
2288 powerpc64-ps3-linux-gnu)
2289 TARGET=POWERPC64
2290 arch_target=powerpc64
2291 AC_DEFINE(TARGET_PS3, 1, [...])
2292 AC_DEFINE(MONO_CROSS_COMPILE,1,[The runtime is compiled for cross-compiling mode])
2293 # It would be better to just use TARGET_POWERPC64, but lots of code already
2294 # uses this define
2295 AC_DEFINE(__mono_ppc64__, 1, [...])
2296 AC_DEFINE(__mono_ilp32__, 1, [64 bit mode with 4 byte longs and pointers])
2297 sizeof_register=8
2298 target_byte_order=G_BIG_ENDIAN
2299 ;;
2301 powerpc64-xbox360-linux-gnu)
2302 TARGET=POWERPC64
2303 arch_target=powerpc64
2304 AC_DEFINE(TARGET_XBOX360, 1, [...])
2305 AC_DEFINE(MONO_CROSS_COMPILE,1,[The runtime is compiled for cross-compiling mode])
2306 # It would be better to just use TARGET_POWERPC64, but lots of code already
2307 # uses this define
2308 sizeof_register=8
2309 target_byte_order=G_BIG_ENDIAN
2310 ;;
2311 *)
2312 AC_MSG_WARN([Cross compiling is only supported for targets matching 'powerpc64-{ps3,xbox360}-linux-gnu'])
2313 esac
2314 fi
2316 # FIXME: Define the others as well
2317 case "$TARGET" in
2318 X86)
2319 AC_DEFINE(TARGET_X86, 1, [...])
2320 ;;
2321 AMD64)
2322 AC_DEFINE(TARGET_AMD64, 1, [...])
2323 ;;
2324 ARM)
2325 AC_DEFINE(TARGET_ARM, 1, [...])
2326 ;;
2327 POWERPC)
2328 AC_DEFINE(TARGET_POWERPC, 1, [...])
2329 ;;
2330 POWERPC64)
2331 AC_DEFINE(TARGET_POWERPC, 1, [...])
2332 AC_DEFINE(TARGET_POWERPC64, 1, [...])
2333 ;;
2334 esac
2336 if test "x$sizeof_register" = "x4"; then
2337 AC_DEFINE(SIZEOF_REGISTER,4,[size of machine integer registers])
2338 elif test "x$sizeof_register" = "x8"; then
2339 AC_DEFINE(SIZEOF_REGISTER,8,[size of machine integer registers])
2340 else
2341 AC_DEFINE(SIZEOF_REGISTER,SIZEOF_VOID_P,[size of machine integer registers])
2342 fi
2344 if test "x$target_byte_order" = "xG_BIG_ENDIAN"; then
2345 AC_DEFINE(TARGET_BYTE_ORDER,G_BIG_ENDIAN,[byte order of target])
2346 elif test "x$target_byte_order" = "xG_LITTLE_ENDIAN"; then
2347 AC_DEFINE(TARGET_BYTE_ORDER,G_LITTLE_ENDIAN,[byte order of target])
2348 else
2349 AC_DEFINE(TARGET_BYTE_ORDER,G_BYTE_ORDER,[byte order of target])
2350 fi
2352 if test "x$have_visibility_hidden" = "xyes"; then
2353 AC_DEFINE(HAVE_VISIBILITY_HIDDEN, 1, [Support for the visibility ("hidden") attribute])
2354 fi
2356 if test "x$have_deprecated" = "xyes"; then
2357 AC_DEFINE(HAVE_DEPRECATED, 1, [Support for the deprecated attribute])
2358 fi
2360 dnl
2361 dnl Simple Generational checks (sgen)
2362 dnl
2363 SGEN_DEFINES=
2364 AC_ARG_WITH(sgen, [ --with-sgen=yes,no Extra Generational GC, default=yes],[buildsgen=$with_sgen],[buildsgen=yes])
2365 if test x$buildsgen = xyes; then
2366 if $sgen_supported; then
2367 SGEN_DEFINES="-DHAVE_SGEN_GC -DHAVE_MOVING_COLLECTOR -DHAVE_WRITE_BARRIERS"
2368 gc_msg="sgen and $gc_msg"
2369 else
2370 buildsgen=no
2371 AC_MSG_WARN("Sgen is not supported on this platform")
2372 fi
2373 fi
2374 AC_SUBST(SGEN_DEFINES)
2375 AM_CONDITIONAL(SUPPORT_SGEN, test x$buildsgen = xyes)
2377 AC_ARG_WITH(jit, [ --with-jit=yes,no If you want to build scripts that default to the JIT (defaults to no)],[
2378 if test x$withval = xyes; then
2379 jit_wanted=true
2380 else
2381 jit_wanted=false
2382 fi
2383 ])
2385 AC_ARG_WITH(interp, [ --with-interp=yes,no If you want to build scripts that default to the interpreter (defaults to no)],[
2386 if test x$withval = xyes; then
2387 interp_wanted=true
2388 else
2389 interp_wanted=false
2390 fi
2391 ])
2393 USEJIT=false
2394 if test x$JIT_SUPPORTED = xyes; then
2395 if $jit_wanted; then
2396 USEJIT=true
2397 jit_status="Building and using the JIT"
2398 else
2399 if $interp_wanted; then
2400 jit_status="Building the JIT, defaulting to the interpreter"
2401 else
2402 AC_ERROR(No JIT or interpreter support available or selected.)
2403 fi
2404 fi
2405 else
2406 if test x$interp_wanted = xtrue; then
2407 jit_status="interpreter"
2408 else
2409 AC_ERROR(No JIT or interpreter support available or selected.)
2410 fi
2411 fi
2413 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
2415 libsuffix=".so"
2417 case "$host" in
2418 *-*-darwin*)
2419 libsuffix=".dylib"
2420 LIBC="libc.dylib"
2421 INTL="libintl.dylib"
2422 SQLITE="libsqlite.0.dylib"
2423 SQLITE3="libsqlite3.0.dylib"
2424 X11="libX11.dylib"
2425 ;;
2426 *-*-*netbsd*)
2427 LIBC="libc.so.12"
2428 INTL="libintl.so.0"
2429 ;;
2430 *-*-*freebsd*)
2431 LIBC="libc.so"
2432 INTL="libintl.so"
2433 SQLITE="libsqlite.so"
2434 SQLITE3="libsqlite3.so"
2435 ;;
2436 *-*-*openbsd*)
2437 LIBC="libc.so"
2438 INTL="libintl.so"
2439 SQLITE="libsqlite.so"
2440 SQLITE3="libsqlite3.so"
2441 ;;
2442 *-*-*linux*)
2443 AC_PATH_X
2444 AC_MSG_CHECKING(for the soname of libX11.so)
2445 for i in $x_libraries /usr/lib /usr/lib64; do
2446 for r in 4 5 6; do
2447 if test -f $i/libX11.so.$r; then
2448 X11=libX11.so.$r
2449 AC_MSG_RESULT($X11)
2450 fi
2451 done
2452 done
2454 if test "x$X11" = "xlibX11.so"; then
2455 AC_MSG_WARN([Could not find X development libs. Do you have the -devel package installed? WinForms may not work...]);
2456 fi
2457 ;;
2458 esac
2461 AC_SUBST(libsuffix)
2463 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86"; then
2464 if test "x$with_tls" = "x__thread"; then
2465 #
2466 # On some linux distributions, TLS works in executables, but linking
2467 # against a shared library containing TLS fails with:
2468 # undefined reference to `__tls_get_addr'
2469 #
2470 rm -f conftest.c conftest.so conftest
2471 echo "static __thread int foo; void main () { foo = 5; }" > conftest.c
2472 $CC -fPIC --shared -o conftest.so conftest.c > /dev/null 2>&1
2473 $CC -o conftest conftest.so > /dev/null 2>&1
2474 if test ! -f conftest; then
2475 AC_MSG_WARN([Disabling usage of __thread.]);
2476 with_tls=pthread
2477 fi
2478 rm -f conftest.c conftest.so conftest
2479 fi
2480 fi
2482 mono_debugger_supported=no
2483 AC_ARG_ENABLE(mono-debugger, [ --disable-mono-debugger disable support for the mdb debugger], try_mono_debugger=$enableval, try_mono_debugger=yes)
2484 if test "x$try_mono_debugger" = "xyes"; then
2485 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86" -o "x$TARGET" = "xALPHA"; then
2486 if test x$use_included_gc = xyes; then
2487 case "$host" in
2488 *-*-*linux*)
2489 mono_debugger_supported=yes
2490 ;;
2491 *86-apple-darwin*)
2492 mono_debugger_supported=yes
2493 ;;
2494 esac
2495 fi
2496 fi
2497 fi
2499 # disable the debugger entirely when building with moonlight
2500 if test "x$with_moonlight" != "xno"; then
2501 mono_debugger_supported=no
2502 fi
2504 AC_MSG_CHECKING(if the Mono Debugger is supported on this platform)
2505 if test "x$mono_debugger_supported" = "xyes"; then
2506 BOEHM_DEFINES="$BOEHM_DEFINES -DMONO_DEBUGGER_SUPPORTED"
2507 NESTED_LIBGC_FLAGS="-DMONO_DEBUGGER_SUPPORTED"
2508 fi
2509 AM_CONDITIONAL(MONO_DEBUGGER_SUPPORTED, test x$mono_debugger_supported = xyes)
2510 AC_MSG_RESULT($mono_debugger_supported)
2512 if test "x$with_tls" = "x__thread"; then
2513 AC_DEFINE(HAVE_KW_THREAD, 1, [Have __thread keyword])
2514 # Pass the information to libgc
2515 CPPFLAGS="$CPPFLAGS -DUSE_COMPILER_TLS"
2516 AC_MSG_CHECKING(if the tls_model attribute is supported)
2517 AC_TRY_COMPILE([static __thread int foo __attribute__((tls_model("initial-exec")));], [
2518 ], [
2519 AC_MSG_RESULT(yes)
2520 AC_DEFINE(HAVE_TLS_MODEL_ATTR, 1, [tld_model available])
2521 ], [
2522 AC_MSG_RESULT(no)
2523 ])
2524 fi
2526 if test ${TARGET} = ARM && test x$cross_compiling = xno && test x$enable_mcs_build != xno; then
2527 dnl ******************************************
2528 dnl *** Check to see what FPU is available ***
2529 dnl ******************************************
2530 AC_MSG_CHECKING(which FPU to use)
2532 AC_TRY_COMPILE([], [
2533 __asm__ ("ldfd f0, [r0]");
2534 ], fpu=FPA, fpu=NONE)
2536 AC_MSG_RESULT($fpu)
2537 CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu=1"
2538 unset fpu
2539 fi
2541 if test ${TARGET} = unknown; then
2542 CPPFLAGS="$CPPFLAGS -DNO_PORT"
2543 AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
2544 fi
2546 if test ${ACCESS_UNALIGNED} = no; then
2547 CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
2548 fi
2550 case "x$gc" in
2551 xincluded)
2552 # Pass CPPFLAGS to libgc configure
2553 # We should use a separate variable for this to avoid passing useless and
2554 # potentially problematic defines to libgc (like -D_FILE_OFFSET_BITS=64)
2555 # This should be executed late so we pick up the final version of CPPFLAGS
2556 # The problem with this approach, is that during a reconfigure, the main
2557 # configure scripts gets invoked with these arguments, so we use separate
2558 # variables understood by libgc's configure to pass CPPFLAGS and CFLAGS.
2559 LIBGC_CPPFLAGS="$CPPFLAGS $NESTED_LIBGC_FLAGS"
2560 if test x$TARGET = xSPARC -o x$TARGET = xSPARC64; then
2561 LIBGC_CPPFLAGS=`echo $LIBGC_CPPFLAGS | sed -e 's/-D_FILE_OFFSET_BITS=64//g'`
2562 fi
2563 ac_configure_args="$ac_configure_args --disable-embed-check --with-libgc-threads=$libgc_threads $libgc_configure_args \"CPPFLAGS_FOR_LIBGC=$LIBGC_CPPFLAGS\" \"CFLAGS_FOR_LIBGC=$CFLAGS_FOR_LIBGC\""
2564 AC_CONFIG_SUBDIRS(libgc)
2565 ;;
2566 esac
2568 #AC_ARG_WITH(profile2, [ --with-profile2=yes,no If you want to install the 2.0 FX (defaults to yes)], [], [with_profile2=yes])
2569 AC_ARG_WITH(profile4, [ --with-profile4=yes,no If you want to install the 4.0 FX (defaults to yes)], [], [with_profile4=yes])
2570 AC_ARG_WITH(monodroid, [ --with-monodroid=yes,no If you want to build the MonoDroid 2.1 assemblies (defaults to no)], [], [with_monodroid=no])
2571 AC_ARG_WITH(monotouch, [ --with-monotouch=yes,no If you want to build the MonoTouch 2.1 assemblies (defaults to no)], [], [with_monotouch=no])
2573 OPROFILE=no
2574 AC_ARG_WITH(oprofile,[ --with-oprofile=no,<oprofile install dir> Enable oprofile support (defaults to no)],[
2575 if test x$with_oprofile != xno; then
2576 oprofile_include=$with_oprofile/include
2577 if test ! -f $oprofile_include/opagent.h; then
2578 AC_MSG_ERROR([oprofile include file not found at $oprofile_include/opagent.h])
2579 fi
2580 OPROFILE=yes
2581 OPROFILE_CFLAGS="-I$oprofile_include"
2582 OPROFILE_LIBS="-L$with_oprofile/lib/oprofile -lopagent"
2583 AC_DEFINE(HAVE_OPROFILE,1,[Have oprofile support])
2584 fi
2585 ])
2587 MALLOC_MEMPOOLS=no
2588 AC_ARG_WITH(malloc_mempools,[ --with-malloc-mempools=yes,no Use malloc for each single mempool allocation (only for runtime debugging, defaults to no)],[
2589 if test x$with_malloc_mempools = xyes; then
2590 MALLOC_MEMPOOLS=yes
2591 AC_DEFINE(USE_MALLOC_FOR_MEMPOOLS,1,[Use malloc for each single mempool allocation])
2592 fi
2593 ])
2596 DISABLE_MCS_DOCS=no
2597 AC_ARG_WITH(mcs_docs,[ --with-mcs-docs=yes,no If you want to build the documentation under mcs (defaults to yes)],[
2598 if test x$with_mcs_docs != xyes; then
2599 DISABLE_MCS_DOCS=yes
2600 fi
2601 ])
2603 MOONLIGHT_DEFINES=
2604 AC_ARG_WITH(moonlight, [ --with-moonlight=yes|no|only If you want to build Mono for Moonlight (defaults to no)],[
2605 MOONLIGHT_DEFINES="-DMOONLIGHT -DDISABLE_ASSEMBLY_REMAPPING"
2606 ], [with_moonlight=no])
2607 AC_SUBST(MOONLIGHT_DEFINES)
2611 AC_CHECK_HEADER([malloc.h],
2612 [AC_DEFINE([HAVE_USR_INCLUDE_MALLOC_H], [1],
2613 [Define to 1 if you have /usr/include/malloc.h.])],,)
2615 dnl
2616 dnl Consistency settings
2617 dnl
2618 if test x$cross_compiling = xyes -o x$enable_mcs_build = xno; then
2619 DISABLE_MCS_DOCS=yes
2620 fi
2622 if test x$DISABLE_MCS_DOCS = xyes; then
2623 docs_dir=""
2624 else
2625 docs_dir=docs
2626 fi
2627 AC_SUBST(docs_dir)
2629 AM_CONDITIONAL(HAVE_OPROFILE, test x$OPROFILE = xyes)
2630 AC_SUBST(OPROFILE_CFLAGS)
2631 AC_SUBST(OPROFILE_LIBS)
2633 libmono_ldflags="$libmono_ldflags $LIBS"
2635 AM_CONDITIONAL(MOONLIGHT, [test "x$with_moonlight" != "xno"])
2636 AM_CONDITIONAL(ONLY_MOONLIGHT, [test "x$with_moonlight" = "xonly"])
2637 AM_CONDITIONAL(INSTALL_4_0, [test "x$with_profile4" = xyes])
2638 AM_CONDITIONAL(INSTALL_MONODROID, [test "x$with_monodroid" = xyes])
2639 AM_CONDITIONAL(INSTALL_MONOTOUCH, [test "x$with_monotouch" = xyes])
2641 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
2642 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
2643 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
2644 AM_CONDITIONAL(SPARC64, test x$TARGET = xSPARC64)
2645 AM_CONDITIONAL(X86, test x$TARGET = xX86)
2646 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
2647 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
2648 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
2649 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
2650 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
2651 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
2652 AM_CONDITIONAL(POWERPC64, test x$TARGET = xPOWERPC64)
2653 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
2654 AM_CONDITIONAL(S390, test x$TARGET = xS390)
2655 AM_CONDITIONAL(S390x, test x$TARGET = xS390x)
2656 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
2658 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
2659 AM_CONDITIONAL(INTERP_SUPPORTED, test x$interp_wanted = xtrue)
2660 AM_CONDITIONAL(INCLUDED_LIBGC, test x$gc = xincluded)
2662 AC_SUBST(LIBC)
2663 AC_SUBST(INTL)
2664 AC_SUBST(SQLITE)
2665 AC_SUBST(SQLITE3)
2666 AC_SUBST(X11)
2667 AC_DEFINE_UNQUOTED(ARCHITECTURE,"$arch_target",[The architecture this is running on])
2668 AC_SUBST(arch_target)
2669 AC_SUBST(CFLAGS)
2670 AC_SUBST(CPPFLAGS)
2671 AC_SUBST(LDFLAGS)
2673 mono_build_root=`pwd`
2674 AC_SUBST(mono_build_root)
2676 if test x$USEJIT = xtrue; then
2677 mono_runtime=mono/mini/mono
2678 else
2679 mono_runtime=mono/interpreter/mint
2680 fi
2681 AC_SUBST(mono_runtime)
2683 mono_cfg_root=$mono_build_root/runtime
2684 if test x$host_win32 = xyes; then
2685 if test "x$cross_compiling" = "xno"; then
2686 mono_cfg_dir=`cygpath -w -a $mono_cfg_root`\\etc
2687 else
2688 mono_cfg_dir=`echo $mono_cfg_root | tr '/' '\\'`\\etc
2689 fi
2690 else
2691 mono_cfg_dir=$mono_cfg_root/etc
2692 fi
2693 AC_SUBST(mono_cfg_dir)
2695 AC_CONFIG_FILES([po/mcs/Makefile.in])
2697 AC_CONFIG_FILES([runtime/mono-wrapper],[chmod +x runtime/mono-wrapper])
2698 AC_CONFIG_FILES([runtime/monodis-wrapper],[chmod +x runtime/monodis-wrapper])
2700 AC_CONFIG_COMMANDS([runtime/etc/mono/1.0/machine.config],
2701 [ depth=../../../..
2702 case $srcdir in
2703 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2704 .) reldir=$depth ;;
2705 *) reldir=$depth/$srcdir ;;
2706 esac
2707 $ac_aux_dir/install-sh -d runtime/etc/mono/1.0
2708 cd runtime/etc/mono/1.0
2709 rm -f machine.config
2710 $LN_S $reldir/data/net_1_1/machine.config machine.config
2711 cd $depth
2712 ],[LN_S='$LN_S'])
2714 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/machine.config],
2715 [ depth=../../../..
2716 case $srcdir in
2717 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2718 .) reldir=$depth ;;
2719 *) reldir=$depth/$srcdir ;;
2720 esac
2721 $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
2722 cd runtime/etc/mono/2.0
2723 rm -f machine.config
2724 $LN_S $reldir/data/net_2_0/machine.config machine.config
2725 cd $depth
2726 ],[LN_S='$LN_S'])
2728 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/web.config],
2729 [ depth=../../../..
2730 case $srcdir in
2731 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2732 .) reldir=$depth ;;
2733 *) reldir=$depth/$srcdir ;;
2734 esac
2735 $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
2736 cd runtime/etc/mono/2.0
2737 rm -f web.config
2738 $LN_S $reldir/data/net_2_0/web.config web.config
2739 cd $depth
2740 ],[LN_S='$LN_S'])
2742 AC_CONFIG_COMMANDS([runtime/etc/mono/browscap.ini],
2743 [ depth=../../..
2744 case $srcdir in
2745 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2746 .) reldir=$depth ;;
2747 *) reldir=$depth/$srcdir ;;
2748 esac
2749 $ac_aux_dir/install-sh -d runtime/etc/mono/
2750 cd runtime/etc/mono/
2751 rm -f browscap.ini
2752 $LN_S $reldir/data/browscap.ini browscap.ini
2753 cd $depth
2754 ],[LN_S='$LN_S'])
2756 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/Browsers/Compat.browser],
2757 [ depth=../../../../..
2758 case $srcdir in
2759 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2760 .) reldir=$depth ;;
2761 *) reldir=$depth/$srcdir ;;
2762 esac
2763 $ac_aux_dir/install-sh -d runtime/etc/mono/2.0/Browsers/
2764 cd runtime/etc/mono/2.0/Browsers
2765 rm -f Compat.browser
2766 $LN_S $reldir/data/net_2_0/Browsers/Compat.browser Compat.browser
2767 cd $depth
2768 ],[LN_S='$LN_S'])
2770 AC_CONFIG_COMMANDS([runtime/etc/mono/4.0/machine.config],
2771 [ depth=../../../..
2772 case $srcdir in
2773 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2774 .) reldir=$depth ;;
2775 *) reldir=$depth/$srcdir ;;
2776 esac
2777 $ac_aux_dir/install-sh -d runtime/etc/mono/4.0
2778 cd runtime/etc/mono/4.0
2779 rm -f machine.config
2780 $LN_S $reldir/data/net_4_0/machine.config machine.config
2781 cd $depth
2782 ],[LN_S='$LN_S'])
2784 AC_CONFIG_COMMANDS([runtime/etc/mono/4.0/web.config],
2785 [ depth=../../../..
2786 case $srcdir in
2787 [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2788 .) reldir=$depth ;;
2789 *) reldir=$depth/$srcdir ;;
2790 esac
2791 $ac_aux_dir/install-sh -d runtime/etc/mono/4.0
2792 cd runtime/etc/mono/4.0
2793 rm -f web.config
2794 $LN_S $reldir/data/net_4_0/web.config web.config
2795 cd $depth
2796 ],[LN_S='$LN_S'])
2798 if test x$enable_quiet_build = xyes; then
2799 AC_CONFIG_COMMANDS([quiet], [for i in `find mono libgc support -name Makefile.in | sed -e 's/Makefile.in/Makefile/g'`; do if test -f $i; then $srcdir/scripts/patch-quiet.sh $i; fi; done], [shell=$SHELL])
2800 AC_CONFIG_COMMANDS([quiet-libtool], [sed -e 's/$echo "copying selected/$show "copying selected/g' < libtool > libtool.tmp && mv libtool.tmp libtool && chmod a+x libtool; sed -e 's/$ECHO "copying selected/# "copying selected/g' < libtool > libtool.tmp && mv libtool.tmp libtool && chmod a+x libtool])
2801 fi
2803 AC_OUTPUT([
2804 Makefile
2805 mono-core.spec
2806 mono-uninstalled.pc
2807 scripts/mono-find-provides
2808 scripts/mono-find-requires
2809 mono/Makefile
2810 mono/utils/Makefile
2811 mono/metadata/Makefile
2812 mono/dis/Makefile
2813 mono/cil/Makefile
2814 mono/arch/Makefile
2815 mono/arch/x86/Makefile
2816 mono/arch/amd64/Makefile
2817 mono/arch/hppa/Makefile
2818 mono/arch/ppc/Makefile
2819 mono/arch/sparc/Makefile
2820 mono/arch/s390/Makefile
2821 mono/arch/s390x/Makefile
2822 mono/arch/arm/Makefile
2823 mono/arch/alpha/Makefile
2824 mono/arch/ia64/Makefile
2825 mono/arch/mips/Makefile
2826 mono/interpreter/Makefile
2827 mono/tests/Makefile
2828 mono/tests/tests-config
2829 mono/tests/assemblyresolve/Makefile
2830 mono/tests/cas/Makefile
2831 mono/tests/cas/assembly/Makefile
2832 mono/tests/cas/demand/Makefile
2833 mono/tests/cas/inheritance/Makefile
2834 mono/tests/cas/linkdemand/Makefile
2835 mono/tests/cas/threads/Makefile
2836 mono/benchmark/Makefile
2837 mono/monograph/Makefile
2838 mono/io-layer/Makefile
2839 mono/mini/Makefile
2840 mono/profiler/Makefile
2841 ikvm-native/Makefile
2842 scripts/Makefile
2843 man/Makefile
2844 web/Makefile
2845 docs/Makefile
2846 data/Makefile
2847 data/net_2_0/Makefile
2848 data/net_4_0/Makefile
2849 data/net_2_0/Browsers/Makefile
2850 data/mint.pc
2851 data/mono-2.pc
2852 data/mono.pc
2853 data/mono-cairo.pc
2854 data/mono-nunit.pc
2855 data/mono-options.pc
2856 data/mono-lineeditor.pc
2857 data/monodoc.pc
2858 data/mono.web.pc
2859 data/dotnet.pc
2860 data/dotnet35.pc
2861 data/wcf.pc
2862 data/cecil.pc
2863 data/system.web.extensions_1.0.pc
2864 data/system.web.extensions.design_1.0.pc
2865 data/system.web.mvc.pc
2866 data/system.web.mvc2.pc
2867 samples/Makefile
2868 support/Makefile
2869 data/config
2870 tools/Makefile
2871 tools/locale-builder/Makefile
2872 tools/sgen/Makefile
2873 runtime/Makefile
2874 msvc/Makefile
2875 po/Makefile
2876 ])
2878 if test x$host_win32 = xyes; then
2879 # Get rid of 'cyg' prefixes in library names
2880 sed -e "s/\/cyg\//\/\//" libtool > libtool.new; mv libtool.new libtool; chmod 755 libtool
2881 # libtool seems to inherit -mno-cygwin from our CFLAGS, and uses it to compile its executable
2882 # wrapper scripts which use exec(). gcc has no problem compiling+linking this, but the resulting
2883 # executable doesn't work...
2884 sed -e "s,-mno-cygwin,,g" libtool > libtool.new; mv libtool.new libtool; chmod 755 libtool
2885 fi
2887 (
2888 case $prefix in
2889 NONE) prefix=$ac_default_prefix ;;
2890 esac
2891 case $exec_prefix in
2892 NONE) exec_prefix='${prefix}' ;;
2893 esac
2895 #
2896 # If we are cross compiling, we don't build in the mcs/ tree. Let us not clobber
2897 # any existing config.make. This allows people to share the same source tree
2898 # with different build directories, one native and one cross
2899 #
2900 if test x$cross_compiling = xno && test x$enable_mcs_build != xno; then
2902 test -w $mcs_topdir/build || chmod +w $mcs_topdir/build
2904 echo "prefix=$prefix" > $mcs_topdir/build/config.make
2905 echo "exec_prefix=$exec_prefix" >> $mcs_topdir/build/config.make
2906 echo "sysconfdir=$sysconfdir" >> $mcs_topdir/build/config.make
2907 echo 'mono_libdir=${exec_prefix}/lib' >> $mcs_topdir/build/config.make
2908 echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $mcs_topdir/build/config.make
2909 echo 'IL_FLAGS = /debug' >> $mcs_topdir/build/config.make
2910 echo "RUNTIME = $mono_build_root/runtime/mono-wrapper" >> $mcs_topdir/build/config.make
2911 echo "ILDISASM = $mono_build_root/runtime/monodis-wrapper" >> $mcs_topdir/build/config.make
2913 case $INSTALL in
2914 [[\\/$]]* | ?:[[\\/]]* ) mcs_INSTALL=$INSTALL ;;
2915 *) mcs_INSTALL=$mono_build_root/$INSTALL ;;
2916 esac
2918 echo "INSTALL = $mcs_INSTALL" >> $mcs_topdir/build/config.make
2920 export VERSION
2921 [myver=$($AWK 'BEGIN {
2922 split (ENVIRON["VERSION"] ".0.0.0", vsplit, ".")
2923 if(length(vsplit [1]) > 4) {
2924 split (substr(ENVIRON["VERSION"], 0, 4) "." substr(ENVIRON["VERSION"], 5) ".0.0", vsplit, ".")
2925 }
2926 print vsplit [1] "." vsplit [2] "." vsplit [3] "." vsplit [4]
2927 }')]
2929 echo "MONO_VERSION = $myver" >> $mcs_topdir/build/config.make
2931 if test x$platform_darwin = xyes; then
2932 echo "PLATFORM = darwin" >> $mcs_topdir/build/config.make
2933 fi
2935 if test x$AOT_SUPPORTED = xyes -a x$enable_system_aot = xdefault; then
2936 enable_system_aot=yes
2937 fi
2939 if test x$host_win32 = xno -a x$platform_darwin != xyes -a x$enable_system_aot = xyes; then
2940 echo "ENABLE_AOT = 1" >> $mcs_topdir/build/config.make
2941 fi
2943 if test x$DISABLE_MCS_DOCS = xyes; then
2944 echo "DISABLE_MCS_DOCS = yes" >> $mcs_topdir/build/config.make
2945 fi
2947 if test x$with_moonlight != xno; then
2948 echo "MOONLIGHT = 1" >> $srcdir/$mcsdir/build/config.make
2949 fi
2951 fi
2953 # if we have an olive folder, override the default settings
2954 if test -d $olivedir; then
2956 if test x$cross_compiling = xno && test x$enable_olive_build != xno; then
2958 test -w $srcdir/$olivedir/build || chmod +w $srcdir/$olivedir/build
2960 echo "prefix=$prefix" > $srcdir/$olivedir/build/config.make
2961 echo "exec_prefix=$exec_prefix" >> $srcdir/$olivedir/build/config.make
2962 echo 'mono_libdir=${exec_prefix}/lib' >> $srcdir/$olivedir/build/config.make
2963 echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $srcdir/$olivedir/build/config.make
2964 echo "RUNTIME = $mono_build_root/runtime/mono-wrapper" >> $srcdir/$olivedir/build/config.make
2965 echo "MONO_VERSION = $myver" >> $srcdir/$olivedir/build/config.make
2966 fi
2967 fi
2969 )
2971 libgdiplus_msg=${libgdiplus_loc:-assumed to be installed}
2973 echo "
2974 mcs source: $mcsdir
2975 olive source: $olive_topdir
2977 Engine:
2978 GC: $gc_msg
2979 GLIB: $with_glib
2980 TLS: $with_tls
2981 SIGALTSTACK: $with_sigaltstack
2982 Engine: $jit_status
2983 oprofile: $OPROFILE
2984 BigArrays: $enable_big_arrays
2985 DTrace: $enable_dtrace
2986 Parallel Mark: $enable_parallel_mark
2987 LLVM Back End: $enable_llvm (dynamically loaded: $enable_loadedllvm)
2989 Libraries:
2990 Moon Profile: $with_moonlight
2991 MonoDroid: $with_monodroid
2992 MonoTouch: $with_monotouch
2993 JNI support: $jdk_headers_found
2994 libgdiplus: $libgdiplus_msg
2995 zlib: $zlib_msg
2996 $disabled
2997 "
2998 if test x$with_static_mono = xno -a "x$host_win32" != "xyes"; then
2999 AC_MSG_WARN(Turning off static Mono is a risk, you might run into unexpected bugs)
3000 fi